qcsrc/common/mutators/mutator/overkill/okhmg.qc

   1 #include "okhmg.qh"
   2
   3 #ifdef SVQC
   4
   5 REGISTER_MUTATOR(okhmg_nadesupport, true);
   6 MUTATOR_HOOKFUNCTION(okhmg_nadesupport, Nade_Damage)
   7 {
   8         if (M_ARGV(1, entity) != WEP_OVERKILL_HMG) return;
   9         return = true;
  10         M_ARGV(3, float) /* damage */ = (M_ARGV(0, entity)).max_health * 0.1;
  11 }
  12
  13 void W_OverkillHeavyMachineGun_Attack_Auto(Weapon thiswep, entity actor, .entity weaponentity, int fire)
  14 {
  15         if (!PHYS_INPUT_BUTTON_ATCK(actor))
  16         {
  17                 w_ready(thiswep, actor, weaponentity, fire);
  18                 return;
  19         }
  20
  21         if((!thiswep.wr_checkammo1(thiswep, actor, weaponentity) && !(actor.items & IT_UNLIMITED_AMMO)) || (!StatusEffects_active(STATUSEFFECT_Superweapons, actor) && !(actor.items & IT_UNLIMITED_SUPERWEAPONS)))
  22         {
  23                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
  24                 w_ready(thiswep, actor, weaponentity, fire);
  25                 return;
  26         }
  27
  28         W_DecreaseAmmo(WEP_OVERKILL_HMG, actor, WEP_CVAR_PRI(okhmg, ammo), weaponentity);
  29
  30         W_SetupShot(actor, weaponentity, true, 0, SND_UZI_FIRE, CH_WEAPON_A, WEP_CVAR_PRI(okhmg, damage), WEP_OVERKILL_HMG.m_id);
  31
  32         if(!autocvar_g_norecoil)
  33         {
  34                 actor.punchangle_x = random () - 0.5;
  35                 actor.punchangle_y = random () - 0.5;
  36         }
  37
  38         float okhmg_spread = bound(WEP_CVAR_PRI(okhmg, spread_min), WEP_CVAR_PRI(okhmg, spread_min) + (WEP_CVAR_PRI(okhmg, spread_add) * actor.(weaponentity).misc_bulletcounter), WEP_CVAR_PRI(okhmg, spread_max));
  39         fireBullet(actor, weaponentity, w_shotorg, w_shotdir, okhmg_spread, WEP_CVAR_PRI(okhmg, solidpenetration), WEP_CVAR_PRI(okhmg, damage), 0, WEP_CVAR_PRI(okhmg, force), WEP_OVERKILL_HMG.m_id, EFFECT_RIFLE);
  40
  41         actor.(weaponentity).misc_bulletcounter = actor.(weaponentity).misc_bulletcounter + 1;
  42
  43         W_MuzzleFlash(thiswep, actor, weaponentity, w_shotorg, w_shotdir);
  44
  45         if (autocvar_g_casings >= 2) // casing code
  46         {
  47                 makevectors(actor.v_angle); // for some reason, this is lost
  48                 SpawnCasing(((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), vectoangles(v_forward), 3, actor, weaponentity);
  49         }
  50
  51         ATTACK_FINISHED(actor, weaponentity) = time + WEP_CVAR_PRI(okhmg, refire) * W_WeaponRateFactor(actor);
  52         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(okhmg, refire), W_OverkillHeavyMachineGun_Attack_Auto);
  53 }
  54
  55 METHOD(OverkillHeavyMachineGun, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
  56 {
  57         if(vdist(actor.origin - actor.enemy.origin, <, 3000 - bound(0, skill, 10) * 200))
  58                 PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false, true);
  59 }
  60
  61 METHOD(OverkillHeavyMachineGun, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
  62 {
  63         if ((WEP_CVAR_SEC(okhmg, refire_type) == 1) && (fire & 2) && (time >= actor.jump_interval))
  64         {
  65                 // Secondary uses it's own refire timer if refire_type is 1.
  66                 actor.jump_interval = time + WEP_CVAR_SEC(okhmg, refire) * W_WeaponRateFactor(actor);
  67                 makevectors(actor.v_angle);
  68                 W_Blaster_Attack(actor, weaponentity, WEP_BLASTER.m_id | HITTYPE_SECONDARY);
  69                 if ((actor.(weaponentity).wframe == WFRAME_IDLE) ||
  70                         (actor.(weaponentity).wframe == WFRAME_FIRE2))
  71                 {
  72                         // Set secondary fire animation.
  73                         actor.(weaponentity).wframe = WFRAME_FIRE2;
  74                         FOREACH_CLIENT(true, LAMBDA(
  75                                 if (it == actor || (IS_SPEC(it) && it.enemy == actor))
  76                                 {
  77                                         wframe_send(it, actor.(weaponentity), WFRAME_FIRE2, autocvar_g_weaponratefactor, true);
  78                                 }
  79                         ));
  80                         animdecide_setaction(actor, ANIMACTION_SHOOT, true);
  81                 }
  82         }
  83     if (WEP_CVAR(okhmg, reload_ammo) && actor.(weaponentity).clip_load < WEP_CVAR_PRI(okhmg, ammo))
  84         {
  85                 // Forced reload.
  86         thiswep.wr_reload(thiswep, actor, weaponentity);
  87                 return;
  88         }
  89         if (fire & 1) // Primary attack
  90         {
  91                 if (!weapon_prepareattack(thiswep, actor, weaponentity, false, 0))
  92                 {
  93                         return;
  94                 }
  95                 actor.(weaponentity).misc_bulletcounter = 0;
  96                 W_OverkillHeavyMachineGun_Attack_Auto(thiswep, actor, weaponentity, fire);
  97                 return;
  98         }
  99         if ((fire & 2) && (WEP_CVAR_SEC(okhmg, refire_type) == 0)) // Secondary attack
 100         {
 101                 if (!weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_SEC(okhmg, refire)))
 102                 {
 103                         return;
 104                 }
 105                 makevectors(actor.v_angle);
 106                 W_Blaster_Attack(actor, weaponentity, WEP_BLASTER.m_id | HITTYPE_SECONDARY);
 107                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(okhmg, animtime), w_ready);
 108         }
 109 }
 110
 111 METHOD(OverkillHeavyMachineGun, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 112 {
 113         float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(okhmg, ammo);
 114         if (autocvar_g_balance_okhmg_reload_ammo)
 115         {
 116                 ammo_amount += actor.(weaponentity).(weapon_load[WEP_OVERKILL_HMG.m_id]) >= WEP_CVAR_PRI(okhmg, ammo);
 117         }
 118         return ammo_amount;
 119 }
 120
 121 METHOD(OverkillHeavyMachineGun, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 122 {
 123         float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_SEC(okhmg, ammo);
 124         if (autocvar_g_balance_okhmg_reload_ammo)
 125         {
 126                 ammo_amount += actor.(weaponentity).(weapon_load[WEP_OVERKILL_HMG.m_id]) >= WEP_CVAR_SEC(okhmg, ammo);
 127         }
 128         return ammo_amount;
 129 }
 130
 131 METHOD(OverkillHeavyMachineGun, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 132 {
 133     W_Reload(actor, weaponentity, WEP_CVAR_PRI(okhmg, ammo), SND_RELOAD);
 134 }
 135
 136 METHOD(OverkillHeavyMachineGun, wr_suicidemessage, Notification(entity thiswep))
 137 {
 138     return WEAPON_THINKING_WITH_PORTALS;
 139 }
 140
 141 METHOD(OverkillHeavyMachineGun, wr_killmessage, Notification(entity thiswep))
 142 {
 143     if(w_deathtype & HITTYPE_SECONDARY)
 144         return WEAPON_OVERKILL_HMG_MURDER_SNIPE;
 145     else
 146         return WEAPON_OVERKILL_HMG_MURDER_SPRAY;
 147 }
 148
 149 #endif
 150 #ifdef CSQC
 151
 152 METHOD(OverkillHeavyMachineGun, wr_impacteffect, void(entity thiswep, entity actor))
 153 {
 154     vector org2;
 155     org2 = w_org + w_backoff * 2;
 156     pointparticles(EFFECT_MACHINEGUN_IMPACT, org2, w_backoff * 1000, 1);
 157     if(!w_issilent)
 158         sound(actor, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_NORM);
 159 }
 160
 161 #endif