qcsrc/client/hud/panel/strafehud.qc

   1 // Author: Juhu
   2
   3 #include "strafehud.qh"
   4
   5 #include <client/draw.qh>
   6 #include <client/hud/panel/racetimer.qh>
   7 #include <client/resources.qh>
   8 #include <client/view.qh>
   9 #include <common/animdecide.qh>
  10 #include <common/ent_cs.qh>
  11 #include <common/mapinfo.qh>
  12 #include <common/physics/movetypes/movetypes.qh>
  13 #include <common/physics/player.qh>
  14 #include <lib/csqcmodel/cl_player.qh>
  15
  16 // StrafeHUD (#25)
  17
  18 void HUD_StrafeHUD_Export(int fh)
  19 {
  20     // allow saving cvars that aesthetically change the panel into hud skin files
  21 }
  22
  23 float hidden_width;
  24 int direction;
  25 float demo_angle = -37;
  26 float demo_direction = 1;
  27 float demo_time = 0;
  28 bool state_onground = false;
  29 float state_onground_time = 0;
  30 bool state_strafekeys = false;
  31 float state_strafekeys_time = 0;
  32 bool turn = false;
  33 float turnangle;
  34 float turnspeed;
  35 float turnaccel;
  36 bool fwd = true;
  37 float starttime = 0;
  38 float startspeed = -1;
  39 float jumptime = 0;
  40 float jumpheight = -1;
  41 float jumpheight_persistent = -1;
  42 float jumpheight_prev = 0;
  43 float jumpspeed_prev = 0;
  44 bool  jumprestart = true;
  45
  46 // provide basic panel cvars to old clients
  47 // TODO remove them after a future release (0.8.2+)
  48 noref string autocvar_hud_panel_strafehud_pos = "0.320000 0.570000";
  49 noref string autocvar_hud_panel_strafehud_size = "0.360000 0.020000";
  50 noref string autocvar_hud_panel_strafehud_bg = "0";
  51 noref string autocvar_hud_panel_strafehud_bg_color = "";
  52 noref string autocvar_hud_panel_strafehud_bg_color_team = "";
  53 noref string autocvar_hud_panel_strafehud_bg_alpha = "0.7";
  54 noref string autocvar_hud_panel_strafehud_bg_border = "";
  55 noref string autocvar_hud_panel_strafehud_bg_padding = "";
  56
  57 void HUD_StrafeHUD()
  58 {
  59     entity strafeplayer;
  60     bool islocal;
  61
  62     // generic hud routines
  63     if(!autocvar__hud_configure)
  64     {
  65         if(!autocvar_hud_panel_strafehud ||
  66            (spectatee_status == -1 && (autocvar_hud_panel_strafehud == 1 || autocvar_hud_panel_strafehud == 3)) ||
  67            (autocvar_hud_panel_strafehud == 3 && !MUTATOR_CALLHOOK(HUD_StrafeHUD_showoptional))) return;
  68     }
  69
  70     HUD_Panel_LoadCvars();
  71
  72     if(autocvar_hud_panel_strafehud_dynamichud)
  73     {
  74         HUD_Scale_Enable();
  75     }
  76     else
  77     {
  78         HUD_Scale_Disable();
  79     }
  80
  81     HUD_Panel_DrawBg();
  82
  83     if(panel_bg_padding)
  84     {
  85         panel_pos  += '1 1 0' * panel_bg_padding;
  86         panel_size -= '2 2 0' * panel_bg_padding;
  87     }
  88
  89     // find out whether the local csqcmodel entity is valid
  90     if(spectatee_status > 0 || isdemo())
  91     {
  92         islocal = false;
  93         strafeplayer = CSQCModel_server2csqc(player_localentnum - 1);
  94     }
  95     else
  96     {
  97         islocal = true;
  98         strafeplayer = csqcplayer;
  99     }
 100
 101     // draw strafehud
 102     if(csqcplayer && strafeplayer)
 103     {
 104         // physics
 105         bool   onground                      = islocal ? IS_ONGROUND(strafeplayer) : !(strafeplayer.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 106         bool   strafekeys;
 107         bool   swimming                      = strafeplayer.waterlevel >= WATERLEVEL_SWIMMING;
 108         bool   spectating                    = entcs_GetSpecState(strafeplayer.sv_entnum) == ENTCS_SPEC_PURE;
 109         float  speed                         = !autocvar__hud_configure ? vlen(vec2(csqcplayer.velocity)) : 1337; // use local csqcmodel entity for this even when spectating, flickers too much otherwise
 110         float  crouch_mod                    = IS_DUCKED(csqcplayer) && !swimming ? .5 : 1;
 111         float  water_mod                     = swimming ? .7 : 1; // very simplified water physics, the hud will not work well (and is not supposed to) while swimming
 112         float  maxspeed_phys                 = onground ? PHYS_MAXSPEED(strafeplayer) : PHYS_MAXAIRSPEED(strafeplayer);
 113         float  maxspeed                      = !autocvar__hud_configure ? maxspeed_phys * crouch_mod * water_mod : 320;
 114         float  movespeed;
 115         float  maxaccel_phys                 = onground ? PHYS_ACCELERATE(strafeplayer) : PHYS_AIRACCELERATE(strafeplayer);
 116         float  maxaccel                      = !autocvar__hud_configure ? maxaccel_phys * crouch_mod * water_mod : 1;
 117         float  vel_angle                     = vectoangles(strafeplayer.velocity).y - (vectoangles(strafeplayer.velocity).y > 180 ? 360 : 0); // change the range from 0° - 360° to -180° - 180° to match how view_angle represents angles
 118         float  view_angle                    = PHYS_INPUT_ANGLES(strafeplayer).y;
 119         float  angle;
 120         vector movement                      = PHYS_INPUT_MOVEVALUES(strafeplayer);
 121         int    keys                          = STAT(PRESSED_KEYS);
 122         int    keys_fwd;
 123         float  wishangle                     = 0;
 124
 125         // HUD
 126         int    mode                          = autocvar_hud_panel_strafehud_mode >= 0 && autocvar_hud_panel_strafehud_mode <= 1 ? autocvar_hud_panel_strafehud_mode : 0;
 127         float  speed_conversion_factor       = GetSpeedUnitFactor(autocvar_hud_panel_strafehud_unit);
 128         float  length_conversion_factor      = GetLengthUnitFactor(autocvar_hud_panel_strafehud_unit);
 129         string speed_unit                    = GetSpeedUnit(autocvar_hud_panel_strafehud_unit);
 130         string length_unit                   = GetLengthUnit(autocvar_hud_panel_strafehud_unit);
 131         int    length_decimals               = autocvar_hud_panel_strafehud_unit >= 3 && autocvar_hud_panel_strafehud_unit <= 5 ? 6 : 2; // use more decimals when displaying km or miles
 132         float  antiflicker_angle             = bound(0, autocvar_hud_panel_strafehud_antiflicker_angle, 180);
 133         float  antiflicker_speed             = max(0, autocvar_hud_panel_strafehud_antiflicker_speed);
 134         float  minspeed;
 135         float  shift_offset                  = 0;
 136         bool   straight_overturn             = false;
 137         bool   immobile                      = speed <= (swimming ? antiflicker_speed : 0);
 138         float  hudangle;
 139         float  neutral_offset;
 140         float  neutral_width;
 141         vector currentangle_color            = autocvar_hud_panel_strafehud_angle_neutral_color;
 142         float  currentangle_offset;
 143         vector currentangle_size             = '0 0 0';
 144         float  bestangle;
 145         float  prebestangle;
 146         float  odd_bestangle;
 147         bool   bestangle_anywhere            = false;
 148         float  bestangle_offset;
 149         float  switch_bestangle_offset;
 150         bool   odd_angles                    = false;
 151         float  odd_bestangle_offset          = 0;
 152         float  switch_odd_bestangle_offset   = 0;
 153         float  bestangle_width;
 154         float  accelzone_left_offset;
 155         float  accelzone_right_offset;
 156         float  accelzone_width;
 157         float  preaccelzone_left_offset;
 158         float  preaccelzone_right_offset;
 159         float  preaccelzone_width;
 160         float  overturn_offset;
 161         float  overturn_width;
 162         float  slickdetector_height;
 163         vector direction_size_vertical       = '0 0 0';
 164         vector direction_size_horizontal     = '0 0 0';
 165         float  range_minangle;
 166         float  arrow_size = max(panel_size.y * min(autocvar_hud_panel_strafehud_angle_arrow_size, 10), 0); // there's only one size cvar for the arrows, they will always have a 45° angle to ensure proper rendering without antialiasing
 167
 168         if(!autocvar_hud_panel_strafehud_uncapped)
 169             arrow_size = max(arrow_size, 1);
 170
 171         // determine whether the player is pressing forwards or backwards keys
 172         if(islocal) // if entity is local player
 173         {
 174             if(movement.x > 0)
 175             {
 176                 keys_fwd = 1;
 177             }
 178             else if(movement.x < 0)
 179             {
 180                 keys_fwd = -1;
 181             }
 182             else
 183             {
 184                 keys_fwd = 0;
 185             }
 186         }
 187         else // alternatively determine direction by querying pressed keys
 188         {
 189             if((keys & KEY_FORWARD) && !(keys & KEY_BACKWARD))
 190             {
 191                 keys_fwd = 1;
 192             }
 193             else if(!(keys & KEY_FORWARD) && (keys & KEY_BACKWARD))
 194             {
 195                 keys_fwd = -1;
 196             }
 197             else
 198             {
 199                 keys_fwd = 0;
 200             }
 201         }
 202
 203         // determine player wishdir
 204         if(islocal) // if entity is local player
 205         {
 206             if(movement.x == 0)
 207             {
 208                 if(movement.y < 0)
 209                 {
 210                     wishangle = -90;
 211                 }
 212                 else if(movement.y > 0)
 213                 {
 214                     wishangle = 90;
 215                 }
 216                 else
 217                 {
 218                     wishangle = 0;
 219                 }
 220             }
 221             else
 222             {
 223                 if(movement.y == 0)
 224                 {
 225                     wishangle = 0;
 226                 }
 227                 else
 228                 {
 229                     wishangle = RAD2DEG * atan2(movement.y, movement.x);
 230                     // wrap the wish angle if it exceeds ±90°
 231                     if(fabs(wishangle) > 90)
 232                     {
 233                         if(wishangle < 0) wishangle += 180;
 234                         else wishangle -= 180;
 235                         wishangle = -wishangle;
 236                     }
 237                 }
 238             }
 239         }
 240         else // alternatively calculate wishdir by querying pressed keys
 241         {
 242             if(keys & KEY_FORWARD || keys & KEY_BACKWARD)
 243             {
 244                 wishangle = 45;
 245             }
 246             else
 247             {
 248                 wishangle = 90;
 249             }
 250             if(keys & KEY_LEFT)
 251             {
 252                 wishangle *= -1;
 253             }
 254             else if(!(keys & KEY_RIGHT))
 255             {
 256                 wishangle = 0; // wraps at 180°
 257             }
 258         }
 259
 260         strafekeys = fabs(wishangle) > 45;
 261
 262         // determine minimum required angle to display full strafe range
 263         range_minangle = fabs(wishangle) % 90; // maximum range is 90 degree
 264         if(range_minangle > 45) // minimum angle range is 45
 265         {
 266             range_minangle = 45 - fabs(wishangle) % 45;
 267         }
 268         range_minangle = 90 - range_minangle; // calculate value which is never >90 or <45
 269         range_minangle *= 2; // multiply to accommodate for both sides of the hud
 270
 271         if(autocvar_hud_panel_strafehud_range == 0)
 272         {
 273             if(autocvar__hud_configure)
 274             {
 275                 hudangle = 90;
 276             }
 277             else
 278             {
 279                 hudangle = range_minangle; // use minimum angle required if dynamically setting hud angle
 280             }
 281         }
 282         else
 283         {
 284             hudangle = bound(0, fabs(autocvar_hud_panel_strafehud_range), 360); // limit HUD range to 360 degrees, higher values don't make sense
 285         }
 286
 287         // detect air strafe turning
 288         if(onground != state_onground)
 289         {
 290             state_onground_time = time;
 291         }
 292         state_onground = onground;
 293
 294         if(strafekeys != state_strafekeys)
 295         {
 296             state_strafekeys_time = time;
 297         }
 298         state_strafekeys = strafekeys;
 299
 300         if((!strafekeys && vlen(vec2(movement)) > 0) || swimming || autocvar__hud_configure)
 301         {
 302             turn = false;
 303         }
 304         else if(onground)
 305         {
 306             if((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_ground) // timeout for strafe jumping in general
 307             {
 308                 turn = false;
 309             }
 310         }
 311         else // air strafe only
 312         {
 313             if(strafekeys)
 314             {
 315                 if(((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_air) || (keys & KEY_JUMP)) // timeout for slick ramps
 316                 {
 317                     turn = true; // CPMA turning
 318                     turnangle = wishangle;
 319
 320                     // calculate the maximum air strafe speed and acceleration
 321                     if(PHYS_MAXAIRSPEED(strafeplayer) == 0){
 322                         maxspeed = 0;
 323                     }
 324                     else if(PHYS_MAXAIRSTRAFESPEED(strafeplayer) == 0 || PHYS_MAXAIRSPEED(strafeplayer) <= PHYS_MAXAIRSTRAFESPEED(strafeplayer)){
 325                         maxspeed = PHYS_MAXAIRSPEED(strafeplayer);
 326                     }
 327                     else{
 328                         maxspeed = PHYS_MAXAIRSPEED(strafeplayer) * pow(fabs(PHYS_MAXAIRSTRAFESPEED(strafeplayer) / PHYS_MAXAIRSPEED(strafeplayer)), 1 - (90 - fabs(wishangle)) / 45); // no modifiers here because they don't affect air strafing
 329                     }
 330                     turnspeed = vlen(vec2(movement));
 331                     if(turnspeed == 0) turnspeed = maxspeed;
 332                     else turnspeed = min(turnspeed, maxspeed);
 333
 334                     if(PHYS_AIRACCELERATE(strafeplayer) == 0){
 335                         maxaccel = 0;
 336                     }
 337                     else if(PHYS_AIRSTRAFEACCELERATE(strafeplayer) == 0 || PHYS_AIRACCELERATE(strafeplayer) <= PHYS_AIRSTRAFEACCELERATE(strafeplayer)){
 338                         maxaccel = PHYS_AIRACCELERATE(strafeplayer);
 339                     }
 340                     else{
 341                         maxaccel = PHYS_AIRACCELERATE(strafeplayer) * pow(fabs(PHYS_AIRSTRAFEACCELERATE(strafeplayer) / PHYS_AIRACCELERATE(strafeplayer)), 1 - (90 - fabs(wishangle)) / 45); // no modifiers here because they don't affect air strafing
 342                     }
 343                     turnaccel = maxaccel;
 344                 }
 345             }
 346             else if((time - state_strafekeys_time) >= autocvar_hud_panel_strafehud_timeout_turn) // timeout for jumping with strafe keys only
 347             {
 348                 turn = false;
 349             }
 350         }
 351         if(turn && (onground || !strafekeys)) // retain last state until strafe turning times out
 352         {
 353             wishangle = turnangle;
 354             movespeed = turnspeed;
 355             maxaccel = turnaccel;
 356         }
 357         else{
 358             movespeed = vlen(vec2(movement));
 359             if(movespeed == 0) movespeed = maxspeed;
 360             else movespeed = min(movespeed, maxspeed);
 361
 362             if(onground)
 363             {
 364                 if((keys & KEY_JUMP) && ((time - state_onground_time) < autocvar_hud_panel_strafehud_timeout_ground)) // if ground timeout hasn't expired yet use air accelerate
 365                 {
 366                     maxaccel = !autocvar__hud_configure ? PHYS_AIRACCELERATE(strafeplayer) * crouch_mod * water_mod : 1;
 367                 }
 368             }
 369             else
 370             {
 371                 if(!(keys & KEY_JUMP) && ((time - state_onground_time) < autocvar_hud_panel_strafehud_timeout_air)) // if air timeout hasn't expired yet use ground accelerate
 372                 {
 373                     maxaccel = !autocvar__hud_configure ? PHYS_ACCELERATE(strafeplayer) * crouch_mod * water_mod : 1;
 374                 }
 375             }
 376         }
 377
 378         minspeed = autocvar_hud_panel_strafehud_switch_minspeed < 0 ? (movespeed - maxaccel) + antiflicker_speed : autocvar_hud_panel_strafehud_switch_minspeed;
 379
 380         // get current strafing angle ranging from -180° to +180°
 381         if(!autocvar__hud_configure)
 382         {
 383             if(speed > 0)
 384             {
 385                 // calculate view angle relative to the players current velocity direction
 386                 angle = vel_angle - view_angle;
 387
 388                 // if the angle goes above 180° or below -180° wrap it to the opposite side since we want the interior angle
 389                 if (angle > 180) angle -= 360;
 390                 else if(angle < -180) angle += 360;
 391
 392                 // determine whether the player is strafing forwards or backwards
 393                 // if the player isn't strafe turning use forwards/backwards keys to determine direction
 394                 if(fabs(wishangle) != 90)
 395                 {
 396                     if(keys_fwd > 0)
 397                     {
 398                         fwd = true;
 399                     }
 400                     else if(keys_fwd < 0)
 401                     {
 402                         fwd = false;
 403                     }
 404                     else
 405                     {
 406                         fwd = fabs(angle) <= 90;
 407                     }
 408                 }
 409                 // otherwise determine by examining the strafe angle
 410                 else
 411                 {
 412                     if(wishangle < 0) // detect direction using wishangle since the direction is not yet set
 413                     {
 414                         fwd = angle <= -wishangle;
 415                     }
 416                     else
 417                     {
 418                         fwd = angle >= -wishangle;
 419                     }
 420                 }
 421
 422                 // shift the strafe angle by 180° when strafing backwards
 423                 if(!fwd)
 424                 {
 425                     if(angle < 0) angle += 180;
 426                     else angle -= 180;
 427                 }
 428
 429                 // don't make the angle indicator switch side too much at ±180° if anti flicker is turned on
 430                 if(angle > (180 - antiflicker_angle) || angle < (-180 + antiflicker_angle))
 431                 {
 432                     straight_overturn = true;
 433                 }
 434             }
 435             else
 436             {
 437                 angle = 0;
 438             }
 439         }
 440         else // simulate turning for HUD setup
 441         {
 442             fwd = true;
 443             if(autocvar__hud_panel_strafehud_demo && ((time - demo_time) >= .025))
 444             {
 445                 demo_time = time;
 446                 demo_angle += demo_direction;
 447                 if(fabs(demo_angle) >= 55)
 448                 {
 449                     demo_direction = -demo_direction;
 450                 }
 451             }
 452             angle = demo_angle;
 453             wishangle = 45 * (demo_angle > 0 ? 1 : -1);
 454         }
 455
 456         // invert the wish angle when strafing backwards
 457         if(!fwd)
 458         {
 459             wishangle = -wishangle;
 460         }
 461
 462         // flip angles if v_flipped is enabled
 463         if(autocvar_v_flipped)
 464         {
 465             angle = -angle;
 466             wishangle = -wishangle;
 467         }
 468
 469         // determine whether the player is strafing left or right
 470         if(wishangle != 0)
 471         {
 472             direction = wishangle > 0 ? 1 : -1;
 473         }
 474         else
 475         {
 476             direction = (angle > antiflicker_angle && angle < (180 - antiflicker_angle)) ? 1 : (angle < -antiflicker_angle && angle > (-180 + antiflicker_angle)) ? -1 : 0;
 477         }
 478
 479         // best angle to strafe at
 480         bestangle = (speed > (movespeed - maxaccel) ? acos((movespeed - maxaccel) / speed) : 0) * RAD2DEG * (direction < 0 ? -1 : 1);
 481         prebestangle = (speed > movespeed ? acos(movespeed / speed) : 0) * RAD2DEG * (direction < 0 ? -1 : 1);
 482         odd_bestangle = -bestangle - wishangle;
 483         bestangle -= wishangle;
 484         prebestangle -= wishangle;
 485
 486         // various offsets and size calculations of hud indicator elements
 487         // how much is hidden by the current hud angle
 488         hidden_width = (360 - hudangle) / hudangle * panel_size.x;
 489         // current angle
 490         currentangle_size.x = autocvar_hud_panel_strafehud_angle_width;
 491         currentangle_size.y = autocvar_hud_panel_strafehud_angle_height;
 492         if(!autocvar_hud_panel_strafehud_uncapped)
 493         {
 494             currentangle_size.x = min(currentangle_size.x, 10);
 495             currentangle_size.y = min(currentangle_size.y, 10);
 496         }
 497         currentangle_size.x *= panel_size.x;
 498         currentangle_size.y *= panel_size.y;
 499         if(!autocvar_hud_panel_strafehud_uncapped)
 500         {
 501             currentangle_size.x = max(currentangle_size.x, 1);
 502             currentangle_size.y = max(currentangle_size.y, 1);
 503         }
 504         else
 505         {
 506             currentangle_size.y = max(currentangle_size.y, 0);
 507         }
 508         if(mode == 0)
 509         {
 510             currentangle_offset = angle/hudangle * panel_size.x;
 511         }
 512         else
 513         {
 514             currentangle_offset = bound(-hudangle/2, angle, hudangle/2)/hudangle * panel_size.x + panel_size.x/2;
 515         }
 516         // best strafe acceleration angle
 517         bestangle_offset        =  bestangle/hudangle * panel_size.x + panel_size.x/2;
 518         switch_bestangle_offset = -bestangle/hudangle * panel_size.x + panel_size.x/2;
 519         bestangle_width = panel_size.x * autocvar_hud_panel_strafehud_switch_width;
 520         if(!autocvar_hud_panel_strafehud_uncapped)
 521             bestangle_width = max(bestangle_width, 1);
 522
 523         if(((angle > -wishangle && direction < 0) || (angle < -wishangle && direction > 0)) && (direction != 0))
 524         {
 525             odd_angles = true;
 526             odd_bestangle_offset = odd_bestangle/hudangle * panel_size.x + panel_size.x/2;
 527             switch_odd_bestangle_offset = (odd_bestangle+bestangle*2)/hudangle * panel_size.x + panel_size.x/2;
 528         }
 529         // direction indicator
 530         direction_size_vertical.x = autocvar_hud_panel_strafehud_direction_width;
 531         if(!autocvar_hud_panel_strafehud_uncapped)
 532             direction_size_vertical.x = min(direction_size_vertical.x, 1);
 533         direction_size_vertical.x *= panel_size.y;
 534         if(!autocvar_hud_panel_strafehud_uncapped)
 535             direction_size_vertical.x = max(direction_size_vertical.x, 1);
 536         direction_size_vertical.y = panel_size.y + direction_size_vertical.x*2;
 537         direction_size_horizontal.x = panel_size.x * min(autocvar_hud_panel_strafehud_direction_length, .5);
 538         direction_size_horizontal.y = direction_size_vertical.x;
 539         // overturn
 540         overturn_width = 180/hudangle * panel_size.x;
 541
 542         // the neutral zone fills the whole strafe bar
 543         if(immobile)
 544         {
 545             // draw neutral zone
 546             if(panel_size.x > 0 && panel_size.y > 0 && autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha > 0)
 547             {
 548                 switch(autocvar_hud_panel_strafehud_style)
 549                 {
 550                     default:
 551                     case 0:
 552                         drawfill(panel_pos, panel_size, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 553                         break;
 554
 555                     case 1:
 556                         HUD_Panel_DrawProgressBar(panel_pos, panel_size, "progressbar", 1, 0, 0, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 557                 }
 558             }
 559         }
 560         else
 561         {
 562             // calculate various zones of the strafe-o-meter
 563             accelzone_width = (90 - fabs(bestangle + wishangle))/hudangle * panel_size.x;
 564             preaccelzone_width = (fabs(bestangle - prebestangle))/hudangle * panel_size.x;
 565             overturn_offset = accelzone_width + preaccelzone_width;
 566             accelzone_right_offset = preaccelzone_width;
 567             accelzone_left_offset = overturn_offset + overturn_width;
 568             preaccelzone_right_offset = 0;
 569             preaccelzone_left_offset = accelzone_left_offset + accelzone_width;
 570             neutral_width = 360/hudangle * panel_size.x - accelzone_width*2 - preaccelzone_width*2 - overturn_width;
 571             neutral_offset = direction < 0 ? preaccelzone_left_offset + preaccelzone_width : -neutral_width;
 572
 573             // shift hud if operating in view angle centered mode
 574             if(mode == 0)
 575             {
 576                 shift_offset = -currentangle_offset;
 577                 bestangle_offset += shift_offset;
 578                 switch_bestangle_offset += shift_offset;
 579                 odd_bestangle_offset += shift_offset;
 580                 switch_odd_bestangle_offset += shift_offset;
 581             }
 582             if(direction < 0) shift_offset += -360/hudangle * panel_size.x;
 583             // calculate how far off-center the strafe zones currently are
 584             shift_offset += (panel_size.x + neutral_width)/2 - wishangle/hudangle * panel_size.x;
 585             // shift strafe zones into correct place
 586             neutral_offset += shift_offset;
 587             accelzone_left_offset += shift_offset;
 588             accelzone_right_offset += shift_offset;
 589             preaccelzone_left_offset += shift_offset;
 590             preaccelzone_right_offset += shift_offset;
 591             overturn_offset += shift_offset;
 592
 593             // draw left acceleration zone
 594             HUD_Panel_DrawStrafeHUD(accelzone_left_offset, accelzone_width, autocvar_hud_panel_strafehud_bar_accel_color, autocvar_hud_panel_strafehud_bar_accel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 1);
 595             HUD_Panel_DrawStrafeHUD(preaccelzone_left_offset, preaccelzone_width, autocvar_hud_panel_strafehud_bar_preaccel_color, autocvar_hud_panel_strafehud_bar_preaccel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 0);
 596
 597             // draw right acceleration zone
 598             HUD_Panel_DrawStrafeHUD(accelzone_right_offset, accelzone_width, autocvar_hud_panel_strafehud_bar_accel_color, autocvar_hud_panel_strafehud_bar_accel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 2);
 599             HUD_Panel_DrawStrafeHUD(preaccelzone_right_offset, preaccelzone_width, autocvar_hud_panel_strafehud_bar_preaccel_color, autocvar_hud_panel_strafehud_bar_preaccel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 0);
 600
 601             // draw overturn zone
 602             HUD_Panel_DrawStrafeHUD(overturn_offset, overturn_width, autocvar_hud_panel_strafehud_bar_overturn_color, autocvar_hud_panel_strafehud_bar_overturn_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 3);
 603
 604             // draw neutral zone
 605             HUD_Panel_DrawStrafeHUD(neutral_offset, neutral_width, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 0);
 606
 607             if(speed >= minspeed && bestangle_width > 0) // only draw indicators if minspeed is reached
 608             {
 609                 // draw the switch indicator(s)
 610                 float offset = !odd_angles ? bestangle_offset : odd_bestangle_offset;
 611                 float switch_offset = !odd_angles ? switch_bestangle_offset : switch_odd_bestangle_offset;
 612
 613                 // remove switch indicator width from offset
 614                 if(direction < 0)
 615                 {
 616                     if(!odd_angles)
 617                         offset -= bestangle_width;
 618                     else
 619                         switch_offset -= bestangle_width;
 620                 }
 621                 else
 622                 {
 623                     if(!odd_angles)
 624                         switch_offset -= bestangle_width;
 625                     else
 626                         offset -= bestangle_width;
 627                 }
 628
 629                 HUD_Panel_DrawStrafeHUD(switch_offset, bestangle_width, autocvar_hud_panel_strafehud_switch_color, autocvar_hud_panel_strafehud_switch_alpha * panel_fg_alpha, 0, 0);
 630                 if(direction == 0) HUD_Panel_DrawStrafeHUD(offset, bestangle_width, autocvar_hud_panel_strafehud_switch_color, autocvar_hud_panel_strafehud_switch_alpha * panel_fg_alpha, 0, 0);
 631             }
 632         }
 633
 634         // slick detector
 635         slickdetector_height = max(autocvar_hud_panel_strafehud_slickdetector_height, 0);
 636         if(!autocvar_hud_panel_strafehud_uncapped)
 637              slickdetector_height = min(slickdetector_height, 1);
 638         slickdetector_height *= panel_size.y;
 639         if(autocvar_hud_panel_strafehud_slickdetector_range > 0 && autocvar_hud_panel_strafehud_slickdetector_alpha > 0 && slickdetector_height > 0 && panel_size.x > 0)
 640         {
 641             float slicksteps = max(autocvar_hud_panel_strafehud_slickdetector_granularity, 0);
 642             bool slickdetected = false;
 643
 644             if(!autocvar_hud_panel_strafehud_uncapped)
 645                 slicksteps = min(slicksteps, 4);
 646             slicksteps = 90 / pow(2, slicksteps);
 647
 648             if(islocal) slickdetected = IS_ONSLICK(strafeplayer); // don't need to traceline if already touching slick
 649
 650             // traceline into every direction
 651             trace_dphitq3surfaceflags = 0;
 652             for(float i = 0; i < 360 && !slickdetected; i += slicksteps)
 653             {
 654                 vector slickoffset;
 655                 float slickrotate;
 656                 slickoffset.z = -cos(i * DEG2RAD) * autocvar_hud_panel_strafehud_slickdetector_range;
 657                 slickrotate = sin(i * DEG2RAD) * autocvar_hud_panel_strafehud_slickdetector_range;
 658                 if(i != 0 && i != 180)
 659                 {
 660                     for(float j = 0; j < 180 && !slickdetected; j += slicksteps)
 661                     {
 662                         slickoffset.x = sin(j * DEG2RAD) * slickrotate;
 663                         slickoffset.y = cos(j * DEG2RAD) * slickrotate;
 664
 665                         traceline(strafeplayer.origin, strafeplayer.origin + slickoffset, MOVE_WORLDONLY, NULL);
 666                         if((PHYS_FRICTION(strafeplayer) == 0 && trace_fraction < 1) || trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK) slickdetected = true;
 667                     }
 668                 }
 669                 else
 670                 {
 671                     slickoffset.x = slickoffset.y = 0;
 672                     traceline(strafeplayer.origin, strafeplayer.origin + slickoffset, MOVE_WORLDONLY, NULL);
 673                     if((PHYS_FRICTION(strafeplayer) == 0 && trace_fraction < 1) || trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK) slickdetected = true;
 674                 }
 675             }
 676
 677             // if a traceline hit a slick surface
 678             if(slickdetected)
 679             {
 680                 vector slickdetector_size = panel_size;
 681                 slickdetector_size.y = slickdetector_height;
 682                 // top horizontal line
 683                 drawfill(panel_pos - eY * slickdetector_size.y, slickdetector_size, autocvar_hud_panel_strafehud_slickdetector_color, autocvar_hud_panel_strafehud_slickdetector_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 684                 // bottom horizontal line
 685                 drawfill(panel_pos + eY * panel_size.y, slickdetector_size, autocvar_hud_panel_strafehud_slickdetector_color, autocvar_hud_panel_strafehud_slickdetector_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 686             }
 687         }
 688
 689         if(direction != 0 && direction_size_vertical.x > 0 && autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha > 0)
 690         {
 691             bool indicator_direction = direction < 0;
 692             // invert left/right when strafing backwards or when strafing towards the opposite side indicated by the direction variable
 693             // if both conditions are true then it's inverted twice hence not inverted at all
 694             if(!fwd != odd_angles)
 695             {
 696                 indicator_direction = !indicator_direction;
 697             }
 698             // draw the direction indicator caps at the sides of the hud
 699             // vertical line
 700             if(direction_size_vertical.y > 0) drawfill(panel_pos - eY * direction_size_horizontal.y + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x), direction_size_vertical, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 701             // top horizontal line
 702             drawfill(panel_pos + eX * (indicator_direction ? 0 : panel_size.x - direction_size_horizontal.x) - eY * direction_size_horizontal.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 703             // bottom horizontal line
 704             drawfill(panel_pos + eX * (indicator_direction ? 0 : panel_size.x - direction_size_horizontal.x) + eY * panel_size.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 705         }
 706
 707         if(speed < ((movespeed - maxaccel) + antiflicker_speed) && !immobile)
 708         {
 709             bestangle_anywhere = true; // moving forward should suffice to gain speed
 710         }
 711
 712         // draw the actual strafe angle
 713         if(!bestangle_anywhere && !immobile) // player gains speed with strafing
 714         {
 715             if((direction > 0 && (angle >= bestangle || angle <= -(bestangle + wishangle*2))) ||
 716                (direction < 0 && (angle <= bestangle || angle >= -(bestangle + wishangle*2))))
 717             currentangle_color = autocvar_hud_panel_strafehud_angle_accel_color;
 718         }
 719
 720         if(fabs(angle + wishangle) > 90) // player is overturning
 721         {
 722             currentangle_color = autocvar_hud_panel_strafehud_angle_overturn_color;
 723         }
 724         else if(bestangle_anywhere) // player gains speed without strafing
 725         {
 726             currentangle_color = autocvar_hud_panel_strafehud_angle_accel_color;
 727         }
 728
 729         if(mode == 0 || straight_overturn)
 730         {
 731             currentangle_offset = panel_size.x/2;
 732         }
 733
 734         if(autocvar_hud_panel_strafehud_style == 2 && !immobile)
 735         {
 736             float moveangle = angle + wishangle;
 737             float strafeangle = (bestangle + wishangle) * (direction < 0 ? -1 : 1);
 738             float strafe_ratio = 0;
 739             if(fabs(moveangle) > 90)
 740             {
 741                 strafe_ratio = -((fabs(moveangle) - 90) / 90);
 742                 if(strafe_ratio < -1) strafe_ratio = -2 - strafe_ratio;
 743             }
 744             else
 745             {
 746                 if(moveangle >= strafeangle)
 747                 {
 748                     strafe_ratio = 1 - (moveangle - strafeangle) / (90 - strafeangle);
 749                 }
 750                 else if(moveangle <= -strafeangle)
 751                 {
 752                     strafe_ratio = 1 - (moveangle + strafeangle) / (-90 + strafeangle);
 753                 }
 754             }
 755             if(strafe_ratio < 0)
 756             {
 757                 currentangle_color = StrafeHUD_mixColors(autocvar_hud_panel_strafehud_angle_neutral_color, autocvar_hud_panel_strafehud_angle_overturn_color, -strafe_ratio);
 758             }
 759             else
 760             {
 761                 currentangle_color = StrafeHUD_mixColors(autocvar_hud_panel_strafehud_angle_neutral_color, autocvar_hud_panel_strafehud_angle_accel_color, strafe_ratio);
 762             }
 763         }
 764
 765         float angleheight_offset = currentangle_size.y;
 766         float ghost_offset = 0;
 767         if(autocvar_hud_panel_strafehud_bestangle && direction != 0)
 768         {
 769             ghost_offset = !odd_angles ? bestangle_offset : odd_bestangle_offset;
 770             if(ghost_offset < 0) ghost_offset = 0;
 771             if(ghost_offset > panel_size.x) ghost_offset = panel_size.x;
 772         }
 773
 774         switch(autocvar_hud_panel_strafehud_angle_style)
 775         {
 776             case 1:
 777                 if(currentangle_size.x > 0 && currentangle_size.y > 0)
 778                 {
 779                     if(autocvar_hud_panel_strafehud_bestangle && direction != 0) drawfill(panel_pos - eY * ((currentangle_size.y - panel_size.y) / 2) + eX * (ghost_offset - currentangle_size.x/2), currentangle_size, autocvar_hud_panel_strafehud_bestangle_color, autocvar_hud_panel_strafehud_bestangle_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 780                     drawfill(panel_pos - eY * ((currentangle_size.y - panel_size.y) / 2) + eX * (currentangle_offset - currentangle_size.x/2), currentangle_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 781                 }
 782                 break;
 783             case 2:
 784                 if(currentangle_size.x > 0 && currentangle_size.y > 0)
 785                 {
 786                     vector line_size = currentangle_size;
 787                     line_size.y = currentangle_size.y / (bound(2, autocvar_hud_panel_strafehud_angle_dashes, currentangle_size.y)*2-1);
 788                     for(float i = 0; i < currentangle_size.y; i += line_size.y*2)
 789                     {
 790                         if(i + line_size.y*2 >= currentangle_size.y) line_size.y = currentangle_size.y - i;
 791                         if(autocvar_hud_panel_strafehud_bestangle && direction != 0) drawfill(panel_pos - eY * ((currentangle_size.y - panel_size.y) / 2 - i) + eX * (ghost_offset - line_size.x/2), line_size, autocvar_hud_panel_strafehud_bestangle_color, autocvar_hud_panel_strafehud_bestangle_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 792                         drawfill(panel_pos - eY * ((currentangle_size.y - panel_size.y) / 2 - i) + eX * (currentangle_offset - line_size.x/2), line_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 793                     }
 794                 }
 795                 break;
 796             case 0:
 797             default:
 798                 // don't offset text and arrows if the angle indicator line isn't drawn
 799                 angleheight_offset = panel_size.y;
 800         }
 801
 802         if(autocvar_hud_panel_strafehud_angle_arrow > 0)
 803         {
 804             if(arrow_size > 0)
 805             {
 806                 if(autocvar_hud_panel_strafehud_angle_arrow == 1 || autocvar_hud_panel_strafehud_angle_arrow >= 3)
 807                 {
 808                     if(autocvar_hud_panel_strafehud_bestangle && direction != 0) StrafeHUD_drawStrafeArrow(panel_pos + eY * ((panel_size.y - angleheight_offset) / 2) + eX * ghost_offset, arrow_size, autocvar_hud_panel_strafehud_bestangle_color, autocvar_hud_panel_strafehud_bestangle_alpha * panel_fg_alpha, true);
 809                     StrafeHUD_drawStrafeArrow(panel_pos + eY * ((panel_size.y - angleheight_offset) / 2) + eX * currentangle_offset, arrow_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, true);
 810                 }
 811                 if(autocvar_hud_panel_strafehud_angle_arrow >= 2)
 812                 {
 813                     if(autocvar_hud_panel_strafehud_bestangle && direction != 0) StrafeHUD_drawStrafeArrow(panel_pos + eY * ((panel_size.y - angleheight_offset) / 2 + angleheight_offset) + eX * ghost_offset, arrow_size, autocvar_hud_panel_strafehud_bestangle_color, autocvar_hud_panel_strafehud_bestangle_alpha * panel_fg_alpha, false);
 814                     StrafeHUD_drawStrafeArrow(panel_pos + eY * ((panel_size.y - angleheight_offset) / 2 + angleheight_offset) + eX * currentangle_offset, arrow_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, false);
 815                 }
 816             }
 817         }
 818
 819         draw_beginBoldFont();
 820         // show speed when crossing the start trigger
 821         if(autocvar_hud_panel_strafehud_startspeed_fade > 0)
 822         {
 823             float text_alpha = 0;
 824             if((race_nextcheckpoint == 1) || (race_checkpoint == 254 && race_nextcheckpoint == 255)) // check if the start trigger was hit (will also trigger if the finish trigger was hit if those have the same ID)
 825             {
 826                 if(starttime != race_checkpointtime)
 827                 {
 828                     starttime = race_checkpointtime;
 829                     startspeed = speed;
 830                 }
 831             }
 832             if(startspeed >= 0)
 833             {
 834                 text_alpha = cos(((time - starttime) / autocvar_hud_panel_strafehud_startspeed_fade) * 90 * DEG2RAD); // fade non-linear like the physics panel does
 835                 if((time - starttime) > autocvar_hud_panel_strafehud_startspeed_fade)
 836                 {
 837                     startspeed = -1;
 838                 }
 839             }
 840             if(startspeed >= 0 && text_alpha > 0 && autocvar_hud_panel_strafehud_startspeed_size > 0)
 841             {
 842                 vector startspeed_size = panel_size;
 843                 startspeed_size.y = autocvar_hud_panel_strafehud_startspeed_size;
 844                 if(!autocvar_hud_panel_strafehud_uncapped)
 845                     startspeed_size.y = min(startspeed_size.y, 10);
 846                 startspeed_size.y *= panel_size.y;
 847                 if(!autocvar_hud_panel_strafehud_uncapped)
 848                     startspeed_size.y = max(startspeed_size.y, 1);
 849
 850                 float text_offset = 0;
 851                 if((autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha > 0) || (autocvar_hud_panel_strafehud_bestangle && autocvar_hud_panel_strafehud_bestangle_alpha * panel_fg_alpha > 0))
 852                 {
 853                     text_offset = (angleheight_offset - panel_size.y) / 2;
 854                     if(arrow_size > 0 && autocvar_hud_panel_strafehud_angle_arrow >= 2)
 855                         text_offset += arrow_size;
 856                     // make sure text doesn't draw inside the strafehud bar
 857                     text_offset = max(text_offset, 0);
 858                 }
 859
 860                 drawstring_aspect(panel_pos + eY * (panel_size.y + text_offset), strcat(ftos_decimals(startspeed * speed_conversion_factor, 2), autocvar_hud_panel_strafehud_unit_show ? speed_unit : ""), startspeed_size, autocvar_hud_panel_strafehud_startspeed_color, text_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 861             }
 862         }
 863         else
 864         {
 865             starttime = 0;
 866             startspeed = -1;
 867         }
 868
 869         // experimental: show height achieved by a single jump (doesn't work in low gravity and may not be 100% accurate)
 870         if(autocvar_hud_panel_strafehud_jumpheight_fade > 0)
 871         {
 872             float text_alpha = 0;
 873             float jumpheight_min = max(autocvar_hud_panel_strafehud_jumpheight_min, 0);
 874             float jumpheight_current = strafeplayer.origin.z;
 875             float jumpspeed_current = strafeplayer.velocity.z;
 876             if(jumpspeed_prev <= jumpspeed_current || jumpheight_prev > jumpheight_current || onground || swimming || IS_DEAD(strafeplayer) || spectating)
 877             {
 878                 // tries to catch kill and spectate but those are not reliable, should just hook to kill/spectate/teleport and reset jump height there
 879                 jumprestart = true;
 880             }
 881             else
 882             {
 883                 if(jumpheight < 0 || jumprestart)
 884                 {
 885                     jumprestart = false;
 886                     jumpheight = 0;
 887                 }
 888                 else
 889                 {
 890                     jumpheight += jumpheight_current - jumpheight_prev;
 891                 }
 892                 if((jumpheight * length_conversion_factor) > jumpheight_min && jumpheight > jumpheight_persistent)
 893                 {
 894                     jumptime = time;
 895                     jumpheight_persistent = jumpheight;
 896                 }
 897             }
 898             jumpheight_prev = jumpheight_current;
 899             jumpspeed_prev = jumpspeed_current;
 900             if(jumpheight_persistent > 0)
 901             {
 902                 text_alpha = cos(((time - jumptime) / autocvar_hud_panel_strafehud_jumpheight_fade) * 90 * DEG2RAD); // fade non-linear like the physics panel does
 903                 if((time - jumptime) > autocvar_hud_panel_strafehud_jumpheight_fade)
 904                 {
 905                     jumpheight_persistent = -1;
 906                 }
 907             }
 908             if(jumpheight_persistent > 0 && text_alpha > 0 && autocvar_hud_panel_strafehud_jumpheight_size > 0)
 909             {
 910                 vector jumpheight_size = panel_size;
 911                 jumpheight_size.y = autocvar_hud_panel_strafehud_jumpheight_size;
 912                 if(!autocvar_hud_panel_strafehud_uncapped)
 913                     jumpheight_size.y = min(jumpheight_size.y, 10);
 914                 jumpheight_size.y *= panel_size.y;
 915                 if(!autocvar_hud_panel_strafehud_uncapped)
 916                     jumpheight_size.y = max(jumpheight_size.y, 1);
 917
 918                 float text_offset = 0;
 919                 if((autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha > 0) || (autocvar_hud_panel_strafehud_bestangle && autocvar_hud_panel_strafehud_bestangle_alpha * panel_fg_alpha > 0))
 920                 {
 921                     text_offset = (angleheight_offset - panel_size.y) / 2;
 922                     if(arrow_size > 0 && autocvar_hud_panel_strafehud_angle_arrow == 1 || autocvar_hud_panel_strafehud_angle_arrow >= 3)
 923                         text_offset += arrow_size;
 924                     // make sure text doesn't draw inside the strafehud bar
 925                     text_offset = max(text_offset, 0);
 926                 }
 927
 928                 drawstring_aspect(panel_pos - eY * (jumpheight_size.y + text_offset), strcat(ftos_decimals(jumpheight_persistent * length_conversion_factor, length_decimals), autocvar_hud_panel_strafehud_unit_show ? length_unit : ""), jumpheight_size, autocvar_hud_panel_strafehud_jumpheight_color, text_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 929             }
 930         }
 931         else
 932         {
 933             jumpheight_prev = jumpspeed_prev = 0;
 934             jumpheight = jumpheight_persistent = -1;
 935         }
 936         draw_endBoldFont();
 937     }
 938 }
 939
 940 // functions to make hud elements align perfectly in the hud area
 941 void HUD_Panel_DrawStrafeHUD(float offset, float width, vector color, float alpha, int type, int gradientType)
 942 {
 943     float mirror_offset, mirror_width;
 944     vector size = panel_size;
 945     vector mirror_size = panel_size;
 946     int gradient_start;
 947     float gradient_offset, gradient_mirror_offset;
 948     float overflow_width = 0, overflow_mirror_width = 0;
 949
 950     float original_width = width;
 951
 952     if(alpha <= 0 && type != 2 || width <= 0) return;
 953
 954     if(type == 2 && gradientType == 0) type = 0;
 955
 956     if(offset < 0)
 957     {
 958         mirror_width = min(fabs(offset), width);
 959         mirror_offset = panel_size.x + hidden_width - fabs(offset);
 960         width += offset;
 961         offset = 0;
 962     }
 963     else
 964     {
 965         mirror_width = min(offset + width - panel_size.x - hidden_width, width);
 966         mirror_offset = max(offset - panel_size.x - hidden_width, 0);
 967     }
 968
 969     if(width < 0) width = 0;
 970     if((offset + width) > panel_size.x)
 971     {
 972         overflow_width = (offset + width) - panel_size.x;
 973         width = panel_size.x - offset;
 974     }
 975     if(mirror_offset < 0)
 976     {
 977         mirror_width += mirror_offset;
 978         mirror_offset = 0;
 979     }
 980
 981     if(mirror_width < 0) mirror_width = 0;
 982     if((mirror_offset + mirror_width) > panel_size.x)
 983     {
 984         overflow_mirror_width = (mirror_offset + mirror_width) - panel_size.x;
 985         mirror_width = panel_size.x - mirror_offset;
 986     }
 987
 988     if(direction < 0) // swap mirror and non-mirror values if direction points left
 989     {
 990         offset += mirror_offset;
 991         mirror_offset = offset - mirror_offset;
 992         offset -= mirror_offset;
 993
 994         width += mirror_width;
 995         mirror_width = width - mirror_width;
 996         width -= mirror_width;
 997
 998         overflow_width += overflow_mirror_width;
 999         overflow_mirror_width = overflow_width - overflow_mirror_width;
1000         overflow_width -= overflow_mirror_width;
1001     }
1002
1003     size.x = width;
1004     mirror_size.x = mirror_width;
1005
1006     switch(type)
1007     {
1008         default:
1009         case 0: // no styling (drawfill)
1010             if(mirror_size.x > 0 && mirror_size.y > 0) drawfill(panel_pos + eX * mirror_offset, mirror_size, color, alpha, DRAWFLAG_NORMAL);
1011             if(size.x > 0 && size.y > 0) drawfill(panel_pos + eX * offset, size, color, alpha, DRAWFLAG_NORMAL);
1012             break;
1013
1014         case 1: // progress bar style
1015             if(mirror_size.x > 0 && mirror_size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * mirror_offset, mirror_size, "progressbar", 1, 0, 0, color, alpha, DRAWFLAG_NORMAL);
1016             if(size.x > 0 && size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * offset, size, "progressbar", 1, 0, 0, color, alpha, DRAWFLAG_NORMAL);
1017             break;
1018
1019         case 2: // gradient style (types: 1 = left, 2 = right, 3 = both)
1020             // determine whether the gradient starts in the mirrored or the non-mirrored area
1021             if(offset == 0 && mirror_offset == 0) gradient_start = width > mirror_width ? 2 : 1;
1022             else if(offset == 0) gradient_start = 2;
1023             else if(mirror_offset == 0) gradient_start = 1;
1024             else gradient_start = 0;
1025
1026             switch(gradient_start){
1027                 default:
1028                 case 0: // no offset required
1029                     gradient_offset = gradient_mirror_offset = 0;
1030                     break;
1031                 case 1: // offset starts in non-mirrored area, mirrored area requires offset
1032                     gradient_offset = 0;
1033                     gradient_mirror_offset = original_width - (mirror_width + overflow_mirror_width);
1034                     break;
1035                 case 2: // offset starts in mirrored area, non-mirrored area requires offset
1036                     gradient_offset = original_width - (width + overflow_width);
1037                     gradient_mirror_offset = 0;
1038             }
1039
1040             StrafeHUD_drawGradient(color, autocvar_hud_panel_strafehud_bar_neutral_color, mirror_size, original_width, mirror_offset, alpha, gradient_mirror_offset, gradientType);
1041             StrafeHUD_drawGradient(color, autocvar_hud_panel_strafehud_bar_neutral_color, size, original_width, offset, alpha, gradient_offset, gradientType);
1042     }
1043 }
1044
1045 vector StrafeHUD_mixColors(vector color1, vector color2, float ratio)
1046 {
1047     vector mixedColor;
1048     if(ratio <= 0) return color1;
1049     if(ratio >= 1) return color2;
1050     mixedColor.x = color1.x + (color2.x - color1.x) * ratio;
1051     mixedColor.y = color1.y + (color2.y - color1.y) * ratio;
1052     mixedColor.z = color1.z + (color2.z - color1.z) * ratio;
1053     return mixedColor;
1054 }
1055
1056 void StrafeHUD_drawGradient(vector color1, vector color2, vector size, float original_width, float offset, float alpha, float gradientOffset, int gradientType)
1057 {
1058     float color_ratio, alpha1, alpha2;
1059     vector gradient_size = size;
1060     alpha1 = bound(0, alpha, 1);
1061     alpha2 = bound(0, autocvar_hud_panel_strafehud_bar_neutral_alpha, 1);
1062     if((alpha1+alpha2) == 0) return;
1063     color_ratio = alpha1/(alpha1+alpha2);
1064     for(int i = 0; i < size.x; ++i)
1065     {
1066         float ratio, alpha_ratio, combine_ratio1, combine_ratio2;
1067         gradient_size.x = size.x - i < 1 ? size.x - i : 1;
1068         ratio = (i + gradientOffset) / original_width * (gradientType == 3 ? 2 : 1);
1069         if(ratio > 1) ratio = 2 - ratio;
1070         if(gradientType != 2) ratio = 1 - ratio;
1071         alpha_ratio = alpha1 - (alpha1 - alpha2) * ratio;
1072         combine_ratio1 = ratio*(1-color_ratio);
1073         combine_ratio2 = (1-ratio)*color_ratio;
1074         ratio = (combine_ratio1 + combine_ratio2) == 0 ? 1 : combine_ratio1/(combine_ratio1 + combine_ratio2);
1075         if(alpha_ratio > 0) drawfill(panel_pos + eX * (offset + i), gradient_size, StrafeHUD_mixColors(color1, color2, ratio), alpha_ratio, DRAWFLAG_NORMAL);
1076     }
1077 }
1078
1079 // draw the strafe arrows (inspired by drawspritearrow() in common/mutators/mutator/waypoints/waypointsprites.qc)
1080 void StrafeHUD_drawStrafeArrow(vector origin, float size, vector color, float alpha, bool flipped)
1081 {
1082     if(flipped) origin -= size*eY;
1083     R_BeginPolygon("", DRAWFLAG_NORMAL, true);
1084     R_PolygonVertex(origin + (flipped ? size*eY : '0 0 0')          , '0 0 0', color, alpha);
1085     R_PolygonVertex(origin + (flipped ? '0 0 0' : size*eY) - size*eX, '0 0 0', color, alpha);
1086     R_PolygonVertex(origin + (flipped ? '0 0 0' : size*eY) + size*eX, '0 0 0', color, alpha);
1087     R_EndPolygon();
1088 }
1089
1090 // length unit conversion (km and miles are only included to match the GetSpeedUnit* functions)
1091 float GetLengthUnitFactor(int length_unit)
1092 {
1093     switch(length_unit)
1094     {
1095         default:
1096         case 1: return 1.0;
1097         case 2: return 0.0254;
1098         case 3: return 0.0254 * 0.001;
1099         case 4: return 0.0254 * 0.001 * 0.6213711922;
1100         case 5: return 0.0254 * 0.001 * 0.5399568035;
1101     }
1102 }
1103
1104 string GetLengthUnit(int length_unit)
1105 {
1106     switch(length_unit)
1107     {
1108         // translator-friendly strings without the initial space
1109         default:
1110         case 1: return strcat(" ", _("qu"));
1111         case 2: return strcat(" ", _("m"));
1112         case 3: return strcat(" ", _("km"));
1113         case 4: return strcat(" ", _("mi"));
1114         case 5: return strcat(" ", _("nmi"));
1115     }
1116 }