qcsrc/common/weapons/all.qc

   1 #include "all.qh"
   2 #ifndef WEAPONS_ALL_C
   3 #define WEAPONS_ALL_C
   4
   5 #if defined(CSQC)
   6         #include <client/main.qh>
   7         #include <common/constants.qh>
   8         #include <common/deathtypes/all.qh>
   9         #include <common/physics/movetypes/movetypes.qh>
  10         #include <common/stats.qh>
  11         #include <common/util.qh>
  12         #include <common/weapons/calculations.qc>
  13         #include <common/weapons/weapon/_mod.inc>
  14         #include <lib/csqcmodel/cl_model.qh>
  15         #include <lib/csqcmodel/interpolate.qh>
  16         #include <lib/warpzone/anglestransform.qh>
  17         #include <lib/warpzone/client.qh>
  18         #include <lib/warpzone/common.qh>
  19 #elif defined(MENUQC)
  20         #include <common/weapons/weapon/_mod.inc>
  21 #elif defined(SVQC)
  22         #include <common/constants.qh>
  23         #include <common/deathtypes/all.qh>
  24         #include <common/items/_mod.qh>
  25         #include <common/mapinfo.qh>
  26         #include <common/monsters/_mod.qh>
  27         #include <common/notifications/all.qh>
  28         #include <common/stats.qh>
  29         #include <common/teams.qh>
  30         #include <common/util.qh>
  31         #include <common/weapons/calculations.qc>
  32         #include <common/weapons/config.qc>
  33         #include <common/weapons/config.qh>
  34         #include <common/weapons/weapon/_mod.inc>
  35         #include <lib/csqcmodel/sv_model.qh>
  36         #include <lib/warpzone/anglestransform.qh>
  37         #include <lib/warpzone/common.qh>
  38         #include <lib/warpzone/server.qh>
  39         #include <lib/warpzone/util_server.qh>
  40         #include <server/command/_mod.qh>
  41         #include <server/hook.qh>
  42         #include <server/items/spawning.qh>
  43         #include <server/mutators/_mod.qh>
  44         #include <server/portals.qh>
  45         #include <server/weapons/common.qh>
  46         #include <server/weapons/csqcprojectile.qh>
  47         #include <server/weapons/tracing.qh>
  48 #endif
  49
  50
  51 // WEAPON PLUGIN SYSTEM
  52
  53 WepSet _WepSet_FromWeapon(int a)
  54 {
  55         a -= WEP_FIRST;
  56         if (REGISTRY_MAX(Weapons) > 24)
  57                 if (a >= 24)
  58                 {
  59                         a -= 24;
  60                         if (REGISTRY_MAX(Weapons) > 48)
  61                                 if (a >= 24)
  62                                 {
  63                                         a -= 24;
  64                                         return '0 0 1' * BIT(a);
  65                                 }
  66                         return '0 1 0' * BIT(a);
  67                 }
  68         return '1 0 0' * BIT(a);
  69 }
  70 #ifdef SVQC
  71         void WriteWepSet(float dst, WepSet w)
  72         {
  73                 if (REGISTRY_MAX(Weapons) > 48) WriteInt72_t(dst, w);
  74                 else if (REGISTRY_MAX(Weapons) > 24) WriteInt48_t(dst, w);
  75                 else WriteInt24_t(dst, w.x);
  76         }
  77 #endif
  78 #ifdef CSQC
  79         WepSet WepSet_GetFromStat()
  80         {
  81                 return STAT(WEAPONS);
  82         }
  83         WepSet WepSet_GetFromStat_InMap()
  84         {
  85                 return STAT(WEAPONSINMAP);
  86         }
  87         WepSet ReadWepSet()
  88         {
  89                 if (REGISTRY_MAX(Weapons) > 48) return ReadInt72_t();
  90                 if (REGISTRY_MAX(Weapons) > 24) return ReadInt48_t();
  91                 return ReadInt24_t() * '1 0 0';
  92         }
  93 #endif
  94
  95 string W_FixWeaponOrder(string order, float complete)
  96 {
  97         return fixPriorityList(order, WEP_FIRST, WEP_LAST, WEP_IMPULSE_BEGIN - WEP_FIRST, complete);
  98 }
  99 string W_NameWeaponOrder_MapFunc(string s)
 100 {
 101         int i = stof(s);
 102         if (s == "0" || i)
 103         {
 104                 entity wi = REGISTRY_GET(Weapons, i);
 105                 if (wi != WEP_Null) return wi.netname;
 106         }
 107         return s;
 108 }
 109
 110 string W_NameWeaponOrder(string order)
 111 {
 112         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
 113 }
 114 string W_NumberWeaponOrder_MapFunc(string s)
 115 {
 116         if (s == "0" || stof(s)) return s;
 117         FOREACH(Weapons, it != WEP_Null && (it.netname == s || it.m_deprecated_netname == s), return ftos(i));
 118         return s;
 119 }
 120 string W_NumberWeaponOrder(string order)
 121 {
 122         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
 123 }
 124
 125 float W_FixWeaponOrder_BuildImpulseList_buf[REGISTRY_MAX(Weapons)];
 126 string W_FixWeaponOrder_BuildImpulseList_order;
 127 void W_FixWeaponOrder_BuildImpulseList_swap(int i, int j, entity pass)
 128 {
 129         float h;
 130         h = W_FixWeaponOrder_BuildImpulseList_buf[i];
 131         W_FixWeaponOrder_BuildImpulseList_buf[i] = W_FixWeaponOrder_BuildImpulseList_buf[j];
 132         W_FixWeaponOrder_BuildImpulseList_buf[j] = h;
 133 }
 134 float W_FixWeaponOrder_BuildImpulseList_cmp(int i, int j, entity pass)
 135 {
 136         int si = W_FixWeaponOrder_BuildImpulseList_buf[i];
 137         Weapon e1 = REGISTRY_GET(Weapons, si);
 138         int sj = W_FixWeaponOrder_BuildImpulseList_buf[j];
 139         Weapon e2 = REGISTRY_GET(Weapons, sj);
 140         int d = (e1.impulse + 9) % 10 - (e2.impulse + 9) % 10;
 141         if (d != 0) return -d;  // high impulse first!
 142         string s = strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " ");
 143         return strstrofs(s, sprintf(" %d ", si), 0)
 144                 - strstrofs(s, sprintf(" %d ", sj), 0); // low char index first!
 145 }
 146 string W_FixWeaponOrder_BuildImpulseList(string o)
 147 {
 148         int i;
 149         W_FixWeaponOrder_BuildImpulseList_order = o;
 150         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 151                 W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST] = i;
 152         heapsort(WEP_LAST - WEP_FIRST + 1, W_FixWeaponOrder_BuildImpulseList_swap, W_FixWeaponOrder_BuildImpulseList_cmp,
 153                 NULL);
 154         o = "";
 155         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 156                 o = strcat(o, " ", ftos(W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST]));
 157         W_FixWeaponOrder_BuildImpulseList_order = string_null;
 158         return substring(o, 1, -1);
 159 }
 160
 161 string W_FixWeaponOrder_AllowIncomplete(entity this, string order)
 162 {
 163         return W_FixWeaponOrder(order, 0);
 164 }
 165
 166 string W_FixWeaponOrder_ForceComplete(string order)
 167 {
 168         if (order == "") order = W_NumberWeaponOrder(cvar_defstring("cl_weaponpriority"));
 169         return W_FixWeaponOrder(order, 1);
 170 }
 171
 172 WepSet W_RandomWeapons(entity e, WepSet remaining, int n)
 173 {
 174         WepSet result = '0 0 0';
 175         for (int j = 0; j < n; ++j)
 176         {
 177                 RandomSelection_Init();
 178                 FOREACH(Weapons, it != WEP_Null, {
 179                         if (remaining & (it.m_wepset))
 180                                 RandomSelection_AddEnt(it, 1, 1);
 181                 });
 182                 Weapon w = RandomSelection_chosen_ent;
 183                 result |= WepSet_FromWeapon(w);
 184                 remaining &= ~WepSet_FromWeapon(w);
 185         }
 186         return result;
 187 }
 188
 189 // TODO: registry handles for below functions
 190 string GetAmmoPicture(Resource ammotype)
 191 {
 192         switch (ammotype)
 193         {
 194                 case RES_SHELLS:  return ITEM_Shells.m_icon;
 195                 case RES_BULLETS: return ITEM_Bullets.m_icon;
 196                 case RES_ROCKETS: return ITEM_Rockets.m_icon;
 197                 case RES_CELLS:   return ITEM_Cells.m_icon;
 198                 case RES_PLASMA:  return ITEM_Plasma.m_icon;
 199                 case RES_FUEL:    return ITEM_JetpackFuel.m_icon;
 200                 default: return "";  // wtf, no ammo type?
 201         }
 202 }
 203
 204 string GetAmmoName(Resource ammotype)
 205 {
 206         switch (ammotype)
 207         {
 208                 case RES_SHELLS:  return ITEM_Shells.m_name;
 209                 case RES_BULLETS: return ITEM_Bullets.m_name;
 210                 case RES_ROCKETS: return ITEM_Rockets.m_name;
 211                 case RES_CELLS:   return ITEM_Cells.m_name;
 212                 case RES_PLASMA:  return ITEM_Plasma.m_name;
 213                 case RES_FUEL:    return ITEM_JetpackFuel.m_name;
 214                 default:          return "batteries";
 215         }
 216 }
 217
 218 entity GetAmmoItem(Resource ammotype)
 219 {
 220         switch (ammotype)
 221         {
 222                 case RES_SHELLS:  return ITEM_Shells;
 223                 case RES_BULLETS: return ITEM_Bullets;
 224                 case RES_ROCKETS: return ITEM_Rockets;
 225                 case RES_CELLS:   return ITEM_Cells;
 226                 case RES_PLASMA:  return ITEM_Plasma;
 227                 case RES_FUEL:    return ITEM_JetpackFuel;
 228         }
 229         LOG_WARNF("Invalid ammo type %d ", ammotype.m_id);
 230         return NULL;
 231         // WEAPONTODO: use this generic func to reduce duplication ?
 232         // GetAmmoPicture  GetAmmoName  notif_arg_item_wepammo  ammo_pickupevalfunc ?
 233 }
 234
 235 #ifdef CSQC
 236 int GetAmmoStat(Resource ammotype)
 237 {
 238         switch (ammotype)
 239         {
 240                 case RES_SHELLS: return STAT_SHELLS;
 241                 case RES_BULLETS: return STAT_NAILS;
 242                 case RES_ROCKETS: return STAT_ROCKETS;
 243                 case RES_CELLS: return STAT_CELLS;
 244                 case RES_PLASMA: return STAT_PLASMA.m_id;
 245                 case RES_FUEL: return STAT_FUEL.m_id;
 246                 default: return -1;
 247         }
 248 }
 249 #endif
 250
 251 string W_Sound(string w_snd)
 252 {
 253         string output = strcat("weapons/", w_snd);
 254         MUTATOR_CALLHOOK(WeaponSound, w_snd, output);
 255         return M_ARGV(1, string);
 256 }
 257
 258 string W_Model(string w_mdl)
 259 {
 260         string output = strcat("models/weapons/", w_mdl);
 261         MUTATOR_CALLHOOK(WeaponModel, w_mdl, output);
 262         return M_ARGV(1, string);
 263 }
 264
 265 #ifdef GAMEQC
 266 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
 267 {
 268         switch (algn)
 269         {
 270                 default:
 271                 case 3:
 272                         // right alignment
 273                         break;
 274                 case 4:
 275                         // left
 276                         vecs.y = -vecs.y;
 277                         break;
 278                 case 1:
 279                 case 2:
 280                         // center
 281                         vecs.y = 0;
 282                         vecs.z -= 2;
 283                         break;
 284         }
 285         return vecs;
 286 }
 287
 288 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn)
 289 {
 290         string s;
 291         if (visual)
 292         {
 293                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 294         }
 295         else if (STAT(SHOOTFROMEYE))
 296         {
 297                 vecs.y = vecs.z = 0;
 298         }
 299         else if (STAT(SHOOTFROMCENTER))
 300         {
 301                 vecs.y = 0;
 302                 vecs.z -= 2;
 303         }
 304         else if ((s = G_SHOOTFROMFIXEDORIGIN) != "")
 305         {
 306                 vector v = stov(s);
 307                 if (y_is_right) v.y = -v.y;
 308                 if (v.x != 0) vecs.x = v.x;
 309                 vecs.y = v.y;
 310                 vecs.z = v.z;
 311         }
 312         else  // just do the same as top
 313         {
 314                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 315         }
 316
 317         return vecs;
 318 }
 319
 320 #define shotorg_adjust shotorg_adjust_values
 321
 322 /**
 323  * supported formats:
 324  *
 325  * 1. simple animated model, muzzle flash handling on h_ model:
 326  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 327  *      tags:
 328  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 329  *        shell = casings ejection point (must be on the right hand side of the gun)
 330  *        weapon = attachment for v_tuba.md3
 331  *    v_tuba.md3 - first and third person model
 332  *    g_tuba.md3 - pickup model
 333  *
 334  * 2. simple animated model, muzzle flash handling on v_ model:
 335  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 336  *      tags:
 337  *        weapon = attachment for v_tuba.md3
 338  *    v_tuba.md3 - first and third person model
 339  *      tags:
 340  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 341  *        shell = casings ejection point (must be on the right hand side of the gun)
 342  *    g_tuba.md3 - pickup model
 343  *
 344  * 3. fully animated model, muzzle flash handling on h_ model:
 345  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 346  *      tags:
 347  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 348  *        shell = casings ejection point (must be on the right hand side of the gun)
 349  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 350  *    v_tuba.md3 - third person model
 351  *    g_tuba.md3 - pickup model
 352  *
 353  * 4. fully animated model, muzzle flash handling on v_ model:
 354  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 355  *      tags:
 356  *        shot = muzzle end (shot origin)
 357  *        shell = casings ejection point (must be on the right hand side of the gun)
 358  *    v_tuba.md3 - third person model
 359  *      tags:
 360  *        shot = muzzle end (for muzzle flashes)
 361  *    g_tuba.md3 - pickup model
 362  *
 363  * writes:
 364  *   this.origin, this.angles
 365  *   this.weaponchild
 366  *   this.movedir, this.view_ofs, this.movedir_aligned
 367  *   this.spawnorigin (SVQC only)
 368  *   attachment stuff
 369  *   anim stuff
 370  * to free:
 371  *   call again with ""
 372  *   remove the ent
 373  */
 374 void CL_WeaponEntity_SetModel(entity this, string name, bool _anim)
 375 {
 376         if (name == "")
 377         {
 378                 vector oldmin = this.mins, oldmax = this.maxs;
 379                 setmodel(this, MDL_Null);
 380                 setsize(this, oldmin, oldmax);
 381                 if (this.weaponchild) delete(this.weaponchild);
 382                 this.weaponchild = NULL;
 383                 this.movedir = '0 0 0';
 384 #ifdef SVQC
 385                 this.spawnorigin = '0 0 0';
 386 #endif
 387                 this.oldorigin = '0 0 0';
 388                 this.anim_fire1  = '0 1 0.01';
 389                 this.anim_fire2  = '0 1 0.01';
 390                 this.anim_idle   = '0 1 0.01';
 391                 this.anim_reload = '0 1 0.01';
 392         }
 393         else
 394         {
 395                 // if there is a child entity, hide it until we're sure we use it
 396                 if (this.weaponchild) this.weaponchild.model = "";
 397                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
 398                 int v_shot_idx;  // used later
 399                 (v_shot_idx = gettagindex(this, "shot")) || (v_shot_idx = gettagindex(this, "tag_shot"));
 400
 401                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
 402                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 403                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
 404                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
 405                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
 406                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
 407
 408                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 409                 // if we don't, this is a "real" animated model
 410                 string t;
 411                 if ((t = "weapon", gettagindex(this, t)) || (t = "tag_weapon", gettagindex(this, t)))
 412                 {
 413                         if (!this.weaponchild)
 414                         {
 415                                 this.weaponchild = new(weaponchild);
 416 #ifdef CSQC
 417                                 this.weaponchild.drawmask = MASK_NORMAL;
 418                                 this.weaponchild.renderflags |= RF_VIEWMODEL;
 419 #endif
 420                         }
 421                         _setmodel(this.weaponchild, W_Model(strcat("v_", name, ".md3")));
 422                         setsize(this.weaponchild, '0 0 0', '0 0 0');
 423                         setattachment(this.weaponchild, this, t);
 424                 }
 425                 else
 426                 {
 427                         if (this.weaponchild) delete(this.weaponchild);
 428                         this.weaponchild = NULL;
 429                 }
 430
 431                 setsize(this, '0 0 0', '0 0 0');
 432                 setorigin(this, '0 0 0');
 433                 this.angles = '0 0 0';
 434                 this.frame = 0;
 435 #ifdef SVQC
 436                 this.viewmodelforclient = NULL;
 437 #else
 438                 this.renderflags &= ~RF_VIEWMODEL;
 439 #endif
 440                 if (v_shot_idx)  // v_ model attached to invisible h_ model
 441                 {
 442                         this.movedir = gettaginfo(this.weaponchild, v_shot_idx);
 443                 }
 444                 else
 445                 {
 446                         int idx;
 447                         if ((idx = gettagindex(this, "shot")) || (idx = gettagindex(this, "tag_shot")))
 448                         {
 449                                 this.movedir = gettaginfo(this, idx);
 450                         }
 451                         else
 452                         {
 453                                 LOG_WARNF("weapon model %s does not support the 'shot' tag, will display shots TOTALLY wrong",
 454                                         this.model);
 455                                 this.movedir = '0 0 0';
 456                         }
 457                 }
 458 #ifdef SVQC
 459                 {
 460                         int idx = 0;
 461                         // v_ model attached to invisible h_ model
 462                         if (this.weaponchild
 463                                 && ((idx = gettagindex(this.weaponchild, "shell")) || (idx = gettagindex(this.weaponchild, "tag_shell"))))
 464                         {
 465                                 this.spawnorigin = gettaginfo(this.weaponchild, idx);
 466                         }
 467                         else if ((idx = gettagindex(this, "shell")) || (idx = gettagindex(this, "tag_shell")))
 468                         {
 469                                 this.spawnorigin = gettaginfo(this, idx);
 470                         }
 471                         else
 472                         {
 473                                 LOG_WARNF("weapon model %s does not support the 'shell' tag, will display casings wrong",
 474                                         this.model);
 475                                 this.spawnorigin = this.movedir;
 476                         }
 477                 }
 478 #endif
 479                 if (v_shot_idx)
 480                 {
 481                         this.oldorigin = '0 0 0';  // use regular attachment
 482                 }
 483                 else
 484                 {
 485                         int idx;
 486                         if (this.weaponchild)
 487                                 (idx = gettagindex(this, "weapon")) || (idx = gettagindex(this, "tag_weapon"));
 488                         else
 489                                 (idx = gettagindex(this, "handle")) || (idx = gettagindex(this, "tag_handle"));
 490                         if (idx)
 491                         {
 492                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
 493                         }
 494                         else
 495                         {
 496                                 LOG_WARNF(
 497                                         "weapon model %s does not support the 'handle' tag "
 498                                         "and neither does the v_ model support the 'shot' tag, "
 499                                         "will display muzzle flashes TOTALLY wrong\n",
 500                                         this.model);
 501                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
 502                         }
 503                 }
 504
 505 #ifdef SVQC
 506                 this.viewmodelforclient = this.owner;
 507 #else
 508                 this.renderflags |= RF_VIEWMODEL;
 509 #endif
 510         }
 511
 512         this.view_ofs = '0 0 0';
 513         this.movedir_aligned = this.movedir;
 514
 515         if (this.movedir.x >= 0)
 516         {
 517                 //int algn = STAT(GUNALIGN, this.owner);
 518                 int algn = W_GunAlign(this, STAT(GUNALIGN, this.owner));
 519         #ifdef SVQC
 520                 this.m_gunalign = algn;
 521         #endif
 522                 vector v = this.movedir;
 523                 this.movedir = shotorg_adjust(v, false, false, algn);
 524                 this.movedir_aligned = shotorg_adjust(v, false, true, algn);
 525                 this.view_ofs = this.movedir_aligned - v;
 526         }
 527
 528         // shotorg_adjust can give negative .x from shootfromfixedorigin
 529         // recheck .x here due to it
 530         if (this.movedir.x >= 0)
 531         {
 532                 int compressed_shotorg = compressShotOrigin(this.movedir);
 533                 // make them match perfectly
 534         #ifdef SVQC
 535                 // null during init
 536                 if (this.owner) STAT(SHOTORG, this.owner) = compressed_shotorg;
 537         #endif
 538                 this.movedir = decompressShotOrigin(compressed_shotorg);
 539         }
 540         else
 541         {
 542                 // don't support negative x shotorgs
 543                 this.movedir = '0 0 0';
 544
 545                 // reset _aligned here too even though as a side effect
 546                 // g_shootfromfixedorigin can make it reset
 547                 // it'd be only slightly better if it was checked individually
 548                 this.movedir_aligned = '0 0 0';
 549
 550         #ifdef SVQC
 551                 // null during init
 552                 if (this.owner) STAT(SHOTORG, this.owner) = 0;
 553         #endif
 554         }
 555
 556 #ifdef SVQC
 557         this.spawnorigin += this.view_ofs;  // offset the casings origin by the same amount
 558 #endif
 559
 560         // check if an instant weapon switch occurred
 561         setorigin(this, this.view_ofs);
 562         if (!_anim) return;
 563         // reset animstate now
 564         this.wframe = WFRAME_IDLE;
 565         setanim(this, this.anim_idle, true, false, true);
 566 }
 567 #endif
 568
 569 #ifdef GAMEQC
 570
 571 REGISTER_NET_TEMP(wframe)
 572 #ifdef CSQC
 573 NET_HANDLE(wframe, bool isNew)
 574 {
 575         WFRAME fr = ReadByte();
 576         float t = ReadFloat();
 577         int slot = ReadByte();
 578         bool restartanim = ReadByte();
 579         entity wepent = viewmodels[slot];
 580         if(fr == WFRAME_IDLE)
 581                 wepent.animstate_looping = false; // we don't need to enforce idle animation
 582         else
 583         {
 584                 vector a = '0 0 0';
 585                 switch(fr)
 586                 {
 587                         default:
 588                         case WFRAME_IDLE: a = wepent.anim_idle; break;
 589                         case WFRAME_FIRE1: a = wepent.anim_fire1; break;
 590                         case WFRAME_FIRE2: a = wepent.anim_fire2; break;
 591                         case WFRAME_RELOAD: a = wepent.anim_reload; break;
 592                 }
 593                 a.z *= t;
 594                 anim_set(wepent, a, !restartanim, restartanim, restartanim);
 595         }
 596         wepent.state = ReadByte();
 597         wepent.weapon_nextthink = ReadFloat();
 598         switch (wepent.state)
 599         {
 600                 case WS_RAISE:
 601                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_raise;
 602                         break;
 603                 case WS_DROP:
 604                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_drop;
 605                         break;
 606                 default:
 607                         wepent.weapon_switchdelay = 0;
 608                         break;
 609         }
 610         return true;
 611 }
 612 #endif
 613
 614 #ifdef SVQC
 615 void wframe_send(entity actor, entity weaponentity, int wepframe, float attackrate, bool restartanim)
 616 {
 617         if (!IS_REAL_CLIENT(actor)) return;
 618         int channel = MSG_ONE;
 619         msg_entity = actor;
 620         WriteHeader(channel, wframe);
 621         WriteByte(channel, wepframe);
 622         WriteFloat(channel, attackrate);
 623         WriteByte(channel, weaponslot(weaponentity.weaponentity_fld));
 624         WriteByte(channel, restartanim);
 625         WriteByte(channel, weaponentity.state);
 626         WriteFloat(channel, weaponentity.weapon_nextthink);
 627 }
 628 #endif
 629
 630 REGISTER_NET_C2S(w_whereis)
 631 #ifdef SVQC
 632 void Weapon_whereis(Weapon this, entity cl);
 633 NET_HANDLE(w_whereis, bool)
 634 {
 635         Weapon wpn = ReadRegistered(Weapons);
 636         if (wpn != WEP_Null) Weapon_whereis(wpn, sender);
 637         return true;
 638 }
 639 #else
 640 void w_whereis(Weapon this)
 641 {
 642         int channel = MSG_C2S;
 643         WriteHeader(channel, w_whereis);
 644         WriteRegistered(Weapons, channel, this);
 645 }
 646 CLIENT_COMMAND(weapon_find, "Show spawn locations of a weapon")
 647 {
 648         switch (request)
 649         {
 650                 case CMD_REQUEST_COMMAND:
 651                 {
 652                         string s = argv(1);
 653                         if (s == "all")
 654                         {
 655                                 FOREACH(Weapons, it != WEP_Null, w_whereis(it));
 656                                 return;
 657                         }
 658                         if (s == "unowned")
 659                         {
 660                                 FOREACH(Weapons, it != WEP_Null && !(STAT(WEAPONS) & it.m_wepset), w_whereis(it));
 661                                 return;
 662                         }
 663                         FOREACH(Weapons, it != WEP_Null && it.netname == s,
 664                         {
 665                                 w_whereis(it);
 666                                 return;
 667                         });
 668                 }
 669                 default:
 670                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 671                 case CMD_REQUEST_USAGE:
 672                 {
 673                         LOG_HELP("Usage:^3 cl_cmd weapon_find <weapon>");
 674                         LOG_HELP("  Where <weapon> is the lowercase weapon name, 'all' or 'unowned'.");
 675                         return;
 676                 }
 677         }
 678 }
 679 #endif
 680
 681 #ifdef SVQC
 682 void W_MuzzleFlash_Model_AttachToShotorg(entity actor, .entity weaponentity, entity flash, vector offset)
 683 {
 684         flash.owner = actor;
 685         flash.angles_z = random() * 360;
 686
 687         entity view = actor.(weaponentity);
 688         entity exterior = actor.exteriorweaponentity;
 689
 690         if (view.oldorigin.x > 0)
 691         {
 692                 setattachment(flash, exterior, "");
 693                 setorigin(flash, view.oldorigin + offset);
 694         }
 695         else
 696         {
 697                 if (gettagindex(exterior, "shot")) setattachment(flash, exterior, "shot");
 698                 else setattachment(flash, exterior, "tag_shot");
 699                 setorigin(flash, offset);
 700         }
 701 }
 702 #elif defined(CSQC)
 703 void W_MuzzleFlash_Model_AttachToShotorg(entity wepent, entity flash, vector offset)
 704 {
 705         flash.owner = wepent;
 706         flash.angles_z = random() * 360;
 707
 708         if (gettagindex(wepent, "shot")) setattachment(flash, wepent, "shot");
 709         else setattachment(flash, wepent, "tag_shot");
 710         setorigin(flash, offset);
 711 }
 712 #endif
 713
 714 void W_MuzzleFlash_Model_Think(entity this)
 715 {
 716         this.frame += 2;
 717         this.scale *= 0.5;
 718         this.alpha -= 0.25;
 719         this.nextthink = time + 0.05;
 720
 721         if(this.alpha <= 0)
 722         {
 723                 setthink(this, SUB_Remove);
 724                 this.nextthink = time;
 725                 this.realowner.muzzle_flash = NULL;
 726                 return;
 727         }
 728 }
 729
 730 void W_MuzzleFlash_Model(entity wepent, entity muzzlemodel)
 731 {
 732         if(wepent.muzzle_flash == NULL)
 733                 wepent.muzzle_flash = spawn();
 734
 735         entity flash = wepent.muzzle_flash;
 736         setmodel(flash, muzzlemodel); // precision set below
 737
 738         flash.scale = 0.75;
 739         setthink(flash, W_MuzzleFlash_Model_Think);
 740         flash.nextthink = time + 0.02;
 741         flash.frame = 2;
 742         flash.alpha = 0.75;
 743         flash.angles_z = random() * 180;
 744         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
 745         flash.owner = flash.realowner = wepent;
 746
 747 #ifdef CSQC
 748         flash.drawmask = MASK_NORMAL;
 749 #endif
 750 }
 751
 752 REGISTER_NET_TEMP(w_muzzleflash)
 753
 754 #ifdef SVQC
 755 void W_MuzzleFlash(Weapon thiswep, entity actor, .entity weaponentity, vector shotorg, vector shotdir)
 756 {
 757         // don't show an exterior muzzle effect for the off-hand
 758         if(weaponslot(weaponentity) == 0)
 759         {
 760                 Send_Effect_Except(thiswep.m_muzzleeffect, shotorg, shotdir * 1000, 1, actor);
 761
 762                 if(thiswep.m_muzzlemodel != MDL_Null)
 763                 {
 764                         W_MuzzleFlash_Model(actor.exteriorweaponentity, thiswep.m_muzzlemodel);
 765                         W_MuzzleFlash_Model_AttachToShotorg(actor, weaponentity, actor.exteriorweaponentity.muzzle_flash, '5 0 0');
 766                 }
 767         }
 768
 769         FOREACH_CLIENT(it == actor || (IS_SPEC(it) && it.enemy == actor),
 770         {
 771                 if(!IS_REAL_CLIENT(it))
 772                         continue;
 773                 int channel = MSG_ONE;
 774                 msg_entity = it;
 775                 WriteHeader(channel, w_muzzleflash);
 776                 WriteByte(channel, thiswep.m_id);
 777                 WriteByte(channel, weaponslot(weaponentity));
 778                 WriteVector(channel, shotorg);
 779         });
 780 }
 781 #elif defined(CSQC)
 782 NET_HANDLE(w_muzzleflash, bool isNew)
 783 {
 784         return = true;
 785         int weapon_id = ReadByte();
 786         int slot = ReadByte();
 787         vector sv_shotorg = ReadVector();
 788
 789         Weapon thiswep = REGISTRY_GET(Weapons, weapon_id);
 790         vector viewangles = getpropertyvec(VF_CL_VIEWANGLES);
 791         vector forward, right, up;
 792         MAKE_VECTORS(viewangles, forward, right, up);
 793
 794         if(autocvar_chase_active)
 795         {
 796                 // in third person mode, show the muzzle flash from the server side weapon position
 797                 // we don't have a view model to reference in this case
 798                 pointparticles(thiswep.m_muzzleeffect, sv_shotorg, forward * 1000, 1);
 799                 return;
 800         }
 801         if(!autocvar_r_drawviewmodel) return;
 802
 803         entity wepent = viewmodels[slot];
 804         // get the local player entity to calculate shot origin
 805         entity rlplayer = CSQCModel_server2csqc(player_localentnum - 1);
 806         if(!rlplayer)
 807                 rlplayer = csqcplayer; // fall back to the global
 808
 809         vector md = wepent.movedir_aligned;
 810         vector dv = forward * md.x + right * -md.y + up * md.z;
 811         vector org = rlplayer.origin + rlplayer.view_ofs + dv;
 812
 813         pointparticles(thiswep.m_muzzleeffect, org, forward * 1000, 1);
 814
 815         if(thiswep.m_muzzlemodel != MDL_Null)
 816         {
 817                 W_MuzzleFlash_Model(wepent, thiswep.m_muzzlemodel);
 818                 W_MuzzleFlash_Model_AttachToShotorg(wepent, wepent.muzzle_flash, '5 0 0');
 819         }
 820 }
 821 #endif
 822
 823
 824 #endif
 825
 826 #endif
 827
 828 #ifdef SVQC
 829 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(entity this, string wo)
 830 {
 831         string o = W_FixWeaponOrder_ForceComplete(wo);
 832         strcpy(CS_CVAR(this).weaponorder_byimpulse, W_FixWeaponOrder_BuildImpulseList(o));
 833         return o;
 834 }
 835 #endif
 836
 837 #ifdef CSQC
 838 REPLICATE(cvar_cl_accuracy_data_share, bool, "cl_accuracy_data_share");
 839 REPLICATE(cvar_cl_accuracy_data_receive, bool, "cl_accuracy_data_receive");
 840 #endif
 841
 842 #ifdef GAMEQC
 843 REPLICATE(cvar_cl_gunalign, int, "cl_gunalign");
 844 REPLICATE(cvar_cl_weapon_switch_reload, bool, "cl_weapon_switch_reload");
 845 REPLICATE(cvar_cl_weapon_switch_fallback_to_impulse, bool, "cl_weapon_switch_fallback_to_impulse");
 846 REPLICATE(cvar_cl_weaponimpulsemode, int, "cl_weaponimpulsemode");
 847 REPLICATE(cvar_cl_weaponpriority, string, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 848 REPLICATE(cvar_cl_weaponpriorities[0], string, "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 849 REPLICATE(cvar_cl_weaponpriorities[1], string, "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 850 REPLICATE(cvar_cl_weaponpriorities[2], string, "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 851 REPLICATE(cvar_cl_weaponpriorities[3], string, "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 852 REPLICATE(cvar_cl_weaponpriorities[4], string, "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 853 REPLICATE(cvar_cl_weaponpriorities[5], string, "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 854 REPLICATE(cvar_cl_weaponpriorities[6], string, "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 855 REPLICATE(cvar_cl_weaponpriorities[7], string, "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 856 REPLICATE(cvar_cl_weaponpriorities[8], string, "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 857 REPLICATE(cvar_cl_weaponpriorities[9], string, "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 858 #endif