qcsrc/common/weapons/all.qc

   1 #include "all.qh"
   2 #ifndef WEAPONS_ALL_C
   3 #define WEAPONS_ALL_C
   4
   5 #if defined(CSQC)
   6         #include <client/main.qh>
   7         #include <common/constants.qh>
   8         #include <common/deathtypes/all.qh>
   9         #include <common/physics/movetypes/movetypes.qh>
  10         #include <common/stats.qh>
  11         #include <common/util.qh>
  12         #include <common/weapons/calculations.qc>
  13         #include <common/weapons/weapon/_mod.inc>
  14         #include <lib/csqcmodel/cl_model.qh>
  15         #include <lib/csqcmodel/interpolate.qh>
  16         #include <lib/warpzone/anglestransform.qh>
  17         #include <lib/warpzone/client.qh>
  18         #include <lib/warpzone/common.qh>
  19 #elif defined(MENUQC)
  20         #include <common/weapons/weapon/_mod.inc>
  21 #elif defined(SVQC)
  22         #include <common/constants.qh>
  23         #include <common/deathtypes/all.qh>
  24         #include <common/items/_mod.qh>
  25         #include <common/mapinfo.qh>
  26         #include <common/monsters/_mod.qh>
  27         #include <common/notifications/all.qh>
  28         #include <common/stats.qh>
  29         #include <common/teams.qh>
  30         #include <common/util.qh>
  31         #include <common/weapons/calculations.qc>
  32         #include <common/weapons/config.qc>
  33         #include <common/weapons/config.qh>
  34         #include <common/weapons/weapon/_mod.inc>
  35         #include <lib/csqcmodel/sv_model.qh>
  36         #include <lib/warpzone/anglestransform.qh>
  37         #include <lib/warpzone/common.qh>
  38         #include <lib/warpzone/server.qh>
  39         #include <lib/warpzone/util_server.qh>
  40         #include <server/command/_mod.qh>
  41         #include <server/hook.qh>
  42         #include <server/items/spawning.qh>
  43         #include <server/mutators/_mod.qh>
  44         #include <server/portals.qh>
  45         #include <server/weapons/common.qh>
  46         #include <server/weapons/csqcprojectile.qh>
  47         #include <server/weapons/tracing.qh>
  48 #endif
  49
  50
  51 // WEAPON PLUGIN SYSTEM
  52
  53 WepSet _WepSet_FromWeapon(int a)
  54 {
  55         a -= WEP_FIRST;
  56         if (REGISTRY_MAX(Weapons) > 24)
  57                 if (a >= 24)
  58                 {
  59                         a -= 24;
  60                         if (REGISTRY_MAX(Weapons) > 48)
  61                                 if (a >= 24)
  62                                 {
  63                                         a -= 24;
  64                                         return '0 0 1' * BIT(a);
  65                                 }
  66                         return '0 1 0' * BIT(a);
  67                 }
  68         return '1 0 0' * BIT(a);
  69 }
  70 #ifdef SVQC
  71         void WriteWepSet(float dst, WepSet w)
  72         {
  73                 if (REGISTRY_MAX(Weapons) > 48) WriteInt72_t(dst, w);
  74                 else if (REGISTRY_MAX(Weapons) > 24) WriteInt48_t(dst, w);
  75                 else WriteInt24_t(dst, w.x);
  76         }
  77 #endif
  78 #ifdef CSQC
  79         WepSet WepSet_GetFromStat()
  80         {
  81                 return STAT(WEAPONS);
  82         }
  83         WepSet WepSet_GetFromStat_InMap()
  84         {
  85                 return STAT(WEAPONSINMAP);
  86         }
  87         WepSet ReadWepSet()
  88         {
  89                 if (REGISTRY_MAX(Weapons) > 48) return ReadInt72_t();
  90                 if (REGISTRY_MAX(Weapons) > 24) return ReadInt48_t();
  91                 return ReadInt24_t() * '1 0 0';
  92         }
  93 #endif
  94
  95 string W_FixWeaponOrder(string order, float complete)
  96 {
  97         return fixPriorityList(order, WEP_FIRST, WEP_LAST, WEP_IMPULSE_BEGIN - WEP_FIRST, complete);
  98 }
  99 string W_NameWeaponOrder_MapFunc(string s)
 100 {
 101         int i = stof(s);
 102         if (s == "0" || i)
 103         {
 104                 entity wi = REGISTRY_GET(Weapons, i);
 105                 if (wi != WEP_Null) return wi.netname;
 106         }
 107         return s;
 108 }
 109
 110 string W_UndeprecateName(string s)
 111 {
 112         switch (s)
 113         {
 114                 case "nex": return "vortex";
 115                 case "rocketlauncher": return "devastator";
 116                 case "laser": return "blaster";
 117                 case "minstanex": return "vaporizer";
 118                 case "grenadelauncher": return "mortar";
 119                 case "uzi": return "machinegun";
 120                 case "hmg": return "okhmg";
 121                 case "rpc": return "okrpc";
 122                 default: return s;
 123         }
 124 }
 125 string W_NameWeaponOrder(string order)
 126 {
 127         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
 128 }
 129 string W_NumberWeaponOrder_MapFunc(string s)
 130 {
 131         if (s == "0" || stof(s)) return s;
 132         s = W_UndeprecateName(s);
 133         FOREACH(Weapons, it != WEP_Null && it.netname == s, return ftos(i));
 134         return s;
 135 }
 136 string W_NumberWeaponOrder(string order)
 137 {
 138         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
 139 }
 140
 141 float W_FixWeaponOrder_BuildImpulseList_buf[REGISTRY_MAX(Weapons)];
 142 string W_FixWeaponOrder_BuildImpulseList_order;
 143 void W_FixWeaponOrder_BuildImpulseList_swap(int i, int j, entity pass)
 144 {
 145         float h;
 146         h = W_FixWeaponOrder_BuildImpulseList_buf[i];
 147         W_FixWeaponOrder_BuildImpulseList_buf[i] = W_FixWeaponOrder_BuildImpulseList_buf[j];
 148         W_FixWeaponOrder_BuildImpulseList_buf[j] = h;
 149 }
 150 float W_FixWeaponOrder_BuildImpulseList_cmp(int i, int j, entity pass)
 151 {
 152         int si = W_FixWeaponOrder_BuildImpulseList_buf[i];
 153         Weapon e1 = REGISTRY_GET(Weapons, si);
 154         int sj = W_FixWeaponOrder_BuildImpulseList_buf[j];
 155         Weapon e2 = REGISTRY_GET(Weapons, sj);
 156         int d = (e1.impulse + 9) % 10 - (e2.impulse + 9) % 10;
 157         if (d != 0) return -d;  // high impulse first!
 158         string s = strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " ");
 159         return strstrofs(s, sprintf(" %d ", si), 0)
 160                 - strstrofs(s, sprintf(" %d ", sj), 0); // low char index first!
 161 }
 162 string W_FixWeaponOrder_BuildImpulseList(string o)
 163 {
 164         int i;
 165         W_FixWeaponOrder_BuildImpulseList_order = o;
 166         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 167                 W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST] = i;
 168         heapsort(WEP_LAST - WEP_FIRST + 1, W_FixWeaponOrder_BuildImpulseList_swap, W_FixWeaponOrder_BuildImpulseList_cmp,
 169                 NULL);
 170         o = "";
 171         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 172                 o = strcat(o, " ", ftos(W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST]));
 173         W_FixWeaponOrder_BuildImpulseList_order = string_null;
 174         return substring(o, 1, -1);
 175 }
 176
 177 string W_FixWeaponOrder_AllowIncomplete(entity this, string order)
 178 {
 179         return W_FixWeaponOrder(order, 0);
 180 }
 181
 182 string W_FixWeaponOrder_ForceComplete(string order)
 183 {
 184         if (order == "") order = W_NumberWeaponOrder(cvar_defstring("cl_weaponpriority"));
 185         return W_FixWeaponOrder(order, 1);
 186 }
 187
 188 WepSet W_RandomWeapons(entity e, WepSet remaining, int n)
 189 {
 190         WepSet result = '0 0 0';
 191         for (int j = 0; j < n; ++j)
 192         {
 193                 RandomSelection_Init();
 194                 FOREACH(Weapons, it != WEP_Null, {
 195                         if (remaining & (it.m_wepset))
 196                                 RandomSelection_AddEnt(it, 1, 1);
 197                 });
 198                 Weapon w = RandomSelection_chosen_ent;
 199                 result |= WepSet_FromWeapon(w);
 200                 remaining &= ~WepSet_FromWeapon(w);
 201         }
 202         return result;
 203 }
 204
 205 string GetAmmoPicture(int ammotype)
 206 {
 207         switch (ammotype)
 208         {
 209                 case RES_SHELLS:  return ITEM_Shells.m_icon;
 210                 case RES_BULLETS: return ITEM_Bullets.m_icon;
 211                 case RES_ROCKETS: return ITEM_Rockets.m_icon;
 212                 case RES_CELLS:   return ITEM_Cells.m_icon;
 213                 case RES_PLASMA:  return ITEM_Plasma.m_icon;
 214                 case RES_FUEL:    return ITEM_JetpackFuel.m_icon;
 215                 default: return "";  // wtf, no ammo type?
 216         }
 217 }
 218
 219 string GetAmmoName(int ammotype)
 220 {
 221         switch (ammotype)
 222         {
 223                 case RES_SHELLS:  return ITEM_Shells.m_name;
 224                 case RES_BULLETS: return ITEM_Bullets.m_name;
 225                 case RES_ROCKETS: return ITEM_Rockets.m_name;
 226                 case RES_CELLS:   return ITEM_Cells.m_name;
 227                 case RES_PLASMA:  return ITEM_Plasma.m_name;
 228                 case RES_FUEL:    return ITEM_JetpackFuel.m_name;
 229                 default:          return "batteries";
 230         }
 231 }
 232
 233 #ifdef CSQC
 234 int GetAmmoTypeFromNum(int i)
 235 {
 236         switch (i)
 237         {
 238                 case 0: return RES_SHELLS;
 239                 case 1: return RES_BULLETS;
 240                 case 2: return RES_ROCKETS;
 241                 case 3: return RES_CELLS;
 242                 case 4: return RES_PLASMA;
 243                 case 5: return RES_FUEL;
 244                 default: return RES_NONE;
 245         }
 246 }
 247
 248 int GetAmmoStat(int ammotype)
 249 {
 250         switch (ammotype)
 251         {
 252                 case RES_SHELLS: return STAT_SHELLS;
 253                 case RES_BULLETS: return STAT_NAILS;
 254                 case RES_ROCKETS: return STAT_ROCKETS;
 255                 case RES_CELLS: return STAT_CELLS;
 256                 case RES_PLASMA: return STAT_PLASMA.m_id;
 257                 case RES_FUEL: return STAT_FUEL.m_id;
 258                 default: return -1;
 259         }
 260 }
 261 #endif
 262
 263 string W_Sound(string w_snd)
 264 {
 265         string output = strcat("weapons/", w_snd);
 266         MUTATOR_CALLHOOK(WeaponSound, w_snd, output);
 267         return M_ARGV(1, string);
 268 }
 269
 270 string W_Model(string w_mdl)
 271 {
 272         string output = strcat("models/weapons/", w_mdl);
 273         MUTATOR_CALLHOOK(WeaponModel, w_mdl, output);
 274         return M_ARGV(1, string);
 275 }
 276
 277 #ifdef GAMEQC
 278 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
 279 {
 280         switch (algn)
 281         {
 282                 default:
 283                 case 3:
 284                         // right alignment
 285                         break;
 286                 case 4:
 287                         // left
 288                         vecs.y = -vecs.y;
 289                         break;
 290                 case 1:
 291                 case 2:
 292                         // center
 293                         vecs.y = 0;
 294                         vecs.z -= 2;
 295                         break;
 296         }
 297         return vecs;
 298 }
 299
 300 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn)
 301 {
 302         string s;
 303         if (visual)
 304         {
 305                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 306         }
 307         else if (STAT(SHOOTFROMEYE))
 308         {
 309                 vecs.y = vecs.z = 0;
 310         }
 311         else if (STAT(SHOOTFROMCENTER))
 312         {
 313                 vecs.y = 0;
 314                 vecs.z -= 2;
 315         }
 316         else if ((s = G_SHOOTFROMFIXEDORIGIN) != "")
 317         {
 318                 vector v = stov(s);
 319                 if (y_is_right) v.y = -v.y;
 320                 if (v.x != 0) vecs.x = v.x;
 321                 vecs.y = v.y;
 322                 vecs.z = v.z;
 323         }
 324         else  // just do the same as top
 325         {
 326                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 327         }
 328
 329         return vecs;
 330 }
 331
 332 #define shotorg_adjust shotorg_adjust_values
 333
 334 /**
 335  * supported formats:
 336  *
 337  * 1. simple animated model, muzzle flash handling on h_ model:
 338  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 339  *      tags:
 340  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 341  *        shell = casings ejection point (must be on the right hand side of the gun)
 342  *        weapon = attachment for v_tuba.md3
 343  *    v_tuba.md3 - first and third person model
 344  *    g_tuba.md3 - pickup model
 345  *
 346  * 2. simple animated model, muzzle flash handling on v_ model:
 347  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 348  *      tags:
 349  *        weapon = attachment for v_tuba.md3
 350  *    v_tuba.md3 - first and third person model
 351  *      tags:
 352  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 353  *        shell = casings ejection point (must be on the right hand side of the gun)
 354  *    g_tuba.md3 - pickup model
 355  *
 356  * 3. fully animated model, muzzle flash handling on h_ model:
 357  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 358  *      tags:
 359  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 360  *        shell = casings ejection point (must be on the right hand side of the gun)
 361  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 362  *    v_tuba.md3 - third person model
 363  *    g_tuba.md3 - pickup model
 364  *
 365  * 4. fully animated model, muzzle flash handling on v_ model:
 366  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 367  *      tags:
 368  *        shot = muzzle end (shot origin)
 369  *        shell = casings ejection point (must be on the right hand side of the gun)
 370  *    v_tuba.md3 - third person model
 371  *      tags:
 372  *        shot = muzzle end (for muzzle flashes)
 373  *    g_tuba.md3 - pickup model
 374  *
 375  * writes:
 376  *   this.origin, this.angles
 377  *   this.weaponchild
 378  *   this.movedir, this.view_ofs, this.movedir_aligned
 379  *   attachment stuff
 380  *   anim stuff
 381  * to free:
 382  *   call again with ""
 383  *   remove the ent
 384  */
 385 void CL_WeaponEntity_SetModel(entity this, string name, bool _anim)
 386 {
 387         if (name == "")
 388         {
 389                 vector oldmin = this.mins, oldmax = this.maxs;
 390                 setmodel(this, MDL_Null);
 391                 setsize(this, oldmin, oldmax);
 392                 if (this.weaponchild) delete(this.weaponchild);
 393                 this.weaponchild = NULL;
 394                 this.movedir = '0 0 0';
 395                 this.spawnorigin = '0 0 0';
 396                 this.oldorigin = '0 0 0';
 397                 this.anim_fire1  = '0 1 0.01';
 398                 this.anim_fire2  = '0 1 0.01';
 399                 this.anim_idle   = '0 1 0.01';
 400                 this.anim_reload = '0 1 0.01';
 401         }
 402         else
 403         {
 404                 // if there is a child entity, hide it until we're sure we use it
 405                 if (this.weaponchild) this.weaponchild.model = "";
 406                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
 407                 int v_shot_idx;  // used later
 408                 (v_shot_idx = gettagindex(this, "shot")) || (v_shot_idx = gettagindex(this, "tag_shot"));
 409
 410                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
 411                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 412                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
 413                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
 414                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
 415                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
 416
 417                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 418                 // if we don't, this is a "real" animated model
 419                 string t;
 420                 if ((t = "weapon", gettagindex(this, t)) || (t = "tag_weapon", gettagindex(this, t)))
 421                 {
 422                         if (!this.weaponchild)
 423                         {
 424                                 this.weaponchild = new(weaponchild);
 425 #ifdef CSQC
 426                                 this.weaponchild.drawmask = MASK_NORMAL;
 427                                 this.weaponchild.renderflags |= RF_VIEWMODEL;
 428 #endif
 429                         }
 430                         _setmodel(this.weaponchild, W_Model(strcat("v_", name, ".md3")));
 431                         setsize(this.weaponchild, '0 0 0', '0 0 0');
 432                         setattachment(this.weaponchild, this, t);
 433                 }
 434                 else
 435                 {
 436                         if (this.weaponchild) delete(this.weaponchild);
 437                         this.weaponchild = NULL;
 438                 }
 439
 440                 setsize(this, '0 0 0', '0 0 0');
 441                 setorigin(this, '0 0 0');
 442                 this.angles = '0 0 0';
 443                 this.frame = 0;
 444 #ifdef SVQC
 445                 this.viewmodelforclient = NULL;
 446 #else
 447                 this.renderflags &= ~RF_VIEWMODEL;
 448 #endif
 449                 if (v_shot_idx)  // v_ model attached to invisible h_ model
 450                 {
 451                         this.movedir = gettaginfo(this.weaponchild, v_shot_idx);
 452                 }
 453                 else
 454                 {
 455                         int idx;
 456                         if ((idx = gettagindex(this, "shot")) || (idx = gettagindex(this, "tag_shot")))
 457                         {
 458                                 this.movedir = gettaginfo(this, idx);
 459                         }
 460                         else
 461                         {
 462                                 LOG_WARNF("weapon model %s does not support the 'shot' tag, will display shots TOTALLY wrong",
 463                                         this.model);
 464                                 this.movedir = '0 0 0';
 465                         }
 466                 }
 467                 {
 468                         int idx = 0;
 469                         // v_ model attached to invisible h_ model
 470                         if (this.weaponchild
 471                                 && ((idx = gettagindex(this.weaponchild, "shell")) || (idx = gettagindex(this.weaponchild, "tag_shell"))))
 472                         {
 473                                 this.spawnorigin = gettaginfo(this.weaponchild, idx);
 474                         }
 475                         else if ((idx = gettagindex(this, "shell")) || (idx = gettagindex(this, "tag_shell")))
 476                         {
 477                                 this.spawnorigin = gettaginfo(this, idx);
 478                         }
 479                         else
 480                         {
 481                                 LOG_WARNF("weapon model %s does not support the 'shell' tag, will display casings wrong",
 482                                         this.model);
 483                                 this.spawnorigin = this.movedir;
 484                         }
 485                 }
 486                 if (v_shot_idx)
 487                 {
 488                         this.oldorigin = '0 0 0';  // use regular attachment
 489                 }
 490                 else
 491                 {
 492                         int idx;
 493                         if (this.weaponchild)
 494                                 (idx = gettagindex(this, "weapon")) || (idx = gettagindex(this, "tag_weapon"));
 495                         else
 496                                 (idx = gettagindex(this, "handle")) || (idx = gettagindex(this, "tag_handle"));
 497                         if (idx)
 498                         {
 499                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
 500                         }
 501                         else
 502                         {
 503                                 LOG_WARNF(
 504                                         "weapon model %s does not support the 'handle' tag "
 505                                         "and neither does the v_ model support the 'shot' tag, "
 506                                         "will display muzzle flashes TOTALLY wrong\n",
 507                                         this.model);
 508                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
 509                         }
 510                 }
 511
 512 #ifdef SVQC
 513                 this.viewmodelforclient = this.owner;
 514 #else
 515                 this.renderflags |= RF_VIEWMODEL;
 516 #endif
 517         }
 518
 519         this.view_ofs = '0 0 0';
 520         this.movedir_aligned = this.movedir;
 521
 522         if (this.movedir.x >= 0)
 523         {
 524                 //int algn = STAT(GUNALIGN, this.owner);
 525                 int algn = W_GunAlign(this, STAT(GUNALIGN, this.owner));
 526         #ifdef SVQC
 527                 this.m_gunalign = algn;
 528         #endif
 529                 vector v = this.movedir;
 530                 this.movedir = shotorg_adjust(v, false, false, algn);
 531                 this.movedir_aligned = shotorg_adjust(v, false, true, algn);
 532                 this.view_ofs = shotorg_adjust(v, false, true, algn) - v;
 533         }
 534         int compressed_shotorg = compressShotOrigin(this.movedir);
 535         // make them match perfectly
 536 #ifdef SVQC
 537         // null during init
 538         if (this.owner) STAT(SHOTORG, this.owner) = compressed_shotorg;
 539 #endif
 540         this.movedir = decompressShotOrigin(compressed_shotorg);
 541
 542         this.spawnorigin += this.view_ofs;  // offset the casings origin by the same amount
 543
 544         // check if an instant weapon switch occurred
 545         setorigin(this, this.view_ofs);
 546         if (!_anim) return;
 547         // reset animstate now
 548         this.wframe = WFRAME_IDLE;
 549         setanim(this, this.anim_idle, true, false, true);
 550 }
 551 #endif
 552
 553 #ifdef GAMEQC
 554
 555 REGISTER_NET_TEMP(wframe)
 556 #ifdef CSQC
 557 NET_HANDLE(wframe, bool isNew)
 558 {
 559         WFRAME fr = ReadByte();
 560         float t = ReadFloat();
 561         int slot = ReadByte();
 562         bool restartanim = ReadByte();
 563         entity wepent = viewmodels[slot];
 564         if(fr == WFRAME_IDLE)
 565                 wepent.animstate_looping = false; // we don't need to enforce idle animation
 566         else
 567         {
 568                 vector a = '0 0 0';
 569                 switch(fr)
 570                 {
 571                         default:
 572                         case WFRAME_IDLE: a = wepent.anim_idle; break;
 573                         case WFRAME_FIRE1: a = wepent.anim_fire1; break;
 574                         case WFRAME_FIRE2: a = wepent.anim_fire2; break;
 575                         case WFRAME_RELOAD: a = wepent.anim_reload; break;
 576                 }
 577                 a.z *= t;
 578                 anim_set(wepent, a, !restartanim, restartanim, restartanim);
 579         }
 580         wepent.state = ReadByte();
 581         wepent.weapon_nextthink = ReadFloat();
 582         switch (wepent.state)
 583         {
 584                 case WS_RAISE:
 585                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_raise;
 586                         break;
 587                 case WS_DROP:
 588                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_drop;
 589                         break;
 590                 default:
 591                         wepent.weapon_switchdelay = 0;
 592                         break;
 593         }
 594         return true;
 595 }
 596 #endif
 597
 598 #ifdef SVQC
 599 void wframe_send(entity actor, entity weaponentity, int wepframe, float attackrate, bool restartanim)
 600 {
 601         if (!IS_REAL_CLIENT(actor)) return;
 602         int channel = MSG_ONE;
 603         msg_entity = actor;
 604         WriteHeader(channel, wframe);
 605         WriteByte(channel, wepframe);
 606         WriteFloat(channel, attackrate);
 607         WriteByte(channel, weaponslot(weaponentity.weaponentity_fld));
 608         WriteByte(channel, restartanim);
 609         WriteByte(channel, weaponentity.state);
 610         WriteFloat(channel, weaponentity.weapon_nextthink);
 611 }
 612 #endif
 613
 614 REGISTER_NET_C2S(w_whereis)
 615 #ifdef SVQC
 616 void Weapon_whereis(Weapon this, entity cl);
 617 NET_HANDLE(w_whereis, bool)
 618 {
 619         Weapon wpn = ReadRegistered(Weapons);
 620         if (wpn != WEP_Null) Weapon_whereis(wpn, sender);
 621         return true;
 622 }
 623 #else
 624 void w_whereis(Weapon this)
 625 {
 626         int channel = MSG_C2S;
 627         WriteHeader(channel, w_whereis);
 628         WriteRegistered(Weapons, channel, this);
 629 }
 630 CLIENT_COMMAND(weapon_find, "Show spawn locations of a weapon")
 631 {
 632         switch (request)
 633         {
 634                 case CMD_REQUEST_COMMAND:
 635                 {
 636                         string s = argv(1);
 637                         if (s == "all")
 638                         {
 639                                 FOREACH(Weapons, it != WEP_Null, w_whereis(it));
 640                                 return;
 641                         }
 642                         if (s == "unowned")
 643                         {
 644                                 FOREACH(Weapons, it != WEP_Null && !(STAT(WEAPONS) & it.m_wepset), w_whereis(it));
 645                                 return;
 646                         }
 647                         FOREACH(Weapons, it != WEP_Null && it.netname == s,
 648                         {
 649                                 w_whereis(it);
 650                                 return;
 651                         });
 652                 }
 653                 default:
 654                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 655                 case CMD_REQUEST_USAGE:
 656                 {
 657                         LOG_HELP("Usage:^3 cl_cmd weapon_find <weapon>");
 658                         LOG_HELP("  Where <weapon> is the lowercase weapon name, 'all' or 'unowned'.");
 659                         return;
 660                 }
 661         }
 662 }
 663 #endif
 664
 665 #ifdef SVQC
 666 void W_MuzzleFlash_Model_AttachToShotorg(entity actor, .entity weaponentity, entity flash, vector offset)
 667 {
 668         flash.owner = actor;
 669         flash.angles_z = random() * 360;
 670
 671         entity view = actor.(weaponentity);
 672         entity exterior = actor.exteriorweaponentity;
 673
 674         if (view.oldorigin.x > 0)
 675         {
 676                 setattachment(flash, exterior, "");
 677                 setorigin(flash, view.oldorigin + offset);
 678         }
 679         else
 680         {
 681                 if (gettagindex(exterior, "shot")) setattachment(flash, exterior, "shot");
 682                 else setattachment(flash, exterior, "tag_shot");
 683                 setorigin(flash, offset);
 684         }
 685 }
 686 #elif defined(CSQC)
 687 void W_MuzzleFlash_Model_AttachToShotorg(entity wepent, entity flash, vector offset)
 688 {
 689         flash.owner = wepent;
 690         flash.angles_z = random() * 360;
 691
 692         if (gettagindex(wepent, "shot")) setattachment(flash, wepent, "shot");
 693         else setattachment(flash, wepent, "tag_shot");
 694         setorigin(flash, offset);
 695 }
 696 #endif
 697
 698 void W_MuzzleFlash_Model_Think(entity this)
 699 {
 700         this.frame += 2;
 701         this.scale *= 0.5;
 702         this.alpha -= 0.25;
 703         this.nextthink = time + 0.05;
 704
 705         if(this.alpha <= 0)
 706         {
 707                 setthink(this, SUB_Remove);
 708                 this.nextthink = time;
 709                 this.realowner.muzzle_flash = NULL;
 710                 return;
 711         }
 712 }
 713
 714 void W_MuzzleFlash_Model(entity wepent, entity muzzlemodel)
 715 {
 716         if(wepent.muzzle_flash == NULL)
 717                 wepent.muzzle_flash = spawn();
 718
 719         entity flash = wepent.muzzle_flash;
 720         setmodel(flash, muzzlemodel); // precision set below
 721
 722         flash.scale = 0.75;
 723         setthink(flash, W_MuzzleFlash_Model_Think);
 724         flash.nextthink = time + 0.02;
 725         flash.frame = 2;
 726         flash.alpha = 0.75;
 727         flash.angles_z = random() * 180;
 728         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
 729         flash.owner = flash.realowner = wepent;
 730
 731 #ifdef CSQC
 732         flash.drawmask = MASK_NORMAL;
 733 #endif
 734 }
 735
 736 REGISTER_NET_TEMP(w_muzzleflash)
 737
 738 #ifdef SVQC
 739 void W_MuzzleFlash(Weapon thiswep, entity actor, .entity weaponentity, vector shotorg, vector shotdir)
 740 {
 741         // don't show an exterior muzzle effect for the off-hand
 742         if(weaponslot(weaponentity) == 0)
 743         {
 744                 Send_Effect_Except(thiswep.m_muzzleeffect, shotorg, shotdir * 1000, 1, actor);
 745
 746                 if(thiswep.m_muzzlemodel != MDL_Null)
 747                 {
 748                         W_MuzzleFlash_Model(actor.exteriorweaponentity, thiswep.m_muzzlemodel);
 749                         W_MuzzleFlash_Model_AttachToShotorg(actor, weaponentity, actor.exteriorweaponentity.muzzle_flash, '5 0 0');
 750                 }
 751         }
 752
 753         FOREACH_CLIENT(it == actor || (IS_SPEC(it) && it.enemy == actor),
 754         {
 755                 if(!IS_REAL_CLIENT(it))
 756                         continue;
 757                 int channel = MSG_ONE;
 758                 msg_entity = it;
 759                 WriteHeader(channel, w_muzzleflash);
 760                 WriteByte(channel, thiswep.m_id);
 761                 WriteByte(channel, weaponslot(weaponentity));
 762                 WriteVector(channel, shotorg);
 763         });
 764 }
 765 #elif defined(CSQC)
 766 NET_HANDLE(w_muzzleflash, bool isNew)
 767 {
 768         return = true;
 769         int weapon_id = ReadByte();
 770         int slot = ReadByte();
 771         vector sv_shotorg = ReadVector();
 772
 773         Weapon thiswep = REGISTRY_GET(Weapons, weapon_id);
 774         vector viewangles = getpropertyvec(VF_CL_VIEWANGLES);
 775         vector forward, right, up;
 776         MAKE_VECTORS(viewangles, forward, right, up);
 777
 778         if(autocvar_chase_active)
 779         {
 780                 // in third person mode, show the muzzle flash from the server side weapon position
 781                 // we don't have a view model to reference in this case
 782                 pointparticles(thiswep.m_muzzleeffect, sv_shotorg, forward * 1000, 1);
 783                 return;
 784         }
 785         if(!autocvar_r_drawviewmodel) return;
 786
 787         entity wepent = viewmodels[slot];
 788         // get the local player entity to calculate shot origin
 789         entity rlplayer = CSQCModel_server2csqc(player_localentnum - 1);
 790         if(!rlplayer)
 791                 rlplayer = csqcplayer; // fall back to the global
 792
 793         vector md = wepent.movedir_aligned;
 794         vector vecs = ((md.x > 0) ? md : '0 0 0');
 795         vector dv = forward * vecs.x + right * -vecs.y + up * vecs.z;
 796         vector org = rlplayer.origin + rlplayer.view_ofs + dv;
 797
 798         pointparticles(thiswep.m_muzzleeffect, org, forward * 1000, 1);
 799
 800         if(thiswep.m_muzzlemodel != MDL_Null)
 801         {
 802                 W_MuzzleFlash_Model(wepent, thiswep.m_muzzlemodel);
 803                 W_MuzzleFlash_Model_AttachToShotorg(wepent, wepent.muzzle_flash, '5 0 0');
 804         }
 805 }
 806 #endif
 807
 808
 809 #endif
 810
 811 #endif