qcsrc/common/weapons/all.qc

   1 #include "all.qh"
   2 #ifndef WEAPONS_ALL_C
   3 #define WEAPONS_ALL_C
   4
   5 #if defined(CSQC)
   6         #include "../constants.qh"
   7         #include "../stats.qh"
   8         #include <lib/warpzone/anglestransform.qh>
   9         #include <lib/warpzone/common.qh>
  10         #include <lib/warpzone/client.qh>
  11         #include "../util.qh"
  12         #include <client/autocvars.qh>
  13         #include "../deathtypes/all.qh"
  14         #include <lib/csqcmodel/interpolate.qh>
  15         #include "../physics/movetypes/movetypes.qh"
  16         #include <client/main.qh>
  17         #include <lib/csqcmodel/cl_model.qh>
  18 #elif defined(MENUQC)
  19 #elif defined(SVQC)
  20         #include <common/items/_mod.qh>
  21         #include <lib/warpzone/anglestransform.qh>
  22         #include <lib/warpzone/common.qh>
  23         #include <lib/warpzone/util_server.qh>
  24         #include <lib/warpzone/server.qh>
  25         #include "../constants.qh"
  26         #include "../stats.qh"
  27         #include "../teams.qh"
  28         #include <common/util.qh>
  29         #include "../monsters/_mod.qh"
  30         #include "config.qh"
  31         #include <server/weapons/common.qh>
  32         #include <server/weapons/csqcprojectile.qh>
  33         #include <server/weapons/tracing.qh>
  34         #include <server/items/spawning.qh>
  35         #include <server/autocvars.qh>
  36         #include "../notifications/all.qh"
  37         #include "../deathtypes/all.qh"
  38         #include <server/mutators/_mod.qh>
  39         #include "../mapinfo.qh"
  40         #include <server/command/_mod.qh>
  41         #include <lib/csqcmodel/sv_model.qh>
  42         #include <server/portals.qh>
  43 #include <server/hook.qh>
  44 #endif
  45 #ifdef GAMEQC
  46         #include "calculations.qc"
  47 #endif
  48 #ifdef SVQC
  49         #include "config.qc"
  50 #endif
  51
  52 #include "weapon/_mod.inc"
  53
  54
  55 // WEAPON PLUGIN SYSTEM
  56
  57 WepSet _WepSet_FromWeapon(int a)
  58 {
  59         a -= WEP_FIRST;
  60         if (REGISTRY_MAX(Weapons) > 24)
  61                 if (a >= 24)
  62                 {
  63                         a -= 24;
  64                         if (REGISTRY_MAX(Weapons) > 48)
  65                                 if (a >= 24)
  66                                 {
  67                                         a -= 24;
  68                                         return '0 0 1' * (2 ** a);
  69                                 }
  70                         return '0 1 0' * (2 ** a);
  71                 }
  72         return '1 0 0' * (2 ** a);
  73 }
  74 #ifdef SVQC
  75         void WriteWepSet(float dst, WepSet w)
  76         {
  77                 if (REGISTRY_MAX(Weapons) > 48) WriteInt72_t(dst, w);
  78                 else if (REGISTRY_MAX(Weapons) > 24) WriteInt48_t(dst, w);
  79                 else WriteInt24_t(dst, w.x);
  80         }
  81 #endif
  82 #ifdef CSQC
  83         WepSet WepSet_GetFromStat()
  84         {
  85                 return STAT(WEAPONS);
  86         }
  87         WepSet WepSet_GetFromStat_InMap()
  88         {
  89                 return STAT(WEAPONSINMAP);
  90         }
  91         WepSet ReadWepSet()
  92         {
  93                 if (REGISTRY_MAX(Weapons) > 48) return ReadInt72_t();
  94                 if (REGISTRY_MAX(Weapons) > 24) return ReadInt48_t();
  95                 return ReadInt24_t() * '1 0 0';
  96         }
  97 #endif
  98
  99 string W_FixWeaponOrder(string order, float complete)
 100 {
 101         return fixPriorityList(order, WEP_FIRST, WEP_LAST, WEP_IMPULSE_BEGIN - WEP_FIRST, complete);
 102 }
 103 string W_NameWeaponOrder_MapFunc(string s)
 104 {
 105         int i = stof(s);
 106         if (s == "0" || i)
 107         {
 108                 entity wi = REGISTRY_GET(Weapons, i);
 109                 if (wi != WEP_Null) return wi.netname;
 110         }
 111         return s;
 112 }
 113
 114 string W_UndeprecateName(string s)
 115 {
 116         switch (s)
 117         {
 118                 case "nex": return "vortex";
 119                 case "rocketlauncher": return "devastator";
 120                 case "laser": return "blaster";
 121                 case "minstanex": return "vaporizer";
 122                 case "grenadelauncher": return "mortar";
 123                 case "uzi": return "machinegun";
 124                 case "hmg": return "okhmg";
 125                 case "rpc": return "okrpc";
 126                 default: return s;
 127         }
 128 }
 129 string W_NameWeaponOrder(string order)
 130 {
 131         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
 132 }
 133 string W_NumberWeaponOrder_MapFunc(string s)
 134 {
 135         if (s == "0" || stof(s)) return s;
 136         s = W_UndeprecateName(s);
 137         FOREACH(Weapons, it != WEP_Null && it.netname == s, return ftos(i));
 138         return s;
 139 }
 140 string W_NumberWeaponOrder(string order)
 141 {
 142         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
 143 }
 144
 145 float W_FixWeaponOrder_BuildImpulseList_buf[REGISTRY_MAX(Weapons)];
 146 string W_FixWeaponOrder_BuildImpulseList_order;
 147 void W_FixWeaponOrder_BuildImpulseList_swap(int i, int j, entity pass)
 148 {
 149         float h;
 150         h = W_FixWeaponOrder_BuildImpulseList_buf[i];
 151         W_FixWeaponOrder_BuildImpulseList_buf[i] = W_FixWeaponOrder_BuildImpulseList_buf[j];
 152         W_FixWeaponOrder_BuildImpulseList_buf[j] = h;
 153 }
 154 float W_FixWeaponOrder_BuildImpulseList_cmp(int i, int j, entity pass)
 155 {
 156         int si = W_FixWeaponOrder_BuildImpulseList_buf[i];
 157         Weapon e1 = REGISTRY_GET(Weapons, si);
 158         int sj = W_FixWeaponOrder_BuildImpulseList_buf[j];
 159         Weapon e2 = REGISTRY_GET(Weapons, sj);
 160         int d = (e1.impulse + 9) % 10 - (e2.impulse + 9) % 10;
 161         if (d != 0) return -d;  // high impulse first!
 162         string s = strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " ");
 163         return strstrofs(s, sprintf(" %d ", si), 0)
 164                 - strstrofs(s, sprintf(" %d ", sj), 0); // low char index first!
 165 }
 166 string W_FixWeaponOrder_BuildImpulseList(string o)
 167 {
 168         int i;
 169         W_FixWeaponOrder_BuildImpulseList_order = o;
 170         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 171                 W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST] = i;
 172         heapsort(WEP_LAST - WEP_FIRST + 1, W_FixWeaponOrder_BuildImpulseList_swap, W_FixWeaponOrder_BuildImpulseList_cmp,
 173                 NULL);
 174         o = "";
 175         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 176                 o = strcat(o, " ", ftos(W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST]));
 177         W_FixWeaponOrder_BuildImpulseList_order = string_null;
 178         return substring(o, 1, -1);
 179 }
 180
 181 string W_FixWeaponOrder_AllowIncomplete(entity this, string order)
 182 {
 183         return W_FixWeaponOrder(order, 0);
 184 }
 185
 186 string W_FixWeaponOrder_ForceComplete(string order)
 187 {
 188         if (order == "") order = W_NumberWeaponOrder(cvar_defstring("cl_weaponpriority"));
 189         return W_FixWeaponOrder(order, 1);
 190 }
 191
 192 WepSet W_RandomWeapons(entity e, WepSet remaining, int n)
 193 {
 194         WepSet result = '0 0 0';
 195         for (int j = 0; j < n; ++j)
 196         {
 197                 RandomSelection_Init();
 198                 FOREACH(Weapons, it != WEP_Null, {
 199                         if (remaining & (it.m_wepset))
 200                                 RandomSelection_AddEnt(it, 1, 1);
 201                 });
 202                 Weapon w = RandomSelection_chosen_ent;
 203                 result |= WepSet_FromWeapon(w);
 204                 remaining &= ~WepSet_FromWeapon(w);
 205         }
 206         return result;
 207 }
 208
 209 string GetAmmoPicture(int ammotype)
 210 {
 211         switch (ammotype)
 212         {
 213                 case RES_SHELLS:  return ITEM_Shells.m_icon;
 214                 case RES_BULLETS: return ITEM_Bullets.m_icon;
 215                 case RES_ROCKETS: return ITEM_Rockets.m_icon;
 216                 case RES_CELLS:   return ITEM_Cells.m_icon;
 217                 case RES_PLASMA:  return ITEM_Plasma.m_icon;
 218                 case RES_FUEL:    return ITEM_JetpackFuel.m_icon;
 219                 default: return "";  // wtf, no ammo type?
 220         }
 221 }
 222
 223 string GetAmmoName(int ammotype)
 224 {
 225         switch (ammotype)
 226         {
 227                 case RES_SHELLS:  return ITEM_Shells.m_name;
 228                 case RES_BULLETS: return ITEM_Bullets.m_name;
 229                 case RES_ROCKETS: return ITEM_Rockets.m_name;
 230                 case RES_CELLS:   return ITEM_Cells.m_name;
 231                 case RES_PLASMA:  return ITEM_Plasma.m_name;
 232                 case RES_FUEL:    return ITEM_JetpackFuel.m_name;
 233                 default:          return "batteries";
 234         }
 235 }
 236
 237 entity GetAmmoItem(int ammotype)
 238 {
 239         switch (ammotype)
 240         {
 241                 case RES_SHELLS:  return ITEM_Shells;
 242                 case RES_BULLETS: return ITEM_Bullets;
 243                 case RES_ROCKETS: return ITEM_Rockets;
 244                 case RES_CELLS:   return ITEM_Cells;
 245                 case RES_PLASMA:  return ITEM_Plasma;
 246                 case RES_FUEL:    return ITEM_JetpackFuel;
 247         }
 248         LOG_WARNF("Invalid ammo type %d ", ammotype);
 249         return NULL;
 250         // WEAPONTODO: use this generic func to reduce duplication ?
 251         // GetAmmoPicture  GetAmmoName  notif_arg_item_wepammo  ammo_pickupevalfunc ?
 252 }
 253
 254 #ifdef SVQC
 255 int GetAmmoConsumptionPrimary(string netname)
 256 // Returns ammo consumed per shot by the primary/default fire mode
 257 // Returns 0 if the netname has no ammo cvar
 258 {
 259         switch (netname)
 260         {
 261                 case "arc":        return autocvar_g_balance_arc_beam_ammo;
 262                 case "devastator": return autocvar_g_balance_devastator_ammo;
 263                 case "machinegun": return autocvar_g_balance_machinegun_sustained_ammo;
 264                 case "minelayer":  return autocvar_g_balance_minelayer_ammo;
 265                 case "seeker":     return autocvar_g_balance_seeker_tag_ammo;
 266                 default:           return cvar(strcat("g_balance_", netname, "_primary_ammo"));
 267         }
 268 }
 269 #endif
 270
 271 #ifdef CSQC
 272 int GetAmmoTypeFromNum(int i)
 273 {
 274         switch (i)
 275         {
 276                 case 0: return RES_SHELLS;
 277                 case 1: return RES_BULLETS;
 278                 case 2: return RES_ROCKETS;
 279                 case 3: return RES_CELLS;
 280                 case 4: return RES_PLASMA;
 281                 case 5: return RES_FUEL;
 282                 default: return RES_NONE;
 283         }
 284 }
 285
 286 int GetAmmoStat(int ammotype)
 287 {
 288         switch (ammotype)
 289         {
 290                 case RES_SHELLS: return STAT_SHELLS;
 291                 case RES_BULLETS: return STAT_NAILS;
 292                 case RES_ROCKETS: return STAT_ROCKETS;
 293                 case RES_CELLS: return STAT_CELLS;
 294                 case RES_PLASMA: return STAT_PLASMA.m_id;
 295                 case RES_FUEL: return STAT_FUEL.m_id;
 296                 default: return -1;
 297         }
 298 }
 299 #endif
 300
 301 string W_Sound(string w_snd)
 302 {
 303         string output = strcat("weapons/", w_snd);
 304         MUTATOR_CALLHOOK(WeaponSound, w_snd, output);
 305         return M_ARGV(1, string);
 306 }
 307
 308 string W_Model(string w_mdl)
 309 {
 310         string output = strcat("models/weapons/", w_mdl);
 311         MUTATOR_CALLHOOK(WeaponModel, w_mdl, output);
 312         return M_ARGV(1, string);
 313 }
 314
 315 #ifdef GAMEQC
 316 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
 317 {
 318         switch (algn)
 319         {
 320                 default:
 321                 case 3:
 322                         // right alignment
 323                         break;
 324                 case 4:
 325                         // left
 326                         vecs.y = -vecs.y;
 327                         break;
 328                 case 1:
 329                 case 2:
 330                         // center
 331                         vecs.y = 0;
 332                         vecs.z -= 2;
 333                         break;
 334         }
 335         return vecs;
 336 }
 337
 338 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn)
 339 {
 340         string s;
 341         if (visual)
 342         {
 343                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 344         }
 345         else if (STAT(SHOOTFROMEYE))
 346         {
 347                 vecs.y = vecs.z = 0;
 348         }
 349         else if (STAT(SHOOTFROMCENTER))
 350         {
 351                 vecs.y = 0;
 352                 vecs.z -= 2;
 353         }
 354         else if ((s = G_SHOOTFROMFIXEDORIGIN) != "")
 355         {
 356                 vector v = stov(s);
 357                 if (y_is_right) v.y = -v.y;
 358                 if (v.x != 0) vecs.x = v.x;
 359                 vecs.y = v.y;
 360                 vecs.z = v.z;
 361         }
 362         else  // just do the same as top
 363         {
 364                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 365         }
 366
 367         return vecs;
 368 }
 369
 370 #define shotorg_adjust shotorg_adjust_values
 371
 372 /**
 373  * supported formats:
 374  *
 375  * 1. simple animated model, muzzle flash handling on h_ model:
 376  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 377  *      tags:
 378  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 379  *        shell = casings ejection point (must be on the right hand side of the gun)
 380  *        weapon = attachment for v_tuba.md3
 381  *    v_tuba.md3 - first and third person model
 382  *    g_tuba.md3 - pickup model
 383  *
 384  * 2. simple animated model, muzzle flash handling on v_ model:
 385  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 386  *      tags:
 387  *        weapon = attachment for v_tuba.md3
 388  *    v_tuba.md3 - first and third person model
 389  *      tags:
 390  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 391  *        shell = casings ejection point (must be on the right hand side of the gun)
 392  *    g_tuba.md3 - pickup model
 393  *
 394  * 3. fully animated model, muzzle flash handling on h_ model:
 395  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 396  *      tags:
 397  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 398  *        shell = casings ejection point (must be on the right hand side of the gun)
 399  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 400  *    v_tuba.md3 - third person model
 401  *    g_tuba.md3 - pickup model
 402  *
 403  * 4. fully animated model, muzzle flash handling on v_ model:
 404  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 405  *      tags:
 406  *        shot = muzzle end (shot origin)
 407  *        shell = casings ejection point (must be on the right hand side of the gun)
 408  *    v_tuba.md3 - third person model
 409  *      tags:
 410  *        shot = muzzle end (for muzzle flashes)
 411  *    g_tuba.md3 - pickup model
 412  *
 413  * writes:
 414  *   this.origin, this.angles
 415  *   this.weaponchild
 416  *   this.movedir, this.view_ofs, this.movedir_aligned
 417  *   attachment stuff
 418  *   anim stuff
 419  * to free:
 420  *   call again with ""
 421  *   remove the ent
 422  */
 423 void CL_WeaponEntity_SetModel(entity this, string name, bool _anim)
 424 {
 425         if (name == "")
 426         {
 427                 vector oldmin = this.mins, oldmax = this.maxs;
 428                 setmodel(this, MDL_Null);
 429                 setsize(this, oldmin, oldmax);
 430                 if (this.weaponchild) delete(this.weaponchild);
 431                 this.weaponchild = NULL;
 432                 this.movedir = '0 0 0';
 433                 this.spawnorigin = '0 0 0';
 434                 this.oldorigin = '0 0 0';
 435                 this.anim_fire1  = '0 1 0.01';
 436                 this.anim_fire2  = '0 1 0.01';
 437                 this.anim_idle   = '0 1 0.01';
 438                 this.anim_reload = '0 1 0.01';
 439         }
 440         else
 441         {
 442                 // if there is a child entity, hide it until we're sure we use it
 443                 if (this.weaponchild) this.weaponchild.model = "";
 444                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
 445                 int v_shot_idx;  // used later
 446                 (v_shot_idx = gettagindex(this, "shot")) || (v_shot_idx = gettagindex(this, "tag_shot"));
 447
 448                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
 449                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 450                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
 451                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
 452                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
 453                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
 454
 455                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 456                 // if we don't, this is a "real" animated model
 457                 string t;
 458                 if ((t = "weapon", gettagindex(this, t)) || (t = "tag_weapon", gettagindex(this, t)))
 459                 {
 460                         if (!this.weaponchild)
 461                         {
 462                                 this.weaponchild = new(weaponchild);
 463 #ifdef CSQC
 464                                 this.weaponchild.drawmask = MASK_NORMAL;
 465                                 this.weaponchild.renderflags |= RF_VIEWMODEL;
 466 #endif
 467                         }
 468                         _setmodel(this.weaponchild, W_Model(strcat("v_", name, ".md3")));
 469                         setsize(this.weaponchild, '0 0 0', '0 0 0');
 470                         setattachment(this.weaponchild, this, t);
 471                 }
 472                 else
 473                 {
 474                         if (this.weaponchild) delete(this.weaponchild);
 475                         this.weaponchild = NULL;
 476                 }
 477
 478                 setsize(this, '0 0 0', '0 0 0');
 479                 setorigin(this, '0 0 0');
 480                 this.angles = '0 0 0';
 481                 this.frame = 0;
 482 #ifdef SVQC
 483                 this.viewmodelforclient = NULL;
 484 #else
 485                 this.renderflags &= ~RF_VIEWMODEL;
 486 #endif
 487                 if (v_shot_idx)  // v_ model attached to invisible h_ model
 488                 {
 489                         this.movedir = gettaginfo(this.weaponchild, v_shot_idx);
 490                 }
 491                 else
 492                 {
 493                         int idx;
 494                         if ((idx = gettagindex(this, "shot")) || (idx = gettagindex(this, "tag_shot")))
 495                         {
 496                                 this.movedir = gettaginfo(this, idx);
 497                         }
 498                         else
 499                         {
 500                                 LOG_WARNF("weapon model %s does not support the 'shot' tag, will display shots TOTALLY wrong",
 501                                         this.model);
 502                                 this.movedir = '0 0 0';
 503                         }
 504                 }
 505                 {
 506                         int idx = 0;
 507                         // v_ model attached to invisible h_ model
 508                         if (this.weaponchild
 509                                 && ((idx = gettagindex(this.weaponchild, "shell")) || (idx = gettagindex(this.weaponchild, "tag_shell"))))
 510                         {
 511                                 this.spawnorigin = gettaginfo(this.weaponchild, idx);
 512                         }
 513                         else if ((idx = gettagindex(this, "shell")) || (idx = gettagindex(this, "tag_shell")))
 514                         {
 515                                 this.spawnorigin = gettaginfo(this, idx);
 516                         }
 517                         else
 518                         {
 519                                 LOG_WARNF("weapon model %s does not support the 'shell' tag, will display casings wrong",
 520                                         this.model);
 521                                 this.spawnorigin = this.movedir;
 522                         }
 523                 }
 524                 if (v_shot_idx)
 525                 {
 526                         this.oldorigin = '0 0 0';  // use regular attachment
 527                 }
 528                 else
 529                 {
 530                         int idx;
 531                         if (this.weaponchild)
 532                                 (idx = gettagindex(this, "weapon")) || (idx = gettagindex(this, "tag_weapon"));
 533                         else
 534                                 (idx = gettagindex(this, "handle")) || (idx = gettagindex(this, "tag_handle"));
 535                         if (idx)
 536                         {
 537                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
 538                         }
 539                         else
 540                         {
 541                                 LOG_WARNF(
 542                                         "weapon model %s does not support the 'handle' tag "
 543                                         "and neither does the v_ model support the 'shot' tag, "
 544                                         "will display muzzle flashes TOTALLY wrong\n",
 545                                         this.model);
 546                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
 547                         }
 548                 }
 549
 550 #ifdef SVQC
 551                 this.viewmodelforclient = this.owner;
 552 #else
 553                 this.renderflags |= RF_VIEWMODEL;
 554 #endif
 555         }
 556
 557         this.view_ofs = '0 0 0';
 558         this.movedir_aligned = this.movedir;
 559
 560         if (this.movedir.x >= 0)
 561         {
 562                 //int algn = STAT(GUNALIGN, this.owner);
 563                 int algn = W_GunAlign(this, STAT(GUNALIGN, this.owner));
 564         #ifdef SVQC
 565                 this.m_gunalign = algn;
 566         #endif
 567                 vector v = this.movedir;
 568                 this.movedir = shotorg_adjust(v, false, false, algn);
 569                 this.movedir_aligned = shotorg_adjust(v, false, true, algn);
 570                 this.view_ofs = shotorg_adjust(v, false, true, algn) - v;
 571         }
 572         int compressed_shotorg = compressShotOrigin(this.movedir);
 573         // make them match perfectly
 574 #ifdef SVQC
 575         // null during init
 576         if (this.owner) STAT(SHOTORG, this.owner) = compressed_shotorg;
 577 #endif
 578         this.movedir = decompressShotOrigin(compressed_shotorg);
 579
 580         this.spawnorigin += this.view_ofs;  // offset the casings origin by the same amount
 581
 582         // check if an instant weapon switch occurred
 583         setorigin(this, this.view_ofs);
 584         if (!_anim) return;
 585         // reset animstate now
 586         this.wframe = WFRAME_IDLE;
 587         setanim(this, this.anim_idle, true, false, true);
 588 }
 589 #endif
 590
 591 #ifdef GAMEQC
 592
 593 REGISTER_NET_TEMP(wframe)
 594 #ifdef CSQC
 595 NET_HANDLE(wframe, bool isNew)
 596 {
 597         WFRAME fr = ReadByte();
 598         float t = ReadFloat();
 599         int slot = ReadByte();
 600         bool restartanim = ReadByte();
 601         entity wepent = viewmodels[slot];
 602         if(fr == WFRAME_IDLE)
 603                 wepent.animstate_looping = false; // we don't need to enforce idle animation
 604         else
 605         {
 606                 vector a = '0 0 0';
 607                 switch(fr)
 608                 {
 609                         default:
 610                         case WFRAME_IDLE: a = wepent.anim_idle; break;
 611                         case WFRAME_FIRE1: a = wepent.anim_fire1; break;
 612                         case WFRAME_FIRE2: a = wepent.anim_fire2; break;
 613                         case WFRAME_RELOAD: a = wepent.anim_reload; break;
 614                 }
 615                 a.z *= t;
 616                 anim_set(wepent, a, !restartanim, restartanim, restartanim);
 617         }
 618         wepent.state = ReadByte();
 619         wepent.weapon_nextthink = ReadFloat();
 620         switch (wepent.state)
 621         {
 622                 case WS_RAISE:
 623                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_raise;
 624                         break;
 625                 case WS_DROP:
 626                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_drop;
 627                         break;
 628                 default:
 629                         wepent.weapon_switchdelay = 0;
 630                         break;
 631         }
 632         return true;
 633 }
 634 #endif
 635
 636 #ifdef SVQC
 637 void wframe_send(entity actor, entity weaponentity, int wepframe, float attackrate, bool restartanim)
 638 {
 639         if (!IS_REAL_CLIENT(actor)) return;
 640         int channel = MSG_ONE;
 641         msg_entity = actor;
 642         WriteHeader(channel, wframe);
 643         WriteByte(channel, wepframe);
 644         WriteFloat(channel, attackrate);
 645         WriteByte(channel, weaponslot(weaponentity.weaponentity_fld));
 646         WriteByte(channel, restartanim);
 647         WriteByte(channel, weaponentity.state);
 648         WriteFloat(channel, weaponentity.weapon_nextthink);
 649 }
 650 #endif
 651
 652 REGISTER_NET_C2S(w_whereis)
 653 #ifdef SVQC
 654 void Weapon_whereis(Weapon this, entity cl);
 655 NET_HANDLE(w_whereis, bool)
 656 {
 657         Weapon wpn = ReadRegistered(Weapons);
 658         if (wpn != WEP_Null) Weapon_whereis(wpn, sender);
 659         return true;
 660 }
 661 #else
 662 void w_whereis(Weapon this)
 663 {
 664         int channel = MSG_C2S;
 665         WriteHeader(channel, w_whereis);
 666         WriteRegistered(Weapons, channel, this);
 667 }
 668 CLIENT_COMMAND(weapon_find, "Show spawn locations of a weapon")
 669 {
 670         switch (request)
 671         {
 672                 case CMD_REQUEST_COMMAND:
 673                 {
 674                         string s = argv(1);
 675                         if (s == "all")
 676                         {
 677                                 FOREACH(Weapons, it != WEP_Null, w_whereis(it));
 678                                 return;
 679                         }
 680                         if (s == "unowned")
 681                         {
 682                                 FOREACH(Weapons, it != WEP_Null && !(STAT(WEAPONS) & it.m_wepset), w_whereis(it));
 683                                 return;
 684                         }
 685                         FOREACH(Weapons, it != WEP_Null && it.netname == s,
 686                         {
 687                                 w_whereis(it);
 688                                 return;
 689                         });
 690                 }
 691                 default:
 692                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 693                 case CMD_REQUEST_USAGE:
 694                 {
 695                         LOG_HELP("Usage:^3 cl_cmd weapon_find weapon");
 696                         LOG_HELP("  Where 'weapon' is the lowercase weapon name, 'all' or 'unowned'.");
 697                         return;
 698                 }
 699         }
 700 }
 701 #endif
 702
 703 #ifdef SVQC
 704 void W_MuzzleFlash_Model_AttachToShotorg(entity actor, .entity weaponentity, entity flash, vector offset)
 705 {
 706         flash.owner = actor;
 707         flash.angles_z = random() * 360;
 708
 709         entity view = actor.(weaponentity);
 710         entity exterior = actor.exteriorweaponentity;
 711
 712         if (view.oldorigin.x > 0)
 713         {
 714                 setattachment(flash, exterior, "");
 715                 setorigin(flash, view.oldorigin + offset);
 716         }
 717         else
 718         {
 719                 if (gettagindex(exterior, "shot")) setattachment(flash, exterior, "shot");
 720                 else setattachment(flash, exterior, "tag_shot");
 721                 setorigin(flash, offset);
 722         }
 723 }
 724 #elif defined(CSQC)
 725 void W_MuzzleFlash_Model_AttachToShotorg(entity wepent, entity flash, vector offset)
 726 {
 727         flash.owner = wepent;
 728         flash.angles_z = random() * 360;
 729
 730         if (gettagindex(wepent, "shot")) setattachment(flash, wepent, "shot");
 731         else setattachment(flash, wepent, "tag_shot");
 732         setorigin(flash, offset);
 733 }
 734 #endif
 735
 736 void W_MuzzleFlash_Model_Think(entity this)
 737 {
 738         this.frame += 2;
 739         this.scale *= 0.5;
 740         this.alpha -= 0.25;
 741         this.nextthink = time + 0.05;
 742
 743         if(this.alpha <= 0)
 744         {
 745                 setthink(this, SUB_Remove);
 746                 this.nextthink = time;
 747                 this.realowner.muzzle_flash = NULL;
 748                 return;
 749         }
 750 }
 751
 752 void W_MuzzleFlash_Model(entity wepent, entity muzzlemodel)
 753 {
 754         if(wepent.muzzle_flash == NULL)
 755                 wepent.muzzle_flash = spawn();
 756
 757         entity flash = wepent.muzzle_flash;
 758         setmodel(flash, muzzlemodel); // precision set below
 759
 760         flash.scale = 0.75;
 761         setthink(flash, W_MuzzleFlash_Model_Think);
 762         flash.nextthink = time + 0.02;
 763         flash.frame = 2;
 764         flash.alpha = 0.75;
 765         flash.angles_z = random() * 180;
 766         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
 767         flash.owner = flash.realowner = wepent;
 768
 769 #ifdef CSQC
 770         flash.drawmask = MASK_NORMAL;
 771 #endif
 772 }
 773
 774 REGISTER_NET_TEMP(w_muzzleflash)
 775
 776 #ifdef SVQC
 777 void W_MuzzleFlash(Weapon thiswep, entity actor, .entity weaponentity, vector shotorg, vector shotdir)
 778 {
 779         // don't show an exterior muzzle effect for the off-hand
 780         if(weaponslot(weaponentity) == 0)
 781         {
 782                 Send_Effect_Except(thiswep.m_muzzleeffect, shotorg, shotdir * 1000, 1, actor);
 783
 784                 if(thiswep.m_muzzlemodel != MDL_Null)
 785                 {
 786                         W_MuzzleFlash_Model(actor.exteriorweaponentity, thiswep.m_muzzlemodel);
 787                         W_MuzzleFlash_Model_AttachToShotorg(actor, weaponentity, actor.exteriorweaponentity.muzzle_flash, '5 0 0');
 788                 }
 789         }
 790
 791         FOREACH_CLIENT(it == actor || (IS_SPEC(it) && it.enemy == actor),
 792         {
 793                 if(!IS_REAL_CLIENT(it))
 794                         continue;
 795                 int channel = MSG_ONE;
 796                 msg_entity = it;
 797                 WriteHeader(channel, w_muzzleflash);
 798                 WriteByte(channel, thiswep.m_id);
 799                 WriteByte(channel, weaponslot(weaponentity));
 800                 WriteVector(channel, shotorg);
 801         });
 802 }
 803 #elif defined(CSQC)
 804 NET_HANDLE(w_muzzleflash, bool isNew)
 805 {
 806         return = true;
 807         int weapon_id = ReadByte();
 808         int slot = ReadByte();
 809         vector sv_shotorg = ReadVector();
 810
 811         Weapon thiswep = REGISTRY_GET(Weapons, weapon_id);
 812         vector viewangles = getpropertyvec(VF_CL_VIEWANGLES);
 813         vector forward, right, up;
 814         MAKE_VECTORS(viewangles, forward, right, up);
 815
 816         if(autocvar_chase_active)
 817         {
 818                 // in third person mode, show the muzzle flash from the server side weapon position
 819                 // we don't have a view model to reference in this case
 820                 pointparticles(thiswep.m_muzzleeffect, sv_shotorg, forward * 1000, 1);
 821                 return;
 822         }
 823         if(!autocvar_r_drawviewmodel) return;
 824
 825         entity wepent = viewmodels[slot];
 826         // get the local player entity to calculate shot origin
 827         entity rlplayer = CSQCModel_server2csqc(player_localentnum - 1);
 828         if(!rlplayer)
 829                 rlplayer = csqcplayer; // fall back to the global
 830
 831         vector md = wepent.movedir_aligned;
 832         vector vecs = ((md.x > 0) ? md : '0 0 0');
 833         vector dv = forward * vecs.x + right * -vecs.y + up * vecs.z;
 834         vector org = rlplayer.origin + rlplayer.view_ofs + dv;
 835
 836         pointparticles(thiswep.m_muzzleeffect, org, forward * 1000, 1);
 837
 838         if(thiswep.m_muzzlemodel != MDL_Null)
 839         {
 840                 W_MuzzleFlash_Model(wepent, thiswep.m_muzzlemodel);
 841                 W_MuzzleFlash_Model_AttachToShotorg(wepent, wepent.muzzle_flash, '5 0 0');
 842         }
 843 }
 844 #endif
 845
 846
 847 #endif
 848
 849 #endif