qcsrc/client/hud.qc

   1 /*
   2 ==================
   3 Misc HUD functions
   4 ==================
   5 */
   6
   7 // a border picture is a texture containing nine parts:
   8 //   1/4 width: left part
   9 //   1/2 width: middle part (stretched)
  10 //   1/4 width: right part
  11 // divided into
  12 //   1/4 height: top part
  13 //   1/2 height: middle part (stretched)
  14 //   1/4 height: bottom part
  15 void draw_BorderPicture(vector theOrigin, string pic, vector theSize, vector theColor, float theAlpha, vector theBorderSize)
  16 {
  17     if (theBorderSize_x < 0 && theBorderSize_y < 0) // draw whole image as it is
  18     {
  19                 drawpic(theOrigin, pic, theSize, theColor, theAlpha, 0);
  20                 return;
  21     }
  22         if (theBorderSize_x == 0 && theBorderSize_y == 0) // no border
  23         {
  24                 // draw only the central part
  25                 drawsubpic(theOrigin, theSize, pic, '0.25 0.25 0', '0.5 0.5 0', theColor, theAlpha, 0);
  26                 return;
  27         }
  28
  29         vector dX, dY;
  30         vector width, height;
  31         vector bW, bH;
  32         //pic = draw_UseSkinFor(pic);
  33         width = eX * theSize_x;
  34         height = eY * theSize_y;
  35         if(theSize_x <= theBorderSize_x * 2)
  36         {
  37                 // not wide enough... draw just left and right then
  38                 bW = eX * (0.25 * theSize_x / (theBorderSize_x * 2));
  39                 if(theSize_y <= theBorderSize_y * 2)
  40                 {
  41                         // not high enough... draw just corners
  42                         bH = eY * (0.25 * theSize_y / (theBorderSize_y * 2));
  43                         drawsubpic(theOrigin,                 width * 0.5 + height * 0.5, pic, '0 0 0',           bW + bH, theColor, theAlpha, 0);
  44                         drawsubpic(theOrigin + width   * 0.5, width * 0.5 + height * 0.5, pic, eX - bW,           bW + bH, theColor, theAlpha, 0);
  45                         drawsubpic(theOrigin + height  * 0.5, width * 0.5 + height * 0.5, pic, eY - bH,           bW + bH, theColor, theAlpha, 0);
  46                         drawsubpic(theOrigin + theSize * 0.5, width * 0.5 + height * 0.5, pic, eX + eY - bW - bH, bW + bH, theColor, theAlpha, 0);
  47                 }
  48                 else
  49                 {
  50                         dY = theBorderSize_x * eY;
  51                         drawsubpic(theOrigin,                             width * 0.5          +     dY, pic, '0 0    0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  52                         drawsubpic(theOrigin + width * 0.5,               width * 0.5          +     dY, pic, '0 0    0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  53                         drawsubpic(theOrigin                        + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0',           '0 0.5  0' + bW, theColor, theAlpha, 0);
  54                         drawsubpic(theOrigin + width * 0.5          + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0' + eX - bW, '0 0.5  0' + bW, theColor, theAlpha, 0);
  55                         drawsubpic(theOrigin               + height - dY, width * 0.5          +     dY, pic, '0 0.75 0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  56                         drawsubpic(theOrigin + width * 0.5 + height - dY, width * 0.5          +     dY, pic, '0 0.75 0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  57                 }
  58         }
  59         else
  60         {
  61                 if(theSize_y <= theBorderSize_y * 2)
  62                 {
  63                         // not high enough... draw just top and bottom then
  64                         bH = eY * (0.25 * theSize_y / (theBorderSize_y * 2));
  65                         dX = theBorderSize_x * eX;
  66                         drawsubpic(theOrigin,                                         dX + height * 0.5, pic, '0    0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  67                         drawsubpic(theOrigin + dX,                        width - 2 * dX + height * 0.5, pic, '0.25 0 0',           '0.5  0 0' + bH, theColor, theAlpha, 0);
  68                         drawsubpic(theOrigin + width - dX,                            dX + height * 0.5, pic, '0.75 0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  69                         drawsubpic(theOrigin              + height * 0.5,             dX + height * 0.5, pic, '0    0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  70                         drawsubpic(theOrigin + dX         + height * 0.5, width - 2 * dX + height * 0.5, pic, '0.25 0 0' + eY - bH, '0.5  0 0' + bH, theColor, theAlpha, 0);
  71                         drawsubpic(theOrigin + width - dX + height * 0.5,             dX + height * 0.5, pic, '0.75 0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  72                 }
  73                 else
  74                 {
  75                         dX = theBorderSize_x * eX;
  76                         dY = theBorderSize_x * eY;
  77                         drawsubpic(theOrigin,                                        dX          +     dY, pic, '0    0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  78                         drawsubpic(theOrigin                  + dX,      width - 2 * dX          +     dY, pic, '0.25 0    0', '0.5  0.25 0', theColor, theAlpha, 0);
  79                         drawsubpic(theOrigin          + width - dX,                  dX          +     dY, pic, '0.75 0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  80                         drawsubpic(theOrigin          + dY,                          dX + height - 2 * dY, pic, '0    0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
  81                         drawsubpic(theOrigin          + dY         + dX, width - 2 * dX + height - 2 * dY, pic, '0.25 0.25 0', '0.5  0.5  0', theColor, theAlpha, 0);
  82                         drawsubpic(theOrigin          + dY + width - dX,             dX + height - 2 * dY, pic, '0.75 0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
  83                         drawsubpic(theOrigin + height - dY,                          dX          +     dY, pic, '0    0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
  84                         drawsubpic(theOrigin + height - dY         + dX, width - 2 * dX          +     dY, pic, '0.25 0.75 0', '0.5  0.25 0', theColor, theAlpha, 0);
  85                         drawsubpic(theOrigin + height - dY + width - dX,             dX          +     dY, pic, '0.75 0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
  86                 }
  87         }
  88 }
  89
  90 vector HUD_Get_Num_Color (float x, float maxvalue)
  91 {
  92         float blinkingamt;
  93         vector color;
  94         if(x >= maxvalue) {
  95                 color_x = sin(2*M_PI*time);
  96                 color_y = 1;
  97                 color_z = sin(2*M_PI*time);
  98         }
  99         else if(x > maxvalue * 0.75) {
 100                 color_x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
 101                 color_y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
 102                 color_z = 0;
 103         }
 104         else if(x > maxvalue * 0.5) {
 105                 color_x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
 106                 color_y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
 107                 color_z = 1 - (x-100)*0.02; // blue value between 1 -> 0
 108         }
 109         else if(x > maxvalue * 0.25) {
 110                 color_x = 1;
 111                 color_y = 1;
 112                 color_z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
 113         }
 114         else if(x > maxvalue * 0.1) {
 115                 color_x = 1;
 116                 color_y = (x-20)*90/27/100; // green value between 0 -> 1
 117                 color_z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
 118         }
 119         else {
 120                 color_x = 1;
 121                 color_y = 0;
 122                 color_z = 0;
 123         }
 124
 125         blinkingamt = (1 - x/maxvalue/0.25);
 126         if(blinkingamt > 0)
 127         {
 128                 color_x = color_x - color_x * blinkingamt * sin(2*M_PI*time);
 129                 color_y = color_y - color_y * blinkingamt * sin(2*M_PI*time);
 130                 color_z = color_z - color_z * blinkingamt * sin(2*M_PI*time);
 131         }
 132         return color;
 133 }
 134
 135 float stringwidth_colors(string s, vector theSize)
 136 {
 137         return stringwidth(s, TRUE, theSize);
 138 }
 139
 140 float stringwidth_nocolors(string s, vector theSize)
 141 {
 142         return stringwidth(s, FALSE, theSize);
 143 }
 144
 145 void drawstringright(vector position, string text, vector theScale, vector rgb, float theAlpha, float flag)
 146 {
 147         position_x -= 2 / 3 * strlen(text) * theScale_x;
 148         drawstring(position, text, theScale, rgb, theAlpha, flag);
 149 }
 150
 151 void drawstringcenter(vector position, string text, vector theScale, vector rgb, float theAlpha, float flag)
 152 {
 153         position_x = 0.5 * (vid_conwidth - 0.6025 * strlen(text) * theScale_x);
 154         drawstring(position, text, theScale, rgb, theAlpha, flag);
 155 }
 156
 157 // return the string of the onscreen race timer
 158 string MakeRaceString(float cp, float mytime, float histime, float lapdelta, string hisname)
 159 {
 160         string col;
 161         string timestr;
 162         string cpname;
 163         string lapstr;
 164         lapstr = "";
 165
 166         if(histime == 0) // goal hit
 167         {
 168                 if(mytime > 0)
 169                 {
 170                         timestr = strcat("+", ftos_decimals(+mytime, TIME_DECIMALS));
 171                         col = "^1";
 172                 }
 173                 else if(mytime == 0)
 174                 {
 175                         timestr = "+0.0";
 176                         col = "^3";
 177                 }
 178                 else
 179                 {
 180                         timestr = strcat("-", ftos_decimals(-mytime, TIME_DECIMALS));
 181                         col = "^2";
 182                 }
 183
 184                 if(lapdelta > 0)
 185                 {
 186                         lapstr = sprintf(_(" (-%dL)"), lapdelta);
 187                         col = "^2";
 188                 }
 189                 else if(lapdelta < 0)
 190                 {
 191                         lapstr = sprintf(_(" (+%dL)"), -lapdelta);
 192                         col = "^1";
 193                 }
 194         }
 195         else if(histime > 0) // anticipation
 196         {
 197                 if(mytime >= histime)
 198                         timestr = strcat("+", ftos_decimals(mytime - histime, TIME_DECIMALS));
 199                 else
 200                         timestr = TIME_ENCODED_TOSTRING(TIME_ENCODE(histime));
 201                 col = "^3";
 202         }
 203         else
 204         {
 205                 col = "^7";
 206                 timestr = "";
 207         }
 208
 209         if(cp == 254)
 210                 cpname = _("Start line");
 211         else if(cp == 255)
 212                 cpname = _("Finish line");
 213         else if(cp)
 214                 cpname = sprintf(_("Intermediate %d"), cp);
 215         else
 216                 cpname = _("Finish line");
 217
 218         if(histime < 0)
 219                 return strcat(col, cpname);
 220         else if(hisname == "")
 221                 return strcat(col, sprintf(_("%s (%s)"), cpname, timestr));
 222         else
 223                 return strcat(col, sprintf(_("%s (%s %s)"), cpname, timestr, strcat(hisname, col, lapstr)));
 224 }
 225
 226 // Check if the given name already exist in race rankings? In that case, where? (otherwise return 0)
 227 float race_CheckName(string net_name) {
 228         float i;
 229         for (i=RANKINGS_CNT-1;i>=0;--i)
 230                 if(grecordholder[i] == net_name)
 231                         return i+1;
 232         return 0;
 233 }
 234
 235 float GetPlayerColorForce(float i)
 236 {
 237         if(!teamplay)
 238                 return 0;
 239         else
 240                 return stof(getplayerkeyvalue(i, "colors")) & 15;
 241 }
 242
 243 float GetPlayerColor(float i)
 244 {
 245         if(!playerslots[i].gotscores) // unconnected
 246                 return NUM_SPECTATOR;
 247         else if(stof(getplayerkeyvalue(i, "frags")) == FRAGS_SPECTATOR)
 248                 return NUM_SPECTATOR;
 249         else
 250                 return GetPlayerColorForce(i);
 251 }
 252
 253 string GetPlayerName(float i)
 254 {
 255         return ColorTranslateRGB(getplayerkeyvalue(i, "name"));
 256 }
 257
 258
 259 /*
 260 ==================
 261 HUD panels
 262 ==================
 263 */
 264
 265 // draw the background/borders
 266 #define HUD_Panel_DrawBg(theAlpha)\
 267 if(panel_bg != "0" && panel_bg != "")\
 268         draw_BorderPicture(panel_pos - '1 1 0' * panel_bg_border, panel_bg, panel_size + '1 1 0' * 2 * panel_bg_border, panel_bg_color, panel_bg_alpha * theAlpha, '1 1 0' * (panel_bg_border/BORDER_MULTIPLIER))
 269
 270 //basically the same code of draw_ButtonPicture and draw_VertButtonPicture for the menu
 271 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, float vertical, float baralign, vector theColor, float theAlpha, float drawflag)
 272 {
 273         if(!length_ratio || !theAlpha)
 274                 return;
 275         if(length_ratio > 1)
 276                 length_ratio = 1;
 277         if (baralign == 3)
 278         {
 279                 if(length_ratio < -1)
 280                         length_ratio = -1;
 281         }
 282         else if(length_ratio < 0)
 283                 return;
 284
 285         vector square;
 286         vector width, height;
 287         if(vertical) {
 288                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
 289                 if(precache_pic(pic) == "") {
 290                         pic = "gfx/hud/default/progressbar_vertical";
 291                 }
 292
 293         if (baralign == 1) // bottom align
 294                         theOrigin_y += (1 - length_ratio) * theSize_y;
 295         else if (baralign == 2) // center align
 296             theOrigin_y += 0.5 * (1 - length_ratio) * theSize_y;
 297         else if (baralign == 3) // center align, positive values down, negative up
 298                 {
 299                         theSize_y *= 0.5;
 300                         if (length_ratio > 0)
 301                                 theOrigin_y += theSize_y;
 302                         else
 303                         {
 304                                 theOrigin_y += (1 + length_ratio) * theSize_y;
 305                                 length_ratio = -length_ratio;
 306                         }
 307                 }
 308                 theSize_y *= length_ratio;
 309
 310                 vector bH;
 311                 width = eX * theSize_x;
 312                 height = eY * theSize_y;
 313                 if(theSize_y <= theSize_x * 2)
 314                 {
 315                         // button not high enough
 316                         // draw just upper and lower part then
 317                         square = eY * theSize_y * 0.5;
 318                         bH = eY * (0.25 * theSize_y / (theSize_x * 2));
 319                         drawsubpic(theOrigin,          square + width, pic, '0 0 0', eX + bH, theColor, theAlpha, drawflag);
 320                         drawsubpic(theOrigin + square, square + width, pic, eY - bH, eX + bH, theColor, theAlpha, drawflag);
 321                 }
 322                 else
 323                 {
 324                         square = eY * theSize_x;
 325                         drawsubpic(theOrigin,                   width   +     square, pic, '0 0    0', '1 0.25 0', theColor, theAlpha, drawflag);
 326                         drawsubpic(theOrigin +          square, theSize - 2 * square, pic, '0 0.25 0', '1 0.5  0', theColor, theAlpha, drawflag);
 327                         drawsubpic(theOrigin + height - square, width   +     square, pic, '0 0.75 0', '1 0.25 0', theColor, theAlpha, drawflag);
 328                 }
 329         } else {
 330                 pic = strcat(hud_skin_path, "/", pic);
 331                 if(precache_pic(pic) == "") {
 332                         pic = "gfx/hud/default/progressbar";
 333                 }
 334
 335                 if (baralign == 1) // right align
 336                         theOrigin_x += (1 - length_ratio) * theSize_x;
 337         else if (baralign == 2) // center align
 338             theOrigin_x += 0.5 * (1 - length_ratio) * theSize_x;
 339         else if (baralign == 3) // center align, positive values on the right, negative on the left
 340                 {
 341                         theSize_x *= 0.5;
 342                         if (length_ratio > 0)
 343                                 theOrigin_x += theSize_x;
 344                         else
 345                         {
 346                                 theOrigin_x += (1 + length_ratio) * theSize_x;
 347                                 length_ratio = -length_ratio;
 348                         }
 349                 }
 350                 theSize_x *= length_ratio;
 351
 352                 vector bW;
 353                 width = eX * theSize_x;
 354                 height = eY * theSize_y;
 355                 if(theSize_x <= theSize_y * 2)
 356                 {
 357                         // button not wide enough
 358                         // draw just left and right part then
 359                         square = eX * theSize_x * 0.5;
 360                         bW = eX * (0.25 * theSize_x / (theSize_y * 2));
 361                         drawsubpic(theOrigin,          square + height, pic, '0 0 0', eY + bW, theColor, theAlpha, drawflag);
 362                         drawsubpic(theOrigin + square, square + height, pic, eX - bW, eY + bW, theColor, theAlpha, drawflag);
 363                 }
 364                 else
 365                 {
 366                         square = eX * theSize_y;
 367                         drawsubpic(theOrigin,                  height  +     square, pic, '0    0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 368                         drawsubpic(theOrigin +         square, theSize - 2 * square, pic, '0.25 0 0', '0.5  1 0', theColor, theAlpha, drawflag);
 369                         drawsubpic(theOrigin + width - square, height  +     square, pic, '0.75 0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 370                 }
 371         }
 372 }
 373
 374 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float theAlpha, float drawflag)
 375 {
 376         if(!theAlpha)
 377                 return;
 378
 379         string pic;
 380         pic = strcat(hud_skin_path, "/num_leading");
 381         if(precache_pic(pic) == "") {
 382                 pic = "gfx/hud/default/num_leading";
 383         }
 384
 385         drawsubpic(pos, eX * min(mySize_x * 0.5, mySize_y) + eY * mySize_y, pic, '0 0 0', '0.25 1 0', color, theAlpha, drawflag);
 386         if(mySize_x/mySize_y > 2)
 387                 drawsubpic(pos + eX * mySize_y, eX * (mySize_x - 2 * mySize_y) + eY * mySize_y, pic, '0.25 0 0', '0.5 1 0', color, theAlpha, drawflag);
 388         drawsubpic(pos + eX * mySize_x - eX * min(mySize_x * 0.5, mySize_y), eX * min(mySize_x * 0.5, mySize_y) + eY * mySize_y, pic, '0.75 0 0', '0.25 1 0', color, theAlpha, drawflag);
 389 }
 390
 391 // Weapon icons (#0)
 392 //
 393 entity weaponorder[WEP_MAXCOUNT];
 394 void weaponorder_swap(float i, float j, entity pass)
 395 {
 396         entity h;
 397         h = weaponorder[i];
 398         weaponorder[i] = weaponorder[j];
 399         weaponorder[j] = h;
 400 }
 401
 402 string weaponorder_cmp_str;
 403 float weaponorder_cmp(float i, float j, entity pass)
 404 {
 405         float ai, aj;
 406         ai = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[i].weapon), 0);
 407         aj = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[j].weapon), 0);
 408         return aj - ai; // the string is in REVERSE order (higher prio at the right is what we want, but higher prio first is the string)
 409 }
 410
 411 void HUD_Weapons(void)
 412 {
 413         // declarations
 414         WepSet weapons_stat = WepSet_GetFromStat();
 415         float i, f, a;
 416         float screen_ar, center_x = 0, center_y;
 417         float weapon_count, weapon_id;
 418         float row, column, rows = 0, columns;
 419         float aspect = autocvar_hud_panel_weapons_aspect;
 420
 421         float panel_weapon_accuracy;
 422
 423         float timeout = autocvar_hud_panel_weapons_timeout;
 424         float timein_effect_length = autocvar_hud_panel_weapons_timeout_speed_in; //? 0.375 : 0);
 425         float timeout_effect_length = autocvar_hud_panel_weapons_timeout_speed_out; //? 0.75 : 0);
 426
 427         float ammo_full;
 428         float barsize_x = 0, barsize_y = 0, baroffset_x = 0, baroffset_y = 0;
 429         vector ammo_color = '1 0 1';
 430         float ammo_alpha = 1;
 431
 432         float when = max(1, autocvar_hud_panel_weapons_complainbubble_time);
 433         float fadetime = max(0, autocvar_hud_panel_weapons_complainbubble_fadetime);
 434
 435         vector weapon_pos, weapon_size = '0 0 0';
 436         local noref vector old_panel_size; // fteqcc sucks
 437         vector color;
 438
 439         // check to see if we want to continue
 440         if(hud != HUD_NORMAL) { return; }
 441
 442         if(!autocvar__hud_configure)
 443         {
 444                 if((!autocvar_hud_panel_weapons) || (spectatee_status == -1))
 445                         return;
 446                 if(timeout && time >= weapontime + timeout + timeout_effect_length)
 447                 if(autocvar_hud_panel_weapons_timeout_effect == 3 || (autocvar_hud_panel_weapons_timeout_effect == 1 && !(autocvar_hud_panel_weapons_timeout_fadebgmin + autocvar_hud_panel_weapons_timeout_fadefgmin)))
 448                 {
 449                         weaponprevtime = time;
 450                         return;
 451                 }
 452         }
 453
 454         // update generic hud functions
 455         HUD_Panel_UpdateCvars();
 456         HUD_Panel_ApplyFadeAlpha();
 457
 458         draw_beginBoldFont();
 459
 460         // figure out weapon order (how the weapons are sorted) // TODO make this configurable
 461         if(weaponorder_bypriority != autocvar_cl_weaponpriority || !weaponorder[0])
 462         {
 463                 float weapon_cnt;
 464                 if(weaponorder_bypriority)
 465                         strunzone(weaponorder_bypriority);
 466                 if(weaponorder_byimpulse)
 467                         strunzone(weaponorder_byimpulse);
 468
 469                 weaponorder_bypriority = strzone(autocvar_cl_weaponpriority);
 470                 weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(weaponorder_bypriority))));
 471                 weaponorder_cmp_str = strcat(" ", weaponorder_byimpulse, " ");
 472
 473                 weapon_cnt = 0;
 474                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 475                 {
 476                         self = get_weaponinfo(i);
 477                         if(self.impulse >= 0)
 478                         {
 479                                 weaponorder[weapon_cnt] = self;
 480                                 ++weapon_cnt;
 481                         }
 482                 }
 483                 for(i = weapon_cnt; i < WEP_MAXCOUNT; ++i)
 484                         weaponorder[i] = world;
 485                 heapsort(weapon_cnt, weaponorder_swap, weaponorder_cmp, world);
 486
 487                 weaponorder_cmp_str = string_null;
 488         }
 489
 490         if(!autocvar_hud_panel_weapons_complainbubble || autocvar__hud_configure || time - complain_weapon_time >= when + fadetime)
 491                 complain_weapon = 0;
 492
 493         // determine which weapons are going to be shown
 494         if (autocvar_hud_panel_weapons_onlyowned)
 495         {
 496                 if(autocvar__hud_configure)
 497                 {
 498                         if (!weapons_stat)
 499                                 for(i = WEP_FIRST; i <= WEP_LAST; i += floor((WEP_LAST-WEP_FIRST)/5))
 500                                         weapons_stat |= WepSet_FromWeapon(i);
 501
 502                         if(menu_enabled != 2)
 503                                 HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 504                 }
 505
 506                 // do we own this weapon?
 507                 weapon_count = 0;
 508                 for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 509                         if(weapons_stat & WepSet_FromWeapon(weaponorder[i].weapon))
 510                                 ++weapon_count;
 511
 512                 // add it anyway if weaponcomplain is shown
 513                 if(complain_weapon)
 514                         ++weapon_count;
 515
 516                 // might as well commit suicide now, no reason to live ;)
 517                 if (weapon_count == 0)
 518                 {
 519                         draw_endBoldFont();
 520                         return;
 521                 }
 522
 523                 old_panel_size = panel_size;
 524                 if(panel_bg_padding)
 525                         old_panel_size -= '2 2 0' * panel_bg_padding;
 526
 527                 // first find values for the standard table (with all the weapons)
 528                 rows = old_panel_size_y/old_panel_size_x;
 529                 rows = bound(1, floor((sqrt(4 * aspect * rows * WEP_COUNT + rows * rows) + rows + 0.5) / 2), WEP_COUNT);
 530                 columns = ceil(WEP_COUNT/rows);
 531                 weapon_size_x = old_panel_size_x / columns;
 532                 weapon_size_y = old_panel_size_y / rows;
 533
 534                 // change table values to include only the owned weapons
 535                 // weapon_size won't be changed
 536                 if(weapon_count <= rows)
 537                 {
 538                         rows = weapon_count;
 539                         columns = 1;
 540                 }
 541                 else
 542                         columns = ceil(weapon_count / rows);
 543
 544                 // reduce size of the panel
 545                 panel_size_x = columns * weapon_size_x;
 546                 panel_size_y = rows * weapon_size_y;
 547                 panel_pos_x += (old_panel_size_x - panel_size_x) / 2;
 548                 panel_pos_y += (old_panel_size_y - panel_size_y) / 2;
 549                 if(panel_bg_padding)
 550                         panel_size += '2 2 0' * panel_bg_padding;
 551         }
 552         else
 553                 weapon_count = WEP_COUNT;
 554
 555         // animation for fading in/out the panel respectively when not in use
 556         if(!autocvar__hud_configure)
 557         {
 558                 if (timeout && time >= weapontime + timeout) // apply timeout effect if needed
 559                 {
 560                         f = bound(0, (time - (weapontime + timeout)) / timeout_effect_length, 1);
 561
 562                         // fade the panel alpha
 563                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 564                         {
 565                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * f + (1 - f));
 566                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * f + (1 - f));
 567                         }
 568                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 569                         {
 570                                 panel_bg_alpha *= (1 - f);
 571                                 panel_fg_alpha *= (1 - f);
 572                         }
 573
 574                         // move the panel off the screen
 575                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 576                         {
 577                                 f *= f; // for a cooler movement
 578                                 center_x = panel_pos_x + panel_size_x/2;
 579                                 center_y = panel_pos_y + panel_size_y/2;
 580                                 screen_ar = vid_conwidth/vid_conheight;
 581                                 if (center_x/center_y < screen_ar) //bottom left
 582                                 {
 583                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //bottom
 584                                                 panel_pos_y += f * (vid_conheight - panel_pos_y);
 585                                         else //left
 586                                                 panel_pos_x -= f * (panel_pos_x + panel_size_x);
 587                                 }
 588                                 else //top right
 589                                 {
 590                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //right
 591                                                 panel_pos_x += f * (vid_conwidth - panel_pos_x);
 592                                         else //top
 593                                                 panel_pos_y -= f * (panel_pos_y + panel_size_y);
 594                                 }
 595                                 if(f == 1)
 596                                         center_x = -1; // mark the panel as off screen
 597                         }
 598                         weaponprevtime = time - (1 - f) * timein_effect_length;
 599                 }
 600                 else if (timeout && time < weaponprevtime + timein_effect_length) // apply timein effect if needed
 601                 {
 602                         f = bound(0, (time - weaponprevtime) / timein_effect_length, 1);
 603
 604                         // fade the panel alpha
 605                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 606                         {
 607                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * (1 - f) + f);
 608                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * (1 - f) + f);
 609                         }
 610                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 611                         {
 612                                 panel_bg_alpha *= (f);
 613                                 panel_fg_alpha *= (f);
 614                         }
 615
 616                         // move the panel back on screen
 617                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 618                         {
 619                                 f *= f; // for a cooler movement
 620                                 f = 1 - f;
 621                                 center_x = panel_pos_x + panel_size_x/2;
 622                                 center_y = panel_pos_y + panel_size_y/2;
 623                                 screen_ar = vid_conwidth/vid_conheight;
 624                                 if (center_x/center_y < screen_ar) //bottom left
 625                                 {
 626                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //bottom
 627                                                 panel_pos_y += f * (vid_conheight - panel_pos_y);
 628                                         else //left
 629                                                 panel_pos_x -= f * (panel_pos_x + panel_size_x);
 630                                 }
 631                                 else //top right
 632                                 {
 633                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //right
 634                                                 panel_pos_x += f * (vid_conwidth - panel_pos_x);
 635                                         else //top
 636                                                 panel_pos_y -= f * (panel_pos_y + panel_size_y);
 637                                 }
 638                         }
 639                 }
 640         }
 641
 642         // draw the background, then change the virtual size of it to better fit other items inside
 643         HUD_Panel_DrawBg(1);
 644
 645         if(center_x == -1)
 646         {
 647                 draw_endBoldFont();
 648                 return;
 649         }
 650
 651         if(panel_bg_padding)
 652         {
 653                 panel_pos += '1 1 0' * panel_bg_padding;
 654                 panel_size -= '2 2 0' * panel_bg_padding;
 655         }
 656
 657         // after the sizing and animations are done, update the other values
 658
 659         if(!rows) // if rows is > 0 onlyowned code has already updated these vars
 660         {
 661                 rows = panel_size_y/panel_size_x;
 662                 rows = bound(1, floor((sqrt(4 * aspect * rows * weapon_count + rows * rows) + rows + 0.5) / 2), weapon_count);
 663                 columns = ceil(weapon_count/rows);
 664                 weapon_size = eX * panel_size_x*(1/columns) + eY * panel_size_y*(1/rows);
 665         }
 666
 667         // calculate position/size for visual bar displaying ammount of ammo status
 668         if (autocvar_hud_panel_weapons_ammo)
 669         {
 670                 ammo_color = stov(autocvar_hud_panel_weapons_ammo_color);
 671                 ammo_alpha = panel_fg_alpha * autocvar_hud_panel_weapons_ammo_alpha;
 672
 673                 if(weapon_size_x/weapon_size_y > aspect)
 674                 {
 675                         barsize_x = aspect * weapon_size_y;
 676                         barsize_y = weapon_size_y;
 677                         baroffset_x = (weapon_size_x - barsize_x) / 2;
 678                 }
 679                 else
 680                 {
 681                         barsize_y = 1/aspect * weapon_size_x;
 682                         barsize_x = weapon_size_x;
 683                         baroffset_y = (weapon_size_y - barsize_y) / 2;
 684                 }
 685         }
 686         if(autocvar_hud_panel_weapons_accuracy)
 687                 Accuracy_LoadColors();
 688
 689         row = column = 0;
 690         for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 691         {
 692                 // retrieve information about the current weapon to be drawn
 693                 self = weaponorder[i];
 694                 weapon_id = self.impulse;
 695
 696                 // skip if this weapon doesn't exist
 697                 if(!self || weapon_id < 0) { continue; }
 698
 699                 // skip this weapon if we don't own it (and onlyowned is enabled)-- or if weapons_complainbubble is showing for this weapon
 700                 if(autocvar_hud_panel_weapons_onlyowned)
 701                 if (!((weapons_stat & WepSet_FromWeapon(self.weapon)) || (self.weapon == complain_weapon)))
 702                         continue;
 703
 704                 // figure out the drawing position of weapon
 705                 weapon_pos = (panel_pos
 706                         + eX * column * weapon_size_x
 707                         + eY * row * weapon_size_y);
 708
 709                 // draw background behind currently selected weapon
 710                 if(self.weapon == switchweapon)
 711                         drawpic_aspect_skin(weapon_pos, "weapon_current_bg", weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 712
 713                 // draw the weapon accuracy
 714                 if(autocvar_hud_panel_weapons_accuracy)
 715                 {
 716                         panel_weapon_accuracy = weapon_accuracy[self.weapon-WEP_FIRST];
 717                         if(panel_weapon_accuracy >= 0)
 718                         {
 719                                 color = Accuracy_GetColor(panel_weapon_accuracy);
 720                                 drawpic_aspect_skin(weapon_pos, "weapon_accuracy", weapon_size, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 721                         }
 722                 }
 723
 724                 // drawing all the weapon items
 725                 if(weapons_stat & WepSet_FromWeapon(self.weapon))
 726                 {
 727                         // draw the weapon image
 728                         drawpic_aspect_skin(weapon_pos, strcat("weapon", self.netname), weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 729
 730                         // draw weapon label string
 731                         switch(autocvar_hud_panel_weapons_label)
 732                         {
 733                                 case 1: // weapon number
 734                                         drawstring(weapon_pos, ftos(weapon_id), '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 735                                         break;
 736
 737                                 case 2: // bind
 738                                         drawstring(weapon_pos, getcommandkey(ftos(weapon_id), strcat("weapon_group_", ftos(weapon_id))), '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 739                                         break;
 740
 741                                 case 3: // weapon name
 742                                         drawstring(weapon_pos, strtolower(self.message), '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 743                                         break;
 744
 745                                 default: // nothing
 746                                         break;
 747                         }
 748
 749                         // draw ammo status bar
 750                         if(autocvar_hud_panel_weapons_ammo && (self.ammo_field != ammo_none))
 751                         {
 752                                 a = getstati(GetAmmoStat(self.ammo_field)); // how much ammo do we have?
 753
 754                                 if(a > 0)
 755                                 {
 756                                         switch(self.ammo_field)
 757                                         {
 758                                                 case ammo_shells:  ammo_full = autocvar_hud_panel_weapons_ammo_full_shells;  break;
 759                                                 case ammo_nails:   ammo_full = autocvar_hud_panel_weapons_ammo_full_nails;   break;
 760                                                 case ammo_rockets: ammo_full = autocvar_hud_panel_weapons_ammo_full_rockets; break;
 761                                                 case ammo_cells:   ammo_full = autocvar_hud_panel_weapons_ammo_full_cells;   break;
 762                                                 case ammo_fuel:    ammo_full = autocvar_hud_panel_weapons_ammo_full_fuel;    break;
 763                                                 default: ammo_full = 60;
 764                                         }
 765
 766                                         drawsetcliparea(
 767                                                 weapon_pos_x + baroffset_x,
 768                                                 weapon_pos_y + baroffset_y,
 769                                                 barsize_x * bound(0, a/ammo_full, 1),
 770                                                 barsize_y
 771                                         );
 772
 773                                         drawpic_aspect_skin(
 774                                                 weapon_pos,
 775                                                 "weapon_ammo",
 776                                                 weapon_size,
 777                                                 ammo_color,
 778                                                 ammo_alpha,
 779                                                 DRAWFLAG_NORMAL
 780                                         );
 781
 782                                         drawresetcliparea();
 783                                 }
 784                         }
 785                 }
 786                 else // draw a "ghost weapon icon" if you don't have the weapon
 787                 {
 788                         drawpic_aspect_skin(weapon_pos, strcat("weapon", self.netname), weapon_size, '0 0 0', panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
 789                 }
 790
 791                 // draw the complain message
 792                 if(self.weapon == complain_weapon)
 793                 {
 794                         if(fadetime)
 795                                 a = ((complain_weapon_time + when > time) ? 1 : bound(0, (complain_weapon_time + when + fadetime - time) / fadetime, 1));
 796                         else
 797                                 a = ((complain_weapon_time + when > time) ? 1 : 0);
 798
 799                         string s;
 800                         if(complain_weapon_type == 0) {
 801                                 s = _("Out of ammo");
 802                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_outofammo);
 803                         }
 804                         else if(complain_weapon_type == 1) {
 805                                 s = _("Don't have");
 806                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_donthave);
 807                         }
 808                         else {
 809                                 s = _("Unavailable");
 810                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_unavailable);
 811                         }
 812                         float padding = autocvar_hud_panel_weapons_complainbubble_padding;
 813                         drawpic_aspect_skin(weapon_pos + '1 1 0' * padding, "weapon_complainbubble", weapon_size - '2 2 0' * padding, color, a * panel_fg_alpha, DRAWFLAG_NORMAL);
 814                         drawstring_aspect(weapon_pos + '1 1 0' * padding, s, weapon_size - '2 2 0' * padding, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 815                 }
 816
 817                 // continue with new position for the next weapon
 818                 ++row;
 819                 if(row >= rows)
 820                 {
 821                         row = 0;
 822                         ++column;
 823                 }
 824         }
 825
 826         draw_endBoldFont();
 827 }
 828
 829 // Ammo (#1)
 830 void DrawAmmoItem(vector myPos, vector mySize, .float ammotype, float currently_selected, float infinite_ammo)
 831 {
 832         float a;
 833         if(autocvar__hud_configure)
 834         {
 835                 currently_selected = (ammotype == ammo_rockets); //rockets always selected
 836                 a = 60;
 837         }
 838         else
 839                 a = getstati(GetAmmoStat(ammotype)); // how much ammo do we have of type itemcode?
 840
 841         vector color;
 842         if(infinite_ammo)
 843                 color = '0 0.5 0.75';
 844         else if(a < 10)
 845                 color = '0.7 0 0';
 846         else
 847                 color = '1 1 1';
 848
 849         float theAlpha;
 850         if(currently_selected)
 851                 theAlpha = 1;
 852         else
 853                 theAlpha = 0.7;
 854
 855         vector picpos, numpos;
 856         if(autocvar_hud_panel_ammo_iconalign)
 857         {
 858                 numpos = myPos;
 859                 picpos = myPos + eX * 2 * mySize_y;
 860         }
 861         else
 862         {
 863                 numpos = myPos + eX * mySize_y;
 864                 picpos = myPos;
 865         }
 866
 867         if(currently_selected)
 868                 drawpic_aspect_skin(myPos, "ammo_current_bg", mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 869
 870     if(a > 0 && autocvar_hud_panel_ammo_progressbar)
 871         HUD_Panel_DrawProgressBar(myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize_x, mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize_x, autocvar_hud_panel_ammo_progressbar_name, a/autocvar_hud_panel_ammo_maxammo, 0, 0, color, autocvar_hud_progressbar_alpha * panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 872
 873     if(autocvar_hud_panel_ammo_text)
 874     {
 875         if(a > 0 || infinite_ammo)
 876             drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 877         else // "ghost" ammo count
 878             drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize_x + eY * mySize_y, '0 0 0', panel_fg_alpha * theAlpha * 0.5, DRAWFLAG_NORMAL);
 879     }
 880         if(a > 0 || infinite_ammo)
 881                 drawpic_aspect_skin(picpos, GetAmmoPicture(ammotype), '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 882         else // "ghost" ammo icon
 883                 drawpic_aspect_skin(picpos, GetAmmoPicture(ammotype), '1 1 0' * mySize_y, '0 0 0', panel_fg_alpha * theAlpha * 0.5, DRAWFLAG_NORMAL);
 884 }
 885
 886 void HUD_Ammo(void)
 887 {
 888     if(hud != HUD_NORMAL) return;
 889         if(!autocvar__hud_configure)
 890         {
 891                 if(!autocvar_hud_panel_ammo) return;
 892                 if(spectatee_status == -1) return;
 893         }
 894
 895         HUD_Panel_UpdateCvars();
 896         HUD_Panel_ApplyFadeAlpha();
 897
 898         draw_beginBoldFont();
 899
 900         vector pos, mySize;
 901         pos = panel_pos;
 902         mySize = panel_size;
 903
 904         HUD_Panel_DrawBg(1);
 905         if(panel_bg_padding)
 906         {
 907                 pos += '1 1 0' * panel_bg_padding;
 908                 mySize -= '2 2 0' * panel_bg_padding;
 909         }
 910
 911         float rows = 0, columns, row, column;
 912         vector ammo_size;
 913         if(autocvar_hud_panel_ammo_onlycurrent)
 914                 ammo_size = mySize;
 915         else
 916         {
 917                 rows = mySize_y/mySize_x;
 918                 rows = bound(1, floor((sqrt(4 * (3/1) * rows * AMMO_COUNT + rows * rows) + rows + 0.5) / 2), AMMO_COUNT);
 919                 //                               ^^^ ammo item aspect goes here
 920
 921                 columns = ceil(AMMO_COUNT/rows);
 922
 923                 ammo_size = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
 924         }
 925
 926         local vector offset = '0 0 0'; // fteqcc sucks
 927         float newSize;
 928         if(ammo_size_x/ammo_size_y > 3)
 929         {
 930                 newSize = 3 * ammo_size_y;
 931                 offset_x = ammo_size_x - newSize;
 932                 pos_x += offset_x/2;
 933                 ammo_size_x = newSize;
 934         }
 935         else
 936         {
 937                 newSize = 1/3 * ammo_size_x;
 938                 offset_y = ammo_size_y - newSize;
 939                 pos_y += offset_y/2;
 940                 ammo_size_y = newSize;
 941         }
 942
 943         float i;
 944         float infinite_ammo = (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_WEAPON_AMMO);
 945         if(autocvar_hud_panel_ammo_onlycurrent)
 946         {
 947                 if(autocvar__hud_configure)
 948                 {
 949                         DrawAmmoItem(pos, ammo_size, ammo_rockets, true, FALSE);
 950                 }
 951                 else
 952                 {
 953                         DrawAmmoItem(
 954                                 pos,
 955                                 ammo_size,
 956                                 (get_weaponinfo(switchweapon)).ammo_field,
 957                                 TRUE,
 958                                 infinite_ammo
 959                         );
 960                 }
 961         }
 962         else
 963         {
 964                 .float ammotype;
 965                 row = column = 0;
 966                 for(i = 0; i < AMMO_COUNT; ++i)
 967                 {
 968                         ammotype = GetAmmoFieldFromNum(i);
 969                         DrawAmmoItem(
 970                                 pos + eX * column * (ammo_size_x + offset_x) + eY * row * (ammo_size_y + offset_y),
 971                                 ammo_size,
 972                                 ammotype,
 973                                 ((get_weaponinfo(switchweapon)).ammo_field == ammotype),
 974                                 infinite_ammo
 975                         );
 976
 977                         ++row;
 978                         if(row >= rows)
 979                         {
 980                                 row = 0;
 981                                 column = column + 1;
 982                         }
 983                 }
 984         }
 985
 986         draw_endBoldFont();
 987 }
 988
 989 void DrawNumIcon_expanding(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha, float fadelerp)
 990 {
 991         vector newPos = '0 0 0', newSize = '0 0 0';
 992         vector picpos, numpos;
 993
 994         if (vertical)
 995         {
 996                 if(mySize_y/mySize_x > 2)
 997                 {
 998                         newSize_y = 2 * mySize_x;
 999                         newSize_x = mySize_x;
1000
1001                         newPos_y = myPos_y + (mySize_y - newSize_y) / 2;
1002                         newPos_x = myPos_x;
1003                 }
1004                 else
1005                 {
1006                         newSize_x = 1/2 * mySize_y;
1007                         newSize_y = mySize_y;
1008
1009                         newPos_x = myPos_x + (mySize_x - newSize_x) / 2;
1010                         newPos_y = myPos_y;
1011                 }
1012
1013                 if(icon_right_align)
1014                 {
1015                         numpos = newPos;
1016                         picpos = newPos + eY * newSize_x;
1017                 }
1018                 else
1019                 {
1020                         picpos = newPos;
1021                         numpos = newPos + eY * newSize_x;
1022                 }
1023
1024                 newSize_y /= 2;
1025                 drawpic_aspect_skin(picpos, icon, newSize, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1026                 // make number smaller than icon, it looks better
1027                 // reduce only y to draw numbers with different number of digits with the same y size
1028                 numpos_y += newSize_y * ((1 - 0.7) / 2);
1029                 newSize_y *= 0.7;
1030                 drawstring_aspect(numpos, ftos(x), newSize, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1031                 return;
1032         }
1033
1034         if(mySize_x/mySize_y > 3)
1035         {
1036                 newSize_x = 3 * mySize_y;
1037                 newSize_y = mySize_y;
1038
1039                 newPos_x = myPos_x + (mySize_x - newSize_x) / 2;
1040                 newPos_y = myPos_y;
1041         }
1042         else
1043         {
1044                 newSize_y = 1/3 * mySize_x;
1045                 newSize_x = mySize_x;
1046
1047                 newPos_y = myPos_y + (mySize_y - newSize_y) / 2;
1048                 newPos_x = myPos_x;
1049         }
1050
1051         if(icon_right_align) // right align
1052         {
1053                 numpos = newPos;
1054                 picpos = newPos + eX * 2 * newSize_y;
1055         }
1056         else // left align
1057         {
1058                 numpos = newPos + eX * newSize_y;
1059                 picpos = newPos;
1060         }
1061
1062         // NOTE: newSize_x is always equal to 3 * mySize_y so we can use
1063         // '2 1 0' * newSize_y instead of eX * (2/3) * newSize_x + eY * newSize_y
1064         drawstring_aspect_expanding(numpos, ftos(x), '2 1 0' * newSize_y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1065         drawpic_aspect_skin_expanding(picpos, icon, '1 1 0' * newSize_y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1066 }
1067
1068 void DrawNumIcon(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha)
1069 {
1070         DrawNumIcon_expanding(myPos, mySize, x, icon, vertical, icon_right_align, color, theAlpha, 0);
1071 }
1072
1073 // Powerups (#2)
1074 //
1075 void HUD_Powerups(void)
1076 {
1077         float strength_time, shield_time, superweapons_time;
1078         if(!autocvar__hud_configure)
1079         {
1080                 if(!autocvar_hud_panel_powerups) return;
1081                 if(spectatee_status == -1) return;
1082                 if(!(getstati(STAT_ITEMS, 0, 24) & (IT_STRENGTH | IT_INVINCIBLE | IT_SUPERWEAPON))) return;
1083                 if (getstati(STAT_HEALTH) <= 0) return;
1084
1085                 strength_time = bound(0, getstatf(STAT_STRENGTH_FINISHED) - time, 99);
1086                 shield_time = bound(0, getstatf(STAT_INVINCIBLE_FINISHED) - time, 99);
1087                 superweapons_time = bound(0, getstatf(STAT_SUPERWEAPONS_FINISHED) - time, 99);
1088
1089                 if (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_SUPERWEAPONS)
1090                         superweapons_time = 99; // force max
1091
1092                 // prevent stuff to show up on mismatch that will be fixed next frame
1093                 if (!(getstati(STAT_ITEMS, 0, 24) & IT_SUPERWEAPON))
1094                         superweapons_time = 0;
1095         }
1096         else
1097         {
1098                 strength_time = 15;
1099                 shield_time = 27;
1100                 superweapons_time = 13;
1101         }
1102
1103         HUD_Panel_UpdateCvars();
1104         HUD_Panel_ApplyFadeAlpha();
1105
1106         draw_beginBoldFont();
1107
1108         vector pos, mySize;
1109         pos = panel_pos;
1110         mySize = panel_size;
1111
1112         HUD_Panel_DrawBg(bound(0, max(strength_time, shield_time, superweapons_time), 1));
1113         if(panel_bg_padding)
1114         {
1115                 pos += '1 1 0' * panel_bg_padding;
1116                 mySize -= '2 2 0' * panel_bg_padding;
1117         }
1118
1119         float panel_ar = mySize_x/mySize_y;
1120         float is_vertical = (panel_ar < 1);
1121         vector shield_offset = '0 0 0', strength_offset = '0 0 0', superweapons_offset = '0 0 0';
1122
1123         float superweapons_is = -1;
1124
1125         if(superweapons_time)
1126         {
1127                 if(strength_time)
1128                 {
1129                         if(shield_time)
1130                                 superweapons_is = 0;
1131                         else
1132                                 superweapons_is = 2;
1133                 }
1134                 else
1135                 {
1136                         if(shield_time)
1137                                 superweapons_is = 1;
1138                         else
1139                                 superweapons_is = 2;
1140                 }
1141         }
1142
1143         // FIXME handle superweapons here
1144         if(superweapons_is == 0)
1145         {
1146                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1147                 {
1148                         mySize_x *= (1.0 / 3.0);
1149                         superweapons_offset_x = mySize_x;
1150                         if (autocvar_hud_panel_powerups_flip)
1151                                 shield_offset_x = 2*mySize_x;
1152                         else
1153                                 strength_offset_x = 2*mySize_x;
1154                 }
1155                 else
1156                 {
1157                         mySize_y *= (1.0 / 3.0);
1158                         superweapons_offset_y = mySize_y;
1159                         if (autocvar_hud_panel_powerups_flip)
1160                                 shield_offset_y = 2*mySize_y;
1161                         else
1162                                 strength_offset_y = 2*mySize_y;
1163                 }
1164         }
1165         else
1166         {
1167                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1168                 {
1169                         mySize_x *= 0.5;
1170                         if (autocvar_hud_panel_powerups_flip)
1171                                 shield_offset_x = mySize_x;
1172                         else
1173                                 strength_offset_x = mySize_x;
1174                 }
1175                 else
1176                 {
1177                         mySize_y *= 0.5;
1178                         if (autocvar_hud_panel_powerups_flip)
1179                                 shield_offset_y = mySize_y;
1180                         else
1181                                 strength_offset_y = mySize_y;
1182                 }
1183         }
1184
1185         float shield_baralign, strength_baralign, superweapons_baralign;
1186         float shield_iconalign, strength_iconalign, superweapons_iconalign;
1187
1188         if (autocvar_hud_panel_powerups_flip)
1189         {
1190                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1191                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1192                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1193                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1194         }
1195         else
1196         {
1197                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1198                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1199                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1200                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1201         }
1202
1203         if(superweapons_is == 0)
1204         {
1205                 superweapons_iconalign = strength_iconalign;
1206                 superweapons_baralign = 2;
1207         }
1208         else if(superweapons_is == 1)
1209         {
1210                 superweapons_offset = strength_offset;
1211                 superweapons_iconalign = strength_iconalign;
1212                 superweapons_baralign = strength_baralign;
1213         }
1214         else // if(superweapons_is == 2)
1215         {
1216                 superweapons_offset = shield_offset;
1217                 superweapons_iconalign = shield_iconalign;
1218                 superweapons_baralign = shield_baralign;
1219         }
1220
1221         if(shield_time)
1222         {
1223                 const float maxshield = 30;
1224                 float shield = ceil(shield_time);
1225                 if(autocvar_hud_panel_powerups_progressbar)
1226                 {
1227                         HUD_Panel_GetProgressBarColor(shield);
1228                         HUD_Panel_DrawProgressBar(pos + shield_offset, mySize, autocvar_hud_panel_powerups_progressbar_shield, shield/maxshield, is_vertical, shield_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1229                 }
1230                 if(autocvar_hud_panel_powerups_text)
1231                 {
1232                         if(shield > 1)
1233                                 DrawNumIcon(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1);
1234                         if(shield <= 5)
1235                                 DrawNumIcon_expanding(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1, bound(0, (shield - shield_time) / 0.5, 1));
1236                 }
1237         }
1238
1239         if(strength_time)
1240         {
1241                 const float maxstrength = 30;
1242                 float strength = ceil(strength_time);
1243                 if(autocvar_hud_panel_powerups_progressbar)
1244                 {
1245                         HUD_Panel_GetProgressBarColor(strength);
1246                         HUD_Panel_DrawProgressBar(pos + strength_offset, mySize, autocvar_hud_panel_powerups_progressbar_strength, strength/maxstrength, is_vertical, strength_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1247                 }
1248                 if(autocvar_hud_panel_powerups_text)
1249                 {
1250                         if(strength > 1)
1251                                 DrawNumIcon(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1);
1252                         if(strength <= 5)
1253                                 DrawNumIcon_expanding(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1, bound(0, (strength - strength_time) / 0.5, 1));
1254                 }
1255         }
1256
1257         if(superweapons_time)
1258         {
1259                 const float maxsuperweapons = 30;
1260                 float superweapons = ceil(superweapons_time);
1261                 if(autocvar_hud_panel_powerups_progressbar)
1262                 {
1263                         HUD_Panel_GetProgressBarColor(superweapons);
1264                         HUD_Panel_DrawProgressBar(pos + superweapons_offset, mySize, autocvar_hud_panel_powerups_progressbar_superweapons, superweapons/maxsuperweapons, is_vertical, superweapons_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1265                 }
1266                 if(autocvar_hud_panel_powerups_text)
1267                 {
1268                         if(superweapons > 1)
1269                                 DrawNumIcon(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1);
1270                         if(superweapons <= 5)
1271                                 DrawNumIcon_expanding(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1, bound(0, (superweapons - superweapons_time) / 0.5, 1));
1272                 }
1273         }
1274
1275         draw_endBoldFont();
1276 }
1277
1278 // Health/armor (#3)
1279 //
1280
1281 // prev_* vars contain the health/armor at the previous FRAME
1282 // set to -1 when player is dead or was not playing
1283 float prev_health, prev_armor;
1284 float health_damagetime, armor_damagetime;
1285 float health_beforedamage, armor_beforedamage;
1286 // old_p_* vars keep track of previous values when smoothing value changes of the progressbar
1287 float old_p_health, old_p_armor;
1288 float old_p_healthtime, old_p_armortime;
1289 // prev_p_* vars contain the health/armor progressbar value at the previous FRAME
1290 // set to -1 to forcedly stop effects when we switch spectated player (e.g. from playerX: 70h to playerY: 50h)
1291 float prev_p_health, prev_p_armor;
1292
1293 void HUD_HealthArmor(void)
1294 {
1295         float armor, health, fuel;
1296         if(!autocvar__hud_configure)
1297         {
1298                 if(!autocvar_hud_panel_healtharmor) return;
1299                 if(hud != HUD_NORMAL) return;
1300                 if(spectatee_status == -1) return;
1301
1302                 health = getstati(STAT_HEALTH);
1303                 if(health <= 0)
1304                 {
1305                         prev_health = -1;
1306                         return;
1307                 }
1308                 armor = getstati(STAT_ARMOR);
1309
1310                 // code to check for spectatee_status changes is in Ent_ClientData()
1311                 // prev_p_health and prev_health can be set to -1 there
1312
1313                 if (prev_p_health == -1)
1314                 {
1315                         // no effect
1316                         health_beforedamage = 0;
1317                         armor_beforedamage = 0;
1318                         health_damagetime = 0;
1319                         armor_damagetime = 0;
1320                         prev_health = health;
1321                         prev_armor = armor;
1322                         old_p_health = health;
1323                         old_p_armor = armor;
1324                         prev_p_health = health;
1325                         prev_p_armor = armor;
1326                 }
1327                 else if (prev_health == -1)
1328                 {
1329                         //start the load effect
1330                         health_damagetime = 0;
1331                         armor_damagetime = 0;
1332                         prev_health = 0;
1333                         prev_armor = 0;
1334                 }
1335                 fuel = getstati(STAT_FUEL);
1336         }
1337         else
1338         {
1339                 health = 150;
1340                 armor = 75;
1341                 fuel = 20;
1342         }
1343
1344         HUD_Panel_UpdateCvars();
1345         HUD_Panel_ApplyFadeAlpha();
1346         vector pos, mySize;
1347         pos = panel_pos;
1348         mySize = panel_size;
1349
1350         HUD_Panel_DrawBg(1);
1351         if(panel_bg_padding)
1352         {
1353                 pos += '1 1 0' * panel_bg_padding;
1354                 mySize -= '2 2 0' * panel_bg_padding;
1355         }
1356
1357         float baralign = autocvar_hud_panel_healtharmor_baralign;
1358         float iconalign = autocvar_hud_panel_healtharmor_iconalign;
1359
1360     float maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
1361     float maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
1362         if(autocvar_hud_panel_healtharmor == 2) // combined health and armor display
1363         {
1364                 vector v;
1365                 v = healtharmor_maxdamage(health, armor, armorblockpercent, DEATH_WEAPON);
1366
1367                 float x;
1368                 x = floor(v_x + 1);
1369
1370         float maxtotal = maxhealth + maxarmor;
1371                 string biggercount;
1372                 if(v_z) // NOT fully armored
1373                 {
1374                         biggercount = "health";
1375                         if(autocvar_hud_panel_healtharmor_progressbar)
1376                         {
1377                                 HUD_Panel_GetProgressBarColor(health);
1378                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, x/maxtotal, 0, (baralign == 1 || baralign == 2), progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1379                         }
1380                         if(armor)
1381             if(autocvar_hud_panel_healtharmor_text)
1382                                 drawpic_aspect_skin(pos + eX * mySize_x - eX * 0.5 * mySize_y, "armor", '0.5 0.5 0' * mySize_y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
1383                 }
1384                 else
1385                 {
1386                         biggercount = "armor";
1387                         if(autocvar_hud_panel_healtharmor_progressbar)
1388                         {
1389                                 HUD_Panel_GetProgressBarColor(armor);
1390                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, x/maxtotal, 0, (baralign == 1 || baralign == 2), progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1391                         }
1392                         if(health)
1393             if(autocvar_hud_panel_healtharmor_text)
1394                                 drawpic_aspect_skin(pos + eX * mySize_x - eX * 0.5 * mySize_y, "health", '0.5 0.5 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1395                 }
1396         if(autocvar_hud_panel_healtharmor_text)
1397                         DrawNumIcon(pos, mySize, x, biggercount, 0, iconalign, HUD_Get_Num_Color(x, maxtotal), 1);
1398
1399                 if(fuel)
1400                 {
1401                         HUD_Panel_GetProgressBarColor(fuel);
1402                         HUD_Panel_DrawProgressBar(pos, eX * mySize_x + eY * 0.2 * mySize_y, "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), progressbar_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1403                 }
1404         }
1405         else
1406         {
1407                 float panel_ar = mySize_x/mySize_y;
1408                 float is_vertical = (panel_ar < 1);
1409                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
1410                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1411                 {
1412                         mySize_x *= 0.5;
1413                         if (autocvar_hud_panel_healtharmor_flip)
1414                                 health_offset_x = mySize_x;
1415                         else
1416                                 armor_offset_x = mySize_x;
1417                 }
1418                 else
1419                 {
1420                         mySize_y *= 0.5;
1421                         if (autocvar_hud_panel_healtharmor_flip)
1422                                 health_offset_y = mySize_y;
1423                         else
1424                                 armor_offset_y = mySize_y;
1425                 }
1426
1427                 float health_baralign, armor_baralign, fuel_baralign;
1428                 float health_iconalign, armor_iconalign;
1429                 if (autocvar_hud_panel_healtharmor_flip)
1430                 {
1431                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1432                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1433                         fuel_baralign = health_baralign;
1434                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1435                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1436                 }
1437                 else
1438                 {
1439                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1440                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1441                         fuel_baralign = armor_baralign;
1442                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1443                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1444                 }
1445
1446                 //if(health)
1447                 {
1448                         if(autocvar_hud_panel_healtharmor_progressbar)
1449                         {
1450                                 HUD_Panel_GetProgressBarColor(health);
1451                                 float p_health, pain_health_alpha;
1452                                 p_health = health;
1453                                 pain_health_alpha = 1;
1454                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1455                                 {
1456                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1457                                         {
1458                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1459                                                 {
1460                                                         if (time - old_p_healthtime < 1)
1461                                                                 old_p_health = prev_p_health;
1462                                                         else
1463                                                                 old_p_health = prev_health;
1464                                                         old_p_healthtime = time;
1465                                                 }
1466                                                 if (time - old_p_healthtime < 1)
1467                                                 {
1468                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
1469                                                         prev_p_health = p_health;
1470                                                 }
1471                                         }
1472                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1473                                         {
1474                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1475                                                 {
1476                                                         if (time - health_damagetime >= 1)
1477                                                                 health_beforedamage = prev_health;
1478                                                         health_damagetime = time;
1479                                                 }
1480                                                 if (time - health_damagetime < 1)
1481                                                 {
1482                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
1483                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
1484                                                 }
1485                                         }
1486                                         prev_health = health;
1487
1488                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
1489                                         {
1490                                                 float BLINK_FACTOR = 0.15;
1491                                                 float BLINK_BASE = 0.85;
1492                                                 float BLINK_FREQ = 9;
1493                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
1494                                         }
1495                                 }
1496                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
1497                         }
1498                         if(autocvar_hud_panel_healtharmor_text)
1499                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
1500                 }
1501
1502                 if(armor)
1503                 {
1504                         if(autocvar_hud_panel_healtharmor_progressbar)
1505                         {
1506                                 HUD_Panel_GetProgressBarColor(armor);
1507                                 float p_armor;
1508                                 p_armor = armor;
1509                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1510                                 {
1511                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1512                                         {
1513                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1514                                                 {
1515                                                         if (time - old_p_armortime < 1)
1516                                                                 old_p_armor = prev_p_armor;
1517                                                         else
1518                                                                 old_p_armor = prev_armor;
1519                                                         old_p_armortime = time;
1520                                                 }
1521                                                 if (time - old_p_armortime < 1)
1522                                                 {
1523                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
1524                                                         prev_p_armor = p_armor;
1525                                                 }
1526                                         }
1527                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1528                                         {
1529                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1530                                                 {
1531                                                         if (time - armor_damagetime >= 1)
1532                                                                 armor_beforedamage = prev_armor;
1533                                                         armor_damagetime = time;
1534                                                 }
1535                                                 if (time - armor_damagetime < 1)
1536                                                 {
1537                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
1538                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
1539                                                 }
1540                                         }
1541                                         prev_armor = armor;
1542                                 }
1543                                 HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1544                         }
1545                         if(autocvar_hud_panel_healtharmor_text)
1546                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
1547                 }
1548
1549                 if(fuel)
1550                 {
1551                         if (is_vertical)
1552                                 mySize_x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
1553                         else
1554                                 mySize_y *= 0.2;
1555                         if (panel_ar >= 4)
1556                                 mySize_x *= 2; //restore full panel size
1557                         else if (panel_ar < 1/4)
1558                                 mySize_y *= 2; //restore full panel size
1559                         HUD_Panel_GetProgressBarColor(fuel);
1560                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, progressbar_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1561                 }
1562         }
1563 }
1564
1565 // Notification area (#4)
1566 //
1567
1568 void HUD_Notify_Push(string icon, string attacker, string victim)
1569 {
1570         if(icon != "")
1571         {
1572                 --kn_index;
1573                 if (kn_index == -1) { kn_index = KN_MAX_ENTRIES-1; }
1574                 notify_times[kn_index] = time;
1575
1576                 // icon
1577                 if(notify_icon[kn_index]) { strunzone(notify_icon[kn_index]); }
1578                 notify_icon[kn_index] = strzone(icon);
1579
1580                 // attacker
1581                 if(notify_attackers[kn_index]) { strunzone(notify_attackers[kn_index]); }
1582                 notify_attackers[kn_index] = strzone(attacker);
1583
1584                 // victim
1585                 if(notify_victims[kn_index]) { strunzone(notify_victims[kn_index]); }
1586                 notify_victims[kn_index] = strzone(victim);
1587         }
1588 }
1589
1590 void HUD_Notify(void)
1591 {
1592         if(!autocvar__hud_configure)
1593         {
1594                 if(!autocvar_hud_panel_notify) return;
1595         }
1596
1597         HUD_Panel_UpdateCvars();
1598         HUD_Panel_ApplyFadeAlpha();
1599         vector pos, mySize;
1600         pos = panel_pos;
1601         mySize = panel_size;
1602
1603         HUD_Panel_DrawBg(1);
1604         if(panel_bg_padding)
1605         {
1606                 pos += '1 1 0' * panel_bg_padding;
1607                 mySize -= '2 2 0' * panel_bg_padding;
1608         }
1609
1610         float entries, height;
1611         entries = bound(1, floor(KN_MAX_ENTRIES * mySize_y/mySize_x), KN_MAX_ENTRIES);
1612         height = mySize_y/entries;
1613
1614         vector fontsize;
1615         float fontheight = height * autocvar_hud_panel_notify_fontsize;
1616         fontsize = '0.5 0.5 0' * fontheight;
1617
1618         float a;
1619         float when;
1620         when = autocvar_hud_panel_notify_time;
1621         float fadetime;
1622         fadetime = autocvar_hud_panel_notify_fadetime;
1623
1624         vector pos_attacker, pos_victim, pos_icon;
1625         float width_attacker;
1626         string attacker, victim, icon;
1627
1628         float i, j, step, limit;
1629         if(autocvar_hud_panel_notify_flip) //order items from the top down
1630         {
1631                 i = 0;
1632                 step = +1;
1633                 limit = entries;
1634         }
1635         else //order items from the bottom up
1636         {
1637                 i = entries - 1;
1638                 step = -1;
1639                 limit = -1;
1640         }
1641
1642         for(j = kn_index;  i != limit;  i += step, ++j)
1643         {
1644                 if(autocvar__hud_configure)
1645                 {
1646                         if (step == +1)
1647                                 a = i;
1648                         else // inverse order
1649                                 a = entries - 1 - i;
1650                         attacker = textShortenToWidth(sprintf(_("Player %d"), a+1), 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1651                         victim = textShortenToWidth(sprintf(_("Player %d"), a+2), 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1652                         icon = strcat("weapon", get_weaponinfo(WEP_FIRST + mod(floor(a*2.4), WEP_LAST)).netname);
1653                         a = bound(0, (when - a) / 4, 1);
1654                         goto hud_config_notifyprint;
1655                 }
1656                 else
1657                 {
1658                         if (j == KN_MAX_ENTRIES)
1659                                 j = 0;
1660
1661                         if(notify_times[j] + when > time)
1662                                 a = 1;
1663                         else if(fadetime)
1664                         {
1665                                 a = bound(0, (notify_times[j] + when + fadetime - time) / fadetime, 1);
1666                                 if(!a)
1667                                 {
1668                                         break;
1669                                 }
1670                         }
1671                         else
1672                         {
1673                                 break;
1674                         }
1675
1676                         attacker = notify_attackers[j];
1677                         victim = notify_victims[j];
1678                         icon = notify_icon[j];
1679                 }
1680
1681                 //type = notify_deathtype[j];
1682                 //w = DEATH_WEAPONOF(type);
1683
1684                 if(icon != "")
1685                 {
1686                         if((attacker != "") && (victim == ""))
1687                         {
1688                                 // Y [used by] X
1689                                 attacker = textShortenToWidth(attacker, 0.73 * mySize_x - height, fontsize, stringwidth_colors);
1690                                 pos_attacker = pos + eX * (0.27 * mySize_x + height) + eY * ((0.5 * fontsize_y + i * height) + (0.5 * (height - fontheight)));
1691                                 pos_icon = pos + eX * 0.25 * mySize_x - eX * height + eY * i * height;
1692
1693                                 drawpic_aspect_skin(pos_icon, icon, '2 1 0' * height, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
1694                                 drawcolorcodedstring(pos_attacker, attacker, fontsize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
1695                         }
1696                         else if((attacker != "") && (victim != ""))
1697                         {
1698                                 // X [did action to] Y
1699                                 attacker = textShortenToWidth(attacker, 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1700                                 victim = textShortenToWidth(victim, 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1701 :hud_config_notifyprint
1702                                 width_attacker = stringwidth(attacker, TRUE, fontsize);
1703                                 pos_attacker = pos + eX * (0.48 * mySize_x - height - width_attacker) + eY * ((0.5 * fontsize_y + i * height) + (0.5 * (height - fontheight)));
1704                                 pos_victim = pos + eX * (0.52 * mySize_x + height) + eY * ((0.5 * fontsize_y + i * height) + (0.5 * (height - fontheight)));
1705                                 pos_icon = pos + eX * 0.5 * mySize_x - eX * height + eY * i * height;
1706
1707                                 drawpic_aspect_skin(pos_icon, icon, '2 1 0' * height, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
1708                                 drawcolorcodedstring(pos_attacker, attacker, fontsize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
1709                                 drawcolorcodedstring(pos_victim, victim, fontsize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
1710                         }
1711                 }
1712         }
1713 }
1714
1715 // Timer (#5)
1716 //
1717 // TODO: macro
1718 string seconds_tostring(float sec)
1719 {
1720         float minutes;
1721         minutes = floor(sec / 60);
1722
1723         sec -= minutes * 60;
1724         return sprintf("%d:%02d", minutes, sec);
1725 }
1726
1727 void HUD_Timer(void)
1728 {
1729         if(!autocvar__hud_configure)
1730         {
1731                 if(!autocvar_hud_panel_timer) return;
1732         }
1733
1734         HUD_Panel_UpdateCvars();
1735         HUD_Panel_ApplyFadeAlpha();
1736
1737         draw_beginBoldFont();
1738
1739         vector pos, mySize;
1740         pos = panel_pos;
1741         mySize = panel_size;
1742
1743         HUD_Panel_DrawBg(1);
1744         if(panel_bg_padding)
1745         {
1746                 pos += '1 1 0' * panel_bg_padding;
1747                 mySize -= '2 2 0' * panel_bg_padding;
1748         }
1749
1750         string timer;
1751         float timelimit, elapsedTime, timeleft, minutesLeft;
1752
1753         timelimit = getstatf(STAT_TIMELIMIT);
1754
1755         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1756         timeleft = ceil(timeleft);
1757
1758         minutesLeft = floor(timeleft / 60);
1759
1760         vector timer_color;
1761         if(minutesLeft >= 5 || warmup_stage || timelimit == 0) //don't use red or yellow in warmup or when there is no timelimit
1762                 timer_color = '1 1 1'; //white
1763         else if(minutesLeft >= 1)
1764                 timer_color = '1 1 0'; //yellow
1765         else
1766                 timer_color = '1 0 0'; //red
1767
1768         if (autocvar_hud_panel_timer_increment || timelimit == 0 || warmup_stage) {
1769                 if (time < getstatf(STAT_GAMESTARTTIME)) {
1770                         //while restart is still active, show 00:00
1771                         timer = seconds_tostring(0);
1772                 } else {
1773                         elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
1774                         timer = seconds_tostring(elapsedTime);
1775                 }
1776         } else {
1777                 timer = seconds_tostring(timeleft);
1778         }
1779
1780         drawstring_aspect(pos, timer, mySize, timer_color, panel_fg_alpha, DRAWFLAG_NORMAL);
1781
1782         draw_endBoldFont();
1783 }
1784
1785 // Radar (#6)
1786 //
1787 void HUD_Radar(void)
1788 {
1789         if (!autocvar__hud_configure)
1790         {
1791                 if (hud_panel_radar_maximized)
1792                 {
1793                         if (!hud_draw_maximized) return;
1794                 }
1795                 else
1796                 {
1797                         if (autocvar_hud_panel_radar == 0) return;
1798                         if (autocvar_hud_panel_radar != 2 && !teamplay) return;
1799                 }
1800         }
1801
1802         HUD_Panel_UpdateCvars();
1803         HUD_Panel_ApplyFadeAlpha();
1804
1805         float f = 0;
1806
1807         if (hud_panel_radar_maximized && !autocvar__hud_configure)
1808         {
1809                 panel_size = autocvar_hud_panel_radar_maximized_size;
1810                 panel_size_x = bound(0.2, panel_size_x, 1) * vid_conwidth;
1811                 panel_size_y = bound(0.2, panel_size_y, 1) * vid_conheight;
1812                 panel_pos_x = (vid_conwidth - panel_size_x) / 2;
1813                 panel_pos_y = (vid_conheight - panel_size_y) / 2;
1814
1815                 panel_bg = strcat(hud_skin_path, "/border_default"); // always use the default border when maximized
1816                 if(precache_pic(panel_bg) == "") { panel_bg = "gfx/hud/default/border_default"; } // fallback
1817
1818                 switch(hud_panel_radar_maximized_zoommode)
1819                 {
1820                         default:
1821                         case 0:
1822                                 f = current_zoomfraction;
1823                                 break;
1824                         case 1:
1825                                 f = 1 - current_zoomfraction;
1826                                 break;
1827                         case 2:
1828                                 f = 0;
1829                                 break;
1830                         case 3:
1831                                 f = 1;
1832                                 break;
1833                 }
1834
1835                 switch(hud_panel_radar_maximized_rotation)
1836                 {
1837                         case 0:
1838                                 teamradar_angle = view_angles_y - 90;
1839                                 break;
1840                         default:
1841                                 teamradar_angle = 90 * hud_panel_radar_maximized_rotation;
1842                                 break;
1843                 }
1844         }
1845         if (!hud_panel_radar_maximized && !autocvar__hud_configure)
1846         {
1847                 switch(hud_panel_radar_zoommode)
1848                 {
1849                         default:
1850                         case 0:
1851                                 f = current_zoomfraction;
1852                                 break;
1853                         case 1:
1854                                 f = 1 - current_zoomfraction;
1855                                 break;
1856                         case 2:
1857                                 f = 0;
1858                                 break;
1859                         case 3:
1860                                 f = 1;
1861                                 break;
1862                 }
1863
1864                 switch(hud_panel_radar_rotation)
1865                 {
1866                         case 0:
1867                                 teamradar_angle = view_angles_y - 90;
1868                                 break;
1869                         default:
1870                                 teamradar_angle = 90 * hud_panel_radar_rotation;
1871                                 break;
1872                 }
1873         }
1874
1875         vector pos, mySize;
1876         pos = panel_pos;
1877         mySize = panel_size;
1878
1879         HUD_Panel_DrawBg(1);
1880         if(panel_bg_padding)
1881         {
1882                 pos += '1 1 0' * panel_bg_padding;
1883                 mySize -= '2 2 0' * panel_bg_padding;
1884         }
1885
1886         float color2;
1887         entity tm;
1888         float scale2d, normalsize, bigsize;
1889
1890         teamradar_origin2d = pos + 0.5 * mySize;
1891         teamradar_size2d = mySize;
1892
1893         if(minimapname == "")
1894                 return;
1895
1896         teamradar_loadcvars();
1897
1898         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
1899         teamradar_size2d = mySize;
1900
1901         teamradar_extraclip_mins = teamradar_extraclip_maxs = '0 0 0'; // we always center
1902
1903         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
1904         if((hud_panel_radar_rotation == 0 && !hud_panel_radar_maximized) || (hud_panel_radar_maximized_rotation == 0 && hud_panel_radar_maximized))
1905         {
1906                 // max-min distance must fit the radar in any rotation
1907                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen2d(mi_scale));
1908         }
1909         else
1910         {
1911                 vector c0, c1, c2, c3, span;
1912                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
1913                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
1914                 c2 = rotate('1 0 0' * mi_min_x + '0 1 0' * mi_max_y, teamradar_angle * DEG2RAD);
1915                 c3 = rotate('1 0 0' * mi_max_x + '0 1 0' * mi_min_y, teamradar_angle * DEG2RAD);
1916                 span = '0 0 0';
1917                 span_x = max(c0_x, c1_x, c2_x, c3_x) - min(c0_x, c1_x, c2_x, c3_x);
1918                 span_y = max(c0_y, c1_y, c2_y, c3_y) - min(c0_y, c1_y, c2_y, c3_y);
1919
1920                 // max-min distance must fit the radar in x=x, y=y
1921                 bigsize = min(
1922                         teamradar_size2d_x * scale2d / (1.05 * span_x),
1923                         teamradar_size2d_y * scale2d / (1.05 * span_y)
1924                 );
1925         }
1926
1927         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / hud_panel_radar_scale;
1928         if(bigsize > normalsize)
1929                 normalsize = bigsize;
1930
1931         teamradar_size =
1932                   f * bigsize
1933                 + (1 - f) * normalsize;
1934         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
1935                   f * mi_center
1936                 + (1 - f) * view_origin);
1937
1938         drawsetcliparea(
1939                 pos_x,
1940                 pos_y,
1941                 mySize_x,
1942                 mySize_y
1943         );
1944
1945         draw_teamradar_background(hud_panel_radar_foreground_alpha);
1946
1947         for(tm = world; (tm = find(tm, classname, "radarlink")); )
1948                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
1949         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
1950                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm, tm.teamradar_color, panel_fg_alpha);
1951         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
1952         {
1953                 color2 = GetPlayerColor(tm.sv_entnum);
1954                 //if(color == NUM_SPECTATOR || color == color2)
1955                         draw_teamradar_player(tm.origin, tm.angles, Team_ColorRGB(color2));
1956         }
1957         draw_teamradar_player(view_origin, view_angles, '1 1 1');
1958
1959         drawresetcliparea();
1960 }
1961
1962 // Score (#7)
1963 //
1964 void HUD_UpdatePlayerTeams();
1965 void HUD_Score_Rankings(vector pos, vector mySize, entity me, float team_count)
1966 {
1967         float score;
1968         entity tm = world, pl;
1969 #define SCOREPANEL_MAX_ENTRIES 6
1970 #define SCOREPANEL_ASPECTRATIO 2
1971         float entries = bound(1, floor(SCOREPANEL_MAX_ENTRIES * mySize_y/mySize_x * SCOREPANEL_ASPECTRATIO), SCOREPANEL_MAX_ENTRIES);
1972         vector fontsize = '1 1 0' * (mySize_y/entries);
1973
1974         vector rgb, score_color;
1975         rgb = '1 1 1';
1976         score_color = '1 1 1';
1977
1978         float name_size = mySize_x*0.75;
1979         float spacing_size = mySize_x*0.04;
1980         const float highlight_alpha = 0.2;
1981         float i = 0, me_printed = 0, first_pl = 0;
1982         string s;
1983         if (autocvar__hud_configure)
1984         {
1985                 float players_per_team = 0;
1986                 if (team_count)
1987                 {
1988                         // show team scores in the first line
1989                         float score_size = mySize_x / team_count;
1990                         players_per_team = max(2, ceil((entries - 1) / team_count));
1991                         for(i=0; i<team_count; ++i) {
1992                                 if (i == floor((entries - 2) / players_per_team) || (entries == 1 && i == 0))
1993                                         HUD_Panel_DrawHighlight(pos + eX * score_size * i, eX * score_size + eY * fontsize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1994                                 drawstring_aspect(pos + eX * score_size * i, ftos(175 - 23*i), eX * score_size + eY * fontsize_y, Team_ColorRGB(ColorByTeam(i)) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
1995                         }
1996                         first_pl = 1;
1997                         pos_y += fontsize_y;
1998                 }
1999                 score = 10 + SCOREPANEL_MAX_ENTRIES * 3;
2000                 for (i=first_pl; i<entries; ++i)
2001                 {
2002                         //simulate my score is lower than all displayed players,
2003                         //so that I don't appear at all showing pure rankings.
2004                         //This is to better show the difference between the 2 ranking views
2005                         if (i == entries-1 && autocvar_hud_panel_score_rankings == 1)
2006                         {
2007                                 rgb = '1 1 0';
2008                                 drawfill(pos, eX * mySize_x + eY * fontsize_y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2009                                 s = GetPlayerName(player_localnum);
2010                                 score = 7;
2011                         }
2012                         else
2013                         {
2014                                 s = sprintf(_("Player %d"), i + 1 - first_pl);
2015                                 score -= 3;
2016                         }
2017
2018                         if (team_count)
2019                                 score_color = Team_ColorRGB(ColorByTeam(floor((i - first_pl) / players_per_team))) * 0.8;
2020                         s = textShortenToWidth(s, name_size, fontsize, stringwidth_colors);
2021                         drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, TRUE, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2022                         drawstring(pos + eX * (name_size + spacing_size), ftos(score), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2023                         pos_y += fontsize_y;
2024                 }
2025                 return;
2026         }
2027
2028         if (!scoreboard_fade_alpha) // the scoreboard too calls HUD_UpdatePlayerTeams
2029                 HUD_UpdatePlayerTeams();
2030         if (team_count)
2031         {
2032                 // show team scores in the first line
2033                 float score_size = mySize_x / team_count;
2034                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2035                         if(tm.team == NUM_SPECTATOR)
2036                                 continue;
2037                         if (tm.team == myteam)
2038                                 drawfill(pos + eX * score_size * i, eX * score_size + eY * fontsize_y, '1 1 1', highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2039                         drawstring_aspect(pos + eX * score_size * i, ftos(tm.(teamscores[ts_primary])), eX * score_size + eY * fontsize_y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2040                         ++i;
2041                 }
2042                 first_pl = 1;
2043                 pos_y += fontsize_y;
2044                 tm = teams.sort_next;
2045         }
2046         i = first_pl;
2047
2048         do
2049         for (pl = players.sort_next; pl && i<entries; pl = pl.sort_next)
2050         {
2051                 if ((team_count && pl.team != tm.team) || pl.team == NUM_SPECTATOR)
2052                         continue;
2053
2054                 if (i == entries-1 && !me_printed && pl != me)
2055                 if (autocvar_hud_panel_score_rankings == 1 && spectatee_status != -1)
2056                 {
2057                         for (pl = me.sort_next; pl; pl = pl.sort_next)
2058                                 if (pl.team != NUM_SPECTATOR)
2059                                         break;
2060
2061                         if (pl)
2062                                 rgb = '1 1 0'; //not last but not among the leading players: yellow
2063                         else
2064                                 rgb = '1 0 0'; //last: red
2065                         pl = me;
2066                 }
2067
2068                 if (pl == me)
2069                 {
2070                         if (i == first_pl)
2071                                 rgb = '0 1 0'; //first: green
2072                         me_printed = 1;
2073                         drawfill(pos, eX * mySize_x + eY * fontsize_y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2074                 }
2075                 if (team_count)
2076                         score_color = Team_ColorRGB(pl.team) * 0.8;
2077                 s = textShortenToWidth(GetPlayerName(pl.sv_entnum), name_size, fontsize, stringwidth_colors);
2078                 drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, TRUE, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2079                 drawstring(pos + eX * (name_size + spacing_size), ftos(pl.(scores[ps_primary])), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2080                 pos_y += fontsize_y;
2081                 ++i;
2082         }
2083         while (i<entries && team_count && (tm = tm.sort_next) && (tm.team != NUM_SPECTATOR || (tm = tm.sort_next)));
2084 }
2085
2086 void HUD_Score(void)
2087 {
2088         if(!autocvar__hud_configure)
2089         {
2090                 if(!autocvar_hud_panel_score) return;
2091                 if(spectatee_status == -1 && (gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2092         }
2093
2094         HUD_Panel_UpdateCvars();
2095         HUD_Panel_ApplyFadeAlpha();
2096         vector pos, mySize;
2097         pos = panel_pos;
2098         mySize = panel_size;
2099
2100         HUD_Panel_DrawBg(1);
2101         if(panel_bg_padding)
2102         {
2103                 pos += '1 1 0' * panel_bg_padding;
2104                 mySize -= '2 2 0' * panel_bg_padding;
2105         }
2106
2107         float score, distribution = 0;
2108         string sign;
2109         vector distribution_color;
2110         entity tm, pl, me;
2111
2112 #ifdef COMPAT_XON050_ENGINE
2113         me = (spectatee_status > 0) ? playerslots[spectatee_status - 1] : playerslots[player_localentnum - 1];
2114 #else
2115         me = playerslots[player_localentnum - 1];
2116 #endif
2117
2118         if((scores_flags[ps_primary] & SFL_TIME) && !teamplay) { // race/cts record display on HUD
2119                 string timer, distrtimer;
2120
2121                 pl = players.sort_next;
2122                 if(pl == me)
2123                         pl = pl.sort_next;
2124                 if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
2125                         if(pl.scores[ps_primary] == 0)
2126                                 pl = world;
2127
2128                 score = me.(scores[ps_primary]);
2129                 timer = TIME_ENCODED_TOSTRING(score);
2130
2131                 draw_beginBoldFont();
2132                 if (pl && ((!(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)) || score)) {
2133                         // distribution display
2134                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2135
2136                         distrtimer = ftos_decimals(fabs(distribution/pow(10, TIME_DECIMALS)), TIME_DECIMALS);
2137
2138                         if (distribution <= 0) {
2139                                 distribution_color = '0 1 0';
2140                                 sign = "-";
2141                         }
2142                         else {
2143                                 distribution_color = '1 0 0';
2144                                 sign = "+";
2145                         }
2146                         drawstring_aspect(pos + eX * 0.75 * mySize_x, strcat(sign, distrtimer), eX * 0.25 * mySize_x + eY * (1/3) * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2147                 }
2148                 // race record display
2149                 if (distribution <= 0)
2150                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2151                 drawstring_aspect(pos, timer, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2152                 draw_endBoldFont();
2153         } else if (!teamplay) { // non-teamgames
2154                 if ((spectatee_status == -1 && !autocvar__hud_configure) || autocvar_hud_panel_score_rankings)
2155                 {
2156                         HUD_Score_Rankings(pos, mySize, me, 0);
2157                         return;
2158                 }
2159                 // me vector := [team/connected frags id]
2160                 pl = players.sort_next;
2161                 if(pl == me)
2162                         pl = pl.sort_next;
2163
2164                 if(autocvar__hud_configure)
2165                         distribution = 42;
2166                 else if(pl)
2167                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2168                 else
2169                         distribution = 0;
2170
2171                 score = me.(scores[ps_primary]);
2172                 if(autocvar__hud_configure)
2173                         score = 123;
2174
2175                 if(distribution >= 5)
2176                         distribution_color = eY;
2177                 else if(distribution >= 0)
2178                         distribution_color = '1 1 1';
2179                 else if(distribution >= -5)
2180                         distribution_color = '1 1 0';
2181                 else
2182                         distribution_color = eX;
2183
2184                 string distribution_str;
2185                 distribution_str = ftos(distribution);
2186                 draw_beginBoldFont();
2187                 if (distribution >= 0)
2188                 {
2189                         if (distribution > 0)
2190                                 distribution_str = strcat("+", distribution_str);
2191                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2192                 }
2193                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize_x + eY * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2194                 drawstring_aspect(pos + eX * 0.75 * mySize_x, distribution_str, eX * 0.25 * mySize_x + eY * (1/3) * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2195                 draw_endBoldFont();
2196         } else { // teamgames
2197                 float scores_count = 0, row, column, rows = 0, columns = 0;
2198                 local noref vector offset = '0 0 0';
2199                 vector score_pos, score_size; //for scores other than myteam
2200                 if (spectatee_status == -1 || autocvar_hud_panel_score_rankings)
2201                 {
2202                         for(tm = teams.sort_next; tm, tm.team != NUM_SPECTATOR; tm = tm.sort_next)
2203                                 ++scores_count;
2204                         if (autocvar_hud_panel_score_rankings)
2205                         {
2206                                 HUD_Score_Rankings(pos, mySize, me, scores_count);
2207                                 return;
2208                         }
2209                         rows = mySize_y/mySize_x;
2210                         rows = bound(1, floor((sqrt(4 * (3/1) * rows * scores_count + rows * rows) + rows + 0.5) / 2), scores_count);
2211                         //                               ^^^ ammo item aspect goes here
2212
2213                         columns = ceil(scores_count/rows);
2214
2215                         score_size = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
2216
2217                         float newSize;
2218                         if(score_size_x/score_size_y > 3)
2219                         {
2220                                 newSize = 3 * score_size_y;
2221                                 offset_x = score_size_x - newSize;
2222                                 pos_x += offset_x/2;
2223                                 score_size_x = newSize;
2224                         }
2225                         else
2226                         {
2227                                 newSize = 1/3 * score_size_x;
2228                                 offset_y = score_size_y - newSize;
2229                                 pos_y += offset_y/2;
2230                                 score_size_y = newSize;
2231                         }
2232                 }
2233                 else
2234                         score_size = eX * mySize_x*(1/4) + eY * mySize_y*(1/3);
2235
2236                 float max_fragcount;
2237                 max_fragcount = -99;
2238                 draw_beginBoldFont();
2239                 row = column = 0;
2240                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2241                         if(tm.team == NUM_SPECTATOR)
2242                                 continue;
2243                         score = tm.(teamscores[ts_primary]);
2244                         if(autocvar__hud_configure)
2245                                 score = 123;
2246
2247                         if (score > max_fragcount)
2248                                 max_fragcount = score;
2249
2250                         if (spectatee_status == -1)
2251                         {
2252                                 score_pos = pos + eX * column * (score_size_x + offset_x) + eY * row * (score_size_y + offset_y);
2253                                 if (max_fragcount == score)
2254                                         HUD_Panel_DrawHighlight(score_pos, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2255                                 drawstring_aspect(score_pos, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2256                                 ++row;
2257                                 if(row >= rows)
2258                                 {
2259                                         row = 0;
2260                                         ++column;
2261                                 }
2262                         }
2263                         else if(tm.team == myteam) {
2264                                 if (max_fragcount == score)
2265                                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2266                                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize_x + eY * mySize_y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2267                         } else {
2268                                 if (max_fragcount == score)
2269                                         HUD_Panel_DrawHighlight(pos + eX * 0.75 * mySize_x + eY * (1/3) * rows * mySize_y, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2270                                 drawstring_aspect(pos + eX * 0.75 * mySize_x + eY * (1/3) * rows * mySize_y, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2271                                 ++rows;
2272                         }
2273                 }
2274                 draw_endBoldFont();
2275         }
2276 }
2277
2278 // Race timer (#8)
2279 //
2280 void HUD_RaceTimer (void)
2281 {
2282         if(!autocvar__hud_configure)
2283         {
2284                 if(!autocvar_hud_panel_racetimer) return;
2285                 if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2286                 if(spectatee_status == -1) return;
2287         }
2288
2289         HUD_Panel_UpdateCvars();
2290         HUD_Panel_ApplyFadeAlpha();
2291
2292         draw_beginBoldFont();
2293
2294         vector pos, mySize;
2295         pos = panel_pos;
2296         mySize = panel_size;
2297
2298         HUD_Panel_DrawBg(1);
2299         if(panel_bg_padding)
2300         {
2301                 pos += '1 1 0' * panel_bg_padding;
2302                 mySize -= '2 2 0' * panel_bg_padding;
2303         }
2304
2305         // always force 4:1 aspect
2306         vector newSize = '0 0 0';
2307         if(mySize_x/mySize_y > 4)
2308         {
2309                 newSize_x = 4 * mySize_y;
2310                 newSize_y = mySize_y;
2311
2312                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
2313         }
2314         else
2315         {
2316                 newSize_y = 1/4 * mySize_x;
2317                 newSize_x = mySize_x;
2318
2319                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
2320         }
2321         mySize = newSize;
2322
2323         float a, t;
2324         string s, forcetime;
2325
2326         if(autocvar__hud_configure)
2327         {
2328                 s = "0:13:37";
2329                 drawstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, FALSE, '0.60 0.60 0' * mySize_y), s, '0.60 0.60 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2330                 s = _("^1Intermediate 1 (+15.42)");
2331                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.20 * mySize_y) + eY * 0.60 * mySize_y, s, '1 1 0' * 0.20 * mySize_y, panel_fg_alpha, DRAWFLAG_NORMAL);
2332                 s = sprintf(_("^1PENALTY: %.1f (%s)"), 2, "missing a checkpoint");
2333                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.20 * mySize_y) + eY * 0.80 * mySize_y, s, '1 1 0' * 0.20 * mySize_y, panel_fg_alpha, DRAWFLAG_NORMAL);
2334         }
2335         else if(race_checkpointtime)
2336         {
2337                 a = bound(0, 2 - (time - race_checkpointtime), 1);
2338                 s = "";
2339                 forcetime = "";
2340                 if(a > 0) // just hit a checkpoint?
2341                 {
2342                         if(race_checkpoint != 254)
2343                         {
2344                                 if(race_time && race_previousbesttime)
2345                                         s = MakeRaceString(race_checkpoint, TIME_DECODE(race_time) - TIME_DECODE(race_previousbesttime), 0, 0, race_previousbestname);
2346                                 else
2347                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
2348                                 if(race_time)
2349                                         forcetime = TIME_ENCODED_TOSTRING(race_time);
2350                         }
2351                 }
2352                 else
2353                 {
2354                         if(race_laptime && race_nextbesttime && race_nextcheckpoint != 254)
2355                         {
2356                                 a = bound(0, 2 - ((race_laptime + TIME_DECODE(race_nextbesttime)) - (time + TIME_DECODE(race_penaltyaccumulator))), 1);
2357                                 if(a > 0) // next one?
2358                                 {
2359                                         s = MakeRaceString(race_nextcheckpoint, (time + TIME_DECODE(race_penaltyaccumulator)) - race_laptime, TIME_DECODE(race_nextbesttime), 0, race_nextbestname);
2360                                 }
2361                         }
2362                 }
2363
2364                 if(s != "" && a > 0)
2365                 {
2366                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2367                 }
2368
2369                 if(race_penaltytime)
2370                 {
2371                         a = bound(0, 2 - (time - race_penaltyeventtime), 1);
2372                         if(a > 0)
2373                         {
2374                                 s = sprintf(_("^1PENALTY: %.1f (%s)"), race_penaltytime * 0.1, race_penaltyreason);
2375                                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.8 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2376                         }
2377                 }
2378
2379                 if(forcetime != "")
2380                 {
2381                         a = bound(0, (time - race_checkpointtime) / 0.5, 1);
2382                         drawstring_expanding(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(forcetime, FALSE, '1 1 0' * 0.6 * mySize_y), forcetime, '1 1 0' * 0.6 * mySize_y, '1 1 1', panel_fg_alpha, 0, a);
2383                 }
2384                 else
2385                         a = 1;
2386
2387                 if(race_laptime && race_checkpoint != 255)
2388                 {
2389                         s = TIME_ENCODED_TOSTRING(TIME_ENCODE(time + TIME_DECODE(race_penaltyaccumulator) - race_laptime));
2390                         drawstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, FALSE, '0.6 0.6 0' * mySize_y), s, '0.6 0.6 0' * mySize_y, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
2391                 }
2392         }
2393         else
2394         {
2395                 if(race_mycheckpointtime)
2396                 {
2397                         a = bound(0, 2 - (time - race_mycheckpointtime), 1);
2398                         s = MakeRaceString(race_mycheckpoint, TIME_DECODE(race_mycheckpointdelta), -(race_mycheckpointenemy == ""), race_mycheckpointlapsdelta, race_mycheckpointenemy);
2399                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2400                 }
2401                 if(race_othercheckpointtime && race_othercheckpointenemy != "")
2402                 {
2403                         a = bound(0, 2 - (time - race_othercheckpointtime), 1);
2404                         s = MakeRaceString(race_othercheckpoint, -TIME_DECODE(race_othercheckpointdelta), -(race_othercheckpointenemy == ""), race_othercheckpointlapsdelta, race_othercheckpointenemy);
2405                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2406                 }
2407
2408                 if(race_penaltytime && !race_penaltyaccumulator)
2409                 {
2410                         t = race_penaltytime * 0.1 + race_penaltyeventtime;
2411                         a = bound(0, (1 + t - time), 1);
2412                         if(a > 0)
2413                         {
2414                                 if(time < t)
2415                                         s = sprintf(_("^1PENALTY: %.1f (%s)"), (t - time) * 0.1, race_penaltyreason);
2416                                 else
2417                                         s = sprintf(_("^2PENALTY: %.1f (%s)"), 0, race_penaltyreason);
2418                                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2419                         }
2420                 }
2421         }
2422
2423         draw_endBoldFont();
2424 }
2425
2426 // Vote window (#9)
2427 //
2428 float vote_yescount;
2429 float vote_nocount;
2430 float vote_needed;
2431 float vote_highlighted; // currently selected vote
2432
2433 float vote_active; // is there an active vote?
2434 float vote_prev; // previous state of vote_active to check for a change
2435 float vote_alpha;
2436 float vote_change; // "time" when vote_active changed
2437
2438 void HUD_Vote(void)
2439 {
2440         if(autocvar_cl_allow_uid2name == -1 && (gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE || (serverflags & SERVERFLAG_PLAYERSTATS)))
2441         {
2442                 vote_active = 1;
2443                 if (autocvar__hud_configure)
2444                 {
2445                         vote_yescount = 0;
2446                         vote_nocount = 0;
2447                         print(_("^1You must answer before entering hud configure mode\n"));
2448                         cvar_set("_hud_configure", "0");
2449                 }
2450                 if(vote_called_vote)
2451                         strunzone(vote_called_vote);
2452                 vote_called_vote = strzone(_("^2Name ^7instead of \"^1Anonymous player^7\" in stats"));
2453                 uid2name_dialog = 1;
2454         }
2455
2456         if(!autocvar__hud_configure)
2457         {
2458                 if(!autocvar_hud_panel_vote) return;
2459
2460                 panel_fg_alpha = autocvar_hud_panel_fg_alpha;
2461                 panel_bg_alpha_str = autocvar_hud_panel_vote_bg_alpha;
2462
2463                 if(panel_bg_alpha_str == "") {
2464                         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);
2465                 }
2466                 panel_bg_alpha = stof(panel_bg_alpha_str);
2467         }
2468         else
2469         {
2470                 vote_yescount = 3;
2471                 vote_nocount = 2;
2472                 vote_needed = 4;
2473         }
2474
2475         string s;
2476         float a;
2477         if(vote_active != vote_prev) {
2478                 vote_change = time;
2479                 vote_prev = vote_active;
2480         }
2481
2482         if(vote_active || autocvar__hud_configure)
2483                 vote_alpha = bound(0, (time - vote_change) * 2, 1);
2484         else
2485                 vote_alpha = bound(0, 1 - (time - vote_change) * 2, 1);
2486
2487         if(!vote_alpha)
2488                 return;
2489
2490         HUD_Panel_UpdateCvars();
2491         HUD_Panel_ApplyFadeAlpha();
2492
2493         if(uid2name_dialog)
2494         {
2495                 panel_pos = eX * 0.3 * vid_conwidth + eY * 0.1 * vid_conheight;
2496                 panel_size = eX * 0.4 * vid_conwidth + eY * 0.3 * vid_conheight;
2497         }
2498
2499     // these must be below above block
2500         vector pos, mySize;
2501         pos = panel_pos;
2502         mySize = panel_size;
2503
2504         a = vote_alpha * (vote_highlighted ? autocvar_hud_panel_vote_alreadyvoted_alpha : 1);
2505         HUD_Panel_DrawBg(a);
2506         a = panel_fg_alpha * a;
2507
2508         if(panel_bg_padding)
2509         {
2510                 pos += '1 1 0' * panel_bg_padding;
2511                 mySize -= '2 2 0' * panel_bg_padding;
2512         }
2513
2514         // always force 3:1 aspect
2515         vector newSize = '0 0 0';
2516         if(mySize_x/mySize_y > 3)
2517         {
2518                 newSize_x = 3 * mySize_y;
2519                 newSize_y = mySize_y;
2520
2521                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
2522         }
2523         else
2524         {
2525                 newSize_y = 1/3 * mySize_x;
2526                 newSize_x = mySize_x;
2527
2528                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
2529         }
2530         mySize = newSize;
2531
2532         s = _("A vote has been called for:");
2533         if(uid2name_dialog)
2534                 s = _("Allow servers to store and display your name?");
2535         drawstring_aspect(pos, s, eX * mySize_x + eY * (2/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2536         s = textShortenToWidth(vote_called_vote, mySize_x, '1 1 0' * mySize_y * (1/8), stringwidth_colors);
2537         if(autocvar__hud_configure)
2538                 s = _("^1Configure the HUD");
2539         drawcolorcodedstring_aspect(pos + eY * (2/8) * mySize_y, s, eX * mySize_x + eY * (1.75/8) * mySize_y, a, DRAWFLAG_NORMAL);
2540
2541         // print the yes/no counts
2542     s = sprintf(_("Yes (%s): %d"), getcommandkey("vyes", "vyes"), vote_yescount);
2543         drawstring_aspect(pos + eY * (4/8) * mySize_y, s, eX * 0.5 * mySize_x + eY * (1.5/8) * mySize_y, '0 1 0', a, DRAWFLAG_NORMAL);
2544     s = sprintf(_("No (%s): %d"), getcommandkey("vno", "vno"), vote_nocount);
2545         drawstring_aspect(pos + eX * 0.5 * mySize_x + eY * (4/8) * mySize_y, s, eX * 0.5 * mySize_x + eY * (1.5/8) * mySize_y, '1 0 0', a, DRAWFLAG_NORMAL);
2546
2547         // draw the progress bar backgrounds
2548         drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_back", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2549
2550         // draw the highlights
2551         if(vote_highlighted == 1) {
2552                 drawsetcliparea(pos_x, pos_y, mySize_x * 0.5, mySize_y);
2553                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_voted", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2554         }
2555         else if(vote_highlighted == -1) {
2556                 drawsetcliparea(pos_x + 0.5 * mySize_x, pos_y, mySize_x * 0.5, mySize_y);
2557                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_voted", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2558         }
2559
2560         // draw the progress bars
2561         if(vote_yescount && vote_needed)
2562         {
2563                 drawsetcliparea(pos_x, pos_y, mySize_x * 0.5 * (vote_yescount/vote_needed), mySize_y);
2564                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_prog", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2565         }
2566
2567         if(vote_nocount && vote_needed)
2568         {
2569                 drawsetcliparea(pos_x + mySize_x - mySize_x * 0.5 * (vote_nocount/vote_needed), pos_y, mySize_x * 0.5, mySize_y);
2570                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_prog", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2571         }
2572
2573         drawresetcliparea();
2574 }
2575
2576 // Mod icons panel (#10)
2577 //
2578
2579 float mod_active; // is there any active mod icon?
2580
2581 void DrawCAItem(vector myPos, vector mySize, float aspect_ratio, float layout, float i)
2582 {
2583         float stat;
2584         string pic;
2585         vector color;
2586 #ifdef GMQCC
2587         stat = -1;
2588         pic = "";
2589         color = '0 0 0';
2590 #endif
2591         switch(i)
2592         {
2593                 case 0:
2594                         stat = getstati(STAT_REDALIVE);
2595                         pic = "player_red.tga";
2596                         color = '1 0 0';
2597                         break;
2598                 case 1:
2599                         stat = getstati(STAT_BLUEALIVE);
2600                         pic = "player_blue.tga";
2601                         color = '0 0 1';
2602                         break;
2603                 case 2:
2604                         stat = getstati(STAT_YELLOWALIVE);
2605                         pic = "player_yellow.tga";
2606                         color = '1 1 0';
2607                         break;
2608                 default:
2609                 case 3:
2610                         stat = getstati(STAT_PINKALIVE);
2611                         pic = "player_pink.tga";
2612                         color = '1 0 1';
2613                         break;
2614         }
2615
2616         if(mySize_x/mySize_y > aspect_ratio)
2617         {
2618                 i = aspect_ratio * mySize_y;
2619                 myPos_x = myPos_x + (mySize_x - i) / 2;
2620                 mySize_x = i;
2621         }
2622         else
2623         {
2624                 i = 1/aspect_ratio * mySize_x;
2625                 myPos_y = myPos_y + (mySize_y - i) / 2;
2626                 mySize_y = i;
2627         }
2628
2629         if(layout)
2630         {
2631                 drawpic_aspect_skin(myPos, pic, eX * 0.7 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2632                 drawstring_aspect(myPos + eX * 0.7 * mySize_x, ftos(stat), eX * 0.3 * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2633         }
2634         else
2635                 drawstring_aspect(myPos, ftos(stat), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2636 }
2637
2638 // Clan Arena and Freeze Tag HUD modicons
2639 void HUD_Mod_CA(vector myPos, vector mySize)
2640 {
2641         mod_active = 1; // required in each mod function that always shows something
2642         entity tm;
2643         float teams_count = 0;
2644         for(tm = teams.sort_next; tm; tm = tm.sort_next)
2645                 if(tm.team != NUM_SPECTATOR)
2646                         ++teams_count;
2647
2648         float layout;
2649         if(gametype == MAPINFO_TYPE_CA)
2650                 layout = autocvar_hud_panel_modicons_ca_layout;
2651         else //if(gametype == MAPINFO_TYPE_FREEZETAG)
2652                 layout = autocvar_hud_panel_modicons_freezetag_layout;
2653         float rows, columns, aspect_ratio;
2654         rows = mySize_y/mySize_x;
2655         aspect_ratio = (layout) ? 2 : 1;
2656         rows = bound(1, floor((sqrt((4 * aspect_ratio * teams_count + rows) * rows) + rows + 0.5) / 2), teams_count);
2657         columns = ceil(teams_count/rows);
2658
2659         int i;
2660         float row = 0, column = 0;
2661         vector pos, itemSize;
2662         itemSize = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
2663         for(i=0; i<teams_count; ++i)
2664         {
2665                 pos = myPos + eX * column * itemSize_x + eY * row * itemSize_y;
2666
2667                 DrawCAItem(pos, itemSize, aspect_ratio, layout, i);
2668
2669                 ++row;
2670                 if(row >= rows)
2671                 {
2672                         row = 0;
2673                         ++column;
2674                 }
2675         }
2676 }
2677
2678 // CTF HUD modicon section
2679 float redflag_prevframe, blueflag_prevframe; // status during previous frame
2680 float redflag_prevstatus, blueflag_prevstatus; // last remembered status
2681 float redflag_statuschange_time, blueflag_statuschange_time; // time when the status changed
2682
2683 void HUD_Mod_CTF_Reset(void)
2684 {
2685         redflag_prevstatus = blueflag_prevstatus = redflag_prevframe = blueflag_prevframe = redflag_statuschange_time = blueflag_statuschange_time = 0;
2686 }
2687
2688 void HUD_Mod_CTF(vector pos, vector mySize)
2689 {
2690         vector redflag_pos, blueflag_pos;
2691         vector flag_size;
2692         float f; // every function should have that
2693
2694         float redflag, blueflag; // current status
2695         float redflag_statuschange_elapsedtime, blueflag_statuschange_elapsedtime; // time since the status changed
2696         float stat_items;
2697
2698         stat_items = getstati(STAT_ITEMS, 0, 24);
2699         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
2700         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
2701
2702         if(redflag || blueflag)
2703                 mod_active = 1;
2704         else
2705                 mod_active = 0;
2706
2707         if(autocvar__hud_configure)
2708         {
2709                 redflag = 1;
2710                 blueflag = 2;
2711         }
2712
2713         // when status CHANGES, set old status into prevstatus and current status into status
2714         if (redflag != redflag_prevframe)
2715         {
2716                 redflag_statuschange_time = time;
2717                 redflag_prevstatus = redflag_prevframe;
2718                 redflag_prevframe = redflag;
2719         }
2720
2721         if (blueflag != blueflag_prevframe)
2722         {
2723                 blueflag_statuschange_time = time;
2724                 blueflag_prevstatus = blueflag_prevframe;
2725                 blueflag_prevframe = blueflag;
2726         }
2727
2728         redflag_statuschange_elapsedtime = time - redflag_statuschange_time;
2729         blueflag_statuschange_elapsedtime = time - blueflag_statuschange_time;
2730
2731         float BLINK_FACTOR = 0.15;
2732         float BLINK_BASE = 0.85;
2733         // note:
2734         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
2735         // thus
2736         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
2737         // ensure RMS == 1
2738         float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
2739
2740         string red_icon, red_icon_prevstatus;
2741         float red_alpha, red_alpha_prevstatus;
2742         red_alpha = red_alpha_prevstatus = 1;
2743         switch(redflag) {
2744                 case 1: red_icon = "flag_red_taken"; break;
2745                 case 2: red_icon = "flag_red_lost"; break;
2746                 case 3: red_icon = "flag_red_carrying"; red_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2747                 default:
2748                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2749                                 red_icon = "flag_red_shielded";
2750                         else
2751                                 red_icon = string_null;
2752                         break;
2753         }
2754         switch(redflag_prevstatus) {
2755                 case 1: red_icon_prevstatus = "flag_red_taken"; break;
2756                 case 2: red_icon_prevstatus = "flag_red_lost"; break;
2757                 case 3: red_icon_prevstatus = "flag_red_carrying"; red_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2758                 default:
2759                         if(redflag == 3)
2760                                 red_icon_prevstatus = "flag_red_carrying"; // make it more visible
2761                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2762                                 red_icon_prevstatus = "flag_red_shielded";
2763                         else
2764                                 red_icon_prevstatus = string_null;
2765                         break;
2766         }
2767
2768         string blue_icon, blue_icon_prevstatus;
2769         float blue_alpha, blue_alpha_prevstatus;
2770         blue_alpha = blue_alpha_prevstatus = 1;
2771         switch(blueflag) {
2772                 case 1: blue_icon = "flag_blue_taken"; break;
2773                 case 2: blue_icon = "flag_blue_lost"; break;
2774                 case 3: blue_icon = "flag_blue_carrying"; blue_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2775                 default:
2776                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2777                                 blue_icon = "flag_blue_shielded";
2778                         else
2779                                 blue_icon = string_null;
2780                         break;
2781         }
2782         switch(blueflag_prevstatus) {
2783                 case 1: blue_icon_prevstatus = "flag_blue_taken"; break;
2784                 case 2: blue_icon_prevstatus = "flag_blue_lost"; break;
2785                 case 3: blue_icon_prevstatus = "flag_blue_carrying"; blue_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2786                 default:
2787                         if(blueflag == 3)
2788                                 blue_icon_prevstatus = "flag_blue_carrying"; // make it more visible
2789                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2790                                 blue_icon_prevstatus = "flag_blue_shielded";
2791                         else
2792                                 blue_icon_prevstatus = string_null;
2793                         break;
2794         }
2795
2796         if(mySize_x > mySize_y) {
2797                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2798                         redflag_pos = pos;
2799                         blueflag_pos = pos + eX * 0.5 * mySize_x;
2800                 } else {
2801                         blueflag_pos = pos;
2802                         redflag_pos = pos + eX * 0.5 * mySize_x;
2803                 }
2804                 flag_size = eX * 0.5 * mySize_x + eY * mySize_y;
2805         } else {
2806                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2807                         redflag_pos = pos;
2808                         blueflag_pos = pos + eY * 0.5 * mySize_y;
2809                 } else {
2810                         blueflag_pos = pos;
2811                         redflag_pos = pos + eY * 0.5 * mySize_y;
2812                 }
2813                 flag_size = eY * 0.5 * mySize_y + eX * mySize_x;
2814         }
2815
2816         f = bound(0, redflag_statuschange_elapsedtime*2, 1);
2817         if(red_icon_prevstatus && f < 1)
2818                 drawpic_aspect_skin_expanding(redflag_pos, red_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * red_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2819         if(red_icon)
2820                 drawpic_aspect_skin(redflag_pos, red_icon, flag_size, '1 1 1', panel_fg_alpha * red_alpha * f, DRAWFLAG_NORMAL);
2821
2822         f = bound(0, blueflag_statuschange_elapsedtime*2, 1);
2823         if(blue_icon_prevstatus && f < 1)
2824                 drawpic_aspect_skin_expanding(blueflag_pos, blue_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * blue_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2825         if(blue_icon)
2826                 drawpic_aspect_skin(blueflag_pos, blue_icon, flag_size, '1 1 1', panel_fg_alpha * blue_alpha * f, DRAWFLAG_NORMAL);
2827 }
2828
2829 // Keyhunt HUD modicon section
2830 float kh_runheretime;
2831
2832 void HUD_Mod_KH_Reset(void)
2833 {
2834         kh_runheretime = 0;
2835 }
2836
2837 void HUD_Mod_KH(vector pos, vector mySize)
2838 {
2839         mod_active = 1; // keyhunt should never hide the mod icons panel
2840         float kh_keys;
2841         float keyteam;
2842         float a, aa;
2843         vector p = '0 0 0', pa, kh_size = '0 0 0', kh_asize = '0 0 0';
2844
2845         kh_keys = getstati(STAT_KH_KEYS);
2846
2847         p_x = pos_x;
2848         if(mySize_x > mySize_y)
2849         {
2850                 p_y = pos_y + 0.25 * mySize_y;
2851                 pa = p - eY * 0.25 * mySize_y;
2852
2853                 kh_size_x = mySize_x * 0.25;
2854                 kh_size_y = 0.75 * mySize_y;
2855                 kh_asize_x = mySize_x * 0.25;
2856                 kh_asize_y = mySize_y * 0.25;
2857         }
2858         else
2859         {
2860                 p_y = pos_y + 0.125 * mySize_y;
2861                 pa = p - eY * 0.125 * mySize_y;
2862
2863                 kh_size_x = mySize_x * 0.5;
2864                 kh_size_y = 0.375 * mySize_y;
2865                 kh_asize_x = mySize_x * 0.5;
2866                 kh_asize_y = mySize_y * 0.125;
2867         }
2868
2869         float i, key;
2870
2871         float keycount;
2872         keycount = 0;
2873         for(i = 0; i < 4; ++i)
2874         {
2875                 key = floor(kh_keys / pow(32, i)) & 31;
2876                 keyteam = key - 1;
2877                 if(keyteam == 30 && keycount <= 4)
2878                         keycount += 4;
2879                 if(keyteam == myteam || keyteam == -1 || keyteam == 30)
2880                         keycount += 1;
2881         }
2882
2883         // this yields 8 exactly if "RUN HERE" shows
2884
2885         if(keycount == 8)
2886         {
2887                 if(!kh_runheretime)
2888                         kh_runheretime = time;
2889                 pa_y -= fabs(sin((time - kh_runheretime) * 3.5)) * 6; // make the arrows jump in case of RUN HERE
2890         }
2891         else
2892                 kh_runheretime = 0;
2893
2894         for(i = 0; i < 4; ++i)
2895         {
2896                 key = floor(kh_keys / pow(32, i)) & 31;
2897                 keyteam = key - 1;
2898                 switch(keyteam)
2899                 {
2900                         case 30: // my key
2901                                 keyteam = myteam;
2902                                 a = 1;
2903                                 aa = 1;
2904                                 break;
2905                         case -1: // no key
2906                                 a = 0;
2907                                 aa = 0;
2908                                 break;
2909                         default: // owned or dropped
2910                                 a = 0.2;
2911                                 aa = 0.5;
2912                                 break;
2913                 }
2914                 a = a * panel_fg_alpha;
2915                 aa = aa * panel_fg_alpha;
2916                 if(a > 0)
2917                 {
2918                         switch(keyteam)
2919                         {
2920                                 case NUM_TEAM_1:
2921                                         drawpic_aspect_skin(pa, "kh_redarrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2922                                         break;
2923                                 case NUM_TEAM_2:
2924                                         drawpic_aspect_skin(pa, "kh_bluearrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2925                                         break;
2926                                 case NUM_TEAM_3:
2927                                         drawpic_aspect_skin(pa, "kh_yellowarrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2928                                         break;
2929                                 case NUM_TEAM_4:
2930                                         drawpic_aspect_skin(pa, "kh_pinkarrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2931                                         break;
2932                                 default:
2933                                         break;
2934                         }
2935                         switch(i) // YAY! switch(i) inside a for loop for i. DailyWTF, here we come!
2936                         {
2937                                 case 0:
2938                                         drawpic_aspect_skin(p, "kh_red", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2939                                         break;
2940                                 case 1:
2941                                         drawpic_aspect_skin(p, "kh_blue", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2942                                         break;
2943                                 case 2:
2944                                         drawpic_aspect_skin(p, "kh_yellow", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2945                                         break;
2946                                 case 3:
2947                                         drawpic_aspect_skin(p, "kh_pink", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2948                                         break;
2949                         }
2950                 }
2951                 if(mySize_x > mySize_y)
2952                 {
2953                         p_x += 0.25 * mySize_x;
2954                         pa_x += 0.25 * mySize_x;
2955                 }
2956                 else
2957                 {
2958                         if(i == 1)
2959                         {
2960                                 p_y = pos_y + 0.625 * mySize_y;
2961                                 pa_y = pos_y + 0.5 * mySize_y;
2962                                 p_x = pos_x;
2963                                 pa_x = pos_x;
2964                         }
2965                         else
2966                         {
2967                                 p_x += 0.5 * mySize_x;
2968                                 pa_x += 0.5 * mySize_x;
2969                         }
2970                 }
2971         }
2972 }
2973
2974 // Keepaway HUD mod icon
2975 float kaball_prevstatus; // last remembered status
2976 float kaball_statuschange_time; // time when the status changed
2977
2978 // we don't need to reset for keepaway since it immediately
2979 // autocorrects prevstatus as to if the player has the ball or not
2980
2981 void HUD_Mod_Keepaway(vector pos, vector mySize)
2982 {
2983         mod_active = 1; // keepaway should always show the mod HUD
2984
2985         float BLINK_FACTOR = 0.15;
2986         float BLINK_BASE = 0.85;
2987         float BLINK_FREQ = 5;
2988         float kaball_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
2989
2990         float stat_items = getstati(STAT_ITEMS, 0, 24);
2991         float kaball = (stat_items/IT_KEY1) & 1;
2992
2993         if(kaball != kaball_prevstatus)
2994         {
2995                 kaball_statuschange_time = time;
2996                 kaball_prevstatus = kaball;
2997         }
2998
2999         vector kaball_pos, kaball_size;
3000
3001         if(mySize_x > mySize_y) {
3002                 kaball_pos = pos + eX * 0.25 * mySize_x;
3003                 kaball_size = eX * 0.5 * mySize_x + eY * mySize_y;
3004         } else {
3005                 kaball_pos = pos + eY * 0.25 * mySize_y;
3006                 kaball_size = eY * 0.5 * mySize_y + eX * mySize_x;
3007         }
3008
3009         float kaball_statuschange_elapsedtime = time - kaball_statuschange_time;
3010         float f = bound(0, kaball_statuschange_elapsedtime*2, 1);
3011
3012         if(kaball_prevstatus && f < 1)
3013                 drawpic_aspect_skin_expanding(kaball_pos, "keepawayball_carrying", kaball_size, '1 1 1', panel_fg_alpha * kaball_alpha, DRAWFLAG_NORMAL, f);
3014
3015         if(kaball)
3016                 drawpic_aspect_skin(pos, "keepawayball_carrying", eX * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha * kaball_alpha * f, DRAWFLAG_NORMAL);
3017 }
3018
3019
3020 // Nexball HUD mod icon
3021 void HUD_Mod_NexBall(vector pos, vector mySize)
3022 {
3023         float stat_items, nb_pb_starttime, dt, p;
3024
3025         stat_items = getstati(STAT_ITEMS, 0, 24);
3026         nb_pb_starttime = getstatf(STAT_NB_METERSTART);
3027
3028         if (stat_items & IT_KEY1)
3029                 mod_active = 1;
3030         else
3031                 mod_active = 0;
3032
3033         //Manage the progress bar if any
3034         if (nb_pb_starttime > 0)
3035         {
3036                 dt = mod(time - nb_pb_starttime, nb_pb_period);
3037                 // one period of positive triangle
3038                 p = 2 * dt / nb_pb_period;
3039                 if (p > 1)
3040                         p = 2 - p;
3041
3042                 //Draw the filling
3043                 HUD_Panel_GetProgressBarColor(nexball);
3044                 if(mySize_x > mySize_y)
3045                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", p, 0, 0, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3046                 else
3047                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", p, 1, 0, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3048         }
3049
3050         if (stat_items & IT_KEY1)
3051                 drawpic_aspect_skin(pos, "nexball_carrying", eX * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3052 }
3053
3054 // Race/CTS HUD mod icons
3055 float crecordtime_prev; // last remembered crecordtime
3056 float crecordtime_change_time; // time when crecordtime last changed
3057 float srecordtime_prev; // last remembered srecordtime
3058 float srecordtime_change_time; // time when srecordtime last changed
3059
3060 float race_status_time;
3061 float race_status_prev;
3062 string race_status_name_prev;
3063 void HUD_Mod_Race(vector pos, vector mySize)
3064 {
3065         mod_active = 1; // race should never hide the mod icons panel
3066         entity me;
3067         me = playerslots[player_localnum];
3068         float t, score;
3069         float f; // yet another function has this
3070         score = me.(scores[ps_primary]);
3071
3072         if(!(scores_flags[ps_primary] & SFL_TIME) || teamplay) // race/cts record display on HUD
3073                 return; // no records in the actual race
3074
3075         // clientside personal record
3076         string rr;
3077         if(gametype == MAPINFO_TYPE_CTS)
3078                 rr = CTS_RECORD;
3079         else
3080                 rr = RACE_RECORD;
3081         t = stof(db_get(ClientProgsDB, strcat(shortmapname, rr, "time")));
3082
3083         if(score && (score < t || !t)) {
3084                 db_put(ClientProgsDB, strcat(shortmapname, rr, "time"), ftos(score));
3085                 if(autocvar_cl_autodemo_delete_keeprecords)
3086                 {
3087                         f = autocvar_cl_autodemo_delete;
3088                         f &= ~1;
3089                         cvar_set("cl_autodemo_delete", ftos(f)); // don't delete demo with new record!
3090                 }
3091         }
3092
3093         if(t != crecordtime_prev) {
3094                 crecordtime_prev = t;
3095                 crecordtime_change_time = time;
3096         }
3097
3098         vector textPos, medalPos;
3099         float squareSize;
3100         if(mySize_x > mySize_y) {
3101                 // text on left side
3102                 squareSize = min(mySize_y, mySize_x/2);
3103                 textPos = pos + eX * 0.5 * max(0, mySize_x/2 - squareSize) + eY * 0.5 * (mySize_y - squareSize);
3104                 medalPos = pos + eX * 0.5 * max(0, mySize_x/2 - squareSize) + eX * 0.5 * mySize_x + eY * 0.5 * (mySize_y - squareSize);
3105         } else {
3106                 // text on top
3107                 squareSize = min(mySize_x, mySize_y/2);
3108                 textPos = pos + eY * 0.5 * max(0, mySize_y/2 - squareSize) + eX * 0.5 * (mySize_x - squareSize);
3109                 medalPos = pos + eY * 0.5 * max(0, mySize_y/2 - squareSize) + eY * 0.5 * mySize_y + eX * 0.5 * (mySize_x - squareSize);
3110         }
3111
3112         f = time - crecordtime_change_time;
3113
3114         if (f > 1) {
3115                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3116                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3117         } else {
3118                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3119                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3120                 drawstring_aspect_expanding(pos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3121                 drawstring_aspect_expanding(pos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3122         }
3123
3124         // server record
3125         t = race_server_record;
3126         if(t != srecordtime_prev) {
3127                 srecordtime_prev = t;
3128                 srecordtime_change_time = time;
3129         }
3130         f = time - srecordtime_change_time;
3131
3132         if (f > 1) {
3133                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3134                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3135         } else {
3136                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3137                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3138                 drawstring_aspect_expanding(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3139                 drawstring_aspect_expanding(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3140         }
3141
3142         if (race_status != race_status_prev || race_status_name != race_status_name_prev) {
3143                 race_status_time = time + 5;
3144                 race_status_prev = race_status;
3145                 if (race_status_name_prev)
3146                         strunzone(race_status_name_prev);
3147                 race_status_name_prev = strzone(race_status_name);
3148         }
3149
3150         // race "awards"
3151         float a;
3152         a = bound(0, race_status_time - time, 1);
3153
3154         string s;
3155         s = textShortenToWidth(race_status_name, squareSize, '1 1 0' * 0.1 * squareSize, stringwidth_colors);
3156
3157         float rank;
3158         if(race_status > 0)
3159                 rank = race_CheckName(race_status_name);
3160         else
3161                 rank = 0;
3162         string rankname;
3163         rankname = count_ordinal(rank);
3164
3165         vector namepos;
3166         namepos = medalPos + '0 0.8 0' * squareSize;
3167         vector rankpos;
3168         rankpos = medalPos + '0 0.15 0' * squareSize;
3169
3170         if(race_status == 0)
3171                 drawpic_aspect_skin(medalPos, "race_newfail", '1 1 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3172         else if(race_status == 1) {
3173                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newtime", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3174                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3175                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3176         } else if(race_status == 2) {
3177                 if(race_status_name == GetPlayerName(player_localnum) || !race_myrank || race_myrank < rank)
3178                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankgreen", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3179                 else
3180                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankyellow", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3181                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3182                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3183         } else if(race_status == 3) {
3184                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrecordserver", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3185                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3186                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3187         }
3188
3189         if (race_status_time - time <= 0) {
3190                 race_status_prev = -1;
3191                 race_status = -1;
3192                 if(race_status_name)
3193                         strunzone(race_status_name);
3194                 race_status_name = string_null;
3195                 if(race_status_name_prev)
3196                         strunzone(race_status_name_prev);
3197                 race_status_name_prev = string_null;
3198         }
3199 }
3200
3201 void DrawDomItem(vector myPos, vector mySize, float aspect_ratio, float layout, float i)
3202 {
3203         float stat, pps_ratio;
3204         string pic;
3205         vector color;
3206 #ifdef GMQCC
3207         stat = -1;
3208         pic = "";
3209         color = '0 0 0';
3210 #endif
3211         switch(i)
3212         {
3213                 case 0:
3214                         stat = getstatf(STAT_DOM_PPS_RED);
3215                         pic = "dom_icon_red";
3216                         color = '1 0 0';
3217                         break;
3218                 case 1:
3219                         stat = getstatf(STAT_DOM_PPS_BLUE);
3220                         pic = "dom_icon_blue";
3221                         color = '0 0 1';
3222                         break;
3223                 case 2:
3224                         stat = getstatf(STAT_DOM_PPS_YELLOW);
3225                         pic = "dom_icon_yellow";
3226                         color = '1 1 0';
3227                         break;
3228                 default:
3229                 case 3:
3230                         stat = getstatf(STAT_DOM_PPS_PINK);
3231                         pic = "dom_icon_pink";
3232                         color = '1 0 1';
3233                         break;
3234         }
3235         pps_ratio = stat / getstatf(STAT_DOM_TOTAL_PPS);
3236
3237         if(mySize_x/mySize_y > aspect_ratio)
3238         {
3239                 i = aspect_ratio * mySize_y;
3240                 myPos_x = myPos_x + (mySize_x - i) / 2;
3241                 mySize_x = i;
3242         }
3243         else
3244         {
3245                 i = 1/aspect_ratio * mySize_x;
3246                 myPos_y = myPos_y + (mySize_y - i) / 2;
3247                 mySize_y = i;
3248         }
3249
3250         if (layout) // show text too
3251         {
3252                 //draw the text
3253                 color *= 0.5 + pps_ratio * (1 - 0.5); // half saturated color at min, full saturated at max
3254                 if (layout == 2) // average pps
3255                         drawstring_aspect(myPos + eX * mySize_y, ftos_decimals(stat, 2), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3256                 else // percentage of average pps
3257                         drawstring_aspect(myPos + eX * mySize_y, strcat( ftos(floor(pps_ratio*100 + 0.5)), "%" ), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3258         }
3259
3260         //draw the icon
3261         drawpic_aspect_skin(myPos, pic, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3262         if (stat > 0)
3263         {
3264                 drawsetcliparea(myPos_x, myPos_y + mySize_y * (1 - pps_ratio), mySize_y, mySize_y * pps_ratio);
3265                 drawpic_aspect_skin(myPos, strcat(pic, "-highlighted"), '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3266                 drawresetcliparea();
3267         }
3268 }
3269
3270 void HUD_Mod_Dom(vector myPos, vector mySize)
3271 {
3272         mod_active = 1; // required in each mod function that always shows something
3273         entity tm;
3274         float teams_count = 0;
3275         for(tm = teams.sort_next; tm; tm = tm.sort_next)
3276                 if(tm.team != NUM_SPECTATOR)
3277                         ++teams_count;
3278
3279         float layout = autocvar_hud_panel_modicons_dom_layout;
3280         float rows, columns, aspect_ratio;
3281         rows = mySize_y/mySize_x;
3282         aspect_ratio = (layout) ? 3 : 1;
3283         rows = bound(1, floor((sqrt((4 * aspect_ratio * teams_count + rows) * rows) + rows + 0.5) / 2), teams_count);
3284         columns = ceil(teams_count/rows);
3285
3286         int i;
3287         float row = 0, column = 0;
3288         vector pos, itemSize;
3289         itemSize = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
3290         for(i=0; i<teams_count; ++i)
3291         {
3292                 pos = myPos + eX * column * itemSize_x + eY * row * itemSize_y;
3293
3294                 DrawDomItem(pos, itemSize, aspect_ratio, layout, i);
3295
3296                 ++row;
3297                 if(row >= rows)
3298                 {
3299                         row = 0;
3300                         ++column;
3301                 }
3302         }
3303 }
3304
3305 float mod_prev; // previous state of mod_active to check for a change
3306 float mod_alpha;
3307 float mod_change; // "time" when mod_active changed
3308
3309 void HUD_ModIcons(void)
3310 {
3311         if(!autocvar__hud_configure)
3312         {
3313                 if(!autocvar_hud_panel_modicons) return;
3314                 if (gametype != MAPINFO_TYPE_CTF && gametype != MAPINFO_TYPE_KEYHUNT && gametype != MAPINFO_TYPE_NEXBALL && gametype != MAPINFO_TYPE_CTS && gametype != MAPINFO_TYPE_RACE && gametype != MAPINFO_TYPE_CA && gametype != MAPINFO_TYPE_FREEZETAG && gametype != MAPINFO_TYPE_KEEPAWAY && gametype != MAPINFO_TYPE_DOMINATION) return;
3315         }
3316
3317         HUD_Panel_UpdateCvars();
3318         HUD_Panel_ApplyFadeAlpha();
3319
3320         draw_beginBoldFont();
3321
3322         vector pos, mySize;
3323         pos = panel_pos;
3324         mySize = panel_size;
3325
3326         if(mod_active != mod_prev) {
3327                 mod_change = time;
3328                 mod_prev = mod_active;
3329         }
3330
3331         if(mod_active || autocvar__hud_configure)
3332                 mod_alpha = bound(0, (time - mod_change) * 2, 1);
3333         else
3334                 mod_alpha = bound(0, 1 - (time - mod_change) * 2, 1);
3335
3336         if(mod_alpha)
3337                 HUD_Panel_DrawBg(mod_alpha);
3338
3339         if(panel_bg_padding)
3340         {
3341                 pos += '1 1 0' * panel_bg_padding;
3342                 mySize -= '2 2 0' * panel_bg_padding;
3343         }
3344
3345         // these MUST be ran in order to update mod_active
3346         if(gametype == MAPINFO_TYPE_KEYHUNT)
3347                 HUD_Mod_KH(pos, mySize);
3348         else if(gametype == MAPINFO_TYPE_CTF || autocvar__hud_configure)
3349                 HUD_Mod_CTF(pos, mySize); // forcealpha only needed for ctf icons, as only they are shown in config mode
3350         else if(gametype == MAPINFO_TYPE_NEXBALL)
3351                 HUD_Mod_NexBall(pos, mySize);
3352         else if(gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE)
3353                 HUD_Mod_Race(pos, mySize);
3354         else if(gametype == MAPINFO_TYPE_CA || gametype == MAPINFO_TYPE_FREEZETAG)
3355                 HUD_Mod_CA(pos, mySize);
3356         else if(gametype == MAPINFO_TYPE_DOMINATION)
3357                 HUD_Mod_Dom(pos, mySize);
3358         else if(gametype == MAPINFO_TYPE_KEEPAWAY)
3359                 HUD_Mod_Keepaway(pos, mySize);
3360
3361         draw_endBoldFont();
3362 }
3363
3364 // Draw pressed keys (#11)
3365 //
3366 void HUD_PressedKeys(void)
3367 {
3368         if(!autocvar__hud_configure)
3369         {
3370                 if(!autocvar_hud_panel_pressedkeys) return;
3371                 if(spectatee_status <= 0 && autocvar_hud_panel_pressedkeys < 2) return;
3372         }
3373
3374         HUD_Panel_UpdateCvars();
3375         HUD_Panel_ApplyFadeAlpha();
3376         vector pos, mySize;
3377         pos = panel_pos;
3378         mySize = panel_size;
3379
3380         HUD_Panel_DrawBg(1);
3381         if(panel_bg_padding)
3382         {
3383                 pos += '1 1 0' * panel_bg_padding;
3384                 mySize -= '2 2 0' * panel_bg_padding;
3385         }
3386
3387         // force custom aspect
3388         float aspect = autocvar_hud_panel_pressedkeys_aspect;
3389         if(aspect)
3390         {
3391                 vector newSize = '0 0 0';
3392                 if(mySize_x/mySize_y > aspect)
3393                 {
3394                         newSize_x = aspect * mySize_y;
3395                         newSize_y = mySize_y;
3396
3397                         pos_x = pos_x + (mySize_x - newSize_x) / 2;
3398                 }
3399                 else
3400                 {
3401                         newSize_y = 1/aspect * mySize_x;
3402                         newSize_x = mySize_x;
3403
3404                         pos_y = pos_y + (mySize_y - newSize_y) / 2;
3405                 }
3406                 mySize = newSize;
3407         }
3408
3409         vector keysize;
3410         keysize = eX * mySize_x * (1/3.0) + eY * mySize_y * (1/(3.0 - !autocvar_hud_panel_pressedkeys_attack));
3411         float pressedkeys;
3412         pressedkeys = getstatf(STAT_PRESSED_KEYS);
3413
3414         if(autocvar_hud_panel_pressedkeys_attack)
3415         {
3416                 drawpic_aspect_skin(pos + eX * keysize_x * 0.5, ((pressedkeys & KEY_ATCK) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3417                 drawpic_aspect_skin(pos + eX * keysize_x * 1.5, ((pressedkeys & KEY_ATCK2) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3418                 pos_y += keysize_y;
3419         }
3420
3421         drawpic_aspect_skin(pos, ((pressedkeys & KEY_CROUCH) ? "key_crouch_inv.tga" : "key_crouch.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3422         drawpic_aspect_skin(pos + eX * keysize_x, ((pressedkeys & KEY_FORWARD) ? "key_forward_inv.tga" : "key_forward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3423         drawpic_aspect_skin(pos + eX * keysize_x * 2, ((pressedkeys & KEY_JUMP) ? "key_jump_inv.tga" : "key_jump.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3424         pos_y += keysize_y;
3425         drawpic_aspect_skin(pos, ((pressedkeys & KEY_LEFT) ? "key_left_inv.tga" : "key_left.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3426         drawpic_aspect_skin(pos + eX * keysize_x, ((pressedkeys & KEY_BACKWARD) ? "key_backward_inv.tga" : "key_backward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3427         drawpic_aspect_skin(pos + eX * keysize_x * 2, ((pressedkeys & KEY_RIGHT) ? "key_right_inv.tga" : "key_right.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3428 }
3429
3430 // Handle chat as a panel (#12)
3431 //
3432 void HUD_Chat(void)
3433 {
3434         if(!autocvar__hud_configure)
3435         {
3436                 if (!autocvar_hud_panel_chat)
3437                 {
3438                         if (!autocvar_con_chatrect)
3439                                 cvar_set("con_chatrect", "0");
3440                         return;
3441                 }
3442                 if(autocvar__con_chat_maximized)
3443                         if(!hud_draw_maximized) return;
3444         }
3445
3446         HUD_Panel_UpdateCvars();
3447         HUD_Panel_ApplyFadeAlpha();
3448
3449         if(autocvar__con_chat_maximized && !autocvar__hud_configure) // draw at full screen height if maximized
3450         {
3451                 panel_pos_y = panel_bg_border;
3452                 panel_size_y = vid_conheight - panel_bg_border * 2;
3453                 if(panel_bg == "0") // force a border when maximized
3454                 {
3455                         if(precache_pic(panel_bg) == "") {
3456                                 panel_bg = strcat(hud_skin_path, "/border_default");
3457                                 if(precache_pic(panel_bg) == "") {
3458                                         panel_bg = "gfx/hud/default/border_default";
3459                                 }
3460                         }
3461                 }
3462                 panel_bg_alpha = max(0.75, panel_bg_alpha); // force an theAlpha of at least 0.75
3463         }
3464
3465         vector pos, mySize;
3466         pos = panel_pos;
3467         mySize = panel_size;
3468
3469         HUD_Panel_DrawBg(1);
3470
3471         if(panel_bg_padding)
3472         {
3473                 pos += '1 1 0' * panel_bg_padding;
3474                 mySize -= '2 2 0' * panel_bg_padding;
3475         }
3476
3477         if (!autocvar_con_chatrect)
3478                 cvar_set("con_chatrect", "1");
3479
3480         cvar_set("con_chatrect_x", ftos(pos_x/vid_conwidth));
3481         cvar_set("con_chatrect_y", ftos(pos_y/vid_conheight));
3482
3483         cvar_set("con_chatwidth", ftos(mySize_x/vid_conwidth));
3484         cvar_set("con_chat", ftos(floor(mySize_y/autocvar_con_chatsize - 0.5)));
3485
3486         if(autocvar__hud_configure)
3487         {
3488                 vector chatsize;
3489                 chatsize = '1 1 0' * autocvar_con_chatsize;
3490                 cvar_set("con_chatrect_x", "9001"); // over 9000, we'll fake it instead for more control over theAlpha and such
3491                 float i, a;
3492                 for(i = 0; i < autocvar_con_chat; ++i)
3493                 {
3494                         if(i == autocvar_con_chat - 1)
3495                                 a = panel_fg_alpha;
3496                         else
3497                                 a = panel_fg_alpha * floor(((i + 1) * 7 + autocvar_con_chattime)/45);
3498                         drawcolorcodedstring(pos, textShortenToWidth(_("^3Player^7: This is the chat area."), mySize_x, chatsize, stringwidth_colors), chatsize, a, DRAWFLAG_NORMAL);
3499                         pos_y += chatsize_y;
3500                 }
3501         }
3502 }
3503
3504 // Engine info panel (#13)
3505 //
3506 float prevfps;
3507 float prevfps_time;
3508 float framecounter;
3509
3510 float frametimeavg;
3511 float frametimeavg1; // 1 frame ago
3512 float frametimeavg2; // 2 frames ago
3513 void HUD_EngineInfo(void)
3514 {
3515         if(!autocvar__hud_configure)
3516         {
3517                 if(!autocvar_hud_panel_engineinfo) return;
3518         }
3519
3520         HUD_Panel_UpdateCvars();
3521         HUD_Panel_ApplyFadeAlpha();
3522         vector pos, mySize;
3523         pos = panel_pos;
3524         mySize = panel_size;
3525
3526         HUD_Panel_DrawBg(1);
3527         if(panel_bg_padding)
3528         {
3529                 pos += '1 1 0' * panel_bg_padding;
3530                 mySize -= '2 2 0' * panel_bg_padding;
3531         }
3532
3533         float currentTime = gettime(GETTIME_REALTIME);
3534         if(cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage"))
3535         {
3536                 float currentframetime = currentTime - prevfps_time;
3537                 frametimeavg = (frametimeavg + frametimeavg1 + frametimeavg2 + currentframetime)/4; // average three frametimes into framecounter for slightly more stable fps readings :P
3538                 frametimeavg2 = frametimeavg1;
3539                 frametimeavg1 = frametimeavg;
3540
3541                 float weight;
3542                 weight = cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_new_weight");
3543                 if(currentframetime > 0.0001) // filter out insane values which sometimes seem to occur and throw off the average? If you are getting 10,000 fps or more, then you don't need a framerate counter.
3544                 {
3545                         if(fabs(prevfps - (1/frametimeavg)) > prevfps * cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_instantupdate_change_threshold")) // if there was a big jump in fps, just force prevfps at current (1/currentframetime) to make big updates instant
3546                                 prevfps = (1/currentframetime);
3547                         prevfps = (1 - weight) * prevfps + weight * (1/frametimeavg); // framecounter just used so there's no need for a new variable, think of it as "frametime average"
3548                 }
3549                 prevfps_time = currentTime;
3550         }
3551         else
3552         {
3553                 framecounter += 1;
3554                 if(currentTime - prevfps_time > autocvar_hud_panel_engineinfo_framecounter_time)
3555                 {
3556                         prevfps = framecounter/(currentTime - prevfps_time);
3557                         framecounter = 0;
3558                         prevfps_time = currentTime;
3559                 }
3560         }
3561
3562         vector color;
3563         color = HUD_Get_Num_Color (prevfps, 100);
3564         drawstring_aspect(pos, sprintf(_("FPS: %.*f"), autocvar_hud_panel_engineinfo_framecounter_decimals, prevfps), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3565 }
3566
3567 // Info messages panel (#14)
3568 //
3569 #define drawInfoMessage(s)\
3570         if(autocvar_hud_panel_infomessages_flip)\
3571                 o_x = pos_x + mySize_x - stringwidth(s, TRUE, fontsize);\
3572         drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);\
3573         o_y += fontsize_y;
3574 void HUD_InfoMessages(void)
3575 {
3576         if(!autocvar__hud_configure)
3577         {
3578                 if(!autocvar_hud_panel_infomessages) return;
3579         }
3580
3581         HUD_Panel_UpdateCvars();
3582         HUD_Panel_ApplyFadeAlpha();
3583         vector pos, mySize;
3584         pos = panel_pos;
3585         mySize = panel_size;
3586
3587         HUD_Panel_DrawBg(1);
3588         if(panel_bg_padding)
3589         {
3590                 pos += '1 1 0' * panel_bg_padding;
3591                 mySize -= '2 2 0' * panel_bg_padding;
3592         }
3593
3594         // always force 5:1 aspect
3595         vector newSize = '0 0 0';
3596         if(mySize_x/mySize_y > 5)
3597         {
3598                 newSize_x = 5 * mySize_y;
3599                 newSize_y = mySize_y;
3600
3601                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
3602         }
3603         else
3604         {
3605                 newSize_y = 1/5 * mySize_x;
3606                 newSize_x = mySize_x;
3607
3608                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
3609         }
3610
3611         mySize = newSize;
3612         entity tm;
3613         vector o;
3614         o = pos;
3615
3616         vector fontsize;
3617         fontsize = '0.20 0.20 0' * mySize_y;
3618
3619         float a;
3620         a = panel_fg_alpha;
3621
3622         string s;
3623         if(!autocvar__hud_configure)
3624         {
3625                 if(spectatee_status && !intermission)
3626                 {
3627                         a = 1;
3628                         if(spectatee_status == -1)
3629                                 s = _("^1Observing");
3630                         else
3631 #ifdef COMPAT_XON050_ENGINE
3632                                 s = sprintf(_("^1Spectating: ^7%s"), GetPlayerName(spectatee_status - 1));
3633 #else
3634                                 s = sprintf(_("^1Spectating: ^7%s"), GetPlayerName(player_localentnum - 1));
3635 #endif
3636                         drawInfoMessage(s)
3637
3638                         if(spectatee_status == -1)
3639                                 s = sprintf(_("^1Press ^3%s^1 to spectate"), getcommandkey("primary fire", "+fire"));
3640                         else
3641                                 s = sprintf(_("^1Press ^3%s^1 or ^3%s^1 for next or previous player"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3642                         drawInfoMessage(s)
3643
3644                         if(spectatee_status == -1)
3645                                 s = sprintf(_("^1Use ^3%s^1 or ^3%s^1 to change the speed"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3646                         else
3647                                 s = sprintf(_("^1Press ^3%s^1 to observe"), getcommandkey("secondary fire", "+fire2"));
3648                         drawInfoMessage(s)
3649
3650                         s = sprintf(_("^1Press ^3%s^1 for gamemode info"), getcommandkey("server info", "+show_info"));
3651                         drawInfoMessage(s)
3652
3653                         if(gametype == MAPINFO_TYPE_LMS)
3654                         {
3655                                 entity sk;
3656                                 sk = playerslots[player_localnum];
3657                                 if(sk.(scores[ps_primary]) >= 666)
3658                                         s = _("^1Match has already begun");
3659                                 else if(sk.(scores[ps_primary]) > 0)
3660                                         s = _("^1You have no more lives left");
3661                                 else
3662                                         s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3663                         }
3664                         else
3665                                 s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3666                         drawInfoMessage(s)
3667
3668                         //show restart countdown:
3669                         if (time < getstatf(STAT_GAMESTARTTIME)) {
3670                                 float countdown;
3671                                 //we need to ceil, otherwise the countdown would be off by .5 when using round()
3672                                 countdown = ceil(getstatf(STAT_GAMESTARTTIME) - time);
3673                                 s = sprintf(_("^1Game starts in ^3%d^1 seconds"), countdown);
3674                                 drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);
3675                                 o_y += fontsize_y;
3676                         }
3677                 }
3678                 if(warmup_stage && !intermission)
3679                 {
3680                         s = _("^2Currently in ^1warmup^2 stage!");
3681                         drawInfoMessage(s)
3682                 }
3683
3684                 string blinkcolor;
3685                 if(mod(time, 1) >= 0.5)
3686                         blinkcolor = "^1";
3687                 else
3688                         blinkcolor = "^3";
3689
3690                 if(ready_waiting && !intermission && !spectatee_status)
3691                 {
3692                         if(ready_waiting_for_me)
3693                         {
3694                                 if(warmup_stage)
3695                                         s = sprintf(_("%sPress ^3%s%s to end warmup"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3696                                 else
3697                                         s = sprintf(_("%sPress ^3%s%s once you are ready"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3698                         }
3699                         else
3700                         {
3701                                 if(warmup_stage)
3702                                         s = _("^2Waiting for others to ready up to end warmup...");
3703                                 else
3704                                         s = _("^2Waiting for others to ready up...");
3705                         }
3706                         drawInfoMessage(s)
3707                 }
3708                 else if(warmup_stage && !intermission && !spectatee_status)
3709                 {
3710                         s = sprintf(_("^2Press ^3%s^2 to end warmup"), getcommandkey("ready", "ready"));
3711                         drawInfoMessage(s)
3712                 }
3713
3714                 if(teamplay && !intermission && !spectatee_status && gametype != MAPINFO_TYPE_CA && teamnagger)
3715                 {
3716                         float ts_min = 0, ts_max = 0;
3717                         tm = teams.sort_next;
3718                         if (tm)
3719                         {
3720                                 for(; tm.sort_next; tm = tm.sort_next)
3721                                 {
3722                                         if(!tm.team_size || tm.team == NUM_SPECTATOR)
3723                                                 continue;
3724                                         if(!ts_min) ts_min = tm.team_size;
3725                                         else ts_min = min(ts_min, tm.team_size);
3726                                         if(!ts_max) ts_max = tm.team_size;
3727                                         else ts_max = max(ts_max, tm.team_size);
3728                                 }
3729                                 if ((ts_max - ts_min) > 1)
3730                                 {
3731                                         s = strcat(blinkcolor, _("Teamnumbers are unbalanced!"));
3732                                         tm = GetTeam(myteam, false);
3733                                         if (tm)
3734                                         if (tm.team != NUM_SPECTATOR)
3735                                         if (tm.team_size == ts_max)
3736                                                 s = strcat(s, sprintf(_(" Press ^3%s%s to adjust"), getcommandkey("team menu", "menu_showteamselect"), blinkcolor));
3737                                         drawInfoMessage(s)
3738                                 }
3739                         }
3740                 }
3741         }
3742         else
3743         {
3744                 s = _("^7Press ^3ESC ^7to show HUD options.");
3745                 drawInfoMessage(s)
3746                 s = _("^3Doubleclick ^7a panel for panel-specific options.");
3747                 drawInfoMessage(s)
3748                 s = _("^3CTRL ^7to disable collision testing, ^3SHIFT ^7and");
3749                 drawInfoMessage(s)
3750                 s = _("^3ALT ^7+ ^3ARROW KEYS ^7for fine adjustments.");
3751                 drawInfoMessage(s)
3752         }
3753 }
3754
3755 // Physics panel (#15)
3756 //
3757 vector acc_prevspeed;
3758 float acc_prevtime, acc_avg, top_speed, top_speed_time;
3759 void HUD_Physics(void)
3760 {
3761         if(!autocvar__hud_configure)
3762         {
3763                 if(!autocvar_hud_panel_physics) return;
3764                 if(spectatee_status == -1 && (autocvar_hud_panel_physics == 1 || autocvar_hud_panel_physics == 3)) return;
3765                 if(autocvar_hud_panel_physics == 3 && !(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
3766         }
3767
3768         HUD_Panel_UpdateCvars();
3769         HUD_Panel_ApplyFadeAlpha();
3770
3771         draw_beginBoldFont();
3772
3773         HUD_Panel_DrawBg(1);
3774         if(panel_bg_padding)
3775         {
3776                 panel_pos += '1 1 0' * panel_bg_padding;
3777                 panel_size -= '2 2 0' * panel_bg_padding;
3778         }
3779
3780         float acceleration_progressbar_scale = 0;
3781         if(autocvar_hud_panel_physics_progressbar && autocvar_hud_panel_physics_acceleration_progressbar_scale > 1)
3782                 acceleration_progressbar_scale = autocvar_hud_panel_physics_acceleration_progressbar_scale;
3783
3784         float text_scale;
3785         if (autocvar_hud_panel_physics_text_scale <= 0)
3786                 text_scale = 1;
3787         else
3788                 text_scale = min(autocvar_hud_panel_physics_text_scale, 1);
3789
3790         //compute speed
3791         float speed, conversion_factor;
3792         string unit;
3793
3794         switch(autocvar_hud_panel_physics_speed_unit)
3795         {
3796                 default:
3797                 case 1:
3798                         unit = _(" qu/s");
3799                         conversion_factor = 1.0;
3800                         break;
3801                 case 2:
3802                         unit = _(" m/s");
3803                         conversion_factor = 0.0254;
3804                         break;
3805                 case 3:
3806                         unit = _(" km/h");
3807                         conversion_factor = 0.0254 * 3.6;
3808                         break;
3809                 case 4:
3810                         unit = _(" mph");
3811                         conversion_factor = 0.0254 * 3.6 * 0.6213711922;
3812                         break;
3813                 case 5:
3814                         unit = _(" knots");
3815                         conversion_factor = 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
3816                         break;
3817         }
3818
3819         vector vel = (csqcplayer ? csqcplayer.velocity : pmove_vel);
3820
3821         float max_speed = floor( autocvar_hud_panel_physics_speed_max * conversion_factor + 0.5 );
3822         if (autocvar__hud_configure)
3823                 speed = floor( max_speed * 0.65 + 0.5 );
3824         else if(autocvar_hud_panel_physics_speed_vertical)
3825                 speed = floor( vlen(vel) * conversion_factor + 0.5 );
3826         else
3827                 speed = floor( vlen(vel - vel_z * '0 0 1') * conversion_factor + 0.5 );
3828
3829         //compute acceleration
3830         float acceleration, f;
3831         if (autocvar__hud_configure)
3832                 acceleration = autocvar_hud_panel_physics_acceleration_max * 0.3;
3833         else
3834         {
3835                 // 1 m/s = 0.0254 qu/s; 1 g = 9.80665 m/s^2
3836                 f = time - acc_prevtime;
3837                 if(autocvar_hud_panel_physics_acceleration_vertical)
3838                         acceleration = (vlen(vel) - vlen(acc_prevspeed));
3839                 else
3840                         acceleration = (vlen(vel - '0 0 1' * vel_z) - vlen(acc_prevspeed - '0 0 1' * acc_prevspeed_z));
3841
3842                 acceleration = acceleration * (1 / max(0.0001, f)) * (0.0254 / 9.80665);
3843
3844                 acc_prevspeed = vel;
3845                 acc_prevtime = time;
3846
3847                 f = bound(0, f * 10, 1);
3848                 acc_avg = acc_avg * (1 - f) + acceleration * f;
3849         }
3850
3851         //compute layout
3852         float panel_ar = panel_size_x/panel_size_y;
3853         vector speed_offset = '0 0 0', acceleration_offset = '0 0 0';
3854         if (panel_ar >= 5 && !acceleration_progressbar_scale)
3855         {
3856                 panel_size_x *= 0.5;
3857                 if (autocvar_hud_panel_physics_flip)
3858                         speed_offset_x = panel_size_x;
3859                 else
3860                         acceleration_offset_x = panel_size_x;
3861         }
3862         else
3863         {
3864                 panel_size_y *= 0.5;
3865                 if (autocvar_hud_panel_physics_flip)
3866                         speed_offset_y = panel_size_y;
3867                 else
3868                         acceleration_offset_y = panel_size_y;
3869         }
3870         float speed_baralign, acceleration_baralign;
3871         if (autocvar_hud_panel_physics_baralign == 1)
3872                 acceleration_baralign = speed_baralign = 1;
3873     else if(autocvar_hud_panel_physics_baralign == 4)
3874                 acceleration_baralign = speed_baralign = 2;
3875         else if (autocvar_hud_panel_physics_flip)
3876         {
3877                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 2);
3878                 speed_baralign = (autocvar_hud_panel_physics_baralign == 3);
3879         }
3880         else
3881         {
3882                 speed_baralign = (autocvar_hud_panel_physics_baralign == 2);
3883                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 3);
3884         }
3885         if (autocvar_hud_panel_physics_acceleration_progressbar_mode == 0)
3886                 acceleration_baralign = 3; //override hud_panel_physics_baralign value for acceleration
3887
3888         //draw speed
3889         if(speed)
3890         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
3891         {
3892                 HUD_Panel_GetProgressBarColor(speed);
3893                 HUD_Panel_DrawProgressBar(panel_pos + speed_offset, panel_size, "progressbar", speed/max_speed, 0, speed_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3894         }
3895         vector tmp_offset = '0 0 0', tmp_size = '0 0 0';
3896         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
3897         {
3898                 tmp_size_x = panel_size_x * 0.75;
3899                 tmp_size_y = panel_size_y * text_scale;
3900                 if (speed_baralign)
3901                         tmp_offset_x = panel_size_x - tmp_size_x;
3902                 //else
3903                         //tmp_offset_x = 0;
3904                 tmp_offset_y = (panel_size_y - tmp_size_y) / 2;
3905                 drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(speed), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3906
3907                 //draw speed unit
3908                 if (speed_baralign)
3909                         tmp_offset_x = 0;
3910                 else
3911                         tmp_offset_x = tmp_size_x;
3912                 if (autocvar_hud_panel_physics_speed_unit_show)
3913                 {
3914                         //tmp_offset_y = 0;
3915                         tmp_size_x = panel_size_x * (1 - 0.75);
3916                         tmp_size_y = panel_size_y * 0.4 * text_scale;
3917                         tmp_offset_y = (panel_size_y * 0.4 - tmp_size_y) / 2;
3918                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, unit, tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3919                 }
3920         }
3921
3922         //compute and draw top speed
3923         if (autocvar_hud_panel_physics_topspeed)
3924         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
3925         {
3926                 if (autocvar__hud_configure)
3927                 {
3928                         top_speed = floor( max_speed * 0.75 + 0.5 );
3929                         f = 1;
3930                 }
3931                 else
3932                 {
3933                         if (speed >= top_speed)
3934                         {
3935                                 top_speed = speed;
3936                                 top_speed_time = time;
3937                         }
3938                         if (top_speed != 0)
3939                         {
3940                                 f = max(1, autocvar_hud_panel_physics_topspeed_time);
3941                                 // divide by f to make it start from 1
3942                                 f = cos( ((time - top_speed_time) / f) * PI/2 );
3943                         }
3944             else //hide top speed 0, it would be stupid
3945                                 f = 0;
3946                 }
3947                 if (f > 0)
3948                 {
3949                         //top speed progressbar peak
3950                         if(speed < top_speed)
3951                         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
3952                         {
3953                                 float peak_offset_x;
3954                                 vector peak_size = '0 0 0';
3955                                 if (speed_baralign == 0)
3956                                         peak_offset_x = min(top_speed, max_speed)/max_speed * panel_size_x;
3957                 else if (speed_baralign == 1)
3958                                         peak_offset_x = (1 - min(top_speed, max_speed)/max_speed) * panel_size_x;
3959                 else // if (speed_baralign == 2)
3960                     peak_offset_x = min(top_speed, max_speed)/max_speed * panel_size_x * 0.5;
3961                                 //if speed is not 0 the speed progressbar already fetched the color
3962                                 if (speed == 0)
3963                                         HUD_Panel_GetProgressBarColor(speed);
3964                                 peak_size_x = floor(panel_size_x * 0.01 + 1.5);
3965                 peak_size_y = panel_size_y;
3966                 if (speed_baralign == 2) // draw two peaks, on both sides
3967                 {
3968                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size_x + peak_offset_x - peak_size_x), peak_size, progressbar_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3969                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size_x - peak_offset_x + peak_size_x), peak_size, progressbar_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3970                 }
3971                 else
3972                     drawfill(panel_pos + speed_offset + eX * (peak_offset_x - peak_size_x), peak_size, progressbar_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3973                         }
3974
3975                         //top speed
3976                         tmp_offset_y = panel_size_y * 0.4;
3977                         tmp_size_x = panel_size_x * (1 - 0.75);
3978                         tmp_size_y = (panel_size_y - tmp_offset_y) * text_scale;
3979                         tmp_offset_y += (panel_size_y - tmp_offset_y - tmp_size_y) / 2;
3980                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(top_speed), tmp_size, '1 0 0', f * panel_fg_alpha, DRAWFLAG_NORMAL);
3981                 }
3982                 else
3983                         top_speed = 0;
3984         }
3985
3986         //draw acceleration
3987         if(acceleration)
3988         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 3)
3989         {
3990                 if (acceleration < 0)
3991                         HUD_Panel_GetProgressBarColor(acceleration_neg);
3992                 else
3993                         HUD_Panel_GetProgressBarColor(acceleration);
3994
3995                 f = acceleration/autocvar_hud_panel_physics_acceleration_max;
3996                 if (autocvar_hud_panel_physics_acceleration_progressbar_nonlinear)
3997                         f = sqrt(f);
3998
3999                 if (acceleration_progressbar_scale) // allow progressbar to go out of panel bounds
4000                 {
4001                         tmp_size = acceleration_progressbar_scale * panel_size_x * eX + panel_size_y * eY;
4002
4003                         if (acceleration_baralign == 1)
4004                                 tmp_offset_x = panel_size_x - tmp_size_x;
4005                         else if (acceleration_baralign == 2 || acceleration_baralign == 3)
4006                                 tmp_offset_x = (panel_size_x - tmp_size_x) / 2;
4007                         else
4008                                 tmp_offset_x = 0;
4009                         tmp_offset_y = 0;
4010                 }
4011                 else
4012                 {
4013                         tmp_size = panel_size;
4014                         tmp_offset = '0 0 0';
4015                 }
4016
4017                 HUD_Panel_DrawProgressBar(panel_pos + acceleration_offset + tmp_offset, tmp_size, "accelbar", f, 0, acceleration_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4018         }
4019         tmp_size_x = panel_size_x;
4020         tmp_size_y = panel_size_y * text_scale;
4021         tmp_offset_x = 0;
4022         tmp_offset_y = (panel_size_y - tmp_size_y) / 2;
4023         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 3)
4024                 drawstring_aspect(panel_pos + acceleration_offset + tmp_offset, strcat(ftos_decimals(acceleration, 2), "g"), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4025
4026         draw_endBoldFont();
4027 }
4028
4029 // CenterPrint (#16)
4030 //
4031 #define CENTERPRINT_MAX_MSGS 10
4032 #define CENTERPRINT_MAX_ENTRIES 50
4033 #define CENTERPRINT_SPACING 0.7
4034 float cpm_index;
4035 string centerprint_messages[CENTERPRINT_MAX_MSGS];
4036 float centerprint_msgID[CENTERPRINT_MAX_MSGS];
4037 float centerprint_time[CENTERPRINT_MAX_MSGS];
4038 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
4039 float centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
4040 float centerprint_showing;
4041
4042 void centerprint_generic(float new_id, string strMessage, float duration, float countdown_num)
4043 {
4044         //printf("centerprint_generic(%d, '%s^7', %d, %d);\n", new_id, strMessage, duration, countdown_num);
4045         float i, j;
4046
4047         if(strMessage == "" && new_id == 0)
4048                 return;
4049
4050         // strip trailing newlines
4051         j = strlen(strMessage) - 1;
4052         while(substring(strMessage, j, 1) == "\n" && j >= 0)
4053                 --j;
4054         if (j < strlen(strMessage) - 1)
4055                 strMessage = substring(strMessage, 0, j + 1);
4056
4057         if(strMessage == "" && new_id == 0)
4058                 return;
4059
4060         // strip leading newlines
4061         j = 0;
4062         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
4063                 ++j;
4064         if (j > 0)
4065                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
4066
4067         if(strMessage == "" && new_id == 0)
4068                 return;
4069
4070         if (!centerprint_showing)
4071                 centerprint_showing = TRUE;
4072
4073         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4074         {
4075                 if (j == CENTERPRINT_MAX_MSGS)
4076                         j = 0;
4077                 if (new_id && new_id == centerprint_msgID[j])
4078                 {
4079                         if (strMessage == "" && centerprint_messages[j] != "" && centerprint_countdown_num[j] == 0)
4080                         {
4081                                 // fade out the current msg (duration and countdown_num are ignored)
4082                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
4083                                 if (centerprint_expire_time[j] > time + min(5, autocvar_hud_panel_centerprint_fade_out) || centerprint_expire_time[j] < time)
4084                                         centerprint_expire_time[j] = time + min(5, autocvar_hud_panel_centerprint_fade_out);
4085                                 return;
4086                         }
4087                         break; // found a msg with the same id, at position j
4088                 }
4089         }
4090
4091         if (i == CENTERPRINT_MAX_MSGS)
4092         {
4093                 // a msg with the same id was not found, add the msg at the next position
4094                 --cpm_index;
4095                 if (cpm_index == -1)
4096                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
4097                 j = cpm_index;
4098         }
4099         if(centerprint_messages[j])
4100                 strunzone(centerprint_messages[j]);
4101         centerprint_messages[j] = strzone(strMessage);
4102         centerprint_msgID[j] = new_id;
4103         if (duration < 0)
4104         {
4105                 centerprint_time[j] = -1;
4106                 centerprint_expire_time[j] = time;
4107         }
4108         else
4109         {
4110                 if(duration == 0)
4111                         duration = max(1, autocvar_hud_panel_centerprint_time);
4112                 centerprint_time[j] = duration;
4113                 centerprint_expire_time[j] = time + duration;
4114         }
4115         centerprint_countdown_num[j] = countdown_num;
4116 }
4117
4118 void centerprint_hud(string strMessage)
4119 {
4120         centerprint_generic(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
4121 }
4122
4123 void reset_centerprint_messages(void)
4124 {
4125         float i;
4126         for (i=0; i<CENTERPRINT_MAX_MSGS; ++i)
4127         {
4128                 centerprint_expire_time[i] = 0;
4129                 centerprint_time[i] = 1;
4130                 centerprint_msgID[i] = 0;
4131                 if(centerprint_messages[i])
4132                         strunzone(centerprint_messages[i]);
4133                 centerprint_messages[i] = string_null;
4134         }
4135 }
4136 float hud_configure_cp_generation_time;
4137 void HUD_CenterPrint (void)
4138 {
4139         if(!autocvar__hud_configure)
4140         {
4141                 if(!autocvar_hud_panel_centerprint) return;
4142
4143                 if (hud_configure_prev && hud_configure_prev != -1)
4144                         reset_centerprint_messages();
4145         }
4146         else
4147         {
4148                 if (!hud_configure_prev)
4149                         reset_centerprint_messages();
4150                 if (time > hud_configure_cp_generation_time)
4151                 {
4152                         float r;
4153                         r = random();
4154                         if (r > 0.9)
4155                                 centerprint_generic(floor(r*1000), strcat(sprintf("^3Countdown message at time %s", seconds_tostring(time)), ", seconds left: ^COUNT"), 1, 10);
4156                         else if (r > 0.8)
4157                                 centerprint_generic(0, sprintf("^1Multiline message at time %s that\n^1lasts longer than normal", seconds_tostring(time)), 20, 0);
4158                         else
4159                                 centerprint_hud(sprintf("Message at time %s", seconds_tostring(time)));
4160                         hud_configure_cp_generation_time = time + 1 + random()*4;
4161                 }
4162         }
4163
4164         HUD_Panel_UpdateCvars();
4165
4166         // this panel doesn't fade when showing the scoreboard
4167         if(autocvar__menu_alpha)
4168                 HUD_Panel_ApplyFadeAlpha();
4169
4170         if(scoreboard_fade_alpha)
4171         {
4172                 // move the panel below the scoreboard
4173                 if (scoreboard_bottom >= 0.96 * vid_conheight)
4174                         return;
4175                 vector target_pos;
4176
4177                 target_pos = eY * scoreboard_bottom + eX * 0.5 * (vid_conwidth - panel_size_x);
4178
4179                 if(target_pos_y > panel_pos_y)
4180                 {
4181                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
4182                         panel_size_y = min(panel_size_y, vid_conheight - scoreboard_bottom);
4183                 }
4184         }
4185
4186         HUD_Panel_DrawBg(1);
4187
4188         if (!centerprint_showing)
4189                 return;
4190
4191         if(panel_bg_padding)
4192         {
4193                 panel_pos += '1 1 0' * panel_bg_padding;
4194                 panel_size -= '2 2 0' * panel_bg_padding;
4195         }
4196
4197         float entries, height;
4198         vector fontsize;
4199         // entries = bound(1, floor(CENTERPRINT_MAX_ENTRIES * 4 * panel_size_y/panel_size_x), CENTERPRINT_MAX_ENTRIES);
4200         // height = panel_size_y/entries;
4201         // fontsize = '1 1 0' * height;
4202         height = vid_conheight/50 * autocvar_hud_panel_centerprint_fontscale;
4203         fontsize = '1 1 0' * height;
4204         entries = bound(1, floor(panel_size_y/height), CENTERPRINT_MAX_ENTRIES);
4205
4206         float i, j, k, n, g;
4207         float a, sz, align, current_msg_pos_y = 0, msg_size;
4208         vector pos;
4209         string ts;
4210         float all_messages_expired = TRUE;
4211
4212         pos = panel_pos;
4213         if (autocvar_hud_panel_centerprint_flip)
4214                 pos_y += panel_size_y;
4215         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
4216         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4217         {
4218                 if (j == CENTERPRINT_MAX_MSGS)
4219                         j = 0;
4220                 if (centerprint_expire_time[j] <= time)
4221                 {
4222                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0)
4223                         {
4224                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
4225                                 if (centerprint_countdown_num[j] == 0)
4226                                         continue;
4227                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
4228                         }
4229                         else if(centerprint_time[j] != -1)
4230                                 continue;
4231                 }
4232
4233                 all_messages_expired = FALSE;
4234
4235                 // fade the centerprint_hud in/out
4236                 if(centerprint_time[j] < 0)  // Expired but forced. Expire time is the fade-in time.
4237                         a = (time - centerprint_expire_time[j]) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4238                 else if(centerprint_expire_time[j] - autocvar_hud_panel_centerprint_fade_out > time)  // Regularily printed. Not fading out yet.
4239                         a = (time - (centerprint_expire_time[j] - centerprint_time[j])) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4240                 else // Expiring soon, so fade it out.
4241                         a = (centerprint_expire_time[j] - time) / max(0.0001, autocvar_hud_panel_centerprint_fade_out);
4242
4243                 if (a <= 0.5/255.0)  // Guaranteed invisible - don't show.
4244                         continue;
4245                 if (a > 1)
4246                         a = 1;
4247
4248                 // set the size from fading in/out before subsequent fading
4249                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
4250
4251                 // also fade it based on positioning
4252                 if(autocvar_hud_panel_centerprint_fade_subsequent)
4253                 {
4254                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1); // pass one: all messages after the first have half theAlpha
4255                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1); // pass two: after that, gradually lower theAlpha even more for each message
4256                 }
4257                 a *= panel_fg_alpha;
4258
4259                 // finally set the size based on the new theAlpha from subsequent fading
4260                 sz = sz * (autocvar_hud_panel_centerprint_fade_subsequent_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_subsequent_minfontsize));
4261                 drawfontscale = sz * '1 1 0';
4262
4263                 if (centerprint_countdown_num[j])
4264                         n = tokenizebyseparator(strreplace("^COUNT", count_seconds(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
4265                 else
4266                         n = tokenizebyseparator(centerprint_messages[j], "\n");
4267
4268                 if (autocvar_hud_panel_centerprint_flip)
4269                 {
4270                         // check if the message can be entirely shown
4271                         for(k = 0; k < n; ++k)
4272                         {
4273                                 getWrappedLine_remaining = argv(k);
4274                                 while(getWrappedLine_remaining)
4275                                 {
4276                                         ts = getWrappedLine(panel_size_x * sz, fontsize, stringwidth_colors);
4277                                         if (ts != "")
4278                                                 pos_y -= fontsize_y;
4279                                         else
4280                                                 pos_y -= fontsize_y * CENTERPRINT_SPACING/2;
4281                                 }
4282                         }
4283                         current_msg_pos_y = pos_y; // save starting pos (first line) of the current message
4284                 }
4285
4286                 msg_size = pos_y;
4287                 for(k = 0; k < n; ++k)
4288                 {
4289                         getWrappedLine_remaining = argv(k);
4290                         while(getWrappedLine_remaining)
4291                         {
4292                                 ts = getWrappedLine(panel_size_x * sz, fontsize, stringwidth_colors);
4293                                 if (ts != "")
4294                                 {
4295                                         if (align)
4296                                                 pos_x = panel_pos_x + (panel_size_x - stringwidth(ts, TRUE, fontsize)) * align;
4297                                         if (a > 0.5/255.0)  // Otherwise guaranteed invisible - don't show. This is checked a second time after some multiplications with other factors were done so temporary changes of these cannot cause flicker.
4298                                                 drawcolorcodedstring(pos + eY * 0.5 * (1 - sz) * fontsize_y, ts, fontsize, a, DRAWFLAG_NORMAL);
4299                                         pos_y += fontsize_y;
4300                                 }
4301                                 else
4302                                         pos_y += fontsize_y * CENTERPRINT_SPACING/2;
4303                         }
4304                 }
4305
4306                 ++g; // move next position number up
4307
4308                 msg_size = pos_y - msg_size;
4309                 if (autocvar_hud_panel_centerprint_flip)
4310                 {
4311                         pos_y = current_msg_pos_y - CENTERPRINT_SPACING * fontsize_y;
4312                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4313                                 pos_y += (msg_size + CENTERPRINT_SPACING * fontsize_y) * (1 - sqrt(sz));
4314
4315                         if (pos_y < panel_pos_y) // check if the next message can be shown
4316                         {
4317                                 drawfontscale = '1 1 0';
4318                                 return;
4319                         }
4320                 }
4321                 else
4322                 {
4323                         pos_y += CENTERPRINT_SPACING * fontsize_y;
4324                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4325                                 pos_y -= (msg_size + CENTERPRINT_SPACING * fontsize_y) * (1 - sqrt(sz));
4326
4327                         if(pos_y > panel_pos_y + panel_size_y - fontsize_y) // check if the next message can be shown
4328                         {
4329                                 drawfontscale = '1 1 0';
4330                                 return;
4331                         }
4332                 }
4333         }
4334         drawfontscale = '1 1 0';
4335         if (all_messages_expired)
4336         {
4337                 centerprint_showing = FALSE;
4338                 reset_centerprint_messages();
4339         }
4340 }
4341
4342 /*
4343 ==================
4344 Main HUD system
4345 ==================
4346 */
4347
4348 void HUD_Reset (void)
4349 {
4350         // reset gametype specific icons
4351         if(gametype == MAPINFO_TYPE_KEYHUNT)
4352                 HUD_Mod_KH_Reset();
4353         else if(gametype == MAPINFO_TYPE_CTF)
4354                 HUD_Mod_CTF_Reset();
4355 }
4356
4357 void HUD_Main (void)
4358 {
4359         float i;
4360         // global hud theAlpha fade
4361         if(menu_enabled == 1)
4362                 hud_fade_alpha = 1;
4363         else
4364                 hud_fade_alpha = (1 - autocvar__menu_alpha);
4365
4366         if(scoreboard_fade_alpha)
4367                 hud_fade_alpha = (1 - scoreboard_fade_alpha);
4368
4369         if(autocvar__hud_configure)
4370                 if(isdemo())
4371                         HUD_Configure_Exit_Force();
4372
4373         if(intermission == 2) // no hud during mapvote
4374         {
4375                 if (autocvar__hud_configure)
4376                         HUD_Configure_Exit_Force();
4377                 hud_fade_alpha = 0;
4378         }
4379         else if(autocvar__menu_alpha == 0 && scoreboard_fade_alpha == 0)
4380                 hud_fade_alpha = 1;
4381
4382         // panels that we want to be active together with the scoreboard
4383         // they must call HUD_Panel_ApplyFadeAlpha(); only when showing the menu
4384         if(scoreboard_fade_alpha == 1)
4385         {
4386                 (panel = HUD_PANEL(CENTERPRINT)).panel_draw();
4387                 return;
4388         }
4389
4390         if(!autocvar__hud_configure && !hud_fade_alpha)
4391                 return;
4392
4393         // Drawing stuff
4394         if (hud_skin_prev != autocvar_hud_skin)
4395         {
4396                 if (hud_skin_path)
4397                         strunzone(hud_skin_path);
4398                 hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
4399                 if (hud_skin_prev)
4400                         strunzone(hud_skin_prev);
4401                 hud_skin_prev = strzone(autocvar_hud_skin);
4402         }
4403
4404         // HUD configure visible grid
4405         if(autocvar__hud_configure && autocvar_hud_configure_grid && autocvar_hud_configure_grid_alpha)
4406         {
4407                 hud_configure_gridSize_x = bound(0.005, cvar("hud_configure_grid_xsize"), 0.2);
4408                 hud_configure_gridSize_y = bound(0.005, cvar("hud_configure_grid_ysize"), 0.2);
4409                 hud_configure_realGridSize_x = hud_configure_gridSize_x * vid_conwidth;
4410                 hud_configure_realGridSize_y = hud_configure_gridSize_y * vid_conheight;
4411                 vector s;
4412                 // x-axis
4413                 s = eX + eY * vid_conheight;
4414                 for(i = 1; i < 1/hud_configure_gridSize_x; ++i)
4415                         drawfill(eX * i * hud_configure_realGridSize_x, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
4416                 // y-axis
4417                 s = eY + eX * vid_conwidth;
4418                 for(i = 1; i < 1/hud_configure_gridSize_y; ++i)
4419                         drawfill(eY * i * hud_configure_realGridSize_y, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
4420         }
4421
4422 #ifdef COMPAT_XON050_ENGINE
4423     current_player = (spectatee_status > 0) ? spectatee_status : player_localentnum;
4424 #else
4425     current_player = player_localentnum;
4426 #endif
4427
4428         // draw the dock
4429         if(autocvar_hud_dock != "" && autocvar_hud_dock != "0")
4430         {
4431                 float f;
4432                 vector color;
4433                 float hud_dock_color_team = autocvar_hud_dock_color_team;
4434                 if((teamplay) && hud_dock_color_team) {
4435                         if(autocvar__hud_configure && myteam == NUM_SPECTATOR)
4436                                 color = '1 0 0' * hud_dock_color_team;
4437                         else
4438                                 color = myteamcolors * hud_dock_color_team;
4439                 }
4440                 else if(autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && hud_dock_color_team) {
4441                         color = '1 0 0' * hud_dock_color_team;
4442                 }
4443                 else
4444                 {
4445                         string hud_dock_color = autocvar_hud_dock_color;
4446                         if(hud_dock_color == "shirt") {
4447                                 f = stof(getplayerkeyvalue(current_player - 1, "colors"));
4448                                 color = colormapPaletteColor(floor(f / 16), 0);
4449                         }
4450                         else if(hud_dock_color == "pants") {
4451                                 f = stof(getplayerkeyvalue(current_player - 1, "colors"));
4452                                 color = colormapPaletteColor(mod(f, 16), 1);
4453                         }
4454                         else
4455                                 color = stov(hud_dock_color);
4456                 }
4457
4458                 string pic;
4459                 pic = strcat(hud_skin_path, "/", autocvar_hud_dock);
4460                 if(precache_pic(pic) == "") {
4461                         pic = strcat(hud_skin_path, "/dock_medium");
4462                         if(precache_pic(pic) == "") {
4463                                 pic = "gfx/hud/default/dock_medium";
4464                         }
4465                 }
4466                 drawpic('0 0 0', pic, eX * vid_conwidth + eY * vid_conheight, color, autocvar_hud_dock_alpha * hud_fade_alpha, DRAWFLAG_NORMAL); // no aspect ratio forcing on dock...
4467         }
4468
4469         // cache the panel order into the panel_order array
4470         if(autocvar__hud_panelorder != hud_panelorder_prev) {
4471                 for(i = 0; i < HUD_PANEL_NUM; ++i)
4472                         panel_order[i] = -1;
4473                 string s = "";
4474                 float p_num, warning = false;
4475                 float argc = tokenize_console(autocvar__hud_panelorder);
4476                 if (argc > HUD_PANEL_NUM)
4477                         warning = true;
4478                 //first detect wrong/missing panel numbers
4479                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4480                         p_num = stof(argv(i));
4481                         if (p_num >= 0 && p_num < HUD_PANEL_NUM) { //correct panel number?
4482                                 if (panel_order[p_num] == -1) //found for the first time?
4483                                         s = strcat(s, ftos(p_num), " ");
4484                                 panel_order[p_num] = 1; //mark as found
4485                         }
4486                         else
4487                                 warning = true;
4488                 }
4489                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4490                         if (panel_order[i] == -1) {
4491                                 warning = true;
4492                                 s = strcat(s, ftos(i), " "); //add missing panel number
4493                         }
4494                 }
4495                 if (warning)
4496                         print(_("Automatically fixed wrong/missing panel numbers in _hud_panelorder\n"));
4497
4498                 cvar_set("_hud_panelorder", s);
4499                 if(hud_panelorder_prev)
4500                         strunzone(hud_panelorder_prev);
4501                 hud_panelorder_prev = strzone(s);
4502
4503                 //now properly set panel_order
4504                 tokenize_console(s);
4505                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4506                         panel_order[i] = stof(argv(i));
4507                 }
4508         }
4509
4510         hud_draw_maximized = 0;
4511         // draw panels in order specified by panel_order array
4512         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
4513                 (panel = hud_panel[panel_order[i]]).panel_draw();
4514
4515         hud_draw_maximized = 1; // panels that may be maximized must check this var
4516         // draw maximized panels on top
4517         if(hud_panel_radar_maximized)
4518                 (panel = HUD_PANEL(RADAR)).panel_draw();
4519         if(autocvar__con_chat_maximized)
4520                 (panel = HUD_PANEL(CHAT)).panel_draw();
4521
4522         if(autocvar__hud_configure)
4523         {
4524                 if(tab_panel)
4525                 {
4526                         panel = tab_panel;
4527                         HUD_Panel_UpdatePosSize()
4528                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .2, DRAWFLAG_NORMAL);
4529                 }
4530                 if(highlightedPanel)
4531                 {
4532                         panel = highlightedPanel;
4533                         HUD_Panel_UpdatePosSize()
4534                         HUD_Panel_HlBorder(panel_bg_border + 1.5 * hlBorderSize, '0 0.5 1', 0.25 * (1 - autocvar__menu_alpha));
4535                 }
4536                 if(!hud_configure_prev || hud_configure_prev == -1)
4537                 {
4538                         if(autocvar_hud_cursormode) { setcursormode(1); }
4539                         hudShiftState = 0;
4540                         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
4541                                 hud_panel[panel_order[i]].update_time = time;
4542                 }
4543         }
4544         else if(hud_configure_prev && hud_configure_prev != -1 && autocvar_hud_cursormode)
4545                 setcursormode(0);
4546
4547         hud_configure_prev = autocvar__hud_configure;
4548
4549         if (!autocvar__hud_configure) // hud config mode disabled, enable normal theAlpha stuff again
4550                 if (menu_enabled)
4551                         menu_enabled = 0;
4552 }