qcsrc/client/hud/panel/strafehud.qc

   1 // Author: Juhu
   2
   3 #include "strafehud.qh"
   4
   5 #include <client/autocvars.qh>
   6 #include <client/draw.qh>
   7 #include <client/hud/panel/racetimer.qh>
   8 #include <client/resources.qh>
   9 #include <common/animdecide.qh>
  10 #include <common/ent_cs.qh>
  11 #include <common/mapinfo.qh>
  12 #include <common/physics/movetypes/movetypes.qh>
  13 #include <common/physics/player.qh>
  14 #include <lib/csqcmodel/cl_player.qh>
  15
  16 // StrafeHUD (#25)
  17
  18 void HUD_StrafeHUD_Export(int fh)
  19 {
  20     // allow saving cvars that aesthetically change the panel into hud skin files
  21 }
  22
  23 float hidden_width;
  24 int direction;
  25 float demo_angle = -37;
  26 float demo_direction = 1;
  27 float demo_time = 0;
  28 bool state_onground = false;
  29 float state_onground_time = 0;
  30 bool state_strafekeys = false;
  31 float state_strafekeys_time = 0;
  32 bool turn = false;
  33 float turnangle;
  34 float turnspeed;
  35 bool fwd = true;
  36 bool state_fwd = true;
  37 bool state_fwd_prev = true;
  38 float state_fwd_time = 0;
  39 float starttime = 0;
  40 float startspeed = -1;
  41 float jumptime = 0;
  42 float jumpheight = -1;
  43 float jumpheight_persistent = -1;
  44 float jumpheight_prev = 0;
  45 float jumpspeed_prev = 0;
  46 bool  jumprestart = true;
  47
  48 // provide basic panel cvars to old clients
  49 // TODO remove them after a future release (0.8.2+)
  50 noref string autocvar_hud_panel_strafehud_pos = "0.320000 0.570000";
  51 noref string autocvar_hud_panel_strafehud_size = "0.360000 0.020000";
  52 noref string autocvar_hud_panel_strafehud_bg = "0";
  53 noref string autocvar_hud_panel_strafehud_bg_color = "";
  54 noref string autocvar_hud_panel_strafehud_bg_color_team = "";
  55 noref string autocvar_hud_panel_strafehud_bg_alpha = "0.7";
  56 noref string autocvar_hud_panel_strafehud_bg_border = "";
  57 noref string autocvar_hud_panel_strafehud_bg_padding = "";
  58
  59 void HUD_StrafeHUD()
  60 {
  61     entity strafeplayer;
  62     bool islocal;
  63
  64     // generic hud routines
  65     if(!autocvar__hud_configure)
  66     {
  67         if(!autocvar_hud_panel_strafehud ||
  68            (spectatee_status == -1 && (autocvar_hud_panel_strafehud == 1 || autocvar_hud_panel_strafehud == 3)) ||
  69            (autocvar_hud_panel_strafehud == 3 && !MUTATOR_CALLHOOK(HUD_StrafeHUD_showoptional))) return;
  70     }
  71
  72     HUD_Panel_LoadCvars();
  73
  74     if(autocvar_hud_panel_strafehud_dynamichud)
  75     {
  76         HUD_Scale_Enable();
  77     }
  78     else
  79     {
  80         HUD_Scale_Disable();
  81     }
  82
  83     HUD_Panel_DrawBg();
  84
  85     if(panel_bg_padding)
  86     {
  87         panel_pos  += '1 1 0' * panel_bg_padding;
  88         panel_size -= '2 2 0' * panel_bg_padding;
  89     }
  90
  91     // find out whether the local csqcmodel entity is valid
  92     if(spectatee_status > 0 || isdemo())
  93     {
  94         islocal = false;
  95         strafeplayer = CSQCModel_server2csqc(player_localentnum - 1);
  96     }
  97     else
  98     {
  99         islocal = true;
 100         strafeplayer = csqcplayer;
 101     }
 102
 103     // draw strafehud
 104     if(csqcplayer && strafeplayer)
 105     {
 106         // physics
 107         bool   onground                      = islocal ? IS_ONGROUND(strafeplayer) : !(strafeplayer.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 108         bool   strafekeys;
 109         bool   swimming                      = strafeplayer.waterlevel >= WATERLEVEL_SWIMMING;
 110         bool   spectating                    = entcs_GetSpecState(strafeplayer.sv_entnum) == ENTCS_SPEC_PURE;
 111         float  speed                         = !autocvar__hud_configure ? vlen(vec2(csqcplayer.velocity)) : 1337; // use local csqcmodel entity for this even when spectating, flickers too much otherwise
 112         float  maxspeed_crouch_mod           = IS_DUCKED(strafeplayer) && !swimming ? .5 : 1;
 113         float  maxspeed_water_mod            = swimming ? .7 : 1; // very simplified water physics, the hud will not work well (and is not supposed to) while swimming
 114         float  maxspeed_phys                 = onground ? PHYS_MAXSPEED(strafeplayer) : PHYS_MAXAIRSPEED(strafeplayer);
 115         float  maxspeed                      = !autocvar__hud_configure ? maxspeed_phys * maxspeed_crouch_mod * maxspeed_water_mod : 320;
 116         float  vel_angle                     = vectoangles(strafeplayer.velocity).y - (vectoangles(strafeplayer.velocity).y > 180 ? 360 : 0); // change the range from 0° - 360° to -180° - 180° to match how view_angle represents angles
 117         float  view_angle                    = PHYS_INPUT_ANGLES(strafeplayer).y;
 118         float  angle;
 119         vector movement                      = PHYS_INPUT_MOVEVALUES(strafeplayer);
 120         int    keys                          = STAT(PRESSED_KEYS);
 121         int    keys_fwd;
 122         float  wishangle                     = 0;
 123
 124         // HUD
 125         int    mode                          = autocvar_hud_panel_strafehud_mode >= 0 && autocvar_hud_panel_strafehud_mode <= 1 ? autocvar_hud_panel_strafehud_mode : 0;
 126         float  speed_conversion_factor       = GetSpeedUnitFactor(autocvar_hud_panel_strafehud_unit);
 127         float  length_conversion_factor      = GetLengthUnitFactor(autocvar_hud_panel_strafehud_unit);
 128         string speed_unit                    = GetSpeedUnit(autocvar_hud_panel_strafehud_unit);
 129         string length_unit                   = GetLengthUnit(autocvar_hud_panel_strafehud_unit);
 130         int    length_decimals               = autocvar_hud_panel_strafehud_unit >= 3 && autocvar_hud_panel_strafehud_unit <= 5 ? 6 : 2; // use more decimals when displaying km or miles
 131         float  antiflicker_angle             = bound(0, autocvar_hud_panel_strafehud_antiflicker_angle, 180);
 132         float  antiflicker_speed             = max(0, autocvar_hud_panel_strafehud_antiflicker_speed);
 133         float  minspeed;
 134         float  shift_offset                  = 0;
 135         bool   straight_overturn             = false;
 136         bool   immobile                      = speed <= (swimming ? antiflicker_speed : 0);
 137         float  hudangle;
 138         float  neutral_offset;
 139         float  neutral_width;
 140         vector currentangle_color            = autocvar_hud_panel_strafehud_angle_neutral_color;
 141         float  currentangle_offset;
 142         vector currentangle_size             = '0 0 0';
 143         float  bestangle;
 144         float  odd_bestangle;
 145         bool   bestangle_anywhere            = false;
 146         float  bestangle_offset;
 147         float  switch_bestangle_offset;
 148         bool   odd_angles                    = false;
 149         float  odd_bestangle_offset          = 0;
 150         float  switch_odd_bestangle_offset   = 0;
 151         float  bestangle_width;
 152         float  accelzone_left_offset;
 153         float  accelzone_right_offset;
 154         float  accelzone_width;
 155         float  overturn_offset;
 156         float  overturn_width;
 157         float  slickdetector_height;
 158         vector direction_size_vertical       = '0 0 0';
 159         vector direction_size_horizontal     = '0 0 0';
 160         float  range_minangle;
 161
 162         // determine whether the player is pressing forwards or backwards keys
 163         if(islocal) // if entity is local player
 164         {
 165             if(movement.x > 0)
 166             {
 167                 keys_fwd = 1;
 168             }
 169             else if(movement.x < 0)
 170             {
 171                 keys_fwd = -1;
 172             }
 173             else
 174             {
 175                 keys_fwd = 0;
 176             }
 177         }
 178         else // alternatively determine direction by querying pressed keys
 179         {
 180             if((keys & KEY_FORWARD) && !(keys & KEY_BACKWARD))
 181             {
 182                 keys_fwd = 1;
 183             }
 184             else if(!(keys & KEY_FORWARD) && (keys & KEY_BACKWARD))
 185             {
 186                 keys_fwd = -1;
 187             }
 188             else
 189             {
 190                 keys_fwd = 0;
 191             }
 192         }
 193
 194         // determine player wishdir
 195         if(islocal) // if entity is local player
 196         {
 197             if(movement.x == 0)
 198             {
 199                 if(movement.y < 0)
 200                 {
 201                     wishangle = -90;
 202                 }
 203                 else if(movement.y > 0)
 204                 {
 205                     wishangle = 90;
 206                 }
 207                 else
 208                 {
 209                     wishangle = 0;
 210                 }
 211             }
 212             else
 213             {
 214                 if(movement.y == 0)
 215                 {
 216                     wishangle = 0;
 217                 }
 218                 else
 219                 {
 220                     wishangle = RAD2DEG * atan2(movement.y, movement.x);
 221                     // wrap the wish angle if it exceeds ±90°
 222                     if(fabs(wishangle) > 90)
 223                     {
 224                         if(wishangle < 0) wishangle += 180;
 225                         else wishangle -= 180;
 226                         wishangle = -wishangle;
 227                     }
 228                 }
 229             }
 230         }
 231         else // alternatively calculate wishdir by querying pressed keys
 232         {
 233             if(keys & KEY_FORWARD || keys & KEY_BACKWARD)
 234             {
 235                 wishangle = 45;
 236             }
 237             else
 238             {
 239                 wishangle = 90;
 240             }
 241             if(keys & KEY_LEFT)
 242             {
 243                 wishangle *= -1;
 244             }
 245             else if(!(keys & KEY_RIGHT))
 246             {
 247                 wishangle = 0; // wraps at 180°
 248             }
 249         }
 250
 251         strafekeys = fabs(wishangle) > 45;
 252
 253         // determine minimum required angle to display full strafe range
 254         range_minangle = fabs(wishangle) % 90; // maximum range is 90 degree
 255         if(range_minangle > 45) // minimum angle range is 45
 256         {
 257             range_minangle = 45 - fabs(wishangle) % 45;
 258         }
 259         range_minangle = 90 - range_minangle; // calculate value which is never >90 or <45
 260         range_minangle *= 2; // multiply to accommodate for both sides of the hud
 261
 262         if(autocvar_hud_panel_strafehud_range == 0)
 263         {
 264             if(autocvar__hud_configure)
 265             {
 266                 hudangle = 90;
 267             }
 268             else
 269             {
 270                 hudangle = range_minangle; // use minimum angle required if dynamically setting hud angle
 271             }
 272         }
 273         else
 274         {
 275             hudangle = bound(0, fabs(autocvar_hud_panel_strafehud_range), 360); // limit HUD range to 360 degrees, higher values don't make sense
 276         }
 277
 278         // detect air strafe turning
 279         if(onground != state_onground)
 280         {
 281             state_onground_time = time;
 282         }
 283         state_onground = onground;
 284
 285         if(strafekeys != state_strafekeys)
 286         {
 287             state_strafekeys_time = time;
 288         }
 289         state_strafekeys = strafekeys;
 290
 291         if((!strafekeys && vlen(vec2(movement)) > 0) || swimming || autocvar__hud_configure)
 292         {
 293             turn = false;
 294         }
 295         else if(onground)
 296         {
 297             if((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_ground) // timeout for strafe jumping in general
 298             {
 299                 turn = false;
 300             }
 301         }
 302         else // air strafe only
 303         {
 304             if(strafekeys)
 305             {
 306                 if(((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_air) || (keys & KEY_JUMP)) // timeout for slick ramps
 307                 {
 308                     turn = true; // CPMA turning
 309                     turnangle = wishangle;
 310
 311                     // calculate the maximum air strafe speed
 312                     if(PHYS_MAXAIRSPEED(strafeplayer) == 0){
 313                         maxspeed = turnspeed = 0;
 314                     }
 315                     else if(PHYS_MAXAIRSTRAFESPEED(strafeplayer) == 0 || PHYS_MAXAIRSPEED(strafeplayer) <= PHYS_MAXAIRSTRAFESPEED(strafeplayer)){
 316                         maxspeed = turnspeed = PHYS_MAXAIRSPEED(strafeplayer);
 317                     }
 318                     else{
 319                         maxspeed = turnspeed = PHYS_MAXAIRSPEED(strafeplayer) * pow(fabs(PHYS_MAXAIRSTRAFESPEED(strafeplayer) / PHYS_MAXAIRSPEED(strafeplayer)), 1 - (90 - fabs(wishangle)) / 45); // no modifiers here because they don't affect air strafing
 320                     }
 321                 }
 322             }
 323             else if((time - state_strafekeys_time) >= autocvar_hud_panel_strafehud_timeout_turn) // timeout for jumping with strafe keys only
 324             {
 325                 turn = false;
 326             }
 327         }
 328         if(turn && (onground || !strafekeys)) // retain last state until strafe turning times out
 329         {
 330             wishangle = turnangle;
 331             maxspeed = turnspeed;
 332         }
 333
 334         minspeed = autocvar_hud_panel_strafehud_switch_minspeed < 0 ? maxspeed + antiflicker_speed : autocvar_hud_panel_strafehud_switch_minspeed;
 335
 336         // get current strafing angle ranging from -180° to +180°
 337         if(!autocvar__hud_configure)
 338         {
 339             if(speed > 0)
 340             {
 341                 // calculate view angle relative to the players current velocity direction
 342                 angle = vel_angle - view_angle;
 343
 344                 // if the angle goes above 180° or below -180° wrap it to the opposite side since we want the interior angle
 345                 if (angle > 180) angle -= 360;
 346                 else if(angle < -180) angle += 360;
 347
 348                 // determine whether the player is strafing forwards or backwards
 349                 // if the player isn't strafe turning use forwards/backwards keys to determine direction
 350                 if(fabs(wishangle) != 90)
 351                 {
 352                     if(keys_fwd > 0)
 353                     {
 354                         state_fwd = true;
 355                     }
 356                     else if(keys_fwd < 0)
 357                     {
 358                         state_fwd = false;
 359                     }
 360                     else
 361                     {
 362                         state_fwd = fabs(angle) <= 90;
 363                     }
 364                 }
 365                 // otherwise determine by examining the strafe angle
 366                 else
 367                 {
 368                     if(wishangle < 0) // detect direction using wishangle since the direction is not yet set
 369                     {
 370                         state_fwd = angle <= -wishangle;
 371                     }
 372                     else
 373                     {
 374                         state_fwd = angle >= -wishangle;
 375                     }
 376                 }
 377
 378                 if(state_fwd_prev != state_fwd)
 379                 {
 380                     state_fwd_time = time;
 381                 }
 382                 state_fwd_prev = state_fwd;
 383
 384                 if((time - state_fwd_time) >= autocvar_hud_panel_strafehud_timeout_direction || speed < maxspeed || ((fabs(wishangle) == 90) && mode == 0)) // timeout when changing between forwards and backwards movement
 385                 {
 386                     fwd = state_fwd;
 387                 }
 388
 389                 // shift the strafe angle by 180° when strafing backwards
 390                 if(!fwd)
 391                 {
 392                     if(angle < 0) angle += 180;
 393                     else angle -= 180;
 394                 }
 395
 396                 // don't make the angle indicator switch side too much at ±180° if anti flicker is turned on
 397                 if(angle > (180 - antiflicker_angle) || angle < (-180 + antiflicker_angle))
 398                 {
 399                     straight_overturn = true;
 400                 }
 401             }
 402             else
 403             {
 404                 angle = 0;
 405             }
 406         }
 407         else // simulate turning for HUD setup
 408         {
 409             fwd = true;
 410             if(autocvar__hud_panel_strafehud_demo && ((time - demo_time) >= .025))
 411             {
 412                 demo_time = time;
 413                 demo_angle += demo_direction;
 414                 if(fabs(demo_angle) >= 55)
 415                 {
 416                     demo_direction = -demo_direction;
 417                 }
 418             }
 419             angle = demo_angle;
 420             wishangle = 45 * (demo_angle > 0 ? 1 : -1);
 421         }
 422
 423         // invert the wish angle when strafing backwards
 424         if(!fwd)
 425         {
 426             wishangle = -wishangle;
 427         }
 428
 429         // flip angles if v_flipped is enabled
 430         if(autocvar_v_flipped)
 431         {
 432             angle = -angle;
 433             wishangle = -wishangle;
 434         }
 435
 436         // determine whether the player is strafing left or right
 437         if(wishangle != 0)
 438         {
 439             direction = wishangle > 0 ? 1 : -1;
 440         }
 441         else
 442         {
 443             direction = (angle > antiflicker_angle && angle < (180 - antiflicker_angle)) ? 1 : (angle < -antiflicker_angle && angle > (-180 + antiflicker_angle)) ? -1 : 0;
 444         }
 445
 446         // best angle to strafe at
 447         bestangle = (speed > maxspeed ? acos(maxspeed / speed) : 0) * RAD2DEG * (direction < 0 ? -1 : 1);
 448         odd_bestangle = -bestangle - wishangle;
 449         bestangle -= wishangle;
 450
 451         // various offsets and size calculations of hud indicator elements
 452         // how much is hidden by the current hud angle
 453         hidden_width = (360 - hudangle) / hudangle * panel_size.x;
 454         // current angle
 455         currentangle_size.x = max(panel_size.x * autocvar_hud_panel_strafehud_angle_width, 1);
 456         if(mode == 0)
 457         {
 458             currentangle_offset = angle/hudangle * panel_size.x;
 459         }
 460         else
 461         {
 462             currentangle_offset = bound(-hudangle/2, angle, hudangle/2)/hudangle * panel_size.x + panel_size.x/2;
 463         }
 464         currentangle_size.y = max(panel_size.y * min(autocvar_hud_panel_strafehud_angle_height, 2), 1);
 465         // best strafe acceleration angle
 466         bestangle_offset        =  bestangle/hudangle * panel_size.x + panel_size.x/2;
 467         switch_bestangle_offset = -bestangle/hudangle * panel_size.x + panel_size.x/2;
 468         bestangle_width = max(panel_size.x * autocvar_hud_panel_strafehud_switch_width, 1);
 469
 470         if(((angle > -wishangle && direction < 0) || (angle < -wishangle && direction > 0)) && (direction != 0))
 471         {
 472             odd_angles = true;
 473             odd_bestangle_offset = odd_bestangle/hudangle * panel_size.x + panel_size.x/2;
 474             switch_odd_bestangle_offset = (odd_bestangle+bestangle*2)/hudangle * panel_size.x + panel_size.x/2;
 475         }
 476         // direction indicator
 477         direction_size_vertical.x = max(panel_size.y * min(autocvar_hud_panel_strafehud_direction_width, .5), 1);
 478         direction_size_vertical.y = panel_size.y;
 479         direction_size_horizontal.x = max(panel_size.x * min(autocvar_hud_panel_strafehud_direction_length, .5), direction_size_vertical.x);
 480         direction_size_horizontal.y = direction_size_vertical.x;
 481         // overturn
 482         overturn_width = 180/hudangle * panel_size.x;
 483
 484         // the neutral zone fills the whole strafe bar
 485         if(immobile)
 486         {
 487             // draw neutral zone
 488             if(panel_size.x > 0 && panel_size.y > 0 && autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha > 0)
 489             {
 490                 switch(autocvar_hud_panel_strafehud_style)
 491                 {
 492                     default:
 493                     case 0:
 494                         drawfill(panel_pos, panel_size, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 495                         break;
 496
 497                     case 1:
 498                         HUD_Panel_DrawProgressBar(panel_pos, panel_size, "progressbar", 1, 0, 0, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 499                 }
 500             }
 501         }
 502         else
 503         {
 504             // calculate various zones of the strafe-o-meter
 505             accelzone_width = overturn_offset = (90 - fabs(bestangle + wishangle))/hudangle * panel_size.x;
 506             accelzone_right_offset = 0;
 507             accelzone_left_offset = overturn_offset + overturn_width;
 508             neutral_width = 360/hudangle * panel_size.x - accelzone_width*2 - overturn_width;
 509             neutral_offset = direction < 0 ? accelzone_left_offset + accelzone_width : -neutral_width;
 510
 511             // remove switch indicator width from offset
 512             if(direction < 0)
 513             {
 514                 bestangle_offset -= bestangle_width;
 515                 switch_odd_bestangle_offset -= bestangle_width;
 516             }
 517             else
 518             {
 519                 switch_bestangle_offset -= bestangle_width;
 520                 odd_bestangle_offset -= bestangle_width;
 521             }
 522
 523             // shift hud if operating in view angle centered mode
 524             if(mode == 0)
 525             {
 526                 shift_offset = -currentangle_offset;
 527                 bestangle_offset += shift_offset;
 528                 switch_bestangle_offset += shift_offset;
 529                 odd_bestangle_offset += shift_offset;
 530                 switch_odd_bestangle_offset += shift_offset;
 531             }
 532             if(direction < 0) shift_offset += -360/hudangle * panel_size.x;
 533             // calculate how far off-center the strafe zones currently are
 534             shift_offset += (panel_size.x + neutral_width)/2 - wishangle/hudangle * panel_size.x;
 535             // shift strafe zones into correct place
 536             neutral_offset += shift_offset;
 537             accelzone_left_offset += shift_offset;
 538             accelzone_right_offset += shift_offset;
 539             overturn_offset += shift_offset;
 540
 541             // draw left acceleration zone
 542             HUD_Panel_DrawStrafeHUD(accelzone_left_offset, accelzone_width, autocvar_hud_panel_strafehud_bar_accel_color, autocvar_hud_panel_strafehud_bar_accel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 1);
 543
 544             // draw right acceleration zone
 545             HUD_Panel_DrawStrafeHUD(accelzone_right_offset, accelzone_width, autocvar_hud_panel_strafehud_bar_accel_color, autocvar_hud_panel_strafehud_bar_accel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 2);
 546
 547             // draw overturn zone
 548             HUD_Panel_DrawStrafeHUD(overturn_offset, overturn_width, autocvar_hud_panel_strafehud_bar_overturn_color, autocvar_hud_panel_strafehud_bar_overturn_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 3);
 549
 550             // draw neutral zone
 551             HUD_Panel_DrawStrafeHUD(neutral_offset, neutral_width, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 0);
 552
 553             if(direction != 0 && direction_size_vertical.x > 0 && autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha > 0)
 554             {
 555                 bool indicator_direction = direction < 0;
 556                 // invert left/right when strafing backwards or when strafing towards the opposite side indicated by the direction variable
 557                 // if both conditions are true then it's inverted twice hence not inverted at all
 558                 if(!fwd != odd_angles)
 559                 {
 560                     indicator_direction = !indicator_direction;
 561                 }
 562                 // draw the direction indicator caps at the sides of the hud
 563                 // vertical line
 564                 if(direction_size_vertical.y > 0) drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x), direction_size_vertical, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 565                 // top horizontal line
 566                 drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x - direction_size_horizontal.x + direction_size_vertical.x) - eY * direction_size_horizontal.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 567                 // bottom horizontal line
 568                 drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x - direction_size_horizontal.x + direction_size_vertical.x) + eY * panel_size.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 569             }
 570
 571             if(speed >= minspeed) // only draw indicators if minspeed is reached
 572             {
 573                 // draw best angles for acceleration
 574                 float offset = !odd_angles ? bestangle_offset : odd_bestangle_offset;
 575                 float switch_offset = !odd_angles ? switch_bestangle_offset : switch_odd_bestangle_offset;
 576                 // both indicators are inactive if no direction can be determined
 577                 vector switch_color = direction != 0 ? autocvar_hud_panel_strafehud_switch_active_color : autocvar_hud_panel_strafehud_switch_inactive_color;
 578                 float switch_alpha = direction != 0 ? autocvar_hud_panel_strafehud_switch_active_alpha : autocvar_hud_panel_strafehud_switch_inactive_alpha;
 579                 // draw the switch indicators
 580                 HUD_Panel_DrawStrafeHUD(switch_offset, bestangle_width, autocvar_hud_panel_strafehud_switch_inactive_color, autocvar_hud_panel_strafehud_switch_inactive_alpha * panel_fg_alpha, 0, 0);
 581                 HUD_Panel_DrawStrafeHUD(offset, bestangle_width, switch_color, switch_alpha * panel_fg_alpha, 0, 0);
 582             }
 583         }
 584
 585         // experimental: slick detector
 586         slickdetector_height = panel_size.y * bound(0, autocvar_hud_panel_strafehud_slickdetector_height, 0.5);
 587         if(autocvar_hud_panel_strafehud_slickdetector_range > 0 && autocvar_hud_panel_strafehud_slickdetector_alpha > 0 && slickdetector_height > 0 && panel_size.x > 0) // dunno if slick detection works in spectate
 588         {
 589             float slicksteps = 90 / pow(2, bound(0, autocvar_hud_panel_strafehud_slickdetector_granularity, 4));
 590             bool slickdetected = false;
 591
 592             slickdetected = IS_ONSLICK(strafeplayer); // don't need to traceline if already touching slick
 593
 594             // traceline into every direction
 595             trace_dphitq3surfaceflags = 0;
 596             for(float i = 0; i < 360 && !slickdetected; i += slicksteps)
 597             {
 598                 vector slickoffset;
 599                 float slickrotate;
 600                 slickoffset.z = -cos(i * DEG2RAD) * autocvar_hud_panel_strafehud_slickdetector_range;
 601                 slickrotate = sin(i * DEG2RAD) * autocvar_hud_panel_strafehud_slickdetector_range;
 602                 if(i != 0 && i != 180)
 603                 {
 604                     for(float j = 0; j < 180 && !slickdetected; j += slicksteps)
 605                     {
 606                         slickoffset.x = sin(j * DEG2RAD) * slickrotate;
 607                         slickoffset.y = cos(j * DEG2RAD) * slickrotate;
 608
 609                         traceline(strafeplayer.origin, strafeplayer.origin + slickoffset, MOVE_WORLDONLY, NULL);
 610                         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK) slickdetected = true;
 611                     }
 612                 }
 613                 else
 614                 {
 615                     slickoffset.x = slickoffset.y = 0;
 616                     traceline(strafeplayer.origin, strafeplayer.origin + slickoffset, MOVE_WORLDONLY, NULL);
 617                     if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK) slickdetected = true;
 618                 }
 619             }
 620
 621             // if a traceline hit a slick surface
 622             if(slickdetected)
 623             {
 624                 vector slickdetector_size = panel_size;
 625                 slickdetector_size.y = slickdetector_height;
 626                 // top horizontal line
 627                 drawfill(panel_pos - eY * slickdetector_size.y, slickdetector_size, autocvar_hud_panel_strafehud_slickdetector_color, autocvar_hud_panel_strafehud_slickdetector_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 628                 // bottom horizontal line
 629                 drawfill(panel_pos + eY * panel_size.y, slickdetector_size, autocvar_hud_panel_strafehud_slickdetector_color, autocvar_hud_panel_strafehud_slickdetector_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 630             }
 631         }
 632
 633         draw_beginBoldFont();
 634         // show speed when crossing the start trigger
 635         if(autocvar_hud_panel_strafehud_startspeed_fade > 0)
 636         {
 637             float text_alpha = 0;
 638             if((race_nextcheckpoint == 1) || (race_checkpoint == 254 && race_nextcheckpoint == 255)) // check if the start trigger was hit (will also trigger if the finish trigger was hit if those have the same ID)
 639             {
 640                 if(starttime != race_checkpointtime)
 641                 {
 642                     starttime = race_checkpointtime;
 643                     startspeed = speed;
 644                 }
 645             }
 646             if(startspeed >= 0)
 647             {
 648                 text_alpha = cos(((time - starttime) / autocvar_hud_panel_strafehud_startspeed_fade) * 90 * DEG2RAD); // fade non-linear like the physics panel does
 649                 if((time - starttime) > autocvar_hud_panel_strafehud_startspeed_fade)
 650                 {
 651                     startspeed = -1;
 652                 }
 653             }
 654             if(startspeed >= 0 && text_alpha > 0 && autocvar_hud_panel_strafehud_startspeed_size > 0)
 655             {
 656                 vector startspeed_size = panel_size;
 657                 startspeed_size.y = panel_size.y * min(autocvar_hud_panel_strafehud_startspeed_size, 5);
 658                 drawstring_aspect(panel_pos + eY * panel_size.y, strcat(ftos_decimals(startspeed * speed_conversion_factor, 2), autocvar_hud_panel_strafehud_unit_show ? speed_unit : ""), startspeed_size, autocvar_hud_panel_strafehud_startspeed_color, text_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 659             }
 660         }
 661         else
 662         {
 663             starttime = 0;
 664             startspeed = -1;
 665         }
 666
 667         // experimental: show height achieved by a single jump (doesn't work in low gravity and may not be 100% accurate)
 668         if(autocvar_hud_panel_strafehud_jumpheight_fade > 0)
 669         {
 670             float text_alpha = 0;
 671             float jumpheight_min = max(autocvar_hud_panel_strafehud_jumpheight_min, 0);
 672             float jumpheight_current = strafeplayer.origin.z;
 673             float jumpspeed_current = strafeplayer.velocity.z;
 674             if(jumpspeed_prev <= jumpspeed_current || jumpheight_prev > jumpheight_current || IS_ONGROUND(strafeplayer) || swimming || IS_DEAD(strafeplayer) || spectating)
 675             {
 676                 // tries to catch kill and spectate but those are not reliable, should just hook to kill/spectate/teleport and reset jump height there
 677                 jumprestart = true;
 678             }
 679             else
 680             {
 681                 if(jumpheight < 0 || jumprestart)
 682                 {
 683                     jumprestart = false;
 684                     jumpheight = 0;
 685                 }
 686                 else
 687                 {
 688                     jumpheight += jumpheight_current - jumpheight_prev;
 689                 }
 690                 if((jumpheight * length_conversion_factor) > jumpheight_min && jumpheight > jumpheight_persistent)
 691                 {
 692                     jumptime = time;
 693                     jumpheight_persistent = jumpheight;
 694                 }
 695             }
 696             jumpheight_prev = jumpheight_current;
 697             jumpspeed_prev = jumpspeed_current;
 698             if(jumpheight_persistent > 0)
 699             {
 700                 text_alpha = cos(((time - jumptime) / autocvar_hud_panel_strafehud_jumpheight_fade) * 90 * DEG2RAD); // fade non-linear like the physics panel does
 701                 if((time - jumptime) > autocvar_hud_panel_strafehud_jumpheight_fade)
 702                 {
 703                     jumpheight_persistent = -1;
 704                 }
 705             }
 706             if(jumpheight_persistent > 0 && text_alpha > 0 && autocvar_hud_panel_strafehud_jumpheight_size > 0)
 707             {
 708                 vector jumpheight_size = panel_size;
 709                 jumpheight_size.y = panel_size.y * min(autocvar_hud_panel_strafehud_jumpheight_size, 5);
 710                 drawstring_aspect(panel_pos - eY * jumpheight_size.y, strcat(ftos_decimals(jumpheight_persistent * length_conversion_factor, length_decimals), autocvar_hud_panel_strafehud_unit_show ? length_unit : ""), jumpheight_size, autocvar_hud_panel_strafehud_jumpheight_color, text_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 711             }
 712         }
 713         else
 714         {
 715             jumpheight_prev = jumpspeed_prev = 0;
 716             jumpheight = jumpheight_persistent = -1;
 717         }
 718         draw_endBoldFont();
 719
 720         if(speed < (maxspeed + antiflicker_speed) && !immobile)
 721         {
 722             bestangle_anywhere = true; // moving forward should suffice to gain speed
 723         }
 724
 725         // draw the actual strafe angle
 726         if(!bestangle_anywhere && !immobile) // player gains speed with strafing
 727         {
 728             if((direction > 0 && (angle >= bestangle || angle <= -(bestangle + wishangle*2))) ||
 729                (direction < 0 && (angle <= bestangle || angle >= -(bestangle + wishangle*2))))
 730             currentangle_color = autocvar_hud_panel_strafehud_angle_accel_color;
 731         }
 732
 733         if(fabs(angle + wishangle) > 90) // player is overturning
 734         {
 735             currentangle_color = autocvar_hud_panel_strafehud_angle_overturn_color;
 736         }
 737         else if(bestangle_anywhere) // player gains speed without strafing
 738         {
 739             currentangle_color = autocvar_hud_panel_strafehud_angle_accel_color;
 740         }
 741
 742         if(mode == 0 || straight_overturn)
 743         {
 744             currentangle_offset = panel_size.x/2;
 745         }
 746
 747         if(autocvar_hud_panel_strafehud_style == 2 && !immobile)
 748         {
 749             float moveangle = angle + wishangle;
 750             float strafeangle = (bestangle + wishangle) * (direction < 0 ? -1 : 1);
 751             float strafe_ratio = 0;
 752             if(fabs(moveangle) > 90)
 753             {
 754                 strafe_ratio = -((fabs(moveangle) - 90) / 90);
 755                 if(strafe_ratio < -1) strafe_ratio = -2 - strafe_ratio;
 756             }
 757             else
 758             {
 759                 if(moveangle >= strafeangle)
 760                 {
 761                     strafe_ratio = 1 - (moveangle - strafeangle) / (90 - strafeangle);
 762                 }
 763                 else if(moveangle <= -strafeangle)
 764                 {
 765                     strafe_ratio = 1 - (moveangle + strafeangle) / (-90 + strafeangle);
 766                 }
 767             }
 768             if(strafe_ratio < 0)
 769             {
 770                 currentangle_color = StrafeHUD_mixColors(autocvar_hud_panel_strafehud_angle_neutral_color, autocvar_hud_panel_strafehud_angle_overturn_color, -strafe_ratio);
 771             }
 772             else
 773             {
 774                 currentangle_color = StrafeHUD_mixColors(autocvar_hud_panel_strafehud_angle_neutral_color, autocvar_hud_panel_strafehud_angle_accel_color, strafe_ratio);
 775             }
 776         }
 777
 778         if(currentangle_size.x > 0 && currentangle_size.y > 0 && autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha > 0)
 779         {
 780             drawfill(panel_pos - eY * ((currentangle_size.y - panel_size.y) / 2) + eX * (currentangle_offset - currentangle_size.x/2), currentangle_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 781         }
 782     }
 783 }
 784
 785 // functions to make hud elements align perfectly in the hud area
 786 void HUD_Panel_DrawStrafeHUD(float offset, float width, vector color, float alpha, int type, int gradientType)
 787 {
 788     float mirror_offset, mirror_width;
 789     vector size = panel_size;
 790     vector mirror_size = panel_size;
 791     int gradient_start;
 792     float gradient_offset, gradient_mirror_offset;
 793     float overflow_width = 0, overflow_mirror_width = 0;
 794
 795     float original_width = width;
 796
 797     if(alpha <= 0 && type != 2 || width <= 0) return;
 798
 799     if(type == 2 && gradientType == 0) type = 0;
 800
 801     if(offset < 0)
 802     {
 803         mirror_width = min(fabs(offset), width);
 804         mirror_offset = panel_size.x + hidden_width - fabs(offset);
 805         width += offset;
 806         offset = 0;
 807     }
 808     else
 809     {
 810         mirror_width = min(offset + width - panel_size.x - hidden_width, width);
 811         mirror_offset = max(offset - panel_size.x - hidden_width, 0);
 812     }
 813
 814     if(width < 0) width = 0;
 815     if((offset + width) > panel_size.x)
 816     {
 817         overflow_width = (offset + width) - panel_size.x;
 818         width = panel_size.x - offset;
 819     }
 820     if(mirror_offset < 0)
 821     {
 822         mirror_width += mirror_offset;
 823         mirror_offset = 0;
 824     }
 825
 826     if(mirror_width < 0) mirror_width = 0;
 827     if((mirror_offset + mirror_width) > panel_size.x)
 828     {
 829         overflow_mirror_width = (mirror_offset + mirror_width) - panel_size.x;
 830         mirror_width = panel_size.x - mirror_offset;
 831     }
 832
 833     if(direction < 0) // swap mirror and non-mirror values if direction points left
 834     {
 835         offset += mirror_offset;
 836         mirror_offset = offset - mirror_offset;
 837         offset -= mirror_offset;
 838
 839         width += mirror_width;
 840         mirror_width = width - mirror_width;
 841         width -= mirror_width;
 842
 843         overflow_width += overflow_mirror_width;
 844         overflow_mirror_width = overflow_width - overflow_mirror_width;
 845         overflow_width -= overflow_mirror_width;
 846     }
 847
 848     size.x = width;
 849     mirror_size.x = mirror_width;
 850
 851     switch(type)
 852     {
 853         default:
 854         case 0: // no styling (drawfill)
 855             if(mirror_size.x > 0 && mirror_size.y > 0) drawfill(panel_pos + eX * mirror_offset, mirror_size, color, alpha, DRAWFLAG_NORMAL);
 856             if(size.x > 0 && size.y > 0) drawfill(panel_pos + eX * offset, size, color, alpha, DRAWFLAG_NORMAL);
 857             break;
 858
 859         case 1: // progress bar style
 860             if(mirror_size.x > 0 && mirror_size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * mirror_offset, mirror_size, "progressbar", 1, 0, 0, color, alpha, DRAWFLAG_NORMAL);
 861             if(size.x > 0 && size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * offset, size, "progressbar", 1, 0, 0, color, alpha, DRAWFLAG_NORMAL);
 862             break;
 863
 864         case 2: // gradient style (types: 1 = left, 2 = right, 3 = both)
 865             // determine whether the gradient starts in the mirrored or the non-mirrored area
 866             if(offset == 0 && mirror_offset == 0) gradient_start = width > mirror_width ? 2 : 1;
 867             else if(offset == 0) gradient_start = 2;
 868             else if(mirror_offset == 0) gradient_start = 1;
 869             else gradient_start = 0;
 870
 871             switch(gradient_start){
 872                 default:
 873                 case 0: // no offset required
 874                     gradient_offset = gradient_mirror_offset = 0;
 875                     break;
 876                 case 1: // offset starts in non-mirrored area, mirrored area requires offset
 877                     gradient_offset = 0;
 878                     gradient_mirror_offset = original_width - (mirror_width + overflow_mirror_width);
 879                     break;
 880                 case 2: // offset starts in mirrored area, non-mirrored area requires offset
 881                     gradient_offset = original_width - (width + overflow_width);
 882                     gradient_mirror_offset = 0;
 883             }
 884
 885             StrafeHUD_drawGradient(color, autocvar_hud_panel_strafehud_bar_neutral_color, mirror_size, original_width, mirror_offset, alpha, gradient_mirror_offset, gradientType);
 886             StrafeHUD_drawGradient(color, autocvar_hud_panel_strafehud_bar_neutral_color, size, original_width, offset, alpha, gradient_offset, gradientType);
 887     }
 888 }
 889
 890 vector StrafeHUD_mixColors(vector color1, vector color2, float ratio)
 891 {
 892     vector mixedColor;
 893     if(ratio <= 0) return color1;
 894     if(ratio >= 1) return color2;
 895     mixedColor.x = color1.x + (color2.x - color1.x) * ratio;
 896     mixedColor.y = color1.y + (color2.y - color1.y) * ratio;
 897     mixedColor.z = color1.z + (color2.z - color1.z) * ratio;
 898     return mixedColor;
 899 }
 900
 901 void StrafeHUD_drawGradient(vector color1, vector color2, vector size, float original_width, float offset, float alpha, float gradientOffset, int gradientType)
 902 {
 903     float color_ratio, alpha1, alpha2;
 904     vector gradient_size = size;
 905     alpha1 = bound(0, alpha, 1);
 906     alpha2 = bound(0, autocvar_hud_panel_strafehud_bar_neutral_alpha, 1);
 907     if((alpha1+alpha2) == 0) return;
 908     color_ratio = alpha1/(alpha1+alpha2);
 909     for(int i = 0; i < size.x; ++i)
 910     {
 911         float ratio, alpha_ratio, combine_ratio1, combine_ratio2;
 912         gradient_size.x = size.x - i < 1 ? size.x - i : 1;
 913         ratio = (i + gradientOffset) / original_width * (gradientType == 3 ? 2 : 1);
 914         if(ratio > 1) ratio = 2 - ratio;
 915         if(gradientType != 2) ratio = 1 - ratio;
 916         alpha_ratio = alpha1 - (alpha1 - alpha2) * ratio;
 917         combine_ratio1 = ratio*(1-color_ratio);
 918         combine_ratio2 = (1-ratio)*color_ratio;
 919         ratio = (combine_ratio1 + combine_ratio2) == 0 ? 1 : combine_ratio1/(combine_ratio1 + combine_ratio2);
 920         if(alpha_ratio > 0) drawfill(panel_pos + eX * (offset + i), gradient_size, StrafeHUD_mixColors(color1, color2, ratio), alpha_ratio, DRAWFLAG_NORMAL);
 921     }
 922 }
 923
 924 // length unit conversion (km and miles are only included to match the GetSpeedUnit* functions)
 925 float GetLengthUnitFactor(int length_unit)
 926 {
 927         switch(length_unit)
 928         {
 929                 default:
 930                 case 1: return 1.0;
 931                 case 2: return 0.0254;
 932                 case 3: return 0.0254 * 0.001;
 933                 case 4: return 0.0254 * 0.001 * 0.6213711922;
 934                 case 5: return 0.0254 * 0.001 * 0.5399568035;
 935         }
 936 }
 937
 938 string GetLengthUnit(int length_unit)
 939 {
 940         switch(length_unit)
 941         {
 942                 // translator-friendly strings without the initial space
 943                 default:
 944                 case 1: return strcat(" ", _("qu"));
 945                 case 2: return strcat(" ", _("m"));
 946                 case 3: return strcat(" ", _("km"));
 947                 case 4: return strcat(" ", _("mi"));
 948                 case 5: return strcat(" ", _("nmi"));
 949         }
 950 }