qcsrc/common/weapons/all.qc

   1 #include "all.qh"
   2 #ifndef WEAPONS_ALL_C
   3 #define WEAPONS_ALL_C
   4
   5 #if defined(CSQC)
   6         #include <client/autocvars.qh>
   7         #include <client/main.qh>
   8         #include <common/constants.qh>
   9         #include <common/deathtypes/all.qh>
  10         #include <common/physics/movetypes/movetypes.qh>
  11         #include <common/stats.qh>
  12         #include <common/util.qh>
  13         #include <common/weapons/calculations.qc>
  14         #include <common/weapons/weapon/_mod.inc>
  15         #include <lib/csqcmodel/cl_model.qh>
  16         #include <lib/csqcmodel/interpolate.qh>
  17         #include <lib/warpzone/anglestransform.qh>
  18         #include <lib/warpzone/client.qh>
  19         #include <lib/warpzone/common.qh>
  20 #elif defined(MENUQC)
  21         #include <common/weapons/weapon/_mod.inc>
  22 #elif defined(SVQC)
  23         #include <common/constants.qh>
  24         #include <common/deathtypes/all.qh>
  25         #include <common/items/_mod.qh>
  26         #include <common/mapinfo.qh>
  27         #include <common/monsters/_mod.qh>
  28         #include <common/notifications/all.qh>
  29         #include <common/stats.qh>
  30         #include <common/teams.qh>
  31         #include <common/util.qh>
  32         #include <common/weapons/calculations.qc>
  33         #include <common/weapons/config.qc>
  34         #include <common/weapons/config.qh>
  35         #include <common/weapons/weapon/_mod.inc>
  36         #include <lib/csqcmodel/sv_model.qh>
  37         #include <lib/warpzone/anglestransform.qh>
  38         #include <lib/warpzone/common.qh>
  39         #include <lib/warpzone/server.qh>
  40         #include <lib/warpzone/util_server.qh>
  41         #include <server/autocvars.qh>
  42         #include <server/command/_mod.qh>
  43         #include <server/hook.qh>
  44         #include <server/items/spawning.qh>
  45         #include <server/mutators/_mod.qh>
  46         #include <server/portals.qh>
  47         #include <server/weapons/common.qh>
  48         #include <server/weapons/csqcprojectile.qh>
  49         #include <server/weapons/tracing.qh>
  50 #endif
  51
  52
  53 // WEAPON PLUGIN SYSTEM
  54
  55 WepSet _WepSet_FromWeapon(int a)
  56 {
  57         a -= WEP_FIRST;
  58         if (REGISTRY_MAX(Weapons) > 24)
  59                 if (a >= 24)
  60                 {
  61                         a -= 24;
  62                         if (REGISTRY_MAX(Weapons) > 48)
  63                                 if (a >= 24)
  64                                 {
  65                                         a -= 24;
  66                                         return '0 0 1' * (2 ** a);
  67                                 }
  68                         return '0 1 0' * (2 ** a);
  69                 }
  70         return '1 0 0' * (2 ** a);
  71 }
  72 #ifdef SVQC
  73         void WriteWepSet(float dst, WepSet w)
  74         {
  75                 if (REGISTRY_MAX(Weapons) > 48) WriteInt72_t(dst, w);
  76                 else if (REGISTRY_MAX(Weapons) > 24) WriteInt48_t(dst, w);
  77                 else WriteInt24_t(dst, w.x);
  78         }
  79 #endif
  80 #ifdef CSQC
  81         WepSet WepSet_GetFromStat()
  82         {
  83                 return STAT(WEAPONS);
  84         }
  85         WepSet WepSet_GetFromStat_InMap()
  86         {
  87                 return STAT(WEAPONSINMAP);
  88         }
  89         WepSet ReadWepSet()
  90         {
  91                 if (REGISTRY_MAX(Weapons) > 48) return ReadInt72_t();
  92                 if (REGISTRY_MAX(Weapons) > 24) return ReadInt48_t();
  93                 return ReadInt24_t() * '1 0 0';
  94         }
  95 #endif
  96
  97 string W_FixWeaponOrder(string order, float complete)
  98 {
  99         return fixPriorityList(order, WEP_FIRST, WEP_LAST, WEP_IMPULSE_BEGIN - WEP_FIRST, complete);
 100 }
 101 string W_NameWeaponOrder_MapFunc(string s)
 102 {
 103         int i = stof(s);
 104         if (s == "0" || i)
 105         {
 106                 entity wi = REGISTRY_GET(Weapons, i);
 107                 if (wi != WEP_Null) return wi.netname;
 108         }
 109         return s;
 110 }
 111
 112 string W_UndeprecateName(string s)
 113 {
 114         switch (s)
 115         {
 116                 case "nex": return "vortex";
 117                 case "rocketlauncher": return "devastator";
 118                 case "laser": return "blaster";
 119                 case "minstanex": return "vaporizer";
 120                 case "grenadelauncher": return "mortar";
 121                 case "uzi": return "machinegun";
 122                 case "hmg": return "okhmg";
 123                 case "rpc": return "okrpc";
 124                 default: return s;
 125         }
 126 }
 127 string W_NameWeaponOrder(string order)
 128 {
 129         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
 130 }
 131 string W_NumberWeaponOrder_MapFunc(string s)
 132 {
 133         if (s == "0" || stof(s)) return s;
 134         s = W_UndeprecateName(s);
 135         FOREACH(Weapons, it != WEP_Null && it.netname == s, return ftos(i));
 136         return s;
 137 }
 138 string W_NumberWeaponOrder(string order)
 139 {
 140         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
 141 }
 142
 143 float W_FixWeaponOrder_BuildImpulseList_buf[REGISTRY_MAX(Weapons)];
 144 string W_FixWeaponOrder_BuildImpulseList_order;
 145 void W_FixWeaponOrder_BuildImpulseList_swap(int i, int j, entity pass)
 146 {
 147         float h;
 148         h = W_FixWeaponOrder_BuildImpulseList_buf[i];
 149         W_FixWeaponOrder_BuildImpulseList_buf[i] = W_FixWeaponOrder_BuildImpulseList_buf[j];
 150         W_FixWeaponOrder_BuildImpulseList_buf[j] = h;
 151 }
 152 float W_FixWeaponOrder_BuildImpulseList_cmp(int i, int j, entity pass)
 153 {
 154         int si = W_FixWeaponOrder_BuildImpulseList_buf[i];
 155         Weapon e1 = REGISTRY_GET(Weapons, si);
 156         int sj = W_FixWeaponOrder_BuildImpulseList_buf[j];
 157         Weapon e2 = REGISTRY_GET(Weapons, sj);
 158         int d = (e1.impulse + 9) % 10 - (e2.impulse + 9) % 10;
 159         if (d != 0) return -d;  // high impulse first!
 160         string s = strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " ");
 161         return strstrofs(s, sprintf(" %d ", si), 0)
 162                 - strstrofs(s, sprintf(" %d ", sj), 0); // low char index first!
 163 }
 164 string W_FixWeaponOrder_BuildImpulseList(string o)
 165 {
 166         int i;
 167         W_FixWeaponOrder_BuildImpulseList_order = o;
 168         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 169                 W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST] = i;
 170         heapsort(WEP_LAST - WEP_FIRST + 1, W_FixWeaponOrder_BuildImpulseList_swap, W_FixWeaponOrder_BuildImpulseList_cmp,
 171                 NULL);
 172         o = "";
 173         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 174                 o = strcat(o, " ", ftos(W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST]));
 175         W_FixWeaponOrder_BuildImpulseList_order = string_null;
 176         return substring(o, 1, -1);
 177 }
 178
 179 string W_FixWeaponOrder_AllowIncomplete(entity this, string order)
 180 {
 181         return W_FixWeaponOrder(order, 0);
 182 }
 183
 184 string W_FixWeaponOrder_ForceComplete(string order)
 185 {
 186         if (order == "") order = W_NumberWeaponOrder(cvar_defstring("cl_weaponpriority"));
 187         return W_FixWeaponOrder(order, 1);
 188 }
 189
 190 WepSet W_RandomWeapons(entity e, WepSet remaining, int n)
 191 {
 192         WepSet result = '0 0 0';
 193         for (int j = 0; j < n; ++j)
 194         {
 195                 RandomSelection_Init();
 196                 FOREACH(Weapons, it != WEP_Null, {
 197                         if (remaining & (it.m_wepset))
 198                                 RandomSelection_AddEnt(it, 1, 1);
 199                 });
 200                 Weapon w = RandomSelection_chosen_ent;
 201                 result |= WepSet_FromWeapon(w);
 202                 remaining &= ~WepSet_FromWeapon(w);
 203         }
 204         return result;
 205 }
 206
 207 string GetAmmoPicture(int ammotype)
 208 {
 209         switch (ammotype)
 210         {
 211                 case RES_SHELLS:  return ITEM_Shells.m_icon;
 212                 case RES_BULLETS: return ITEM_Bullets.m_icon;
 213                 case RES_ROCKETS: return ITEM_Rockets.m_icon;
 214                 case RES_CELLS:   return ITEM_Cells.m_icon;
 215                 case RES_PLASMA:  return ITEM_Plasma.m_icon;
 216                 case RES_FUEL:    return ITEM_JetpackFuel.m_icon;
 217                 default: return "";  // wtf, no ammo type?
 218         }
 219 }
 220
 221 string GetAmmoName(int ammotype)
 222 {
 223         switch (ammotype)
 224         {
 225                 case RES_SHELLS:  return ITEM_Shells.m_name;
 226                 case RES_BULLETS: return ITEM_Bullets.m_name;
 227                 case RES_ROCKETS: return ITEM_Rockets.m_name;
 228                 case RES_CELLS:   return ITEM_Cells.m_name;
 229                 case RES_PLASMA:  return ITEM_Plasma.m_name;
 230                 case RES_FUEL:    return ITEM_JetpackFuel.m_name;
 231                 default:          return "batteries";
 232         }
 233 }
 234
 235 #ifdef CSQC
 236 int GetAmmoTypeFromNum(int i)
 237 {
 238         switch (i)
 239         {
 240                 case 0: return RES_SHELLS;
 241                 case 1: return RES_BULLETS;
 242                 case 2: return RES_ROCKETS;
 243                 case 3: return RES_CELLS;
 244                 case 4: return RES_PLASMA;
 245                 case 5: return RES_FUEL;
 246                 default: return RES_NONE;
 247         }
 248 }
 249
 250 int GetAmmoStat(int ammotype)
 251 {
 252         switch (ammotype)
 253         {
 254                 case RES_SHELLS: return STAT_SHELLS;
 255                 case RES_BULLETS: return STAT_NAILS;
 256                 case RES_ROCKETS: return STAT_ROCKETS;
 257                 case RES_CELLS: return STAT_CELLS;
 258                 case RES_PLASMA: return STAT_PLASMA.m_id;
 259                 case RES_FUEL: return STAT_FUEL.m_id;
 260                 default: return -1;
 261         }
 262 }
 263 #endif
 264
 265 string W_Sound(string w_snd)
 266 {
 267         string output = strcat("weapons/", w_snd);
 268         MUTATOR_CALLHOOK(WeaponSound, w_snd, output);
 269         return M_ARGV(1, string);
 270 }
 271
 272 string W_Model(string w_mdl)
 273 {
 274         string output = strcat("models/weapons/", w_mdl);
 275         MUTATOR_CALLHOOK(WeaponModel, w_mdl, output);
 276         return M_ARGV(1, string);
 277 }
 278
 279 #ifdef GAMEQC
 280 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
 281 {
 282         switch (algn)
 283         {
 284                 default:
 285                 case 3:
 286                         // right alignment
 287                         break;
 288                 case 4:
 289                         // left
 290                         vecs.y = -vecs.y;
 291                         break;
 292                 case 1:
 293                 case 2:
 294                         // center
 295                         vecs.y = 0;
 296                         vecs.z -= 2;
 297                         break;
 298         }
 299         return vecs;
 300 }
 301
 302 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn)
 303 {
 304         string s;
 305         if (visual)
 306         {
 307                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 308         }
 309         else if (STAT(SHOOTFROMEYE))
 310         {
 311                 vecs.y = vecs.z = 0;
 312         }
 313         else if (STAT(SHOOTFROMCENTER))
 314         {
 315                 vecs.y = 0;
 316                 vecs.z -= 2;
 317         }
 318         else if ((s = G_SHOOTFROMFIXEDORIGIN) != "")
 319         {
 320                 vector v = stov(s);
 321                 if (y_is_right) v.y = -v.y;
 322                 if (v.x != 0) vecs.x = v.x;
 323                 vecs.y = v.y;
 324                 vecs.z = v.z;
 325         }
 326         else  // just do the same as top
 327         {
 328                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 329         }
 330
 331         return vecs;
 332 }
 333
 334 #define shotorg_adjust shotorg_adjust_values
 335
 336 /**
 337  * supported formats:
 338  *
 339  * 1. simple animated model, muzzle flash handling on h_ model:
 340  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 341  *      tags:
 342  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 343  *        shell = casings ejection point (must be on the right hand side of the gun)
 344  *        weapon = attachment for v_tuba.md3
 345  *    v_tuba.md3 - first and third person model
 346  *    g_tuba.md3 - pickup model
 347  *
 348  * 2. simple animated model, muzzle flash handling on v_ model:
 349  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 350  *      tags:
 351  *        weapon = attachment for v_tuba.md3
 352  *    v_tuba.md3 - first and third person model
 353  *      tags:
 354  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 355  *        shell = casings ejection point (must be on the right hand side of the gun)
 356  *    g_tuba.md3 - pickup model
 357  *
 358  * 3. fully animated model, muzzle flash handling on h_ model:
 359  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 360  *      tags:
 361  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 362  *        shell = casings ejection point (must be on the right hand side of the gun)
 363  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 364  *    v_tuba.md3 - third person model
 365  *    g_tuba.md3 - pickup model
 366  *
 367  * 4. fully animated model, muzzle flash handling on v_ model:
 368  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 369  *      tags:
 370  *        shot = muzzle end (shot origin)
 371  *        shell = casings ejection point (must be on the right hand side of the gun)
 372  *    v_tuba.md3 - third person model
 373  *      tags:
 374  *        shot = muzzle end (for muzzle flashes)
 375  *    g_tuba.md3 - pickup model
 376  *
 377  * writes:
 378  *   this.origin, this.angles
 379  *   this.weaponchild
 380  *   this.movedir, this.view_ofs, this.movedir_aligned
 381  *   attachment stuff
 382  *   anim stuff
 383  * to free:
 384  *   call again with ""
 385  *   remove the ent
 386  */
 387 void CL_WeaponEntity_SetModel(entity this, string name, bool _anim)
 388 {
 389         if (name == "")
 390         {
 391                 vector oldmin = this.mins, oldmax = this.maxs;
 392                 setmodel(this, MDL_Null);
 393                 setsize(this, oldmin, oldmax);
 394                 if (this.weaponchild) delete(this.weaponchild);
 395                 this.weaponchild = NULL;
 396                 this.movedir = '0 0 0';
 397                 this.spawnorigin = '0 0 0';
 398                 this.oldorigin = '0 0 0';
 399                 this.anim_fire1  = '0 1 0.01';
 400                 this.anim_fire2  = '0 1 0.01';
 401                 this.anim_idle   = '0 1 0.01';
 402                 this.anim_reload = '0 1 0.01';
 403         }
 404         else
 405         {
 406                 // if there is a child entity, hide it until we're sure we use it
 407                 if (this.weaponchild) this.weaponchild.model = "";
 408                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
 409                 int v_shot_idx;  // used later
 410                 (v_shot_idx = gettagindex(this, "shot")) || (v_shot_idx = gettagindex(this, "tag_shot"));
 411
 412                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
 413                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 414                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
 415                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
 416                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
 417                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
 418
 419                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 420                 // if we don't, this is a "real" animated model
 421                 string t;
 422                 if ((t = "weapon", gettagindex(this, t)) || (t = "tag_weapon", gettagindex(this, t)))
 423                 {
 424                         if (!this.weaponchild)
 425                         {
 426                                 this.weaponchild = new(weaponchild);
 427 #ifdef CSQC
 428                                 this.weaponchild.drawmask = MASK_NORMAL;
 429                                 this.weaponchild.renderflags |= RF_VIEWMODEL;
 430 #endif
 431                         }
 432                         _setmodel(this.weaponchild, W_Model(strcat("v_", name, ".md3")));
 433                         setsize(this.weaponchild, '0 0 0', '0 0 0');
 434                         setattachment(this.weaponchild, this, t);
 435                 }
 436                 else
 437                 {
 438                         if (this.weaponchild) delete(this.weaponchild);
 439                         this.weaponchild = NULL;
 440                 }
 441
 442                 setsize(this, '0 0 0', '0 0 0');
 443                 setorigin(this, '0 0 0');
 444                 this.angles = '0 0 0';
 445                 this.frame = 0;
 446 #ifdef SVQC
 447                 this.viewmodelforclient = NULL;
 448 #else
 449                 this.renderflags &= ~RF_VIEWMODEL;
 450 #endif
 451                 if (v_shot_idx)  // v_ model attached to invisible h_ model
 452                 {
 453                         this.movedir = gettaginfo(this.weaponchild, v_shot_idx);
 454                 }
 455                 else
 456                 {
 457                         int idx;
 458                         if ((idx = gettagindex(this, "shot")) || (idx = gettagindex(this, "tag_shot")))
 459                         {
 460                                 this.movedir = gettaginfo(this, idx);
 461                         }
 462                         else
 463                         {
 464                                 LOG_WARNF("weapon model %s does not support the 'shot' tag, will display shots TOTALLY wrong",
 465                                         this.model);
 466                                 this.movedir = '0 0 0';
 467                         }
 468                 }
 469                 {
 470                         int idx = 0;
 471                         // v_ model attached to invisible h_ model
 472                         if (this.weaponchild
 473                                 && ((idx = gettagindex(this.weaponchild, "shell")) || (idx = gettagindex(this.weaponchild, "tag_shell"))))
 474                         {
 475                                 this.spawnorigin = gettaginfo(this.weaponchild, idx);
 476                         }
 477                         else if ((idx = gettagindex(this, "shell")) || (idx = gettagindex(this, "tag_shell")))
 478                         {
 479                                 this.spawnorigin = gettaginfo(this, idx);
 480                         }
 481                         else
 482                         {
 483                                 LOG_WARNF("weapon model %s does not support the 'shell' tag, will display casings wrong",
 484                                         this.model);
 485                                 this.spawnorigin = this.movedir;
 486                         }
 487                 }
 488                 if (v_shot_idx)
 489                 {
 490                         this.oldorigin = '0 0 0';  // use regular attachment
 491                 }
 492                 else
 493                 {
 494                         int idx;
 495                         if (this.weaponchild)
 496                                 (idx = gettagindex(this, "weapon")) || (idx = gettagindex(this, "tag_weapon"));
 497                         else
 498                                 (idx = gettagindex(this, "handle")) || (idx = gettagindex(this, "tag_handle"));
 499                         if (idx)
 500                         {
 501                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
 502                         }
 503                         else
 504                         {
 505                                 LOG_WARNF(
 506                                         "weapon model %s does not support the 'handle' tag "
 507                                         "and neither does the v_ model support the 'shot' tag, "
 508                                         "will display muzzle flashes TOTALLY wrong\n",
 509                                         this.model);
 510                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
 511                         }
 512                 }
 513
 514 #ifdef SVQC
 515                 this.viewmodelforclient = this.owner;
 516 #else
 517                 this.renderflags |= RF_VIEWMODEL;
 518 #endif
 519         }
 520
 521         this.view_ofs = '0 0 0';
 522         this.movedir_aligned = this.movedir;
 523
 524         if (this.movedir.x >= 0)
 525         {
 526                 //int algn = STAT(GUNALIGN, this.owner);
 527                 int algn = W_GunAlign(this, STAT(GUNALIGN, this.owner));
 528         #ifdef SVQC
 529                 this.m_gunalign = algn;
 530         #endif
 531                 vector v = this.movedir;
 532                 this.movedir = shotorg_adjust(v, false, false, algn);
 533                 this.movedir_aligned = shotorg_adjust(v, false, true, algn);
 534                 this.view_ofs = shotorg_adjust(v, false, true, algn) - v;
 535         }
 536         int compressed_shotorg = compressShotOrigin(this.movedir);
 537         // make them match perfectly
 538 #ifdef SVQC
 539         // null during init
 540         if (this.owner) STAT(SHOTORG, this.owner) = compressed_shotorg;
 541 #endif
 542         this.movedir = decompressShotOrigin(compressed_shotorg);
 543
 544         this.spawnorigin += this.view_ofs;  // offset the casings origin by the same amount
 545
 546         // check if an instant weapon switch occurred
 547         setorigin(this, this.view_ofs);
 548         if (!_anim) return;
 549         // reset animstate now
 550         this.wframe = WFRAME_IDLE;
 551         setanim(this, this.anim_idle, true, false, true);
 552 }
 553 #endif
 554
 555 #ifdef GAMEQC
 556
 557 REGISTER_NET_TEMP(wframe)
 558 #ifdef CSQC
 559 NET_HANDLE(wframe, bool isNew)
 560 {
 561         WFRAME fr = ReadByte();
 562         float t = ReadFloat();
 563         int slot = ReadByte();
 564         bool restartanim = ReadByte();
 565         entity wepent = viewmodels[slot];
 566         if(fr == WFRAME_IDLE)
 567                 wepent.animstate_looping = false; // we don't need to enforce idle animation
 568         else
 569         {
 570                 vector a = '0 0 0';
 571                 switch(fr)
 572                 {
 573                         default:
 574                         case WFRAME_IDLE: a = wepent.anim_idle; break;
 575                         case WFRAME_FIRE1: a = wepent.anim_fire1; break;
 576                         case WFRAME_FIRE2: a = wepent.anim_fire2; break;
 577                         case WFRAME_RELOAD: a = wepent.anim_reload; break;
 578                 }
 579                 a.z *= t;
 580                 anim_set(wepent, a, !restartanim, restartanim, restartanim);
 581         }
 582         wepent.state = ReadByte();
 583         wepent.weapon_nextthink = ReadFloat();
 584         switch (wepent.state)
 585         {
 586                 case WS_RAISE:
 587                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_raise;
 588                         break;
 589                 case WS_DROP:
 590                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_drop;
 591                         break;
 592                 default:
 593                         wepent.weapon_switchdelay = 0;
 594                         break;
 595         }
 596         return true;
 597 }
 598 #endif
 599
 600 #ifdef SVQC
 601 void wframe_send(entity actor, entity weaponentity, int wepframe, float attackrate, bool restartanim)
 602 {
 603         if (!IS_REAL_CLIENT(actor)) return;
 604         int channel = MSG_ONE;
 605         msg_entity = actor;
 606         WriteHeader(channel, wframe);
 607         WriteByte(channel, wepframe);
 608         WriteFloat(channel, attackrate);
 609         WriteByte(channel, weaponslot(weaponentity.weaponentity_fld));
 610         WriteByte(channel, restartanim);
 611         WriteByte(channel, weaponentity.state);
 612         WriteFloat(channel, weaponentity.weapon_nextthink);
 613 }
 614 #endif
 615
 616 REGISTER_NET_C2S(w_whereis)
 617 #ifdef SVQC
 618 void Weapon_whereis(Weapon this, entity cl);
 619 NET_HANDLE(w_whereis, bool)
 620 {
 621         Weapon wpn = ReadRegistered(Weapons);
 622         if (wpn != WEP_Null) Weapon_whereis(wpn, sender);
 623         return true;
 624 }
 625 #else
 626 void w_whereis(Weapon this)
 627 {
 628         int channel = MSG_C2S;
 629         WriteHeader(channel, w_whereis);
 630         WriteRegistered(Weapons, channel, this);
 631 }
 632 CLIENT_COMMAND(weapon_find, "Show spawn locations of a weapon")
 633 {
 634         switch (request)
 635         {
 636                 case CMD_REQUEST_COMMAND:
 637                 {
 638                         string s = argv(1);
 639                         if (s == "all")
 640                         {
 641                                 FOREACH(Weapons, it != WEP_Null, w_whereis(it));
 642                                 return;
 643                         }
 644                         if (s == "unowned")
 645                         {
 646                                 FOREACH(Weapons, it != WEP_Null && !(STAT(WEAPONS) & it.m_wepset), w_whereis(it));
 647                                 return;
 648                         }
 649                         FOREACH(Weapons, it != WEP_Null && it.netname == s,
 650                         {
 651                                 w_whereis(it);
 652                                 return;
 653                         });
 654                 }
 655                 default:
 656                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 657                 case CMD_REQUEST_USAGE:
 658                 {
 659                         LOG_HELP("Usage:^3 cl_cmd weapon_find weapon");
 660                         LOG_HELP("  Where 'weapon' is the lowercase weapon name, 'all' or 'unowned'.");
 661                         return;
 662                 }
 663         }
 664 }
 665 #endif
 666
 667 #ifdef SVQC
 668 void W_MuzzleFlash_Model_AttachToShotorg(entity actor, .entity weaponentity, entity flash, vector offset)
 669 {
 670         flash.owner = actor;
 671         flash.angles_z = random() * 360;
 672
 673         entity view = actor.(weaponentity);
 674         entity exterior = actor.exteriorweaponentity;
 675
 676         if (view.oldorigin.x > 0)
 677         {
 678                 setattachment(flash, exterior, "");
 679                 setorigin(flash, view.oldorigin + offset);
 680         }
 681         else
 682         {
 683                 if (gettagindex(exterior, "shot")) setattachment(flash, exterior, "shot");
 684                 else setattachment(flash, exterior, "tag_shot");
 685                 setorigin(flash, offset);
 686         }
 687 }
 688 #elif defined(CSQC)
 689 void W_MuzzleFlash_Model_AttachToShotorg(entity wepent, entity flash, vector offset)
 690 {
 691         flash.owner = wepent;
 692         flash.angles_z = random() * 360;
 693
 694         if (gettagindex(wepent, "shot")) setattachment(flash, wepent, "shot");
 695         else setattachment(flash, wepent, "tag_shot");
 696         setorigin(flash, offset);
 697 }
 698 #endif
 699
 700 void W_MuzzleFlash_Model_Think(entity this)
 701 {
 702         this.frame += 2;
 703         this.scale *= 0.5;
 704         this.alpha -= 0.25;
 705         this.nextthink = time + 0.05;
 706
 707         if(this.alpha <= 0)
 708         {
 709                 setthink(this, SUB_Remove);
 710                 this.nextthink = time;
 711                 this.realowner.muzzle_flash = NULL;
 712                 return;
 713         }
 714 }
 715
 716 void W_MuzzleFlash_Model(entity wepent, entity muzzlemodel)
 717 {
 718         if(wepent.muzzle_flash == NULL)
 719                 wepent.muzzle_flash = spawn();
 720
 721         entity flash = wepent.muzzle_flash;
 722         setmodel(flash, muzzlemodel); // precision set below
 723
 724         flash.scale = 0.75;
 725         setthink(flash, W_MuzzleFlash_Model_Think);
 726         flash.nextthink = time + 0.02;
 727         flash.frame = 2;
 728         flash.alpha = 0.75;
 729         flash.angles_z = random() * 180;
 730         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
 731         flash.owner = flash.realowner = wepent;
 732
 733 #ifdef CSQC
 734         flash.drawmask = MASK_NORMAL;
 735 #endif
 736 }
 737
 738 REGISTER_NET_TEMP(w_muzzleflash)
 739
 740 #ifdef SVQC
 741 void W_MuzzleFlash(Weapon thiswep, entity actor, .entity weaponentity, vector shotorg, vector shotdir)
 742 {
 743         // don't show an exterior muzzle effect for the off-hand
 744         if(weaponslot(weaponentity) == 0)
 745         {
 746                 Send_Effect_Except(thiswep.m_muzzleeffect, shotorg, shotdir * 1000, 1, actor);
 747
 748                 if(thiswep.m_muzzlemodel != MDL_Null)
 749                 {
 750                         W_MuzzleFlash_Model(actor.exteriorweaponentity, thiswep.m_muzzlemodel);
 751                         W_MuzzleFlash_Model_AttachToShotorg(actor, weaponentity, actor.exteriorweaponentity.muzzle_flash, '5 0 0');
 752                 }
 753         }
 754
 755         FOREACH_CLIENT(it == actor || (IS_SPEC(it) && it.enemy == actor),
 756         {
 757                 if(!IS_REAL_CLIENT(it))
 758                         continue;
 759                 int channel = MSG_ONE;
 760                 msg_entity = it;
 761                 WriteHeader(channel, w_muzzleflash);
 762                 WriteByte(channel, thiswep.m_id);
 763                 WriteByte(channel, weaponslot(weaponentity));
 764                 WriteVector(channel, shotorg);
 765         });
 766 }
 767 #elif defined(CSQC)
 768 NET_HANDLE(w_muzzleflash, bool isNew)
 769 {
 770         return = true;
 771         int weapon_id = ReadByte();
 772         int slot = ReadByte();
 773         vector sv_shotorg = ReadVector();
 774
 775         Weapon thiswep = REGISTRY_GET(Weapons, weapon_id);
 776         vector viewangles = getpropertyvec(VF_CL_VIEWANGLES);
 777         vector forward, right, up;
 778         MAKE_VECTORS(viewangles, forward, right, up);
 779
 780         if(autocvar_chase_active)
 781         {
 782                 // in third person mode, show the muzzle flash from the server side weapon position
 783                 // we don't have a view model to reference in this case
 784                 pointparticles(thiswep.m_muzzleeffect, sv_shotorg, forward * 1000, 1);
 785                 return;
 786         }
 787         if(!autocvar_r_drawviewmodel) return;
 788
 789         entity wepent = viewmodels[slot];
 790         // get the local player entity to calculate shot origin
 791         entity rlplayer = CSQCModel_server2csqc(player_localentnum - 1);
 792         if(!rlplayer)
 793                 rlplayer = csqcplayer; // fall back to the global
 794
 795         vector md = wepent.movedir_aligned;
 796         vector vecs = ((md.x > 0) ? md : '0 0 0');
 797         vector dv = forward * vecs.x + right * -vecs.y + up * vecs.z;
 798         vector org = rlplayer.origin + rlplayer.view_ofs + dv;
 799
 800         pointparticles(thiswep.m_muzzleeffect, org, forward * 1000, 1);
 801
 802         if(thiswep.m_muzzlemodel != MDL_Null)
 803         {
 804                 W_MuzzleFlash_Model(wepent, thiswep.m_muzzlemodel);
 805                 W_MuzzleFlash_Model_AttachToShotorg(wepent, wepent.muzzle_flash, '5 0 0');
 806         }
 807 }
 808 #endif
 809
 810
 811 #endif
 812
 813 #endif