qcsrc/client/hud/panel/strafehud.qc

   1 // Author: Juhu
   2
   3 #include "strafehud.qh"
   4
   5 #include <client/autocvars.qh>
   6 #include <client/draw.qh>
   7 #include <client/hud/panel/racetimer.qh>
   8 #include <client/resources.qh>
   9 #include <common/animdecide.qh>
  10 #include <common/ent_cs.qh>
  11 #include <common/mapinfo.qh>
  12 #include <common/physics/movetypes/movetypes.qh>
  13 #include <common/physics/player.qh>
  14 #include <lib/csqcmodel/cl_player.qh>
  15
  16 // StrafeHUD (#25)
  17
  18 void HUD_StrafeHUD_Export(int fh)
  19 {
  20     // allow saving cvars that aesthetically change the panel into hud skin files
  21 }
  22
  23 float hidden_width;
  24 int direction;
  25 float demo_angle = -37;
  26 float demo_direction = 1;
  27 float demo_time = 0;
  28 bool state_onground = false;
  29 float state_onground_time = 0;
  30 bool state_strafekeys = false;
  31 float state_strafekeys_time = 0;
  32 bool turn = false;
  33 float turnangle;
  34 bool fwd = true;
  35 bool state_fwd = true;
  36 bool state_fwd_prev = true;
  37 float state_fwd_time = 0;
  38 float starttime = 0;
  39 float startspeed = -1;
  40 float jumptime = 0;
  41 float jumpheight = -1;
  42 float jumpheight_persistent = -1;
  43 float jumpheight_prev = 0;
  44 float jumpspeed_prev = 0;
  45 bool  jumprestart = true;
  46
  47 // provide basic panel cvars to old clients
  48 // TODO remove them after a future release (0.8.2+)
  49 noref string autocvar_hud_panel_strafehud_pos = "0.320000 0.570000";
  50 noref string autocvar_hud_panel_strafehud_size = "0.360000 0.020000";
  51 noref string autocvar_hud_panel_strafehud_bg = "0";
  52 noref string autocvar_hud_panel_strafehud_bg_color = "";
  53 noref string autocvar_hud_panel_strafehud_bg_color_team = "";
  54 noref string autocvar_hud_panel_strafehud_bg_alpha = "0.7";
  55 noref string autocvar_hud_panel_strafehud_bg_border = "";
  56 noref string autocvar_hud_panel_strafehud_bg_padding = "";
  57
  58 void HUD_StrafeHUD()
  59 {
  60     entity strafeplayer;
  61     bool islocal;
  62
  63     // generic hud routines
  64     if(!autocvar__hud_configure)
  65     {
  66         if(!autocvar_hud_panel_strafehud ||
  67            (spectatee_status == -1 && (autocvar_hud_panel_strafehud == 1 || autocvar_hud_panel_strafehud == 3)) ||
  68            (autocvar_hud_panel_strafehud == 3 && !MUTATOR_CALLHOOK(HUD_StrafeHUD_showoptional))) return;
  69     }
  70
  71     HUD_Panel_LoadCvars();
  72
  73     if(autocvar_hud_panel_strafehud_dynamichud)
  74     {
  75         HUD_Scale_Enable();
  76     }
  77     else
  78     {
  79         HUD_Scale_Disable();
  80     }
  81
  82     HUD_Panel_DrawBg();
  83
  84     if(panel_bg_padding)
  85     {
  86         panel_pos  += '1 1 0' * panel_bg_padding;
  87         panel_size -= '2 2 0' * panel_bg_padding;
  88     }
  89
  90     // find out whether the local csqcmodel entity is valid
  91     if(spectatee_status > 0 || isdemo())
  92     {
  93         islocal = false;
  94         strafeplayer = CSQCModel_server2csqc(player_localentnum - 1);
  95     }
  96     else
  97     {
  98         islocal = true;
  99         strafeplayer = csqcplayer;
 100     }
 101
 102     // draw strafehud
 103     if(csqcplayer && strafeplayer)
 104     {
 105         // physics
 106         bool   onground                      = islocal ? IS_ONGROUND(strafeplayer) : !(strafeplayer.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 107         bool   strafekeys;
 108         bool   swimming                      = strafeplayer.waterlevel >= WATERLEVEL_SWIMMING;
 109         bool   spectating                    = entcs_GetSpecState(strafeplayer.sv_entnum) == ENTCS_SPEC_PURE;
 110         float  speed                         = !autocvar__hud_configure ? vlen(vec2(csqcplayer.velocity)) : 1337; // use local csqcmodel entity for this even when spectating, flickers too much otherwise
 111         float  maxspeed_crouch_mod           = IS_DUCKED(strafeplayer) && !swimming ? .5 : 1;
 112         float  maxspeed_water_mod            = swimming ? .7 : 1; // very simplified water physics, the hud will not work well (and is not supposed to) while swimming
 113         float  maxspeed_phys                 = onground ? PHYS_MAXSPEED(strafeplayer) : PHYS_MAXAIRSPEED(strafeplayer);
 114         float  maxspeed                      = !autocvar__hud_configure ? maxspeed_phys * maxspeed_crouch_mod * maxspeed_water_mod : 320;
 115         float  vel_angle                     = vectoangles(strafeplayer.velocity).y - (vectoangles(strafeplayer.velocity).y > 180 ? 360 : 0); // change the range from 0° - 360° to -180° - 180° to match how view_angle represents angles
 116         float  view_angle                    = PHYS_INPUT_ANGLES(strafeplayer).y;
 117         float  angle;
 118         vector movement                      = PHYS_INPUT_MOVEVALUES(strafeplayer);
 119         int    keys                          = STAT(PRESSED_KEYS);
 120         int    keys_fwd;
 121         float  wishangle                     = 0;
 122
 123         // HUD
 124         int    mode                          = autocvar_hud_panel_strafehud_mode >= 0 && autocvar_hud_panel_strafehud_mode <= 1 ? autocvar_hud_panel_strafehud_mode : 0;
 125         float  speed_conversion_factor       = GetSpeedUnitFactor(autocvar_hud_panel_strafehud_unit);
 126         float  length_conversion_factor      = GetLengthUnitFactor(autocvar_hud_panel_strafehud_unit);
 127         string speed_unit                    = GetSpeedUnit(autocvar_hud_panel_strafehud_unit);
 128         string length_unit                   = GetLengthUnit(autocvar_hud_panel_strafehud_unit);
 129         int    length_decimals               = autocvar_hud_panel_strafehud_unit >= 3 && autocvar_hud_panel_strafehud_unit <= 5 ? 6 : 2; // use more decimals when displaying km or miles
 130         float  antiflicker_angle             = bound(0, autocvar_hud_panel_strafehud_antiflicker_angle, 180);
 131         float  antiflicker_speed             = max(0, autocvar_hud_panel_strafehud_antiflicker_speed);
 132         float  minspeed;
 133         float  shift_offset                  = 0;
 134         bool   straight_overturn             = false;
 135         bool   immobile                      = speed <= (swimming ? antiflicker_speed : 0);
 136         float  hudangle;
 137         float  neutral_offset;
 138         float  neutral_width;
 139         vector currentangle_color            = autocvar_hud_panel_strafehud_angle_neutral_color;
 140         float  currentangle_offset;
 141         vector currentangle_size             = '0 0 0';
 142         float  bestangle;
 143         float  odd_bestangle;
 144         bool   bestangle_anywhere            = false;
 145         float  bestangle_offset;
 146         float  switch_bestangle_offset;
 147         bool   odd_angles                    = false;
 148         float  odd_bestangle_offset          = 0;
 149         float  switch_odd_bestangle_offset   = 0;
 150         float  bestangle_width;
 151         float  accelzone_left_offset;
 152         float  accelzone_right_offset;
 153         float  accelzone_width;
 154         float  overturn_offset;
 155         float  overturn_width;
 156         float  slickdetector_height;
 157         vector direction_size_vertical       = '0 0 0';
 158         vector direction_size_horizontal     = '0 0 0';
 159         float  range_minangle;
 160
 161         // determine whether the player is pressing forwards or backwards keys
 162         if(islocal) // if entity is local player
 163         {
 164             if(movement.x > 0)
 165             {
 166                 keys_fwd = 1;
 167             }
 168             else if(movement.x < 0)
 169             {
 170                 keys_fwd = -1;
 171             }
 172             else
 173             {
 174                 keys_fwd = 0;
 175             }
 176         }
 177         else // alternatively determine direction by querying pressed keys
 178         {
 179             if((keys & KEY_FORWARD) && !(keys & KEY_BACKWARD))
 180             {
 181                 keys_fwd = 1;
 182             }
 183             else if(!(keys & KEY_FORWARD) && (keys & KEY_BACKWARD))
 184             {
 185                 keys_fwd = -1;
 186             }
 187             else
 188             {
 189                 keys_fwd = 0;
 190             }
 191         }
 192
 193         // determine player wishdir
 194         if(islocal) // if entity is local player
 195         {
 196             if(movement.x == 0)
 197             {
 198                 if(movement.y < 0)
 199                 {
 200                     wishangle = -90;
 201                 }
 202                 else if(movement.y > 0)
 203                 {
 204                     wishangle = 90;
 205                 }
 206                 else
 207                 {
 208                     wishangle = 0;
 209                 }
 210             }
 211             else
 212             {
 213                 if(movement.y == 0)
 214                 {
 215                     wishangle = 0;
 216                 }
 217                 else
 218                 {
 219                     wishangle = RAD2DEG * atan2(movement.y, movement.x);
 220                     // wrap the wish angle if it exceeds ±90°
 221                     if(fabs(wishangle) > 90)
 222                     {
 223                         if(wishangle < 0) wishangle += 180;
 224                         else wishangle -= 180;
 225                         wishangle = -wishangle;
 226                     }
 227                 }
 228             }
 229         }
 230         else // alternatively calculate wishdir by querying pressed keys
 231         {
 232             if(keys & KEY_FORWARD || keys & KEY_BACKWARD)
 233             {
 234                 wishangle = 45;
 235             }
 236             else
 237             {
 238                 wishangle = 90;
 239             }
 240             if(keys & KEY_LEFT)
 241             {
 242                 wishangle *= -1;
 243             }
 244             else if(!(keys & KEY_RIGHT))
 245             {
 246                 wishangle = 0; // wraps at 180°
 247             }
 248         }
 249
 250         strafekeys = fabs(wishangle) == 90;
 251
 252         // determine minimum required angle to display full strafe range
 253         range_minangle = fabs(wishangle) % 90; // maximum range is 90 degree
 254         if(range_minangle > 45) // minimum angle range is 45
 255         {
 256             range_minangle = 45 - fabs(wishangle) % 45;
 257         }
 258         range_minangle = 90 - range_minangle; // calculate value which is never >90 or <45
 259         range_minangle *= 2; // multiply to accommodate for both sides of the hud
 260
 261         if(autocvar_hud_panel_strafehud_range == 0)
 262         {
 263             if(autocvar__hud_configure)
 264             {
 265                 hudangle = 90;
 266             }
 267             else
 268             {
 269                 hudangle = range_minangle; // use minimum angle required if dynamically setting hud angle
 270             }
 271         }
 272         else
 273         {
 274             hudangle = bound(0, fabs(autocvar_hud_panel_strafehud_range), 360); // limit HUD range to 360 degrees, higher values don't make sense
 275         }
 276
 277         // detect air strafe turning
 278         if(onground != state_onground)
 279         {
 280             state_onground_time = time;
 281         }
 282         state_onground = onground;
 283
 284         if(strafekeys != state_strafekeys)
 285         {
 286             state_strafekeys_time = time;
 287         }
 288         state_strafekeys = strafekeys;
 289
 290         if((keys & KEY_FORWARD) || (keys & KEY_BACKWARD) || swimming || autocvar__hud_configure)
 291         {
 292             turn = false;
 293         }
 294         else if(onground)
 295         {
 296             if((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_ground) // timeout for strafe jumping in general
 297             {
 298                 turn = false;
 299             }
 300         }
 301         else // air strafe only
 302         {
 303             if(strafekeys)
 304             {
 305                 if(((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_air) || (keys & KEY_JUMP)) // timeout for slick ramps
 306                 {
 307                     turn = true; // CPMA turning
 308                     turnangle = wishangle;
 309                 }
 310             }
 311             else if((time - state_strafekeys_time) >= autocvar_hud_panel_strafehud_timeout_turn) // timeout for jumping with strafe keys only
 312             {
 313                 turn = false;
 314             }
 315         }
 316         if(turn)
 317         {
 318             maxspeed = PHYS_MAXAIRSTRAFESPEED(strafeplayer); // no modifiers here because they don't affect air strafing
 319             wishangle = turnangle;
 320         }
 321
 322         minspeed = autocvar_hud_panel_strafehud_switch_minspeed < 0 ? maxspeed + antiflicker_speed : autocvar_hud_panel_strafehud_switch_minspeed;
 323
 324         // get current strafing angle ranging from -180° to +180°
 325         if(!autocvar__hud_configure)
 326         {
 327             if(speed > 0)
 328             {
 329                 // calculate view angle relative to the players current velocity direction
 330                 angle = vel_angle - view_angle;
 331
 332                 // if the angle goes above 180° or below -180° wrap it to the opposite side since we want the interior angle
 333                 if (angle > 180) angle -= 360;
 334                 else if(angle < -180) angle += 360;
 335
 336                 // determine whether the player is strafing forwards or backwards
 337                 // if the player isn't strafe turning use forwards/backwards keys to determine direction
 338                 if(!strafekeys)
 339                 {
 340                     if(keys_fwd > 0)
 341                     {
 342                         state_fwd = true;
 343                     }
 344                     else if(keys_fwd < 0)
 345                     {
 346                         state_fwd = false;
 347                     }
 348                     else
 349                     {
 350                         state_fwd = fabs(angle) <= 90;
 351                     }
 352                 }
 353                 // otherwise determine by examining the strafe angle
 354                 else
 355                 {
 356                     if(wishangle < 0) // detect direction using wishangle since the direction is not yet set
 357                     {
 358                         state_fwd = angle <= -wishangle;
 359                     }
 360                     else
 361                     {
 362                         state_fwd = angle >= -wishangle;
 363                     }
 364                 }
 365
 366                 if(state_fwd_prev != state_fwd)
 367                 {
 368                     state_fwd_time = time;
 369                 }
 370                 state_fwd_prev = state_fwd;
 371
 372                 if((time - state_fwd_time) >= autocvar_hud_panel_strafehud_timeout_direction || speed < maxspeed || (strafekeys && mode == 0)) // timeout when changing between forwards and backwards movement
 373                 {
 374                     fwd = state_fwd;
 375                 }
 376
 377                 // shift the strafe angle by 180° when strafing backwards
 378                 if(!fwd)
 379                 {
 380                     if(angle < 0) angle += 180;
 381                     else angle -= 180;
 382                 }
 383
 384                 // don't make the angle indicator switch side too much at ±180° if anti flicker is turned on
 385                 if(angle > (180 - antiflicker_angle) || angle < (-180 + antiflicker_angle))
 386                 {
 387                     straight_overturn = true;
 388                 }
 389             }
 390             else
 391             {
 392                 angle = 0;
 393             }
 394         }
 395         else // simulate turning for HUD setup
 396         {
 397             fwd = true;
 398             if(autocvar__hud_panel_strafehud_demo && ((time - demo_time) >= .025))
 399             {
 400                 demo_time = time;
 401                 demo_angle += demo_direction;
 402                 if(fabs(demo_angle) >= 55)
 403                 {
 404                     demo_direction = -demo_direction;
 405                 }
 406             }
 407             angle = demo_angle;
 408             wishangle = 45 * (demo_angle > 0 ? 1 : -1);
 409         }
 410
 411         // invert the wish angle when strafing backwards
 412         if(!fwd)
 413         {
 414             wishangle = -wishangle;
 415         }
 416
 417         // flip angles if v_flipped is enabled
 418         if(autocvar_v_flipped)
 419         {
 420             angle = -angle;
 421             wishangle = -wishangle;
 422         }
 423
 424         // determine whether the player is strafing left or right
 425         if(wishangle != 0)
 426         {
 427             direction = wishangle > 0 ? 1 : -1;
 428         }
 429         else
 430         {
 431             direction = (angle > antiflicker_angle && angle < (180 - antiflicker_angle)) ? 1 : (angle < -antiflicker_angle && angle > (-180 + antiflicker_angle)) ? -1 : 0;
 432         }
 433
 434         // best angle to strafe at
 435         bestangle = (speed > maxspeed ? acos(maxspeed / speed) : 0) * RAD2DEG * (direction < 0 ? -1 : 1);
 436         odd_bestangle = -bestangle - wishangle;
 437         bestangle -= wishangle;
 438
 439         // various offsets and size calculations of hud indicator elements
 440         // how much is hidden by the current hud angle
 441         hidden_width = (360 - hudangle) / hudangle * panel_size.x;
 442         // current angle
 443         currentangle_size.x = max(panel_size.x * autocvar_hud_panel_strafehud_angle_width, 1);
 444         if(mode == 0)
 445         {
 446             currentangle_offset = angle/hudangle * panel_size.x;
 447         }
 448         else
 449         {
 450             currentangle_offset = bound(-hudangle/2, angle, hudangle/2)/hudangle * panel_size.x + panel_size.x/2;
 451         }
 452         currentangle_size.y = max(panel_size.y * min(autocvar_hud_panel_strafehud_angle_height, 2), 1);
 453         // best strafe acceleration angle
 454         bestangle_offset        =  bestangle/hudangle * panel_size.x + panel_size.x/2;
 455         switch_bestangle_offset = -bestangle/hudangle * panel_size.x + panel_size.x/2;
 456         bestangle_width = max(panel_size.x * autocvar_hud_panel_strafehud_switch_width, 1);
 457
 458         if(((angle > -wishangle && direction < 0) || (angle < -wishangle && direction > 0)) && (direction != 0))
 459         {
 460             odd_angles = true;
 461             odd_bestangle_offset = odd_bestangle/hudangle * panel_size.x + panel_size.x/2;
 462             switch_odd_bestangle_offset = (odd_bestangle+bestangle*2)/hudangle * panel_size.x + panel_size.x/2;
 463         }
 464         // direction indicator
 465         direction_size_vertical.x = max(panel_size.y * min(autocvar_hud_panel_strafehud_direction_width, .5), 1);
 466         direction_size_vertical.y = panel_size.y;
 467         direction_size_horizontal.x = max(panel_size.x * min(autocvar_hud_panel_strafehud_direction_length, .5), direction_size_vertical.x);
 468         direction_size_horizontal.y = direction_size_vertical.x;
 469         // overturn
 470         overturn_width = 180/hudangle * panel_size.x;
 471
 472         // the neutral zone fills the whole strafe bar
 473         if(immobile)
 474         {
 475             // draw neutral zone
 476             if(panel_size.x > 0 && panel_size.y > 0 && autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha > 0)
 477             {
 478                 switch(autocvar_hud_panel_strafehud_style)
 479                 {
 480                     default:
 481                     case 0:
 482                         drawfill(panel_pos, panel_size, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 483                         break;
 484
 485                     case 1:
 486                         HUD_Panel_DrawProgressBar(panel_pos, panel_size, "progressbar", 1, 0, 0, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 487                 }
 488             }
 489         }
 490         else
 491         {
 492             // calculate various zones of the strafe-o-meter
 493             accelzone_width = overturn_offset = (90 - fabs(bestangle + wishangle))/hudangle * panel_size.x;
 494             accelzone_right_offset = 0;
 495             accelzone_left_offset = overturn_offset + overturn_width;
 496             neutral_width = 360/hudangle * panel_size.x - accelzone_width*2 - overturn_width;
 497             neutral_offset = direction < 0 ? accelzone_left_offset + accelzone_width : -neutral_width;
 498
 499             // remove switch indicator width from offset
 500             if(direction < 0)
 501             {
 502                 bestangle_offset -= bestangle_width;
 503                 switch_odd_bestangle_offset -= bestangle_width;
 504             }
 505             else
 506             {
 507                 switch_bestangle_offset -= bestangle_width;
 508                 odd_bestangle_offset -= bestangle_width;
 509             }
 510
 511             // shift hud if operating in view angle centered mode
 512             if(mode == 0)
 513             {
 514                 shift_offset = -currentangle_offset;
 515                 bestangle_offset += shift_offset;
 516                 switch_bestangle_offset += shift_offset;
 517                 odd_bestangle_offset += shift_offset;
 518                 switch_odd_bestangle_offset += shift_offset;
 519             }
 520             if(direction < 0) shift_offset += -360/hudangle * panel_size.x;
 521             // calculate how far off-center the strafe zones currently are
 522             shift_offset += (panel_size.x + neutral_width)/2 - wishangle/hudangle * panel_size.x;
 523             // shift strafe zones into correct place
 524             neutral_offset += shift_offset;
 525             accelzone_left_offset += shift_offset;
 526             accelzone_right_offset += shift_offset;
 527             overturn_offset += shift_offset;
 528
 529             // draw left acceleration zone
 530             HUD_Panel_DrawStrafeHUD(accelzone_left_offset, accelzone_width, autocvar_hud_panel_strafehud_bar_accel_color, autocvar_hud_panel_strafehud_bar_accel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 1);
 531
 532             // draw right acceleration zone
 533             HUD_Panel_DrawStrafeHUD(accelzone_right_offset, accelzone_width, autocvar_hud_panel_strafehud_bar_accel_color, autocvar_hud_panel_strafehud_bar_accel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 2);
 534
 535             // draw overturn zone
 536             HUD_Panel_DrawStrafeHUD(overturn_offset, overturn_width, autocvar_hud_panel_strafehud_bar_overturn_color, autocvar_hud_panel_strafehud_bar_overturn_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 3);
 537
 538             // draw neutral zone
 539             HUD_Panel_DrawStrafeHUD(neutral_offset, neutral_width, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 0);
 540
 541             if(direction != 0 && direction_size_vertical.x > 0 && autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha > 0)
 542             {
 543                 bool indicator_direction = direction < 0;
 544                 // invert left/right when strafing backwards or when strafing towards the opposite side indicated by the direction variable
 545                 // if both conditions are true then it's inverted twice hence not inverted at all
 546                 if(!fwd != odd_angles)
 547                 {
 548                     indicator_direction = !indicator_direction;
 549                 }
 550                 // draw the direction indicator caps at the sides of the hud
 551                 // vertical line
 552                 if(direction_size_vertical.y > 0) drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x), direction_size_vertical, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 553                 // top horizontal line
 554                 drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x - direction_size_horizontal.x + direction_size_vertical.x) - eY * direction_size_horizontal.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 555                 // bottom horizontal line
 556                 drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x - direction_size_horizontal.x + direction_size_vertical.x) + eY * panel_size.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 557             }
 558
 559             if(speed >= minspeed) // only draw indicators if minspeed is reached
 560             {
 561                 // draw best angles for acceleration
 562                 float offset = !odd_angles ? bestangle_offset : odd_bestangle_offset;
 563                 float switch_offset = !odd_angles ? switch_bestangle_offset : switch_odd_bestangle_offset;
 564                 // both indicators are inactive if no direction can be determined
 565                 vector switch_color = direction != 0 ? autocvar_hud_panel_strafehud_switch_active_color : autocvar_hud_panel_strafehud_switch_inactive_color;
 566                 float switch_alpha = direction != 0 ? autocvar_hud_panel_strafehud_switch_active_alpha : autocvar_hud_panel_strafehud_switch_inactive_alpha;
 567                 // draw the switch indicators
 568                 HUD_Panel_DrawStrafeHUD(switch_offset, bestangle_width, autocvar_hud_panel_strafehud_switch_inactive_color, autocvar_hud_panel_strafehud_switch_inactive_alpha * panel_fg_alpha, 0, 0);
 569                 HUD_Panel_DrawStrafeHUD(offset, bestangle_width, switch_color, switch_alpha * panel_fg_alpha, 0, 0);
 570             }
 571         }
 572
 573         // experimental: slick detector
 574         slickdetector_height = panel_size.y * bound(0, autocvar_hud_panel_strafehud_slickdetector_height, 0.5);
 575         if(autocvar_hud_panel_strafehud_slickdetector_range > 0 && autocvar_hud_panel_strafehud_slickdetector_alpha > 0 && slickdetector_height > 0 && panel_size.x > 0) // dunno if slick detection works in spectate
 576         {
 577             float slicksteps = 90 / pow(2, bound(0, autocvar_hud_panel_strafehud_slickdetector_granularity, 4));
 578             bool slickdetected = false;
 579
 580             slickdetected = IS_ONSLICK(strafeplayer); // don't need to traceline if already touching slick
 581
 582             // traceline into every direction
 583             trace_dphitq3surfaceflags = 0;
 584             for(float i = 0; i < 360 && !slickdetected; i += slicksteps)
 585             {
 586                 vector slickoffset;
 587                 float slickrotate;
 588                 slickoffset.z = -cos(i * DEG2RAD) * autocvar_hud_panel_strafehud_slickdetector_range;
 589                 slickrotate = sin(i * DEG2RAD) * autocvar_hud_panel_strafehud_slickdetector_range;
 590                 if(i != 0 && i != 180)
 591                 {
 592                     for(float j = 0; j < 180 && !slickdetected; j += slicksteps)
 593                     {
 594                         slickoffset.x = sin(j * DEG2RAD) * slickrotate;
 595                         slickoffset.y = cos(j * DEG2RAD) * slickrotate;
 596
 597                         traceline(strafeplayer.origin, strafeplayer.origin + slickoffset, MOVE_WORLDONLY, NULL);
 598                         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK) slickdetected = true;
 599                     }
 600                 }
 601                 else
 602                 {
 603                     slickoffset.x = slickoffset.y = 0;
 604                     traceline(strafeplayer.origin, strafeplayer.origin + slickoffset, MOVE_WORLDONLY, NULL);
 605                     if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK) slickdetected = true;
 606                 }
 607             }
 608
 609             // if a traceline hit a slick surface
 610             if(slickdetected)
 611             {
 612                 vector slickdetector_size = panel_size;
 613                 slickdetector_size.y = slickdetector_height;
 614                 // top horizontal line
 615                 drawfill(panel_pos - eY * slickdetector_size.y, slickdetector_size, autocvar_hud_panel_strafehud_slickdetector_color, autocvar_hud_panel_strafehud_slickdetector_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 616                 // bottom horizontal line
 617                 drawfill(panel_pos + eY * panel_size.y, slickdetector_size, autocvar_hud_panel_strafehud_slickdetector_color, autocvar_hud_panel_strafehud_slickdetector_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 618             }
 619         }
 620
 621         draw_beginBoldFont();
 622         // show speed when crossing the start trigger
 623         if(autocvar_hud_panel_strafehud_startspeed_fade > 0)
 624         {
 625             float text_alpha = 0;
 626             if((race_nextcheckpoint == 1) || (race_checkpoint == 254 && race_nextcheckpoint == 255)) // check if the start trigger was hit (will also trigger if the finish trigger was hit if those have the same ID)
 627             {
 628                 if(starttime != race_checkpointtime)
 629                 {
 630                     starttime = race_checkpointtime;
 631                     startspeed = speed;
 632                 }
 633             }
 634             if(startspeed >= 0)
 635             {
 636                 text_alpha = cos(((time - starttime) / autocvar_hud_panel_strafehud_startspeed_fade) * 90 * DEG2RAD); // fade non-linear like the physics panel does
 637                 if((time - starttime) > autocvar_hud_panel_strafehud_startspeed_fade)
 638                 {
 639                     startspeed = -1;
 640                 }
 641             }
 642             if(startspeed >= 0 && text_alpha > 0 && autocvar_hud_panel_strafehud_startspeed_size > 0)
 643             {
 644                 vector startspeed_size = panel_size;
 645                 startspeed_size.y = panel_size.y * min(autocvar_hud_panel_strafehud_startspeed_size, 5);
 646                 drawstring_aspect(panel_pos + eY * panel_size.y, strcat(ftos_decimals(startspeed * speed_conversion_factor, 2), autocvar_hud_panel_strafehud_unit_show ? speed_unit : ""), startspeed_size, autocvar_hud_panel_strafehud_startspeed_color, text_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 647             }
 648         }
 649         else
 650         {
 651             starttime = 0;
 652             startspeed = -1;
 653         }
 654
 655         // experimental: show height achieved by a single jump (doesn't work in low gravity and may not be 100% accurate)
 656         if(autocvar_hud_panel_strafehud_jumpheight_fade > 0)
 657         {
 658             float text_alpha = 0;
 659             float jumpheight_min = max(autocvar_hud_panel_strafehud_jumpheight_min, 0);
 660             float jumpheight_current = strafeplayer.origin.z;
 661             float jumpspeed_current = strafeplayer.velocity.z;
 662             if(jumpspeed_prev <= jumpspeed_current || jumpheight_prev > jumpheight_current || IS_ONGROUND(strafeplayer) || swimming || IS_DEAD(strafeplayer) || spectating)
 663             {
 664                 // tries to catch kill and spectate but those are not reliable, should just hook to kill/spectate/teleport and reset jump height there
 665                 jumprestart = true;
 666             }
 667             else
 668             {
 669                 if(jumpheight < 0 || jumprestart)
 670                 {
 671                     jumprestart = false;
 672                     jumpheight = 0;
 673                 }
 674                 else
 675                 {
 676                     jumpheight += jumpheight_current - jumpheight_prev;
 677                 }
 678                 if((jumpheight * length_conversion_factor) > jumpheight_min && jumpheight > jumpheight_persistent)
 679                 {
 680                     jumptime = time;
 681                     jumpheight_persistent = jumpheight;
 682                 }
 683             }
 684             jumpheight_prev = jumpheight_current;
 685             jumpspeed_prev = jumpspeed_current;
 686             if(jumpheight_persistent > 0)
 687             {
 688                 text_alpha = cos(((time - jumptime) / autocvar_hud_panel_strafehud_jumpheight_fade) * 90 * DEG2RAD); // fade non-linear like the physics panel does
 689                 if((time - jumptime) > autocvar_hud_panel_strafehud_jumpheight_fade)
 690                 {
 691                     jumpheight_persistent = -1;
 692                 }
 693             }
 694             if(jumpheight_persistent > 0 && text_alpha > 0 && autocvar_hud_panel_strafehud_jumpheight_size > 0)
 695             {
 696                 vector jumpheight_size = panel_size;
 697                 jumpheight_size.y = panel_size.y * min(autocvar_hud_panel_strafehud_jumpheight_size, 5);
 698                 drawstring_aspect(panel_pos - eY * jumpheight_size.y, strcat(ftos_decimals(jumpheight_persistent * length_conversion_factor, length_decimals), autocvar_hud_panel_strafehud_unit_show ? length_unit : ""), jumpheight_size, autocvar_hud_panel_strafehud_jumpheight_color, text_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 699             }
 700         }
 701         else
 702         {
 703             jumpheight_prev = jumpspeed_prev = 0;
 704             jumpheight = jumpheight_persistent = -1;
 705         }
 706         draw_endBoldFont();
 707
 708         if(speed < (maxspeed + antiflicker_speed) && !immobile)
 709         {
 710             bestangle_anywhere = true; // moving forward should suffice to gain speed
 711         }
 712
 713         // draw the actual strafe angle
 714         if(!bestangle_anywhere && !immobile) // player gains speed with strafing
 715         {
 716             if((direction > 0 && (angle >= bestangle || angle <= -(bestangle + wishangle*2))) ||
 717                (direction < 0 && (angle <= bestangle || angle >= -(bestangle + wishangle*2))))
 718             currentangle_color = autocvar_hud_panel_strafehud_angle_accel_color;
 719         }
 720
 721         if(fabs(angle + wishangle) > 90) // player is overturning
 722         {
 723             currentangle_color = autocvar_hud_panel_strafehud_angle_overturn_color;
 724         }
 725         else if(bestangle_anywhere) // player gains speed without strafing
 726         {
 727             currentangle_color = autocvar_hud_panel_strafehud_angle_accel_color;
 728         }
 729
 730         if(mode == 0 || straight_overturn)
 731         {
 732             currentangle_offset = panel_size.x/2;
 733         }
 734
 735         if(autocvar_hud_panel_strafehud_style == 2 && !immobile)
 736         {
 737             float moveangle = angle + wishangle;
 738             float strafeangle = (bestangle + wishangle) * (direction < 0 ? -1 : 1);
 739             float strafe_ratio = 0;
 740             if(fabs(moveangle) > 90)
 741             {
 742                 strafe_ratio = -((fabs(moveangle) - 90) / 90);
 743                 if(strafe_ratio < -1) strafe_ratio = -2 - strafe_ratio;
 744             }
 745             else
 746             {
 747                 if(moveangle >= strafeangle)
 748                 {
 749                     strafe_ratio = 1 - (moveangle - strafeangle) / (90 - strafeangle);
 750                 }
 751                 else if(moveangle <= -strafeangle)
 752                 {
 753                     strafe_ratio = 1 - (moveangle + strafeangle) / (-90 + strafeangle);
 754                 }
 755             }
 756             if(strafe_ratio < 0)
 757             {
 758                 currentangle_color = StrafeHUD_mixColors(autocvar_hud_panel_strafehud_angle_neutral_color, autocvar_hud_panel_strafehud_angle_overturn_color, -strafe_ratio);
 759             }
 760             else
 761             {
 762                 currentangle_color = StrafeHUD_mixColors(autocvar_hud_panel_strafehud_angle_neutral_color, autocvar_hud_panel_strafehud_angle_accel_color, strafe_ratio);
 763             }
 764         }
 765
 766         if(currentangle_size.x > 0 && currentangle_size.y > 0 && autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha > 0)
 767         {
 768             drawfill(panel_pos - eY * ((currentangle_size.y - panel_size.y) / 2) + eX * (currentangle_offset - currentangle_size.x/2), currentangle_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 769         }
 770     }
 771 }
 772
 773 // functions to make hud elements align perfectly in the hud area
 774 void HUD_Panel_DrawStrafeHUD(float offset, float width, vector color, float alpha, int type, int gradientType)
 775 {
 776     float mirror_offset, mirror_width;
 777     vector size = panel_size;
 778     vector mirror_size = panel_size;
 779     int gradient_start;
 780     float gradient_offset, gradient_mirror_offset;
 781     float overflow_width = 0, overflow_mirror_width = 0;
 782
 783     float original_width = width;
 784
 785     if(alpha <= 0 && type != 2 || width <= 0) return;
 786
 787     if(type == 2 && gradientType == 0) type = 0;
 788
 789     if(offset < 0)
 790     {
 791         mirror_width = min(fabs(offset), width);
 792         mirror_offset = panel_size.x + hidden_width - fabs(offset);
 793         width += offset;
 794         offset = 0;
 795     }
 796     else
 797     {
 798         mirror_width = min(offset + width - panel_size.x - hidden_width, width);
 799         mirror_offset = max(offset - panel_size.x - hidden_width, 0);
 800     }
 801
 802     if(width < 0) width = 0;
 803     if((offset + width) > panel_size.x)
 804     {
 805         overflow_width = (offset + width) - panel_size.x;
 806         width = panel_size.x - offset;
 807     }
 808     if(mirror_offset < 0)
 809     {
 810         mirror_width += mirror_offset;
 811         mirror_offset = 0;
 812     }
 813
 814     if(mirror_width < 0) mirror_width = 0;
 815     if((mirror_offset + mirror_width) > panel_size.x)
 816     {
 817         overflow_mirror_width = (mirror_offset + mirror_width) - panel_size.x;
 818         mirror_width = panel_size.x - mirror_offset;
 819     }
 820
 821     if(direction < 0) // swap mirror and non-mirror values if direction points left
 822     {
 823         offset += mirror_offset;
 824         mirror_offset = offset - mirror_offset;
 825         offset -= mirror_offset;
 826
 827         width += mirror_width;
 828         mirror_width = width - mirror_width;
 829         width -= mirror_width;
 830
 831         overflow_width += overflow_mirror_width;
 832         overflow_mirror_width = overflow_width - overflow_mirror_width;
 833         overflow_width -= overflow_mirror_width;
 834     }
 835
 836     size.x = width;
 837     mirror_size.x = mirror_width;
 838
 839     switch(type)
 840     {
 841         default:
 842         case 0: // no styling (drawfill)
 843             if(mirror_size.x > 0 && mirror_size.y > 0) drawfill(panel_pos + eX * mirror_offset, mirror_size, color, alpha, DRAWFLAG_NORMAL);
 844             if(size.x > 0 && size.y > 0) drawfill(panel_pos + eX * offset, size, color, alpha, DRAWFLAG_NORMAL);
 845             break;
 846
 847         case 1: // progress bar style
 848             if(mirror_size.x > 0 && mirror_size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * mirror_offset, mirror_size, "progressbar", 1, 0, 0, color, alpha, DRAWFLAG_NORMAL);
 849             if(size.x > 0 && size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * offset, size, "progressbar", 1, 0, 0, color, alpha, DRAWFLAG_NORMAL);
 850             break;
 851
 852         case 2: // gradient style (types: 1 = left, 2 = right, 3 = both)
 853             // determine whether the gradient starts in the mirrored or the non-mirrored area
 854             if(offset == 0 && mirror_offset == 0) gradient_start = width > mirror_width ? 2 : 1;
 855             else if(offset == 0) gradient_start = 2;
 856             else if(mirror_offset == 0) gradient_start = 1;
 857             else gradient_start = 0;
 858
 859             switch(gradient_start){
 860                 default:
 861                 case 0: // no offset required
 862                     gradient_offset = gradient_mirror_offset = 0;
 863                     break;
 864                 case 1: // offset starts in non-mirrored area, mirrored area requires offset
 865                     gradient_offset = 0;
 866                     gradient_mirror_offset = original_width - (mirror_width + overflow_mirror_width);
 867                     break;
 868                 case 2: // offset starts in mirrored area, non-mirrored area requires offset
 869                     gradient_offset = original_width - (width + overflow_width);
 870                     gradient_mirror_offset = 0;
 871             }
 872
 873             StrafeHUD_drawGradient(color, autocvar_hud_panel_strafehud_bar_neutral_color, mirror_size, original_width, mirror_offset, alpha, gradient_mirror_offset, gradientType);
 874             StrafeHUD_drawGradient(color, autocvar_hud_panel_strafehud_bar_neutral_color, size, original_width, offset, alpha, gradient_offset, gradientType);
 875     }
 876 }
 877
 878 vector StrafeHUD_mixColors(vector color1, vector color2, float ratio)
 879 {
 880     vector mixedColor;
 881     if(ratio <= 0) return color1;
 882     if(ratio >= 1) return color2;
 883     mixedColor.x = color1.x + (color2.x - color1.x) * ratio;
 884     mixedColor.y = color1.y + (color2.y - color1.y) * ratio;
 885     mixedColor.z = color1.z + (color2.z - color1.z) * ratio;
 886     return mixedColor;
 887 }
 888
 889 void StrafeHUD_drawGradient(vector color1, vector color2, vector size, float original_width, float offset, float alpha, float gradientOffset, int gradientType)
 890 {
 891     float color_ratio, alpha1, alpha2;
 892     vector gradient_size = size;
 893     alpha1 = bound(0, alpha, 1);
 894     alpha2 = bound(0, autocvar_hud_panel_strafehud_bar_neutral_alpha, 1);
 895     if((alpha1+alpha2) == 0) return;
 896     color_ratio = alpha1/(alpha1+alpha2);
 897     for(int i = 0; i < size.x; ++i)
 898     {
 899         float ratio, alpha_ratio, combine_ratio1, combine_ratio2;
 900         gradient_size.x = size.x - i < 1 ? size.x - i : 1;
 901         ratio = (i + gradientOffset) / original_width * (gradientType == 3 ? 2 : 1);
 902         if(ratio > 1) ratio = 2 - ratio;
 903         if(gradientType != 2) ratio = 1 - ratio;
 904         alpha_ratio = alpha1 - (alpha1 - alpha2) * ratio;
 905         combine_ratio1 = ratio*(1-color_ratio);
 906         combine_ratio2 = (1-ratio)*color_ratio;
 907         ratio = (combine_ratio1 + combine_ratio2) == 0 ? 1 : combine_ratio1/(combine_ratio1 + combine_ratio2);
 908         if(alpha_ratio > 0) drawfill(panel_pos + eX * (offset + i), gradient_size, StrafeHUD_mixColors(color1, color2, ratio), alpha_ratio, DRAWFLAG_NORMAL);
 909     }
 910 }
 911
 912 // length unit conversion (km and miles are only included to match the GetSpeedUnit* functions)
 913 float GetLengthUnitFactor(int length_unit)
 914 {
 915         switch(length_unit)
 916         {
 917                 default:
 918                 case 1: return 1.0;
 919                 case 2: return 0.0254;
 920                 case 3: return 0.0254 * 0.001;
 921                 case 4: return 0.0254 * 0.001 * 0.6213711922;
 922                 case 5: return 0.0254 * 0.001 * 0.5399568035;
 923         }
 924 }
 925
 926 string GetLengthUnit(int length_unit)
 927 {
 928         switch(length_unit)
 929         {
 930                 // translator-friendly strings without the initial space
 931                 default:
 932                 case 1: return strcat(" ", _("qu"));
 933                 case 2: return strcat(" ", _("m"));
 934                 case 3: return strcat(" ", _("km"));
 935                 case 4: return strcat(" ", _("mi"));
 936                 case 5: return strcat(" ", _("nmi"));
 937         }
 938 }