qcsrc/common/weapons/all.qc

   1 #include "all.qh"
   2 #ifndef WEAPONS_ALL_C
   3 #define WEAPONS_ALL_C
   4
   5 #if defined(CSQC)
   6         #include <client/main.qh>
   7         #include <common/constants.qh>
   8         #include <common/deathtypes/all.qh>
   9         #include <common/physics/movetypes/movetypes.qh>
  10         #include <common/stats.qh>
  11         #include <common/util.qh>
  12         #include <common/weapons/calculations.qc>
  13         #include <common/weapons/weapon/_mod.inc>
  14         #include <lib/csqcmodel/cl_model.qh>
  15         #include <lib/csqcmodel/interpolate.qh>
  16         #include <lib/warpzone/anglestransform.qh>
  17         #include <lib/warpzone/client.qh>
  18         #include <lib/warpzone/common.qh>
  19 #elif defined(MENUQC)
  20         #include <common/weapons/weapon/_mod.inc>
  21 #elif defined(SVQC)
  22         #include <common/constants.qh>
  23         #include <common/deathtypes/all.qh>
  24         #include <common/items/_mod.qh>
  25         #include <common/mapinfo.qh>
  26         #include <common/monsters/_mod.qh>
  27         #include <common/notifications/all.qh>
  28         #include <common/stats.qh>
  29         #include <common/teams.qh>
  30         #include <common/util.qh>
  31         #include <common/weapons/calculations.qc>
  32         #include <common/weapons/config.qc>
  33         #include <common/weapons/config.qh>
  34         #include <common/weapons/weapon/_mod.inc>
  35         #include <lib/csqcmodel/sv_model.qh>
  36         #include <lib/warpzone/anglestransform.qh>
  37         #include <lib/warpzone/common.qh>
  38         #include <lib/warpzone/server.qh>
  39         #include <lib/warpzone/util_server.qh>
  40         #include <server/command/_mod.qh>
  41         #include <server/hook.qh>
  42         #include <server/items/spawning.qh>
  43         #include <server/mutators/_mod.qh>
  44         #include <server/portals.qh>
  45         #include <server/weapons/common.qh>
  46         #include <server/weapons/csqcprojectile.qh>
  47         #include <server/weapons/tracing.qh>
  48 #endif
  49
  50
  51 // WEAPON PLUGIN SYSTEM
  52
  53 WepSet _WepSet_FromWeapon(int a)
  54 {
  55         a -= WEP_FIRST;
  56         if (REGISTRY_MAX(Weapons) > 24)
  57                 if (a >= 24)
  58                 {
  59                         a -= 24;
  60                         if (REGISTRY_MAX(Weapons) > 48)
  61                                 if (a >= 24)
  62                                 {
  63                                         a -= 24;
  64                                         return '0 0 1' * BIT(a);
  65                                 }
  66                         return '0 1 0' * BIT(a);
  67                 }
  68         return '1 0 0' * BIT(a);
  69 }
  70 #ifdef SVQC
  71         void WriteWepSet(float dst, WepSet w)
  72         {
  73                 if (REGISTRY_MAX(Weapons) > 48) WriteInt72_t(dst, w);
  74                 else if (REGISTRY_MAX(Weapons) > 24) WriteInt48_t(dst, w);
  75                 else WriteInt24_t(dst, w.x);
  76         }
  77 #endif
  78 #ifdef CSQC
  79         WepSet WepSet_GetFromStat()
  80         {
  81                 return STAT(WEAPONS);
  82         }
  83         WepSet WepSet_GetFromStat_InMap()
  84         {
  85                 return STAT(WEAPONSINMAP);
  86         }
  87         WepSet ReadWepSet()
  88         {
  89                 if (REGISTRY_MAX(Weapons) > 48) return ReadInt72_t();
  90                 if (REGISTRY_MAX(Weapons) > 24) return ReadInt48_t();
  91                 return ReadInt24_t() * '1 0 0';
  92         }
  93 #endif
  94
  95 string W_FixWeaponOrder(string order, float complete)
  96 {
  97         return fixPriorityList(order, WEP_FIRST, WEP_LAST, WEP_IMPULSE_BEGIN - WEP_FIRST, complete);
  98 }
  99 string W_NameWeaponOrder_MapFunc(string s)
 100 {
 101         int i = stof(s);
 102         if (s == "0" || i)
 103         {
 104                 entity wi = REGISTRY_GET(Weapons, i);
 105                 if (wi != WEP_Null) return wi.netname;
 106         }
 107         return s;
 108 }
 109
 110 string W_UndeprecateName(string s)
 111 {
 112         switch (s)
 113         {
 114                 case "nex": return "vortex";
 115                 case "rocketlauncher": return "devastator";
 116                 case "laser": return "blaster";
 117                 case "minstanex": return "vaporizer";
 118                 case "grenadelauncher": return "mortar";
 119                 case "uzi": return "machinegun";
 120                 case "hmg": return "okhmg";
 121                 case "rpc": return "okrpc";
 122                 default: return s;
 123         }
 124 }
 125 string W_NameWeaponOrder(string order)
 126 {
 127         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
 128 }
 129 string W_NumberWeaponOrder_MapFunc(string s)
 130 {
 131         if (s == "0" || stof(s)) return s;
 132         s = W_UndeprecateName(s);
 133         FOREACH(Weapons, it != WEP_Null && it.netname == s, return ftos(i));
 134         return s;
 135 }
 136 string W_NumberWeaponOrder(string order)
 137 {
 138         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
 139 }
 140
 141 float W_FixWeaponOrder_BuildImpulseList_buf[REGISTRY_MAX(Weapons)];
 142 string W_FixWeaponOrder_BuildImpulseList_order;
 143 void W_FixWeaponOrder_BuildImpulseList_swap(int i, int j, entity pass)
 144 {
 145         float h;
 146         h = W_FixWeaponOrder_BuildImpulseList_buf[i];
 147         W_FixWeaponOrder_BuildImpulseList_buf[i] = W_FixWeaponOrder_BuildImpulseList_buf[j];
 148         W_FixWeaponOrder_BuildImpulseList_buf[j] = h;
 149 }
 150 float W_FixWeaponOrder_BuildImpulseList_cmp(int i, int j, entity pass)
 151 {
 152         int si = W_FixWeaponOrder_BuildImpulseList_buf[i];
 153         Weapon e1 = REGISTRY_GET(Weapons, si);
 154         int sj = W_FixWeaponOrder_BuildImpulseList_buf[j];
 155         Weapon e2 = REGISTRY_GET(Weapons, sj);
 156         int d = (e1.impulse + 9) % 10 - (e2.impulse + 9) % 10;
 157         if (d != 0) return -d;  // high impulse first!
 158         string s = strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " ");
 159         return strstrofs(s, sprintf(" %d ", si), 0)
 160                 - strstrofs(s, sprintf(" %d ", sj), 0); // low char index first!
 161 }
 162 string W_FixWeaponOrder_BuildImpulseList(string o)
 163 {
 164         int i;
 165         W_FixWeaponOrder_BuildImpulseList_order = o;
 166         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 167                 W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST] = i;
 168         heapsort(WEP_LAST - WEP_FIRST + 1, W_FixWeaponOrder_BuildImpulseList_swap, W_FixWeaponOrder_BuildImpulseList_cmp,
 169                 NULL);
 170         o = "";
 171         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 172                 o = strcat(o, " ", ftos(W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST]));
 173         W_FixWeaponOrder_BuildImpulseList_order = string_null;
 174         return substring(o, 1, -1);
 175 }
 176
 177 string W_FixWeaponOrder_AllowIncomplete(entity this, string order)
 178 {
 179         return W_FixWeaponOrder(order, 0);
 180 }
 181
 182 string W_FixWeaponOrder_ForceComplete(string order)
 183 {
 184         if (order == "") order = W_NumberWeaponOrder(cvar_defstring("cl_weaponpriority"));
 185         return W_FixWeaponOrder(order, 1);
 186 }
 187
 188 WepSet W_RandomWeapons(entity e, WepSet remaining, int n)
 189 {
 190         WepSet result = '0 0 0';
 191         for (int j = 0; j < n; ++j)
 192         {
 193                 RandomSelection_Init();
 194                 FOREACH(Weapons, it != WEP_Null, {
 195                         if (remaining & (it.m_wepset))
 196                                 RandomSelection_AddEnt(it, 1, 1);
 197                 });
 198                 Weapon w = RandomSelection_chosen_ent;
 199                 result |= WepSet_FromWeapon(w);
 200                 remaining &= ~WepSet_FromWeapon(w);
 201         }
 202         return result;
 203 }
 204
 205 string GetAmmoPicture(int ammotype)
 206 {
 207         switch (ammotype)
 208         {
 209                 case RES_SHELLS:  return ITEM_Shells.m_icon;
 210                 case RES_BULLETS: return ITEM_Bullets.m_icon;
 211                 case RES_ROCKETS: return ITEM_Rockets.m_icon;
 212                 case RES_CELLS:   return ITEM_Cells.m_icon;
 213                 case RES_PLASMA:  return ITEM_Plasma.m_icon;
 214                 case RES_FUEL:    return ITEM_JetpackFuel.m_icon;
 215                 default: return "";  // wtf, no ammo type?
 216         }
 217 }
 218
 219 string GetAmmoName(int ammotype)
 220 {
 221         switch (ammotype)
 222         {
 223                 case RES_SHELLS:  return ITEM_Shells.m_name;
 224                 case RES_BULLETS: return ITEM_Bullets.m_name;
 225                 case RES_ROCKETS: return ITEM_Rockets.m_name;
 226                 case RES_CELLS:   return ITEM_Cells.m_name;
 227                 case RES_PLASMA:  return ITEM_Plasma.m_name;
 228                 case RES_FUEL:    return ITEM_JetpackFuel.m_name;
 229                 default:          return "batteries";
 230         }
 231 }
 232
 233 entity GetAmmoItem(int ammotype)
 234 {
 235         switch (ammotype)
 236         {
 237                 case RES_SHELLS:  return ITEM_Shells;
 238                 case RES_BULLETS: return ITEM_Bullets;
 239                 case RES_ROCKETS: return ITEM_Rockets;
 240                 case RES_CELLS:   return ITEM_Cells;
 241                 case RES_PLASMA:  return ITEM_Plasma;
 242                 case RES_FUEL:    return ITEM_JetpackFuel;
 243         }
 244         LOG_WARNF("Invalid ammo type %d ", ammotype);
 245         return NULL;
 246         // WEAPONTODO: use this generic func to reduce duplication ?
 247         // GetAmmoPicture  GetAmmoName  notif_arg_item_wepammo  ammo_pickupevalfunc ?
 248 }
 249
 250 #ifdef CSQC
 251 int GetAmmoTypeFromNum(int i)
 252 {
 253         switch (i)
 254         {
 255                 case 0: return RES_SHELLS;
 256                 case 1: return RES_BULLETS;
 257                 case 2: return RES_ROCKETS;
 258                 case 3: return RES_CELLS;
 259                 case 4: return RES_PLASMA;
 260                 case 5: return RES_FUEL;
 261                 default: return RES_NONE;
 262         }
 263 }
 264
 265 int GetAmmoStat(int ammotype)
 266 {
 267         switch (ammotype)
 268         {
 269                 case RES_SHELLS: return STAT_SHELLS;
 270                 case RES_BULLETS: return STAT_NAILS;
 271                 case RES_ROCKETS: return STAT_ROCKETS;
 272                 case RES_CELLS: return STAT_CELLS;
 273                 case RES_PLASMA: return STAT_PLASMA.m_id;
 274                 case RES_FUEL: return STAT_FUEL.m_id;
 275                 default: return -1;
 276         }
 277 }
 278 #endif
 279
 280 string W_Sound(string w_snd)
 281 {
 282         string output = strcat("weapons/", w_snd);
 283         MUTATOR_CALLHOOK(WeaponSound, w_snd, output);
 284         return M_ARGV(1, string);
 285 }
 286
 287 string W_Model(string w_mdl)
 288 {
 289         string output = strcat("models/weapons/", w_mdl);
 290         MUTATOR_CALLHOOK(WeaponModel, w_mdl, output);
 291         return M_ARGV(1, string);
 292 }
 293
 294 #ifdef GAMEQC
 295 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
 296 {
 297         switch (algn)
 298         {
 299                 default:
 300                 case 3:
 301                         // right alignment
 302                         break;
 303                 case 4:
 304                         // left
 305                         vecs.y = -vecs.y;
 306                         break;
 307                 case 1:
 308                 case 2:
 309                         // center
 310                         vecs.y = 0;
 311                         vecs.z -= 2;
 312                         break;
 313         }
 314         return vecs;
 315 }
 316
 317 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn)
 318 {
 319         string s;
 320         if (visual)
 321         {
 322                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 323         }
 324         else if (STAT(SHOOTFROMEYE))
 325         {
 326                 vecs.y = vecs.z = 0;
 327         }
 328         else if (STAT(SHOOTFROMCENTER))
 329         {
 330                 vecs.y = 0;
 331                 vecs.z -= 2;
 332         }
 333         else if ((s = G_SHOOTFROMFIXEDORIGIN) != "")
 334         {
 335                 vector v = stov(s);
 336                 if (y_is_right) v.y = -v.y;
 337                 if (v.x != 0) vecs.x = v.x;
 338                 vecs.y = v.y;
 339                 vecs.z = v.z;
 340         }
 341         else  // just do the same as top
 342         {
 343                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 344         }
 345
 346         return vecs;
 347 }
 348
 349 #define shotorg_adjust shotorg_adjust_values
 350
 351 /**
 352  * supported formats:
 353  *
 354  * 1. simple animated model, muzzle flash handling on h_ model:
 355  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 356  *      tags:
 357  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 358  *        shell = casings ejection point (must be on the right hand side of the gun)
 359  *        weapon = attachment for v_tuba.md3
 360  *    v_tuba.md3 - first and third person model
 361  *    g_tuba.md3 - pickup model
 362  *
 363  * 2. simple animated model, muzzle flash handling on v_ model:
 364  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 365  *      tags:
 366  *        weapon = attachment for v_tuba.md3
 367  *    v_tuba.md3 - first and third person model
 368  *      tags:
 369  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 370  *        shell = casings ejection point (must be on the right hand side of the gun)
 371  *    g_tuba.md3 - pickup model
 372  *
 373  * 3. fully animated model, muzzle flash handling on h_ model:
 374  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 375  *      tags:
 376  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 377  *        shell = casings ejection point (must be on the right hand side of the gun)
 378  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 379  *    v_tuba.md3 - third person model
 380  *    g_tuba.md3 - pickup model
 381  *
 382  * 4. fully animated model, muzzle flash handling on v_ model:
 383  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 384  *      tags:
 385  *        shot = muzzle end (shot origin)
 386  *        shell = casings ejection point (must be on the right hand side of the gun)
 387  *    v_tuba.md3 - third person model
 388  *      tags:
 389  *        shot = muzzle end (for muzzle flashes)
 390  *    g_tuba.md3 - pickup model
 391  *
 392  * writes:
 393  *   this.origin, this.angles
 394  *   this.weaponchild
 395  *   this.movedir, this.view_ofs, this.movedir_aligned
 396  *   attachment stuff
 397  *   anim stuff
 398  * to free:
 399  *   call again with ""
 400  *   remove the ent
 401  */
 402 void CL_WeaponEntity_SetModel(entity this, string name, bool _anim)
 403 {
 404         if (name == "")
 405         {
 406                 vector oldmin = this.mins, oldmax = this.maxs;
 407                 setmodel(this, MDL_Null);
 408                 setsize(this, oldmin, oldmax);
 409                 if (this.weaponchild) delete(this.weaponchild);
 410                 this.weaponchild = NULL;
 411                 this.movedir = '0 0 0';
 412                 this.spawnorigin = '0 0 0';
 413                 this.oldorigin = '0 0 0';
 414                 this.anim_fire1  = '0 1 0.01';
 415                 this.anim_fire2  = '0 1 0.01';
 416                 this.anim_idle   = '0 1 0.01';
 417                 this.anim_reload = '0 1 0.01';
 418         }
 419         else
 420         {
 421                 // if there is a child entity, hide it until we're sure we use it
 422                 if (this.weaponchild) this.weaponchild.model = "";
 423                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
 424                 int v_shot_idx;  // used later
 425                 (v_shot_idx = gettagindex(this, "shot")) || (v_shot_idx = gettagindex(this, "tag_shot"));
 426
 427                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
 428                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 429                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
 430                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
 431                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
 432                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
 433
 434                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 435                 // if we don't, this is a "real" animated model
 436                 string t;
 437                 if ((t = "weapon", gettagindex(this, t)) || (t = "tag_weapon", gettagindex(this, t)))
 438                 {
 439                         if (!this.weaponchild)
 440                         {
 441                                 this.weaponchild = new(weaponchild);
 442 #ifdef CSQC
 443                                 this.weaponchild.drawmask = MASK_NORMAL;
 444                                 this.weaponchild.renderflags |= RF_VIEWMODEL;
 445 #endif
 446                         }
 447                         _setmodel(this.weaponchild, W_Model(strcat("v_", name, ".md3")));
 448                         setsize(this.weaponchild, '0 0 0', '0 0 0');
 449                         setattachment(this.weaponchild, this, t);
 450                 }
 451                 else
 452                 {
 453                         if (this.weaponchild) delete(this.weaponchild);
 454                         this.weaponchild = NULL;
 455                 }
 456
 457                 setsize(this, '0 0 0', '0 0 0');
 458                 setorigin(this, '0 0 0');
 459                 this.angles = '0 0 0';
 460                 this.frame = 0;
 461 #ifdef SVQC
 462                 this.viewmodelforclient = NULL;
 463 #else
 464                 this.renderflags &= ~RF_VIEWMODEL;
 465 #endif
 466                 if (v_shot_idx)  // v_ model attached to invisible h_ model
 467                 {
 468                         this.movedir = gettaginfo(this.weaponchild, v_shot_idx);
 469                 }
 470                 else
 471                 {
 472                         int idx;
 473                         if ((idx = gettagindex(this, "shot")) || (idx = gettagindex(this, "tag_shot")))
 474                         {
 475                                 this.movedir = gettaginfo(this, idx);
 476                         }
 477                         else
 478                         {
 479                                 LOG_WARNF("weapon model %s does not support the 'shot' tag, will display shots TOTALLY wrong",
 480                                         this.model);
 481                                 this.movedir = '0 0 0';
 482                         }
 483                 }
 484                 {
 485                         int idx = 0;
 486                         // v_ model attached to invisible h_ model
 487                         if (this.weaponchild
 488                                 && ((idx = gettagindex(this.weaponchild, "shell")) || (idx = gettagindex(this.weaponchild, "tag_shell"))))
 489                         {
 490                                 this.spawnorigin = gettaginfo(this.weaponchild, idx);
 491                         }
 492                         else if ((idx = gettagindex(this, "shell")) || (idx = gettagindex(this, "tag_shell")))
 493                         {
 494                                 this.spawnorigin = gettaginfo(this, idx);
 495                         }
 496                         else
 497                         {
 498                                 LOG_WARNF("weapon model %s does not support the 'shell' tag, will display casings wrong",
 499                                         this.model);
 500                                 this.spawnorigin = this.movedir;
 501                         }
 502                 }
 503                 if (v_shot_idx)
 504                 {
 505                         this.oldorigin = '0 0 0';  // use regular attachment
 506                 }
 507                 else
 508                 {
 509                         int idx;
 510                         if (this.weaponchild)
 511                                 (idx = gettagindex(this, "weapon")) || (idx = gettagindex(this, "tag_weapon"));
 512                         else
 513                                 (idx = gettagindex(this, "handle")) || (idx = gettagindex(this, "tag_handle"));
 514                         if (idx)
 515                         {
 516                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
 517                         }
 518                         else
 519                         {
 520                                 LOG_WARNF(
 521                                         "weapon model %s does not support the 'handle' tag "
 522                                         "and neither does the v_ model support the 'shot' tag, "
 523                                         "will display muzzle flashes TOTALLY wrong\n",
 524                                         this.model);
 525                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
 526                         }
 527                 }
 528
 529 #ifdef SVQC
 530                 this.viewmodelforclient = this.owner;
 531 #else
 532                 this.renderflags |= RF_VIEWMODEL;
 533 #endif
 534         }
 535
 536         this.view_ofs = '0 0 0';
 537         this.movedir_aligned = this.movedir;
 538
 539         if (this.movedir.x >= 0)
 540         {
 541                 //int algn = STAT(GUNALIGN, this.owner);
 542                 int algn = W_GunAlign(this, STAT(GUNALIGN, this.owner));
 543         #ifdef SVQC
 544                 this.m_gunalign = algn;
 545         #endif
 546                 vector v = this.movedir;
 547                 this.movedir = shotorg_adjust(v, false, false, algn);
 548                 this.movedir_aligned = shotorg_adjust(v, false, true, algn);
 549                 this.view_ofs = shotorg_adjust(v, false, true, algn) - v;
 550         }
 551         int compressed_shotorg = compressShotOrigin(this.movedir);
 552         // make them match perfectly
 553 #ifdef SVQC
 554         // null during init
 555         if (this.owner) STAT(SHOTORG, this.owner) = compressed_shotorg;
 556 #endif
 557         this.movedir = decompressShotOrigin(compressed_shotorg);
 558
 559         this.spawnorigin += this.view_ofs;  // offset the casings origin by the same amount
 560
 561         // check if an instant weapon switch occurred
 562         setorigin(this, this.view_ofs);
 563         if (!_anim) return;
 564         // reset animstate now
 565         this.wframe = WFRAME_IDLE;
 566         setanim(this, this.anim_idle, true, false, true);
 567 }
 568 #endif
 569
 570 #ifdef GAMEQC
 571
 572 REGISTER_NET_TEMP(wframe)
 573 #ifdef CSQC
 574 NET_HANDLE(wframe, bool isNew)
 575 {
 576         WFRAME fr = ReadByte();
 577         float t = ReadFloat();
 578         int slot = ReadByte();
 579         bool restartanim = ReadByte();
 580         entity wepent = viewmodels[slot];
 581         if(fr == WFRAME_IDLE)
 582                 wepent.animstate_looping = false; // we don't need to enforce idle animation
 583         else
 584         {
 585                 vector a = '0 0 0';
 586                 switch(fr)
 587                 {
 588                         default:
 589                         case WFRAME_IDLE: a = wepent.anim_idle; break;
 590                         case WFRAME_FIRE1: a = wepent.anim_fire1; break;
 591                         case WFRAME_FIRE2: a = wepent.anim_fire2; break;
 592                         case WFRAME_RELOAD: a = wepent.anim_reload; break;
 593                 }
 594                 a.z *= t;
 595                 anim_set(wepent, a, !restartanim, restartanim, restartanim);
 596         }
 597         wepent.state = ReadByte();
 598         wepent.weapon_nextthink = ReadFloat();
 599         switch (wepent.state)
 600         {
 601                 case WS_RAISE:
 602                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_raise;
 603                         break;
 604                 case WS_DROP:
 605                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_drop;
 606                         break;
 607                 default:
 608                         wepent.weapon_switchdelay = 0;
 609                         break;
 610         }
 611         return true;
 612 }
 613 #endif
 614
 615 #ifdef SVQC
 616 void wframe_send(entity actor, entity weaponentity, int wepframe, float attackrate, bool restartanim)
 617 {
 618         if (!IS_REAL_CLIENT(actor)) return;
 619         int channel = MSG_ONE;
 620         msg_entity = actor;
 621         WriteHeader(channel, wframe);
 622         WriteByte(channel, wepframe);
 623         WriteFloat(channel, attackrate);
 624         WriteByte(channel, weaponslot(weaponentity.weaponentity_fld));
 625         WriteByte(channel, restartanim);
 626         WriteByte(channel, weaponentity.state);
 627         WriteFloat(channel, weaponentity.weapon_nextthink);
 628 }
 629 #endif
 630
 631 REGISTER_NET_C2S(w_whereis)
 632 #ifdef SVQC
 633 void Weapon_whereis(Weapon this, entity cl);
 634 NET_HANDLE(w_whereis, bool)
 635 {
 636         Weapon wpn = ReadRegistered(Weapons);
 637         if (wpn != WEP_Null) Weapon_whereis(wpn, sender);
 638         return true;
 639 }
 640 #else
 641 void w_whereis(Weapon this)
 642 {
 643         int channel = MSG_C2S;
 644         WriteHeader(channel, w_whereis);
 645         WriteRegistered(Weapons, channel, this);
 646 }
 647 CLIENT_COMMAND(weapon_find, "Show spawn locations of a weapon")
 648 {
 649         switch (request)
 650         {
 651                 case CMD_REQUEST_COMMAND:
 652                 {
 653                         string s = argv(1);
 654                         if (s == "all")
 655                         {
 656                                 FOREACH(Weapons, it != WEP_Null, w_whereis(it));
 657                                 return;
 658                         }
 659                         if (s == "unowned")
 660                         {
 661                                 FOREACH(Weapons, it != WEP_Null && !(STAT(WEAPONS) & it.m_wepset), w_whereis(it));
 662                                 return;
 663                         }
 664                         FOREACH(Weapons, it != WEP_Null && it.netname == s,
 665                         {
 666                                 w_whereis(it);
 667                                 return;
 668                         });
 669                 }
 670                 default:
 671                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 672                 case CMD_REQUEST_USAGE:
 673                 {
 674                         LOG_HELP("Usage:^3 cl_cmd weapon_find <weapon>");
 675                         LOG_HELP("  Where <weapon> is the lowercase weapon name, 'all' or 'unowned'.");
 676                         return;
 677                 }
 678         }
 679 }
 680 #endif
 681
 682 #ifdef SVQC
 683 void W_MuzzleFlash_Model_AttachToShotorg(entity actor, .entity weaponentity, entity flash, vector offset)
 684 {
 685         flash.owner = actor;
 686         flash.angles_z = random() * 360;
 687
 688         entity view = actor.(weaponentity);
 689         entity exterior = actor.exteriorweaponentity;
 690
 691         if (view.oldorigin.x > 0)
 692         {
 693                 setattachment(flash, exterior, "");
 694                 setorigin(flash, view.oldorigin + offset);
 695         }
 696         else
 697         {
 698                 if (gettagindex(exterior, "shot")) setattachment(flash, exterior, "shot");
 699                 else setattachment(flash, exterior, "tag_shot");
 700                 setorigin(flash, offset);
 701         }
 702 }
 703 #elif defined(CSQC)
 704 void W_MuzzleFlash_Model_AttachToShotorg(entity wepent, entity flash, vector offset)
 705 {
 706         flash.owner = wepent;
 707         flash.angles_z = random() * 360;
 708
 709         if (gettagindex(wepent, "shot")) setattachment(flash, wepent, "shot");
 710         else setattachment(flash, wepent, "tag_shot");
 711         setorigin(flash, offset);
 712 }
 713 #endif
 714
 715 void W_MuzzleFlash_Model_Think(entity this)
 716 {
 717         this.frame += 2;
 718         this.scale *= 0.5;
 719         this.alpha -= 0.25;
 720         this.nextthink = time + 0.05;
 721
 722         if(this.alpha <= 0)
 723         {
 724                 setthink(this, SUB_Remove);
 725                 this.nextthink = time;
 726                 this.realowner.muzzle_flash = NULL;
 727                 return;
 728         }
 729 }
 730
 731 void W_MuzzleFlash_Model(entity wepent, entity muzzlemodel)
 732 {
 733         if(wepent.muzzle_flash == NULL)
 734                 wepent.muzzle_flash = spawn();
 735
 736         entity flash = wepent.muzzle_flash;
 737         setmodel(flash, muzzlemodel); // precision set below
 738
 739         flash.scale = 0.75;
 740         setthink(flash, W_MuzzleFlash_Model_Think);
 741         flash.nextthink = time + 0.02;
 742         flash.frame = 2;
 743         flash.alpha = 0.75;
 744         flash.angles_z = random() * 180;
 745         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
 746         flash.owner = flash.realowner = wepent;
 747
 748 #ifdef CSQC
 749         flash.drawmask = MASK_NORMAL;
 750 #endif
 751 }
 752
 753 REGISTER_NET_TEMP(w_muzzleflash)
 754
 755 #ifdef SVQC
 756 void W_MuzzleFlash(Weapon thiswep, entity actor, .entity weaponentity, vector shotorg, vector shotdir)
 757 {
 758         // don't show an exterior muzzle effect for the off-hand
 759         if(weaponslot(weaponentity) == 0)
 760         {
 761                 Send_Effect_Except(thiswep.m_muzzleeffect, shotorg, shotdir * 1000, 1, actor);
 762
 763                 if(thiswep.m_muzzlemodel != MDL_Null)
 764                 {
 765                         W_MuzzleFlash_Model(actor.exteriorweaponentity, thiswep.m_muzzlemodel);
 766                         W_MuzzleFlash_Model_AttachToShotorg(actor, weaponentity, actor.exteriorweaponentity.muzzle_flash, '5 0 0');
 767                 }
 768         }
 769
 770         FOREACH_CLIENT(it == actor || (IS_SPEC(it) && it.enemy == actor),
 771         {
 772                 if(!IS_REAL_CLIENT(it))
 773                         continue;
 774                 int channel = MSG_ONE;
 775                 msg_entity = it;
 776                 WriteHeader(channel, w_muzzleflash);
 777                 WriteByte(channel, thiswep.m_id);
 778                 WriteByte(channel, weaponslot(weaponentity));
 779                 WriteVector(channel, shotorg);
 780         });
 781 }
 782 #elif defined(CSQC)
 783 NET_HANDLE(w_muzzleflash, bool isNew)
 784 {
 785         return = true;
 786         int weapon_id = ReadByte();
 787         int slot = ReadByte();
 788         vector sv_shotorg = ReadVector();
 789
 790         Weapon thiswep = REGISTRY_GET(Weapons, weapon_id);
 791         vector viewangles = getpropertyvec(VF_CL_VIEWANGLES);
 792         vector forward, right, up;
 793         MAKE_VECTORS(viewangles, forward, right, up);
 794
 795         if(autocvar_chase_active)
 796         {
 797                 // in third person mode, show the muzzle flash from the server side weapon position
 798                 // we don't have a view model to reference in this case
 799                 pointparticles(thiswep.m_muzzleeffect, sv_shotorg, forward * 1000, 1);
 800                 return;
 801         }
 802         if(!autocvar_r_drawviewmodel) return;
 803
 804         entity wepent = viewmodels[slot];
 805         // get the local player entity to calculate shot origin
 806         entity rlplayer = CSQCModel_server2csqc(player_localentnum - 1);
 807         if(!rlplayer)
 808                 rlplayer = csqcplayer; // fall back to the global
 809
 810         vector md = wepent.movedir_aligned;
 811         vector vecs = ((md.x > 0) ? md : '0 0 0');
 812         vector dv = forward * vecs.x + right * -vecs.y + up * vecs.z;
 813         vector org = rlplayer.origin + rlplayer.view_ofs + dv;
 814
 815         pointparticles(thiswep.m_muzzleeffect, org, forward * 1000, 1);
 816
 817         if(thiswep.m_muzzlemodel != MDL_Null)
 818         {
 819                 W_MuzzleFlash_Model(wepent, thiswep.m_muzzlemodel);
 820                 W_MuzzleFlash_Model_AttachToShotorg(wepent, wepent.muzzle_flash, '5 0 0');
 821         }
 822 }
 823 #endif
 824
 825
 826 #endif
 827
 828 #endif