qcsrc/menu/xonotic/dialog_singleplayer.qc

   1 #include "dialog_singleplayer.qh"
   2
   3 #include <common/gamemodes/_mod.qh>
   4 #include "bigbutton.qh"
   5 #include "radiobutton.qh"
   6 #include "textlabel.qh"
   7 #include "campaign.qh"
   8
   9 void InstantAction_LoadMap(entity btn, entity dummy)
  10 {
  11         float pmin = 2, pmax = 16, pstep = 1;
  12
  13         cvar_set("timelimit_override", "10");
  14
  15         if(random() < 0.4) // 40% are DM
  16         {
  17                 MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
  18                 pmin = 2;
  19                 pmax = 8;
  20                 pstep = 1;
  21         }
  22         else if(random() < 0.5) // half of the remaining 60%, i.e. 30%, are CTF
  23         {
  24                 MapInfo_SwitchGameType(MAPINFO_TYPE_CTF);
  25                 pmin = 4;
  26                 pmax = 12;
  27                 pstep = 2;
  28         }
  29         else if(random() < 0.5) // half of the remaining 30%, i.e. 15%, are TDM
  30         {
  31                 MapInfo_SwitchGameType(MAPINFO_TYPE_TEAM_DEATHMATCH);
  32                 pmin = 4;
  33                 pmax = 8;
  34                 pstep = 2;
  35         }
  36         else if(random() < 0.666) // 2/3 of the remaining 15%, i.e. 10%, are KH
  37         {
  38                 MapInfo_SwitchGameType(MAPINFO_TYPE_KEYHUNT);
  39                 pmin = 6;
  40                 pmax = 6;
  41                 pstep = 6; // works both for 2 and 3 teams
  42                 // TODO find team count of map, set pstep=2 or 3, and use 2v2(v2) games at least
  43         }
  44         else // somehow distribute the remaining 5%
  45         {
  46                 float r;
  47                 r = floor(random() * 4);
  48                 switch(r)
  49                 {
  50                         default:
  51                         case 0:
  52                                 MapInfo_SwitchGameType(MAPINFO_TYPE_LMS);
  53                                 pmin = 2;
  54                                 pmax = 6;
  55                                 pstep = 1;
  56                                 cvar_set("timelimit_override", "-1");
  57                                 break;
  58                         case 1:
  59                                 MapInfo_SwitchGameType(MAPINFO_TYPE_DOMINATION);
  60                                 pmin = 2;
  61                                 pmax = 8;
  62                                 pstep = 2;
  63                                 break;
  64                         case 2:
  65                                 MapInfo_SwitchGameType(MAPINFO_TYPE_ONSLAUGHT);
  66                                 pmin = 6;
  67                                 pmax = 16;
  68                                 pstep = 2;
  69                                 break;
  70                         case 3:
  71                                 MapInfo_SwitchGameType(MAPINFO_TYPE_ASSAULT);
  72                                 pmin = 4;
  73                                 pmax = 16;
  74                                 pstep = 2;
  75                                 break;
  76                         // CA, Freezetag: bot AI does not work, add them once it does
  77                 }
  78         }
  79
  80         // find random map
  81         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  82         string s;
  83         do
  84         {
  85                 float m;
  86                 m = floor(random() * MapInfo_count);
  87                 s = MapInfo_BSPName_ByID(m);
  88         }
  89         while(!fexists(sprintf("maps/%s.waypoints", s)));
  90
  91         // these commands are also executed when starting a map from Multiplayer / Create
  92         // in the menu_loadmap_prepare alias
  93         localcmd("disconnect\n");
  94         localcmd("g_campaign 0\n");
  95
  96         MapInfo_LoadMap(s, 1);
  97
  98         // configure bots
  99         float p;
 100         pmin = pstep * ceil(pmin / pstep);
 101         pmax = pstep * floor(pmax / pstep);
 102         p = pmin + pstep * floor(random() * ((pmax - pmin) / pstep + 1));
 103
 104         // cvar_set doesn't always work starting an InstantAction game while playing the campaign
 105         //cvar_set("bot_number", ftos(p - 1));
 106         localcmd(strcat("bot_number ", ftos(p - 1), "\n"));
 107
 108         // make sure we go back to menu
 109         cvar_set("lastlevel", "1");
 110 }
 111
 112 void XonoticSingleplayerDialog_fill(entity me)
 113 {
 114         entity e, btnPrev, btnNext, lblTitle;
 115
 116         me.TR(me);
 117                 me.TDempty(me, (me.columns - 3) / 2);
 118                 me.TD(me, 2, 3, e = makeXonoticBigButton(_("Instant action! (random map with bots)"), '0 0 0'));
 119                         e.onClick = InstantAction_LoadMap;
 120                         e.onClickEntity = NULL;
 121         me.TR(me);
 122         me.TR(me);
 123         me.TR(me);
 124                 me.TD(me, 1, 1, btnPrev = makeXonoticButton("<<", '0 0 0'));
 125                 me.TD(me, 1, me.columns - 2, lblTitle = makeXonoticTextLabel(0.5, _("???")));
 126                 me.TD(me, 1, 1, btnNext = makeXonoticButton(">>", '0 0 0'));
 127         me.TR(me);
 128                 me.TD(me, me.rows - 6, me.columns, me.campaignBox = makeXonoticCampaignList());
 129                         btnPrev.onClick = MultiCampaign_Prev;
 130                         btnPrev.onClickEntity = me.campaignBox;
 131                         btnNext.onClick = MultiCampaign_Next;
 132                         btnNext.onClickEntity = me.campaignBox;
 133                         me.campaignBox.buttonNext = btnNext;
 134                         me.campaignBox.buttonPrev = btnPrev;
 135                         me.campaignBox.labelTitle = lblTitle;
 136
 137         me.gotoRC(me, me.rows - 2, 0);
 138                 me.TD(me, 1, 2, e = makeXonoticTextLabel(0.5, _("Campaign Difficulty:")));
 139                 me.TD(me, 1, 1, e = makeXonoticRadioButton(1, "g_campaign_skill", "-2", ZCTX(_("CSKL^Easy"))));
 140                 me.TD(me, 1, 1, e = makeXonoticRadioButton(1, "g_campaign_skill", "0", ZCTX(_("CSKL^Medium"))));
 141                 me.TD(me, 1, 1, e = makeXonoticRadioButton(1, "g_campaign_skill", "2", ZCTX(_("CSKL^Hard"))));
 142                 me.TR(me);
 143                 me.TD(me, 1, me.columns, e = makeXonoticButton(_("Start Singleplayer!"), '0 0 0'));
 144                         e.onClick = CampaignList_LoadMap;
 145                         e.onClickEntity = me.campaignBox;
 146 }