qcsrc/common/items/inventory.qh

   1 #pragma once
   2
   3 #include "all.qh"
   4
   5 #ifdef GAMEQC
   6 CLASS(Inventory, Object)
   7     /** Stores counts of items, the id being the index */
   8     ATTRIBARRAY(Inventory, inv_items, int, REGISTRY_MAX(Items));
   9     /** Previous state */
  10     ATTRIB(Inventory, inventory, Inventory);
  11 ENDCLASS(Inventory)
  12
  13 /** Player inventory */
  14 .Inventory inventory;
  15
  16 REGISTER_NET_LINKED(ENT_CLIENT_INVENTORY)
  17
  18 const int Inventory_groups_minor = 8; // must be a multiple of 8 (one byte) to optimize bandwidth usage
  19 const int Inventory_groups_major = 4; // must be >= ceil(REGISTRY_COUNT(Items) / Inventory_groups_minor)
  20 #endif
  21
  22 // no need to perform these checks on both server and client
  23 #ifdef CSQC
  24 STATIC_INIT(Inventory)
  25 {
  26         if (Inventory_groups_minor / 8 != floor(Inventory_groups_minor / 8))
  27                 error("Inventory_groups_minor is not a multiple of 8.");
  28         int min_major_value = ceil(REGISTRY_COUNT(Items) / Inventory_groups_minor);
  29         if (Inventory_groups_major < min_major_value)
  30                 error(sprintf("Inventory_groups_major can not be < %d.", min_major_value));
  31 }
  32 #endif
  33
  34 #ifdef SVQC
  35 #define G_MAJOR(id) (floor((id) / Inventory_groups_minor))
  36 #define G_MINOR(id) ((id) % Inventory_groups_minor)
  37 #endif
  38
  39 #ifdef CSQC
  40 Inventory g_inventory;
  41 NET_HANDLE(ENT_CLIENT_INVENTORY, bool isnew)
  42 {
  43     make_pure(this);
  44     g_inventory = this;
  45     const int majorBits = Readbits(Inventory_groups_major);
  46     for (int i = 0; i < Inventory_groups_major; ++i) {
  47         if (!(majorBits & BIT(i))) {
  48             continue;
  49         }
  50         const int minorBits = Readbits(Inventory_groups_minor);
  51         for (int j = 0; j < Inventory_groups_minor; ++j) {
  52             if (!(minorBits & BIT(j))) {
  53                 continue;
  54             }
  55             const GameItem it = REGISTRY_GET(Items, Inventory_groups_minor * i + j);
  56             .int fld = inv_items[it.m_id];
  57             int prev = this.(fld);
  58             int next = this.(fld) = ReadByte();
  59             LOG_DEBUGF("%s: %.0f -> %.0f", it.m_name, prev, next);
  60         }
  61     }
  62     return true;
  63 }
  64 #endif
  65
  66 #ifdef SVQC
  67 int minorBitsArr[Inventory_groups_major];
  68 void Inventory_Write(Inventory data)
  69 {
  70     if (!data) {
  71         WriteShort(MSG_ENTITY, 0);
  72         return;
  73     }
  74     TC(Inventory, data);
  75
  76         for (int i = 0; i < Inventory_groups_major; ++i)
  77                 minorBitsArr[i] = 0;
  78
  79     int majorBits = 0;
  80     FOREACH(Items, true, {
  81         .int fld = inv_items[it.m_id];
  82         const bool changed = data.inventory.(fld) != data.(fld);
  83         if (changed) {
  84                         int maj = G_MAJOR(it.m_id);
  85                         majorBits = BITSET(majorBits, BIT(maj), true);
  86                         minorBitsArr[maj] = BITSET(minorBitsArr[maj], BIT(G_MINOR(it.m_id)), true);
  87         }
  88     });
  89
  90         Writebits(MSG_ENTITY, majorBits, Inventory_groups_major);
  91         for (int i = 0; i < Inventory_groups_major; ++i)
  92         {
  93                 if (!(majorBits & BIT(i)))
  94                         continue;
  95
  96                 const int minorBits = minorBitsArr[i];
  97                 Writebits(MSG_ENTITY, minorBits, Inventory_groups_minor);
  98                 for (int j = 0; j < Inventory_groups_minor; ++j)
  99                 {
 100                         if (!(minorBits & BIT(j)))
 101                                 continue;
 102
 103                         const entity it = REGISTRY_GET(Items, Inventory_groups_minor * i + j);
 104                         WriteByte(MSG_ENTITY, data.inv_items[it.m_id]);
 105                 }
 106         }
 107 }
 108 #endif
 109
 110 #undef G_MAJOR
 111 #undef G_MINOR
 112
 113 #ifdef SVQC
 114 bool Inventory_Send(Inventory this, Client to, int sf)
 115 {
 116     TC(Inventory, this);
 117     WriteHeader(MSG_ENTITY, ENT_CLIENT_INVENTORY);
 118     TC(PlayerState, this.owner);
 119     Inventory_Write(this);
 120     return true;
 121 }
 122
 123 bool Inventory_customize(entity this, entity client)
 124 {
 125     // sends to spectators too!
 126     return (PS(client) && PS(client).inventory == this);
 127 }
 128
 129 void Inventory_new(PlayerState this)
 130 {
 131     Inventory inv = NEW(Inventory), bak = NEW(Inventory);
 132     inv.inventory = bak;
 133     setcefc(inv, Inventory_customize);
 134     Net_LinkEntity((inv.owner = this).inventory = inv, false, 0, Inventory_Send);
 135 }
 136 void Inventory_delete(entity e) { delete(e.inventory.inventory); delete(e.inventory); }
 137 void Inventory_update(entity e) { e.inventory.SendFlags = 0xFFFFFF; }
 138 #endif