qcsrc/client/hud/panel/strafehud.qc

   1 // Author: Juhu
   2
   3 #include "strafehud.qh"
   4
   5 #include <client/draw.qh>
   6 #include <client/hud/panel/racetimer.qh>
   7 #include <client/resources.qh>
   8 #include <client/view.qh>
   9 #include <common/animdecide.qh>
  10 #include <common/ent_cs.qh>
  11 #include <common/mapinfo.qh>
  12 #include <common/physics/movetypes/movetypes.qh>
  13 #include <common/physics/player.qh>
  14 #include <lib/csqcmodel/cl_player.qh>
  15
  16 // StrafeHUD (#25)
  17
  18 void HUD_StrafeHUD_Export(int fh)
  19 {
  20     // allow saving cvars that aesthetically change the panel into hud skin files
  21 }
  22
  23 float hidden_width;
  24 int direction;
  25 float demo_angle = -37;
  26 float demo_direction = 1;
  27 float demo_time = 0;
  28 bool state_onground = false;
  29 float state_onground_time = 0;
  30 bool state_strafekeys = false;
  31 float state_strafekeys_time = 0;
  32 bool turn = false;
  33 float turnangle;
  34 float turnspeed;
  35 bool fwd = true;
  36 float starttime = 0;
  37 float startspeed = -1;
  38 float jumptime = 0;
  39 float jumpheight = -1;
  40 float jumpheight_persistent = -1;
  41 float jumpheight_prev = 0;
  42 float jumpspeed_prev = 0;
  43 bool  jumprestart = true;
  44
  45 // provide basic panel cvars to old clients
  46 // TODO remove them after a future release (0.8.2+)
  47 noref string autocvar_hud_panel_strafehud_pos = "0.320000 0.570000";
  48 noref string autocvar_hud_panel_strafehud_size = "0.360000 0.020000";
  49 noref string autocvar_hud_panel_strafehud_bg = "0";
  50 noref string autocvar_hud_panel_strafehud_bg_color = "";
  51 noref string autocvar_hud_panel_strafehud_bg_color_team = "";
  52 noref string autocvar_hud_panel_strafehud_bg_alpha = "0.7";
  53 noref string autocvar_hud_panel_strafehud_bg_border = "";
  54 noref string autocvar_hud_panel_strafehud_bg_padding = "";
  55
  56 void HUD_StrafeHUD()
  57 {
  58     entity strafeplayer;
  59     bool islocal;
  60
  61     // generic hud routines
  62     if(!autocvar__hud_configure)
  63     {
  64         if(!autocvar_hud_panel_strafehud ||
  65            (spectatee_status == -1 && (autocvar_hud_panel_strafehud == 1 || autocvar_hud_panel_strafehud == 3)) ||
  66            (autocvar_hud_panel_strafehud == 3 && !MUTATOR_CALLHOOK(HUD_StrafeHUD_showoptional))) return;
  67     }
  68
  69     HUD_Panel_LoadCvars();
  70
  71     if(autocvar_hud_panel_strafehud_dynamichud)
  72     {
  73         HUD_Scale_Enable();
  74     }
  75     else
  76     {
  77         HUD_Scale_Disable();
  78     }
  79
  80     HUD_Panel_DrawBg();
  81
  82     if(panel_bg_padding)
  83     {
  84         panel_pos  += '1 1 0' * panel_bg_padding;
  85         panel_size -= '2 2 0' * panel_bg_padding;
  86     }
  87
  88     // find out whether the local csqcmodel entity is valid
  89     if(spectatee_status > 0 || isdemo())
  90     {
  91         islocal = false;
  92         strafeplayer = CSQCModel_server2csqc(player_localentnum - 1);
  93     }
  94     else
  95     {
  96         islocal = true;
  97         strafeplayer = csqcplayer;
  98     }
  99
 100     // draw strafehud
 101     if(csqcplayer && strafeplayer)
 102     {
 103         // physics
 104         bool   onground                      = islocal ? IS_ONGROUND(strafeplayer) : !(strafeplayer.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 105         bool   strafekeys;
 106         bool   swimming                      = strafeplayer.waterlevel >= WATERLEVEL_SWIMMING;
 107         bool   spectating                    = entcs_GetSpecState(strafeplayer.sv_entnum) == ENTCS_SPEC_PURE;
 108         float  speed                         = !autocvar__hud_configure ? vlen(vec2(csqcplayer.velocity)) : 1337; // use local csqcmodel entity for this even when spectating, flickers too much otherwise
 109         float  maxspeed_crouch_mod           = IS_DUCKED(csqcplayer) && !swimming ? .5 : 1;
 110         float  maxspeed_water_mod            = swimming ? .7 : 1; // very simplified water physics, the hud will not work well (and is not supposed to) while swimming
 111         float  maxspeed_phys                 = onground ? PHYS_MAXSPEED(strafeplayer) : PHYS_MAXAIRSPEED(strafeplayer);
 112         float  maxspeed                      = !autocvar__hud_configure ? maxspeed_phys * maxspeed_crouch_mod * maxspeed_water_mod : 320;
 113         float  movespeed;
 114         float  vel_angle                     = vectoangles(strafeplayer.velocity).y - (vectoangles(strafeplayer.velocity).y > 180 ? 360 : 0); // change the range from 0° - 360° to -180° - 180° to match how view_angle represents angles
 115         float  view_angle                    = PHYS_INPUT_ANGLES(strafeplayer).y;
 116         float  angle;
 117         vector movement                      = PHYS_INPUT_MOVEVALUES(strafeplayer);
 118         int    keys                          = STAT(PRESSED_KEYS);
 119         int    keys_fwd;
 120         float  wishangle                     = 0;
 121
 122         // HUD
 123         int    mode                          = autocvar_hud_panel_strafehud_mode >= 0 && autocvar_hud_panel_strafehud_mode <= 1 ? autocvar_hud_panel_strafehud_mode : 0;
 124         float  speed_conversion_factor       = GetSpeedUnitFactor(autocvar_hud_panel_strafehud_unit);
 125         float  length_conversion_factor      = GetLengthUnitFactor(autocvar_hud_panel_strafehud_unit);
 126         string speed_unit                    = GetSpeedUnit(autocvar_hud_panel_strafehud_unit);
 127         string length_unit                   = GetLengthUnit(autocvar_hud_panel_strafehud_unit);
 128         int    length_decimals               = autocvar_hud_panel_strafehud_unit >= 3 && autocvar_hud_panel_strafehud_unit <= 5 ? 6 : 2; // use more decimals when displaying km or miles
 129         float  antiflicker_angle             = bound(0, autocvar_hud_panel_strafehud_antiflicker_angle, 180);
 130         float  antiflicker_speed             = max(0, autocvar_hud_panel_strafehud_antiflicker_speed);
 131         float  minspeed;
 132         float  shift_offset                  = 0;
 133         bool   straight_overturn             = false;
 134         bool   immobile                      = speed <= (swimming ? antiflicker_speed : 0);
 135         float  hudangle;
 136         float  neutral_offset;
 137         float  neutral_width;
 138         vector currentangle_color            = autocvar_hud_panel_strafehud_angle_neutral_color;
 139         float  currentangle_offset;
 140         vector currentangle_size             = '0 0 0';
 141         float  bestangle;
 142         float  odd_bestangle;
 143         bool   bestangle_anywhere            = false;
 144         float  bestangle_offset;
 145         float  switch_bestangle_offset;
 146         bool   odd_angles                    = false;
 147         float  odd_bestangle_offset          = 0;
 148         float  switch_odd_bestangle_offset   = 0;
 149         float  bestangle_width;
 150         float  accelzone_left_offset;
 151         float  accelzone_right_offset;
 152         float  accelzone_width;
 153         float  overturn_offset;
 154         float  overturn_width;
 155         float  slickdetector_height;
 156         vector direction_size_vertical       = '0 0 0';
 157         vector direction_size_horizontal     = '0 0 0';
 158         float  range_minangle;
 159
 160         // determine whether the player is pressing forwards or backwards keys
 161         if(islocal) // if entity is local player
 162         {
 163             if(movement.x > 0)
 164             {
 165                 keys_fwd = 1;
 166             }
 167             else if(movement.x < 0)
 168             {
 169                 keys_fwd = -1;
 170             }
 171             else
 172             {
 173                 keys_fwd = 0;
 174             }
 175         }
 176         else // alternatively determine direction by querying pressed keys
 177         {
 178             if((keys & KEY_FORWARD) && !(keys & KEY_BACKWARD))
 179             {
 180                 keys_fwd = 1;
 181             }
 182             else if(!(keys & KEY_FORWARD) && (keys & KEY_BACKWARD))
 183             {
 184                 keys_fwd = -1;
 185             }
 186             else
 187             {
 188                 keys_fwd = 0;
 189             }
 190         }
 191
 192         // determine player wishdir
 193         if(islocal) // if entity is local player
 194         {
 195             if(movement.x == 0)
 196             {
 197                 if(movement.y < 0)
 198                 {
 199                     wishangle = -90;
 200                 }
 201                 else if(movement.y > 0)
 202                 {
 203                     wishangle = 90;
 204                 }
 205                 else
 206                 {
 207                     wishangle = 0;
 208                 }
 209             }
 210             else
 211             {
 212                 if(movement.y == 0)
 213                 {
 214                     wishangle = 0;
 215                 }
 216                 else
 217                 {
 218                     wishangle = RAD2DEG * atan2(movement.y, movement.x);
 219                     // wrap the wish angle if it exceeds ±90°
 220                     if(fabs(wishangle) > 90)
 221                     {
 222                         if(wishangle < 0) wishangle += 180;
 223                         else wishangle -= 180;
 224                         wishangle = -wishangle;
 225                     }
 226                 }
 227             }
 228         }
 229         else // alternatively calculate wishdir by querying pressed keys
 230         {
 231             if(keys & KEY_FORWARD || keys & KEY_BACKWARD)
 232             {
 233                 wishangle = 45;
 234             }
 235             else
 236             {
 237                 wishangle = 90;
 238             }
 239             if(keys & KEY_LEFT)
 240             {
 241                 wishangle *= -1;
 242             }
 243             else if(!(keys & KEY_RIGHT))
 244             {
 245                 wishangle = 0; // wraps at 180°
 246             }
 247         }
 248
 249         strafekeys = fabs(wishangle) > 45;
 250
 251         // determine minimum required angle to display full strafe range
 252         range_minangle = fabs(wishangle) % 90; // maximum range is 90 degree
 253         if(range_minangle > 45) // minimum angle range is 45
 254         {
 255             range_minangle = 45 - fabs(wishangle) % 45;
 256         }
 257         range_minangle = 90 - range_minangle; // calculate value which is never >90 or <45
 258         range_minangle *= 2; // multiply to accommodate for both sides of the hud
 259
 260         if(autocvar_hud_panel_strafehud_range == 0)
 261         {
 262             if(autocvar__hud_configure)
 263             {
 264                 hudangle = 90;
 265             }
 266             else
 267             {
 268                 hudangle = range_minangle; // use minimum angle required if dynamically setting hud angle
 269             }
 270         }
 271         else
 272         {
 273             hudangle = bound(0, fabs(autocvar_hud_panel_strafehud_range), 360); // limit HUD range to 360 degrees, higher values don't make sense
 274         }
 275
 276         // detect air strafe turning
 277         if(onground != state_onground)
 278         {
 279             state_onground_time = time;
 280         }
 281         state_onground = onground;
 282
 283         if(strafekeys != state_strafekeys)
 284         {
 285             state_strafekeys_time = time;
 286         }
 287         state_strafekeys = strafekeys;
 288
 289         if((!strafekeys && vlen(vec2(movement)) > 0) || swimming || autocvar__hud_configure)
 290         {
 291             turn = false;
 292         }
 293         else if(onground)
 294         {
 295             if((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_ground) // timeout for strafe jumping in general
 296             {
 297                 turn = false;
 298             }
 299         }
 300         else // air strafe only
 301         {
 302             if(strafekeys)
 303             {
 304                 if(((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_air) || (keys & KEY_JUMP)) // timeout for slick ramps
 305                 {
 306                     turn = true; // CPMA turning
 307                     turnangle = wishangle;
 308
 309                     // calculate the maximum air strafe speed
 310                     if(PHYS_MAXAIRSPEED(strafeplayer) == 0){
 311                         maxspeed = 0;
 312                     }
 313                     else if(PHYS_MAXAIRSTRAFESPEED(strafeplayer) == 0 || PHYS_MAXAIRSPEED(strafeplayer) <= PHYS_MAXAIRSTRAFESPEED(strafeplayer)){
 314                         maxspeed = PHYS_MAXAIRSPEED(strafeplayer);
 315                     }
 316                     else{
 317                         maxspeed = PHYS_MAXAIRSPEED(strafeplayer) * pow(fabs(PHYS_MAXAIRSTRAFESPEED(strafeplayer) / PHYS_MAXAIRSPEED(strafeplayer)), 1 - (90 - fabs(wishangle)) / 45); // no modifiers here because they don't affect air strafing
 318                     }
 319
 320                     turnspeed = vlen(vec2(movement));
 321                     if(turnspeed == 0) turnspeed = maxspeed;
 322                     else turnspeed = min(turnspeed, maxspeed);
 323                 }
 324             }
 325             else if((time - state_strafekeys_time) >= autocvar_hud_panel_strafehud_timeout_turn) // timeout for jumping with strafe keys only
 326             {
 327                 turn = false;
 328             }
 329         }
 330         if(turn && (onground || !strafekeys)) // retain last state until strafe turning times out
 331         {
 332             wishangle = turnangle;
 333             movespeed = turnspeed;
 334         }
 335         else{
 336             movespeed = vlen(vec2(movement));
 337             if(movespeed == 0) movespeed = maxspeed;
 338             else movespeed = min(movespeed, maxspeed);
 339         }
 340
 341         minspeed = autocvar_hud_panel_strafehud_switch_minspeed < 0 ? movespeed + antiflicker_speed : autocvar_hud_panel_strafehud_switch_minspeed;
 342
 343         // get current strafing angle ranging from -180° to +180°
 344         if(!autocvar__hud_configure)
 345         {
 346             if(speed > 0)
 347             {
 348                 // calculate view angle relative to the players current velocity direction
 349                 angle = vel_angle - view_angle;
 350
 351                 // if the angle goes above 180° or below -180° wrap it to the opposite side since we want the interior angle
 352                 if (angle > 180) angle -= 360;
 353                 else if(angle < -180) angle += 360;
 354
 355                 // determine whether the player is strafing forwards or backwards
 356                 // if the player isn't strafe turning use forwards/backwards keys to determine direction
 357                 if(fabs(wishangle) != 90)
 358                 {
 359                     if(keys_fwd > 0)
 360                     {
 361                         fwd = true;
 362                     }
 363                     else if(keys_fwd < 0)
 364                     {
 365                         fwd = false;
 366                     }
 367                     else
 368                     {
 369                         fwd = fabs(angle) <= 90;
 370                     }
 371                 }
 372                 // otherwise determine by examining the strafe angle
 373                 else
 374                 {
 375                     if(wishangle < 0) // detect direction using wishangle since the direction is not yet set
 376                     {
 377                         fwd = angle <= -wishangle;
 378                     }
 379                     else
 380                     {
 381                         fwd = angle >= -wishangle;
 382                     }
 383                 }
 384
 385                 // shift the strafe angle by 180° when strafing backwards
 386                 if(!fwd)
 387                 {
 388                     if(angle < 0) angle += 180;
 389                     else angle -= 180;
 390                 }
 391
 392                 // don't make the angle indicator switch side too much at ±180° if anti flicker is turned on
 393                 if(angle > (180 - antiflicker_angle) || angle < (-180 + antiflicker_angle))
 394                 {
 395                     straight_overturn = true;
 396                 }
 397             }
 398             else
 399             {
 400                 angle = 0;
 401             }
 402         }
 403         else // simulate turning for HUD setup
 404         {
 405             fwd = true;
 406             if(autocvar__hud_panel_strafehud_demo && ((time - demo_time) >= .025))
 407             {
 408                 demo_time = time;
 409                 demo_angle += demo_direction;
 410                 if(fabs(demo_angle) >= 55)
 411                 {
 412                     demo_direction = -demo_direction;
 413                 }
 414             }
 415             angle = demo_angle;
 416             wishangle = 45 * (demo_angle > 0 ? 1 : -1);
 417         }
 418
 419         // invert the wish angle when strafing backwards
 420         if(!fwd)
 421         {
 422             wishangle = -wishangle;
 423         }
 424
 425         // flip angles if v_flipped is enabled
 426         if(autocvar_v_flipped)
 427         {
 428             angle = -angle;
 429             wishangle = -wishangle;
 430         }
 431
 432         // determine whether the player is strafing left or right
 433         if(wishangle != 0)
 434         {
 435             direction = wishangle > 0 ? 1 : -1;
 436         }
 437         else
 438         {
 439             direction = (angle > antiflicker_angle && angle < (180 - antiflicker_angle)) ? 1 : (angle < -antiflicker_angle && angle > (-180 + antiflicker_angle)) ? -1 : 0;
 440         }
 441
 442         // best angle to strafe at
 443         bestangle = (speed > movespeed ? acos(movespeed / speed) : 0) * RAD2DEG * (direction < 0 ? -1 : 1);
 444         odd_bestangle = -bestangle - wishangle;
 445         bestangle -= wishangle;
 446
 447         // various offsets and size calculations of hud indicator elements
 448         // how much is hidden by the current hud angle
 449         hidden_width = (360 - hudangle) / hudangle * panel_size.x;
 450         // current angle
 451         currentangle_size.x = panel_size.x * min(autocvar_hud_panel_strafehud_angle_width, 10);
 452         currentangle_size.y = panel_size.y * min(autocvar_hud_panel_strafehud_angle_height, 10);
 453         if(mode == 0)
 454         {
 455             currentangle_offset = angle/hudangle * panel_size.x;
 456         }
 457         else
 458         {
 459             currentangle_offset = bound(-hudangle/2, angle, hudangle/2)/hudangle * panel_size.x + panel_size.x/2;
 460         }
 461         // best strafe acceleration angle
 462         bestangle_offset        =  bestangle/hudangle * panel_size.x + panel_size.x/2;
 463         switch_bestangle_offset = -bestangle/hudangle * panel_size.x + panel_size.x/2;
 464         bestangle_width = panel_size.x * autocvar_hud_panel_strafehud_switch_width;
 465
 466         if(((angle > -wishangle && direction < 0) || (angle < -wishangle && direction > 0)) && (direction != 0))
 467         {
 468             odd_angles = true;
 469             odd_bestangle_offset = odd_bestangle/hudangle * panel_size.x + panel_size.x/2;
 470             switch_odd_bestangle_offset = (odd_bestangle+bestangle*2)/hudangle * panel_size.x + panel_size.x/2;
 471         }
 472         // direction indicator
 473         direction_size_vertical.x = panel_size.y * min(autocvar_hud_panel_strafehud_direction_width, .5);
 474         direction_size_vertical.y = panel_size.y;
 475         direction_size_horizontal.x = max(panel_size.x * min(autocvar_hud_panel_strafehud_direction_length, .5), direction_size_vertical.x);
 476         direction_size_horizontal.y = direction_size_vertical.x;
 477         // overturn
 478         overturn_width = 180/hudangle * panel_size.x;
 479
 480         // the neutral zone fills the whole strafe bar
 481         if(immobile)
 482         {
 483             // draw neutral zone
 484             if(panel_size.x > 0 && panel_size.y > 0 && autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha > 0)
 485             {
 486                 switch(autocvar_hud_panel_strafehud_style)
 487                 {
 488                     default:
 489                     case 0:
 490                         drawfill(panel_pos, panel_size, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 491                         break;
 492
 493                     case 1:
 494                         HUD_Panel_DrawProgressBar(panel_pos, panel_size, "progressbar", 1, 0, 0, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 495                 }
 496             }
 497         }
 498         else
 499         {
 500             // calculate various zones of the strafe-o-meter
 501             accelzone_width = overturn_offset = (90 - fabs(bestangle + wishangle))/hudangle * panel_size.x;
 502             accelzone_right_offset = 0;
 503             accelzone_left_offset = overturn_offset + overturn_width;
 504             neutral_width = 360/hudangle * panel_size.x - accelzone_width*2 - overturn_width;
 505             neutral_offset = direction < 0 ? accelzone_left_offset + accelzone_width : -neutral_width;
 506
 507             // remove switch indicator width from offset
 508             if(direction < 0)
 509             {
 510                 bestangle_offset -= bestangle_width;
 511                 switch_odd_bestangle_offset -= bestangle_width;
 512             }
 513             else
 514             {
 515                 switch_bestangle_offset -= bestangle_width;
 516                 odd_bestangle_offset -= bestangle_width;
 517             }
 518
 519             // shift hud if operating in view angle centered mode
 520             if(mode == 0)
 521             {
 522                 shift_offset = -currentangle_offset;
 523                 bestangle_offset += shift_offset;
 524                 switch_bestangle_offset += shift_offset;
 525                 odd_bestangle_offset += shift_offset;
 526                 switch_odd_bestangle_offset += shift_offset;
 527             }
 528             if(direction < 0) shift_offset += -360/hudangle * panel_size.x;
 529             // calculate how far off-center the strafe zones currently are
 530             shift_offset += (panel_size.x + neutral_width)/2 - wishangle/hudangle * panel_size.x;
 531             // shift strafe zones into correct place
 532             neutral_offset += shift_offset;
 533             accelzone_left_offset += shift_offset;
 534             accelzone_right_offset += shift_offset;
 535             overturn_offset += shift_offset;
 536
 537             // draw left acceleration zone
 538             HUD_Panel_DrawStrafeHUD(accelzone_left_offset, accelzone_width, autocvar_hud_panel_strafehud_bar_accel_color, autocvar_hud_panel_strafehud_bar_accel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 1);
 539
 540             // draw right acceleration zone
 541             HUD_Panel_DrawStrafeHUD(accelzone_right_offset, accelzone_width, autocvar_hud_panel_strafehud_bar_accel_color, autocvar_hud_panel_strafehud_bar_accel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 2);
 542
 543             // draw overturn zone
 544             HUD_Panel_DrawStrafeHUD(overturn_offset, overturn_width, autocvar_hud_panel_strafehud_bar_overturn_color, autocvar_hud_panel_strafehud_bar_overturn_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 3);
 545
 546             // draw neutral zone
 547             HUD_Panel_DrawStrafeHUD(neutral_offset, neutral_width, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 0);
 548
 549             if(direction != 0 && direction_size_vertical.x > 0 && autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha > 0)
 550             {
 551                 bool indicator_direction = direction < 0;
 552                 // invert left/right when strafing backwards or when strafing towards the opposite side indicated by the direction variable
 553                 // if both conditions are true then it's inverted twice hence not inverted at all
 554                 if(!fwd != odd_angles)
 555                 {
 556                     indicator_direction = !indicator_direction;
 557                 }
 558                 // draw the direction indicator caps at the sides of the hud
 559                 // vertical line
 560                 if(direction_size_vertical.y > 0) drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x), direction_size_vertical, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 561                 // top horizontal line
 562                 drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x - direction_size_horizontal.x + direction_size_vertical.x) - eY * direction_size_horizontal.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 563                 // bottom horizontal line
 564                 drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x - direction_size_horizontal.x + direction_size_vertical.x) + eY * panel_size.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 565             }
 566
 567             if(speed >= minspeed && bestangle_width > 0) // only draw indicators if minspeed is reached
 568             {
 569                 // draw the switch indicator(s)
 570                 float offset = !odd_angles ? bestangle_offset : odd_bestangle_offset;
 571                 float switch_offset = !odd_angles ? switch_bestangle_offset : switch_odd_bestangle_offset;
 572                 HUD_Panel_DrawStrafeHUD(switch_offset, bestangle_width, autocvar_hud_panel_strafehud_switch_color, autocvar_hud_panel_strafehud_switch_alpha * panel_fg_alpha, 0, 0);
 573                 if(direction == 0) HUD_Panel_DrawStrafeHUD(offset, bestangle_width, autocvar_hud_panel_strafehud_switch_color, autocvar_hud_panel_strafehud_switch_alpha * panel_fg_alpha, 0, 0);
 574             }
 575         }
 576
 577         // experimental: slick detector
 578         slickdetector_height = panel_size.y * bound(0, autocvar_hud_panel_strafehud_slickdetector_height, 0.5);
 579         if(autocvar_hud_panel_strafehud_slickdetector_range > 0 && autocvar_hud_panel_strafehud_slickdetector_alpha > 0 && slickdetector_height > 0 && panel_size.x > 0) // dunno if slick detection works in spectate
 580         {
 581             float slicksteps = 90 / pow(2, bound(0, autocvar_hud_panel_strafehud_slickdetector_granularity, 4));
 582             bool slickdetected = false;
 583
 584             if(islocal) slickdetected = IS_ONSLICK(strafeplayer); // don't need to traceline if already touching slick
 585
 586             // traceline into every direction
 587             trace_dphitq3surfaceflags = 0;
 588             for(float i = 0; i < 360 && !slickdetected; i += slicksteps)
 589             {
 590                 vector slickoffset;
 591                 float slickrotate;
 592                 slickoffset.z = -cos(i * DEG2RAD) * autocvar_hud_panel_strafehud_slickdetector_range;
 593                 slickrotate = sin(i * DEG2RAD) * autocvar_hud_panel_strafehud_slickdetector_range;
 594                 if(i != 0 && i != 180)
 595                 {
 596                     for(float j = 0; j < 180 && !slickdetected; j += slicksteps)
 597                     {
 598                         slickoffset.x = sin(j * DEG2RAD) * slickrotate;
 599                         slickoffset.y = cos(j * DEG2RAD) * slickrotate;
 600
 601                         traceline(strafeplayer.origin, strafeplayer.origin + slickoffset, MOVE_WORLDONLY, NULL);
 602                         if((PHYS_FRICTION(strafeplayer) == 0 && trace_fraction < 1) || trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK) slickdetected = true;
 603                     }
 604                 }
 605                 else
 606                 {
 607                     slickoffset.x = slickoffset.y = 0;
 608                     traceline(strafeplayer.origin, strafeplayer.origin + slickoffset, MOVE_WORLDONLY, NULL);
 609                     if((PHYS_FRICTION(strafeplayer) == 0 && trace_fraction < 1) || trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK) slickdetected = true;
 610                 }
 611             }
 612
 613             // if a traceline hit a slick surface
 614             if(slickdetected)
 615             {
 616                 vector slickdetector_size = panel_size;
 617                 slickdetector_size.y = slickdetector_height;
 618                 // top horizontal line
 619                 drawfill(panel_pos - eY * slickdetector_size.y, slickdetector_size, autocvar_hud_panel_strafehud_slickdetector_color, autocvar_hud_panel_strafehud_slickdetector_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 620                 // bottom horizontal line
 621                 drawfill(panel_pos + eY * panel_size.y, slickdetector_size, autocvar_hud_panel_strafehud_slickdetector_color, autocvar_hud_panel_strafehud_slickdetector_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 622             }
 623         }
 624
 625         if(speed < (movespeed + antiflicker_speed) && !immobile)
 626         {
 627             bestangle_anywhere = true; // moving forward should suffice to gain speed
 628         }
 629
 630         // draw the actual strafe angle
 631         if(!bestangle_anywhere && !immobile) // player gains speed with strafing
 632         {
 633             if((direction > 0 && (angle >= bestangle || angle <= -(bestangle + wishangle*2))) ||
 634                (direction < 0 && (angle <= bestangle || angle >= -(bestangle + wishangle*2))))
 635             currentangle_color = autocvar_hud_panel_strafehud_angle_accel_color;
 636         }
 637
 638         if(fabs(angle + wishangle) > 90) // player is overturning
 639         {
 640             currentangle_color = autocvar_hud_panel_strafehud_angle_overturn_color;
 641         }
 642         else if(bestangle_anywhere) // player gains speed without strafing
 643         {
 644             currentangle_color = autocvar_hud_panel_strafehud_angle_accel_color;
 645         }
 646
 647         if(mode == 0 || straight_overturn)
 648         {
 649             currentangle_offset = panel_size.x/2;
 650         }
 651
 652         if(autocvar_hud_panel_strafehud_style == 2 && !immobile)
 653         {
 654             float moveangle = angle + wishangle;
 655             float strafeangle = (bestangle + wishangle) * (direction < 0 ? -1 : 1);
 656             float strafe_ratio = 0;
 657             if(fabs(moveangle) > 90)
 658             {
 659                 strafe_ratio = -((fabs(moveangle) - 90) / 90);
 660                 if(strafe_ratio < -1) strafe_ratio = -2 - strafe_ratio;
 661             }
 662             else
 663             {
 664                 if(moveangle >= strafeangle)
 665                 {
 666                     strafe_ratio = 1 - (moveangle - strafeangle) / (90 - strafeangle);
 667                 }
 668                 else if(moveangle <= -strafeangle)
 669                 {
 670                     strafe_ratio = 1 - (moveangle + strafeangle) / (-90 + strafeangle);
 671                 }
 672             }
 673             if(strafe_ratio < 0)
 674             {
 675                 currentangle_color = StrafeHUD_mixColors(autocvar_hud_panel_strafehud_angle_neutral_color, autocvar_hud_panel_strafehud_angle_overturn_color, -strafe_ratio);
 676             }
 677             else
 678             {
 679                 currentangle_color = StrafeHUD_mixColors(autocvar_hud_panel_strafehud_angle_neutral_color, autocvar_hud_panel_strafehud_angle_accel_color, strafe_ratio);
 680             }
 681         }
 682
 683         if(autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha > 0)
 684         {
 685             switch(autocvar_hud_panel_strafehud_angle_style)
 686             {
 687                 case 1:
 688                     if(currentangle_size.x > 0 && currentangle_size.y > 0) drawfill(panel_pos - eY * ((currentangle_size.y - panel_size.y) / 2) + eX * (currentangle_offset - currentangle_size.x/2), currentangle_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 689                     break;
 690                 case 2:
 691                     if(currentangle_size.x > 0 && currentangle_size.y > 0)
 692                     {
 693                         vector line_size = currentangle_size;
 694                         line_size.y = currentangle_size.y / (bound(2, autocvar_hud_panel_strafehud_angle_dashes, currentangle_size.y)*2-1);
 695                         for(float i = 0; i < currentangle_size.y; i += line_size.y*2)
 696                         {
 697                             if(i + line_size.y*2 >= currentangle_size.y) line_size.y = currentangle_size.y - i;
 698                             drawfill(panel_pos - eY * ((currentangle_size.y - panel_size.y) / 2 - i) + eX * (currentangle_offset - line_size.x/2), line_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 699                         }
 700                     }
 701                     break;
 702                 case 0:
 703                 default:
 704             }
 705
 706             if(autocvar_hud_panel_strafehud_angle_arrow > 0)
 707             {
 708                 float arrow_size = panel_size.y * min(autocvar_hud_panel_strafehud_angle_arrow_size, 10); // there's only one size cvar, arrows always have a 45° angle to ensure proper rendering without antialiasing
 709                 if(arrow_size > 0)
 710                 {
 711                     if(autocvar_hud_panel_strafehud_angle_arrow == 1 || autocvar_hud_panel_strafehud_angle_arrow >= 3)
 712                         StrafeHUD_drawStrafeArrow(panel_pos + eY * ((panel_size.y - currentangle_size.y) / 2) + eX * currentangle_offset, arrow_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, true);
 713                     if(autocvar_hud_panel_strafehud_angle_arrow >= 2)
 714                         StrafeHUD_drawStrafeArrow(panel_pos + eY * ((panel_size.y - currentangle_size.y) / 2 + currentangle_size.y) + eX * currentangle_offset, arrow_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, false);
 715                 }
 716             }
 717         }
 718
 719         draw_beginBoldFont();
 720         // show speed when crossing the start trigger
 721         if(autocvar_hud_panel_strafehud_startspeed_fade > 0)
 722         {
 723             float text_alpha = 0;
 724             if((race_nextcheckpoint == 1) || (race_checkpoint == 254 && race_nextcheckpoint == 255)) // check if the start trigger was hit (will also trigger if the finish trigger was hit if those have the same ID)
 725             {
 726                 if(starttime != race_checkpointtime)
 727                 {
 728                     starttime = race_checkpointtime;
 729                     startspeed = speed;
 730                 }
 731             }
 732             if(startspeed >= 0)
 733             {
 734                 text_alpha = cos(((time - starttime) / autocvar_hud_panel_strafehud_startspeed_fade) * 90 * DEG2RAD); // fade non-linear like the physics panel does
 735                 if((time - starttime) > autocvar_hud_panel_strafehud_startspeed_fade)
 736                 {
 737                     startspeed = -1;
 738                 }
 739             }
 740             if(startspeed >= 0 && text_alpha > 0 && autocvar_hud_panel_strafehud_startspeed_size > 0)
 741             {
 742                 vector startspeed_size = panel_size;
 743                 startspeed_size.y = panel_size.y * min(autocvar_hud_panel_strafehud_startspeed_size, 10);
 744                 drawstring_aspect(panel_pos + eY * panel_size.y, strcat(ftos_decimals(startspeed * speed_conversion_factor, 2), autocvar_hud_panel_strafehud_unit_show ? speed_unit : ""), startspeed_size, autocvar_hud_panel_strafehud_startspeed_color, text_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 745             }
 746         }
 747         else
 748         {
 749             starttime = 0;
 750             startspeed = -1;
 751         }
 752
 753         // experimental: show height achieved by a single jump (doesn't work in low gravity and may not be 100% accurate)
 754         if(autocvar_hud_panel_strafehud_jumpheight_fade > 0)
 755         {
 756             float text_alpha = 0;
 757             float jumpheight_min = max(autocvar_hud_panel_strafehud_jumpheight_min, 0);
 758             float jumpheight_current = strafeplayer.origin.z;
 759             float jumpspeed_current = strafeplayer.velocity.z;
 760             if(jumpspeed_prev <= jumpspeed_current || jumpheight_prev > jumpheight_current || onground || swimming || IS_DEAD(strafeplayer) || spectating)
 761             {
 762                 // tries to catch kill and spectate but those are not reliable, should just hook to kill/spectate/teleport and reset jump height there
 763                 jumprestart = true;
 764             }
 765             else
 766             {
 767                 if(jumpheight < 0 || jumprestart)
 768                 {
 769                     jumprestart = false;
 770                     jumpheight = 0;
 771                 }
 772                 else
 773                 {
 774                     jumpheight += jumpheight_current - jumpheight_prev;
 775                 }
 776                 if((jumpheight * length_conversion_factor) > jumpheight_min && jumpheight > jumpheight_persistent)
 777                 {
 778                     jumptime = time;
 779                     jumpheight_persistent = jumpheight;
 780                 }
 781             }
 782             jumpheight_prev = jumpheight_current;
 783             jumpspeed_prev = jumpspeed_current;
 784             if(jumpheight_persistent > 0)
 785             {
 786                 text_alpha = cos(((time - jumptime) / autocvar_hud_panel_strafehud_jumpheight_fade) * 90 * DEG2RAD); // fade non-linear like the physics panel does
 787                 if((time - jumptime) > autocvar_hud_panel_strafehud_jumpheight_fade)
 788                 {
 789                     jumpheight_persistent = -1;
 790                 }
 791             }
 792             if(jumpheight_persistent > 0 && text_alpha > 0 && autocvar_hud_panel_strafehud_jumpheight_size > 0)
 793             {
 794                 vector jumpheight_size = panel_size;
 795                 jumpheight_size.y = panel_size.y * min(autocvar_hud_panel_strafehud_jumpheight_size, 10);
 796                 drawstring_aspect(panel_pos - eY * jumpheight_size.y, strcat(ftos_decimals(jumpheight_persistent * length_conversion_factor, length_decimals), autocvar_hud_panel_strafehud_unit_show ? length_unit : ""), jumpheight_size, autocvar_hud_panel_strafehud_jumpheight_color, text_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 797             }
 798         }
 799         else
 800         {
 801             jumpheight_prev = jumpspeed_prev = 0;
 802             jumpheight = jumpheight_persistent = -1;
 803         }
 804         draw_endBoldFont();
 805     }
 806 }
 807
 808 // functions to make hud elements align perfectly in the hud area
 809 void HUD_Panel_DrawStrafeHUD(float offset, float width, vector color, float alpha, int type, int gradientType)
 810 {
 811     float mirror_offset, mirror_width;
 812     vector size = panel_size;
 813     vector mirror_size = panel_size;
 814     int gradient_start;
 815     float gradient_offset, gradient_mirror_offset;
 816     float overflow_width = 0, overflow_mirror_width = 0;
 817
 818     float original_width = width;
 819
 820     if(alpha <= 0 && type != 2 || width <= 0) return;
 821
 822     if(type == 2 && gradientType == 0) type = 0;
 823
 824     if(offset < 0)
 825     {
 826         mirror_width = min(fabs(offset), width);
 827         mirror_offset = panel_size.x + hidden_width - fabs(offset);
 828         width += offset;
 829         offset = 0;
 830     }
 831     else
 832     {
 833         mirror_width = min(offset + width - panel_size.x - hidden_width, width);
 834         mirror_offset = max(offset - panel_size.x - hidden_width, 0);
 835     }
 836
 837     if(width < 0) width = 0;
 838     if((offset + width) > panel_size.x)
 839     {
 840         overflow_width = (offset + width) - panel_size.x;
 841         width = panel_size.x - offset;
 842     }
 843     if(mirror_offset < 0)
 844     {
 845         mirror_width += mirror_offset;
 846         mirror_offset = 0;
 847     }
 848
 849     if(mirror_width < 0) mirror_width = 0;
 850     if((mirror_offset + mirror_width) > panel_size.x)
 851     {
 852         overflow_mirror_width = (mirror_offset + mirror_width) - panel_size.x;
 853         mirror_width = panel_size.x - mirror_offset;
 854     }
 855
 856     if(direction < 0) // swap mirror and non-mirror values if direction points left
 857     {
 858         offset += mirror_offset;
 859         mirror_offset = offset - mirror_offset;
 860         offset -= mirror_offset;
 861
 862         width += mirror_width;
 863         mirror_width = width - mirror_width;
 864         width -= mirror_width;
 865
 866         overflow_width += overflow_mirror_width;
 867         overflow_mirror_width = overflow_width - overflow_mirror_width;
 868         overflow_width -= overflow_mirror_width;
 869     }
 870
 871     size.x = width;
 872     mirror_size.x = mirror_width;
 873
 874     switch(type)
 875     {
 876         default:
 877         case 0: // no styling (drawfill)
 878             if(mirror_size.x > 0 && mirror_size.y > 0) drawfill(panel_pos + eX * mirror_offset, mirror_size, color, alpha, DRAWFLAG_NORMAL);
 879             if(size.x > 0 && size.y > 0) drawfill(panel_pos + eX * offset, size, color, alpha, DRAWFLAG_NORMAL);
 880             break;
 881
 882         case 1: // progress bar style
 883             if(mirror_size.x > 0 && mirror_size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * mirror_offset, mirror_size, "progressbar", 1, 0, 0, color, alpha, DRAWFLAG_NORMAL);
 884             if(size.x > 0 && size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * offset, size, "progressbar", 1, 0, 0, color, alpha, DRAWFLAG_NORMAL);
 885             break;
 886
 887         case 2: // gradient style (types: 1 = left, 2 = right, 3 = both)
 888             // determine whether the gradient starts in the mirrored or the non-mirrored area
 889             if(offset == 0 && mirror_offset == 0) gradient_start = width > mirror_width ? 2 : 1;
 890             else if(offset == 0) gradient_start = 2;
 891             else if(mirror_offset == 0) gradient_start = 1;
 892             else gradient_start = 0;
 893
 894             switch(gradient_start){
 895                 default:
 896                 case 0: // no offset required
 897                     gradient_offset = gradient_mirror_offset = 0;
 898                     break;
 899                 case 1: // offset starts in non-mirrored area, mirrored area requires offset
 900                     gradient_offset = 0;
 901                     gradient_mirror_offset = original_width - (mirror_width + overflow_mirror_width);
 902                     break;
 903                 case 2: // offset starts in mirrored area, non-mirrored area requires offset
 904                     gradient_offset = original_width - (width + overflow_width);
 905                     gradient_mirror_offset = 0;
 906             }
 907
 908             StrafeHUD_drawGradient(color, autocvar_hud_panel_strafehud_bar_neutral_color, mirror_size, original_width, mirror_offset, alpha, gradient_mirror_offset, gradientType);
 909             StrafeHUD_drawGradient(color, autocvar_hud_panel_strafehud_bar_neutral_color, size, original_width, offset, alpha, gradient_offset, gradientType);
 910     }
 911 }
 912
 913 vector StrafeHUD_mixColors(vector color1, vector color2, float ratio)
 914 {
 915     vector mixedColor;
 916     if(ratio <= 0) return color1;
 917     if(ratio >= 1) return color2;
 918     mixedColor.x = color1.x + (color2.x - color1.x) * ratio;
 919     mixedColor.y = color1.y + (color2.y - color1.y) * ratio;
 920     mixedColor.z = color1.z + (color2.z - color1.z) * ratio;
 921     return mixedColor;
 922 }
 923
 924 void StrafeHUD_drawGradient(vector color1, vector color2, vector size, float original_width, float offset, float alpha, float gradientOffset, int gradientType)
 925 {
 926     float color_ratio, alpha1, alpha2;
 927     vector gradient_size = size;
 928     alpha1 = bound(0, alpha, 1);
 929     alpha2 = bound(0, autocvar_hud_panel_strafehud_bar_neutral_alpha, 1);
 930     if((alpha1+alpha2) == 0) return;
 931     color_ratio = alpha1/(alpha1+alpha2);
 932     for(int i = 0; i < size.x; ++i)
 933     {
 934         float ratio, alpha_ratio, combine_ratio1, combine_ratio2;
 935         gradient_size.x = size.x - i < 1 ? size.x - i : 1;
 936         ratio = (i + gradientOffset) / original_width * (gradientType == 3 ? 2 : 1);
 937         if(ratio > 1) ratio = 2 - ratio;
 938         if(gradientType != 2) ratio = 1 - ratio;
 939         alpha_ratio = alpha1 - (alpha1 - alpha2) * ratio;
 940         combine_ratio1 = ratio*(1-color_ratio);
 941         combine_ratio2 = (1-ratio)*color_ratio;
 942         ratio = (combine_ratio1 + combine_ratio2) == 0 ? 1 : combine_ratio1/(combine_ratio1 + combine_ratio2);
 943         if(alpha_ratio > 0) drawfill(panel_pos + eX * (offset + i), gradient_size, StrafeHUD_mixColors(color1, color2, ratio), alpha_ratio, DRAWFLAG_NORMAL);
 944     }
 945 }
 946
 947 // draw the strafe arrows (inspired by drawspritearrow() in common/mutators/mutator/waypoints/waypointsprites.qc)
 948 void StrafeHUD_drawStrafeArrow(vector origin, float size, vector color, float alpha, bool flipped)
 949 {
 950     if(flipped) origin -= size*eY;
 951     R_BeginPolygon("", DRAWFLAG_NORMAL, true);
 952     R_PolygonVertex(origin + (flipped ? size*eY : '0 0 0')          , '0 0 0', color, alpha);
 953     R_PolygonVertex(origin + (flipped ? '0 0 0' : size*eY) - size*eX, '0 0 0', color, alpha);
 954     R_PolygonVertex(origin + (flipped ? '0 0 0' : size*eY) + size*eX, '0 0 0', color, alpha);
 955     R_EndPolygon();
 956 }
 957
 958 // length unit conversion (km and miles are only included to match the GetSpeedUnit* functions)
 959 float GetLengthUnitFactor(int length_unit)
 960 {
 961     switch(length_unit)
 962     {
 963         default:
 964         case 1: return 1.0;
 965         case 2: return 0.0254;
 966         case 3: return 0.0254 * 0.001;
 967         case 4: return 0.0254 * 0.001 * 0.6213711922;
 968         case 5: return 0.0254 * 0.001 * 0.5399568035;
 969     }
 970 }
 971
 972 string GetLengthUnit(int length_unit)
 973 {
 974     switch(length_unit)
 975     {
 976         // translator-friendly strings without the initial space
 977         default:
 978         case 1: return strcat(" ", _("qu"));
 979         case 2: return strcat(" ", _("m"));
 980         case 3: return strcat(" ", _("km"));
 981         case 4: return strcat(" ", _("mi"));
 982         case 5: return strcat(" ", _("nmi"));
 983     }
 984 }