qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/mapinfo.qh>
   5 #include <common/net_linked.qh>
   6 #include <common/physics/player.qh>
   7 #include <common/stats.qh>
   8 #include <common/teams.qh>
   9 #include <common/util.qh>
  10 #include <common/weapons/_all.qh>
  11 #include <lib/csqcmodel/sv_model.qh>
  12 #include <lib/warpzone/common.qh>
  13 #include <lib/warpzone/util_server.qh>
  14 #include <server/antilag.qh>
  15 #include <server/bot/default/aim.qh>
  16 #include <server/bot/default/cvars.qh>
  17 #include <server/bot/default/havocbot/havocbot.qh>
  18 #include <server/bot/default/havocbot/scripting.qh>
  19 #include <server/bot/default/navigation.qh>
  20 #include <server/bot/default/scripting.qh>
  21 #include <server/bot/default/waypoints.qh>
  22 #include <server/campaign.qh>
  23 #include <server/client.qh>
  24 #include <server/damage.qh>
  25 #include <server/items/items.qh>
  26 #include <server/mutators/_mod.qh>
  27 #include <server/race.qh>
  28 #include <server/scores_rules.qh>
  29 #include <server/teamplay.qh>
  30 #include <server/weapons/accuracy.qh>
  31 #include <server/weapons/selection.qh>
  32 #include <server/world.qh>
  33
  34 STATIC_INIT(bot) { bot_calculate_stepheightvec(); }
  35
  36 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  37 void bot_setclientfields(entity this)
  38 {
  39         CS_CVAR(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  40         CS_CVAR(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  41 }
  42
  43 entity bot_spawn()
  44 {
  45         entity bot = spawnclient();
  46         if (bot)
  47         {
  48                 setItemGroupCount();
  49                 currentbots = currentbots + 1;
  50                 bot_setnameandstuff(bot);
  51                 ClientConnect(bot);
  52                 bot_setclientfields(bot);
  53                 PutClientInServer(bot);
  54         }
  55         return bot;
  56 }
  57
  58 void bot_think(entity this)
  59 {
  60         if (this.bot_nextthink > time)
  61                 return;
  62
  63         this.flags &= ~FL_GODMODE;
  64         if(autocvar_bot_god)
  65                 this.flags |= FL_GODMODE;
  66
  67         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * min(14 / (skill + this.bot_aiskill + 14), 1));
  68
  69         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  70         {
  71                 if (IS_PLAYER(this))
  72                 {
  73                         .entity weaponentity = weaponentities[0];
  74                         if(this.(weaponentity).m_weapon == WEP_Null)
  75                                 W_NextWeapon(this, 0, weaponentity);
  76                 }
  77                 CS(this).movement = '0 0 0';
  78                 this.bot_nextthink = time + 0.5;
  79                 return;
  80         }
  81
  82         if (this.fixangle)
  83         {
  84                 this.v_angle = this.angles;
  85                 this.v_angle_z = 0;
  86                 this.fixangle = false;
  87         }
  88
  89         this.dmg_take = 0;
  90         this.dmg_save = 0;
  91         this.dmg_inflictor = NULL;
  92
  93         // calculate an aiming latency based on the skill setting
  94         // (simulated network latency + naturally delayed reflexes)
  95         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
  96         // minimum ping 20+10 random
  97         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
  98         // skill 10 = ping 0.2 (adrenaline)
  99         // skill 0 = ping 0.7 (slightly drunk)
 100
 101         // clear buttons
 102         PHYS_INPUT_BUTTON_ATCK(this) = false;
 103         // keep jump button pressed for a short while, useful with ramp jumps
 104         PHYS_INPUT_BUTTON_JUMP(this) = (!IS_DEAD(this) && time < this.bot_jump_time + 0.2);
 105         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 106         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 107         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 108         PHYS_INPUT_BUTTON_HOOK(this) = false;
 109         PHYS_INPUT_BUTTON_INFO(this) = false;
 110         PHYS_INPUT_BUTTON_DRAG(this) = false;
 111         PHYS_INPUT_BUTTON_CHAT(this) = false;
 112         PHYS_INPUT_BUTTON_USE(this) = false;
 113
 114         if (time < game_starttime)
 115         {
 116                 .entity weaponentity = weaponentities[0];
 117                 if(this.(weaponentity).m_weapon == WEP_Null)
 118                         W_NextWeapon(this, 0, weaponentity);
 119                 // block the bot during the countdown to game start
 120                 CS(this).movement = '0 0 0';
 121                 return;
 122         }
 123
 124         // if dead, just wait until we can respawn
 125         if (IS_DEAD(this) || IS_OBSERVER(this))
 126         {
 127                 if (bot_waypoint_queue_owner == this)
 128                         bot_waypoint_queue_owner = NULL;
 129                 this.aistatus = 0;
 130                 CS(this).movement = '0 0 0';
 131                 if (IS_OBSERVER(this))
 132                         return;
 133                 if (IS_DEAD(this))
 134                 {
 135                         if (!navigation_goalrating_timeout(this))
 136                                 navigation_goalrating_timeout_force(this);
 137                         // jump must not be pressed for at least one frame in order for
 138                         // PlayerThink to detect the key down event
 139                         if (this.deadflag == DEAD_DYING)
 140                                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 141                         else if (this.deadflag == DEAD_DEAD)
 142                                 PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 143                 }
 144         }
 145         else if(this.aistatus & AI_STATUS_STUCK)
 146                 navigation_unstuck(this);
 147
 148         // now call the current bot AI (havocbot for example)
 149         this.bot_ai(this);
 150 }
 151
 152 void bot_setnameandstuff(entity this)
 153 {
 154         string readfile, s;
 155         int file, tokens, prio;
 156
 157         file = fopen(autocvar_bot_config_file, FILE_READ);
 158
 159         if(file < 0)
 160         {
 161                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 162                 readfile = "";
 163         }
 164         else
 165         {
 166                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
 167                 TeamBalance_GetTeamCounts(balance, NULL);
 168                 int smallest_team = -1;
 169                 int smallest_count = -1;
 170                 if (teamplay)
 171                 {
 172                         for (int i = 1; i <= AVAILABLE_TEAMS; ++i)
 173                         {
 174                                 // NOTE if (autocvar_g_campaign && autocvar_g_campaign_forceteam == i)
 175                                 // TeamBalance_GetNumberOfPlayers(balance, i); returns the number of players + 1
 176                                 // since it keeps a spot for the real player in the desired team
 177                                 int count = TeamBalance_GetNumberOfPlayers(balance, i);
 178                                 if (smallest_count < 0 || count < smallest_count)
 179                                 {
 180                                         smallest_team = i;
 181                                         smallest_count = count;
 182                                 }
 183                         }
 184                 }
 185                 TeamBalance_Destroy(balance);
 186                 RandomSelection_Init();
 187                 while((readfile = fgets(file)))
 188                 {
 189                         if(substring(readfile, 0, 2) == "//")
 190                                 continue;
 191                         if(substring(readfile, 0, 1) == "#")
 192                                 continue;
 193                         // NOTE if the line is empty tokenizebyseparator(readfile, "\t")
 194                         // will create 1 empty token because there's no separator (bug?)
 195                         if (readfile == "")
 196                                 continue;
 197                         tokens = tokenizebyseparator(readfile, "\t");
 198                         if(tokens == 0)
 199                                 continue;
 200                         s = argv(0);
 201                         prio = 0;
 202                         bool conflict = false;
 203                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 204                                 if (s == it.cleanname)
 205                                 {
 206                                         conflict = true;
 207                                         break;
 208                                 }
 209                         });
 210                         if (!conflict)
 211                                 prio += 1;
 212                         if (teamplay && !(autocvar_bot_vs_human && AVAILABLE_TEAMS == 2))
 213                         {
 214                                 int forced_team = stof(argv(5));
 215                                 if (!Team_IsValidIndex(forced_team))
 216                                         forced_team = 0;
 217                                 if (!forced_team || forced_team == smallest_team)
 218                                         prio += 2;
 219                         }
 220                         RandomSelection_AddString(readfile, 1, prio);
 221                 }
 222                 readfile = RandomSelection_chosen_string;
 223                 fclose(file);
 224         }
 225
 226         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 227
 228         tokens = tokenizebyseparator(readfile, "\t");
 229         if(argv(0) != "") bot_name = argv(0);
 230         else bot_name = "Bot";
 231
 232         if(argv(1) != "") bot_model = argv(1);
 233         else bot_model = "";
 234
 235         if(argv(2) != "") bot_skin = argv(2);
 236         else bot_skin = "0";
 237
 238         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 239         else bot_shirt = ftos(floor(random() * 15));
 240
 241         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 242         else bot_pants = ftos(floor(random() * 15));
 243
 244         if (teamplay && !(autocvar_bot_vs_human && AVAILABLE_TEAMS == 2))
 245         {
 246                 this.bot_forced_team = stof(argv(5));
 247                 if (!Team_IsValidIndex(this.bot_forced_team))
 248                         this.bot_forced_team = 0;
 249         }
 250         else
 251                 this.bot_forced_team = 0;
 252
 253         prio = 6;
 254
 255         #define READSKILL(f, w, r) MACRO_BEGIN \
 256                 if(argv(prio) != "") \
 257                         this.f = stof(argv(prio)) * w; \
 258                 else \
 259                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 260                 prio++; \
 261         MACRO_END
 262         //print(bot_name, ": ping=", argv(9), "\n");
 263
 264         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 265         READSKILL(bot_moveskill, 2, 0); // move skill
 266         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 267
 268         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 269
 270         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 271         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 272         READSKILL(bot_rangepreference, 1, 0); // read skill
 273
 274         READSKILL(bot_aimskill, 2, 0); // aim skill
 275         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 276         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 277
 278         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 279         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 280
 281         if (file >= 0 && argv(prio) != "")
 282                 LOG_INFOF("^1Warning^7: too many parameters for bot %s, please check format of %s", bot_name, autocvar_bot_config_file);
 283
 284         this.bot_config_loaded = true;
 285
 286         // this is really only a default, TeamBalance_JoinBestTeam is called later
 287         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 288         this.bot_preferredcolors = this.clientcolors;
 289
 290         string prefix = (autocvar_g_campaign ? "" : autocvar_bot_prefix);
 291         string suffix = (autocvar_g_campaign ? "" : autocvar_bot_suffix);
 292         string name = (autocvar_bot_usemodelnames ? bot_model : bot_name);
 293
 294         if (name == "")
 295         {
 296                 name = ftos(etof(this));
 297                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 298         }
 299         else
 300         {
 301                 // number bots with identical names
 302                 int j = 0;
 303                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 304                         if(it.cleanname == name)
 305                                 ++j;
 306                 });
 307                 if (j)
 308                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 309                 else
 310                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 311         }
 312         this.cleanname = strzone(name);
 313
 314         // pick the model and skin
 315         if(substring(bot_model, -4, 1) != ".")
 316                 bot_model = strcat(bot_model, ".iqm");
 317         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 318         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 319 }
 320
 321 void bot_custom_weapon_priority_setup()
 322 {
 323         static string bot_priority_far_prev;
 324         static string bot_priority_mid_prev;
 325         static string bot_priority_close_prev;
 326         static string bot_priority_distances_prev;
 327         float tokens, i, w;
 328
 329         bot_custom_weapon = false;
 330
 331         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 332                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 333                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 334                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 335         )
 336                 return;
 337
 338         if (bot_priority_distances_prev != autocvar_bot_ai_custom_weapon_priority_distances)
 339         {
 340                 strcpy(bot_priority_distances_prev, autocvar_bot_ai_custom_weapon_priority_distances);
 341                 tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 342
 343                 if (tokens!=2)
 344                         return;
 345
 346                 bot_distance_far = stof(argv(0));
 347                 bot_distance_close = stof(argv(1));
 348
 349                 if(bot_distance_far < bot_distance_close){
 350                         bot_distance_far = stof(argv(1));
 351                         bot_distance_close = stof(argv(0));
 352                 }
 353         }
 354
 355         int c;
 356
 357         #define PARSE_WEAPON_PRIORITIES(dist) MACRO_BEGIN \
 358                 if (bot_priority_##dist##_prev != autocvar_bot_ai_custom_weapon_priority_##dist) { \
 359                         strcpy(bot_priority_##dist##_prev, autocvar_bot_ai_custom_weapon_priority_##dist); \
 360                         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_##dist)," "); \
 361                         bot_weapons_##dist[0] = -1; \
 362                         c = 0; \
 363                         for(i = 0; i < tokens && c < REGISTRY_COUNT(Weapons); ++i) { \
 364                                 w = stof(argv(i)); \
 365                                 if (w >= WEP_FIRST && w <= WEP_LAST) { \
 366                                         bot_weapons_##dist[c] = w; \
 367                                         ++c; \
 368                                 } \
 369                         } \
 370                         if (c < REGISTRY_COUNT(Weapons)) \
 371                                 bot_weapons_##dist[c] = -1; \
 372                 } \
 373         MACRO_END
 374
 375         PARSE_WEAPON_PRIORITIES(far);
 376         PARSE_WEAPON_PRIORITIES(mid);
 377         PARSE_WEAPON_PRIORITIES(close);
 378
 379         bot_custom_weapon = true;
 380 }
 381
 382 void bot_endgame()
 383 {
 384         bot_relinkplayerlist();
 385         entity e = bot_list;
 386         while (e)
 387         {
 388                 setcolor(e, e.bot_preferredcolors);
 389                 e = e.nextbot;
 390         }
 391         // if dynamic waypoints are ever implemented, save them here
 392 }
 393
 394 void bot_relinkplayerlist()
 395 {
 396         player_count = 0;
 397         currentbots = 0;
 398         bot_list = NULL;
 399
 400         entity prevbot = NULL;
 401         FOREACH_CLIENT(true,
 402         {
 403                 ++player_count;
 404
 405                 if(IS_BOT_CLIENT(it))
 406                 {
 407                         if (!IS_OBSERVER(it) && !bot_ispaused(it))
 408                         {
 409                                 if(prevbot)
 410                                         prevbot.nextbot = it;
 411                                 else
 412                                         bot_list = it;
 413                                 prevbot = it;
 414                         }
 415                         ++currentbots;
 416                 }
 417         });
 418         if(prevbot)
 419                 prevbot.nextbot = NULL;
 420         bot_strategytoken = bot_list;
 421         bot_strategytoken_taken = true;
 422 }
 423
 424 void bot_clientdisconnect(entity this)
 425 {
 426         if (!IS_BOT_CLIENT(this))
 427                 return;
 428         bot_clearqueue(this);
 429         strfree(this.cleanname);
 430         strfree(this.netname_freeme);
 431         strfree(this.playermodel_freeme);
 432         strfree(this.playerskin_freeme);
 433         if(this.bot_cmd_current)
 434                 delete(this.bot_cmd_current);
 435         if(bot_waypoint_queue_owner == this)
 436                 bot_waypoint_queue_owner = NULL;
 437 }
 438
 439 void bot_clientconnect(entity this)
 440 {
 441         if (!IS_BOT_CLIENT(this)) return;
 442         this.bot_preferredcolors = this.clientcolors;
 443         this.bot_nextthink = time - random();
 444         this.isbot = true;
 445         this.createdtime = this.bot_nextthink;
 446
 447         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 448         {
 449                 bot_setnameandstuff(this);
 450                 bot_setclientfields(this);
 451         }
 452
 453         havocbot_setupbot(this);
 454 }
 455
 456 void bot_removefromlargestteam()
 457 {
 458         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 459         TeamBalance_GetTeamCounts(balance, NULL);
 460
 461         entity best = NULL;
 462         float besttime = 0;
 463         int bestcount = 0;
 464
 465         int bcount = 0;
 466         FOREACH_CLIENT(it.isbot,
 467         {
 468                 ++bcount;
 469
 470                 if(!best)
 471                 {
 472                         best = it;
 473                         besttime = it.createdtime;
 474                 }
 475
 476                 int thiscount = 0;
 477
 478                 if (Team_IsValidTeam(it.team))
 479                 {
 480                         thiscount = TeamBalance_GetNumberOfPlayers(balance,
 481                                 Team_TeamToIndex(it.team));
 482                 }
 483
 484                 if(thiscount > bestcount)
 485                 {
 486                         bestcount = thiscount;
 487                         besttime = it.createdtime;
 488                         best = it;
 489                 }
 490                 else if(thiscount == bestcount && besttime < it.createdtime)
 491                 {
 492                         besttime = it.createdtime;
 493                         best = it;
 494                 }
 495         });
 496         TeamBalance_Destroy(balance);
 497         if(!bcount)
 498                 return; // no bots to remove
 499         currentbots = currentbots - 1;
 500         dropclient(best);
 501 }
 502
 503 void bot_removenewest()
 504 {
 505         if(teamplay)
 506         {
 507                 bot_removefromlargestteam();
 508                 return;
 509         }
 510
 511         float besttime = 0;
 512         entity best = NULL;
 513         int bcount = 0;
 514
 515         FOREACH_CLIENT(it.isbot,
 516         {
 517                 ++bcount;
 518
 519                 if(!best)
 520                 {
 521                         best = it;
 522                         besttime = it.createdtime;
 523                 }
 524
 525                 if(besttime < it.createdtime)
 526                 {
 527                         besttime = it.createdtime;
 528                         best = it;
 529                 }
 530         });
 531
 532         if(!bcount)
 533                 return; // no bots to remove
 534
 535         currentbots = currentbots - 1;
 536         dropclient(best);
 537 }
 538
 539 void autoskill(float factor)
 540 {
 541         int bestbot = -1;
 542         int bestplayer = -1;
 543         FOREACH_CLIENT(IS_PLAYER(it), {
 544                 if(IS_REAL_CLIENT(it))
 545                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 546                 else
 547                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 548         });
 549
 550         string msg = strcat("autoskill: best player got ", ftos(bestplayer), ", ""best bot got ", ftos(bestbot), "; ");
 551         if(bestbot < 0 || bestplayer < 0)
 552         {
 553                 msg = strcat(msg, "not doing anything");
 554                 // don't return, let it reset all counters below
 555         }
 556         else if(bestbot <= bestplayer * factor - 2)
 557         {
 558                 if(autocvar_skill < 17)
 559                 {
 560                         msg = strcat(msg, "2 frags difference, increasing skill");
 561                         cvar_set("skill", ftos(autocvar_skill + 1));
 562                         bprint("^2BOT SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 563                 }
 564         }
 565         else if(bestbot >= bestplayer * factor + 2)
 566         {
 567                 if(autocvar_skill > 0)
 568                 {
 569                         msg = strcat(msg, "2 frags difference, decreasing skill");
 570                         cvar_set("skill", ftos(autocvar_skill - 1));
 571                         bprint("^1BOT SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 572                 }
 573         }
 574         else
 575         {
 576                 msg = strcat(msg, "not doing anything");
 577                 return;
 578                 // don't reset counters, wait for them to accumulate
 579         }
 580         LOG_DEBUG(msg);
 581
 582         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 583 }
 584
 585 void bot_calculate_stepheightvec()
 586 {
 587         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 588         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 589         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 590         jumpheight_time = autocvar_sv_jumpvelocity / autocvar_sv_gravity;
 591 }
 592
 593 bool bot_fixcount(bool multiple_per_frame)
 594 {
 595         int activerealplayers = 0;
 596         int realplayers = 0;
 597         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 598                 activerealplayers = M_ARGV(0, int);
 599                 realplayers = M_ARGV(1, int);
 600         } else {
 601                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 602                         if(IS_PLAYER(it))
 603                                 ++activerealplayers;
 604                         ++realplayers;
 605                 });
 606         }
 607
 608         int bots;
 609         // But don't remove bots immediately on level change, as the real players
 610         // usually haven't rejoined yet
 611         bots_would_leave = false;
 612         if (autocvar_bot_vs_human && AVAILABLE_TEAMS == 2)
 613                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 614         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 615         {
 616                 int minplayers = max(0, floor(autocvar_minplayers));
 617                 if (teamplay)
 618                         minplayers = max(0, floor(autocvar_minplayers_per_team) * AVAILABLE_TEAMS);
 619                 int minbots = max(0, floor(autocvar_bot_number));
 620
 621                 // add bots to reach minplayers if needed
 622                 bots = max(minbots, minplayers - activerealplayers);
 623                 // cap bots to the max players allowed by the server
 624                 int player_limit = GetPlayerLimit();
 625                 if(player_limit)
 626                         bots = min(bots, max(player_limit - activerealplayers, 0));
 627                 bots = min(bots, maxclients - realplayers);
 628
 629                 if(bots > minbots)
 630                         bots_would_leave = true;
 631         }
 632         else
 633         {
 634                 // if there are no players, remove bots
 635                 bots = 0;
 636         }
 637
 638         // only add one bot per frame to avoid utter chaos
 639         if(time > botframe_nextthink)
 640         {
 641                 while (currentbots < bots)
 642                 {
 643                         if (bot_spawn() == NULL)
 644                         {
 645                                 bprint("Can not add bot, server full.\n");
 646                                 return false;
 647                         }
 648                         if (!multiple_per_frame)
 649                         {
 650                                 break;
 651                         }
 652                 }
 653                 while (currentbots > bots && bots >= 0)
 654                         bot_removenewest();
 655         }
 656
 657         return true;
 658 }
 659
 660 void bot_serverframe()
 661 {
 662         if (intermission_running && currentbots > 0)
 663         {
 664                 // after the end of the match all bots stay unless all human players disconnect
 665                 int realplayers = 0;
 666                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 667                 if (!realplayers)
 668                 {
 669                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 670                         currentbots = 0;
 671                 }
 672                 return;
 673         }
 674
 675         if (game_stopped)
 676                 return;
 677
 678         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 679         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 680         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 681         // either intentionally or automatically (sv_spectate 0)
 682         // A working workaround for this bug was implemented in commit fbd145044, see entcs_attach
 683         if (time < 2.5)
 684         {
 685                 currentbots = -1;
 686                 return;
 687         }
 688
 689         if (currentbots == -1)
 690         {
 691                 // count bots already in the server from the previous match
 692                 currentbots = 0;
 693                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 694         }
 695
 696         if(autocvar_skill != skill)
 697         {
 698                 float wpcost_update = false;
 699                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 700                         wpcost_update = true;
 701                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 702                         wpcost_update = true;
 703
 704                 skill = autocvar_skill;
 705                 if (wpcost_update)
 706                         waypoint_updatecost_foralllinks();
 707         }
 708
 709         bot_calculate_stepheightvec();
 710         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 711
 712         if(time > autoskill_nextthink)
 713         {
 714                 float a;
 715                 a = autocvar_skill_auto;
 716                 if(a)
 717                         autoskill(a);
 718                 autoskill_nextthink = time + 5;
 719         }
 720
 721         if(time > botframe_nextthink)
 722         {
 723                 if(!bot_fixcount(false))
 724                         botframe_nextthink = time + 10;
 725         }
 726
 727         if(botframe_spawnedwaypoints)
 728         {
 729                 if(autocvar_waypoint_benchmark)
 730                         localcmd("quit\n");
 731         }
 732
 733         if (currentbots > 0 || waypointeditor_enabled || autocvar_g_waypointeditor_auto)
 734         if (botframe_spawnedwaypoints)
 735         {
 736                 if(botframe_cachedwaypointlinks)
 737                 {
 738                         if(!botframe_loadedforcedlinks)
 739                                 waypoint_load_hardwiredlinks();
 740                 }
 741                 else
 742                 {
 743                         // TODO: Make this check cleaner
 744                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 745                         {
 746                                 waypoint_save_links();
 747                                 break;
 748                         });
 749                 }
 750         }
 751         else
 752         {
 753                 botframe_spawnedwaypoints = true;
 754                 waypoint_loadall();
 755                 waypoint_load_links();
 756         }
 757
 758         if (bot_list)
 759         {
 760                 // cycle the goal token from one bot to the next each frame
 761                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 762                 //  frame, which causes choppy framerates)
 763                 if (bot_strategytoken_taken)
 764                 {
 765                         // give goal token to the first bot without goals; if all bots don't have
 766                         // any goal (or are dead/frozen) simply give it to the next one
 767                         bot_strategytoken_taken = false;
 768                         entity bot_strategytoken_save = bot_strategytoken;
 769                         while (true)
 770                         {
 771                                 if (bot_strategytoken)
 772                                         bot_strategytoken = bot_strategytoken.nextbot;
 773                                 if (!bot_strategytoken)
 774                                         bot_strategytoken = bot_list;
 775
 776                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 777                                         && !bot_strategytoken.goalcurrent)
 778                                         break;
 779
 780                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 781                                         break;
 782                                 if (bot_strategytoken == bot_strategytoken_save)
 783                                         bot_strategytoken_save = NULL; // looped through all the bots
 784                         }
 785                 }
 786
 787                 if (botframe_nextdangertime < time)
 788                 {
 789                         float interval;
 790                         interval = autocvar_bot_ai_dangerdetectioninterval;
 791                         if (botframe_nextdangertime < time - interval * 1.5)
 792                                 botframe_nextdangertime = time;
 793                         botframe_nextdangertime = botframe_nextdangertime + interval;
 794                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 795                 }
 796         }
 797
 798         if (waypointeditor_enabled)
 799                 botframe_showwaypointlinks();
 800
 801         if (autocvar_g_waypointeditor_auto)
 802                 botframe_autowaypoints();
 803
 804         if (currentbots > 0)
 805                 bot_custom_weapon_priority_setup();
 806 }