qcsrc/common/vehicles/vehicle/racer.qc

   1 #include "racer.qh"
   2
   3 #if defined(SVQC)
   4         #include <common/gamemodes/gamemode/ctf/sv_ctf.qh>
   5         #include <common/mapobjects/trigger/impulse.qh>
   6 #endif
   7
   8 #ifdef GAMEQC
   9
  10 #ifdef SVQC
  11 bool autocvar_g_vehicle_racer = true;
  12
  13 float autocvar_g_vehicle_racer_thinkrate = 0.05; // TODO: any higher causes it to sink in liquids
  14
  15 float autocvar_g_vehicle_racer_speed_afterburn = 3000;
  16 // energy consumed per second
  17 float autocvar_g_vehicle_racer_afterburn_cost = 130;
  18
  19 float autocvar_g_vehicle_racer_waterburn_cost = 5;
  20 float autocvar_g_vehicle_racer_waterburn_speed = 750;
  21
  22 float autocvar_g_vehicle_racer_water_speed_forward = 600;
  23 float autocvar_g_vehicle_racer_water_speed_strafe = 600;
  24
  25 float autocvar_g_vehicle_racer_pitchlimit = 30;
  26
  27 float autocvar_g_vehicle_racer_water_downforce = 0.03;
  28 float autocvar_g_vehicle_racer_water_upforcedamper = 15;
  29
  30 float autocvar_g_vehicle_racer_anglestabilizer = 1.75;
  31 float autocvar_g_vehicle_racer_downforce = 0.01;
  32
  33 float autocvar_g_vehicle_racer_speed_forward = 650;
  34 float autocvar_g_vehicle_racer_speed_strafe = 650;
  35 float autocvar_g_vehicle_racer_springlength = 90;
  36 float autocvar_g_vehicle_racer_upforcedamper = 2;
  37 float autocvar_g_vehicle_racer_friction = 0.45;
  38
  39 float autocvar_g_vehicle_racer_water_time = 5;
  40
  41 //float autocvar_g_vehicle_racer_collision_multiplier = 0.05;
  42
  43 // 0 = hover, != 0 = maglev
  44 int autocvar_g_vehicle_racer_hovertype = 0;
  45 // NOTE!! x 4 (4 engines)
  46 float autocvar_g_vehicle_racer_hoverpower = 8000;
  47
  48 float autocvar_g_vehicle_racer_turnroll = 30;
  49 float autocvar_g_vehicle_racer_turnspeed = 220;
  50 float autocvar_g_vehicle_racer_pitchspeed = 125;
  51
  52 float autocvar_g_vehicle_racer_energy = 100;
  53 float autocvar_g_vehicle_racer_energy_regen = 90;
  54 float autocvar_g_vehicle_racer_energy_regen_pause = 0.35;
  55
  56 float autocvar_g_vehicle_racer_health = 200;
  57 float autocvar_g_vehicle_racer_health_regen = 0;
  58 float autocvar_g_vehicle_racer_health_regen_pause = 0;
  59
  60 float autocvar_g_vehicle_racer_shield = 100;
  61 float autocvar_g_vehicle_racer_shield_regen = 30;
  62 float autocvar_g_vehicle_racer_shield_regen_pause = 1;
  63
  64 bool autocvar_g_vehicle_racer_rocket_locktarget = true;
  65 float autocvar_g_vehicle_racer_rocket_locking_time = 0.35;
  66 float autocvar_g_vehicle_racer_rocket_locking_releasetime = 0.5;
  67 float autocvar_g_vehicle_racer_rocket_locked_time = 4;
  68
  69 float autocvar_g_vehicle_racer_respawntime = 35;
  70
  71 float autocvar_g_vehicle_racer_blowup_radius = 250;
  72 float autocvar_g_vehicle_racer_blowup_coredamage = 250;
  73 float autocvar_g_vehicle_racer_blowup_edgedamage = 15;
  74 float autocvar_g_vehicle_racer_blowup_forceintensity = 250;
  75
  76 // Factor of old velocity to keep after collision
  77 float autocvar_g_vehicle_racer_bouncefactor = 0.25;
  78 // if != 0, New veloctiy after bounce = 0 if new velocity < this
  79 float autocvar_g_vehicle_racer_bouncestop = 0;
  80 // "minspeed_for_pain speedchange_to_pain_factor max_damage"
  81 vector autocvar_g_vehicle_racer_bouncepain = '200 0.15 150';
  82
  83 .float racer_watertime;
  84 .float racer_air_finished; // TODO: use a standard air meter for entities
  85
  86 var .vector(entity this, string tag_name, float spring_length, float max_power) racer_force_from_tag;
  87
  88 void racer_align4point(entity this, entity player, float _delta)
  89 {
  90         vector push_vector;
  91         float fl_push, fr_push, bl_push, br_push;
  92
  93         push_vector  = this.racer_force_from_tag(this, "tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  94         fr_push   = force_fromtag_normpower;
  95         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  96
  97         push_vector += this.racer_force_from_tag(this, "tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  98         fl_push   = force_fromtag_normpower;
  99         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 100
 101         push_vector += this.racer_force_from_tag(this, "tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 102         br_push   = force_fromtag_normpower;
 103         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 104
 105         push_vector += this.racer_force_from_tag(this, "tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 106         bl_push   = force_fromtag_normpower;
 107         //vehicles_sweap_collision(force_fromtag_origin, this.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 108
 109         this.velocity += push_vector * _delta;
 110
 111         float uforce = autocvar_g_vehicle_racer_upforcedamper;
 112
 113         int cont = pointcontents(this.origin - '0 0 64');
 114         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 115         {
 116                 uforce = autocvar_g_vehicle_racer_water_upforcedamper;
 117
 118                 if(PHYS_INPUT_BUTTON_CROUCH(player) && time < this.racer_air_finished)
 119                         this.velocity_z += 30;
 120                 else
 121                         this.velocity_z += 200;
 122         }
 123
 124
 125         // Anti ocilation
 126         if(this.velocity_z > 0)
 127                 this.velocity_z *= 1 - uforce * _delta;
 128
 129         push_vector_x =  (fl_push - bl_push);
 130         push_vector_x += (fr_push - br_push);
 131         push_vector_x *= 360;
 132
 133         push_vector_z = (fr_push - fl_push);
 134         push_vector_z += (br_push - bl_push);
 135         push_vector_z *= 360;
 136
 137         // Apply angle diffrance
 138         this.angles_z += push_vector_z * _delta;
 139         this.angles_x += push_vector_x * _delta;
 140
 141         // Apply stabilizer
 142         this.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 143         this.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 144 }
 145
 146 void racer_fire_rocket_aim(entity this, entity player, string tagname, entity trg)
 147 {
 148         vector v = gettaginfo(this, gettagindex(this, tagname));
 149         racer_fire_rocket(this, player, v, v_forward, trg);
 150 }
 151
 152 bool racer_frame(entity this, float dt)
 153 {
 154         entity player = this;
 155         entity vehic = player.vehicle;
 156         return = true;
 157
 158 #ifdef SVQC
 159         if(game_stopped)
 160         {
 161                 vehic.solid = SOLID_NOT;
 162                 vehic.takedamage = DAMAGE_NO;
 163                 set_movetype(vehic, MOVETYPE_NONE);
 164                 return;
 165         }
 166 #endif
 167
 168         vehicles_frame(vehic, player);
 169
 170         int cont = Mod_Q1BSP_SuperContentsFromNativeContents(pointcontents(vehic.origin));
 171         if(!(cont & DPCONTENTS_WATER))
 172                 vehic.racer_air_finished = 0;
 173         else if (!vehic.racer_air_finished)
 174                 vehic.racer_air_finished = time + autocvar_g_vehicle_racer_water_time;
 175
 176 #ifdef SVQC
 177         if(IS_DEAD(vehic))
 178         {
 179                 PHYS_INPUT_BUTTON_ATCK(player) = PHYS_INPUT_BUTTON_ATCK2(player) = false;
 180                 return;
 181         }
 182 #endif
 183
 184         racer_align4point(vehic, player, dt);
 185
 186 #ifdef SVQC
 187         PHYS_INPUT_BUTTON_ZOOM(player) = PHYS_INPUT_BUTTON_CROUCH(player) = false;
 188 #endif
 189
 190         vehic.angles_x *= -1;
 191
 192         // Yaw
 193         float ftmp = autocvar_g_vehicle_racer_turnspeed * dt;
 194         ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - vehic.angles_y, vehic.angles_y), ftmp);
 195         vehic.angles_y = anglemods(vehic.angles_y + ftmp);
 196
 197         // Roll
 198         vehic.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * dt;
 199
 200         // Pitch
 201         ftmp = autocvar_g_vehicle_racer_pitchspeed  * dt;
 202         ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - vehic.angles_x, vehic.angles_x), ftmp);
 203         vehic.angles_x = bound(-autocvar_g_vehicle_racer_pitchlimit, anglemods(vehic.angles_x + ftmp), autocvar_g_vehicle_racer_pitchlimit);
 204
 205         makevectors(vehic.angles);
 206         vehic.angles_x *= -1;
 207
 208         //ftmp = vehic.velocity_z;
 209         vector df = vehic.velocity * -autocvar_g_vehicle_racer_friction;
 210         //vehic.velocity_z = ftmp;
 211
 212         if(PHYS_CS(player).movement)
 213         {
 214                 if(cont & DPCONTENTS_LIQUIDSMASK)
 215                 {
 216                         if(PHYS_CS(player).movement_x) { df += v_forward * ((PHYS_CS(player).movement_x > 0) ? autocvar_g_vehicle_racer_water_speed_forward : -autocvar_g_vehicle_racer_water_speed_forward); }
 217                         if(PHYS_CS(player).movement_y) { df += v_right * ((PHYS_CS(player).movement_y > 0) ? autocvar_g_vehicle_racer_water_speed_strafe : -autocvar_g_vehicle_racer_water_speed_strafe); }
 218                 }
 219                 else
 220                 {
 221                         if(PHYS_CS(player).movement_x) { df += v_forward * ((PHYS_CS(player).movement_x > 0) ? autocvar_g_vehicle_racer_speed_forward : -autocvar_g_vehicle_racer_speed_forward); }
 222                         if(PHYS_CS(player).movement_y) { df += v_right * ((PHYS_CS(player).movement_y > 0) ? autocvar_g_vehicle_racer_speed_strafe : -autocvar_g_vehicle_racer_speed_strafe); }
 223                 }
 224
 225 #ifdef SVQC
 226                 if(vehic.sound_nexttime < time || vehic.sounds != 1)
 227                 {
 228                         vehic.sounds = 1;
 229                         vehic.sound_nexttime = time + 10.922667; //soundlength("vehicles/racer_move.wav");
 230                         sound (vehic, CH_TRIGGER_SINGLE, SND_VEH_RACER_MOVE, VOL_VEHICLEENGINE, ATTEN_NORM);
 231                 }
 232 #endif
 233         }
 234 #ifdef SVQC
 235         else
 236         {
 237                 if(vehic.sound_nexttime < time || vehic.sounds != 0)
 238                 {
 239                         vehic.sounds = 0;
 240                         vehic.sound_nexttime = time + 11.888604; //soundlength("vehicles/racer_idle.wav");
 241                         sound (vehic, CH_TRIGGER_SINGLE, SND_VEH_RACER_IDLE, VOL_VEHICLEENGINE, ATTEN_NORM);
 242                 }
 243         }
 244 #endif
 245
 246         // Afterburn
 247         if (PHYS_INPUT_BUTTON_JUMP(player) && vehic.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * dt))
 248         {
 249 #ifdef SVQC
 250                 if(time - vehic.wait > 0.2)
 251                         pointparticles(EFFECT_RACER_BOOSTER, vehic.origin - v_forward * 32, v_forward  * vlen(vehic.velocity), 1);
 252 #endif
 253
 254                 vehic.wait = time;
 255
 256                 if(cont & DPCONTENTS_LIQUIDSMASK)
 257                 {
 258                         vehic.vehicle_energy -= autocvar_g_vehicle_racer_waterburn_cost * dt;
 259                         df += (v_forward * autocvar_g_vehicle_racer_waterburn_speed);
 260                 }
 261                 else
 262                 {
 263                         vehic.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * dt;
 264                         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 265                 }
 266
 267 #ifdef SVQC
 268                 // NOTE: reusing .invincible_finished here as delay counter for the smoke effect
 269                 if(vehic.invincible_finished < time)
 270                 {
 271                         traceline(vehic.origin, vehic.origin - '0 0 256', MOVE_NORMAL, vehic);
 272                         if(trace_fraction != 1.0)
 273                                 pointparticles(EFFECT_SMOKE_SMALL, trace_endpos, '0 0 0', 1);
 274
 275                         vehic.invincible_finished = time + 0.1 + (random() * 0.1);
 276                 }
 277
 278                 // NOTE: reusing .strength_finished here as a sound delay counter
 279                 if(vehic.strength_finished < time)
 280                 {
 281                         vehic.strength_finished = time + 10.922667; //soundlength("vehicles/racer_boost.wav");
 282                         sound (vehic.tur_head, CH_TRIGGER_SINGLE, SND_VEH_RACER_BOOST, VOL_VEHICLEENGINE, ATTEN_NORM);
 283                 }
 284 #endif
 285         }
 286         else
 287         {
 288                 vehic.strength_finished = 0;
 289                 sound (vehic.tur_head, CH_TRIGGER_SINGLE, SND_Null, VOL_VEHICLEENGINE, ATTEN_NORM);
 290         }
 291
 292         if(cont & DPCONTENTS_LIQUIDSMASK)
 293                 vehic.racer_watertime = time;
 294
 295         float dforce = autocvar_g_vehicle_racer_downforce;
 296         if(time - vehic.racer_watertime <= 3)
 297                 dforce = autocvar_g_vehicle_racer_water_downforce;
 298
 299         df -= v_up * (vlen(vehic.velocity) * dforce);
 300         PHYS_CS(player).movement = vehic.velocity += df * dt;
 301
 302 #ifdef SVQC
 303
 304         Weapon wep1 = WEP_RACER;
 305         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 306         if (!weaponLocked(player) && !weaponUseForbidden(player))
 307         if (PHYS_INPUT_BUTTON_ATCK(player))
 308         if (wep1.wr_checkammo1(wep1, vehic, weaponentity))
 309         {
 310                 wep1.wr_think(wep1, vehic, weaponentity, 1);
 311         }
 312
 313         if(autocvar_g_vehicle_racer_rocket_locktarget)
 314         {
 315                 if(time >= vehic.vehicle_last_trace)
 316                 {
 317                         crosshair_trace(player);
 318
 319                         vehicles_locktarget(vehic, (1 / autocvar_g_vehicle_racer_rocket_locking_time) * dt,
 320                                                          (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * dt,
 321                                                          autocvar_g_vehicle_racer_rocket_locked_time);
 322
 323                         vehic.vehicle_last_trace = time + autocvar_g_vehicle_racer_thinkrate;
 324                 }
 325
 326                 if(vehic.lock_target)
 327                 {
 328                         if(vehic.lock_strength == 1)
 329                                 UpdateAuxiliaryXhair(player, real_origin(vehic.lock_target), '1 0 0', 0);
 330                         else if(vehic.lock_strength > 0.5)
 331                                 UpdateAuxiliaryXhair(player, real_origin(vehic.lock_target), '0 1 0', 0);
 332                         else if(vehic.lock_strength < 0.5)
 333                                 UpdateAuxiliaryXhair(player, real_origin(vehic.lock_target), '0 0 1', 0);
 334                 }
 335         }
 336
 337         if (!weaponLocked(player) && !weaponUseForbidden(player))
 338         if(time > vehic.delay)
 339         if(PHYS_INPUT_BUTTON_ATCK2(player))
 340         {
 341                 vehic.misc_bulletcounter += 1;
 342                 vehic.delay = time + 0.3;
 343
 344                 if(vehic.misc_bulletcounter == 1)
 345                 {
 346                         racer_fire_rocket_aim(vehic, player, "tag_rocket_r", (vehic.lock_strength == 1 && vehic.lock_target) ? vehic.lock_target : NULL);
 347                         player.vehicle_ammo2 = 50;
 348                 }
 349                 else if(vehic.misc_bulletcounter == 2)
 350                 {
 351                         racer_fire_rocket_aim(vehic, player, "tag_rocket_l", (vehic.lock_strength == 1 && vehic.lock_target) ? vehic.lock_target : NULL);
 352                         vehic.lock_strength  = 0;
 353                         vehic.lock_target       = NULL;
 354                         vehic.misc_bulletcounter = 0;
 355                         vehic.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 356                         vehic.lip = time;
 357                         player.vehicle_ammo2 = 0;
 358                 }
 359         }
 360         else if(vehic.misc_bulletcounter == 0)
 361                 player.vehicle_ammo2 = 100;
 362
 363         player.vehicle_reload2 = bound(0, 100 * ((time - vehic.lip) / (vehic.delay - vehic.lip)), 100);
 364
 365         if(vehic.vehicle_flags & VHF_SHIELDREGEN)
 366                 vehicles_regen(vehic, vehic.dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, dt, true);
 367
 368         if(vehic.vehicle_flags & VHF_HEALTHREGEN)
 369                 vehicles_regen_resource(vehic, vehic.dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, dt, false, RES_HEALTH);
 370
 371         if(vehic.vehicle_flags & VHF_ENERGYREGEN)
 372                 vehicles_regen(vehic, vehic.wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, dt, false);
 373
 374         VEHICLE_UPDATE_PLAYER_RESOURCE(player, vehic, health, racer, RES_HEALTH);
 375         VEHICLE_UPDATE_PLAYER(player, vehic, energy, racer);
 376
 377         if(vehic.vehicle_flags & VHF_HASSHIELD)
 378                 VEHICLE_UPDATE_PLAYER(player, vehic, shield, racer);
 379
 380         PHYS_INPUT_BUTTON_ATCK(player) = PHYS_INPUT_BUTTON_ATCK2(player) = false;
 381 #endif
 382
 383         setorigin(player, vehic.origin + '0 0 32');
 384 #ifdef SVQC
 385         player.oldorigin = player.origin; // negate fall damage
 386 #endif
 387         player.velocity = vehic.velocity;
 388 }
 389 #endif
 390
 391 #ifdef SVQC
 392 void racer_think(entity this)
 393 {
 394         float dt = autocvar_g_vehicle_racer_thinkrate;
 395
 396         this.nextthink = time + dt;
 397
 398         tracebox(this.origin, this.mins, this.maxs, this.origin - ('0 0 1' * autocvar_g_vehicle_racer_springlength), MOVE_NOMONSTERS, this);
 399
 400         vector df = this.velocity * -autocvar_g_vehicle_racer_friction;
 401         df_z += (1 - trace_fraction) * autocvar_g_vehicle_racer_hoverpower + sin(time * 2) * (autocvar_g_vehicle_racer_springlength * 2);
 402
 403         float forced = autocvar_g_vehicle_racer_upforcedamper;
 404
 405         //int cont = pointcontents(this.origin - '0 0 64');
 406         traceline(this.origin - '0 0 64', this.origin - '0 0 64', MOVE_NOMONSTERS, this);
 407         //if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 408         if(trace_dpstartcontents & DPCONTENTS_LIQUIDSMASK)
 409         {
 410                 forced = autocvar_g_vehicle_racer_water_upforcedamper;
 411                 this.velocity_z += 200;
 412         }
 413
 414         this.velocity += df * dt;
 415         if(this.velocity_z > 0)
 416                 this.velocity_z *= 1 - forced * dt;
 417
 418         this.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * dt);
 419         this.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * dt);
 420
 421         CSQCMODEL_AUTOUPDATE(this);
 422 }
 423
 424 void racer_exit(entity this, int eject)
 425 {
 426         vector spot;
 427
 428         setthink(this, racer_think);
 429         this.nextthink  = time;
 430         set_movetype(this, MOVETYPE_BOUNCE);
 431         sound (this.tur_head, CH_TRIGGER_SINGLE, SND_Null, VOL_VEHICLEENGINE, ATTEN_NORM);
 432
 433         if(!this.owner)
 434                 return;
 435
 436         makevectors(this.angles);
 437         if(eject)
 438         {
 439                 spot = this.origin + v_forward * 100 + '0 0 64';
 440                 spot = vehicles_findgoodexit(this, this.owner, spot);
 441                 setorigin(this.owner, spot);
 442                 this.owner.velocity = (v_up + v_forward * 0.25) * 750;
 443                 this.owner.oldvelocity = this.owner.velocity;
 444         }
 445         else
 446         {
 447                 if(vdist(this.velocity, >, 2 * autocvar_sv_maxairspeed))
 448                 {
 449                         this.owner.velocity = normalize(this.velocity) * autocvar_sv_maxairspeed * 2;
 450                         this.owner.velocity_z += 200;
 451                         spot = this.origin + v_forward * 32 + '0 0 32';
 452                         spot = vehicles_findgoodexit(this, this.owner, spot);
 453                 }
 454                 else
 455                 {
 456                         this.owner.velocity = this.velocity * 0.5;
 457                         this.owner.velocity_z += 10;
 458                         spot = this.origin - v_forward * 200 + '0 0 32';
 459                         spot = vehicles_findgoodexit(this, this.owner, spot);
 460                 }
 461                 this.owner.oldvelocity = this.owner.velocity;
 462                 setorigin(this.owner , spot);
 463         }
 464         antilag_clear(this.owner, CS(this.owner));
 465         this.owner = NULL;
 466 }
 467
 468 void racer_blowup(entity this)
 469 {
 470         this.deadflag = DEAD_DEAD;
 471         this.vehicle_exit(this, VHEF_NORMAL);
 472
 473         RadiusDamage (this, this.enemy, autocvar_g_vehicle_racer_blowup_coredamage,
 474                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 475                                         autocvar_g_vehicle_racer_blowup_radius, NULL, NULL,
 476                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 477                                         DEATH_VH_WAKI_DEATH.m_id, DMG_NOWEP, NULL);
 478
 479         this.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 480         setthink(this, vehicles_spawn);
 481         set_movetype(this, MOVETYPE_NONE);
 482         this.effects    = EF_NODRAW;
 483         this.solid = SOLID_NOT;
 484
 485         this.colormod  = '0 0 0';
 486         this.avelocity = '0 0 0';
 487         this.velocity  = '0 0 0';
 488
 489         setorigin(this, this.pos1);
 490 }
 491
 492 void racer_blowup_think(entity this)
 493 {
 494         this.nextthink = time;
 495
 496         if(time >= this.delay)
 497                 racer_blowup(this);
 498
 499         //CSQCMODEL_AUTOUPDATE(this);
 500 }
 501
 502 void racer_deadtouch(entity this, entity toucher)
 503 {
 504         this.avelocity_x *= 0.7;
 505         this.cnt -= 1;
 506         if(this.cnt <= 0)
 507                 racer_blowup(this);
 508 }
 509
 510 spawnfunc(vehicle_racer)
 511 {
 512         if(!autocvar_g_vehicle_racer) { delete(this); return; }
 513         if(!vehicle_initialize(this, VEH_RACER, false)) { delete(this); return; }
 514 }
 515
 516 #endif // SVQC
 517
 518 METHOD(Racer, vr_impact, void(Racer thisveh, entity instance))
 519 {
 520 #ifdef SVQC
 521     if(autocvar_g_vehicle_racer_bouncepain)
 522         vehicles_impact(instance, autocvar_g_vehicle_racer_bouncepain_x, autocvar_g_vehicle_racer_bouncepain_y, autocvar_g_vehicle_racer_bouncepain_z);
 523 #endif
 524 }
 525
 526 METHOD(Racer, vr_enter, void(Racer thisveh, entity instance))
 527 {
 528     set_movetype(instance, MOVETYPE_BOUNCE);
 529 #ifdef SVQC
 530     instance.owner.vehicle_health = (GetResource(instance, RES_HEALTH) / autocvar_g_vehicle_racer_health)  * 100;
 531     instance.owner.vehicle_shield = (instance.vehicle_shield / autocvar_g_vehicle_racer_shield)  * 100;
 532
 533     if(instance.owner.flagcarried)
 534        setorigin(instance.owner.flagcarried, '-190 0 96');
 535 #endif
 536 }
 537
 538 METHOD(Racer, vr_spawn, void(Racer thisveh, entity instance))
 539 {
 540 #ifdef SVQC
 541     if(autocvar_g_vehicle_racer_hovertype != 0)
 542         instance.racer_force_from_tag = vehicles_force_fromtag_maglev;
 543     else
 544         instance.racer_force_from_tag = vehicles_force_fromtag_hover;
 545
 546     setthink(instance, racer_think);
 547     instance.nextthink    = time;
 548     SetResourceExplicit(instance, RES_HEALTH, autocvar_g_vehicle_racer_health);
 549     instance.vehicle_shield = autocvar_g_vehicle_racer_shield;
 550
 551     set_movetype(instance, MOVETYPE_TOSS);
 552     instance.solid                = SOLID_SLIDEBOX;
 553     instance.delay                = time;
 554     instance.scale                = 0.5; // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 555     instance.mass                 = 900;
 556
 557     setattachment(instance.vehicle_hudmodel, instance, "");
 558     setattachment(instance.vehicle_viewport, instance, "tag_viewport");
 559
 560     instance.PlayerPhysplug = racer_frame;
 561
 562     instance.bouncefactor = autocvar_g_vehicle_racer_bouncefactor;
 563     instance.bouncestop = autocvar_g_vehicle_racer_bouncestop;
 564     instance.damageforcescale = 0.5;
 565     SetResourceExplicit(instance, RES_HEALTH, autocvar_g_vehicle_racer_health);
 566     instance.vehicle_shield = autocvar_g_vehicle_racer_shield;
 567 #endif
 568 }
 569
 570 METHOD(Racer, vr_death, void(Racer thisveh, entity instance))
 571 {
 572 #ifdef SVQC
 573     setSendEntity(instance, func_null); // stop networking this racer (for now)
 574     SetResourceExplicit(instance, RES_HEALTH, 0);
 575     instance.event_damage       = func_null;
 576     instance.solid                      = SOLID_CORPSE;
 577     instance.takedamage         = DAMAGE_NO;
 578     instance.deadflag           = DEAD_DYING;
 579     set_movetype(instance, MOVETYPE_BOUNCE);
 580     instance.wait                       = time;
 581     instance.delay                      = 2 + time + random() * 3;
 582     instance.cnt                        = 1 + random() * 2;
 583     settouch(instance, racer_deadtouch);
 584
 585     Send_Effect(EFFECT_EXPLOSION_MEDIUM, instance.origin, '0 0 0', 1);
 586
 587     if(random() < 0.5)
 588         instance.avelocity_z = 32;
 589     else
 590         instance.avelocity_z = -32;
 591
 592     instance.avelocity_x = -vlen(instance.velocity) * 0.2;
 593     instance.velocity += '0 0 700';
 594     instance.colormod = '-0.5 -0.5 -0.5';
 595
 596     setthink(instance, racer_blowup_think);
 597     instance.nextthink = time;
 598 #endif
 599 }
 600
 601 #ifdef CSQC
 602 METHOD(Racer, vr_hud, void(Racer thisveh))
 603 {
 604     Vehicles_drawHUD(VEH_RACER.m_icon, "vehicle_racer_weapon1", "vehicle_racer_weapon2",
 605                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 606                      "vehicle_icon_ammo2", autocvar_hud_progressbar_vehicles_ammo2_color);
 607 }
 608 METHOD(Racer, vr_crosshair, void(Racer thisveh, entity player))
 609 {
 610     Vehicles_drawCrosshair(vCROSS_GUIDE);
 611 }
 612 #endif
 613 METHOD(Racer, vr_setup, void(Racer thisveh, entity instance))
 614 {
 615 #ifdef SVQC
 616     instance.vehicle_exit = racer_exit;
 617
 618     // we have no need to network energy
 619     if(autocvar_g_vehicle_racer_energy && autocvar_g_vehicle_racer_energy_regen)
 620         instance.vehicle_flags |= VHF_ENERGYREGEN;
 621
 622     if(autocvar_g_vehicle_racer_shield)
 623         instance.vehicle_flags |= VHF_HASSHIELD;
 624
 625     if(autocvar_g_vehicle_racer_shield_regen)
 626         instance.vehicle_flags |= VHF_SHIELDREGEN;
 627
 628     if(autocvar_g_vehicle_racer_health_regen)
 629         instance.vehicle_flags |= VHF_HEALTHREGEN;
 630
 631     instance.respawntime = autocvar_g_vehicle_racer_respawntime;
 632     SetResourceExplicit(instance, RES_HEALTH, autocvar_g_vehicle_racer_health);
 633     instance.vehicle_shield = autocvar_g_vehicle_racer_shield;
 634     instance.max_health = GetResource(instance, RES_HEALTH);
 635 #endif
 636
 637 #ifdef CSQC
 638     AuxiliaryXhair[0].axh_image = vCROSS_LOCK; // Rocket
 639 #endif
 640 }
 641
 642 #endif