qcsrc/common/weapons/all.qc

   1 #include "all.qh"
   2 #ifndef WEAPONS_ALL_C
   3 #define WEAPONS_ALL_C
   4
   5 #if defined(CSQC)
   6         #include "../constants.qh"
   7         #include "../stats.qh"
   8         #include <lib/warpzone/anglestransform.qh>
   9         #include <lib/warpzone/common.qh>
  10         #include <lib/warpzone/client.qh>
  11         #include "../util.qh"
  12         #include <client/autocvars.qh>
  13         #include "../deathtypes/all.qh"
  14         #include <lib/csqcmodel/interpolate.qh>
  15         #include "../physics/movetypes/movetypes.qh"
  16         #include <client/main.qh>
  17         #include <lib/csqcmodel/cl_model.qh>
  18 #elif defined(MENUQC)
  19 #elif defined(SVQC)
  20         #include <common/items/_mod.qh>
  21         #include <lib/warpzone/anglestransform.qh>
  22         #include <lib/warpzone/common.qh>
  23         #include <lib/warpzone/util_server.qh>
  24         #include <lib/warpzone/server.qh>
  25         #include "../constants.qh"
  26         #include "../stats.qh"
  27         #include "../teams.qh"
  28         #include <common/util.qh>
  29         #include "../monsters/_mod.qh"
  30         #include "config.qh"
  31         #include <server/weapons/common.qh>
  32         #include <server/weapons/csqcprojectile.qh>
  33         #include <server/weapons/tracing.qh>
  34         #include <server/items/spawning.qh>
  35         #include <server/autocvars.qh>
  36         #include "../notifications/all.qh"
  37         #include "../deathtypes/all.qh"
  38         #include <server/mutators/_mod.qh>
  39         #include "../mapinfo.qh"
  40         #include <server/command/_mod.qh>
  41         #include <lib/csqcmodel/sv_model.qh>
  42         #include <server/portals.qh>
  43 #include <server/hook.qh>
  44 #endif
  45 #ifdef GAMEQC
  46         #include "calculations.qc"
  47 #endif
  48 #ifdef SVQC
  49         #include "config.qc"
  50 #endif
  51
  52 #include "weapon/_mod.inc"
  53
  54
  55 // WEAPON PLUGIN SYSTEM
  56
  57 WepSet _WepSet_FromWeapon(int a)
  58 {
  59         a -= WEP_FIRST;
  60         if (REGISTRY_MAX(Weapons) > 24)
  61                 if (a >= 24)
  62                 {
  63                         a -= 24;
  64                         if (REGISTRY_MAX(Weapons) > 48)
  65                                 if (a >= 24)
  66                                 {
  67                                         a -= 24;
  68                                         return '0 0 1' * (2 ** a);
  69                                 }
  70                         return '0 1 0' * (2 ** a);
  71                 }
  72         return '1 0 0' * (2 ** a);
  73 }
  74 #ifdef SVQC
  75         void WriteWepSet(float dst, WepSet w)
  76         {
  77                 if (REGISTRY_MAX(Weapons) > 48) WriteInt72_t(dst, w);
  78                 else if (REGISTRY_MAX(Weapons) > 24) WriteInt48_t(dst, w);
  79                 else WriteInt24_t(dst, w.x);
  80         }
  81 #endif
  82 #ifdef CSQC
  83         WepSet WepSet_GetFromStat()
  84         {
  85                 return STAT(WEAPONS);
  86         }
  87         WepSet WepSet_GetFromStat_InMap()
  88         {
  89                 return STAT(WEAPONSINMAP);
  90         }
  91         WepSet ReadWepSet()
  92         {
  93                 if (REGISTRY_MAX(Weapons) > 48) return ReadInt72_t();
  94                 if (REGISTRY_MAX(Weapons) > 24) return ReadInt48_t();
  95                 return ReadInt24_t() * '1 0 0';
  96         }
  97 #endif
  98
  99 string W_FixWeaponOrder(string order, float complete)
 100 {
 101         return fixPriorityList(order, WEP_FIRST, WEP_LAST, WEP_IMPULSE_BEGIN - WEP_FIRST, complete);
 102 }
 103 string W_NameWeaponOrder_MapFunc(string s)
 104 {
 105         int i = stof(s);
 106         if (s == "0" || i)
 107         {
 108                 entity wi = REGISTRY_GET(Weapons, i);
 109                 if (wi != WEP_Null) return wi.netname;
 110         }
 111         return s;
 112 }
 113
 114 string W_UndeprecateName(string s)
 115 {
 116         switch (s)
 117         {
 118                 case "nex": return "vortex";
 119                 case "rocketlauncher": return "devastator";
 120                 case "laser": return "blaster";
 121                 case "minstanex": return "vaporizer";
 122                 case "grenadelauncher": return "mortar";
 123                 case "uzi": return "machinegun";
 124                 case "hmg": return "okhmg";
 125                 case "rpc": return "okrpc";
 126                 default: return s;
 127         }
 128 }
 129 string W_NameWeaponOrder(string order)
 130 {
 131         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
 132 }
 133 string W_NumberWeaponOrder_MapFunc(string s)
 134 {
 135         if (s == "0" || stof(s)) return s;
 136         s = W_UndeprecateName(s);
 137         FOREACH(Weapons, it != WEP_Null && it.netname == s, return ftos(i));
 138         return s;
 139 }
 140 string W_NumberWeaponOrder(string order)
 141 {
 142         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
 143 }
 144
 145 float W_FixWeaponOrder_BuildImpulseList_buf[REGISTRY_MAX(Weapons)];
 146 string W_FixWeaponOrder_BuildImpulseList_order;
 147 void W_FixWeaponOrder_BuildImpulseList_swap(int i, int j, entity pass)
 148 {
 149         float h;
 150         h = W_FixWeaponOrder_BuildImpulseList_buf[i];
 151         W_FixWeaponOrder_BuildImpulseList_buf[i] = W_FixWeaponOrder_BuildImpulseList_buf[j];
 152         W_FixWeaponOrder_BuildImpulseList_buf[j] = h;
 153 }
 154 float W_FixWeaponOrder_BuildImpulseList_cmp(int i, int j, entity pass)
 155 {
 156         int si = W_FixWeaponOrder_BuildImpulseList_buf[i];
 157         Weapon e1 = REGISTRY_GET(Weapons, si);
 158         int sj = W_FixWeaponOrder_BuildImpulseList_buf[j];
 159         Weapon e2 = REGISTRY_GET(Weapons, sj);
 160         int d = (e1.impulse + 9) % 10 - (e2.impulse + 9) % 10;
 161         if (d != 0) return -d;  // high impulse first!
 162         string s = strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " ");
 163         return strstrofs(s, sprintf(" %d ", si), 0)
 164                 - strstrofs(s, sprintf(" %d ", sj), 0); // low char index first!
 165 }
 166 string W_FixWeaponOrder_BuildImpulseList(string o)
 167 {
 168         int i;
 169         W_FixWeaponOrder_BuildImpulseList_order = o;
 170         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 171                 W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST] = i;
 172         heapsort(WEP_LAST - WEP_FIRST + 1, W_FixWeaponOrder_BuildImpulseList_swap, W_FixWeaponOrder_BuildImpulseList_cmp,
 173                 NULL);
 174         o = "";
 175         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 176                 o = strcat(o, " ", ftos(W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST]));
 177         W_FixWeaponOrder_BuildImpulseList_order = string_null;
 178         return substring(o, 1, -1);
 179 }
 180
 181 string W_FixWeaponOrder_AllowIncomplete(entity this, string order)
 182 {
 183         return W_FixWeaponOrder(order, 0);
 184 }
 185
 186 string W_FixWeaponOrder_ForceComplete(string order)
 187 {
 188         if (order == "") order = W_NumberWeaponOrder(cvar_defstring("cl_weaponpriority"));
 189         return W_FixWeaponOrder(order, 1);
 190 }
 191
 192 WepSet W_RandomWeapons(entity e, WepSet remaining, int n)
 193 {
 194         WepSet result = '0 0 0';
 195         for (int j = 0; j < n; ++j)
 196         {
 197                 RandomSelection_Init();
 198                 FOREACH(Weapons, it != WEP_Null, {
 199                         if (remaining & (it.m_wepset))
 200                                 RandomSelection_AddEnt(it, 1, 1);
 201                 });
 202                 Weapon w = RandomSelection_chosen_ent;
 203                 result |= WepSet_FromWeapon(w);
 204                 remaining &= ~WepSet_FromWeapon(w);
 205         }
 206         return result;
 207 }
 208
 209 string GetAmmoPicture(int ammotype)
 210 {
 211         switch (ammotype)
 212         {
 213                 case RES_SHELLS:  return ITEM_Shells.m_icon;
 214                 case RES_BULLETS: return ITEM_Bullets.m_icon;
 215                 case RES_ROCKETS: return ITEM_Rockets.m_icon;
 216                 case RES_CELLS:   return ITEM_Cells.m_icon;
 217                 case RES_PLASMA:  return ITEM_Plasma.m_icon;
 218                 case RES_FUEL:    return ITEM_JetpackFuel.m_icon;
 219                 default: return "";  // wtf, no ammo type?
 220         }
 221 }
 222
 223 string GetAmmoName(int ammotype)
 224 {
 225         switch (ammotype)
 226         {
 227                 case RES_SHELLS:  return ITEM_Shells.m_name;
 228                 case RES_BULLETS: return ITEM_Bullets.m_name;
 229                 case RES_ROCKETS: return ITEM_Rockets.m_name;
 230                 case RES_CELLS:   return ITEM_Cells.m_name;
 231                 case RES_PLASMA:  return ITEM_Plasma.m_name;
 232                 case RES_FUEL:    return ITEM_JetpackFuel.m_name;
 233                 default:          return "batteries";
 234         }
 235 }
 236
 237 entity GetAmmoItem(int ammotype)
 238 {
 239         switch (ammotype)
 240         {
 241                 case RES_SHELLS:  return ITEM_Shells;
 242                 case RES_BULLETS: return ITEM_Bullets;
 243                 case RES_ROCKETS: return ITEM_Rockets;
 244                 case RES_CELLS:   return ITEM_Cells;
 245                 case RES_PLASMA:  return ITEM_Plasma;
 246                 case RES_FUEL:    return ITEM_JetpackFuel;
 247         }
 248         LOG_WARNF("Invalid ammo type %d ", ammotype);
 249         return NULL;
 250         // WEAPONTODO: use this generic func to reduce duplication ?
 251         // GetAmmoPicture  GetAmmoName  notif_arg_item_wepammo  ammo_pickupevalfunc ?
 252 }
 253
 254 #ifdef CSQC
 255 int GetAmmoTypeFromNum(int i)
 256 {
 257         switch (i)
 258         {
 259                 case 0: return RES_SHELLS;
 260                 case 1: return RES_BULLETS;
 261                 case 2: return RES_ROCKETS;
 262                 case 3: return RES_CELLS;
 263                 case 4: return RES_PLASMA;
 264                 case 5: return RES_FUEL;
 265                 default: return RES_NONE;
 266         }
 267 }
 268
 269 int GetAmmoStat(int ammotype)
 270 {
 271         switch (ammotype)
 272         {
 273                 case RES_SHELLS: return STAT_SHELLS;
 274                 case RES_BULLETS: return STAT_NAILS;
 275                 case RES_ROCKETS: return STAT_ROCKETS;
 276                 case RES_CELLS: return STAT_CELLS;
 277                 case RES_PLASMA: return STAT_PLASMA.m_id;
 278                 case RES_FUEL: return STAT_FUEL.m_id;
 279                 default: return -1;
 280         }
 281 }
 282 #endif
 283
 284 string W_Sound(string w_snd)
 285 {
 286         string output = strcat("weapons/", w_snd);
 287         MUTATOR_CALLHOOK(WeaponSound, w_snd, output);
 288         return M_ARGV(1, string);
 289 }
 290
 291 string W_Model(string w_mdl)
 292 {
 293         string output = strcat("models/weapons/", w_mdl);
 294         MUTATOR_CALLHOOK(WeaponModel, w_mdl, output);
 295         return M_ARGV(1, string);
 296 }
 297
 298 #ifdef GAMEQC
 299 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
 300 {
 301         switch (algn)
 302         {
 303                 default:
 304                 case 3:
 305                         // right alignment
 306                         break;
 307                 case 4:
 308                         // left
 309                         vecs.y = -vecs.y;
 310                         break;
 311                 case 1:
 312                 case 2:
 313                         // center
 314                         vecs.y = 0;
 315                         vecs.z -= 2;
 316                         break;
 317         }
 318         return vecs;
 319 }
 320
 321 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn)
 322 {
 323         string s;
 324         if (visual)
 325         {
 326                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 327         }
 328         else if (STAT(SHOOTFROMEYE))
 329         {
 330                 vecs.y = vecs.z = 0;
 331         }
 332         else if (STAT(SHOOTFROMCENTER))
 333         {
 334                 vecs.y = 0;
 335                 vecs.z -= 2;
 336         }
 337         else if ((s = G_SHOOTFROMFIXEDORIGIN) != "")
 338         {
 339                 vector v = stov(s);
 340                 if (y_is_right) v.y = -v.y;
 341                 if (v.x != 0) vecs.x = v.x;
 342                 vecs.y = v.y;
 343                 vecs.z = v.z;
 344         }
 345         else  // just do the same as top
 346         {
 347                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 348         }
 349
 350         return vecs;
 351 }
 352
 353 #define shotorg_adjust shotorg_adjust_values
 354
 355 /**
 356  * supported formats:
 357  *
 358  * 1. simple animated model, muzzle flash handling on h_ model:
 359  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 360  *      tags:
 361  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 362  *        shell = casings ejection point (must be on the right hand side of the gun)
 363  *        weapon = attachment for v_tuba.md3
 364  *    v_tuba.md3 - first and third person model
 365  *    g_tuba.md3 - pickup model
 366  *
 367  * 2. simple animated model, muzzle flash handling on v_ model:
 368  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 369  *      tags:
 370  *        weapon = attachment for v_tuba.md3
 371  *    v_tuba.md3 - first and third person model
 372  *      tags:
 373  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 374  *        shell = casings ejection point (must be on the right hand side of the gun)
 375  *    g_tuba.md3 - pickup model
 376  *
 377  * 3. fully animated model, muzzle flash handling on h_ model:
 378  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 379  *      tags:
 380  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 381  *        shell = casings ejection point (must be on the right hand side of the gun)
 382  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 383  *    v_tuba.md3 - third person model
 384  *    g_tuba.md3 - pickup model
 385  *
 386  * 4. fully animated model, muzzle flash handling on v_ model:
 387  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 388  *      tags:
 389  *        shot = muzzle end (shot origin)
 390  *        shell = casings ejection point (must be on the right hand side of the gun)
 391  *    v_tuba.md3 - third person model
 392  *      tags:
 393  *        shot = muzzle end (for muzzle flashes)
 394  *    g_tuba.md3 - pickup model
 395  *
 396  * writes:
 397  *   this.origin, this.angles
 398  *   this.weaponchild
 399  *   this.movedir, this.view_ofs, this.movedir_aligned
 400  *   attachment stuff
 401  *   anim stuff
 402  * to free:
 403  *   call again with ""
 404  *   remove the ent
 405  */
 406 void CL_WeaponEntity_SetModel(entity this, string name, bool _anim)
 407 {
 408         if (name == "")
 409         {
 410                 vector oldmin = this.mins, oldmax = this.maxs;
 411                 setmodel(this, MDL_Null);
 412                 setsize(this, oldmin, oldmax);
 413                 if (this.weaponchild) delete(this.weaponchild);
 414                 this.weaponchild = NULL;
 415                 this.movedir = '0 0 0';
 416                 this.spawnorigin = '0 0 0';
 417                 this.oldorigin = '0 0 0';
 418                 this.anim_fire1  = '0 1 0.01';
 419                 this.anim_fire2  = '0 1 0.01';
 420                 this.anim_idle   = '0 1 0.01';
 421                 this.anim_reload = '0 1 0.01';
 422         }
 423         else
 424         {
 425                 // if there is a child entity, hide it until we're sure we use it
 426                 if (this.weaponchild) this.weaponchild.model = "";
 427                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
 428                 int v_shot_idx;  // used later
 429                 (v_shot_idx = gettagindex(this, "shot")) || (v_shot_idx = gettagindex(this, "tag_shot"));
 430
 431                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
 432                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 433                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
 434                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
 435                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
 436                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
 437
 438                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 439                 // if we don't, this is a "real" animated model
 440                 string t;
 441                 if ((t = "weapon", gettagindex(this, t)) || (t = "tag_weapon", gettagindex(this, t)))
 442                 {
 443                         if (!this.weaponchild)
 444                         {
 445                                 this.weaponchild = new(weaponchild);
 446 #ifdef CSQC
 447                                 this.weaponchild.drawmask = MASK_NORMAL;
 448                                 this.weaponchild.renderflags |= RF_VIEWMODEL;
 449 #endif
 450                         }
 451                         _setmodel(this.weaponchild, W_Model(strcat("v_", name, ".md3")));
 452                         setsize(this.weaponchild, '0 0 0', '0 0 0');
 453                         setattachment(this.weaponchild, this, t);
 454                 }
 455                 else
 456                 {
 457                         if (this.weaponchild) delete(this.weaponchild);
 458                         this.weaponchild = NULL;
 459                 }
 460
 461                 setsize(this, '0 0 0', '0 0 0');
 462                 setorigin(this, '0 0 0');
 463                 this.angles = '0 0 0';
 464                 this.frame = 0;
 465 #ifdef SVQC
 466                 this.viewmodelforclient = NULL;
 467 #else
 468                 this.renderflags &= ~RF_VIEWMODEL;
 469 #endif
 470                 if (v_shot_idx)  // v_ model attached to invisible h_ model
 471                 {
 472                         this.movedir = gettaginfo(this.weaponchild, v_shot_idx);
 473                 }
 474                 else
 475                 {
 476                         int idx;
 477                         if ((idx = gettagindex(this, "shot")) || (idx = gettagindex(this, "tag_shot")))
 478                         {
 479                                 this.movedir = gettaginfo(this, idx);
 480                         }
 481                         else
 482                         {
 483                                 LOG_WARNF("weapon model %s does not support the 'shot' tag, will display shots TOTALLY wrong",
 484                                         this.model);
 485                                 this.movedir = '0 0 0';
 486                         }
 487                 }
 488                 {
 489                         int idx = 0;
 490                         // v_ model attached to invisible h_ model
 491                         if (this.weaponchild
 492                                 && ((idx = gettagindex(this.weaponchild, "shell")) || (idx = gettagindex(this.weaponchild, "tag_shell"))))
 493                         {
 494                                 this.spawnorigin = gettaginfo(this.weaponchild, idx);
 495                         }
 496                         else if ((idx = gettagindex(this, "shell")) || (idx = gettagindex(this, "tag_shell")))
 497                         {
 498                                 this.spawnorigin = gettaginfo(this, idx);
 499                         }
 500                         else
 501                         {
 502                                 LOG_WARNF("weapon model %s does not support the 'shell' tag, will display casings wrong",
 503                                         this.model);
 504                                 this.spawnorigin = this.movedir;
 505                         }
 506                 }
 507                 if (v_shot_idx)
 508                 {
 509                         this.oldorigin = '0 0 0';  // use regular attachment
 510                 }
 511                 else
 512                 {
 513                         int idx;
 514                         if (this.weaponchild)
 515                                 (idx = gettagindex(this, "weapon")) || (idx = gettagindex(this, "tag_weapon"));
 516                         else
 517                                 (idx = gettagindex(this, "handle")) || (idx = gettagindex(this, "tag_handle"));
 518                         if (idx)
 519                         {
 520                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
 521                         }
 522                         else
 523                         {
 524                                 LOG_WARNF(
 525                                         "weapon model %s does not support the 'handle' tag "
 526                                         "and neither does the v_ model support the 'shot' tag, "
 527                                         "will display muzzle flashes TOTALLY wrong\n",
 528                                         this.model);
 529                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
 530                         }
 531                 }
 532
 533 #ifdef SVQC
 534                 this.viewmodelforclient = this.owner;
 535 #else
 536                 this.renderflags |= RF_VIEWMODEL;
 537 #endif
 538         }
 539
 540         this.view_ofs = '0 0 0';
 541         this.movedir_aligned = this.movedir;
 542
 543         if (this.movedir.x >= 0)
 544         {
 545                 //int algn = STAT(GUNALIGN, this.owner);
 546                 int algn = W_GunAlign(this, STAT(GUNALIGN, this.owner));
 547         #ifdef SVQC
 548                 this.m_gunalign = algn;
 549         #endif
 550                 vector v = this.movedir;
 551                 this.movedir = shotorg_adjust(v, false, false, algn);
 552                 this.movedir_aligned = shotorg_adjust(v, false, true, algn);
 553                 this.view_ofs = shotorg_adjust(v, false, true, algn) - v;
 554         }
 555         int compressed_shotorg = compressShotOrigin(this.movedir);
 556         // make them match perfectly
 557 #ifdef SVQC
 558         // null during init
 559         if (this.owner) STAT(SHOTORG, this.owner) = compressed_shotorg;
 560 #endif
 561         this.movedir = decompressShotOrigin(compressed_shotorg);
 562
 563         this.spawnorigin += this.view_ofs;  // offset the casings origin by the same amount
 564
 565         // check if an instant weapon switch occurred
 566         setorigin(this, this.view_ofs);
 567         if (!_anim) return;
 568         // reset animstate now
 569         this.wframe = WFRAME_IDLE;
 570         setanim(this, this.anim_idle, true, false, true);
 571 }
 572 #endif
 573
 574 #ifdef GAMEQC
 575
 576 REGISTER_NET_TEMP(wframe)
 577 #ifdef CSQC
 578 NET_HANDLE(wframe, bool isNew)
 579 {
 580         WFRAME fr = ReadByte();
 581         float t = ReadFloat();
 582         int slot = ReadByte();
 583         bool restartanim = ReadByte();
 584         entity wepent = viewmodels[slot];
 585         if(fr == WFRAME_IDLE)
 586                 wepent.animstate_looping = false; // we don't need to enforce idle animation
 587         else
 588         {
 589                 vector a = '0 0 0';
 590                 switch(fr)
 591                 {
 592                         default:
 593                         case WFRAME_IDLE: a = wepent.anim_idle; break;
 594                         case WFRAME_FIRE1: a = wepent.anim_fire1; break;
 595                         case WFRAME_FIRE2: a = wepent.anim_fire2; break;
 596                         case WFRAME_RELOAD: a = wepent.anim_reload; break;
 597                 }
 598                 a.z *= t;
 599                 anim_set(wepent, a, !restartanim, restartanim, restartanim);
 600         }
 601         wepent.state = ReadByte();
 602         wepent.weapon_nextthink = ReadFloat();
 603         switch (wepent.state)
 604         {
 605                 case WS_RAISE:
 606                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_raise;
 607                         break;
 608                 case WS_DROP:
 609                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_drop;
 610                         break;
 611                 default:
 612                         wepent.weapon_switchdelay = 0;
 613                         break;
 614         }
 615         return true;
 616 }
 617 #endif
 618
 619 #ifdef SVQC
 620 void wframe_send(entity actor, entity weaponentity, int wepframe, float attackrate, bool restartanim)
 621 {
 622         if (!IS_REAL_CLIENT(actor)) return;
 623         int channel = MSG_ONE;
 624         msg_entity = actor;
 625         WriteHeader(channel, wframe);
 626         WriteByte(channel, wepframe);
 627         WriteFloat(channel, attackrate);
 628         WriteByte(channel, weaponslot(weaponentity.weaponentity_fld));
 629         WriteByte(channel, restartanim);
 630         WriteByte(channel, weaponentity.state);
 631         WriteFloat(channel, weaponentity.weapon_nextthink);
 632 }
 633 #endif
 634
 635 REGISTER_NET_C2S(w_whereis)
 636 #ifdef SVQC
 637 void Weapon_whereis(Weapon this, entity cl);
 638 NET_HANDLE(w_whereis, bool)
 639 {
 640         Weapon wpn = ReadRegistered(Weapons);
 641         if (wpn != WEP_Null) Weapon_whereis(wpn, sender);
 642         return true;
 643 }
 644 #else
 645 void w_whereis(Weapon this)
 646 {
 647         int channel = MSG_C2S;
 648         WriteHeader(channel, w_whereis);
 649         WriteRegistered(Weapons, channel, this);
 650 }
 651 CLIENT_COMMAND(weapon_find, "Show spawn locations of a weapon")
 652 {
 653         switch (request)
 654         {
 655                 case CMD_REQUEST_COMMAND:
 656                 {
 657                         string s = argv(1);
 658                         if (s == "all")
 659                         {
 660                                 FOREACH(Weapons, it != WEP_Null, w_whereis(it));
 661                                 return;
 662                         }
 663                         if (s == "unowned")
 664                         {
 665                                 FOREACH(Weapons, it != WEP_Null && !(STAT(WEAPONS) & it.m_wepset), w_whereis(it));
 666                                 return;
 667                         }
 668                         FOREACH(Weapons, it != WEP_Null && it.netname == s,
 669                         {
 670                                 w_whereis(it);
 671                                 return;
 672                         });
 673                 }
 674                 default:
 675                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 676                 case CMD_REQUEST_USAGE:
 677                 {
 678                         LOG_HELP("Usage:^3 cl_cmd weapon_find weapon");
 679                         LOG_HELP("  Where 'weapon' is the lowercase weapon name, 'all' or 'unowned'.");
 680                         return;
 681                 }
 682         }
 683 }
 684 #endif
 685
 686 #ifdef SVQC
 687 void W_MuzzleFlash_Model_AttachToShotorg(entity actor, .entity weaponentity, entity flash, vector offset)
 688 {
 689         flash.owner = actor;
 690         flash.angles_z = random() * 360;
 691
 692         entity view = actor.(weaponentity);
 693         entity exterior = actor.exteriorweaponentity;
 694
 695         if (view.oldorigin.x > 0)
 696         {
 697                 setattachment(flash, exterior, "");
 698                 setorigin(flash, view.oldorigin + offset);
 699         }
 700         else
 701         {
 702                 if (gettagindex(exterior, "shot")) setattachment(flash, exterior, "shot");
 703                 else setattachment(flash, exterior, "tag_shot");
 704                 setorigin(flash, offset);
 705         }
 706 }
 707 #elif defined(CSQC)
 708 void W_MuzzleFlash_Model_AttachToShotorg(entity wepent, entity flash, vector offset)
 709 {
 710         flash.owner = wepent;
 711         flash.angles_z = random() * 360;
 712
 713         if (gettagindex(wepent, "shot")) setattachment(flash, wepent, "shot");
 714         else setattachment(flash, wepent, "tag_shot");
 715         setorigin(flash, offset);
 716 }
 717 #endif
 718
 719 void W_MuzzleFlash_Model_Think(entity this)
 720 {
 721         this.frame += 2;
 722         this.scale *= 0.5;
 723         this.alpha -= 0.25;
 724         this.nextthink = time + 0.05;
 725
 726         if(this.alpha <= 0)
 727         {
 728                 setthink(this, SUB_Remove);
 729                 this.nextthink = time;
 730                 this.realowner.muzzle_flash = NULL;
 731                 return;
 732         }
 733 }
 734
 735 void W_MuzzleFlash_Model(entity wepent, entity muzzlemodel)
 736 {
 737         if(wepent.muzzle_flash == NULL)
 738                 wepent.muzzle_flash = spawn();
 739
 740         entity flash = wepent.muzzle_flash;
 741         setmodel(flash, muzzlemodel); // precision set below
 742
 743         flash.scale = 0.75;
 744         setthink(flash, W_MuzzleFlash_Model_Think);
 745         flash.nextthink = time + 0.02;
 746         flash.frame = 2;
 747         flash.alpha = 0.75;
 748         flash.angles_z = random() * 180;
 749         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
 750         flash.owner = flash.realowner = wepent;
 751
 752 #ifdef CSQC
 753         flash.drawmask = MASK_NORMAL;
 754 #endif
 755 }
 756
 757 REGISTER_NET_TEMP(w_muzzleflash)
 758
 759 #ifdef SVQC
 760 void W_MuzzleFlash(Weapon thiswep, entity actor, .entity weaponentity, vector shotorg, vector shotdir)
 761 {
 762         // don't show an exterior muzzle effect for the off-hand
 763         if(weaponslot(weaponentity) == 0)
 764         {
 765                 Send_Effect_Except(thiswep.m_muzzleeffect, shotorg, shotdir * 1000, 1, actor);
 766
 767                 if(thiswep.m_muzzlemodel != MDL_Null)
 768                 {
 769                         W_MuzzleFlash_Model(actor.exteriorweaponentity, thiswep.m_muzzlemodel);
 770                         W_MuzzleFlash_Model_AttachToShotorg(actor, weaponentity, actor.exteriorweaponentity.muzzle_flash, '5 0 0');
 771                 }
 772         }
 773
 774         FOREACH_CLIENT(it == actor || (IS_SPEC(it) && it.enemy == actor),
 775         {
 776                 if(!IS_REAL_CLIENT(it))
 777                         continue;
 778                 int channel = MSG_ONE;
 779                 msg_entity = it;
 780                 WriteHeader(channel, w_muzzleflash);
 781                 WriteByte(channel, thiswep.m_id);
 782                 WriteByte(channel, weaponslot(weaponentity));
 783                 WriteVector(channel, shotorg);
 784         });
 785 }
 786 #elif defined(CSQC)
 787 NET_HANDLE(w_muzzleflash, bool isNew)
 788 {
 789         return = true;
 790         int weapon_id = ReadByte();
 791         int slot = ReadByte();
 792         vector sv_shotorg = ReadVector();
 793
 794         Weapon thiswep = REGISTRY_GET(Weapons, weapon_id);
 795         vector viewangles = getpropertyvec(VF_CL_VIEWANGLES);
 796         vector forward, right, up;
 797         MAKE_VECTORS(viewangles, forward, right, up);
 798
 799         if(autocvar_chase_active)
 800         {
 801                 // in third person mode, show the muzzle flash from the server side weapon position
 802                 // we don't have a view model to reference in this case
 803                 pointparticles(thiswep.m_muzzleeffect, sv_shotorg, forward * 1000, 1);
 804                 return;
 805         }
 806         if(!autocvar_r_drawviewmodel) return;
 807
 808         entity wepent = viewmodels[slot];
 809         // get the local player entity to calculate shot origin
 810         entity rlplayer = CSQCModel_server2csqc(player_localentnum - 1);
 811         if(!rlplayer)
 812                 rlplayer = csqcplayer; // fall back to the global
 813
 814         vector md = wepent.movedir_aligned;
 815         vector vecs = ((md.x > 0) ? md : '0 0 0');
 816         vector dv = forward * vecs.x + right * -vecs.y + up * vecs.z;
 817         vector org = rlplayer.origin + rlplayer.view_ofs + dv;
 818
 819         pointparticles(thiswep.m_muzzleeffect, org, forward * 1000, 1);
 820
 821         if(thiswep.m_muzzlemodel != MDL_Null)
 822         {
 823                 W_MuzzleFlash_Model(wepent, thiswep.m_muzzlemodel);
 824                 W_MuzzleFlash_Model_AttachToShotorg(wepent, wepent.muzzle_flash, '5 0 0');
 825         }
 826 }
 827 #endif
 828
 829
 830 #endif
 831
 832 #endif