qcsrc/menu/menu.qc

   1 #include "menu.qh"
   2
   3 #include "item.qh"
   4
   5 #include "anim/animhost.qh"
   6
   7 #include "item/dialog.qh"
   8 #include "item/listbox.qh"
   9 #include "item/nexposee.qh"
  10
  11 #include "xonotic/commandbutton.qh"
  12 #include "xonotic/mainwindow.qh"
  13 #include "xonotic/serverlist.qh"
  14 #include "xonotic/slider_resolution.qh"
  15
  16 .string controlledCvar;
  17
  18 #include "xonotic/util.qh"
  19
  20 #include <common/items/_mod.qh>
  21 #include <common/weapons/_all.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/mutators/base.qh>
  24
  25 int mouseButtonsPressed;
  26 vector menuMousePos;
  27 int menuShiftState;
  28 float menuPrevTime;
  29 float menuAlpha;
  30 float menuLogoAlpha;
  31 float prevMenuAlpha;
  32 bool menuInitialized;
  33 int menuMouseMode;
  34
  35 // Used for having effects only execute once in main menu, not for every reload
  36 // 0: never been in main menu before. 1: coming back to main menu. 2: in main menu.
  37 int menuNotTheFirstFrame;
  38 bool autocvar_menu_no_music_nor_welcome;
  39
  40 float conwidth_s, conheight_s;
  41 float vidwidth_s, vidheight_s, vidpixelheight_s;
  42 float realconwidth, realconheight;
  43
  44 void m_sync()
  45 {
  46         updateCompression();
  47         vidwidth_s = vidheight_s = vidpixelheight_s = 0;  // Force updateConwidths on next draw
  48
  49         loadAllCvars(main);
  50 }
  51
  52 void m_gamestatus()
  53 {
  54         gamestatus = 0;
  55         if (isserver()) gamestatus |= GAME_ISSERVER;
  56         if (clientstate() == CS_CONNECTED || isdemo()) gamestatus |= GAME_CONNECTED;
  57         if (cvar("developer") > 0) gamestatus |= GAME_DEVELOPER;
  58 }
  59
  60 void m_init()
  61 {
  62         bool restarting = false;
  63         cvar_set("_menu_alpha", "0");
  64         prvm_language = cvar_string("prvm_language");
  65         if (prvm_language == "")
  66         {
  67                 prvm_language = "en";
  68                 cvar_set("prvm_language", prvm_language);
  69                 localcmd("\nmenu_restart\n");
  70                 restarting = true;
  71         }
  72         prvm_language = strzone(prvm_language);
  73         cvar_set("_menu_prvm_language", prvm_language);
  74
  75 #ifdef WATERMARK
  76                 LOG_TRACEF("^4MQC Build information: ^1%s", WATERMARK);
  77 #endif
  78
  79         // list all game dirs (TEST)
  80         if (cvar("developer") > 0)
  81         {
  82                 for (int i = 0; ; ++i)
  83                 {
  84                         string s = getgamedirinfo(i, GETGAMEDIRINFO_NAME);
  85                         if (!s) break;
  86                         LOG_TRACE(s, ": ", getgamedirinfo(i, GETGAMEDIRINFO_DESCRIPTION));
  87                 }
  88         }
  89
  90         registercvar("_menu_cmd_closemenu_available", "0", 0);
  91         cvar_set("_menu_cmd_closemenu_available", "1");
  92
  93         // needs to be done so early because of the constants they create
  94         static_init();
  95         static_init_late();
  96         static_init_precache();
  97
  98         RegisterSLCategories();
  99
 100         float ddsload = cvar("r_texture_dds_load");
 101         float texcomp = cvar("gl_texturecompression");
 102         updateCompression();
 103         if (ddsload != cvar("r_texture_dds_load") || texcomp != cvar("gl_texturecompression")) localcmd("\nr_restart\n");
 104
 105         if (!restarting)
 106         {
 107                 if (cvar("_menu_initialized"))  // always show menu after menu_restart
 108                         m_display();
 109                 else m_hide();
 110                 cvar_set("_menu_initialized", "1");
 111         }
 112 }
 113
 114 const float MENU_ASPECT = 1280 / 1024;
 115
 116 void draw_reset_cropped()
 117 {
 118         draw_reset(conwidth, conheight, 0.5 * (realconwidth - conwidth), 0.5 * (realconheight - conheight));
 119 }
 120 void draw_reset_full()
 121 {
 122         draw_reset(realconwidth, realconheight, 0, 0);
 123 }
 124
 125 void UpdateConWidthHeight(float w, float h, float p)
 126 {
 127         if (w != vidwidth_s || h != vidheight_s || p != vidpixelheight_s)
 128         {
 129                 if (updateConwidths(w, h, p) && menuNotTheFirstFrame)
 130                         localcmd(sprintf("\nexec %s\n", cvar_string("menu_font_cfg")));
 131                 vidwidth_s = w;
 132                 vidheight_s = h;
 133                 vidpixelheight_s = p;
 134         }
 135         conwidth_s = conwidth;
 136         conheight_s = conheight;
 137         realconwidth = cvar("vid_conwidth");
 138         realconheight = cvar("vid_conheight");
 139         if (realconwidth / realconheight > MENU_ASPECT)
 140         {
 141                 // widescreen
 142                 conwidth = realconheight * MENU_ASPECT;
 143                 conheight = realconheight;
 144         }
 145         else
 146         {
 147                 // squarescreen
 148                 conwidth = realconwidth;
 149                 conheight = realconwidth / MENU_ASPECT;
 150         }
 151         if (main)
 152         {
 153                 if (conwidth_s != conwidth || conheight_s != conheight)
 154                 {
 155                         draw_reset_cropped();
 156                         main.resizeNotify(main, '0 0 0', eX * conwidth + eY * conheight, '0 0 0', eX * conwidth + eY * conheight);
 157                 }
 158         }
 159         else
 160         {
 161                 vidwidth_s = vidheight_s = vidpixelheight_s = 0;  // retry next frame
 162         }
 163 }
 164
 165 string m_goto_buffer;
 166 void m_init_delayed()
 167 {
 168         draw_reset_cropped();
 169
 170         menuInitialized = false;
 171         if (!preMenuInit()) return;
 172         menuInitialized = true;
 173
 174         int fh = -1;
 175         if (cvar_string("menu_skin") != "")
 176         {
 177                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
 178                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
 179         }
 180         if (fh < 0 && cvar_defstring("menu_skin") != "")
 181         {
 182                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
 183                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
 184                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
 185         }
 186         if (fh < 0)
 187         {
 188                 draw_currentSkin = "gfx/menu/default";
 189                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
 190         }
 191         if (fh < 0) error("cannot load any menu skin\n");
 192         draw_currentSkin = strzone(draw_currentSkin);
 193         for (string s; (s = fgets(fh)); )
 194         {
 195                 // these two are handled by skinlist.qc
 196                 if (substring(s, 0, 6) == "title ") continue;
 197                 if (substring(s, 0, 7) == "author ") continue;
 198                 int n = tokenize_console(s);
 199                 if (n < 2) continue;
 200                 Skin_ApplySetting(argv(0), substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 201         }
 202         fclose(fh);
 203
 204         int glob = search_begin(strcat(draw_currentSkin, "/*.tga"), true, true);
 205         if (glob >= 0)
 206         {
 207                 for (int i = 0, n = search_getsize(glob); i < n; ++i)
 208                         precache_pic(search_getfilename(glob, i));
 209                 search_end(glob);
 210         }
 211
 212         draw_setMousePointer(SKINGFX_CURSOR, SKINSIZE_CURSOR, SKINOFFSET_CURSOR);
 213
 214         anim = NEW(AnimHost);
 215         main = NEW(MainWindow);
 216         main.configureMainWindow(main);
 217
 218         main.resizeNotify(main, '0 0 0', eX * conwidth + eY * conheight, '0 0 0', eX * conwidth + eY * conheight);
 219         main.focused = true;
 220         menuShiftState = 0;
 221         menuMousePos = '0.5 0.5 0';
 222
 223         m_sync();
 224
 225         if (m_goto_buffer)
 226         {
 227                 m_goto(m_goto_buffer);
 228                 strfree(m_goto_buffer);
 229         }
 230
 231         if (Menu_Active) m_display();  // delayed menu display
 232
 233         cvar_set("_menu_initialized", "2");
 234 }
 235
 236 void m_keyup(float key, float ascii)
 237 {
 238         if (!menuInitialized) return;
 239         if (!Menu_Active) return;
 240         draw_reset_cropped();
 241         main.keyUp(main, key, ascii, menuShiftState);
 242         if (key >= K_MOUSE1 && key <= K_MOUSE3)
 243         {
 244                 --mouseButtonsPressed;
 245                 if (!mouseButtonsPressed) main.mouseRelease(main, menuMousePos);
 246                 if (mouseButtonsPressed < 0)
 247                 {
 248                         mouseButtonsPressed = 0;
 249                         LOG_TRACE("Warning: released an already released button");
 250                 }
 251         }
 252         if (key == K_ALT) menuShiftState &= ~S_ALT;
 253         if (key == K_CTRL) menuShiftState &= ~S_CTRL;
 254         if (key == K_SHIFT) menuShiftState &= ~S_SHIFT;
 255 }
 256
 257 void m_keydown(float key, float ascii)
 258 {
 259         if (!menuInitialized) return;
 260         if (!Menu_Active) return;
 261
 262         if (menuMouseMode && key >= K_MOUSE1 && key <= K_MOUSE3)
 263         {
 264                 // detect a click outside of the game window
 265                 vector p = getmousepos();
 266                 if (p.x < 0 || p.x > realconwidth || p.y < 0 || p.y > realconheight)
 267                 {
 268                         ++mouseButtonsPressed;
 269                         return;
 270                 }
 271         }
 272
 273         if (keyGrabber)
 274         {
 275                 entity e = keyGrabber;
 276                 keyGrabber = NULL;
 277                 e.keyGrabbed(e, key, ascii);
 278         }
 279         else
 280         {
 281                 draw_reset_cropped();
 282                 if (!mouseButtonsPressed && key >= K_MOUSE1 && key <= K_MOUSE3)
 283                         main.mousePress(main, menuMousePos);
 284                 if (!main.keyDown(main, key, ascii, menuShiftState))
 285                 {
 286                         // disable menu on unhandled ESC
 287                         if (key == K_ESCAPE)
 288                                 if (gamestatus & (GAME_ISSERVER | GAME_CONNECTED))  // don't back out to console only
 289                                         m_hide();
 290                 }
 291         }
 292         if (key >= K_MOUSE1 && key <= K_MOUSE3)
 293         {
 294                 ++mouseButtonsPressed;
 295                 if (mouseButtonsPressed > 10)
 296                 {
 297                         mouseButtonsPressed = 10;
 298                         LOG_TRACE("Warning: pressed an already pressed button");
 299                 }
 300         }
 301         if (key == K_ALT) menuShiftState |= S_ALT;
 302         if (key == K_CTRL) menuShiftState |= S_CTRL;
 303         if (key == K_SHIFT) menuShiftState |= S_SHIFT;
 304 }
 305
 306 enum {
 307         SCALEMODE_CROP,
 308         SCALEMODE_LETTERBOX,
 309         SCALEMODE_WIDTH,
 310         SCALEMODE_HEIGHT,
 311         SCALEMODE_STRETCH,
 312 };
 313 void draw_Picture_Aligned(vector algn, float scalemode, string img, float a)
 314 {
 315         vector sz = draw_PictureSize(img);
 316         bool width_is_larger = (sz.x * draw_scale.y >= sz.y * draw_scale.x);
 317         vector isz_w = '1 0 0' + '0 1 0' * ((sz.y / sz.x) * (draw_scale.x / draw_scale.y));
 318         vector isz_h = '0 1 0' + '1 0 0' * ((sz.x / sz.y) * (draw_scale.y / draw_scale.x));
 319         vector isz;
 320         switch (scalemode)
 321         {
 322                 default:
 323                 case SCALEMODE_CROP:
 324                         isz = (width_is_larger ? isz_h : isz_w);
 325                         break;
 326                 case SCALEMODE_LETTERBOX:
 327                         isz = (width_is_larger ? isz_w : isz_h);
 328                         break;
 329                 case SCALEMODE_WIDTH:
 330                         isz = isz_w;
 331                         break;
 332                 case SCALEMODE_HEIGHT:
 333                         isz = isz_h;
 334                         break;
 335                 case SCALEMODE_STRETCH:
 336                         isz = '1 1 0';
 337                         break;
 338         }
 339         vector org = eX * (algn.x * (1 - isz.x)) + eY * (algn.y * (1 - isz.y));
 340         draw_Picture(org, img, isz, '1 1 1', a);
 341 }
 342
 343 void drawBackground(string img, float a, string algn, float force1)
 344 {
 345         if (main.mainNexposee.ModalController_state == 0) return;
 346         vector v = '0 0 0';
 347         int scalemode = SCALEMODE_CROP;
 348         int len = strlen(algn);
 349         for (int i = 0, l = 0; i < len; ++i)
 350         {
 351                 string c = substring(algn, i, 1);
 352                 switch (c)
 353                 {
 354                         case "c":
 355                                 scalemode = SCALEMODE_CROP;
 356                                 goto nopic;
 357                         case "l":
 358                                 scalemode = SCALEMODE_LETTERBOX;
 359                                 goto nopic;
 360                         case "h":
 361                                 scalemode = SCALEMODE_HEIGHT;
 362                                 goto nopic;
 363                         case "w":
 364                                 scalemode = SCALEMODE_WIDTH;
 365                                 goto nopic;
 366                         case "s":
 367                                 scalemode = SCALEMODE_STRETCH;
 368                                 goto nopic;
 369                         case "1": case "4": case "7":
 370                                 v.x = 0.0;
 371                                 break;
 372                         case "2": case "5": case "8":
 373                                 v.x = 0.5;
 374                                 break;
 375                         case "3": case "6": case "9":
 376                                 v.x = 1.0;
 377                                 break;
 378                         default:
 379                                 v.x = random();
 380                                 break;
 381                 }
 382                 switch (c)
 383                 {
 384                         case "7": case "8": case "9":
 385                                 v.y = 0.0;
 386                                 break;
 387                         case "4": case "5": case "6":
 388                                 v.y = 0.5;
 389                                 break;
 390                         case "1": case "2": case "3":
 391                                 v.y = 1.0;
 392                                 break;
 393                         default:
 394                                 v.y = random();
 395                                 break;
 396                 }
 397                 if (l == 0)
 398                 {
 399                         draw_Picture_Aligned(v, scalemode, img, a);
 400                 }
 401                 else if (force1)
 402                 {
 403                         // force all secondary layers to use alpha 1. Prevents ugly issues
 404                         // with overlap. It's a flag because it cannot be used for the
 405                         // ingame background
 406                         draw_Picture_Aligned(v, scalemode, strcat(img, "_l", ftos(l + 1)), 1);
 407                 }
 408                 else
 409                 {
 410                         draw_Picture_Aligned(v, scalemode, strcat(img, "_l", ftos(l + 1)), a);
 411                 }
 412                 ++l;
 413 LABEL(nopic)
 414         }
 415 }
 416
 417 int menu_tooltips;
 418 int menu_tooltips_old;
 419 vector menuTooltipAveragedMousePos;
 420 entity menuTooltipItem;
 421 vector menuTooltipOrigin;
 422 vector menuTooltipSize;
 423 float menuTooltipAlpha;
 424 string menuTooltipText;
 425 int menuTooltipState;  // 0: static, 1: fading in, 2: fading out, 3: forced fading out
 426 bool m_testmousetooltipbox(vector pos)
 427 {
 428         return !(
 429             (pos.x >= menuTooltipOrigin.x && pos.x < menuTooltipOrigin.x + menuTooltipSize.x)
 430             && (pos.y >= menuTooltipOrigin.y && pos.y < menuTooltipOrigin.y + menuTooltipSize.y)
 431                 );
 432 }
 433 bool m_testtooltipbox(vector tooltippos)
 434 {
 435         if (tooltippos.x < 0) return false;
 436         if (tooltippos.y < 0) return false;
 437         if (tooltippos.x + menuTooltipSize.x > 1) return false;
 438         if (tooltippos.y + menuTooltipSize.y > 1) return false;
 439         menuTooltipOrigin = tooltippos;
 440         return true;
 441 }
 442 bool m_allocatetooltipbox(vector pos)
 443 {
 444         vector avoidplus;
 445         avoidplus.x = (SKINAVOID_TOOLTIP_x + SKINSIZE_CURSOR_x - SKINOFFSET_CURSOR_x * SKINSIZE_CURSOR_x) / conwidth;
 446         avoidplus.y = (SKINAVOID_TOOLTIP_y + SKINSIZE_CURSOR_y - SKINOFFSET_CURSOR_y * SKINSIZE_CURSOR_y) / conheight;
 447         avoidplus.z = 0;
 448
 449         vector avoidminus;
 450         avoidminus.x = (SKINAVOID_TOOLTIP_x + SKINOFFSET_CURSOR_x * SKINSIZE_CURSOR_x) / conwidth + menuTooltipSize.x;
 451         avoidminus.y = (SKINAVOID_TOOLTIP_y + SKINOFFSET_CURSOR_y * SKINSIZE_CURSOR_y) / conheight + menuTooltipSize.y;
 452         avoidminus.z = 0;
 453
 454         // bottom right
 455         vector v = pos + avoidplus;
 456         if (m_testtooltipbox(v)) return true;
 457
 458         // bottom center
 459         v.x = pos.x - menuTooltipSize.x * 0.5;
 460         if (m_testtooltipbox(v)) return true;
 461
 462         // bottom left
 463         v.x = pos.x - avoidminus.x;
 464         if (m_testtooltipbox(v)) return true;
 465
 466         // top left
 467         v.y = pos.y - avoidminus.y;
 468         if (m_testtooltipbox(v)) return true;
 469
 470         // top center
 471         v.x = pos.x - menuTooltipSize.x * 0.5;
 472         if (m_testtooltipbox(v)) return true;
 473
 474         // top right
 475         v.x = pos.x + avoidplus.x;
 476         if (m_testtooltipbox(v)) return true;
 477
 478         return false;
 479 }
 480 entity m_findtooltipitem(entity root, vector pos)
 481 {
 482         entity best = NULL;
 483         for (entity it = root; it.instanceOfContainer; )
 484         {
 485                 while (it.instanceOfNexposee && it.focusedChild)
 486                 {
 487                         it = it.focusedChild;
 488                         pos = globalToBox(pos, it.Container_origin, it.Container_size);
 489                 }
 490                 if (it.instanceOfNexposee)
 491                 {
 492                         it = it.itemFromPoint(it, pos);
 493                         if (it.tooltip) best = it;
 494                         else if (menu_tooltips == 2 && (it.controlledCvar || it.onClickCommand)) best = it;
 495                         it = NULL;
 496                 }
 497                 else if (it.instanceOfModalController)
 498                 {
 499                         it = it.focusedChild;
 500                 }
 501                 else
 502                 {
 503                         it = it.itemFromPoint(it, pos);
 504                 }
 505                 if (!it) break;
 506                 if (it.tooltip) best = it;
 507                 else if (menu_tooltips == 2 && (it.controlledCvar || it.onClickCommand)) best = it;
 508                 pos = globalToBox(pos, it.Container_origin, it.Container_size);
 509         }
 510
 511         return best;
 512 }
 513 string gettooltip()
 514 {
 515         if (menu_tooltips == 2)
 516         {
 517                 string s;
 518                 if (menuTooltipItem.controlledCvar)
 519                 {
 520                         string cvar_list = getCvarsMulti(menuTooltipItem);
 521                         if (cvar_list)
 522                                 cvar_list = strcat(menuTooltipItem.controlledCvar, " ", cvar_list);
 523                         else
 524                                 cvar_list = menuTooltipItem.controlledCvar;
 525                         s = strcat("[", cvar_list, " \"", cvar_string(menuTooltipItem.controlledCvar), "\"]");
 526                 }
 527                 else if (menuTooltipItem.onClickCommand)
 528                 {
 529                         s = strcat("<", menuTooltipItem.onClickCommand, ">");
 530                 }
 531                 else
 532                 {
 533                         return menuTooltipItem.tooltip;
 534                 }
 535                 if (menuTooltipItem.tooltip) return strcat(menuTooltipItem.tooltip, " ", s);
 536                 return s;
 537         }
 538         return menuTooltipItem.tooltip;
 539 }
 540 void m_tooltip(vector pos)
 541 {
 542         static string prev_tooltip;
 543         entity it;
 544         menu_tooltips = cvar("menu_tooltips");
 545         if (!menu_tooltips)
 546         {
 547                 // don't return immediately, fade out the active tooltip first
 548                 if (menuTooltipItem == NULL) return;
 549                 it = NULL;
 550                 menu_tooltips_old = menu_tooltips;
 551         }
 552         else
 553         {
 554                 float f = bound(0, frametime * 2, 1);
 555                 menuTooltipAveragedMousePos = menuTooltipAveragedMousePos * (1 - f) + pos * f;
 556                 if (vdist(pos - menuTooltipAveragedMousePos, <, 0.01))
 557                 {
 558                         it = m_findtooltipitem(main, pos);
 559
 560                         if (it.instanceOfListBox && it.isScrolling(it)) it = NULL;
 561
 562                         if (it && prev_tooltip != it.tooltip)
 563                         {
 564                                 // fade out if tooltip of a certain item has changed
 565                                 menuTooltipState = 3;
 566                                 strcpy(prev_tooltip, it.tooltip);
 567                         }
 568                         else if (menuTooltipItem && !m_testmousetooltipbox(pos))
 569                         {
 570                                 menuTooltipState = 3;  // fade out if mouse touches it
 571                         }
 572                 }
 573                 else
 574                 {
 575                         it = NULL;
 576                 }
 577         }
 578         vector fontsize = '1 0 0' * (SKINFONTSIZE_TOOLTIP / conwidth) + '0 1 0' * (SKINFONTSIZE_TOOLTIP / conheight);
 579
 580         // float menuTooltipState; // 0: static, 1: fading in, 2: fading out, 3: forced fading out
 581         if (it != menuTooltipItem)
 582         {
 583                 switch (menuTooltipState)
 584                 {
 585                         case 0:
 586                                 if (menuTooltipItem)
 587                                 {
 588                                         // another item: fade out first
 589                                         menuTooltipState = 2;
 590                                 }
 591                                 else
 592                                 {
 593                                         // new item: fade in
 594                                         menuTooltipState = 1;
 595                                         menuTooltipItem = it;
 596
 597                                         menuTooltipOrigin.x = -1;  // unallocated
 598
 599                                         strcpy(menuTooltipText, gettooltip());
 600
 601                                         int i = 0;
 602                                         float w = 0;
 603                                         for (getWrappedLine_remaining = menuTooltipText; getWrappedLine_remaining && i <= 16; ++i)
 604                                         {
 605                                                 string s = getWrappedLine(SKINWIDTH_TOOLTIP, fontsize, draw_TextWidth_WithoutColors);
 606                                                 if (i == 16)
 607                                                         s = "...";
 608                                                 float f = draw_TextWidth(s, false, fontsize);
 609                                                 if (f > w) w = f;
 610                                         }
 611                                         menuTooltipSize.x = w + 2 * (SKINMARGIN_TOOLTIP_x / conwidth);
 612                                         menuTooltipSize.y = i * fontsize.y + 2 * (SKINMARGIN_TOOLTIP_y / conheight);
 613                                         menuTooltipSize.z = 0;
 614                                 }
 615                                 break;
 616                         case 1:
 617                                 // changing item while fading in: fade out first
 618                                 menuTooltipState = 2;
 619                                 break;
 620                         case 2:
 621                                 // changing item while fading out: can't
 622                                 break;
 623                 }
 624         }
 625         else if (menuTooltipState == 2)  // re-fade in?
 626         {
 627                 menuTooltipState = 1;
 628         }
 629
 630         switch (menuTooltipState)
 631         {
 632                 case 1:  // fade in
 633                         menuTooltipAlpha = bound(0, menuTooltipAlpha + 5 * frametime, 1);
 634                         if (menuTooltipAlpha == 1) menuTooltipState = 0;
 635                         break;
 636                 case 2:  // fade out
 637                 case 3:  // forced fade out
 638                         menuTooltipAlpha = bound(0, menuTooltipAlpha - 2 * frametime, 1);
 639                         if (menuTooltipAlpha == 0)
 640                         {
 641                                 menuTooltipState = 0;
 642                                 menuTooltipItem = NULL;
 643                         }
 644                         break;
 645         }
 646
 647         if (menuTooltipItem == NULL)
 648         {
 649                 strfree(menuTooltipText);
 650                 return;
 651         }
 652         else
 653         {
 654                 if (menu_tooltips != menu_tooltips_old)
 655                 {
 656                         if (menu_tooltips != 0 && menu_tooltips_old != 0) menuTooltipItem = NULL; // reload tooltip next frame
 657                         menu_tooltips_old = menu_tooltips;
 658                 }
 659                 else if (menuTooltipOrigin.x < 0)                                             // unallocated?
 660                 {
 661                         m_allocatetooltipbox(pos);
 662                 }
 663                 if (menuTooltipOrigin.x >= 0)
 664                 {
 665                         // draw the tooltip!
 666                         vector p = SKINBORDER_TOOLTIP;
 667                         p.x *= 1 / conwidth;
 668                         p.y *= 1 / conheight;
 669                         draw_BorderPicture(menuTooltipOrigin, SKINGFX_TOOLTIP, menuTooltipSize, '1 1 1', menuTooltipAlpha, p);
 670                         p = menuTooltipOrigin;
 671                         p.x += SKINMARGIN_TOOLTIP_x / conwidth;
 672                         p.y += SKINMARGIN_TOOLTIP_y / conheight;
 673                         int i = 0;
 674                         for (getWrappedLine_remaining = menuTooltipText; getWrappedLine_remaining && i <= 16; ++i, p.y += fontsize.y)
 675                         {
 676                                 string s = getWrappedLine(SKINWIDTH_TOOLTIP, fontsize, draw_TextWidth_WithoutColors);
 677                                 if (i == 16)
 678                                         s = "...";
 679                                 draw_Text(p, s, fontsize, SKINCOLOR_TOOLTIP, SKINALPHA_TOOLTIP * menuTooltipAlpha, false);
 680                         }
 681                 }
 682         }
 683 }
 684
 685 const int MIN_DISCONNECTION_TIME = 1;
 686 bool autocvar_g_campaign;
 687 void m_draw(float width, float height)
 688 {
 689         static float connected_time;
 690         if (clientstate() == CS_DISCONNECTED)
 691         {
 692                 // avoid a bug where the main menu re-opens when changing maps
 693                 // potentially exclusive to `map <mapname>` cmd?
 694                 if (connected_time && time - connected_time > MIN_DISCONNECTION_TIME)
 695                 {
 696                         if (autocvar_g_campaign)
 697                         {
 698                                 // in the case player uses the disconnect command (in the console or with a key)
 699                                 // reset g_campaign and update menu items to reflect cvar values that may have been restored after quiting the campaign
 700                                 // see also LEAVEMATCH_CMD
 701                                 cvar_set("g_campaign", "0");
 702                                 m_sync();
 703                         }
 704
 705                         // reload the menu so that disconnecting players don't
 706                         // have to press ESC to open it again
 707                         m_toggle(true);
 708
 709                         localcmd("\nmenu_cmd directmenu Welcome RESET\n");
 710                         connected_time = 0;
 711
 712                         // reset main menu
 713                         // FIXME?: find out if anything should be done to reset it more,
 714                         // this is just a fix to make main menu music replay nicely
 715                         menuNotTheFirstFrame = 1;
 716                 }
 717         }
 718         else
 719                 connected_time = time;
 720
 721         m_gamestatus();
 722
 723         execute_next_frame();
 724
 725         menuMouseMode = cvar("menu_mouse_absolute");
 726
 727         if (anim) anim.tickAll(anim);
 728
 729         UpdateConWidthHeight(width, height, cvar("vid_pixelheight"));
 730
 731         if (!menuInitialized)
 732         {
 733                 // TODO draw an info image about this situation
 734                 m_init_delayed();
 735                 return;
 736         }
 737
 738         if (menuNotTheFirstFrame == 0) // only fade the menu in once ever
 739                 menuLogoAlpha = -0.8;  // no idea why, but when I start this at zero, it jumps instead of fading FIXME
 740
 741         if (menuNotTheFirstFrame <= 1) // only once per menu reload
 742         {
 743                 if (Menu_Active && !autocvar_menu_no_music_nor_welcome)
 744                 {
 745                         localcmd("cd loop $menu_cdtrack\n");
 746
 747                         // TODO: enable this when we have a welcome sound
 748                         // FIXME: change the file used according to the selected announcer
 749                         // Only play the welcome announcement once, not on any menu reloads
 750                         //if (menuNotTheFirstFrame == 0)
 751                         //localcmd("play sound/announcer/default/welcome.wav\n");
 752                 }
 753
 754                 menuNotTheFirstFrame = 2;
 755         }
 756
 757         float t = gettime();
 758         float realFrametime = frametime = min(0.2, t - menuPrevTime);
 759         menuPrevTime = t;
 760         time += frametime;
 761
 762         t = cvar("menu_slowmo");
 763         if (t)
 764         {
 765                 frametime *= t;
 766                 realFrametime *= t;
 767         }
 768         else
 769         {
 770                 t = 1;
 771         }
 772
 773         if (Menu_Active)
 774         {
 775                 if (getmousetarget() == (menuMouseMode ? MT_CLIENT : MT_MENU)
 776                     && (getkeydest() == KEY_MENU || getkeydest() == KEY_MENU_GRABBED))
 777                         setkeydest(keyGrabber ? KEY_MENU_GRABBED : KEY_MENU);
 778                 else m_hide();
 779         }
 780
 781         if (cvar("cl_capturevideo")) frametime = t / cvar("cl_capturevideo_fps");  // make capturevideo work smoothly
 782
 783         prevMenuAlpha = menuAlpha;
 784         if (Menu_Active)
 785         {
 786                 if (menuAlpha == 0 && menuLogoAlpha < 2)
 787                 {
 788                         menuLogoAlpha += 2 * frametime;
 789                 }
 790                 else
 791                 {
 792                         menuAlpha = min(1, menuAlpha + 5 * frametime);
 793                         menuLogoAlpha = 2;
 794                 }
 795         }
 796         else
 797         {
 798                 menuAlpha = max(0, menuAlpha - 5 * frametime);
 799                 menuLogoAlpha = 2;
 800         }
 801
 802         draw_reset_cropped();
 803
 804         if (!(gamestatus & (GAME_CONNECTED | GAME_ISSERVER)))
 805         {
 806                 if (menuLogoAlpha > 0)
 807                 {
 808                         draw_reset_full();
 809                         draw_Fill('0 0 0', '1 1 0', SKINCOLOR_BACKGROUND, 1);
 810                         drawBackground(SKINGFX_BACKGROUND, bound(0, menuLogoAlpha, 1), SKINALIGN_BACKGROUND, true);
 811                         draw_reset_cropped();
 812                         if (menuAlpha <= 0 && SKINALPHA_CURSOR_INTRO > 0)
 813                         {
 814                                 draw_alpha = SKINALPHA_CURSOR_INTRO * bound(0, menuLogoAlpha, 1);
 815                                 draw_drawMousePointer(menuMousePos);
 816                                 draw_alpha = 1;
 817                         }
 818                 }
 819         }
 820         else if (SKINALPHA_BACKGROUND_INGAME)
 821         {
 822                 if (menuAlpha > 0)
 823                 {
 824                         draw_reset_full();
 825                         drawBackground(SKINGFX_BACKGROUND_INGAME, menuAlpha * SKINALPHA_BACKGROUND_INGAME,
 826                                 SKINALIGN_BACKGROUND_INGAME, false);
 827                         draw_reset_cropped();
 828                 }
 829         }
 830
 831         if (menuAlpha != prevMenuAlpha) cvar_set("_menu_alpha", ftos(menuAlpha));
 832
 833         draw_reset_cropped();
 834         preMenuDraw();
 835         draw_reset_cropped();
 836
 837         if (menuAlpha <= 0)
 838         {
 839                 if (prevMenuAlpha > 0) main.initializeDialog(main, main.firstChild);
 840                 draw_reset_cropped();
 841                 postMenuDraw();
 842                 return;
 843         }
 844
 845         draw_alpha *= menuAlpha;
 846
 847         if (menuMouseMode)
 848         {
 849                 vector rawMousePos = getmousepos();
 850                 vector newMouse = globalToBox(rawMousePos, draw_shift, draw_scale);
 851                 if (rawMousePos != '0 0 0' && newMouse != menuMousePos)
 852                 {
 853                         menuMousePos = newMouse;
 854                         if (mouseButtonsPressed) main.mouseDrag(main, menuMousePos);
 855                         else main.mouseMove(main, menuMousePos);
 856                 }
 857         }
 858         else if (frametime > 0)
 859         {
 860                 vector dMouse = getmousepos() * (frametime / realFrametime);  // for capturevideo
 861                 if (dMouse != '0 0 0')
 862                 {
 863                         vector minpos = globalToBox('0 0 0', draw_shift, draw_scale);
 864                         vector maxpos = globalToBox(eX * (realconwidth - 1) + eY * (realconheight - 1), draw_shift, draw_scale);
 865                         dMouse = globalToBoxSize(dMouse, draw_scale);
 866                         menuMousePos += dMouse * cvar("menu_mouse_speed");
 867                         menuMousePos.x = bound(minpos.x, menuMousePos.x, maxpos.x);
 868                         menuMousePos.y = bound(minpos.y, menuMousePos.y, maxpos.y);
 869                         if (mouseButtonsPressed) main.mouseDrag(main, menuMousePos);
 870                         else main.mouseMove(main, menuMousePos);
 871                 }
 872         }
 873         main.draw(main);
 874
 875         m_tooltip(menuMousePos);
 876
 877         draw_alpha = max(draw_alpha, SKINALPHA_CURSOR_INTRO * bound(0, menuLogoAlpha, 1));
 878
 879         draw_drawMousePointer(menuMousePos);
 880
 881         draw_reset_cropped();
 882         postMenuDraw();
 883
 884         frametime = 0;
 885         IL_ENDFRAME();
 886 }
 887
 888 void m_display()
 889 {
 890         Menu_Active = true;
 891         setkeydest(KEY_MENU);
 892         setmousetarget((menuMouseMode ? MT_CLIENT : MT_MENU));
 893
 894         if (!menuInitialized) return;
 895
 896         if (mouseButtonsPressed) main.mouseRelease(main, menuMousePos);
 897         mouseButtonsPressed = 0;
 898
 899         main.focusEnter(main);
 900         main.showNotify(main);
 901 }
 902
 903 void m_hide()
 904 {
 905         Menu_Active = false;
 906         setkeydest(KEY_GAME);
 907         setmousetarget(MT_CLIENT);
 908
 909         if (!menuInitialized) return;
 910
 911         main.focusLeave(main);
 912         main.hideNotify(main);
 913 }
 914
 915 void m_toggle(int mode)
 916 {
 917         if (Menu_Active)
 918         {
 919                 if (mode == 1) return;
 920                 m_hide();
 921         }
 922         else
 923         {
 924                 if (mode == 0) return;
 925                 m_display();
 926         }
 927 }
 928
 929 void Shutdown()
 930 {
 931         m_hide();
 932         FOREACH_ENTITY_ORDERED(it.destroy, {
 933                 if (it.classname == "vtbl") continue;
 934                 it.destroy(it);
 935         });
 936         cvar_set("_menu_cmd_closemenu_available", "0");
 937 }
 938
 939 void m_focus_item_chain(entity outermost, entity innermost)
 940 {
 941         if (innermost.parent != outermost) m_focus_item_chain(outermost, innermost.parent);
 942         innermost.parent.setFocus(innermost.parent, innermost);
 943 }
 944
 945 void m_activate_window(entity wnd)
 946 {
 947         entity par = wnd.parent;
 948         if (par) m_activate_window(par);
 949
 950         if (par.instanceOfModalController)
 951         {
 952                 if (wnd.tabSelectingButton)
 953                         // tabs
 954                         TabButton_Click(wnd.tabSelectingButton, wnd);
 955                 else
 956                         // root
 957                         par.initializeDialog(par, wnd);
 958         }
 959         else if (par.instanceOfNexposee)
 960         {
 961                 // nexposee (sorry for violating abstraction here)
 962                 par.selectedChild = wnd;
 963                 par.animationState = 1;
 964                 Container_setFocus(par, NULL);
 965         }
 966         else if (par.instanceOfContainer)
 967         {
 968                 // other containers
 969                 if (par.focused) par.setFocus(par, wnd);
 970         }
 971 }
 972
 973 void m_setpointerfocus(entity wnd)
 974 {
 975         if (!wnd.instanceOfContainer) return;
 976         entity focus = wnd.preferredFocusedGrandChild(wnd);
 977         if (!focus) return;
 978         menuMousePos = focus.origin + 0.5 * focus.size;
 979         menuMousePos.x *= 1 / conwidth;
 980         menuMousePos.y *= 1 / conheight;
 981         entity par = wnd.parent;
 982         if (par.focused) par.setFocus(par, wnd);
 983         if (wnd.focused) m_focus_item_chain(wnd, focus);
 984 }
 985
 986 void m_goto(string itemname)
 987 {
 988         if (!menuInitialized)
 989         {
 990                 strcpy(m_goto_buffer, itemname);
 991                 return;
 992         }
 993         if (itemname == "")  // this can be called by GameCommand
 994         {
 995                 if (gamestatus & (GAME_ISSERVER | GAME_CONNECTED))
 996                 {
 997                         m_hide();
 998                         return;
 999                 }
1000                 itemname = "nexposee";
1001         }
1002
1003         if (itemname == "nexposee")
1004         {
1005                 // unlike 'togglemenu 1', this closes modal and root dialogs if opened
1006                 m_activate_window(main.mainNexposee);
1007                 m_display();
1008         }
1009         else
1010         {
1011                 entity e;
1012                 for (e = NULL; (e = find(e, name, itemname)); )
1013                         if (e.classname != "vtbl") break;
1014
1015                 if ((e) && (!e.requiresConnection || (gamestatus & (GAME_ISSERVER | GAME_CONNECTED))))
1016                 {
1017                         if(!Menu_Active)
1018                                 e.hideMenuOnClose = true;
1019                         m_hide();
1020                         m_activate_window(e);
1021                         m_setpointerfocus(e);
1022                         m_display();
1023                 }
1024         }
1025 }
1026
1027 void m_play_focus_sound()
1028 {
1029         static float menuLastFocusSoundTime;
1030         if (cvar("menu_sounds") < 2) return;
1031         if (time - menuLastFocusSoundTime <= 0.25) return;
1032         localsound(MENU_SOUND_FOCUS);
1033         menuLastFocusSoundTime = time;
1034 }
1035
1036 void m_play_click_sound(string soundfile)
1037 {
1038         if (!cvar("menu_sounds")) return;
1039         localsound(soundfile);
1040 }