qcsrc/common/weapons/all.qc

   1 #include "all.qh"
   2 #ifndef WEAPONS_ALL_C
   3 #define WEAPONS_ALL_C
   4
   5 #if defined(CSQC)
   6         #include <client/main.qh>
   7         #include <common/constants.qh>
   8         #include <common/deathtypes/all.qh>
   9         #include <common/physics/movetypes/movetypes.qh>
  10         #include <common/stats.qh>
  11         #include <common/util.qh>
  12         #include <common/weapons/calculations.qc>
  13         #include <common/weapons/weapon/_mod.inc>
  14         #include <lib/csqcmodel/cl_model.qh>
  15         #include <lib/csqcmodel/interpolate.qh>
  16         #include <lib/warpzone/anglestransform.qh>
  17         #include <lib/warpzone/client.qh>
  18         #include <lib/warpzone/common.qh>
  19 #elif defined(MENUQC)
  20         #include <common/weapons/weapon/_mod.inc>
  21 #elif defined(SVQC)
  22         #include <common/constants.qh>
  23         #include <common/deathtypes/all.qh>
  24         #include <common/items/_mod.qh>
  25         #include <common/mapinfo.qh>
  26         #include <common/monsters/_mod.qh>
  27         #include <common/notifications/all.qh>
  28         #include <common/stats.qh>
  29         #include <common/teams.qh>
  30         #include <common/util.qh>
  31         #include <common/weapons/calculations.qc>
  32         #include <common/weapons/config.qc>
  33         #include <common/weapons/config.qh>
  34         #include <common/weapons/weapon/_mod.inc>
  35         #include <lib/csqcmodel/sv_model.qh>
  36         #include <lib/warpzone/anglestransform.qh>
  37         #include <lib/warpzone/common.qh>
  38         #include <lib/warpzone/server.qh>
  39         #include <lib/warpzone/util_server.qh>
  40         #include <server/command/_mod.qh>
  41         #include <server/hook.qh>
  42         #include <server/items/spawning.qh>
  43         #include <server/mutators/_mod.qh>
  44         #include <server/portals.qh>
  45         #include <server/weapons/common.qh>
  46         #include <server/weapons/csqcprojectile.qh>
  47         #include <server/weapons/tracing.qh>
  48 #endif
  49
  50
  51 // WEAPON PLUGIN SYSTEM
  52
  53 WepSet _WepSet_FromWeapon(int a)
  54 {
  55         a -= WEP_FIRST;
  56         if (REGISTRY_MAX(Weapons) > 24)
  57                 if (a >= 24)
  58                 {
  59                         a -= 24;
  60                         if (REGISTRY_MAX(Weapons) > 48)
  61                                 if (a >= 24)
  62                                 {
  63                                         a -= 24;
  64                                         return '0 0 1' * BIT(a);
  65                                 }
  66                         return '0 1 0' * BIT(a);
  67                 }
  68         return '1 0 0' * BIT(a);
  69 }
  70 #ifdef SVQC
  71         void WriteWepSet(float dst, WepSet w)
  72         {
  73                 if (REGISTRY_MAX(Weapons) > 48) WriteInt72_t(dst, w);
  74                 else if (REGISTRY_MAX(Weapons) > 24) WriteInt48_t(dst, w);
  75                 else WriteInt24_t(dst, w.x);
  76         }
  77 #endif
  78 #ifdef CSQC
  79         WepSet WepSet_GetFromStat()
  80         {
  81                 return STAT(WEAPONS);
  82         }
  83         WepSet WepSet_GetFromStat_InMap()
  84         {
  85                 return STAT(WEAPONSINMAP);
  86         }
  87         WepSet ReadWepSet()
  88         {
  89                 if (REGISTRY_MAX(Weapons) > 48) return ReadInt72_t();
  90                 if (REGISTRY_MAX(Weapons) > 24) return ReadInt48_t();
  91                 return ReadInt24_t() * '1 0 0';
  92         }
  93 #endif
  94
  95 string W_FixWeaponOrder(string order, float complete)
  96 {
  97         return fixPriorityList(order, WEP_FIRST, WEP_LAST, WEP_IMPULSE_BEGIN - WEP_FIRST, complete);
  98 }
  99 string W_NameWeaponOrder_MapFunc(string s)
 100 {
 101         int i = stof(s);
 102         if (s == "0" || i)
 103         {
 104                 entity wi = REGISTRY_GET(Weapons, i);
 105                 if (wi != WEP_Null) return wi.netname;
 106         }
 107         return s;
 108 }
 109
 110 string W_NameWeaponOrder(string order)
 111 {
 112         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
 113 }
 114 string W_NumberWeaponOrder_MapFunc(string s)
 115 {
 116         if (s == "0" || stof(s)) return s;
 117         FOREACH(Weapons, it != WEP_Null && (it.netname == s || it.m_deprecated_netname == s), return ftos(i));
 118         return s;
 119 }
 120 string W_NumberWeaponOrder(string order)
 121 {
 122         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
 123 }
 124
 125 float W_FixWeaponOrder_BuildImpulseList_buf[REGISTRY_MAX(Weapons)];
 126 string W_FixWeaponOrder_BuildImpulseList_order;
 127 void W_FixWeaponOrder_BuildImpulseList_swap(int i, int j, entity pass)
 128 {
 129         float h;
 130         h = W_FixWeaponOrder_BuildImpulseList_buf[i];
 131         W_FixWeaponOrder_BuildImpulseList_buf[i] = W_FixWeaponOrder_BuildImpulseList_buf[j];
 132         W_FixWeaponOrder_BuildImpulseList_buf[j] = h;
 133 }
 134 float W_FixWeaponOrder_BuildImpulseList_cmp(int i, int j, entity pass)
 135 {
 136         int si = W_FixWeaponOrder_BuildImpulseList_buf[i];
 137         Weapon e1 = REGISTRY_GET(Weapons, si);
 138         int sj = W_FixWeaponOrder_BuildImpulseList_buf[j];
 139         Weapon e2 = REGISTRY_GET(Weapons, sj);
 140         int d = (e1.impulse + 9) % 10 - (e2.impulse + 9) % 10;
 141         if (d != 0) return -d;  // high impulse first!
 142         string s = strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " ");
 143         return strstrofs(s, sprintf(" %d ", si), 0)
 144                 - strstrofs(s, sprintf(" %d ", sj), 0); // low char index first!
 145 }
 146 string W_FixWeaponOrder_BuildImpulseList(string o)
 147 {
 148         int i;
 149         W_FixWeaponOrder_BuildImpulseList_order = o;
 150         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 151                 W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST] = i;
 152         heapsort(WEP_LAST - WEP_FIRST + 1, W_FixWeaponOrder_BuildImpulseList_swap, W_FixWeaponOrder_BuildImpulseList_cmp,
 153                 NULL);
 154         o = "";
 155         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 156                 o = strcat(o, " ", ftos(W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST]));
 157         W_FixWeaponOrder_BuildImpulseList_order = string_null;
 158         return substring(o, 1, -1);
 159 }
 160
 161 string W_FixWeaponOrder_AllowIncomplete(entity this, string order)
 162 {
 163         return W_FixWeaponOrder(order, 0);
 164 }
 165
 166 string W_FixWeaponOrder_ForceComplete(string order)
 167 {
 168         if (order == "") order = W_NumberWeaponOrder(cvar_defstring("cl_weaponpriority"));
 169         return W_FixWeaponOrder(order, 1);
 170 }
 171
 172 WepSet W_RandomWeapons(entity e, WepSet remaining, int n)
 173 {
 174         WepSet result = '0 0 0';
 175         for (int j = 0; j < n; ++j)
 176         {
 177                 RandomSelection_Init();
 178                 FOREACH(Weapons, it != WEP_Null, {
 179                         if (remaining & (it.m_wepset))
 180                                 RandomSelection_AddEnt(it, 1, 1);
 181                 });
 182                 Weapon w = RandomSelection_chosen_ent;
 183                 result |= WepSet_FromWeapon(w);
 184                 remaining &= ~WepSet_FromWeapon(w);
 185         }
 186         return result;
 187 }
 188
 189 // TODO: registry handles for below functions
 190 string GetAmmoPicture(Resource ammotype)
 191 {
 192         switch (ammotype)
 193         {
 194                 case RES_SHELLS:  return ITEM_Shells.m_icon;
 195                 case RES_BULLETS: return ITEM_Bullets.m_icon;
 196                 case RES_ROCKETS: return ITEM_Rockets.m_icon;
 197                 case RES_CELLS:   return ITEM_Cells.m_icon;
 198                 case RES_PLASMA:  return ITEM_Plasma.m_icon;
 199                 case RES_FUEL:    return ITEM_JetpackFuel.m_icon;
 200                 default: return "";  // wtf, no ammo type?
 201         }
 202 }
 203
 204 string GetAmmoName(Resource ammotype)
 205 {
 206         switch (ammotype)
 207         {
 208                 case RES_SHELLS:  return ITEM_Shells.m_name;
 209                 case RES_BULLETS: return ITEM_Bullets.m_name;
 210                 case RES_ROCKETS: return ITEM_Rockets.m_name;
 211                 case RES_CELLS:   return ITEM_Cells.m_name;
 212                 case RES_PLASMA:  return ITEM_Plasma.m_name;
 213                 case RES_FUEL:    return ITEM_JetpackFuel.m_name;
 214                 default:          return "batteries";
 215         }
 216 }
 217
 218 entity GetAmmoItem(Resource ammotype)
 219 {
 220         switch (ammotype)
 221         {
 222                 case RES_SHELLS:  return ITEM_Shells;
 223                 case RES_BULLETS: return ITEM_Bullets;
 224                 case RES_ROCKETS: return ITEM_Rockets;
 225                 case RES_CELLS:   return ITEM_Cells;
 226                 case RES_PLASMA:  return ITEM_Plasma;
 227                 case RES_FUEL:    return ITEM_JetpackFuel;
 228         }
 229         LOG_WARNF("Invalid ammo type %d ", ammotype.m_id);
 230         return NULL;
 231         // WEAPONTODO: use this generic func to reduce duplication ?
 232         // GetAmmoPicture  GetAmmoName  notif_arg_item_wepammo  ammo_pickupevalfunc ?
 233 }
 234
 235 #ifdef CSQC
 236 Resource GetAmmoTypeFromNum(int i)
 237 {
 238         switch (i)
 239         {
 240                 case 0: return RES_SHELLS;
 241                 case 1: return RES_BULLETS;
 242                 case 2: return RES_ROCKETS;
 243                 case 3: return RES_CELLS;
 244                 case 4: return RES_PLASMA;
 245                 case 5: return RES_FUEL;
 246                 default: return RES_NONE;
 247         }
 248 }
 249
 250 int GetAmmoStat(Resource ammotype)
 251 {
 252         switch (ammotype)
 253         {
 254                 case RES_SHELLS: return STAT_SHELLS;
 255                 case RES_BULLETS: return STAT_NAILS;
 256                 case RES_ROCKETS: return STAT_ROCKETS;
 257                 case RES_CELLS: return STAT_CELLS;
 258                 case RES_PLASMA: return STAT_PLASMA.m_id;
 259                 case RES_FUEL: return STAT_FUEL.m_id;
 260                 default: return -1;
 261         }
 262 }
 263 #endif
 264
 265 string W_Sound(string w_snd)
 266 {
 267         string output = strcat("weapons/", w_snd);
 268         MUTATOR_CALLHOOK(WeaponSound, w_snd, output);
 269         return M_ARGV(1, string);
 270 }
 271
 272 string W_Model(string w_mdl)
 273 {
 274         string output = strcat("models/weapons/", w_mdl);
 275         MUTATOR_CALLHOOK(WeaponModel, w_mdl, output);
 276         return M_ARGV(1, string);
 277 }
 278
 279 #ifdef GAMEQC
 280 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
 281 {
 282         switch (algn)
 283         {
 284                 default:
 285                 case 3:
 286                         // right alignment
 287                         break;
 288                 case 4:
 289                         // left
 290                         vecs.y = -vecs.y;
 291                         break;
 292                 case 1:
 293                 case 2:
 294                         // center
 295                         vecs.y = 0;
 296                         vecs.z -= 2;
 297                         break;
 298         }
 299         return vecs;
 300 }
 301
 302 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn)
 303 {
 304         string s;
 305         if (visual)
 306         {
 307                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 308         }
 309         else if (STAT(SHOOTFROMEYE))
 310         {
 311                 vecs.y = vecs.z = 0;
 312         }
 313         else if (STAT(SHOOTFROMCENTER))
 314         {
 315                 vecs.y = 0;
 316                 vecs.z -= 2;
 317         }
 318         else if ((s = G_SHOOTFROMFIXEDORIGIN) != "")
 319         {
 320                 vector v = stov(s);
 321                 if (y_is_right) v.y = -v.y;
 322                 if (v.x != 0) vecs.x = v.x;
 323                 vecs.y = v.y;
 324                 vecs.z = v.z;
 325         }
 326         else  // just do the same as top
 327         {
 328                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 329         }
 330
 331         return vecs;
 332 }
 333
 334 #define shotorg_adjust shotorg_adjust_values
 335
 336 /**
 337  * supported formats:
 338  *
 339  * 1. simple animated model, muzzle flash handling on h_ model:
 340  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 341  *      tags:
 342  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 343  *        shell = casings ejection point (must be on the right hand side of the gun)
 344  *        weapon = attachment for v_tuba.md3
 345  *    v_tuba.md3 - first and third person model
 346  *    g_tuba.md3 - pickup model
 347  *
 348  * 2. simple animated model, muzzle flash handling on v_ model:
 349  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 350  *      tags:
 351  *        weapon = attachment for v_tuba.md3
 352  *    v_tuba.md3 - first and third person model
 353  *      tags:
 354  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 355  *        shell = casings ejection point (must be on the right hand side of the gun)
 356  *    g_tuba.md3 - pickup model
 357  *
 358  * 3. fully animated model, muzzle flash handling on h_ model:
 359  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 360  *      tags:
 361  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 362  *        shell = casings ejection point (must be on the right hand side of the gun)
 363  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 364  *    v_tuba.md3 - third person model
 365  *    g_tuba.md3 - pickup model
 366  *
 367  * 4. fully animated model, muzzle flash handling on v_ model:
 368  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 369  *      tags:
 370  *        shot = muzzle end (shot origin)
 371  *        shell = casings ejection point (must be on the right hand side of the gun)
 372  *    v_tuba.md3 - third person model
 373  *      tags:
 374  *        shot = muzzle end (for muzzle flashes)
 375  *    g_tuba.md3 - pickup model
 376  *
 377  * writes:
 378  *   this.origin, this.angles
 379  *   this.weaponchild
 380  *   this.movedir, this.view_ofs, this.movedir_aligned
 381  *   this.spawnorigin (SVQC only)
 382  *   attachment stuff
 383  *   anim stuff
 384  * to free:
 385  *   call again with ""
 386  *   remove the ent
 387  */
 388 void CL_WeaponEntity_SetModel(entity this, string name, bool _anim)
 389 {
 390         if (name == "")
 391         {
 392                 vector oldmin = this.mins, oldmax = this.maxs;
 393                 setmodel(this, MDL_Null);
 394                 setsize(this, oldmin, oldmax);
 395                 if (this.weaponchild) delete(this.weaponchild);
 396                 this.weaponchild = NULL;
 397                 this.movedir = '0 0 0';
 398 #ifdef SVQC
 399                 this.spawnorigin = '0 0 0';
 400 #endif
 401                 this.oldorigin = '0 0 0';
 402                 this.anim_fire1  = '0 1 0.01';
 403                 this.anim_fire2  = '0 1 0.01';
 404                 this.anim_idle   = '0 1 0.01';
 405                 this.anim_reload = '0 1 0.01';
 406         }
 407         else
 408         {
 409                 // if there is a child entity, hide it until we're sure we use it
 410                 if (this.weaponchild) this.weaponchild.model = "";
 411                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
 412                 int v_shot_idx;  // used later
 413                 (v_shot_idx = gettagindex(this, "shot")) || (v_shot_idx = gettagindex(this, "tag_shot"));
 414
 415                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
 416                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 417                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
 418                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
 419                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
 420                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
 421
 422                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 423                 // if we don't, this is a "real" animated model
 424                 string t;
 425                 if ((t = "weapon", gettagindex(this, t)) || (t = "tag_weapon", gettagindex(this, t)))
 426                 {
 427                         if (!this.weaponchild)
 428                         {
 429                                 this.weaponchild = new(weaponchild);
 430 #ifdef CSQC
 431                                 this.weaponchild.drawmask = MASK_NORMAL;
 432                                 this.weaponchild.renderflags |= RF_VIEWMODEL;
 433 #endif
 434                         }
 435                         _setmodel(this.weaponchild, W_Model(strcat("v_", name, ".md3")));
 436                         setsize(this.weaponchild, '0 0 0', '0 0 0');
 437                         setattachment(this.weaponchild, this, t);
 438                 }
 439                 else
 440                 {
 441                         if (this.weaponchild) delete(this.weaponchild);
 442                         this.weaponchild = NULL;
 443                 }
 444
 445                 setsize(this, '0 0 0', '0 0 0');
 446                 setorigin(this, '0 0 0');
 447                 this.angles = '0 0 0';
 448                 this.frame = 0;
 449 #ifdef SVQC
 450                 this.viewmodelforclient = NULL;
 451 #else
 452                 this.renderflags &= ~RF_VIEWMODEL;
 453 #endif
 454                 if (v_shot_idx)  // v_ model attached to invisible h_ model
 455                 {
 456                         this.movedir = gettaginfo(this.weaponchild, v_shot_idx);
 457                 }
 458                 else
 459                 {
 460                         int idx;
 461                         if ((idx = gettagindex(this, "shot")) || (idx = gettagindex(this, "tag_shot")))
 462                         {
 463                                 this.movedir = gettaginfo(this, idx);
 464                         }
 465                         else
 466                         {
 467                                 LOG_WARNF("weapon model %s does not support the 'shot' tag, will display shots TOTALLY wrong",
 468                                         this.model);
 469                                 this.movedir = '0 0 0';
 470                         }
 471                 }
 472 #ifdef SVQC
 473                 {
 474                         int idx = 0;
 475                         // v_ model attached to invisible h_ model
 476                         if (this.weaponchild
 477                                 && ((idx = gettagindex(this.weaponchild, "shell")) || (idx = gettagindex(this.weaponchild, "tag_shell"))))
 478                         {
 479                                 this.spawnorigin = gettaginfo(this.weaponchild, idx);
 480                         }
 481                         else if ((idx = gettagindex(this, "shell")) || (idx = gettagindex(this, "tag_shell")))
 482                         {
 483                                 this.spawnorigin = gettaginfo(this, idx);
 484                         }
 485                         else
 486                         {
 487                                 LOG_WARNF("weapon model %s does not support the 'shell' tag, will display casings wrong",
 488                                         this.model);
 489                                 this.spawnorigin = this.movedir;
 490                         }
 491                 }
 492 #endif
 493                 if (v_shot_idx)
 494                 {
 495                         this.oldorigin = '0 0 0';  // use regular attachment
 496                 }
 497                 else
 498                 {
 499                         int idx;
 500                         if (this.weaponchild)
 501                                 (idx = gettagindex(this, "weapon")) || (idx = gettagindex(this, "tag_weapon"));
 502                         else
 503                                 (idx = gettagindex(this, "handle")) || (idx = gettagindex(this, "tag_handle"));
 504                         if (idx)
 505                         {
 506                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
 507                         }
 508                         else
 509                         {
 510                                 LOG_WARNF(
 511                                         "weapon model %s does not support the 'handle' tag "
 512                                         "and neither does the v_ model support the 'shot' tag, "
 513                                         "will display muzzle flashes TOTALLY wrong\n",
 514                                         this.model);
 515                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
 516                         }
 517                 }
 518
 519 #ifdef SVQC
 520                 this.viewmodelforclient = this.owner;
 521 #else
 522                 this.renderflags |= RF_VIEWMODEL;
 523 #endif
 524         }
 525
 526         this.view_ofs = '0 0 0';
 527         this.movedir_aligned = this.movedir;
 528
 529         if (this.movedir.x >= 0)
 530         {
 531                 //int algn = STAT(GUNALIGN, this.owner);
 532                 int algn = W_GunAlign(this, STAT(GUNALIGN, this.owner));
 533         #ifdef SVQC
 534                 this.m_gunalign = algn;
 535         #endif
 536                 vector v = this.movedir;
 537                 this.movedir = shotorg_adjust(v, false, false, algn);
 538                 this.movedir_aligned = shotorg_adjust(v, false, true, algn);
 539                 this.view_ofs = this.movedir_aligned - v;
 540         }
 541         int compressed_shotorg = compressShotOrigin(this.movedir);
 542         // make them match perfectly
 543 #ifdef SVQC
 544         // null during init
 545         if (this.owner) STAT(SHOTORG, this.owner) = compressed_shotorg;
 546 #endif
 547         this.movedir = decompressShotOrigin(compressed_shotorg);
 548
 549 #ifdef SVQC
 550         this.spawnorigin += this.view_ofs;  // offset the casings origin by the same amount
 551 #endif
 552
 553         // check if an instant weapon switch occurred
 554         setorigin(this, this.view_ofs);
 555         if (!_anim) return;
 556         // reset animstate now
 557         this.wframe = WFRAME_IDLE;
 558         setanim(this, this.anim_idle, true, false, true);
 559 }
 560 #endif
 561
 562 #ifdef GAMEQC
 563
 564 REGISTER_NET_TEMP(wframe)
 565 #ifdef CSQC
 566 NET_HANDLE(wframe, bool isNew)
 567 {
 568         WFRAME fr = ReadByte();
 569         float t = ReadFloat();
 570         int slot = ReadByte();
 571         bool restartanim = ReadByte();
 572         entity wepent = viewmodels[slot];
 573         if(fr == WFRAME_IDLE)
 574                 wepent.animstate_looping = false; // we don't need to enforce idle animation
 575         else
 576         {
 577                 vector a = '0 0 0';
 578                 switch(fr)
 579                 {
 580                         default:
 581                         case WFRAME_IDLE: a = wepent.anim_idle; break;
 582                         case WFRAME_FIRE1: a = wepent.anim_fire1; break;
 583                         case WFRAME_FIRE2: a = wepent.anim_fire2; break;
 584                         case WFRAME_RELOAD: a = wepent.anim_reload; break;
 585                 }
 586                 a.z *= t;
 587                 anim_set(wepent, a, !restartanim, restartanim, restartanim);
 588         }
 589         wepent.state = ReadByte();
 590         wepent.weapon_nextthink = ReadFloat();
 591         switch (wepent.state)
 592         {
 593                 case WS_RAISE:
 594                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_raise;
 595                         break;
 596                 case WS_DROP:
 597                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_drop;
 598                         break;
 599                 default:
 600                         wepent.weapon_switchdelay = 0;
 601                         break;
 602         }
 603         return true;
 604 }
 605 #endif
 606
 607 #ifdef SVQC
 608 void wframe_send(entity actor, entity weaponentity, int wepframe, float attackrate, bool restartanim)
 609 {
 610         if (!IS_REAL_CLIENT(actor)) return;
 611         int channel = MSG_ONE;
 612         msg_entity = actor;
 613         WriteHeader(channel, wframe);
 614         WriteByte(channel, wepframe);
 615         WriteFloat(channel, attackrate);
 616         WriteByte(channel, weaponslot(weaponentity.weaponentity_fld));
 617         WriteByte(channel, restartanim);
 618         WriteByte(channel, weaponentity.state);
 619         WriteFloat(channel, weaponentity.weapon_nextthink);
 620 }
 621 #endif
 622
 623 REGISTER_NET_C2S(w_whereis)
 624 #ifdef SVQC
 625 void Weapon_whereis(Weapon this, entity cl);
 626 NET_HANDLE(w_whereis, bool)
 627 {
 628         Weapon wpn = ReadRegistered(Weapons);
 629         if (wpn != WEP_Null) Weapon_whereis(wpn, sender);
 630         return true;
 631 }
 632 #else
 633 void w_whereis(Weapon this)
 634 {
 635         int channel = MSG_C2S;
 636         WriteHeader(channel, w_whereis);
 637         WriteRegistered(Weapons, channel, this);
 638 }
 639 CLIENT_COMMAND(weapon_find, "Show spawn locations of a weapon")
 640 {
 641         switch (request)
 642         {
 643                 case CMD_REQUEST_COMMAND:
 644                 {
 645                         string s = argv(1);
 646                         if (s == "all")
 647                         {
 648                                 FOREACH(Weapons, it != WEP_Null, w_whereis(it));
 649                                 return;
 650                         }
 651                         if (s == "unowned")
 652                         {
 653                                 FOREACH(Weapons, it != WEP_Null && !(STAT(WEAPONS) & it.m_wepset), w_whereis(it));
 654                                 return;
 655                         }
 656                         FOREACH(Weapons, it != WEP_Null && it.netname == s,
 657                         {
 658                                 w_whereis(it);
 659                                 return;
 660                         });
 661                 }
 662                 default:
 663                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 664                 case CMD_REQUEST_USAGE:
 665                 {
 666                         LOG_HELP("Usage:^3 cl_cmd weapon_find <weapon>");
 667                         LOG_HELP("  Where <weapon> is the lowercase weapon name, 'all' or 'unowned'.");
 668                         return;
 669                 }
 670         }
 671 }
 672 #endif
 673
 674 #ifdef SVQC
 675 void W_MuzzleFlash_Model_AttachToShotorg(entity actor, .entity weaponentity, entity flash, vector offset)
 676 {
 677         flash.owner = actor;
 678         flash.angles_z = random() * 360;
 679
 680         entity view = actor.(weaponentity);
 681         entity exterior = actor.exteriorweaponentity;
 682
 683         if (view.oldorigin.x > 0)
 684         {
 685                 setattachment(flash, exterior, "");
 686                 setorigin(flash, view.oldorigin + offset);
 687         }
 688         else
 689         {
 690                 if (gettagindex(exterior, "shot")) setattachment(flash, exterior, "shot");
 691                 else setattachment(flash, exterior, "tag_shot");
 692                 setorigin(flash, offset);
 693         }
 694 }
 695 #elif defined(CSQC)
 696 void W_MuzzleFlash_Model_AttachToShotorg(entity wepent, entity flash, vector offset)
 697 {
 698         flash.owner = wepent;
 699         flash.angles_z = random() * 360;
 700
 701         if (gettagindex(wepent, "shot")) setattachment(flash, wepent, "shot");
 702         else setattachment(flash, wepent, "tag_shot");
 703         setorigin(flash, offset);
 704 }
 705 #endif
 706
 707 void W_MuzzleFlash_Model_Think(entity this)
 708 {
 709         this.frame += 2;
 710         this.scale *= 0.5;
 711         this.alpha -= 0.25;
 712         this.nextthink = time + 0.05;
 713
 714         if(this.alpha <= 0)
 715         {
 716                 setthink(this, SUB_Remove);
 717                 this.nextthink = time;
 718                 this.realowner.muzzle_flash = NULL;
 719                 return;
 720         }
 721 }
 722
 723 void W_MuzzleFlash_Model(entity wepent, entity muzzlemodel)
 724 {
 725         if(wepent.muzzle_flash == NULL)
 726                 wepent.muzzle_flash = spawn();
 727
 728         entity flash = wepent.muzzle_flash;
 729         setmodel(flash, muzzlemodel); // precision set below
 730
 731         flash.scale = 0.75;
 732         setthink(flash, W_MuzzleFlash_Model_Think);
 733         flash.nextthink = time + 0.02;
 734         flash.frame = 2;
 735         flash.alpha = 0.75;
 736         flash.angles_z = random() * 180;
 737         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
 738         flash.owner = flash.realowner = wepent;
 739
 740 #ifdef CSQC
 741         flash.drawmask = MASK_NORMAL;
 742 #endif
 743 }
 744
 745 REGISTER_NET_TEMP(w_muzzleflash)
 746
 747 #ifdef SVQC
 748 void W_MuzzleFlash(Weapon thiswep, entity actor, .entity weaponentity, vector shotorg, vector shotdir)
 749 {
 750         // don't show an exterior muzzle effect for the off-hand
 751         if(weaponslot(weaponentity) == 0)
 752         {
 753                 Send_Effect_Except(thiswep.m_muzzleeffect, shotorg, shotdir * 1000, 1, actor);
 754
 755                 if(thiswep.m_muzzlemodel != MDL_Null)
 756                 {
 757                         W_MuzzleFlash_Model(actor.exteriorweaponentity, thiswep.m_muzzlemodel);
 758                         W_MuzzleFlash_Model_AttachToShotorg(actor, weaponentity, actor.exteriorweaponentity.muzzle_flash, '5 0 0');
 759                 }
 760         }
 761
 762         FOREACH_CLIENT(it == actor || (IS_SPEC(it) && it.enemy == actor),
 763         {
 764                 if(!IS_REAL_CLIENT(it))
 765                         continue;
 766                 int channel = MSG_ONE;
 767                 msg_entity = it;
 768                 WriteHeader(channel, w_muzzleflash);
 769                 WriteByte(channel, thiswep.m_id);
 770                 WriteByte(channel, weaponslot(weaponentity));
 771                 WriteVector(channel, shotorg);
 772         });
 773 }
 774 #elif defined(CSQC)
 775 NET_HANDLE(w_muzzleflash, bool isNew)
 776 {
 777         return = true;
 778         int weapon_id = ReadByte();
 779         int slot = ReadByte();
 780         vector sv_shotorg = ReadVector();
 781
 782         Weapon thiswep = REGISTRY_GET(Weapons, weapon_id);
 783         vector viewangles = getpropertyvec(VF_CL_VIEWANGLES);
 784         vector forward, right, up;
 785         MAKE_VECTORS(viewangles, forward, right, up);
 786
 787         if(autocvar_chase_active)
 788         {
 789                 // in third person mode, show the muzzle flash from the server side weapon position
 790                 // we don't have a view model to reference in this case
 791                 pointparticles(thiswep.m_muzzleeffect, sv_shotorg, forward * 1000, 1);
 792                 return;
 793         }
 794         if(!autocvar_r_drawviewmodel) return;
 795
 796         entity wepent = viewmodels[slot];
 797         // get the local player entity to calculate shot origin
 798         entity rlplayer = CSQCModel_server2csqc(player_localentnum - 1);
 799         if(!rlplayer)
 800                 rlplayer = csqcplayer; // fall back to the global
 801
 802         vector md = wepent.movedir_aligned;
 803         vector vecs = ((md.x > 0) ? md : '0 0 0');
 804         vector dv = forward * vecs.x + right * -vecs.y + up * vecs.z;
 805         vector org = rlplayer.origin + rlplayer.view_ofs + dv;
 806
 807         pointparticles(thiswep.m_muzzleeffect, org, forward * 1000, 1);
 808
 809         if(thiswep.m_muzzlemodel != MDL_Null)
 810         {
 811                 W_MuzzleFlash_Model(wepent, thiswep.m_muzzlemodel);
 812                 W_MuzzleFlash_Model_AttachToShotorg(wepent, wepent.muzzle_flash, '5 0 0');
 813         }
 814 }
 815 #endif
 816
 817
 818 #endif
 819
 820 #endif
 821
 822 #ifdef SVQC
 823 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 824 {
 825         string o = W_FixWeaponOrder_ForceComplete(wo);
 826         strcpy(CS_CVAR(this).weaponorder_byimpulse, W_FixWeaponOrder_BuildImpulseList(o));
 827         return o;
 828 }
 829 #endif
 830
 831 #ifdef CSQC
 832 REPLICATE(cvar_cl_accuracy_data_share, bool, "cl_accuracy_data_share");
 833 REPLICATE(cvar_cl_accuracy_data_receive, bool, "cl_accuracy_data_receive");
 834 #endif
 835
 836 #ifdef GAMEQC
 837 REPLICATE(cvar_cl_gunalign, int, "cl_gunalign");
 838 REPLICATE(cvar_cl_weapon_switch_reload, bool, "cl_weapon_switch_reload");
 839 REPLICATE(cvar_cl_weapon_switch_fallback_to_impulse, bool, "cl_weapon_switch_fallback_to_impulse");
 840 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 841 REPLICATE(cvar_cl_weaponpriority, string, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 842 REPLICATE(cvar_cl_weaponpriorities[0], string, "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 843 REPLICATE(cvar_cl_weaponpriorities[1], string, "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 844 REPLICATE(cvar_cl_weaponpriorities[2], string, "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 845 REPLICATE(cvar_cl_weaponpriorities[3], string, "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 846 REPLICATE(cvar_cl_weaponpriorities[4], string, "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 847 REPLICATE(cvar_cl_weaponpriorities[5], string, "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 848 REPLICATE(cvar_cl_weaponpriorities[6], string, "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 849 REPLICATE(cvar_cl_weaponpriorities[7], string, "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 850 REPLICATE(cvar_cl_weaponpriorities[8], string, "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 851 REPLICATE(cvar_cl_weaponpriorities[9], string, "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 852 #endif