qcsrc/client/hud/panel/strafehud.qc

   1 // Author: Juhu
   2
   3 #include "strafehud.qh"
   4
   5 #include <client/draw.qh>
   6 #include <client/hud/panel/racetimer.qh>
   7 #include <client/resources.qh>
   8 #include <client/view.qh>
   9 #include <common/animdecide.qh>
  10 #include <common/ent_cs.qh>
  11 #include <common/mapinfo.qh>
  12 #include <common/physics/movetypes/movetypes.qh>
  13 #include <common/physics/player.qh>
  14 #include <lib/csqcmodel/cl_player.qh>
  15
  16 // StrafeHUD (#25)
  17
  18 void HUD_StrafeHUD_Export(int fh)
  19 {
  20     // allow saving cvars that aesthetically change the panel into hud skin files
  21 }
  22
  23 float hidden_width;
  24 int direction;
  25 float demo_angle = -37;
  26 float demo_direction = 1;
  27 float demo_time = 0;
  28 bool state_onground = false;
  29 float state_onground_time = 0;
  30 bool state_strafekeys = false;
  31 float state_strafekeys_time = 0;
  32 bool turn = false;
  33 float turnangle;
  34 float turnspeed;
  35 float turnaccel;
  36 bool fwd = true;
  37 float starttime = 0;
  38 float startspeed = -1;
  39 float jumptime = 0;
  40 float jumpheight = -1;
  41 float jumpheight_persistent = -1;
  42 float jumpheight_prev = 0;
  43 float jumpspeed_prev = 0;
  44 bool  jumprestart = true;
  45
  46 // provide basic panel cvars to old clients
  47 // TODO remove them after a future release (0.8.2+)
  48 noref string autocvar_hud_panel_strafehud_pos = "0.320000 0.570000";
  49 noref string autocvar_hud_panel_strafehud_size = "0.360000 0.020000";
  50 noref string autocvar_hud_panel_strafehud_bg = "0";
  51 noref string autocvar_hud_panel_strafehud_bg_color = "";
  52 noref string autocvar_hud_panel_strafehud_bg_color_team = "";
  53 noref string autocvar_hud_panel_strafehud_bg_alpha = "0.7";
  54 noref string autocvar_hud_panel_strafehud_bg_border = "";
  55 noref string autocvar_hud_panel_strafehud_bg_padding = "";
  56
  57 void HUD_StrafeHUD()
  58 {
  59     entity strafeplayer;
  60     bool islocal;
  61
  62     // generic hud routines
  63     if(!autocvar__hud_configure)
  64     {
  65         if(!autocvar_hud_panel_strafehud ||
  66            (spectatee_status == -1 && (autocvar_hud_panel_strafehud == 1 || autocvar_hud_panel_strafehud == 3)) ||
  67            (autocvar_hud_panel_strafehud == 3 && !MUTATOR_CALLHOOK(HUD_StrafeHUD_showoptional))) return;
  68     }
  69
  70     HUD_Panel_LoadCvars();
  71
  72     if(autocvar_hud_panel_strafehud_dynamichud)
  73     {
  74         HUD_Scale_Enable();
  75     }
  76     else
  77     {
  78         HUD_Scale_Disable();
  79     }
  80
  81     HUD_Panel_DrawBg();
  82
  83     if(panel_bg_padding)
  84     {
  85         panel_pos  += '1 1 0' * panel_bg_padding;
  86         panel_size -= '2 2 0' * panel_bg_padding;
  87     }
  88
  89     // find out whether the local csqcmodel entity is valid
  90     if(spectatee_status > 0 || isdemo())
  91     {
  92         islocal = false;
  93         strafeplayer = CSQCModel_server2csqc(player_localentnum - 1);
  94     }
  95     else
  96     {
  97         islocal = true;
  98         strafeplayer = csqcplayer;
  99     }
 100
 101     // draw strafehud
 102     if(csqcplayer && strafeplayer)
 103     {
 104         // physics
 105         bool   onground                      = islocal ? IS_ONGROUND(strafeplayer) : !(strafeplayer.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 106         bool   strafekeys;
 107         bool   swimming                      = strafeplayer.waterlevel >= WATERLEVEL_SWIMMING;
 108         bool   spectating                    = entcs_GetSpecState(strafeplayer.sv_entnum) == ENTCS_SPEC_PURE;
 109         float  speed                         = !autocvar__hud_configure ? vlen(vec2(csqcplayer.velocity)) : 1337; // use local csqcmodel entity for this even when spectating, flickers too much otherwise
 110         float  crouch_mod                    = IS_DUCKED(csqcplayer) && !swimming ? .5 : 1;
 111         float  water_mod                     = swimming ? .7 : 1; // very simplified water physics, the hud will not work well (and is not supposed to) while swimming
 112         float  maxspeed_phys                 = onground ? PHYS_MAXSPEED(strafeplayer) : PHYS_MAXAIRSPEED(strafeplayer);
 113         float  maxspeed                      = !autocvar__hud_configure ? maxspeed_phys * crouch_mod * water_mod : 320;
 114         float  movespeed;
 115         float  maxaccel_phys                 = onground ? PHYS_ACCELERATE(strafeplayer) : PHYS_AIRACCELERATE(strafeplayer);
 116         float  maxaccel                      = !autocvar__hud_configure ? maxaccel_phys * crouch_mod * water_mod : 1;
 117         float  vel_angle                     = vectoangles(strafeplayer.velocity).y - (vectoangles(strafeplayer.velocity).y > 180 ? 360 : 0); // change the range from 0° - 360° to -180° - 180° to match how view_angle represents angles
 118         float  view_angle                    = PHYS_INPUT_ANGLES(strafeplayer).y;
 119         float  angle;
 120         vector movement                      = PHYS_INPUT_MOVEVALUES(strafeplayer);
 121         int    keys                          = STAT(PRESSED_KEYS);
 122         int    keys_fwd;
 123         float  wishangle                     = 0;
 124
 125         // HUD
 126         int    mode                          = autocvar_hud_panel_strafehud_mode >= 0 && autocvar_hud_panel_strafehud_mode <= 1 ? autocvar_hud_panel_strafehud_mode : 0;
 127         float  speed_conversion_factor       = GetSpeedUnitFactor(autocvar_hud_panel_strafehud_unit);
 128         float  length_conversion_factor      = GetLengthUnitFactor(autocvar_hud_panel_strafehud_unit);
 129         int    length_decimals               = autocvar_hud_panel_strafehud_unit >= 3 && autocvar_hud_panel_strafehud_unit <= 5 ? 6 : 2; // use more decimals when displaying km or miles
 130         float  antiflicker_angle             = bound(0, autocvar_hud_panel_strafehud_antiflicker_angle, 180);
 131         float  antiflicker_speed             = max(0, autocvar_hud_panel_strafehud_antiflicker_speed);
 132         float  minspeed;
 133         float  shift_offset                  = 0;
 134         bool   straight_overturn             = false;
 135         bool   immobile                      = speed <= (swimming ? antiflicker_speed : 0);
 136         float  hudangle;
 137         float  neutral_offset;
 138         float  neutral_width;
 139         vector currentangle_color            = autocvar_hud_panel_strafehud_angle_neutral_color;
 140         float  currentangle_offset;
 141         vector currentangle_size             = '0 0 0';
 142         float  bestangle;
 143         float  prebestangle;
 144         float  odd_bestangle;
 145         bool   bestangle_anywhere            = false;
 146         float  bestangle_offset;
 147         float  switch_bestangle_offset;
 148         bool   odd_angles                    = false;
 149         float  odd_bestangle_offset          = 0;
 150         float  switch_odd_bestangle_offset   = 0;
 151         float  bestangle_width;
 152         float  accelzone_left_offset;
 153         float  accelzone_right_offset;
 154         float  accelzone_width;
 155         float  preaccelzone_left_offset;
 156         float  preaccelzone_right_offset;
 157         float  preaccelzone_width;
 158         float  overturn_offset;
 159         float  overturn_width;
 160         float  slickdetector_height;
 161         vector direction_size_vertical       = '0 0 0';
 162         vector direction_size_horizontal     = '0 0 0';
 163         float  range_minangle;
 164         float  arrow_size = max(panel_size.y * min(autocvar_hud_panel_strafehud_angle_arrow_size, 10), 0); // there's only one size cvar for the arrows, they will always have a 45° angle to ensure proper rendering without antialiasing
 165
 166         if(!autocvar_hud_panel_strafehud_uncapped)
 167             arrow_size = max(arrow_size, 1);
 168
 169         // determine whether the player is pressing forwards or backwards keys
 170         if(islocal) // if entity is local player
 171         {
 172             if(movement.x > 0)
 173             {
 174                 keys_fwd = 1;
 175             }
 176             else if(movement.x < 0)
 177             {
 178                 keys_fwd = -1;
 179             }
 180             else
 181             {
 182                 keys_fwd = 0;
 183             }
 184         }
 185         else // alternatively determine direction by querying pressed keys
 186         {
 187             if((keys & KEY_FORWARD) && !(keys & KEY_BACKWARD))
 188             {
 189                 keys_fwd = 1;
 190             }
 191             else if(!(keys & KEY_FORWARD) && (keys & KEY_BACKWARD))
 192             {
 193                 keys_fwd = -1;
 194             }
 195             else
 196             {
 197                 keys_fwd = 0;
 198             }
 199         }
 200
 201         // determine player wishdir
 202         if(islocal) // if entity is local player
 203         {
 204             if(movement.x == 0)
 205             {
 206                 if(movement.y < 0)
 207                 {
 208                     wishangle = -90;
 209                 }
 210                 else if(movement.y > 0)
 211                 {
 212                     wishangle = 90;
 213                 }
 214                 else
 215                 {
 216                     wishangle = 0;
 217                 }
 218             }
 219             else
 220             {
 221                 if(movement.y == 0)
 222                 {
 223                     wishangle = 0;
 224                 }
 225                 else
 226                 {
 227                     wishangle = RAD2DEG * atan2(movement.y, movement.x);
 228                     // wrap the wish angle if it exceeds ±90°
 229                     if(fabs(wishangle) > 90)
 230                     {
 231                         if(wishangle < 0) wishangle += 180;
 232                         else wishangle -= 180;
 233                         wishangle = -wishangle;
 234                     }
 235                 }
 236             }
 237         }
 238         else // alternatively calculate wishdir by querying pressed keys
 239         {
 240             if(keys & KEY_FORWARD || keys & KEY_BACKWARD)
 241             {
 242                 wishangle = 45;
 243             }
 244             else
 245             {
 246                 wishangle = 90;
 247             }
 248             if(keys & KEY_LEFT)
 249             {
 250                 wishangle *= -1;
 251             }
 252             else if(!(keys & KEY_RIGHT))
 253             {
 254                 wishangle = 0; // wraps at 180°
 255             }
 256         }
 257
 258         strafekeys = fabs(wishangle) > 45;
 259
 260         // determine minimum required angle to display full strafe range
 261         range_minangle = fabs(wishangle) % 90; // maximum range is 90 degree
 262         if(range_minangle > 45) // minimum angle range is 45
 263         {
 264             range_minangle = 45 - fabs(wishangle) % 45;
 265         }
 266         range_minangle = 90 - range_minangle; // calculate value which is never >90 or <45
 267         range_minangle *= 2; // multiply to accommodate for both sides of the hud
 268
 269         if(autocvar_hud_panel_strafehud_range == 0)
 270         {
 271             if(autocvar__hud_configure)
 272             {
 273                 hudangle = 90;
 274             }
 275             else
 276             {
 277                 hudangle = range_minangle; // use minimum angle required if dynamically setting hud angle
 278             }
 279         }
 280         else
 281         {
 282             hudangle = bound(0, fabs(autocvar_hud_panel_strafehud_range), 360); // limit HUD range to 360 degrees, higher values don't make sense
 283         }
 284
 285         // detect air strafe turning
 286         if(onground != state_onground)
 287         {
 288             state_onground_time = time;
 289         }
 290         state_onground = onground;
 291
 292         if(strafekeys != state_strafekeys)
 293         {
 294             state_strafekeys_time = time;
 295         }
 296         state_strafekeys = strafekeys;
 297
 298         if((!strafekeys && vlen(vec2(movement)) > 0) || swimming || autocvar__hud_configure)
 299         {
 300             turn = false;
 301         }
 302         else if(onground)
 303         {
 304             if((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_ground) // timeout for strafe jumping in general
 305             {
 306                 turn = false;
 307             }
 308         }
 309         else // air strafe only
 310         {
 311             if(strafekeys)
 312             {
 313                 if(((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_air) || (keys & KEY_JUMP)) // timeout for slick ramps
 314                 {
 315                     turn = true; // CPMA turning
 316                     turnangle = wishangle;
 317
 318                     // calculate the maximum air strafe speed and acceleration
 319                     if(PHYS_MAXAIRSPEED(strafeplayer) == 0){
 320                         maxspeed = 0;
 321                     }
 322                     else if(PHYS_MAXAIRSTRAFESPEED(strafeplayer) == 0 || PHYS_MAXAIRSPEED(strafeplayer) <= PHYS_MAXAIRSTRAFESPEED(strafeplayer)){
 323                         maxspeed = PHYS_MAXAIRSPEED(strafeplayer);
 324                     }
 325                     else{
 326                         maxspeed = PHYS_MAXAIRSPEED(strafeplayer) * pow(fabs(PHYS_MAXAIRSTRAFESPEED(strafeplayer) / PHYS_MAXAIRSPEED(strafeplayer)), 1 - (90 - fabs(wishangle)) / 45); // no modifiers here because they don't affect air strafing
 327                     }
 328                     turnspeed = vlen(vec2(movement));
 329                     if(turnspeed == 0) turnspeed = maxspeed;
 330                     else turnspeed = min(turnspeed, maxspeed);
 331
 332                     if(PHYS_AIRACCELERATE(strafeplayer) == 0){
 333                         maxaccel = 0;
 334                     }
 335                     else if(PHYS_AIRSTRAFEACCELERATE(strafeplayer) == 0 || PHYS_AIRACCELERATE(strafeplayer) <= PHYS_AIRSTRAFEACCELERATE(strafeplayer)){
 336                         maxaccel = PHYS_AIRACCELERATE(strafeplayer);
 337                     }
 338                     else{
 339                         maxaccel = PHYS_AIRACCELERATE(strafeplayer) * pow(fabs(PHYS_AIRSTRAFEACCELERATE(strafeplayer) / PHYS_AIRACCELERATE(strafeplayer)), 1 - (90 - fabs(wishangle)) / 45); // no modifiers here because they don't affect air strafing
 340                     }
 341                     turnaccel = maxaccel;
 342                 }
 343             }
 344             else if((time - state_strafekeys_time) >= autocvar_hud_panel_strafehud_timeout_turn) // timeout for jumping with strafe keys only
 345             {
 346                 turn = false;
 347             }
 348         }
 349         if(turn && (onground || !strafekeys)) // retain last state until strafe turning times out
 350         {
 351             wishangle = turnangle;
 352             movespeed = turnspeed;
 353             maxaccel = turnaccel;
 354         }
 355         else{
 356             movespeed = vlen(vec2(movement));
 357             if(movespeed == 0) movespeed = maxspeed;
 358             else movespeed = min(movespeed, maxspeed);
 359
 360             if(onground)
 361             {
 362                 if((keys & KEY_JUMP) && ((time - state_onground_time) < autocvar_hud_panel_strafehud_timeout_ground)) // if ground timeout hasn't expired yet use air accelerate
 363                 {
 364                     maxaccel = !autocvar__hud_configure ? PHYS_AIRACCELERATE(strafeplayer) * crouch_mod * water_mod : 1;
 365                 }
 366             }
 367             else
 368             {
 369                 if(!(keys & KEY_JUMP) && ((time - state_onground_time) < autocvar_hud_panel_strafehud_timeout_air)) // if air timeout hasn't expired yet use ground accelerate
 370                 {
 371                     maxaccel = !autocvar__hud_configure ? PHYS_ACCELERATE(strafeplayer) * crouch_mod * water_mod : 1;
 372                 }
 373             }
 374         }
 375
 376         minspeed = autocvar_hud_panel_strafehud_switch_minspeed < 0 ? (movespeed - maxaccel) + antiflicker_speed : autocvar_hud_panel_strafehud_switch_minspeed;
 377
 378         // get current strafing angle ranging from -180° to +180°
 379         if(!autocvar__hud_configure)
 380         {
 381             if(speed > 0)
 382             {
 383                 // calculate view angle relative to the players current velocity direction
 384                 angle = vel_angle - view_angle;
 385
 386                 // if the angle goes above 180° or below -180° wrap it to the opposite side since we want the interior angle
 387                 if (angle > 180) angle -= 360;
 388                 else if(angle < -180) angle += 360;
 389
 390                 // determine whether the player is strafing forwards or backwards
 391                 // if the player isn't strafe turning use forwards/backwards keys to determine direction
 392                 if(fabs(wishangle) != 90)
 393                 {
 394                     if(keys_fwd > 0)
 395                     {
 396                         fwd = true;
 397                     }
 398                     else if(keys_fwd < 0)
 399                     {
 400                         fwd = false;
 401                     }
 402                     else
 403                     {
 404                         fwd = fabs(angle) <= 90;
 405                     }
 406                 }
 407                 // otherwise determine by examining the strafe angle
 408                 else
 409                 {
 410                     if(wishangle < 0) // detect direction using wishangle since the direction is not yet set
 411                     {
 412                         fwd = angle <= -wishangle;
 413                     }
 414                     else
 415                     {
 416                         fwd = angle >= -wishangle;
 417                     }
 418                 }
 419
 420                 // shift the strafe angle by 180° when strafing backwards
 421                 if(!fwd)
 422                 {
 423                     if(angle < 0) angle += 180;
 424                     else angle -= 180;
 425                 }
 426
 427                 // don't make the angle indicator switch side too much at ±180° if anti flicker is turned on
 428                 if(angle > (180 - antiflicker_angle) || angle < (-180 + antiflicker_angle))
 429                 {
 430                     straight_overturn = true;
 431                 }
 432             }
 433             else
 434             {
 435                 angle = 0;
 436             }
 437         }
 438         else // simulate turning for HUD setup
 439         {
 440             fwd = true;
 441             if(autocvar__hud_panel_strafehud_demo && ((time - demo_time) >= .025))
 442             {
 443                 demo_time = time;
 444                 demo_angle += demo_direction;
 445                 if(fabs(demo_angle) >= 55)
 446                 {
 447                     demo_direction = -demo_direction;
 448                 }
 449             }
 450             angle = demo_angle;
 451             wishangle = 45 * (demo_angle > 0 ? 1 : -1);
 452         }
 453
 454         // invert the wish angle when strafing backwards
 455         if(!fwd)
 456         {
 457             wishangle = -wishangle;
 458         }
 459
 460         // flip angles if v_flipped is enabled
 461         if(autocvar_v_flipped)
 462         {
 463             angle = -angle;
 464             wishangle = -wishangle;
 465         }
 466
 467         // determine whether the player is strafing left or right
 468         if(wishangle != 0)
 469         {
 470             direction = wishangle > 0 ? 1 : -1;
 471         }
 472         else
 473         {
 474             direction = (angle > antiflicker_angle && angle < (180 - antiflicker_angle)) ? 1 : (angle < -antiflicker_angle && angle > (-180 + antiflicker_angle)) ? -1 : 0;
 475         }
 476
 477         // best angle to strafe at
 478         bestangle = (speed > fabs(movespeed - maxaccel) ? acos(fabs(movespeed - maxaccel) / speed) * RAD2DEG * (direction < 0 ? -1 : 1) : 0);
 479         prebestangle = (speed > fabs(movespeed) ? acos(fabs(movespeed) / speed) * RAD2DEG * (direction < 0 ? -1 : 1) : 0);
 480         odd_bestangle = -bestangle - wishangle;
 481         bestangle -= wishangle;
 482         prebestangle -= wishangle;
 483
 484         // various offsets and size calculations of hud indicator elements
 485         // how much is hidden by the current hud angle
 486         hidden_width = (360 - hudangle) / hudangle * panel_size.x;
 487         // current angle
 488         currentangle_size.x = autocvar_hud_panel_strafehud_angle_width;
 489         currentangle_size.y = autocvar_hud_panel_strafehud_angle_height;
 490         if(!autocvar_hud_panel_strafehud_uncapped)
 491         {
 492             currentangle_size.x = min(currentangle_size.x, 10);
 493             currentangle_size.y = min(currentangle_size.y, 10);
 494         }
 495         currentangle_size.x *= panel_size.x;
 496         currentangle_size.y *= panel_size.y;
 497         if(!autocvar_hud_panel_strafehud_uncapped)
 498         {
 499             currentangle_size.x = max(currentangle_size.x, 1);
 500             currentangle_size.y = max(currentangle_size.y, 1);
 501         }
 502         else
 503         {
 504             currentangle_size.y = max(currentangle_size.y, 0);
 505         }
 506         if(mode == 0)
 507         {
 508             currentangle_offset = angle/hudangle * panel_size.x;
 509         }
 510         else
 511         {
 512             currentangle_offset = bound(-hudangle/2, angle, hudangle/2)/hudangle * panel_size.x + panel_size.x/2;
 513         }
 514         // best strafe acceleration angle
 515         bestangle_offset        =  bestangle/hudangle * panel_size.x + panel_size.x/2;
 516         switch_bestangle_offset = -bestangle/hudangle * panel_size.x + panel_size.x/2;
 517         bestangle_width = panel_size.x * autocvar_hud_panel_strafehud_switch_width;
 518         if(!autocvar_hud_panel_strafehud_uncapped)
 519             bestangle_width = max(bestangle_width, 1);
 520
 521         if(((angle > -wishangle && direction < 0) || (angle < -wishangle && direction > 0)) && (direction != 0))
 522         {
 523             odd_angles = true;
 524             odd_bestangle_offset = odd_bestangle/hudangle * panel_size.x + panel_size.x/2;
 525             switch_odd_bestangle_offset = (odd_bestangle+bestangle*2)/hudangle * panel_size.x + panel_size.x/2;
 526         }
 527         // direction indicator
 528         direction_size_vertical.x = autocvar_hud_panel_strafehud_direction_width;
 529         if(!autocvar_hud_panel_strafehud_uncapped)
 530             direction_size_vertical.x = min(direction_size_vertical.x, 1);
 531         direction_size_vertical.x *= panel_size.y;
 532         if(!autocvar_hud_panel_strafehud_uncapped)
 533             direction_size_vertical.x = max(direction_size_vertical.x, 1);
 534         direction_size_vertical.y = panel_size.y + direction_size_vertical.x*2;
 535         direction_size_horizontal.x = panel_size.x * min(autocvar_hud_panel_strafehud_direction_length, .5);
 536         direction_size_horizontal.y = direction_size_vertical.x;
 537         // overturn
 538         overturn_width = 180/hudangle * panel_size.x;
 539
 540         // the neutral zone fills the whole strafe bar
 541         if(immobile)
 542         {
 543             // draw neutral zone
 544             if(panel_size.x > 0 && panel_size.y > 0 && autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha > 0)
 545             {
 546                 switch(autocvar_hud_panel_strafehud_style)
 547                 {
 548                     default:
 549                     case 0:
 550                         drawfill(panel_pos, panel_size, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 551                         break;
 552
 553                     case 1:
 554                         HUD_Panel_DrawProgressBar(panel_pos, panel_size, "progressbar", 1, 0, 0, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 555                 }
 556             }
 557         }
 558         else
 559         {
 560             // calculate various zones of the strafe-o-meter
 561             accelzone_width = (90 - fabs(bestangle + wishangle))/hudangle * panel_size.x;
 562             preaccelzone_width = (fabs(bestangle - prebestangle))/hudangle * panel_size.x;
 563             overturn_offset = accelzone_width + preaccelzone_width;
 564             accelzone_right_offset = preaccelzone_width;
 565             accelzone_left_offset = overturn_offset + overturn_width;
 566             preaccelzone_right_offset = 0;
 567             preaccelzone_left_offset = accelzone_left_offset + accelzone_width;
 568             neutral_width = 360/hudangle * panel_size.x - accelzone_width*2 - preaccelzone_width*2 - overturn_width;
 569             neutral_offset = direction < 0 ? preaccelzone_left_offset + preaccelzone_width : -neutral_width;
 570
 571             // shift hud if operating in view angle centered mode
 572             if(mode == 0)
 573             {
 574                 shift_offset = -currentangle_offset;
 575                 bestangle_offset += shift_offset;
 576                 switch_bestangle_offset += shift_offset;
 577                 odd_bestangle_offset += shift_offset;
 578                 switch_odd_bestangle_offset += shift_offset;
 579             }
 580             if(direction < 0) shift_offset += -360/hudangle * panel_size.x;
 581             // calculate how far off-center the strafe zones currently are
 582             shift_offset += (panel_size.x + neutral_width)/2 - wishangle/hudangle * panel_size.x;
 583             // shift strafe zones into correct place
 584             neutral_offset += shift_offset;
 585             accelzone_left_offset += shift_offset;
 586             accelzone_right_offset += shift_offset;
 587             preaccelzone_left_offset += shift_offset;
 588             preaccelzone_right_offset += shift_offset;
 589             overturn_offset += shift_offset;
 590
 591             // draw left acceleration zone
 592             HUD_Panel_DrawStrafeHUD(accelzone_left_offset, accelzone_width, autocvar_hud_panel_strafehud_bar_accel_color, autocvar_hud_panel_strafehud_bar_accel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 1);
 593             HUD_Panel_DrawStrafeHUD(preaccelzone_left_offset, preaccelzone_width, autocvar_hud_panel_strafehud_bar_preaccel_color, autocvar_hud_panel_strafehud_bar_preaccel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 0);
 594
 595             // draw right acceleration zone
 596             HUD_Panel_DrawStrafeHUD(accelzone_right_offset, accelzone_width, autocvar_hud_panel_strafehud_bar_accel_color, autocvar_hud_panel_strafehud_bar_accel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 2);
 597             HUD_Panel_DrawStrafeHUD(preaccelzone_right_offset, preaccelzone_width, autocvar_hud_panel_strafehud_bar_preaccel_color, autocvar_hud_panel_strafehud_bar_preaccel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 0);
 598
 599             // draw overturn zone
 600             HUD_Panel_DrawStrafeHUD(overturn_offset, overturn_width, autocvar_hud_panel_strafehud_bar_overturn_color, autocvar_hud_panel_strafehud_bar_overturn_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 3);
 601
 602             // draw neutral zone
 603             HUD_Panel_DrawStrafeHUD(neutral_offset, neutral_width, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 0);
 604
 605             if(speed >= minspeed && bestangle_width > 0) // only draw indicators if minspeed is reached
 606             {
 607                 // draw the switch indicator(s)
 608                 float offset = !odd_angles ? bestangle_offset : odd_bestangle_offset;
 609                 float switch_offset = !odd_angles ? switch_bestangle_offset : switch_odd_bestangle_offset;
 610
 611                 // remove switch indicator width from offset
 612                 if(direction < 0)
 613                 {
 614                     if(!odd_angles)
 615                         offset -= bestangle_width;
 616                     else
 617                         switch_offset -= bestangle_width;
 618                 }
 619                 else
 620                 {
 621                     if(!odd_angles)
 622                         switch_offset -= bestangle_width;
 623                     else
 624                         offset -= bestangle_width;
 625                 }
 626
 627                 HUD_Panel_DrawStrafeHUD(switch_offset, bestangle_width, autocvar_hud_panel_strafehud_switch_color, autocvar_hud_panel_strafehud_switch_alpha * panel_fg_alpha, 0, 0);
 628                 if(direction == 0) HUD_Panel_DrawStrafeHUD(offset, bestangle_width, autocvar_hud_panel_strafehud_switch_color, autocvar_hud_panel_strafehud_switch_alpha * panel_fg_alpha, 0, 0);
 629             }
 630         }
 631
 632         // slick detector
 633         slickdetector_height = max(autocvar_hud_panel_strafehud_slickdetector_height, 0);
 634         if(!autocvar_hud_panel_strafehud_uncapped)
 635              slickdetector_height = min(slickdetector_height, 1);
 636         slickdetector_height *= panel_size.y;
 637         if(autocvar_hud_panel_strafehud_slickdetector_range > 0 && autocvar_hud_panel_strafehud_slickdetector_alpha > 0 && slickdetector_height > 0 && panel_size.x > 0)
 638         {
 639             float slicksteps = max(autocvar_hud_panel_strafehud_slickdetector_granularity, 0);
 640             bool slickdetected = false;
 641
 642             if(!autocvar_hud_panel_strafehud_uncapped)
 643                 slicksteps = min(slicksteps, 4);
 644             slicksteps = 90 / pow(2, slicksteps);
 645
 646             if(islocal) slickdetected = IS_ONSLICK(strafeplayer); // don't need to traceline if already touching slick
 647
 648             // traceline into every direction
 649             trace_dphitq3surfaceflags = 0;
 650             for(float i = 0; i < 360 && !slickdetected; i += slicksteps)
 651             {
 652                 vector slickoffset;
 653                 float slickrotate;
 654                 slickoffset.z = -cos(i * DEG2RAD) * autocvar_hud_panel_strafehud_slickdetector_range;
 655                 slickrotate = sin(i * DEG2RAD) * autocvar_hud_panel_strafehud_slickdetector_range;
 656                 if(i != 0 && i != 180)
 657                 {
 658                     for(float j = 0; j < 180 && !slickdetected; j += slicksteps)
 659                     {
 660                         slickoffset.x = sin(j * DEG2RAD) * slickrotate;
 661                         slickoffset.y = cos(j * DEG2RAD) * slickrotate;
 662
 663                         traceline(strafeplayer.origin, strafeplayer.origin + slickoffset, MOVE_WORLDONLY, NULL);
 664                         if((PHYS_FRICTION(strafeplayer) == 0 && trace_fraction < 1) || trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK) slickdetected = true;
 665                     }
 666                 }
 667                 else
 668                 {
 669                     slickoffset.x = slickoffset.y = 0;
 670                     traceline(strafeplayer.origin, strafeplayer.origin + slickoffset, MOVE_WORLDONLY, NULL);
 671                     if((PHYS_FRICTION(strafeplayer) == 0 && trace_fraction < 1) || trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK) slickdetected = true;
 672                 }
 673             }
 674
 675             // if a traceline hit a slick surface
 676             if(slickdetected)
 677             {
 678                 vector slickdetector_size = panel_size;
 679                 slickdetector_size.y = slickdetector_height;
 680                 // top horizontal line
 681                 drawfill(panel_pos - eY * slickdetector_size.y, slickdetector_size, autocvar_hud_panel_strafehud_slickdetector_color, autocvar_hud_panel_strafehud_slickdetector_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 682                 // bottom horizontal line
 683                 drawfill(panel_pos + eY * panel_size.y, slickdetector_size, autocvar_hud_panel_strafehud_slickdetector_color, autocvar_hud_panel_strafehud_slickdetector_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 684             }
 685         }
 686
 687         if(direction != 0 && direction_size_vertical.x > 0 && autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha > 0)
 688         {
 689             bool indicator_direction = direction < 0;
 690             // invert left/right when strafing backwards or when strafing towards the opposite side indicated by the direction variable
 691             // if both conditions are true then it's inverted twice hence not inverted at all
 692             if(!fwd != odd_angles)
 693             {
 694                 indicator_direction = !indicator_direction;
 695             }
 696             // draw the direction indicator caps at the sides of the hud
 697             // vertical line
 698             if(direction_size_vertical.y > 0) drawfill(panel_pos - eY * direction_size_horizontal.y + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x), direction_size_vertical, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 699             // top horizontal line
 700             drawfill(panel_pos + eX * (indicator_direction ? 0 : panel_size.x - direction_size_horizontal.x) - eY * direction_size_horizontal.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 701             // bottom horizontal line
 702             drawfill(panel_pos + eX * (indicator_direction ? 0 : panel_size.x - direction_size_horizontal.x) + eY * panel_size.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 703         }
 704
 705         if(speed <= (fabs(movespeed - maxaccel) + antiflicker_speed) && !immobile)
 706         {
 707             bestangle_anywhere = true; // moving forward should suffice to gain speed
 708         }
 709
 710         // draw the actual strafe angle
 711         if(!bestangle_anywhere && !immobile) // player gains speed with strafing
 712         {
 713             if((direction > 0 && (angle >= bestangle || angle <= -(bestangle + wishangle*2))) ||
 714                (direction < 0 && (angle <= bestangle || angle >= -(bestangle + wishangle*2))))
 715             currentangle_color = autocvar_hud_panel_strafehud_angle_accel_color;
 716         }
 717
 718         if(fabs(angle + wishangle) > 90) // player is overturning
 719         {
 720             currentangle_color = autocvar_hud_panel_strafehud_angle_overturn_color;
 721         }
 722         else if(bestangle_anywhere) // player gains speed without strafing
 723         {
 724             currentangle_color = autocvar_hud_panel_strafehud_angle_accel_color;
 725         }
 726
 727         if(mode == 0 || straight_overturn)
 728         {
 729             currentangle_offset = panel_size.x/2;
 730         }
 731
 732         if(autocvar_hud_panel_strafehud_style == 2 && !immobile)
 733         {
 734             float moveangle = angle + wishangle;
 735             float strafeangle = (bestangle + wishangle) * (direction < 0 ? -1 : 1);
 736             float strafe_ratio = 0;
 737             if(fabs(moveangle) > 90)
 738             {
 739                 strafe_ratio = -((fabs(moveangle) - 90) / 90);
 740                 if(strafe_ratio < -1) strafe_ratio = -2 - strafe_ratio;
 741             }
 742             else
 743             {
 744                 if(moveangle >= strafeangle)
 745                 {
 746                     strafe_ratio = 1 - (moveangle - strafeangle) / (90 - strafeangle);
 747                 }
 748                 else if(moveangle <= -strafeangle)
 749                 {
 750                     strafe_ratio = 1 - (moveangle + strafeangle) / (-90 + strafeangle);
 751                 }
 752             }
 753             if(strafe_ratio < 0)
 754             {
 755                 currentangle_color = StrafeHUD_mixColors(autocvar_hud_panel_strafehud_angle_neutral_color, autocvar_hud_panel_strafehud_angle_overturn_color, -strafe_ratio);
 756             }
 757             else
 758             {
 759                 currentangle_color = StrafeHUD_mixColors(autocvar_hud_panel_strafehud_angle_neutral_color, autocvar_hud_panel_strafehud_angle_accel_color, strafe_ratio);
 760             }
 761         }
 762
 763         float angleheight_offset = currentangle_size.y;
 764         float ghost_offset = 0;
 765         if(autocvar_hud_panel_strafehud_bestangle && direction != 0)
 766         {
 767             ghost_offset = !odd_angles ? bestangle_offset : odd_bestangle_offset;
 768             if(ghost_offset < 0) ghost_offset = 0;
 769             if(ghost_offset > panel_size.x) ghost_offset = panel_size.x;
 770         }
 771
 772         switch(autocvar_hud_panel_strafehud_angle_style)
 773         {
 774             case 1:
 775                 if(currentangle_size.x > 0 && currentangle_size.y > 0)
 776                 {
 777                     if(autocvar_hud_panel_strafehud_bestangle && direction != 0) drawfill(panel_pos - eY * ((currentangle_size.y - panel_size.y) / 2) + eX * (ghost_offset - currentangle_size.x/2), currentangle_size, autocvar_hud_panel_strafehud_bestangle_color, autocvar_hud_panel_strafehud_bestangle_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 778                     drawfill(panel_pos - eY * ((currentangle_size.y - panel_size.y) / 2) + eX * (currentangle_offset - currentangle_size.x/2), currentangle_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 779                 }
 780                 break;
 781             case 2:
 782                 if(currentangle_size.x > 0 && currentangle_size.y > 0)
 783                 {
 784                     vector line_size = currentangle_size;
 785                     line_size.y = currentangle_size.y / (bound(2, autocvar_hud_panel_strafehud_angle_dashes, currentangle_size.y)*2-1);
 786                     for(float i = 0; i < currentangle_size.y; i += line_size.y*2)
 787                     {
 788                         if(i + line_size.y*2 >= currentangle_size.y) line_size.y = currentangle_size.y - i;
 789                         if(autocvar_hud_panel_strafehud_bestangle && direction != 0) drawfill(panel_pos - eY * ((currentangle_size.y - panel_size.y) / 2 - i) + eX * (ghost_offset - line_size.x/2), line_size, autocvar_hud_panel_strafehud_bestangle_color, autocvar_hud_panel_strafehud_bestangle_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 790                         drawfill(panel_pos - eY * ((currentangle_size.y - panel_size.y) / 2 - i) + eX * (currentangle_offset - line_size.x/2), line_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 791                     }
 792                 }
 793                 break;
 794             case 0:
 795             default:
 796                 // don't offset text and arrows if the angle indicator line isn't drawn
 797                 angleheight_offset = panel_size.y;
 798         }
 799
 800         if(autocvar_hud_panel_strafehud_angle_arrow > 0)
 801         {
 802             if(arrow_size > 0)
 803             {
 804                 if(autocvar_hud_panel_strafehud_angle_arrow == 1 || autocvar_hud_panel_strafehud_angle_arrow >= 3)
 805                 {
 806                     if(autocvar_hud_panel_strafehud_bestangle && direction != 0) StrafeHUD_drawStrafeArrow(panel_pos + eY * ((panel_size.y - angleheight_offset) / 2) + eX * ghost_offset, arrow_size, autocvar_hud_panel_strafehud_bestangle_color, autocvar_hud_panel_strafehud_bestangle_alpha * panel_fg_alpha, true);
 807                     StrafeHUD_drawStrafeArrow(panel_pos + eY * ((panel_size.y - angleheight_offset) / 2) + eX * currentangle_offset, arrow_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, true);
 808                 }
 809                 if(autocvar_hud_panel_strafehud_angle_arrow >= 2)
 810                 {
 811                     if(autocvar_hud_panel_strafehud_bestangle && direction != 0) StrafeHUD_drawStrafeArrow(panel_pos + eY * ((panel_size.y - angleheight_offset) / 2 + angleheight_offset) + eX * ghost_offset, arrow_size, autocvar_hud_panel_strafehud_bestangle_color, autocvar_hud_panel_strafehud_bestangle_alpha * panel_fg_alpha, false);
 812                     StrafeHUD_drawStrafeArrow(panel_pos + eY * ((panel_size.y - angleheight_offset) / 2 + angleheight_offset) + eX * currentangle_offset, arrow_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, false);
 813                 }
 814             }
 815         }
 816
 817         draw_beginBoldFont();
 818         // show speed when crossing the start trigger
 819         if(autocvar_hud_panel_strafehud_startspeed_fade > 0)
 820         {
 821             float text_alpha = 0;
 822             if((race_nextcheckpoint == 1) || (race_checkpoint == 254 && race_nextcheckpoint == 255)) // check if the start trigger was hit (will also trigger if the finish trigger was hit if those have the same ID)
 823             {
 824                 if(starttime != race_checkpointtime)
 825                 {
 826                     starttime = race_checkpointtime;
 827                     startspeed = speed;
 828                 }
 829             }
 830             if(startspeed >= 0)
 831             {
 832                 text_alpha = cos(((time - starttime) / autocvar_hud_panel_strafehud_startspeed_fade) * 90 * DEG2RAD); // fade non-linear like the physics panel does
 833                 if((time - starttime) > autocvar_hud_panel_strafehud_startspeed_fade)
 834                 {
 835                     startspeed = -1;
 836                 }
 837             }
 838             if(startspeed >= 0 && text_alpha > 0 && autocvar_hud_panel_strafehud_startspeed_size > 0)
 839             {
 840                 vector startspeed_size = panel_size;
 841                 startspeed_size.y = autocvar_hud_panel_strafehud_startspeed_size;
 842                 if(!autocvar_hud_panel_strafehud_uncapped)
 843                     startspeed_size.y = min(startspeed_size.y, 10);
 844                 startspeed_size.y *= panel_size.y;
 845                 if(!autocvar_hud_panel_strafehud_uncapped)
 846                     startspeed_size.y = max(startspeed_size.y, 1);
 847
 848                 float text_offset = 0;
 849                 if((autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha > 0) || (autocvar_hud_panel_strafehud_bestangle && autocvar_hud_panel_strafehud_bestangle_alpha * panel_fg_alpha > 0))
 850                 {
 851                     text_offset = (angleheight_offset - panel_size.y) / 2;
 852                     if(arrow_size > 0 && autocvar_hud_panel_strafehud_angle_arrow >= 2)
 853                         text_offset += arrow_size;
 854                     // make sure text doesn't draw inside the strafehud bar
 855                     text_offset = max(text_offset, 0);
 856                 }
 857
 858                 string speed_unit = GetSpeedUnit(autocvar_hud_panel_strafehud_unit);
 859                 drawstring_aspect(panel_pos + eY * (panel_size.y + text_offset), strcat(ftos_decimals(startspeed * speed_conversion_factor, 2), autocvar_hud_panel_strafehud_unit_show ? speed_unit : ""), startspeed_size, autocvar_hud_panel_strafehud_startspeed_color, text_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 860             }
 861         }
 862         else
 863         {
 864             starttime = 0;
 865             startspeed = -1;
 866         }
 867
 868         // experimental: show height achieved by a single jump (doesn't work in low gravity and may not be 100% accurate)
 869         if(autocvar_hud_panel_strafehud_jumpheight_fade > 0)
 870         {
 871             float text_alpha = 0;
 872             float jumpheight_min = max(autocvar_hud_panel_strafehud_jumpheight_min, 0);
 873             float jumpheight_current = strafeplayer.origin.z;
 874             float jumpspeed_current = strafeplayer.velocity.z;
 875             if(jumpspeed_prev <= jumpspeed_current || jumpheight_prev > jumpheight_current || onground || swimming || IS_DEAD(strafeplayer) || spectating)
 876             {
 877                 // tries to catch kill and spectate but those are not reliable, should just hook to kill/spectate/teleport and reset jump height there
 878                 jumprestart = true;
 879             }
 880             else
 881             {
 882                 if(jumpheight < 0 || jumprestart)
 883                 {
 884                     jumprestart = false;
 885                     jumpheight = 0;
 886                 }
 887                 else
 888                 {
 889                     jumpheight += jumpheight_current - jumpheight_prev;
 890                 }
 891                 if((jumpheight * length_conversion_factor) > jumpheight_min && jumpheight > jumpheight_persistent)
 892                 {
 893                     jumptime = time;
 894                     jumpheight_persistent = jumpheight;
 895                 }
 896             }
 897             jumpheight_prev = jumpheight_current;
 898             jumpspeed_prev = jumpspeed_current;
 899             if(jumpheight_persistent > 0)
 900             {
 901                 text_alpha = cos(((time - jumptime) / autocvar_hud_panel_strafehud_jumpheight_fade) * 90 * DEG2RAD); // fade non-linear like the physics panel does
 902                 if((time - jumptime) > autocvar_hud_panel_strafehud_jumpheight_fade)
 903                 {
 904                     jumpheight_persistent = -1;
 905                 }
 906             }
 907             if(jumpheight_persistent > 0 && text_alpha > 0 && autocvar_hud_panel_strafehud_jumpheight_size > 0)
 908             {
 909                 vector jumpheight_size = panel_size;
 910                 jumpheight_size.y = autocvar_hud_panel_strafehud_jumpheight_size;
 911                 if(!autocvar_hud_panel_strafehud_uncapped)
 912                     jumpheight_size.y = min(jumpheight_size.y, 10);
 913                 jumpheight_size.y *= panel_size.y;
 914                 if(!autocvar_hud_panel_strafehud_uncapped)
 915                     jumpheight_size.y = max(jumpheight_size.y, 1);
 916
 917                 float text_offset = 0;
 918                 if((autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha > 0) || (autocvar_hud_panel_strafehud_bestangle && autocvar_hud_panel_strafehud_bestangle_alpha * panel_fg_alpha > 0))
 919                 {
 920                     text_offset = (angleheight_offset - panel_size.y) / 2;
 921                     if(arrow_size > 0 && autocvar_hud_panel_strafehud_angle_arrow == 1 || autocvar_hud_panel_strafehud_angle_arrow >= 3)
 922                         text_offset += arrow_size;
 923                     // make sure text doesn't draw inside the strafehud bar
 924                     text_offset = max(text_offset, 0);
 925                 }
 926
 927                 string length_unit = GetLengthUnit(autocvar_hud_panel_strafehud_unit);
 928                 drawstring_aspect(panel_pos - eY * (jumpheight_size.y + text_offset), strcat(ftos_decimals(jumpheight_persistent * length_conversion_factor, length_decimals), autocvar_hud_panel_strafehud_unit_show ? length_unit : ""), jumpheight_size, autocvar_hud_panel_strafehud_jumpheight_color, text_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 929             }
 930         }
 931         else
 932         {
 933             jumpheight_prev = jumpspeed_prev = 0;
 934             jumpheight = jumpheight_persistent = -1;
 935         }
 936         draw_endBoldFont();
 937     }
 938 }
 939
 940 // functions to make hud elements align perfectly in the hud area
 941 void HUD_Panel_DrawStrafeHUD(float offset, float width, vector color, float alpha, int type, int gradientType)
 942 {
 943     float mirror_offset, mirror_width;
 944     vector size = panel_size;
 945     vector mirror_size = panel_size;
 946     int gradient_start;
 947     float gradient_offset, gradient_mirror_offset;
 948     float overflow_width = 0, overflow_mirror_width = 0;
 949
 950     float original_width = width;
 951
 952     if(alpha <= 0 && type != 2 || width <= 0) return;
 953
 954     if(type == 2 && gradientType == 0) type = 0;
 955
 956     if(offset < 0)
 957     {
 958         mirror_width = min(fabs(offset), width);
 959         mirror_offset = panel_size.x + hidden_width - fabs(offset);
 960         width += offset;
 961         offset = 0;
 962     }
 963     else
 964     {
 965         mirror_width = min(offset + width - panel_size.x - hidden_width, width);
 966         mirror_offset = max(offset - panel_size.x - hidden_width, 0);
 967     }
 968
 969     if(width < 0) width = 0;
 970     if((offset + width) > panel_size.x)
 971     {
 972         overflow_width = (offset + width) - panel_size.x;
 973         width = panel_size.x - offset;
 974     }
 975     if(mirror_offset < 0)
 976     {
 977         mirror_width += mirror_offset;
 978         mirror_offset = 0;
 979     }
 980
 981     if(mirror_width < 0) mirror_width = 0;
 982     if((mirror_offset + mirror_width) > panel_size.x)
 983     {
 984         overflow_mirror_width = (mirror_offset + mirror_width) - panel_size.x;
 985         mirror_width = panel_size.x - mirror_offset;
 986     }
 987
 988     if(direction < 0) // swap mirror and non-mirror values if direction points left
 989     {
 990         offset += mirror_offset;
 991         mirror_offset = offset - mirror_offset;
 992         offset -= mirror_offset;
 993
 994         width += mirror_width;
 995         mirror_width = width - mirror_width;
 996         width -= mirror_width;
 997
 998         overflow_width += overflow_mirror_width;
 999         overflow_mirror_width = overflow_width - overflow_mirror_width;
1000         overflow_width -= overflow_mirror_width;
1001     }
1002
1003     size.x = width;
1004     mirror_size.x = mirror_width;
1005
1006     switch(type)
1007     {
1008         default:
1009         case 0: // no styling (drawfill)
1010             if(mirror_size.x > 0 && mirror_size.y > 0) drawfill(panel_pos + eX * mirror_offset, mirror_size, color, alpha, DRAWFLAG_NORMAL);
1011             if(size.x > 0 && size.y > 0) drawfill(panel_pos + eX * offset, size, color, alpha, DRAWFLAG_NORMAL);
1012             break;
1013
1014         case 1: // progress bar style
1015             if(mirror_size.x > 0 && mirror_size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * mirror_offset, mirror_size, "progressbar", 1, 0, 0, color, alpha, DRAWFLAG_NORMAL);
1016             if(size.x > 0 && size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * offset, size, "progressbar", 1, 0, 0, color, alpha, DRAWFLAG_NORMAL);
1017             break;
1018
1019         case 2: // gradient style (types: 1 = left, 2 = right, 3 = both)
1020             // determine whether the gradient starts in the mirrored or the non-mirrored area
1021             if(offset == 0 && mirror_offset == 0) gradient_start = width > mirror_width ? 2 : 1;
1022             else if(offset == 0) gradient_start = 2;
1023             else if(mirror_offset == 0) gradient_start = 1;
1024             else gradient_start = 0;
1025
1026             switch(gradient_start){
1027                 default:
1028                 case 0: // no offset required
1029                     gradient_offset = gradient_mirror_offset = 0;
1030                     break;
1031                 case 1: // offset starts in non-mirrored area, mirrored area requires offset
1032                     gradient_offset = 0;
1033                     gradient_mirror_offset = original_width - (mirror_width + overflow_mirror_width);
1034                     break;
1035                 case 2: // offset starts in mirrored area, non-mirrored area requires offset
1036                     gradient_offset = original_width - (width + overflow_width);
1037                     gradient_mirror_offset = 0;
1038             }
1039
1040             StrafeHUD_drawGradient(color, autocvar_hud_panel_strafehud_bar_neutral_color, mirror_size, original_width, mirror_offset, alpha, gradient_mirror_offset, gradientType);
1041             StrafeHUD_drawGradient(color, autocvar_hud_panel_strafehud_bar_neutral_color, size, original_width, offset, alpha, gradient_offset, gradientType);
1042     }
1043 }
1044
1045 vector StrafeHUD_mixColors(vector color1, vector color2, float ratio)
1046 {
1047     vector mixedColor;
1048     if(ratio <= 0) return color1;
1049     if(ratio >= 1) return color2;
1050     mixedColor.x = color1.x + (color2.x - color1.x) * ratio;
1051     mixedColor.y = color1.y + (color2.y - color1.y) * ratio;
1052     mixedColor.z = color1.z + (color2.z - color1.z) * ratio;
1053     return mixedColor;
1054 }
1055
1056 void StrafeHUD_drawGradient(vector color1, vector color2, vector size, float original_width, float offset, float alpha, float gradientOffset, int gradientType)
1057 {
1058     float color_ratio, alpha1, alpha2;
1059     vector gradient_size = size;
1060     alpha1 = bound(0, alpha, 1);
1061     alpha2 = bound(0, autocvar_hud_panel_strafehud_bar_neutral_alpha, 1);
1062     if((alpha1+alpha2) == 0) return;
1063     color_ratio = alpha1/(alpha1+alpha2);
1064     for(int i = 0; i < size.x; ++i)
1065     {
1066         float ratio, alpha_ratio, combine_ratio1, combine_ratio2;
1067         gradient_size.x = size.x - i < 1 ? size.x - i : 1;
1068         ratio = (i + gradientOffset) / original_width * (gradientType == 3 ? 2 : 1);
1069         if(ratio > 1) ratio = 2 - ratio;
1070         if(gradientType != 2) ratio = 1 - ratio;
1071         alpha_ratio = alpha1 - (alpha1 - alpha2) * ratio;
1072         combine_ratio1 = ratio*(1-color_ratio);
1073         combine_ratio2 = (1-ratio)*color_ratio;
1074         ratio = (combine_ratio1 + combine_ratio2) == 0 ? 1 : combine_ratio1/(combine_ratio1 + combine_ratio2);
1075         if(alpha_ratio > 0) drawfill(panel_pos + eX * (offset + i), gradient_size, StrafeHUD_mixColors(color1, color2, ratio), alpha_ratio, DRAWFLAG_NORMAL);
1076     }
1077 }
1078
1079 // draw the strafe arrows (inspired by drawspritearrow() in common/mutators/mutator/waypoints/waypointsprites.qc)
1080 void StrafeHUD_drawStrafeArrow(vector origin, float size, vector color, float alpha, bool flipped)
1081 {
1082     if(flipped) origin -= size*eY;
1083     R_BeginPolygon("", DRAWFLAG_NORMAL, true);
1084     R_PolygonVertex(origin + (flipped ? size*eY : '0 0 0')          , '0 0 0', color, alpha);
1085     R_PolygonVertex(origin + (flipped ? '0 0 0' : size*eY) - size*eX, '0 0 0', color, alpha);
1086     R_PolygonVertex(origin + (flipped ? '0 0 0' : size*eY) + size*eX, '0 0 0', color, alpha);
1087     R_EndPolygon();
1088 }
1089
1090 // length unit conversion (km and miles are only included to match the GetSpeedUnit* functions)
1091 float GetLengthUnitFactor(int length_unit)
1092 {
1093     switch(length_unit)
1094     {
1095         default:
1096         case 1: return 1.0;
1097         case 2: return 0.0254;
1098         case 3: return 0.0254 * 0.001;
1099         case 4: return 0.0254 * 0.001 * 0.6213711922;
1100         case 5: return 0.0254 * 0.001 * 0.5399568035;
1101     }
1102 }
1103
1104 string GetLengthUnit(int length_unit)
1105 {
1106     switch(length_unit)
1107     {
1108         // translator-friendly strings without the initial space
1109         default:
1110         case 1: return strcat(" ", _("qu"));
1111         case 2: return strcat(" ", _("m"));
1112         case 3: return strcat(" ", _("km"));
1113         case 4: return strcat(" ", _("mi"));
1114         case 5: return strcat(" ", _("nmi"));
1115     }
1116 }