qcsrc/common/vehicles/vehicle/racer.qc

   1 #include "racer.qh"
   2
   3 #if defined(SVQC)
   4         #include <common/gamemodes/gamemode/ctf/sv_ctf.qh>
   5         #include <common/mapobjects/trigger/impulse.qh>
   6 #endif
   7
   8 #ifdef GAMEQC
   9
  10 #ifdef SVQC
  11 bool autocvar_g_vehicle_racer = true;
  12
  13 float autocvar_g_vehicle_racer_thinkrate = 0.05; // TODO: any higher causes it to sink in liquids
  14
  15 float autocvar_g_vehicle_racer_speed_afterburn = 3000;
  16 // energy consumed per second
  17 float autocvar_g_vehicle_racer_afterburn_cost = 130;
  18
  19 float autocvar_g_vehicle_racer_waterburn_cost = 5;
  20 float autocvar_g_vehicle_racer_waterburn_speed = 750;
  21
  22 float autocvar_g_vehicle_racer_water_speed_forward = 600;
  23 float autocvar_g_vehicle_racer_water_speed_strafe = 600;
  24
  25 float autocvar_g_vehicle_racer_pitchlimit = 30;
  26
  27 float autocvar_g_vehicle_racer_water_downforce = 0.03;
  28 float autocvar_g_vehicle_racer_water_upforcedamper = 15;
  29
  30 float autocvar_g_vehicle_racer_anglestabilizer = 1.75;
  31 float autocvar_g_vehicle_racer_downforce = 0.01;
  32
  33 float autocvar_g_vehicle_racer_speed_forward = 650;
  34 float autocvar_g_vehicle_racer_speed_strafe = 650;
  35 float autocvar_g_vehicle_racer_springlength = 90;
  36 float autocvar_g_vehicle_racer_upforcedamper = 2;
  37 float autocvar_g_vehicle_racer_friction = 0.45;
  38
  39 float autocvar_g_vehicle_racer_water_time = 5;
  40
  41 //float autocvar_g_vehicle_racer_collision_multiplier = 0.05;
  42
  43 // 0 = hover, != 0 = maglev
  44 int autocvar_g_vehicle_racer_hovertype = 0;
  45 // NOTE!! x 4 (4 engines)
  46 float autocvar_g_vehicle_racer_hoverpower = 8000;
  47
  48 float autocvar_g_vehicle_racer_turnroll = 30;
  49 float autocvar_g_vehicle_racer_turnspeed = 220;
  50 float autocvar_g_vehicle_racer_pitchspeed = 125;
  51
  52 float autocvar_g_vehicle_racer_energy = 100;
  53 float autocvar_g_vehicle_racer_energy_regen = 90;
  54 float autocvar_g_vehicle_racer_energy_regen_pause = 0.35;
  55
  56 float autocvar_g_vehicle_racer_health = 200;
  57 float autocvar_g_vehicle_racer_health_regen = 0;
  58 float autocvar_g_vehicle_racer_health_regen_pause = 0;
  59
  60 float autocvar_g_vehicle_racer_shield = 100;
  61 float autocvar_g_vehicle_racer_shield_regen = 30;
  62 float autocvar_g_vehicle_racer_shield_regen_pause = 1;
  63
  64 bool autocvar_g_vehicle_racer_rocket_locktarget = true;
  65 float autocvar_g_vehicle_racer_rocket_locking_time = 0.35;
  66 float autocvar_g_vehicle_racer_rocket_locking_releasetime = 0.5;
  67 float autocvar_g_vehicle_racer_rocket_locked_time = 4;
  68
  69 float autocvar_g_vehicle_racer_respawntime = 35;
  70
  71 float autocvar_g_vehicle_racer_blowup_radius = 250;
  72 float autocvar_g_vehicle_racer_blowup_coredamage = 250;
  73 float autocvar_g_vehicle_racer_blowup_edgedamage = 15;
  74 float autocvar_g_vehicle_racer_blowup_forceintensity = 250;
  75
  76 // Factor of old velocity to keep after collision
  77 float autocvar_g_vehicle_racer_bouncefactor = 0.25;
  78 // if != 0, New veloctiy after bounce = 0 if new velocity < this
  79 float autocvar_g_vehicle_racer_bouncestop = 0;
  80 // "minspeed_for_pain speedchange_to_pain_factor max_damage"
  81 vector autocvar_g_vehicle_racer_bouncepain = '200 0.15 150';
  82
  83 .float racer_watertime;
  84 .float racer_air_finished; // TODO: use a standard air meter for entities
  85
  86 var .vector(entity this, string tag_name, float spring_length, float max_power) racer_force_from_tag;
  87
  88 void racer_align4point(entity this, entity player, float _delta)
  89 {
  90         vector push_vector;
  91         float fl_push, fr_push, bl_push, br_push;
  92
  93         push_vector  = this.racer_force_from_tag(this, "tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  94         fr_push   = force_fromtag_normpower;
  95         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  96
  97         push_vector += this.racer_force_from_tag(this, "tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  98         fl_push   = force_fromtag_normpower;
  99         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 100
 101         push_vector += this.racer_force_from_tag(this, "tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 102         br_push   = force_fromtag_normpower;
 103         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 104
 105         push_vector += this.racer_force_from_tag(this, "tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 106         bl_push   = force_fromtag_normpower;
 107         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 108
 109         this.velocity += push_vector * _delta;
 110
 111         float uforce = autocvar_g_vehicle_racer_upforcedamper;
 112
 113         int cont = pointcontents(this.origin - '0 0 64');
 114         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 115         {
 116                 uforce = autocvar_g_vehicle_racer_water_upforcedamper;
 117
 118                 if(PHYS_INPUT_BUTTON_CROUCH(player) && time < this.racer_air_finished)
 119                         this.velocity_z += 30;
 120                 else
 121                         this.velocity_z += 200;
 122         }
 123
 124
 125         // Anti ocilation
 126         if(this.velocity_z > 0)
 127                 this.velocity_z *= 1 - uforce * _delta;
 128
 129         push_vector_x =  (fl_push - bl_push);
 130         push_vector_x += (fr_push - br_push);
 131         push_vector_x *= 360;
 132
 133         push_vector_z = (fr_push - fl_push);
 134         push_vector_z += (br_push - bl_push);
 135         push_vector_z *= 360;
 136
 137         // Apply angle diffrance
 138         this.angles_z += push_vector_z * _delta;
 139         this.angles_x += push_vector_x * _delta;
 140
 141         // Apply stabilizer
 142         this.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 143         this.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 144 }
 145
 146 void racer_fire_rocket_aim(entity this, entity player, string tagname, entity trg)
 147 {
 148         vector v = gettaginfo(this, gettagindex(this, tagname));
 149         racer_fire_rocket(this, player, v, v_forward, trg);
 150 }
 151
 152 bool racer_frame(entity this, float dt)
 153 {
 154         entity player = this;
 155         entity vehic = player.vehicle;
 156         return = true;
 157
 158         if(game_stopped)
 159         {
 160                 vehic.solid = SOLID_NOT;
 161                 vehic.takedamage = DAMAGE_NO;
 162                 set_movetype(vehic, MOVETYPE_NONE);
 163                 return;
 164         }
 165
 166         vehicles_frame(vehic, player);
 167
 168         int cont = Mod_Q1BSP_SuperContentsFromNativeContents(pointcontents(vehic.origin));
 169         if(!(cont & DPCONTENTS_WATER))
 170                 vehic.racer_air_finished = 0;
 171         else if (!vehic.racer_air_finished)
 172                 vehic.racer_air_finished = time + autocvar_g_vehicle_racer_water_time;
 173
 174         if(IS_DEAD(vehic))
 175         {
 176                 PHYS_INPUT_BUTTON_ATCK(player) = PHYS_INPUT_BUTTON_ATCK2(player) = false;
 177                 return;
 178         }
 179
 180         racer_align4point(vehic, player, dt);
 181
 182         PHYS_INPUT_BUTTON_ZOOM(player) = PHYS_INPUT_BUTTON_CROUCH(player) = false;
 183
 184         vehic.angles_x *= -1;
 185
 186         // Yaw
 187         float ftmp = autocvar_g_vehicle_racer_turnspeed * dt;
 188         ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - vehic.angles_y, vehic.angles_y), ftmp);
 189         vehic.angles_y = anglemods(vehic.angles_y + ftmp);
 190
 191         // Roll
 192         vehic.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * dt;
 193
 194         // Pitch
 195         ftmp = autocvar_g_vehicle_racer_pitchspeed  * dt;
 196         ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - vehic.angles_x, vehic.angles_x), ftmp);
 197         vehic.angles_x = bound(-autocvar_g_vehicle_racer_pitchlimit, anglemods(vehic.angles_x + ftmp), autocvar_g_vehicle_racer_pitchlimit);
 198
 199         makevectors(vehic.angles);
 200         vehic.angles_x *= -1;
 201
 202         //ftmp = vehic.velocity_z;
 203         vector df = vehic.velocity * -autocvar_g_vehicle_racer_friction;
 204         //vehic.velocity_z = ftmp;
 205
 206         if(CS(player).movement)
 207         {
 208                 if(cont & DPCONTENTS_LIQUIDSMASK)
 209                 {
 210                         if(CS(player).movement_x) { df += v_forward * ((CS(player).movement_x > 0) ? autocvar_g_vehicle_racer_water_speed_forward : -autocvar_g_vehicle_racer_water_speed_forward); }
 211                         if(CS(player).movement_y) { df += v_right * ((CS(player).movement_y > 0) ? autocvar_g_vehicle_racer_water_speed_strafe : -autocvar_g_vehicle_racer_water_speed_strafe); }
 212                 }
 213                 else
 214                 {
 215                         if(CS(player).movement_x) { df += v_forward * ((CS(player).movement_x > 0) ? autocvar_g_vehicle_racer_speed_forward : -autocvar_g_vehicle_racer_speed_forward); }
 216                         if(CS(player).movement_y) { df += v_right * ((CS(player).movement_y > 0) ? autocvar_g_vehicle_racer_speed_strafe : -autocvar_g_vehicle_racer_speed_strafe); }
 217                 }
 218
 219 #ifdef SVQC
 220                 if(vehic.sound_nexttime < time || vehic.sounds != 1)
 221                 {
 222                         vehic.sounds = 1;
 223                         vehic.sound_nexttime = time + 10.922667; //soundlength("vehicles/racer_move.wav");
 224                         sound (vehic, CH_TRIGGER_SINGLE, SND_VEH_RACER_MOVE, VOL_VEHICLEENGINE, ATTEN_NORM);
 225                 }
 226 #endif
 227         }
 228 #ifdef SVQC
 229         else
 230         {
 231                 if(vehic.sound_nexttime < time || vehic.sounds != 0)
 232                 {
 233                         vehic.sounds = 0;
 234                         vehic.sound_nexttime = time + 11.888604; //soundlength("vehicles/racer_idle.wav");
 235                         sound (vehic, CH_TRIGGER_SINGLE, SND_VEH_RACER_IDLE, VOL_VEHICLEENGINE, ATTEN_NORM);
 236                 }
 237         }
 238 #endif
 239
 240         // Afterburn
 241         if (PHYS_INPUT_BUTTON_JUMP(player) && vehic.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * dt))
 242         {
 243 #ifdef SVQC
 244                 if(time - vehic.wait > 0.2)
 245                         pointparticles(EFFECT_RACER_BOOSTER, vehic.origin - v_forward * 32, v_forward  * vlen(vehic.velocity), 1);
 246 #endif
 247
 248                 vehic.wait = time;
 249
 250                 if(cont & DPCONTENTS_LIQUIDSMASK)
 251                 {
 252                         vehic.vehicle_energy -= autocvar_g_vehicle_racer_waterburn_cost * dt;
 253                         df += (v_forward * autocvar_g_vehicle_racer_waterburn_speed);
 254                 }
 255                 else
 256                 {
 257                         vehic.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * dt;
 258                         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 259                 }
 260
 261 #ifdef SVQC
 262                 // NOTE: reusing .invincible_finished here as delay counter for the smoke effect
 263                 if(vehic.invincible_finished < time)
 264                 {
 265                         traceline(vehic.origin, vehic.origin - '0 0 256', MOVE_NORMAL, vehic);
 266                         if(trace_fraction != 1.0)
 267                                 pointparticles(EFFECT_SMOKE_SMALL, trace_endpos, '0 0 0', 1);
 268
 269                         vehic.invincible_finished = time + 0.1 + (random() * 0.1);
 270                 }
 271
 272                 // NOTE: reusing .strength_finished here as a sound delay counter
 273                 if(vehic.strength_finished < time)
 274                 {
 275                         vehic.strength_finished = time + 10.922667; //soundlength("vehicles/racer_boost.wav");
 276                         sound (vehic.tur_head, CH_TRIGGER_SINGLE, SND_VEH_RACER_BOOST, VOL_VEHICLEENGINE, ATTEN_NORM);
 277                 }
 278 #endif
 279         }
 280         else
 281         {
 282                 vehic.strength_finished = 0;
 283                 sound (vehic.tur_head, CH_TRIGGER_SINGLE, SND_Null, VOL_VEHICLEENGINE, ATTEN_NORM);
 284         }
 285
 286         if(cont & DPCONTENTS_LIQUIDSMASK)
 287                 vehic.racer_watertime = time;
 288
 289         float dforce = autocvar_g_vehicle_racer_downforce;
 290         if(time - vehic.racer_watertime <= 3)
 291                 dforce = autocvar_g_vehicle_racer_water_downforce;
 292
 293         df -= v_up * (vlen(vehic.velocity) * dforce);
 294         CS(player).movement = vehic.velocity += df * dt;
 295
 296 #ifdef SVQC
 297
 298         Weapon wep1 = WEP_RACER;
 299         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 300         if (!weaponLocked(player) && !weaponUseForbidden(player))
 301         if (PHYS_INPUT_BUTTON_ATCK(player))
 302         if (wep1.wr_checkammo1(wep1, vehic, weaponentity))
 303         {
 304                 wep1.wr_think(wep1, vehic, weaponentity, 1);
 305         }
 306
 307         if(autocvar_g_vehicle_racer_rocket_locktarget)
 308         {
 309                 if(time >= vehic.vehicle_last_trace)
 310                 {
 311                         crosshair_trace(player);
 312
 313                         vehicles_locktarget(vehic, (1 / autocvar_g_vehicle_racer_rocket_locking_time) * dt,
 314                                                          (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * dt,
 315                                                          autocvar_g_vehicle_racer_rocket_locked_time);
 316
 317                         vehic.vehicle_last_trace = time + autocvar_g_vehicle_racer_thinkrate;
 318                 }
 319
 320                 if(vehic.lock_target)
 321                 {
 322                         if(vehic.lock_strength == 1)
 323                                 UpdateAuxiliaryXhair(player, real_origin(vehic.lock_target), '1 0 0', 0);
 324                         else if(vehic.lock_strength > 0.5)
 325                                 UpdateAuxiliaryXhair(player, real_origin(vehic.lock_target), '0 1 0', 0);
 326                         else if(vehic.lock_strength < 0.5)
 327                                 UpdateAuxiliaryXhair(player, real_origin(vehic.lock_target), '0 0 1', 0);
 328                 }
 329         }
 330
 331         if (!weaponLocked(player) && !weaponUseForbidden(player))
 332         if(time > vehic.delay)
 333         if(PHYS_INPUT_BUTTON_ATCK2(player))
 334         {
 335                 vehic.misc_bulletcounter += 1;
 336                 vehic.delay = time + 0.3;
 337
 338                 if(vehic.misc_bulletcounter == 1)
 339                 {
 340                         racer_fire_rocket_aim(vehic, player, "tag_rocket_r", (vehic.lock_strength == 1 && vehic.lock_target) ? vehic.lock_target : NULL);
 341                         player.vehicle_ammo2 = 50;
 342                 }
 343                 else if(vehic.misc_bulletcounter == 2)
 344                 {
 345                         racer_fire_rocket_aim(vehic, player, "tag_rocket_l", (vehic.lock_strength == 1 && vehic.lock_target) ? vehic.lock_target : NULL);
 346                         vehic.lock_strength  = 0;
 347                         vehic.lock_target       = NULL;
 348                         vehic.misc_bulletcounter = 0;
 349                         vehic.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 350                         vehic.lip = time;
 351                         player.vehicle_ammo2 = 0;
 352                 }
 353         }
 354         else if(vehic.misc_bulletcounter == 0)
 355                 player.vehicle_ammo2 = 100;
 356
 357         player.vehicle_reload2 = bound(0, 100 * ((time - vehic.lip) / (vehic.delay - vehic.lip)), 100);
 358
 359         if(vehic.vehicle_flags & VHF_SHIELDREGEN)
 360                 vehicles_regen(vehic, vehic.dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, dt, true);
 361
 362         if(vehic.vehicle_flags & VHF_HEALTHREGEN)
 363                 vehicles_regen_resource(vehic, vehic.dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, dt, false, RES_HEALTH);
 364
 365         if(vehic.vehicle_flags & VHF_ENERGYREGEN)
 366                 vehicles_regen(vehic, vehic.wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, dt, false);
 367
 368         VEHICLE_UPDATE_PLAYER_RESOURCE(player, vehic, health, racer, RES_HEALTH);
 369         VEHICLE_UPDATE_PLAYER(player, vehic, energy, racer);
 370
 371         if(vehic.vehicle_flags & VHF_HASSHIELD)
 372                 VEHICLE_UPDATE_PLAYER(player, vehic, shield, racer);
 373
 374         PHYS_INPUT_BUTTON_ATCK(player) = PHYS_INPUT_BUTTON_ATCK2(player) = false;
 375 #endif
 376
 377         setorigin(player, vehic.origin + '0 0 32');
 378         player.oldorigin = player.origin; // negate fall damage
 379         player.velocity = vehic.velocity;
 380 }
 381
 382 void racer_think(entity this)
 383 {
 384         float dt = autocvar_g_vehicle_racer_thinkrate;
 385
 386         this.nextthink = time + dt;
 387
 388         tracebox(this.origin, this.mins, this.maxs, this.origin - ('0 0 1' * autocvar_g_vehicle_racer_springlength), MOVE_NOMONSTERS, this);
 389
 390         vector df = this.velocity * -autocvar_g_vehicle_racer_friction;
 391         df_z += (1 - trace_fraction) * autocvar_g_vehicle_racer_hoverpower + sin(time * 2) * (autocvar_g_vehicle_racer_springlength * 2);
 392
 393         float forced = autocvar_g_vehicle_racer_upforcedamper;
 394
 395         //int cont = pointcontents(this.origin - '0 0 64');
 396         traceline(this.origin - '0 0 64', this.origin - '0 0 64', MOVE_NOMONSTERS, this);
 397         //if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 398         if(trace_dpstartcontents & DPCONTENTS_LIQUIDSMASK)
 399         {
 400                 forced = autocvar_g_vehicle_racer_water_upforcedamper;
 401                 this.velocity_z += 200;
 402         }
 403
 404         this.velocity += df * dt;
 405         if(this.velocity_z > 0)
 406                 this.velocity_z *= 1 - forced * dt;
 407
 408         this.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * dt);
 409         this.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * dt);
 410
 411         CSQCMODEL_AUTOUPDATE(this);
 412 }
 413
 414 void racer_exit(entity this, int eject)
 415 {
 416         vector spot;
 417
 418         setthink(this, racer_think);
 419         this.nextthink  = time;
 420         set_movetype(this, MOVETYPE_BOUNCE);
 421         sound (this.tur_head, CH_TRIGGER_SINGLE, SND_Null, VOL_VEHICLEENGINE, ATTEN_NORM);
 422
 423         if(!this.owner)
 424                 return;
 425
 426         makevectors(this.angles);
 427         if(eject)
 428         {
 429                 spot = this.origin + v_forward * 100 + '0 0 64';
 430                 spot = vehicles_findgoodexit(this, this.owner, spot);
 431                 setorigin(this.owner, spot);
 432                 this.owner.velocity = (v_up + v_forward * 0.25) * 750;
 433                 this.owner.oldvelocity = this.owner.velocity;
 434         }
 435         else
 436         {
 437                 if(vdist(this.velocity, >, 2 * autocvar_sv_maxairspeed))
 438                 {
 439                         this.owner.velocity = normalize(this.velocity) * autocvar_sv_maxairspeed * 2;
 440                         this.owner.velocity_z += 200;
 441                         spot = this.origin + v_forward * 32 + '0 0 32';
 442                         spot = vehicles_findgoodexit(this, this.owner, spot);
 443                 }
 444                 else
 445                 {
 446                         this.owner.velocity = this.velocity * 0.5;
 447                         this.owner.velocity_z += 10;
 448                         spot = this.origin - v_forward * 200 + '0 0 32';
 449                         spot = vehicles_findgoodexit(this, this.owner, spot);
 450                 }
 451                 this.owner.oldvelocity = this.owner.velocity;
 452                 setorigin(this.owner , spot);
 453         }
 454         antilag_clear(this.owner, CS(this.owner));
 455         this.owner = NULL;
 456 }
 457
 458 void racer_blowup(entity this)
 459 {
 460         this.deadflag = DEAD_DEAD;
 461         this.vehicle_exit(this, VHEF_NORMAL);
 462
 463         RadiusDamage (this, this.enemy, autocvar_g_vehicle_racer_blowup_coredamage,
 464                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 465                                         autocvar_g_vehicle_racer_blowup_radius, NULL, NULL,
 466                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 467                                         DEATH_VH_WAKI_DEATH.m_id, DMG_NOWEP, NULL);
 468
 469         this.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 470         setthink(this, vehicles_spawn);
 471         set_movetype(this, MOVETYPE_NONE);
 472         this.effects    = EF_NODRAW;
 473         this.solid = SOLID_NOT;
 474
 475         this.colormod  = '0 0 0';
 476         this.avelocity = '0 0 0';
 477         this.velocity  = '0 0 0';
 478
 479         setorigin(this, this.pos1);
 480 }
 481
 482 void racer_blowup_think(entity this)
 483 {
 484         this.nextthink = time;
 485
 486         if(time >= this.delay)
 487                 racer_blowup(this);
 488
 489         //CSQCMODEL_AUTOUPDATE(this);
 490 }
 491
 492 void racer_deadtouch(entity this, entity toucher)
 493 {
 494         this.avelocity_x *= 0.7;
 495         this.cnt -= 1;
 496         if(this.cnt <= 0)
 497                 racer_blowup(this);
 498 }
 499
 500 spawnfunc(vehicle_racer)
 501 {
 502         if(!autocvar_g_vehicle_racer) { delete(this); return; }
 503         if(!vehicle_initialize(this, VEH_RACER, false)) { delete(this); return; }
 504 }
 505
 506 #endif // SVQC
 507
 508 METHOD(Racer, vr_impact, void(Racer thisveh, entity instance))
 509 {
 510 #ifdef SVQC
 511     if(autocvar_g_vehicle_racer_bouncepain)
 512         vehicles_impact(instance, autocvar_g_vehicle_racer_bouncepain_x, autocvar_g_vehicle_racer_bouncepain_y, autocvar_g_vehicle_racer_bouncepain_z);
 513 #endif
 514 }
 515
 516 METHOD(Racer, vr_enter, void(Racer thisveh, entity instance))
 517 {
 518     set_movetype(instance, MOVETYPE_BOUNCE);
 519 #ifdef SVQC
 520     instance.owner.vehicle_health = (GetResource(instance, RES_HEALTH) / autocvar_g_vehicle_racer_health)  * 100;
 521     instance.owner.vehicle_shield = (instance.vehicle_shield / autocvar_g_vehicle_racer_shield)  * 100;
 522
 523     if(instance.owner.flagcarried)
 524        setorigin(instance.owner.flagcarried, '-190 0 96');
 525 #endif
 526 }
 527
 528 METHOD(Racer, vr_spawn, void(Racer thisveh, entity instance))
 529 {
 530 #ifdef SVQC
 531     if(autocvar_g_vehicle_racer_hovertype != 0)
 532         instance.racer_force_from_tag = vehicles_force_fromtag_maglev;
 533     else
 534         instance.racer_force_from_tag = vehicles_force_fromtag_hover;
 535
 536     setthink(instance, racer_think);
 537     instance.nextthink    = time;
 538     SetResourceExplicit(instance, RES_HEALTH, autocvar_g_vehicle_racer_health);
 539     instance.vehicle_shield = autocvar_g_vehicle_racer_shield;
 540
 541     set_movetype(instance, MOVETYPE_TOSS);
 542     instance.solid                = SOLID_SLIDEBOX;
 543     instance.delay                = time;
 544     instance.scale                = 0.5; // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 545     instance.mass                 = 900;
 546
 547     setattachment(instance.vehicle_hudmodel, instance, "");
 548     setattachment(instance.vehicle_viewport, instance, "tag_viewport");
 549
 550     instance.PlayerPhysplug = racer_frame;
 551
 552     instance.bouncefactor = autocvar_g_vehicle_racer_bouncefactor;
 553     instance.bouncestop = autocvar_g_vehicle_racer_bouncestop;
 554     instance.damageforcescale = 0.5;
 555     SetResourceExplicit(instance, RES_HEALTH, autocvar_g_vehicle_racer_health);
 556     instance.vehicle_shield = autocvar_g_vehicle_racer_shield;
 557 #endif
 558 }
 559
 560 METHOD(Racer, vr_death, void(Racer thisveh, entity instance))
 561 {
 562 #ifdef SVQC
 563     setSendEntity(instance, func_null); // stop networking this racer (for now)
 564     SetResourceExplicit(instance, RES_HEALTH, 0);
 565     instance.event_damage       = func_null;
 566     instance.solid                      = SOLID_CORPSE;
 567     instance.takedamage         = DAMAGE_NO;
 568     instance.deadflag           = DEAD_DYING;
 569     set_movetype(instance, MOVETYPE_BOUNCE);
 570     instance.wait                       = time;
 571     instance.delay                      = 2 + time + random() * 3;
 572     instance.cnt                        = 1 + random() * 2;
 573     settouch(instance, racer_deadtouch);
 574
 575     Send_Effect(EFFECT_EXPLOSION_MEDIUM, instance.origin, '0 0 0', 1);
 576
 577     if(random() < 0.5)
 578         instance.avelocity_z = 32;
 579     else
 580         instance.avelocity_z = -32;
 581
 582     instance.avelocity_x = -vlen(instance.velocity) * 0.2;
 583     instance.velocity += '0 0 700';
 584     instance.colormod = '-0.5 -0.5 -0.5';
 585
 586     setthink(instance, racer_blowup_think);
 587     instance.nextthink = time;
 588 #endif
 589 }
 590
 591 #ifdef CSQC
 592 METHOD(Racer, vr_hud, void(Racer thisveh))
 593 {
 594     Vehicles_drawHUD(VEH_RACER.m_icon, "vehicle_racer_weapon1", "vehicle_racer_weapon2",
 595                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 596                      "vehicle_icon_ammo2", autocvar_hud_progressbar_vehicles_ammo2_color);
 597 }
 598 METHOD(Racer, vr_crosshair, void(Racer thisveh, entity player))
 599 {
 600     Vehicles_drawCrosshair(vCROSS_GUIDE);
 601 }
 602 #endif
 603 METHOD(Racer, vr_setup, void(Racer thisveh, entity instance))
 604 {
 605 #ifdef SVQC
 606     instance.vehicle_exit = racer_exit;
 607
 608     // we have no need to network energy
 609     if(autocvar_g_vehicle_racer_energy && autocvar_g_vehicle_racer_energy_regen)
 610         instance.vehicle_flags |= VHF_ENERGYREGEN;
 611
 612     if(autocvar_g_vehicle_racer_shield)
 613         instance.vehicle_flags |= VHF_HASSHIELD;
 614
 615     if(autocvar_g_vehicle_racer_shield_regen)
 616         instance.vehicle_flags |= VHF_SHIELDREGEN;
 617
 618     if(autocvar_g_vehicle_racer_health_regen)
 619         instance.vehicle_flags |= VHF_HEALTHREGEN;
 620
 621     instance.respawntime = autocvar_g_vehicle_racer_respawntime;
 622     SetResourceExplicit(instance, RES_HEALTH, autocvar_g_vehicle_racer_health);
 623     instance.vehicle_shield = autocvar_g_vehicle_racer_shield;
 624     instance.max_health = GetResource(instance, RES_HEALTH);
 625 #endif
 626
 627 #ifdef CSQC
 628     AuxiliaryXhair[0].axh_image = vCROSS_LOCK; // Rocket
 629 #endif
 630 }
 631
 632 #endif