data/qcsrc/server/vore.qc

   1 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   2 .float complain_vore;\r
   3 .float vore_oldmovetype, vore_oldsolid;\r
   4 \r
   5 const float system_delay_time = 0.1;\r
   6 const float complain_delay_time = 1;\r
   7 const float button_delay_time = 0.5;\r
   8 const float steptime = 0.1;\r
   9 \r
  10 entity Swallow_player_check()\r
  11 {\r
  12         // check if we can swallow a player instead of firing our weapon\r
  13 \r
  14         float swallow_range;\r
  15         vector vore_w_shotorg, vore_w_shotdir;\r
  16 \r
  17         swallow_range = cvar("g_balance_vore_swallow_range");\r
  18         if(cvar("g_healthsize")) // we can swallow from further or closer based on our size\r
  19                 swallow_range *= self.scale;\r
  20         makevectors(self.angles);\r
  21         vore_w_shotorg = self.origin;\r
  22         vore_w_shotdir = v_forward;\r
  23 \r
  24         if(self.antilag_debug)\r
  25                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, self.antilag_debug);\r
  26         else\r
  27                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  28         if(trace_fraction < 1)\r
  29         if(trace_ent.classname == "player")\r
  30                 return trace_ent;\r
  31         return world;\r
  32 }\r
  33 \r
  34 float Swallow_condition_check(entity prey)\r
  35 {\r
  36         // checks the necessary conditions for swallowing a player\r
  37 \r
  38         if(prey != self)\r
  39         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  40         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  41         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  42         {\r
  43                 float prey_mass;\r
  44                 prey_mass = cvar("g_balance_vore_load_prey_mass");\r
  45                 if(cvar("g_healthsize"))\r
  46                         prey_mass *= prey.scale;\r
  47 \r
  48                 string swallow_complain;\r
  49                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  50                         swallow_complain = "You cannot swallow your team mates\n";\r
  51                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  52                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  53                 else if(self.stomach_load + prey_mass > self.stomach_maxload)\r
  54                         swallow_complain = strcat("You don't have any room to swallow this player. Their mass is ^3", ftos(prey_mass), "^7 and your remaining capacity is ^3", ftos(self.stomach_maxload - self.stomach_load), "\n");\r
  55                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  56                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  57                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  58                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  59 \r
  60                 if(swallow_complain != "")\r
  61                 {\r
  62                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  63                         {\r
  64                                 play2(self, "misc/forbidden.wav");\r
  65                                 sprint(self, swallow_complain);\r
  66                                 self.complain_vore = time + complain_delay_time;\r
  67                         }\r
  68                         return FALSE;\r
  69                 }\r
  70                 return TRUE;\r
  71         }\r
  72         return FALSE;\r
  73 }\r
  74 \r
  75 float Stomach_TeamMates_check(entity pred)\r
  76 {\r
  77         // checks if a player's stomach contains any team mates\r
  78 \r
  79         entity head;\r
  80         if(teams_matter)\r
  81         {\r
  82                 FOR_EACH_PLAYER(head)\r
  83                 {\r
  84                         if(head.predator == pred && head.team == pred.team)\r
  85                                 return TRUE;\r
  86                 }\r
  87         }\r
  88         return FALSE;\r
  89 }\r
  90 \r
  91 float Stomach_HasLivePrey(entity pred)\r
  92 {\r
  93         entity head;\r
  94         FOR_EACH_PLAYER(head)\r
  95         {\r
  96                 if(head.predator == pred)\r
  97                 if(head.deadflag == DEAD_NO)\r
  98                         return TRUE;\r
  99         }\r
 100         return FALSE;\r
 101 }\r
 102 \r
 103 float Vore_CanLeave()\r
 104 {\r
 105         if(self.stat_eaten)\r
 106         {\r
 107                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
 108                         return TRUE;\r
 109                 if(teams_matter && self.team == self.predator.team)\r
 110                         return TRUE;\r
 111                 if(g_rpg && cvar("g_rpg_canleave"))\r
 112                         return TRUE;\r
 113         }\r
 114         return FALSE;\r
 115 }\r
 116 \r
 117 // position the camera properly for prey\r
 118 void Vore_SetPreyPositions(entity pred)\r
 119 {\r
 120         // pred is the predator and head is the prey\r
 121 \r
 122         local entity head;\r
 123 \r
 124         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 125         // else all players overlap in the center. To do this, we use a random origin on all players in the same stomach.\r
 126         FOR_EACH_PLAYER(head)\r
 127         {\r
 128                 if(head.predator == pred)\r
 129                 {\r
 130                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 131                         head.view_ofs_x = PL_PREY_VIEW_OFS_x + crandom() * cvar("g_vore_neighborprey_distance");\r
 132                         head.view_ofs_y = PL_PREY_VIEW_OFS_y + crandom() * cvar("g_vore_neighborprey_distance");\r
 133                         head.view_ofs_z = PL_PREY_VIEW_OFS_z;\r
 134                 }\r
 135         }\r
 136 }\r
 137 \r
 138 .float gurgle_oldstomachload;\r
 139 void Vore_GurgleSound()\r
 140 {\r
 141         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 142         {\r
 143                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 144 \r
 145                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 146                 self.gurgle_oldstomachload = self.stomach_load;\r
 147         }\r
 148 }\r
 149 \r
 150 void Vore_StomachLoad_Apply()\r
 151 {\r
 152         // apply stomach weight that makes you heavier and larger the more you eat\r
 153         // slowing the player is done in cl_physics.qc\r
 154         if(self.classname != "player")\r
 155                 return;\r
 156 \r
 157         entity e;\r
 158         float prey_mass;\r
 159 \r
 160         // apply the stomach capacity of the predator\r
 161         self.stomach_maxload = cvar("g_balance_vore_load_pred_capacity");\r
 162         if(cvar("g_healthsize"))\r
 163                 self.stomach_maxload *= self.scale;\r
 164         self.stomach_maxload = floor(self.stomach_maxload);\r
 165 \r
 166         self.stomach_load = 0; // start from zero\r
 167         FOR_EACH_PLAYER(e)\r
 168         {\r
 169                 if(e.predator == self)\r
 170                 {\r
 171                         prey_mass = cvar("g_balance_vore_load_prey_mass");\r
 172                         if(cvar("g_healthsize"))\r
 173                                 prey_mass *= e.scale;\r
 174                         self.stomach_load += floor(prey_mass);\r
 175                 }\r
 176         }\r
 177         for(e = world; (e = find(e, classname, "consumable")); )\r
 178         {\r
 179                 if(e.predator == self)\r
 180                         self.stomach_load += floor(e.dmg);\r
 181         }\r
 182 \r
 183         // apply weight\r
 184         self.gravity = 1 + (self.stomach_load / self.stomach_maxload) * cvar("g_balance_vore_load_pred_weight");\r
 185         if(!self.gravity && self.stomach_load)\r
 186                 self.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 187 }\r
 188 \r
 189 void Vore_AutoDigest(entity e)\r
 190 {\r
 191         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 192 \r
 193         if(!cvar("g_vore_digestion") || e.digesting)\r
 194                 return;\r
 195         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 196                 return; // this feature is only for players, not bots\r
 197         if(e.stomach_load)\r
 198                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 199         if(Stomach_TeamMates_check(e))\r
 200                 return; // never begin automatic digestion if we've swallowed a team mate\r
 201 \r
 202         e.digesting = TRUE;\r
 203 }\r
 204 \r
 205 .entity swallow_model;\r
 206 float Vore_SwallowModel_CustomizeEntityForClient()\r
 207 {\r
 208         // use the same system as the weapon model\r
 209 \r
 210         self.viewmodelforclient = self.owner;\r
 211         self.alpha = self.owner.cvar_cl_vore_swallowmodel;\r
 212 \r
 213         if(other.classname == "spectator")\r
 214         if(other.enemy == self.owner)\r
 215         {\r
 216                 self.viewmodelforclient = other;\r
 217                 self.alpha = other.cvar_cl_vore_swallowmodel;\r
 218         }\r
 219 \r
 220         return TRUE;\r
 221 }\r
 222 \r
 223 void Vore_SwallowModel_Think()\r
 224 {\r
 225         // update the position of the swallow model to match our swallow progress\r
 226         float dist;\r
 227         dist = (-0.5 + self.owner.swallow_progress_prey) * cvar("g_vore_swallowmodel_range"); // the model is centered at 0.5 progress\r
 228         if(cvar("g_healthsize"))\r
 229                 dist *= self.scale;\r
 230         self.view_ofs = '1 0 0' * dist;\r
 231 \r
 232         // if our swallow progress is gone or we are dead, the swallow model also goes away\r
 233         if(!self.owner.swallow_progress_prey || self.owner.deadflag != DEAD_NO || self.owner.classname != "player")\r
 234         {\r
 235                 remove(self.owner.swallow_model);\r
 236                 self.owner.swallow_model = world;\r
 237                 return;\r
 238         }\r
 239 \r
 240         // properties that should update whenever possible, but when the predator is not available\r
 241         self.nextthink = time;\r
 242 }\r
 243 \r
 244 void Vore_SwallowModel_Update(entity prey, entity pred)\r
 245 {\r
 246         // if we don't have a swallow model already, spawn one\r
 247         if(!prey.swallow_model)\r
 248         {\r
 249                 prey.swallow_model = spawn();\r
 250                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 251                 prey.swallow_model.solid = SOLID_NOT;\r
 252                 //prey.swallow_model.effects |= EF_NOGUNBOB; // let it bob\r
 253                 prey.swallow_model.effects |= EF_NODEPTHTEST; // don't hide behind walls\r
 254                 prey.swallow_model.owner = prey;\r
 255                 prey.swallow_model.customizeentityforclient = Vore_SwallowModel_CustomizeEntityForClient;\r
 256                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
 257                 prey.swallow_model.nextthink = time;\r
 258         }\r
 259 \r
 260         // properties that should update whenever possible, but when the predator is available\r
 261         string player_swallowmodel;\r
 262         player_swallowmodel = strcat(substring(pred.playermodel, 0, strlen(pred.playermodel) - 4), "_swallow.md3"); // 4 is the extension length\r
 263         if(prey.swallow_model.model != player_swallowmodel) // player model can be changed while the predator is active\r
 264                 setmodel(prey.swallow_model, player_swallowmodel);\r
 265         if(prey.swallow_model.skin != pred.skin) // player skin can be changed while the predator is active\r
 266                 prey.swallow_model.skin = pred.skin;\r
 267         if(cvar("g_healthsize"))\r
 268                 prey.swallow_model.scale = pred.scale / prey.scale; // player size difference\r
 269         if(prey.swallow_model.enemy != pred)\r
 270                 prey.swallow_model.enemy = pred; // enemy is the predator\r
 271         if(prey.swallow_model.colormap != pred.colormap)\r
 272                 prey.swallow_model.colormap = pred.colormap; // pants and shirt color\r
 273         if(prey.swallow_model.glowmod != pred.glowmod)\r
 274                 prey.swallow_model.glowmod = pred.glowmod; // glow color\r
 275 }\r
 276 \r
 277 .entity pusher;\r
 278 .float pushltime;\r
 279 void Vore_Swallow(entity e)\r
 280 {\r
 281         // this player is being swallowed by another player, apply the proper changes\r
 282 \r
 283         e.vore_oldmovetype = e.movetype;\r
 284         e.vore_oldsolid = e.solid;\r
 285         e.punchvector_z = cvar("g_balance_vore_swallow_prey_punchvector");\r
 286 \r
 287         e.predator = self;\r
 288         setorigin(e, e.predator.origin);\r
 289         e.velocity = '0 0 0';\r
 290         e.movetype = MOVETYPE_FOLLOW;\r
 291         e.solid = SOLID_NOT;\r
 292         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 293 \r
 294         // drop keys (KH) and flags (CTF) when we get swallowed\r
 295         kh_Key_DropAll(e, FALSE);\r
 296         if(e.flagcarried)\r
 297                 DropFlag(e.flagcarried, world, e.predator);\r
 298 \r
 299         if(stov(cvar_string("g_vore_regurgitatecolor_color_normal")))\r
 300                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_normal"));\r
 301 \r
 302         if(teams_matter && e.team == e.predator.team)\r
 303         {\r
 304                 if(cvar("g_vore_kick"))\r
 305                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 306                 if(cvar("g_vore_digestion"))\r
 307                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 308         }\r
 309 \r
 310         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 311         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 312         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_predator_punchangle");\r
 313         e.predator.regurgitate_prepare = 0;\r
 314         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 315         e.predator.hitsound += 1; // play this for team mates too, as we could be swallowing them to heal them\r
 316         Vore_AutoDigest(e.predator);\r
 317         Vore_SetPreyPositions(e.predator);\r
 318 \r
 319         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 320         e.predator.weapon_delay = time + button_delay_time;\r
 321         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 322         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 323         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 324 }\r
 325 \r
 326 void Vore_SwallowStep(entity e)\r
 327 {\r
 328         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 329         {\r
 330                 Vore_Swallow(e);\r
 331                 return;\r
 332         }\r
 333 \r
 334         Vore_SwallowModel_Update(e, self);\r
 335 \r
 336         // increase the progress value until it reaches 1, then swallow the player\r
 337         if(e.swallow_progress_prey < 1)\r
 338         {\r
 339                 float fill;\r
 340                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 341                 if(cvar("g_healthsize") && cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 342                         fill *= pow(self.scale / e.scale, cvar("g_balance_vore_swallow_speed_fill_scalediff"));\r
 343                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 344                         fill /= e.stomach_load;\r
 345 \r
 346                 e.swallow_progress_prey += fill;\r
 347         }\r
 348         else\r
 349         {\r
 350                 Vore_Swallow(e);\r
 351                 e.swallow_progress_prey = 0;\r
 352         }\r
 353 \r
 354         // the predator's progress is how much the prey got swallowed\r
 355         self.swallow_progress_pred = e.swallow_progress_prey;\r
 356 }\r
 357 \r
 358 void Vore_Regurgitate(entity e)\r
 359 {\r
 360         // this player is being regurgitated by their predator, apply the proper changes\r
 361 \r
 362         e.movetype = e.vore_oldmovetype;\r
 363         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 364                 e.solid = e.vore_oldsolid;\r
 365         e.view_ofs_z = PL_VIEW_OFS_z;\r
 366         e.punchvector_z = -cvar("g_balance_vore_regurgitate_prey_punchvector");\r
 367 \r
 368         // if the prey has been fully digested, silently detach them\r
 369         if(e.deadflag != DEAD_NO && e.health <= cvar("g_balance_vore_digestion_limit"))\r
 370         {\r
 371                 e.predator = world;\r
 372                 e.modelindex = 0; // hide the dead body\r
 373                 return;\r
 374         }\r
 375 \r
 376         // apply velocities\r
 377         makevectors(e.predator.v_angle);\r
 378         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 379         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 380         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 381         e.pushltime = time + cvar("g_maxpushtime");\r
 382 \r
 383         // if the dead body of the prey is below gibbing health, gib it\r
 384         e.stat_eaten = 0; // necessary for gibs to show\r
 385         PlayerGib(e, e.predator);\r
 386 \r
 387         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 388         if(cvar("g_balance_vore_swallow_speed_fill") && cvar("g_balance_vore_regurgitate_swallowprogress"))\r
 389         {\r
 390                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 391                 Vore_SwallowModel_Update(e, e.predator);\r
 392         }\r
 393 \r
 394         // apply regurgitation damage to the predator\r
 395         if(cvar("g_balance_vore_regurgitate_damage"))\r
 396         {\r
 397                 float regurgitate_dmg;\r
 398                 regurgitate_dmg = cvar("g_balance_vore_regurgitate_damage");\r
 399                 if(cvar("g_healthsize"))\r
 400                         regurgitate_dmg *= e.scale / e.predator.scale;\r
 401                 Damage(e.predator, e, e, regurgitate_dmg, DEATH_REGURGITATION, e.predator.origin, '0 0 0');\r
 402         }\r
 403 \r
 404         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 405         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 406         pointparticles(particleeffectnum("vore_regurgitate"), e.predator.origin, '0 0 0', 1);\r
 407         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_predator_punchangle");\r
 408         e.predator.regurgitate_prepare = 0;\r
 409         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 410         Vore_SetPreyPositions(e.predator);\r
 411 \r
 412         // block firing for a small amount of time, or we'll be firing the next frame\r
 413         e.weapon_delay = time + button_delay_time;\r
 414         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 415         e.predator = world;\r
 416 }\r
 417 \r
 418 void Vore_Disconnect()\r
 419 {\r
 420         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 421 \r
 422         // prey disconnects or goes spectating while inside someone's belly\r
 423         if(self.stat_eaten)\r
 424                 Vore_Regurgitate(self);\r
 425 \r
 426         // pred disconnects or goes spectating with players in their belly\r
 427         entity head;\r
 428         FOR_EACH_PLAYER(head)\r
 429         {\r
 430                 if(head.predator == self)\r
 431                         Vore_Regurgitate(head);\r
 432         }\r
 433         Vore_GurgleSound(); // stop the gurgling sound\r
 434 \r
 435         self.stomach_load = self.gravity = 0; // prevents a bug\r
 436 }\r
 437 \r
 438 .float digestion_step;\r
 439 void Vore_Digest()\r
 440 {\r
 441         // apply digestion to prey\r
 442 \r
 443         if(self.predator.deadflag != DEAD_NO) // dead predators don't digest\r
 444         {\r
 445                 self.predator.digesting = FALSE;\r
 446                 return;\r
 447         }\r
 448         if(self.health <= cvar("g_balance_vore_digestion_limit")) // don't digest below this amount of health\r
 449                 return;\r
 450 \r
 451         if(time > self.digestion_step)\r
 452         {\r
 453                 // if distributed digestion is enabled, reduce digestion strength by the amount of prey in our stomach\r
 454                 float damage, damage_offset;\r
 455 \r
 456                 damage_offset = 1;\r
 457                 if(cvar("g_balance_vore_digestion_distribute")) // apply distributed digestion damage\r
 458                         damage_offset *= self.predator.stomach_load / self.predator.stomach_maxload;\r
 459                 if(cvar("g_healthsize") && cvar("g_balance_vore_digestion_scalediff")) // apply player scale to digestion damage\r
 460                         damage_offset *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_digestion_scalediff"));\r
 461                 damage_offset = ceil(damage_offset);\r
 462 \r
 463                 damage = cvar("g_balance_vore_digestion_damage") / damage_offset;\r
 464                 if(cvar("g_balance_vore_digestion_damage_death") && self.deadflag != DEAD_NO) // amplify digestion damage for dead prey\r
 465                         damage *= cvar("g_balance_vore_digestion_damage_death");\r
 466 \r
 467                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 468                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 469                         self.predator.health += damage * cvar("g_balance_vore_digestion_vampire");\r
 470 \r
 471                 if (self.predator.digestsound_finished < time)\r
 472                 {\r
 473                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 474                         self.predator.digestsound_finished = time + 0.5;\r
 475                 }\r
 476                 self.digestion_step = time + steptime;\r
 477         }\r
 478 \r
 479         if(stov(cvar_string("g_vore_regurgitatecolor_color_digest")))\r
 480                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_digest"));\r
 481 }\r
 482 \r
 483 .float teamheal_step;\r
 484 void Vore_Teamheal()\r
 485 {\r
 486         // apply teamheal\r
 487 \r
 488         if(self.deadflag != DEAD_NO)\r
 489                 return;\r
 490 \r
 491         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 492         if(time > self.teamheal_step)\r
 493         {\r
 494                 self.health += cvar("g_balance_vore_teamheal");\r
 495                 self.teamheal_step = time + steptime;\r
 496 \r
 497                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 498                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 499                 {\r
 500                         play2(self, "misc/beep.wav");\r
 501                         play2(self.predator, "misc/beep.wav");\r
 502                 }\r
 503         }\r
 504 }\r
 505 \r
 506 .float kick_pressed;\r
 507 void Vore_StomachKick()\r
 508 {\r
 509         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 510 \r
 511         if(self.deadflag != DEAD_NO)\r
 512                 return;\r
 513 \r
 514         if(time > self.stomachkick_delay && !self.kick_pressed)\r
 515         {\r
 516                 float damage, vol;\r
 517                 vector force;\r
 518                 damage = cvar("g_balance_vore_kick_damage");\r
 519                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 520                 vol = VOL_BASE;\r
 521 \r
 522                 // apply player scale to the damage / force of the kick\r
 523                 if(cvar("g_healthsize") && cvar("g_balance_vore_kick_scalediff"))\r
 524                 {\r
 525                         damage *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 526                         force *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 527                         vol *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff")); // kick sound volume based on the same scale\r
 528                 }\r
 529                 vol = bound(0, vol, 1);\r
 530 \r
 531                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 532                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), vol, ATTN_NORM);\r
 533                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 534                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 535 \r
 536                 // abort the predator's scheduled regurgitation\r
 537                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 538                         self.predator.regurgitate_prepare = 0;\r
 539 \r
 540                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 541                 if(cvar("g_balance_vore_kick_repress"))\r
 542                 if not(clienttype(self) == CLIENTTYPE_BOT) // not for bots, to prevent an issue\r
 543                         self.kick_pressed = TRUE;\r
 544         }\r
 545 }\r
 546 \r
 547 void Vore_StomachLeave()\r
 548 {\r
 549         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 550 \r
 551         if(self.deadflag != DEAD_NO)\r
 552                 return;\r
 553 \r
 554         if(Vore_CanLeave())\r
 555                 Vore_Regurgitate(self);\r
 556         else if(time > self.complain_vore)\r
 557         {\r
 558                 play2(self, "misc/forbidden.wav");\r
 559                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 560                 self.complain_vore = time + complain_delay_time;\r
 561         }\r
 562 }\r
 563 \r
 564 void Vore_AutoTaunt()\r
 565 {\r
 566         // triggers ambient vore taunts, for both pred and prey\r
 567 \r
 568         float taunt_time;\r
 569 \r
 570         // predator taunts\r
 571         if((self.swallow_progress_pred || (self.stomach_load && Stomach_HasLivePrey(self))) && !Stomach_TeamMates_check(self))\r
 572         {\r
 573                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 574                 {\r
 575                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 576                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 577                 }\r
 578         }\r
 579         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 580         {\r
 581                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 582                 SetAutoTaunt(self, 0, 0);\r
 583         }\r
 584 \r
 585         // prey taunts\r
 586         if((self.swallow_progress_prey || (self.stat_eaten && !(teams_matter && self.team == self.predator.team))) && self.deadflag == DEAD_NO)\r
 587         {\r
 588                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 589                 {\r
 590                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 591                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 592                 }\r
 593         }\r
 594         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 595         {\r
 596                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 597                 SetAutoTaunt(self, 0, 0);\r
 598         }\r
 599 }\r
 600 \r
 601 void Vore_SetSbarRings()\r
 602 {\r
 603         // first clear the ring stats, then configure them if needed\r
 604         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 605         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 606 \r
 607         if(self.stat_eaten)\r
 608         {\r
 609                 if(time <= self.stomachkick_delay)\r
 610                 {\r
 611                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 612                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 613                 }\r
 614         }\r
 615         else\r
 616         {\r
 617                 if(self.swallow_progress_pred)\r
 618                 {\r
 619                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 620                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 621                 }\r
 622                 else if(time <= self.action_delay)\r
 623                 {\r
 624                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 625                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 626                 }\r
 627 \r
 628                 if(self.swallow_progress_prey)\r
 629                 {\r
 630                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 631                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 632                 }\r
 633                 else if(time <= self.regurgitate_prepare)\r
 634                 {\r
 635                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 636                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 637                 }\r
 638         }\r
 639 }\r
 640 \r
 641 .float regurgitatecolor_particles_tick;\r
 642 void Vore()\r
 643 {\r
 644         // main vore code, this is where it all happens\r
 645 \r
 646         Vore_AutoTaunt();\r
 647 \r
 648         if(!self.stat_eaten)\r
 649         if(self.modelindex) // not if we're a gibbed dead body or not visible any more\r
 650         if(self.colormod)\r
 651         if(self.colormod != '1 1 1')\r
 652         {\r
 653                 // slowly wash stomach fluids off players once they're out of the stomach\r
 654                 if(cvar("g_vore_regurgitatecolor_fade"))\r
 655                 if(self.deadflag == DEAD_NO) // not for dead bodies\r
 656                 {\r
 657                         float goo_fade;\r
 658                         goo_fade = cvar("g_vore_regurgitatecolor_fade") * frametime;\r
 659                         goo_fade *= 1 + self.waterlevel; // fade faster when underwater\r
 660 \r
 661                         self.colormod_x += goo_fade;\r
 662                         if(self.colormod_x > 1)\r
 663                                 self.colormod_x = 1;\r
 664                         self.colormod_y += goo_fade;\r
 665                         if(self.colormod_y > 1)\r
 666                                 self.colormod_y = 1;\r
 667                         self.colormod_z += goo_fade;\r
 668                         if(self.colormod_z > 1)\r
 669                                 self.colormod_z = 1;\r
 670                 }\r
 671 \r
 672                 // constant particles falling off dirty players\r
 673                 if(cvar("g_vore_regurgitatecolor_particles"))\r
 674                 if(self.regurgitatecolor_particles_tick < time)\r
 675                 {\r
 676                         pointparticles(particleeffectnum("vore_regurgitate_constant"), self.origin, '0 0 0', 1);\r
 677                         self.regurgitatecolor_particles_tick = time + cvar("g_vore_regurgitatecolor_particles") * vlen(self.colormod); // particle time depends on how dirty the player is\r
 678                 }\r
 679         }\r
 680 \r
 681         // set all vore stats\r
 682         Vore_SetSbarRings();\r
 683         if(self.predator.classname == "player")\r
 684         {\r
 685                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 686                 self.stat_stomachmaxload = self.predator.stomach_maxload; // necessary for the stomach board\r
 687                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 688                 self.stat_eaten = num_for_edict(self.predator);\r
 689         }\r
 690         else\r
 691         {\r
 692                 self.stat_stomachload = self.stomach_load;\r
 693                 self.stat_stomachmaxload = self.stomach_maxload;\r
 694                 self.stat_digesting = self.digesting;\r
 695                 self.stat_eaten = 0;\r
 696         }\r
 697         self.stat_canleave = Vore_CanLeave();\r
 698 \r
 699         // don't allow a player inside a player inside another player :)\r
 700         // prevent this by checking if such has happened, and taking the proper measures\r
 701         // this code has a high priority and must not be stopped by any delay, so run it here\r
 702         if(self.predator.stat_eaten)\r
 703         {\r
 704                 entity target_predator, target_predator_predator, oldself;\r
 705                 target_predator = self.predator;\r
 706                 target_predator_predator = self.predator.predator;\r
 707 \r
 708                 Vore_Regurgitate(self);\r
 709 \r
 710                 // now steal our prey's prey if this probability applies\r
 711                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 712                 {\r
 713                         oldself = self;\r
 714                         self = target_predator_predator;\r
 715                         if(Swallow_condition_check(oldself))\r
 716                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 717                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 718                                 Vore_Swallow(oldself);\r
 719                         self = oldself;\r
 720                 }\r
 721         }\r
 722 \r
 723         // the swallow progress of prey and preds idly decrease by this amount\r
 724         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 725         {\r
 726                 if(self.swallow_progress_pred)\r
 727                 {\r
 728                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 729                         if(self.swallow_progress_pred < 0)\r
 730                                 self.swallow_progress_pred = 0;\r
 731                 }\r
 732                 if(self.swallow_progress_prey)\r
 733                 {\r
 734                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 735                         if(self.swallow_progress_prey < 0)\r
 736                                 self.swallow_progress_prey = 0;\r
 737                 }\r
 738         }\r
 739 \r
 740         // set the predator's stomach load and capacity\r
 741         Vore_StomachLoad_Apply();\r
 742 \r
 743         // apply delays and skip the vore system under some circumstances\r
 744         if(!cvar("g_vore")) // the vore system is disabled\r
 745         {\r
 746                 Vore_Disconnect();\r
 747                 return;\r
 748         }\r
 749         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 750         {\r
 751                 Vore_Disconnect();\r
 752                 return;\r
 753         }\r
 754         if(self.spectatee_status)\r
 755                 return;\r
 756         if(time < self.system_delay)\r
 757                 return;\r
 758 \r
 759 // --------------------------------\r
 760 // Code that addresses predators:\r
 761 // --------------------------------\r
 762 \r
 763         entity prey;\r
 764         prey = Swallow_player_check();\r
 765 \r
 766         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 767         self.stat_canswallow = 0;\r
 768         if(Swallow_condition_check(prey))\r
 769         {\r
 770                 // canswallow stat, used by the HUD\r
 771                 if(teams_matter && prey.team == self.team)\r
 772                         self.stat_canswallow = 2;\r
 773                 else\r
 774                         self.stat_canswallow = 1;\r
 775 \r
 776                 if(self.BUTTON_ATCK)\r
 777                         Vore_SwallowStep(prey);\r
 778         }\r
 779         else if(prey != world)\r
 780                 self.stat_canswallow = -1;\r
 781 \r
 782         // toggle digestion, if the player has someone in their stomach\r
 783         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 784         {\r
 785                 if(self.stomach_load)\r
 786                 {\r
 787                         if(time > self.digest_button_delay_time)\r
 788                         {\r
 789                                 self.digesting = !self.digesting;\r
 790                                 self.digest_button_delay_time = time + button_delay_time;\r
 791                         }\r
 792                 }\r
 793                 else if(time > self.complain_vore)\r
 794                 {\r
 795                         play2(self, "misc/forbidden.wav");\r
 796                         sprint(self, "There is nothing to digest\n");\r
 797                         self.complain_vore = time + complain_delay_time;\r
 798                 }\r
 799         }\r
 800         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 801                 self.digesting = FALSE;\r
 802 \r
 803         // predator wishes to regurgitate his prey\r
 804         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 805         {\r
 806                 if(self.stomach_load)\r
 807                 {\r
 808                         if(time > self.regurgitate_button_delay_time)\r
 809                         {\r
 810                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 811                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 812                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE); // looks good for preparing regurgitation\r
 813                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 814                         }\r
 815                 }\r
 816                 else if(time > self.complain_vore)\r
 817                 {\r
 818                         play2(self, "misc/forbidden.wav");\r
 819                         sprint(self, "There is nothing to regurgitate\n");\r
 820                         self.complain_vore = time + complain_delay_time;\r
 821                 }\r
 822         }\r
 823 \r
 824         if(self.stomach_load > self.stomach_maxload) // the predator got beyond his capacity after eating, so some prey must pop out\r
 825         {\r
 826                 self.regurgitate_prepare = -1;\r
 827                 return;\r
 828         }\r
 829         if(cvar("g_balance_vore_load_pred_speedcap") && self.stomach_load && vlen(self.velocity) >= cvar("g_balance_vore_load_pred_speedcap") / (self.stomach_load / self.stomach_maxload)) // predator's going too fast, gets sick and throws up\r
 830         {\r
 831                 self.regurgitate_prepare = -1;\r
 832                 return;\r
 833         }\r
 834 \r
 835         if(cvar("g_vore_gurglesound"))\r
 836                 Vore_GurgleSound();\r
 837 \r
 838 // --------------------------------\r
 839 // Code that addresses the prey:\r
 840 // --------------------------------\r
 841 \r
 842         if(!self.stat_eaten)\r
 843                 return;\r
 844 \r
 845         if(self.deadflag != DEAD_NO && self.health < cvar("g_balance_vore_digestion_limit")) // make sure health doesn't go below the limit\r
 846                 self.health = cvar("g_balance_vore_digestion_limit");\r
 847 \r
 848         // automatically regurgitate prey that has reached their digestion limit\r
 849         if(cvar("g_balance_vore_digestion_limit_regurgitate"))\r
 850         if(self.health <= cvar("g_balance_vore_digestion_limit"))\r
 851         {\r
 852                 Vore_Regurgitate(self);\r
 853                 return;\r
 854         }\r
 855 \r
 856         // do we stick around inside dead furries? x_x\r
 857         if(self.predator.deadflag != DEAD_NO)\r
 858         {\r
 859                 if(!cvar("g_balance_vore_deadpredator") || !self.predator.modelindex) // if the predator is gibbed, we are out\r
 860                 {\r
 861                         Vore_Regurgitate(self);\r
 862                         return;\r
 863                 }\r
 864                 if(self.predator.regurgitate_prepare) // abort scheduled regurgitation\r
 865                         self.predator.regurgitate_prepare = 0;\r
 866         }\r
 867 \r
 868         // apply delayed regurgitating if it was scheduled\r
 869         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 870         {\r
 871                 self.predator.regurgitate_prepare = 0;\r
 872                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 873                 Vore_Regurgitate(self);\r
 874         }\r
 875 \r
 876         // execute digesting and team healing\r
 877         if(self.predator.digesting == TRUE)\r
 878                 Vore_Digest();\r
 879         if(teams_matter && self.team == self.predator.team)\r
 880         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 881                 Vore_Teamheal();\r
 882 \r
 883         // execute prey commands\r
 884         if(self.BUTTON_ATCK)\r
 885         {\r
 886                 if(cvar("g_vore_kick"))\r
 887                         Vore_StomachKick();\r
 888         }\r
 889         else\r
 890                 self.kick_pressed = FALSE;\r
 891         if(self.BUTTON_JUMP)\r
 892                 Vore_StomachLeave();\r
 893 \r
 894         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 895         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 896         kh_Key_DropAll(self, FALSE);\r
 897 \r
 898         // always position camera at the center of the stomach, to reduce probability of the view poking out\r
 899         self.view_ofs_z = PL_PREY_VIEW_OFS_z * self.predator.scale;\r
 900 }