qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/mapinfo.qh>
   5 #include <common/net_linked.qh>
   6 #include <common/physics/player.qh>
   7 #include <common/stats.qh>
   8 #include <common/teams.qh>
   9 #include <common/util.qh>
  10 #include <common/weapons/_all.qh>
  11 #include <lib/csqcmodel/sv_model.qh>
  12 #include <lib/warpzone/common.qh>
  13 #include <lib/warpzone/util_server.qh>
  14 #include <server/antilag.qh>
  15 #include <server/bot/default/aim.qh>
  16 #include <server/bot/default/cvars.qh>
  17 #include <server/bot/default/havocbot/havocbot.qh>
  18 #include <server/bot/default/havocbot/scripting.qh>
  19 #include <server/bot/default/navigation.qh>
  20 #include <server/bot/default/scripting.qh>
  21 #include <server/bot/default/waypoints.qh>
  22 #include <server/campaign.qh>
  23 #include <server/client.qh>
  24 #include <server/damage.qh>
  25 #include <server/items/items.qh>
  26 #include <server/mutators/_mod.qh>
  27 #include <server/race.qh>
  28 #include <server/scores_rules.qh>
  29 #include <server/teamplay.qh>
  30 #include <server/weapons/accuracy.qh>
  31 #include <server/world.qh>
  32
  33 STATIC_INIT(bot) { bot_calculate_stepheightvec(); }
  34
  35 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  36 void bot_setclientfields(entity this)
  37 {
  38         CS_CVAR(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  39         CS_CVAR(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  40 }
  41
  42 entity bot_spawn()
  43 {
  44         entity bot = spawnclient();
  45         if (bot)
  46         {
  47                 setItemGroupCount();
  48                 currentbots = currentbots + 1;
  49                 bot_setnameandstuff(bot);
  50                 ClientConnect(bot);
  51                 bot_setclientfields(bot);
  52                 PutClientInServer(bot);
  53         }
  54         return bot;
  55 }
  56
  57 void bot_think(entity this)
  58 {
  59         if (this.bot_nextthink > time)
  60                 return;
  61
  62         this.flags &= ~FL_GODMODE;
  63         if(autocvar_bot_god)
  64                 this.flags |= FL_GODMODE;
  65
  66         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  67
  68         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  69         {
  70                 CS(this).movement = '0 0 0';
  71                 this.bot_nextthink = time + 0.5;
  72                 return;
  73         }
  74
  75         if (this.fixangle)
  76         {
  77                 this.v_angle = this.angles;
  78                 this.v_angle_z = 0;
  79                 this.fixangle = false;
  80         }
  81
  82         this.dmg_take = 0;
  83         this.dmg_save = 0;
  84         this.dmg_inflictor = NULL;
  85
  86         // calculate an aiming latency based on the skill setting
  87         // (simulated network latency + naturally delayed reflexes)
  88         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
  89         // minimum ping 20+10 random
  90         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
  91         // skill 10 = ping 0.2 (adrenaline)
  92         // skill 0 = ping 0.7 (slightly drunk)
  93
  94         // clear buttons
  95         PHYS_INPUT_BUTTON_ATCK(this) = false;
  96         // keep jump button pressed for a short while, useful with ramp jumps
  97         PHYS_INPUT_BUTTON_JUMP(this) = (!IS_DEAD(this) && time < this.bot_jump_time + 0.2);
  98         PHYS_INPUT_BUTTON_ATCK2(this) = false;
  99         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 100         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 101         PHYS_INPUT_BUTTON_HOOK(this) = false;
 102         PHYS_INPUT_BUTTON_INFO(this) = false;
 103         PHYS_INPUT_BUTTON_DRAG(this) = false;
 104         PHYS_INPUT_BUTTON_CHAT(this) = false;
 105         PHYS_INPUT_BUTTON_USE(this) = false;
 106
 107         if (time < game_starttime)
 108         {
 109                 // block the bot during the countdown to game start
 110                 CS(this).movement = '0 0 0';
 111                 this.bot_nextthink = game_starttime;
 112                 return;
 113         }
 114
 115         // if dead, just wait until we can respawn
 116         if (IS_DEAD(this) || IS_OBSERVER(this))
 117         {
 118                 if (bot_waypoint_queue_owner == this)
 119                         bot_waypoint_queue_owner = NULL;
 120                 this.aistatus = 0;
 121                 CS(this).movement = '0 0 0';
 122                 if (IS_OBSERVER(this))
 123                         return;
 124                 if (IS_DEAD(this))
 125                 {
 126                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 127                         if (!navigation_goalrating_timeout(this))
 128                                 navigation_goalrating_timeout_force(this);
 129                 }
 130         }
 131         else if(this.aistatus & AI_STATUS_STUCK)
 132                 navigation_unstuck(this);
 133
 134         // now call the current bot AI (havocbot for example)
 135         this.bot_ai(this);
 136 }
 137
 138 void bot_setnameandstuff(entity this)
 139 {
 140         string readfile, s;
 141         int file, tokens, prio;
 142
 143         file = fopen(autocvar_bot_config_file, FILE_READ);
 144
 145         if(file < 0)
 146         {
 147                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 148                 readfile = "";
 149         }
 150         else
 151         {
 152                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
 153                 TeamBalance_GetTeamCounts(balance, NULL);
 154                 int smallest_team = -1;
 155                 int smallest_count = -1;
 156                 if (teamplay)
 157                 {
 158                         for (int i = 1; i <= AvailableTeams(); ++i)
 159                         {
 160                                 // NOTE if (autocvar_g_campaign && autocvar_g_campaign_forceteam == i)
 161                                 // TeamBalance_GetNumberOfPlayers(balance, i); returns the number of players + 1
 162                                 // since it keeps a spot for the real player in the desired team
 163                                 int count = TeamBalance_GetNumberOfPlayers(balance, i);
 164                                 if (smallest_count < 0 || count < smallest_count)
 165                                 {
 166                                         smallest_team = i;
 167                                         smallest_count = count;
 168                                 }
 169                         }
 170                 }
 171                 TeamBalance_Destroy(balance);
 172                 RandomSelection_Init();
 173                 while((readfile = fgets(file)))
 174                 {
 175                         if(substring(readfile, 0, 2) == "//")
 176                                 continue;
 177                         if(substring(readfile, 0, 1) == "#")
 178                                 continue;
 179                         // NOTE if the line is empty tokenizebyseparator(readfile, "\t")
 180                         // will create 1 empty token because there's no separator (bug?)
 181                         if (readfile == "")
 182                                 continue;
 183                         tokens = tokenizebyseparator(readfile, "\t");
 184                         if(tokens == 0)
 185                                 continue;
 186                         s = argv(0);
 187                         prio = 0;
 188                         bool conflict = false;
 189                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 190                                 if (s == it.cleanname)
 191                                 {
 192                                         conflict = true;
 193                                         break;
 194                                 }
 195                         });
 196                         if (!conflict)
 197                                 prio += 1;
 198                         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 199                         {
 200                                 int forced_team = stof(argv(5));
 201                                 if (!Team_IsValidIndex(forced_team))
 202                                         forced_team = 0;
 203                                 if (!forced_team || forced_team == smallest_team)
 204                                         prio += 2;
 205                         }
 206                         RandomSelection_AddString(readfile, 1, prio);
 207                 }
 208                 readfile = RandomSelection_chosen_string;
 209                 fclose(file);
 210         }
 211
 212         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 213
 214         tokens = tokenizebyseparator(readfile, "\t");
 215         if(argv(0) != "") bot_name = argv(0);
 216         else bot_name = "Bot";
 217
 218         if(argv(1) != "") bot_model = argv(1);
 219         else bot_model = "";
 220
 221         if(argv(2) != "") bot_skin = argv(2);
 222         else bot_skin = "0";
 223
 224         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 225         else bot_shirt = ftos(floor(random() * 15));
 226
 227         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 228         else bot_pants = ftos(floor(random() * 15));
 229
 230         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 231                 this.bot_forced_team = stof(argv(5));
 232         else
 233                 this.bot_forced_team = 0;
 234
 235         prio = 6;
 236
 237         #define READSKILL(f, w, r) MACRO_BEGIN \
 238                 if(argv(prio) != "") \
 239                         this.f = stof(argv(prio)) * w; \
 240                 else \
 241                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 242                 prio++; \
 243         MACRO_END
 244         //print(bot_name, ": ping=", argv(9), "\n");
 245
 246         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 247         READSKILL(bot_moveskill, 2, 0); // move skill
 248         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 249
 250         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 251
 252         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 253         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 254         READSKILL(bot_rangepreference, 1, 0); // read skill
 255
 256         READSKILL(bot_aimskill, 2, 0); // aim skill
 257         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 258         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 259
 260         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 261         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 262
 263         if (file >= 0 && argv(prio) != "")
 264                 LOG_INFOF("^1Warning^7: too many parameters for bot %s, please check format of %s", bot_name, autocvar_bot_config_file);
 265
 266         this.bot_config_loaded = true;
 267
 268         // this is really only a default, TeamBalance_JoinBestTeam is called later
 269         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 270         this.bot_preferredcolors = this.clientcolors;
 271
 272         string prefix = (autocvar_g_campaign ? "" : autocvar_bot_prefix);
 273         string suffix = (autocvar_g_campaign ? "" : autocvar_bot_suffix);
 274         string name = (autocvar_bot_usemodelnames ? bot_model : bot_name);
 275
 276         if (name == "")
 277         {
 278                 name = ftos(etof(this));
 279                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 280         }
 281         else
 282         {
 283                 // number bots with identical names
 284                 int j = 0;
 285                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 286                         if(it.cleanname == name)
 287                                 ++j;
 288                 });
 289                 if (j)
 290                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 291                 else
 292                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 293         }
 294         this.cleanname = strzone(name);
 295
 296         // pick the model and skin
 297         if(substring(bot_model, -4, 1) != ".")
 298                 bot_model = strcat(bot_model, ".iqm");
 299         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 300         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 301 }
 302
 303 void bot_custom_weapon_priority_setup()
 304 {
 305         static string bot_priority_far_prev;
 306         static string bot_priority_mid_prev;
 307         static string bot_priority_close_prev;
 308         static string bot_priority_distances_prev;
 309         float tokens, i, w;
 310
 311         bot_custom_weapon = false;
 312
 313         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 314                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 315                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 316                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 317         )
 318                 return;
 319
 320         if (bot_priority_distances_prev != autocvar_bot_ai_custom_weapon_priority_distances)
 321         {
 322                 strcpy(bot_priority_distances_prev, autocvar_bot_ai_custom_weapon_priority_distances);
 323                 tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 324
 325                 if (tokens!=2)
 326                         return;
 327
 328                 bot_distance_far = stof(argv(0));
 329                 bot_distance_close = stof(argv(1));
 330
 331                 if(bot_distance_far < bot_distance_close){
 332                         bot_distance_far = stof(argv(1));
 333                         bot_distance_close = stof(argv(0));
 334                 }
 335         }
 336
 337         int c;
 338
 339         #define PARSE_WEAPON_PRIORITIES(dist) MACRO_BEGIN \
 340                 if (bot_priority_##dist##_prev != autocvar_bot_ai_custom_weapon_priority_##dist) { \
 341                         strcpy(bot_priority_##dist##_prev, autocvar_bot_ai_custom_weapon_priority_##dist); \
 342                         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_##dist)," "); \
 343                         bot_weapons_##dist[0] = -1; \
 344                         c = 0; \
 345                         for(i = 0; i < tokens && c < REGISTRY_COUNT(Weapons); ++i) { \
 346                                 w = stof(argv(i)); \
 347                                 if (w >= WEP_FIRST && w <= WEP_LAST) { \
 348                                         bot_weapons_##dist[c] = w; \
 349                                         ++c; \
 350                                 } \
 351                         } \
 352                         if (c < REGISTRY_COUNT(Weapons)) \
 353                                 bot_weapons_##dist[c] = -1; \
 354                 } \
 355         MACRO_END
 356
 357         PARSE_WEAPON_PRIORITIES(far);
 358         PARSE_WEAPON_PRIORITIES(mid);
 359         PARSE_WEAPON_PRIORITIES(close);
 360
 361         bot_custom_weapon = true;
 362 }
 363
 364 void bot_endgame()
 365 {
 366         bot_relinkplayerlist();
 367         entity e = bot_list;
 368         while (e)
 369         {
 370                 setcolor(e, e.bot_preferredcolors);
 371                 e = e.nextbot;
 372         }
 373         // if dynamic waypoints are ever implemented, save them here
 374 }
 375
 376 void bot_relinkplayerlist()
 377 {
 378         player_count = 0;
 379         currentbots = 0;
 380         bot_list = NULL;
 381
 382         entity prevbot = NULL;
 383         FOREACH_CLIENT(true,
 384         {
 385                 ++player_count;
 386
 387                 if(IS_BOT_CLIENT(it))
 388                 {
 389                         if (!IS_OBSERVER(it) && !bot_ispaused(it))
 390                         {
 391                                 if(prevbot)
 392                                         prevbot.nextbot = it;
 393                                 else
 394                                         bot_list = it;
 395                                 prevbot = it;
 396                         }
 397                         ++currentbots;
 398                 }
 399         });
 400         if(prevbot)
 401                 prevbot.nextbot = NULL;
 402         bot_strategytoken = bot_list;
 403         bot_strategytoken_taken = true;
 404 }
 405
 406 void bot_clientdisconnect(entity this)
 407 {
 408         if (!IS_BOT_CLIENT(this))
 409                 return;
 410         bot_clearqueue(this);
 411         strfree(this.cleanname);
 412         strfree(this.netname_freeme);
 413         strfree(this.playermodel_freeme);
 414         strfree(this.playerskin_freeme);
 415         if(this.bot_cmd_current)
 416                 delete(this.bot_cmd_current);
 417         if(bot_waypoint_queue_owner == this)
 418                 bot_waypoint_queue_owner = NULL;
 419 }
 420
 421 void bot_clientconnect(entity this)
 422 {
 423         if (!IS_BOT_CLIENT(this)) return;
 424         this.bot_preferredcolors = this.clientcolors;
 425         this.bot_nextthink = time - random();
 426         this.lag_func = bot_lagfunc;
 427         this.isbot = true;
 428         this.createdtime = this.bot_nextthink;
 429
 430         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 431         {
 432                 bot_setnameandstuff(this);
 433                 bot_setclientfields(this);
 434         }
 435
 436         if (teamplay && Team_IsValidIndex(this.bot_forced_team))
 437         {
 438                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 439         }
 440         else
 441         {
 442                 this.bot_forced_team = 0;
 443                 TeamBalance_JoinBestTeam(this);
 444         }
 445
 446         havocbot_setupbot(this);
 447 }
 448
 449 void bot_removefromlargestteam()
 450 {
 451         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 452         TeamBalance_GetTeamCounts(balance, NULL);
 453
 454         entity best = NULL;
 455         float besttime = 0;
 456         int bestcount = 0;
 457
 458         int bcount = 0;
 459         FOREACH_CLIENT(it.isbot,
 460         {
 461                 ++bcount;
 462
 463                 if(!best)
 464                 {
 465                         best = it;
 466                         besttime = it.createdtime;
 467                 }
 468
 469                 int thiscount = 0;
 470
 471                 if (Team_IsValidTeam(it.team))
 472                 {
 473                         thiscount = TeamBalance_GetNumberOfPlayers(balance,
 474                                 Team_TeamToIndex(it.team));
 475                 }
 476
 477                 if(thiscount > bestcount)
 478                 {
 479                         bestcount = thiscount;
 480                         besttime = it.createdtime;
 481                         best = it;
 482                 }
 483                 else if(thiscount == bestcount && besttime < it.createdtime)
 484                 {
 485                         besttime = it.createdtime;
 486                         best = it;
 487                 }
 488         });
 489         TeamBalance_Destroy(balance);
 490         if(!bcount)
 491                 return; // no bots to remove
 492         currentbots = currentbots - 1;
 493         dropclient(best);
 494 }
 495
 496 void bot_removenewest()
 497 {
 498         if(teamplay)
 499         {
 500                 bot_removefromlargestteam();
 501                 return;
 502         }
 503
 504         float besttime = 0;
 505         entity best = NULL;
 506         int bcount = 0;
 507
 508         FOREACH_CLIENT(it.isbot,
 509         {
 510                 ++bcount;
 511
 512                 if(!best)
 513                 {
 514                         best = it;
 515                         besttime = it.createdtime;
 516                 }
 517
 518                 if(besttime < it.createdtime)
 519                 {
 520                         besttime = it.createdtime;
 521                         best = it;
 522                 }
 523         });
 524
 525         if(!bcount)
 526                 return; // no bots to remove
 527
 528         currentbots = currentbots - 1;
 529         dropclient(best);
 530 }
 531
 532 void autoskill(float factor)
 533 {
 534         float bestbot;
 535         float bestplayer;
 536
 537         bestbot = -1;
 538         bestplayer = -1;
 539         FOREACH_CLIENT(IS_PLAYER(it), {
 540                 if(IS_REAL_CLIENT(it))
 541                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 542                 else
 543                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 544         });
 545
 546         LOG_DEBUG("autoskill: best player got ", ftos(bestplayer), ", ");
 547         LOG_DEBUG("best bot got ", ftos(bestbot), "; ");
 548         if(bestbot < 0 || bestplayer < 0)
 549         {
 550                 LOG_DEBUG("not doing anything");
 551                 // don't return, let it reset all counters below
 552         }
 553         else if(bestbot <= bestplayer * factor - 2)
 554         {
 555                 if(autocvar_skill < 17)
 556                 {
 557                         LOG_DEBUG("2 frags difference, increasing skill");
 558                         cvar_set("skill", ftos(autocvar_skill + 1));
 559                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 560                 }
 561         }
 562         else if(bestbot >= bestplayer * factor + 2)
 563         {
 564                 if(autocvar_skill > 0)
 565                 {
 566                         LOG_DEBUG("2 frags difference, decreasing skill");
 567                         cvar_set("skill", ftos(autocvar_skill - 1));
 568                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 569                 }
 570         }
 571         else
 572         {
 573                 LOG_DEBUG("not doing anything");
 574                 return;
 575                 // don't reset counters, wait for them to accumulate
 576         }
 577
 578         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 579 }
 580
 581 void bot_calculate_stepheightvec()
 582 {
 583         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 584         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 585         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 586         jumpheight_time = autocvar_sv_jumpvelocity / autocvar_sv_gravity;
 587 }
 588
 589 bool bot_fixcount()
 590 {
 591         int activerealplayers = 0;
 592         int realplayers = 0;
 593         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 594                 activerealplayers = M_ARGV(0, int);
 595                 realplayers = M_ARGV(1, int);
 596         } else {
 597                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 598                         if(IS_PLAYER(it))
 599                                 ++activerealplayers;
 600                         ++realplayers;
 601                 });
 602         }
 603
 604         int bots;
 605         // But don't remove bots immediately on level change, as the real players
 606         // usually haven't rejoined yet
 607         bots_would_leave = false;
 608         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 609                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 610         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 611         {
 612                 int minplayers = max(0, floor(autocvar_minplayers));
 613                 if (teamplay)
 614                         minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
 615                 int minbots = max(0, floor(autocvar_bot_number));
 616
 617                 // add bots to reach minplayers if needed
 618                 bots = max(minbots, minplayers - activerealplayers);
 619                 // cap bots to the max players allowed by the server
 620                 int player_limit = GetPlayerLimit();
 621                 if(player_limit)
 622                         bots = min(bots, max(player_limit - activerealplayers, 0));
 623                 bots = min(bots, maxclients - realplayers);
 624
 625                 if(bots > minbots)
 626                         bots_would_leave = true;
 627         }
 628         else
 629         {
 630                 // if there are no players, remove bots
 631                 bots = 0;
 632         }
 633
 634         // only add one bot per frame to avoid utter chaos
 635         if(time > botframe_nextthink)
 636         {
 637                 if (currentbots < bots)
 638                 {
 639                         if (bot_spawn() == NULL)
 640                         {
 641                                 bprint("Can not add bot, server full.\n");
 642                                 return false;
 643                         }
 644                 }
 645                 while (currentbots > bots && bots >= 0)
 646                         bot_removenewest();
 647         }
 648
 649         return true;
 650 }
 651
 652 void bot_serverframe()
 653 {
 654         if (intermission_running && currentbots > 0)
 655         {
 656                 // after the end of the match all bots stay unless all human players disconnect
 657                 int realplayers = 0;
 658                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 659                 if (!realplayers)
 660                 {
 661                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 662                         currentbots = 0;
 663                 }
 664                 return;
 665         }
 666
 667         if (game_stopped)
 668                 return;
 669
 670         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 671         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 672         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 673         // either intentionally or automatically (sv_spectate 0)
 674         if (time < 2.5)
 675         {
 676                 currentbots = -1;
 677                 return;
 678         }
 679
 680         if (currentbots == -1)
 681         {
 682                 // count bots already in the server from the previous match
 683                 currentbots = 0;
 684                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 685         }
 686
 687         if(autocvar_skill != skill)
 688         {
 689                 float wpcost_update = false;
 690                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 691                         wpcost_update = true;
 692                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 693                         wpcost_update = true;
 694
 695                 skill = autocvar_skill;
 696                 if (wpcost_update)
 697                         waypoint_updatecost_foralllinks();
 698         }
 699
 700         bot_calculate_stepheightvec();
 701         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 702
 703         if(time > autoskill_nextthink)
 704         {
 705                 float a;
 706                 a = autocvar_skill_auto;
 707                 if(a)
 708                         autoskill(a);
 709                 autoskill_nextthink = time + 5;
 710         }
 711
 712         if(time > botframe_nextthink)
 713         {
 714                 if(!bot_fixcount())
 715                         botframe_nextthink = time + 10;
 716         }
 717
 718         if(botframe_spawnedwaypoints)
 719         {
 720                 if(autocvar_waypoint_benchmark)
 721                         localcmd("quit\n");
 722         }
 723
 724         if (currentbots > 0 || waypointeditor_enabled || autocvar_g_waypointeditor_auto)
 725         if (botframe_spawnedwaypoints)
 726         {
 727                 if(botframe_cachedwaypointlinks)
 728                 {
 729                         if(!botframe_loadedforcedlinks)
 730                                 waypoint_load_hardwiredlinks();
 731                 }
 732                 else
 733                 {
 734                         // TODO: Make this check cleaner
 735                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 736                         {
 737                                 waypoint_save_links();
 738                                 break;
 739                         });
 740                 }
 741         }
 742         else
 743         {
 744                 botframe_spawnedwaypoints = true;
 745                 waypoint_loadall();
 746                 waypoint_load_links();
 747         }
 748
 749         if (bot_list)
 750         {
 751                 // cycle the goal token from one bot to the next each frame
 752                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 753                 //  frame, which causes choppy framerates)
 754                 if (bot_strategytoken_taken)
 755                 {
 756                         // give goal token to the first bot without goals; if all bots don't have
 757                         // any goal (or are dead/frozen) simply give it to the next one
 758                         bot_strategytoken_taken = false;
 759                         entity bot_strategytoken_save = bot_strategytoken;
 760                         while (true)
 761                         {
 762                                 if (bot_strategytoken)
 763                                         bot_strategytoken = bot_strategytoken.nextbot;
 764                                 if (!bot_strategytoken)
 765                                         bot_strategytoken = bot_list;
 766
 767                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 768                                         && !bot_strategytoken.goalcurrent)
 769                                         break;
 770
 771                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 772                                         break;
 773                                 if (bot_strategytoken == bot_strategytoken_save)
 774                                         bot_strategytoken_save = NULL; // looped through all the bots
 775                         }
 776                 }
 777
 778                 if (botframe_nextdangertime < time)
 779                 {
 780                         float interval;
 781                         interval = autocvar_bot_ai_dangerdetectioninterval;
 782                         if (botframe_nextdangertime < time - interval * 1.5)
 783                                 botframe_nextdangertime = time;
 784                         botframe_nextdangertime = botframe_nextdangertime + interval;
 785                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 786                 }
 787         }
 788
 789         if (waypointeditor_enabled)
 790                 botframe_showwaypointlinks();
 791
 792         if (autocvar_g_waypointeditor_auto)
 793                 botframe_autowaypoints();
 794
 795         if (currentbots > 0)
 796                 bot_custom_weapon_priority_setup();
 797 }