qcsrc/common/notifications/all.qh

   1 #pragma once
   2
   3 #include <common/command/_mod.qh>
   4
   5 #include <common/constants.qh>
   6 #include <common/teams.qh>
   7 #include <common/util.qh>
   8 #include <common/sounds/sound.qh>
   9 #include <common/weapons/all.qh>
  10
  11 // Operator for bold notifications
  12 #define BOLD_OPERATOR "^BOLD"
  13
  14 /** main types/groups of notifications */
  15 ENUMCLASS(MSG)
  16         /** "Global" AND "personal" announcer messages */
  17         CASE(MSG, ANNCE)
  18         /** "Global" information messages */
  19         CASE(MSG, INFO)
  20         /** "Personal" centerprint messages */
  21         CASE(MSG, CENTER)
  22         /** Subcall MSG_INFO and/or MSG_CENTER notifications */
  23         CASE(MSG, MULTI)
  24         /** Choose which subcall wrapper to activate */
  25         CASE(MSG, CHOICE)
  26         /** Kill centerprint message @deprecated */
  27         CASE(MSG, CENTER_KILL)
  28 ENUMCLASS_END(MSG)
  29
  30 string Get_Notif_TypeName(MSG net_type)
  31 {
  32         switch (net_type)
  33         {
  34                 case MSG_ANNCE: return "MSG_ANNCE";
  35                 case MSG_INFO: return "MSG_INFO";
  36                 case MSG_CENTER: return "MSG_CENTER";
  37                 case MSG_MULTI: return "MSG_MULTI";
  38                 case MSG_CHOICE: return "MSG_CHOICE";
  39                 case MSG_CENTER_KILL: return "MSG_CENTER_KILL";
  40         }
  41         LOG_WARNF("Get_Notif_TypeName(%d): Improper net type!", ORDINAL(net_type));
  42         return "";
  43 }
  44
  45 ENUMCLASS(CPID)
  46         CASE(CPID, ASSAULT_ROLE)
  47         CASE(CPID, ROUND)
  48         CASE(CPID, CAMPCHECK)
  49         CASE(CPID, CTF_CAPSHIELD)
  50         CASE(CPID, CTF_LOWPRIO)
  51         CASE(CPID, CTF_PASS)
  52         CASE(CPID, STALEMATE)
  53         CASE(CPID, NADES)
  54         CASE(CPID, IDLING)
  55         CASE(CPID, ITEM)
  56         CASE(CPID, PREVENT_JOIN)
  57         CASE(CPID, KEEPAWAY)
  58         CASE(CPID, KEEPAWAY_WARN)
  59         CASE(CPID, KEYHUNT)
  60         CASE(CPID, KEYHUNT_OTHER)
  61         CASE(CPID, LMS)
  62         CASE(CPID, MISSING_TEAMS)
  63         CASE(CPID, MISSING_PLAYERS)
  64         CASE(CPID, INSTAGIB_FINDAMMO)
  65         CASE(CPID, NIX)
  66         CASE(CPID, ONSLAUGHT)
  67         CASE(CPID, ONS_CAPSHIELD)
  68         CASE(CPID, OVERTIME)
  69         CASE(CPID, POWERUP)
  70         CASE(CPID, RACE_FINISHLAP)
  71         CASE(CPID, TEAMCHANGE)
  72         CASE(CPID, TIMEOUT)
  73         CASE(CPID, TIMEIN)
  74         CASE(CPID, VEHICLES)
  75         CASE(CPID, VEHICLES_OTHER)
  76         /** always last */
  77         CASE(CPID, LAST)
  78 ENUMCLASS_END(CPID)
  79
  80 USING(Notification, entity);
  81
  82 // used for notification system multi-team identifiers
  83 #define APP_TEAM_NUM(num, prefix) ((num == NUM_TEAM_1) ? prefix##_RED : ((num == NUM_TEAM_2) ? prefix##_BLUE : ((num == NUM_TEAM_3) ? prefix##_YELLOW : prefix##_PINK)))
  84 #define APP_NUM(num, prefix) ((num) ? APP_TEAM_NUM(num, prefix) : prefix##_NEUTRAL)
  85
  86 #define EIGHT_VARS_TO_VARARGS_VARLIST \
  87         VARITEM(1, 0, s1) \
  88         VARITEM(2, 0, XPD(s1, s2)) \
  89         VARITEM(3, 0, XPD(s1, s2, s3)) \
  90         VARITEM(4, 0, XPD(s1, s2, s3, s4)) \
  91         VARITEM(0, 1, f1) \
  92         VARITEM(1, 1, XPD(s1, f1)) \
  93         VARITEM(2, 1, XPD(s1, s2, f1)) \
  94         VARITEM(3, 1, XPD(s1, s2, s3, f1)) \
  95         VARITEM(4, 1, XPD(s1, s2, s3, s4, f1)) \
  96         VARITEM(0, 2, XPD(f1, f2)) \
  97         VARITEM(1, 2, XPD(s1, f1, f2)) \
  98         VARITEM(2, 2, XPD(s1, s2, f1, f2)) \
  99         VARITEM(3, 2, XPD(s1, s2, s3, f1, f2)) \
 100         VARITEM(4, 2, XPD(s1, s2, s3, s4, f1, f2)) \
 101         VARITEM(0, 3, XPD(f1, f2, f3)) \
 102         VARITEM(1, 3, XPD(s1, f1, f2, f3)) \
 103         VARITEM(2, 3, XPD(s1, s2, f1, f2, f3)) \
 104         VARITEM(3, 3, XPD(s1, s2, s3, f1, f2, f3)) \
 105         VARITEM(4, 3, XPD(s1, s2, s3, s4, f1, f2, f3)) \
 106         VARITEM(0, 4, XPD(f1, f2, f3, f4)) \
 107         VARITEM(1, 4, XPD(s1, f1, f2, f3, f4)) \
 108         VARITEM(2, 4, XPD(s1, s2, f1, f2, f3, f4)) \
 109         VARITEM(3, 4, XPD(s1, s2, s3, f1, f2, f3, f4)) \
 110         VARITEM(4, 4, XPD(s1, s2, s3, s4, f1, f2, f3, f4))
 111
 112 void Destroy_All_Notifications();
 113 void Create_Notification_Entity(entity notif,
 114         float var_default,
 115         float var_cvar,
 116         MSG typeId,
 117         string namestring,
 118         int teamnum);
 119 void Create_Notification_Entity_Annce(entity notif,
 120                                                                                 float var_cvar,
 121                                                                                 string namestring,
 122                                                                                 /* MSG_ANNCE */
 123                                                                                 float channel,
 124                                                                                 string snd,
 125                                                                                 float vol,
 126                                                                                 float position,
 127                                                                                 float queuetime);
 128
 129 void Create_Notification_Entity_InfoCenter(entity notif,
 130                                                                                         float var_cvar,
 131                                                                                         string namestring,
 132                                                                                         int strnum,
 133                                                                                         int flnum,
 134                                                                                         /* MSG_INFO & MSG_CENTER */
 135                                                                                         string args,
 136                                                                                         string hudargs,
 137                                                                                         string icon,
 138                                                                                         CPID cpid,
 139                                                                                         string durcnt,
 140                                                                                         string normal,
 141                                                                                         string gentle);
 142
 143 void Create_Notification_Entity_Multi(entity notif,
 144                                                                                 float var_cvar,
 145                                                                                 string namestring,
 146                                                                                 /* MSG_MULTI */
 147                                                                                 Notification anncename,
 148                                                                                 Notification infoname,
 149                                                                                 Notification centername);
 150
 151 void Create_Notification_Entity_Choice(entity notif,
 152                                                                                 float var_cvar,
 153                                                                                 string namestring,
 154                                                                                 /* MSG_CHOICE */
 155                                                                                 float challow_def,
 156                                                                                 float challow_var,
 157                                                                                 MSG chtype,
 158                                                                                 Notification optiona,
 159                                                                                 Notification optionb);
 160
 161 void Dump_Notifications(int fh, bool alsoprint);
 162
 163 #define DEFAULT_FILENAME "notifications_dump.cfg"
 164 // NOTE: dumpeffectinfo, dumpnotifs, dumpturrets and dumpweapons use similar code
 165 GENERIC_COMMAND(dumpnotifs, "Dump all notifications into " DEFAULT_FILENAME, false)
 166 {
 167         switch (request)
 168         {
 169                 case CMD_REQUEST_COMMAND:
 170                 {
 171                         #ifdef GAMEQC
 172                         string filename = argv(1);
 173                         bool alsoprint = false;
 174                         if (filename == "")
 175                         {
 176                                 filename = DEFAULT_FILENAME;
 177                                 alsoprint = false;
 178                         }
 179                         else if (filename == "-")
 180                         {
 181                                 filename = DEFAULT_FILENAME;
 182                                 alsoprint = true;
 183                         }
 184                         int fh = fopen(filename, FILE_WRITE);
 185                         if (fh >= 0)
 186                         {
 187                                 Dump_Notifications(fh, alsoprint);
 188                                 LOG_INFOF("Dumping notifications... File located in ^2data/data/%s^7.", filename);
 189                                 fclose(fh);
 190                         }
 191                         else
 192                         {
 193                                 LOG_INFOF("^1Error: ^7Could not open file '%s'!", filename);
 194                         }
 195                         #else
 196                         LOG_INFO("Notification dump command only works with cl_cmd and sv_cmd.");
 197                         #endif
 198                         return;
 199                 }
 200                 default:
 201                 case CMD_REQUEST_USAGE:
 202                 {
 203                         LOG_HELP("Usage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [<filename>]");
 204                         LOG_HELPF("  Where <filename> is the file to write (default is %s),", DEFAULT_FILENAME);
 205                         LOG_HELP("  if supplied with '-' output to console as well as default,");
 206                         LOG_HELP("  if left blank, it will only write to default.");
 207                         return;
 208                 }
 209         }
 210 }
 211 #undef DEFAULT_FILENAME
 212
 213 #ifdef NOTIFICATIONS_DEBUG
 214 bool autocvar_notification_debug = false;
 215 void Debug_Notification(string input)
 216 {
 217         switch (autocvar_notification_debug)
 218         {
 219                 case 1: { LOG_TRACE(input); break; }
 220                 case 2: { LOG_INFO(input); break; }
 221         }
 222 }
 223 #endif
 224
 225 void Local_Notification(MSG net_type, Notification net_name, ...count);
 226 /** glue for networking, forwards to `Local_Notification` */
 227 void Local_Notification_WOVA(
 228         MSG net_type, Notification net_name,
 229         float stringcount, float floatcount,
 230         string s1, string s2, string s3, string s4,
 231         float f1, float f2, float f3, float f4);
 232
 233 #ifdef CSQC
 234 string prev_soundfile;
 235 float prev_soundtime;
 236 #endif
 237
 238 #ifdef SVQC
 239 IntrusiveList g_notifications;
 240 STATIC_INIT(g_notifications) { g_notifications = IL_NEW(); }
 241 #endif
 242
 243 #ifdef SVQC
 244 ENUMCLASS(NOTIF)
 245         /** send to one client and their spectators */
 246         CASE(NOTIF, ONE)
 247         /** send ONLY to one client */
 248         CASE(NOTIF, ONE_ONLY)
 249         /** send only to X team and their spectators */
 250         CASE(NOTIF, TEAM)
 251         /** send only to X team and their spectators, except for Y person and their spectators */
 252         CASE(NOTIF, TEAM_EXCEPT)
 253         /** send to everyone */
 254         CASE(NOTIF, ALL)
 255         /** send to everyone except X person and their spectators */
 256         CASE(NOTIF, ALL_EXCEPT)
 257 ENUMCLASS_END(NOTIF)
 258
 259 string Get_Notif_BroadcastName(NOTIF broadcast)
 260 {
 261         switch (broadcast)
 262         {
 263                 case NOTIF_ONE: return "NOTIF_ONE";
 264                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
 265                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
 266                 case NOTIF_ALL: return "NOTIF_ALL";
 267                 case NOTIF_TEAM: return "NOTIF_TEAM";
 268                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
 269         }
 270         LOG_WARNF("Get_Notif_BroadcastName(%d): Improper broadcast!", broadcast);
 271         return "";
 272 }
 273
 274 void Kill_Notification(
 275         NOTIF broadcast, entity client,
 276         MSG net_type, CPID net_name);
 277 void Send_Notification(
 278         NOTIF broadcast, entity client,
 279         MSG net_type, Notification net_name,
 280         ...count);
 281 void Send_Notification_WOVA(
 282         NOTIF broadcast, entity client,
 283         MSG net_type, Notification net_name,
 284         float stringcount, float floatcount,
 285         string s1, string s2, string s3, string s4,
 286         float f1, float f2, float f3, float f4);
 287 void Send_Notification_WOCOVA(
 288         NOTIF broadcast, entity client,
 289         MSG net_type, Notification net_name,
 290         string s1, string s2, string s3, string s4,
 291         float f1, float f2, float f3, float f4);
 292 #endif
 293
 294 // ===========================
 295 //  Special CVAR Declarations
 296 // ===========================
 297
 298 // MAKE SURE THIS IS ALWAYS SYNCHRONIZED WITH THE DUMP
 299 // NOTIFICATIONS FUNCTION IN THE .QC FILE!
 300
 301 #define NOTIF_ADD_AUTOCVAR(name,defaultvalue) float autocvar_notification_##name = defaultvalue;
 302
 303 float autocvar_notification_show_location = false;
 304 string autocvar_notification_show_location_string = ""; //_(" at the %s");
 305 float autocvar_notification_show_sprees = true;
 306 float autocvar_notification_show_sprees_info = 3; // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 307 float autocvar_notification_show_sprees_info_newline = true;
 308 float autocvar_notification_show_sprees_info_specialonly = true;
 309 float autocvar_notification_errors_are_fatal = true;
 310 #ifdef SVQC
 311 float autocvar_notification_lifetime_runtime = 0.5;
 312 float autocvar_notification_lifetime_mapload = 10;
 313 #endif
 314
 315 #ifdef SVQC
 316 void Notification_GetCvars(entity this, entity store);
 317 float autocvar_notification_server_allows_location = 1; // 0 = no, 1 = yes
 318 #else
 319 float autocvar_notification_item_centerprinttime = 1.5;
 320
 321 // 0 = no, 1 = yes, 2 = forced on for all MSG_INFO notifs
 322 // DISABLED IN CODE, BUT ENABLED IN CONFIG FOR COMPATIBILITY WITH OLD CLIENTS
 323 float autocvar_notification_allow_chatboxprint = 0;
 324
 325 float autocvar_notification_show_sprees_center = true;
 326 float autocvar_notification_show_sprees_center_specialonly = true;
 327 #endif
 328
 329
 330 // ============================
 331 //  Notification Argument List
 332 // ============================
 333 /*
 334  These arguments get replaced with the Local_Notification_sprintf
 335  and other such functions found in all.qc to supply data
 336  from networked notifications to their usage in sprintf... It
 337  allows for more dynamic data to be inferred by the local
 338  notification parser, so that the server does not have to network
 339  anything too crazy on a per-client/per-situation basis.
 340
 341  Pay attention to the CSQC/SVQC relations, some of these are redefined
 342  in slightly different ways for different programs, this is because the
 343  server does a more conservative approach to the notifs than the client.
 344
 345  All arguments are swapped into strings, so be sure that your
 346  sprintf usage matches with proper %s placement.
 347
 348  Argument descriptions:
 349         s1-s4: string arguments to be literally swapped into sprintf
 350         s2loc: s2 string of locations of deaths or other events
 351         s3loc: s3 string of locations of deaths or other events
 352         f1-f4: float arguments expanded into strings to be swapped into sprintf
 353         f1p2dec: f1 float to string with 2 decimal places
 354         f2p2dec: f2 float to string with 2 decimal places
 355         f2primsec: f2 float primary or secondary selection for weapons
 356         f3primsec: f3 float primary or secondary selection for weapons
 357         f1secs: count_seconds of f1
 358         f1points: point or points depending on f1
 359         f1ord: count_ordinal of f1
 360         f1time: process_time of f1
 361         f1race_time: TIME_ENCODED_TOSTRING of f1
 362         f2race_time: TIME_ENCODED_TOSTRING of f2
 363         race_col: color of race time/position (i.e. good or bad)
 364         race_diff: show time difference between f2 and f3
 365         missing_teams: show which teams still need players
 366         pass_key: find the keybind for "passing" or "dropping" in CTF game mode
 367         nade_key: find the keybind for nade throwing
 368         frag_ping: show the ping of a player
 369         frag_stats: show health/armor/ping of a player
 370         frag_pos: show score status and position in the match of a player
 371         spree_cen: centerprint notif for kill spree/how many kills they have
 372         spree_inf: info notif for kill spree/how many kills they have
 373         spree_end: placed at the end of murder messages to show ending of sprees
 374         spree_lost: placed at the end of suicide messages to show losing of sprees
 375         item_wepname: return full name of a weapon from weaponid
 376         item_wepammo: ammo display for weapon from f1 and f2
 377         item_centime: amount of time to display weapon message in centerprint
 378         item_buffname: return full name of a buff from buffid
 379         death_team: show the full name of the team a player is switching from
 380         minigame1_name: return human readable name of a minigame from its id(s1)
 381         minigame1_d: return descriptor name of a minigame from its id(s1)
 382 */
 383
 384 const float NOTIF_MAX_ARGS = 7;
 385 const float NOTIF_MAX_HUDARGS = 2;
 386 const float NOTIF_MAX_DURCNT = 2;
 387
 388 #ifdef CSQC
 389 const int NOTIF_QUEUE_MAX = 10;
 390 entity notif_queue_entity[NOTIF_QUEUE_MAX];
 391 MSG notif_queue_type[NOTIF_QUEUE_MAX];
 392 float notif_queue_time[NOTIF_QUEUE_MAX];
 393
 394 float notif_queue_next_time;
 395 int notif_queue_length;
 396
 397 void Local_Notification_Queue_Process();
 398 #endif
 399
 400 string arg_slot[NOTIF_MAX_ARGS];
 401
 402 const float ARG_CS_SV_HA = 1; // enabled on CSQC, SVQC, and Hudargs
 403 const float ARG_CS_SV_DC = 2; // enabled on CSQC, SVQC, and durcnt centerprint
 404 const float ARG_CS_SV = 3; // enabled on CSQC and SVQC
 405 const float ARG_CS = 4; // unique result to CSQC
 406 const float ARG_SV = 5; // unique result to SVQC
 407 const float ARG_DC = 6; // unique result to durcnt/centerprint
 408
 409 // todo possible idea.... declare how many floats/strings each arg needs, and then dynamically increment the input
 410 // this way, we don't need to have duplicates like i.e. s2loc and s3loc?
 411
 412 string BUFF_NAME(int i);
 413
 414 #define NOTIF_ARGUMENT_LIST \
 415         ARG_CASE(ARG_CS_SV_HA,  "s1",            s1) \
 416         ARG_CASE(ARG_CS_SV_HA,  "s2",            s2) \
 417         ARG_CASE(ARG_CS_SV_HA,  "s3",            s3) \
 418         ARG_CASE(ARG_CS_SV_HA,  "s4",            s4) \
 419         ARG_CASE(ARG_CS_SV,     "s2loc",         ((autocvar_notification_show_location && (s2 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s2) : "")) \
 420         ARG_CASE(ARG_CS_SV,     "s3loc",         ((autocvar_notification_show_location && (s3 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s3) : "")) \
 421         ARG_CASE(ARG_CS_SV_DC,  "f1",            ftos(f1)) \
 422         ARG_CASE(ARG_CS_SV_DC,  "f2",            ftos(f2)) \
 423         ARG_CASE(ARG_CS_SV,     "f3",            ftos(f3)) \
 424         ARG_CASE(ARG_CS_SV,     "f4",            ftos(f4)) \
 425         ARG_CASE(ARG_CS_SV,     "f1dtime",       ftos_decimals(TIME_DECODE(f1), 2)) \
 426         ARG_CASE(ARG_CS_SV,     "f2dtime",       ftos_decimals(TIME_DECODE(f2), 2)) \
 427         ARG_CASE(ARG_CS,        "f2primsec",     (f2 ? _("secondary") : _("primary"))) \
 428         ARG_CASE(ARG_CS,        "f3primsec",     (f3 ? _("secondary") : _("primary"))) \
 429         ARG_CASE(ARG_CS,        "f1secs",        count_seconds(f1)) \
 430         ARG_CASE(ARG_CS,        "f1points",      (f1 == 1 ? _("point") : _("points"))) \
 431         ARG_CASE(ARG_CS_SV,     "f1ord",         count_ordinal(f1)) \
 432         ARG_CASE(ARG_CS_SV,     "f1time",        process_time(2, f1)) \
 433         ARG_CASE(ARG_CS_SV_HA,  "f1race_time",   TIME_ENCODED_TOSTRING(f1, true)) \
 434         ARG_CASE(ARG_CS_SV_HA,  "f2race_time",   TIME_ENCODED_TOSTRING(f2, true)) \
 435         ARG_CASE(ARG_CS_SV_HA,  "f3race_time",   TIME_ENCODED_TOSTRING(f3, true)) \
 436         ARG_CASE(ARG_CS_SV,     "race_col",      CCR(((f1 == 1) ? "^F1" : "^F2"))) \
 437         ARG_CASE(ARG_CS_SV,     "race_diff",     ((f2 > f3) ? sprintf(CCR("^1[+%s]"), TIME_ENCODED_TOSTRING(f2 - f3, true)) : sprintf(CCR("^2[-%s]"), TIME_ENCODED_TOSTRING(f3 - f2, true)))) \
 438         ARG_CASE(ARG_CS,        "missing_teams", notif_arg_missing_teams(f1)) \
 439         ARG_CASE(ARG_CS,        "pass_key",      getcommandkey(_("drop flag"), "+use")) \
 440         ARG_CASE(ARG_CS,        "nade_key",      getcommandkey(_("throw nade"), "dropweapon")) \
 441         ARG_CASE(ARG_CS,        "join_key",      getcommandkey(_("jump"), "+jump")) \
 442         ARG_CASE(ARG_CS,        "frag_ping",     notif_arg_frag_ping(true, f2)) \
 443         ARG_CASE(ARG_CS,        "frag_stats",    notif_arg_frag_stats(f2, f3, f4)) \
 444         /*ARG_CASE(ARG_CS,      "frag_pos",      ((Should_Print_Score_Pos(f1)) ? sprintf("\n^BG%s", Read_Score_Pos(f1)) : ""))*/ \
 445         ARG_CASE(ARG_CS,        "spree_cen",     (autocvar_notification_show_sprees ? notif_arg_spree_cen(f1) : "")) \
 446         ARG_CASE(ARG_CS_SV,     "spree_inf",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(1, input, s2, f2) : "")) \
 447         ARG_CASE(ARG_CS_SV,     "spree_end",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(-1, "", "", f1) : "")) \
 448         ARG_CASE(ARG_CS_SV,     "spree_lost",    (autocvar_notification_show_sprees ? notif_arg_spree_inf(-2, "", "", f1) : "")) \
 449         ARG_CASE(ARG_CS_SV,     "item_wepname",  REGISTRY_GET(Weapons, f1).m_name) \
 450         ARG_CASE(ARG_CS_SV,     "item_buffname", BUFF_NAME(f1)) \
 451         ARG_CASE(ARG_CS_SV,     "f3buffname",    BUFF_NAME(f3)) \
 452         ARG_CASE(ARG_CS_SV,     "item_wepammo",  (f2 > 0 ? notif_arg_item_wepammo(f1, f2) : "")) \
 453         ARG_CASE(ARG_DC,        "item_centime",  ftos(autocvar_notification_item_centerprinttime)) \
 454         ARG_CASE(ARG_SV,        "death_team",    Team_ColoredFullName(f1)) \
 455         ARG_CASE(ARG_CS,        "death_team",    Team_ColoredFullName(f1 - 1)) \
 456         ARG_CASE(ARG_CS_SV_HA,  "minigame1_name",find(NULL,netname,s1).descriptor.message) \
 457         ARG_CASE(ARG_CS_SV_HA,  "minigame1_d",   find(NULL,netname,s1).descriptor.netname)
 458
 459 #define NOTIF_HIT_MAX(count,funcname) MACRO_BEGIN \
 460         if(sel_num == count) { backtrace(sprintf("%s: Hit maximum arguments!\n", funcname)); break; } \
 461 MACRO_END
 462
 463 #define NOTIF_HIT_UNKNOWN(token,funcname) { backtrace(sprintf("%s: Hit unknown token in selected string! '%s'\n", funcname, selected)); break; }
 464
 465 #define KILL_SPREE_LIST \
 466         SPREE_ITEM(3, 03, _("TRIPLE FRAG! "), _("%s^K1 made a TRIPLE FRAG! %s^BG"), _("%s^K1 made a TRIPLE SCORE! %s^BG")) \
 467         SPREE_ITEM(5, 05, _("RAGE! "), _("%s^K1 unlocked RAGE! %s^BG"), _("%s^K1 made FIVE SCORES IN A ROW! %s^BG")) \
 468         SPREE_ITEM(10, 10, _("MASSACRE! "), _("%s^K1 started a MASSACRE! %s^BG"), _("%s^K1 made TEN SCORES IN A ROW! %s^BG")) \
 469         SPREE_ITEM(15, 15, _("MAYHEM! "), _("%s^K1 executed MAYHEM! %s^BG"), _("%s^K1 made FIFTEEN SCORES IN A ROW! %s^BG")) \
 470         SPREE_ITEM(20, 20, _("BERSERKER! "), _("%s^K1 is a BERSERKER! %s^BG"), _("%s^K1 made TWENTY SCORES IN A ROW! %s^BG")) \
 471         SPREE_ITEM(25, 25, _("CARNAGE! "), _("%s^K1 inflicts CARNAGE! %s^BG"), _("%s^K1 made TWENTY FIVE SCORES IN A ROW! %s^BG")) \
 472         SPREE_ITEM(30, 30, _("ARMAGEDDON! "), _("%s^K1 unleashes ARMAGEDDON! %s^BG"), _("%s^K1 made THIRTY SCORES IN A ROW! %s^BG"))
 473
 474 #ifdef CSQC
 475 string notif_arg_frag_ping(bool newline, float fping)
 476 {
 477         string s = newline ? "\n" : " ";
 478         if (fping < 0)
 479                 return sprintf(CCR(_("%s(^F1Bot^BG)")), s);
 480         else
 481                 return sprintf(CCR(_("%s(Ping ^F1%d^BG)")), s, fping);
 482 }
 483
 484 string notif_arg_frag_stats(float fhealth, float farmor, float fping)
 485 {
 486         string s = notif_arg_frag_ping(false, fping);
 487         if (fhealth > 1)
 488                 return sprintf(CCR(_("\n(Health ^1%d^BG / Armor ^2%d^BG)%s")), fhealth, farmor, s);
 489         else
 490                 return sprintf(CCR(_("\n(^F4Dead^BG)%s")), s);
 491 }
 492
 493 string notif_arg_missing_teams(float f1)
 494 {
 495         return strcat(
 496                 ((f1 & BIT(0)) ? strcat(Team_ColoredFullName(NUM_TEAM_1), (f1 >> 1) ? ", " : "") : ""),
 497                 ((f1 & BIT(1)) ? strcat(Team_ColoredFullName(NUM_TEAM_2), (f1 >> 2) ? ", " : "") : ""),
 498                 ((f1 & BIT(2)) ? strcat(Team_ColoredFullName(NUM_TEAM_3), (f1 >> 3) ? ", " : "") : ""),
 499                 ((f1 & BIT(3)) ?        Team_ColoredFullName(NUM_TEAM_4)                         : "")
 500         );
 501 }
 502
 503 string notif_arg_spree_cen(float spree)
 504 {
 505         // 0 = off, 1 = target (but only for first victim) and attacker
 506         if(autocvar_notification_show_sprees_center)
 507         {
 508                 if(spree > 1)
 509                 {
 510                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 511                                 case counta: { return normal_or_gentle(center, sprintf(_("%d score spree! "), spree)); }
 512
 513                         switch(spree)
 514                         {
 515                                 KILL_SPREE_LIST
 516                                 default:
 517                                 {
 518                                         if (!autocvar_notification_show_sprees_center_specialonly)
 519                                         {
 520                                                 return
 521                                                         sprintf(
 522                                                                 normal_or_gentle(
 523                                                                         _("%d frag spree! "),
 524                                                                         _("%d score spree! ")
 525                                                                 ),
 526                                                                 spree);
 527                                         }
 528                                         else { return ""; } // don't show spree information if it isn't an achievement
 529                                 }
 530                         }
 531
 532                         #undef SPREE_ITEM
 533                 }
 534                 else if(spree == -1) // first blood
 535                 {
 536                         return normal_or_gentle(_("First blood! "), _("First score! "));
 537                 }
 538                 else if(spree == -2) // first victim
 539                 {
 540                         return normal_or_gentle(_("First victim! "), _("First casualty! "));
 541                 }
 542         }
 543         return "";
 544 }
 545 #endif
 546
 547 string notif_arg_spree_inf(float type, string input, string player, float spree)
 548 {
 549         switch(type)
 550         {
 551                 case 1: // attacker kill spree
 552                 {
 553                         // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 554                         // this conditional (& 2) is true for 2 and 3
 555                         if(autocvar_notification_show_sprees_info & 2)
 556                         {
 557                                 #ifdef CSQC
 558                                 string spree_newline =
 559                                         ( autocvar_notification_show_sprees_info_newline ?
 560                                                 ((substring(input, 0, 1) == "\{3}") ? "\n\{3}" : "\n") : "" );
 561                                 #else
 562                                 string spree_newline =
 563                                         (autocvar_notification_show_sprees_info_newline ? "\n" : "");
 564                                 #endif
 565
 566                                 if(spree > 1)
 567                                 {
 568                                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 569                                                 case counta: { return sprintf(CCR(normal_or_gentle(normal, gentle)), player, spree_newline); }
 570
 571                                         switch(spree)
 572                                         {
 573                                                 KILL_SPREE_LIST
 574                                                 default:
 575                                                 {
 576                                                         if (!autocvar_notification_show_sprees_info_specialonly)
 577                                                         {
 578                                                                 return
 579                                                                         sprintf(
 580                                                                                 CCR(normal_or_gentle(
 581                                                                                         _("%s^K1 has %d frags in a row! %s^BG"),
 582                                                                                         _("%s^K1 made %d scores in a row! %s^BG")
 583                                                                                 )),
 584                                                                                 player,
 585                                                                                 spree,
 586                                                                                 spree_newline
 587                                                                         );
 588                                                         }
 589                                                         else { return ""; } // don't show spree information if it isn't an achievement
 590                                                 }
 591                                         }
 592
 593                                         #undef SPREE_ITEM
 594                                 }
 595                                 else if(spree == -1) // firstblood
 596                                 {
 597                                         return
 598                                                 sprintf(
 599                                                         CCR(normal_or_gentle(
 600                                                                 _("%s^K1 drew first blood! %s^BG"),
 601                                                                 _("%s^K1 got the first score! %s^BG")
 602                                                         )),
 603                                                         player,
 604                                                         spree_newline
 605                                                 );
 606                                 }
 607                         }
 608                         break;
 609                 }
 610
 611                 case -1: // kill spree ended
 612                 {
 613                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 614                         {
 615                                 return
 616                                         sprintf(normal_or_gentle(
 617                                                 _(", ending their %d frag spree"),
 618                                                 _(", ending their %d score spree")
 619                                                 ),
 620                                                 spree
 621                                         );
 622                         }
 623                         break;
 624                 }
 625
 626                 case -2: // kill spree lost
 627                 {
 628                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 629                         {
 630                                 return
 631                                         sprintf(normal_or_gentle(
 632                                                 _(", losing their %d frag spree"),
 633                                                 _(", losing their %d score spree")
 634                                                 ),
 635                                                 spree
 636                                         );
 637                         }
 638                         break;
 639                 }
 640         }
 641         return "";
 642 }
 643
 644 string notif_arg_item_wepammo(float f1, float f2)
 645 {
 646         string ammoitems = "";
 647         Weapon wep = REGISTRY_GET(Weapons, f1);
 648         // TODO: registry handles
 649         switch (wep.ammo_type)
 650         {
 651                 case RES_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
 652                 case RES_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
 653                 case RES_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
 654                 case RES_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
 655                 case RES_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
 656                 case RES_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
 657                 default: return ""; // doesn't use ammo
 658         }
 659         return sprintf(_(" with %d %s"), f2, strtolower(ammoitems));
 660 }
 661
 662
 663 // ====================================
 664 //  Initialization/Create Declarations
 665 // ====================================
 666
 667 // common notification entity values
 668 .int nent_default;
 669 .bool nent_enabled;
 670 .MSG nent_type;
 671 .string nent_name;
 672 .int nent_stringcount;
 673 .int nent_floatcount;
 674 .int nent_teamnum;
 675
 676 // MSG_ANNCE entity values
 677 .int nent_channel;
 678 .string nent_snd;
 679 .float nent_vol;
 680 .float nent_position;
 681 .float nent_queuetime;
 682
 683 // MSG_INFO and MSG_CENTER entity values
 684 .string nent_args; // used by both
 685 .string nent_hudargs; // used by info
 686 .string nent_icon; // used by info
 687 .CPID nent_cpid; // used by center
 688 .string nent_durcnt; // used by center
 689 .string nent_string; // used by both
 690
 691 // MSG_MULTI entity values
 692 .entity nent_msgannce;
 693 .entity nent_msginfo;
 694 .entity nent_msgcenter;
 695
 696 // MSG_CHOICE entity values
 697 .float nent_challow_def;
 698 .float nent_challow_var;
 699 .entity nent_optiona;
 700 .entity nent_optionb;
 701
 702 // networked notification entity values
 703 #ifdef SVQC
 704 .NOTIF nent_broadcast;
 705 #endif
 706 .entity nent_client;
 707 .MSG nent_net_type;
 708 .float nent_net_name;
 709 .string nent_strings[4];
 710 .float nent_floats[4];
 711
 712 #define ACVNN(name) autocvar_notification_##name
 713
 714 REGISTRY(Notifications, BITS(11))
 715 REGISTER_REGISTRY(Notifications)
 716 REGISTRY_SORT(Notifications);
 717
 718 REGISTRY_DEFINE_GET(Notifications, NULL)
 719 STATIC_INIT(Notifications) { FOREACH(Notifications, true, it.m_id = i); }
 720 REGISTRY_CHECK(Notifications)
 721
 722 const int NOTIF_CHOICE_MAX = 20;
 723 // NOTE: a team choice is actually made of 4 choices (one per team) with the same nent_choice_idx
 724 // thus they are counted as 1 in nent_choice_count
 725 int nent_choice_count = 0;
 726 .int nent_choice_idx;
 727 .int msg_choice_choices[NOTIF_CHOICE_MAX]; // set on each player containing MSG_CHOICE choices
 728 // initialization error detection
 729 bool notif_error;
 730 bool notif_global_error;
 731
 732 STATIC_INIT_LATE(Notif_Choices)
 733 {
 734         if (nent_choice_count > NOTIF_CHOICE_MAX)
 735                 LOG_FATALF("Too many MSG_CHOICE notifications (%d), hit NOTIF_CHOICE_MAX (%d) limit",
 736                         nent_choice_count, NOTIF_CHOICE_MAX);
 737 }
 738
 739 string Get_Notif_CvarName(Notification notif)
 740 {
 741         if(!notif.nent_teamnum)
 742                 return notif.nent_name;
 743         return substring(notif.nent_name, 0, -strlen(Static_Team_ColorName(notif.nent_teamnum)) - 2);
 744 }
 745
 746 Notification Get_Notif_Ent(MSG net_type, int net_name)
 747 {
 748         Notification it = REGISTRY_GET(Notifications, net_name);
 749         if (it.nent_type != net_type) {
 750                 LOG_WARNF("Get_Notif_Ent(%s (%d), %s (%d)): Improper net type '%s'!",
 751                         Get_Notif_TypeName(net_type), net_type,
 752                         it.registered_id, net_name,
 753                         Get_Notif_TypeName(it.nent_type)
 754                 );
 755                 return NULL;
 756         }
 757         return it;
 758 }
 759
 760 #define MSG_ANNCE_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, sound, channel, volume, position, queuetime) \
 761         MSG_ANNCE_NOTIF_(teamnum, ANNCE_##name, ANNCE_##cvarname, defaultvalue, sound, channel, volume, position, queuetime)
 762
 763 #define MSG_ANNCE_NOTIF(name, defaultvalue, sound, channel, volume, position, queuetime) \
 764         NOTIF_ADD_AUTOCVAR(ANNCE_##name, defaultvalue) \
 765         MSG_ANNCE_NOTIF_(0, ANNCE_##name, ANNCE_##name, defaultvalue, sound, channel, volume, position, queuetime)
 766
 767 #define MSG_ANNCE_NOTIF_(teamnum, name, cvarname, defaultvalue, sound, channel, volume, position, queuetime) \
 768         REGISTER(Notifications, name, m_id, new_pure(msg_annce_notification)) { \
 769                 Create_Notification_Entity      (this, defaultvalue, ACVNN(cvarname), MSG_ANNCE, strtoupper(#name), teamnum); \
 770                 Create_Notification_Entity_Annce(this, ACVNN(cvarname), strtoupper(#name), \
 771                         channel,    /* channel   */ \
 772                         sound,      /* snd       */ \
 773                         volume,     /* vol       */ \
 774                         position,   /* position  */ \
 775                         queuetime); /* queuetime */ \
 776         }
 777
 778 #define MSG_INFO_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle) \
 779         MSG_INFO_NOTIF_(teamnum, INFO_##name, INFO_##cvarname, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle)
 780
 781 #define MSG_INFO_NOTIF(name, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle) \
 782         NOTIF_ADD_AUTOCVAR(INFO_##name, defaultvalue) \
 783         MSG_INFO_NOTIF_(0, INFO_##name, INFO_##name, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle)
 784
 785 #define MSG_INFO_NOTIF_(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle) \
 786         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 787                 Create_Notification_Entity           (this, defaultvalue, ACVNN(cvarname), MSG_INFO, strtoupper(#name), teamnum); \
 788                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
 789                         args,     /* args    */ \
 790                         hudargs,  /* hudargs */ \
 791                         icon,     /* icon    */ \
 792                         CPID_Null,/* cpid    */ \
 793                         "",       /* durcnt  */ \
 794                         normal,   /* normal  */ \
 795                         gentle);  /* gentle  */ \
 796         }
 797
 798 .string nent_iconargs;
 799 #define MULTIICON_INFO(name, defaultvalue, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 800         MULTIICON_INFO_(INFO_##name, defaultvalue, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle)
 801 #define MULTIICON_INFO_(name, defaultvalue, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 802         NOTIF_ADD_AUTOCVAR(name, defaultvalue) \
 803         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 804                 Create_Notification_Entity           (this, defaultvalue, ACVNN(name), MSG_INFO, strtoupper(#name), 0); \
 805                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 806                         args,     /* args    */ \
 807                         hudargs,  /* hudargs */ \
 808                         icon,     /* icon    */ \
 809                         CPID_Null,/* cpid    */ \
 810                         "",       /* durcnt  */ \
 811                         normal,   /* normal  */ \
 812                         gentle);  /* gentle  */ \
 813                 this.nent_iconargs = iconargs; \
 814         }
 815
 816 #define MSG_CENTER_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 817         MSG_CENTER_NOTIF_(teamnum, CENTER_##name, CENTER_##cvarname, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle)
 818
 819 #define MSG_CENTER_NOTIF(name, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 820         NOTIF_ADD_AUTOCVAR(CENTER_##name, defaultvalue) \
 821         MSG_CENTER_NOTIF_(0, CENTER_##name, CENTER_##name, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle)
 822
 823 #define MSG_CENTER_NOTIF_(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 824         REGISTER(Notifications, name, m_id, new_pure(msg_center_notification)) { \
 825                 Create_Notification_Entity           (this, defaultvalue, ACVNN(cvarname), MSG_CENTER, strtoupper(#name), teamnum); \
 826                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
 827                         args,    /* args    */ \
 828                         "",      /* hudargs */ \
 829                         "",      /* icon    */ \
 830                         cpid,    /* cpid    */ \
 831                         durcnt,  /* durcnt  */ \
 832                         normal,  /* normal  */ \
 833                         gentle); /* gentle  */ \
 834         }
 835
 836 #define MSG_MULTI_NOTIF(name, defaultvalue, anncename, infoname, centername) \
 837         NOTIF_ADD_AUTOCVAR(name, defaultvalue) \
 838         REGISTER(Notifications, name, m_id, new_pure(msg_multi_notification)) { \
 839                 Create_Notification_Entity      (this, defaultvalue, ACVNN(name), MSG_MULTI, strtoupper(#name), 0); \
 840                 Create_Notification_Entity_Multi(this, ACVNN(name), strtoupper(#name), \
 841                         anncename,   /* anncename  */ \
 842                         infoname,    /* infoname   */ \
 843                         centername); /* centername */ \
 844         }
 845
 846 #define MSG_CHOICE_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, challow, chtype, optiona, optionb) \
 847         MSG_CHOICE_NOTIF_(teamnum, CHOICE_##name, CHOICE_##cvarname, defaultvalue, challow, chtype, optiona, optionb)
 848
 849 #define MSG_CHOICE_NOTIF(name, defaultvalue, challow, chtype, optiona, optionb) \
 850         NOTIF_ADD_AUTOCVAR(CHOICE_##name, defaultvalue) \
 851         NOTIF_ADD_AUTOCVAR(CHOICE_##name##_ALLOWED, challow) \
 852         MSG_CHOICE_NOTIF_(0, CHOICE_##name, CHOICE_##name, defaultvalue, challow, chtype, optiona, optionb)
 853
 854 #define MSG_CHOICE_NOTIF_(teamnum, name, cvarname, defaultvalue, challow, chtype, optiona, optionb) \
 855         REGISTER(Notifications, name, m_id, new_pure(msg_choice_notification)) { \
 856                 this.nent_choice_idx = nent_choice_count; \
 857                 if (!teamnum || teamnum == NUM_TEAM_4) \
 858                         nent_choice_count++; \
 859                 Create_Notification_Entity       (this, defaultvalue, ACVNN(cvarname), MSG_CHOICE, strtoupper(#name), teamnum); \
 860                 Create_Notification_Entity_Choice(this, ACVNN(cvarname), strtoupper(#name), \
 861                         challow,                                 /* challow_def */ \
 862                         autocvar_notification_##cvarname##_ALLOWED,  /* challow_var */ \
 863                         chtype,                                  /* chtype      */ \
 864                         optiona,                                 /* optiona     */ \
 865                         optionb);                                /* optionb     */ \
 866         }
 867
 868 REGISTRY_BEGIN(Notifications)
 869 {
 870         notif_global_error = false;
 871 }
 872
 873 REGISTRY_END(Notifications)
 874 {
 875         if (!notif_global_error) return;
 876         // shit happened... stop the loading of the program now if this is unacceptable
 877         if (autocvar_notification_errors_are_fatal)
 878                 LOG_FATAL("Notification initialization failed! Read above and fix the errors!");
 879         else
 880                 LOG_SEVERE("Notification initialization failed! Read above and fix the errors!");
 881 }
 882
 883 #ifdef CSQC
 884 .int cvar_value;
 885 void ReplicateVars(bool would_destroy)
 886 {
 887         if (!would_destroy)
 888                 FOREACH(Notifications, it.nent_type == MSG_CHOICE && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
 889                         string cvarname = strcat("notification_", Get_Notif_CvarName(it));
 890                         // NOTE: REPLICATE_SIMPLE can return;
 891                         REPLICATE_SIMPLE(it.cvar_value, cvarname);
 892                 });
 893 }
 894 #endif
 895
 896 #include "all.inc"