data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(cvar("g_healthsize")) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         makevectors(self.angles);\r
  22         vore_w_shotorg = self.origin;\r
  23         vore_w_shotdir = v_forward;\r
  24 \r
  25         if(self.antilag_debug)\r
  26                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, self.antilag_debug);\r
  27         else\r
  28                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  29         if(trace_fraction < 1)\r
  30         if(trace_ent.classname == "player")\r
  31                 return trace_ent;\r
  32         return world;\r
  33 }\r
  34 \r
  35 float Swallow_condition_check(entity prey)\r
  36 {\r
  37         // checks the necessary conditions for swallowing a player\r
  38 \r
  39         if(prey != self)\r
  40         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  41         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  42         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  43         {\r
  44                 float prey_mass;\r
  45                 prey_mass = cvar("g_balance_vore_load_prey_mass");\r
  46                 if(cvar("g_healthsize"))\r
  47                         prey_mass *= prey.scale;\r
  48 \r
  49                 string swallow_complain;\r
  50                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  51                         swallow_complain = "You cannot swallow your team mates\n";\r
  52                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  53                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  54                 else if(self.stomach_load + prey_mass > self.stomach_maxload)\r
  55                         swallow_complain = strcat("You don't have any room to swallow this player. Their mass is ^3", ftos(prey_mass), "^7 and your remaining capacity is ^3", ftos(self.stomach_maxload - self.stomach_load), "\n");\r
  56                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  57                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  58                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  59                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  60 \r
  61                 if(swallow_complain != "")\r
  62                 {\r
  63                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  64                         {\r
  65                                 play2(self, "misc/forbidden.wav");\r
  66                                 sprint(self, swallow_complain);\r
  67                                 self.complain_vore = time + complain_delay_time;\r
  68                         }\r
  69                         return FALSE;\r
  70                 }\r
  71                 return TRUE;\r
  72         }\r
  73         return FALSE;\r
  74 }\r
  75 \r
  76 float Stomach_TeamMates_check(entity pred)\r
  77 {\r
  78         // checks if a player's stomach contains any team mates\r
  79 \r
  80         entity head;\r
  81         if(teams_matter)\r
  82         {\r
  83                 FOR_EACH_PLAYER(head)\r
  84                 {\r
  85                         if(head.predator == pred && head.team == pred.team)\r
  86                                 return TRUE;\r
  87                 }\r
  88         }\r
  89         return FALSE;\r
  90 }\r
  91 \r
  92 float Stomach_HasLivePrey(entity pred)\r
  93 {\r
  94         entity head;\r
  95         FOR_EACH_PLAYER(head)\r
  96         {\r
  97                 if(head.predator == pred)\r
  98                 if(head.deadflag == DEAD_NO)\r
  99                         return TRUE;\r
 100         }\r
 101         return FALSE;\r
 102 }\r
 103 \r
 104 float Vore_CanLeave()\r
 105 {\r
 106         if(self.stat_eaten)\r
 107         {\r
 108                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
 109                         return TRUE;\r
 110                 if(teams_matter && self.team == self.predator.team)\r
 111                         return TRUE;\r
 112                 if(g_rpg && cvar("g_rpg_canleave"))\r
 113                         return TRUE;\r
 114         }\r
 115         return FALSE;\r
 116 }\r
 117 \r
 118 // position the camera properly for prey\r
 119 void Vore_SetPreyPositions(entity pred)\r
 120 {\r
 121         // pred is the predator and head is the prey\r
 122 \r
 123         local entity head;\r
 124 \r
 125         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 126         // else all players overlap in the center. To do this, we use a random origin on all players in the same stomach.\r
 127         FOR_EACH_PLAYER(head)\r
 128         {\r
 129                 if(head.predator == pred)\r
 130                 {\r
 131                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 132                         head.view_ofs_x = PL_PREY_VIEW_OFS_x + crandom() * cvar("g_vore_neighborprey_distance");\r
 133                         head.view_ofs_y = PL_PREY_VIEW_OFS_y + crandom() * cvar("g_vore_neighborprey_distance");\r
 134                         head.view_ofs_z = PL_PREY_VIEW_OFS_z;\r
 135                 }\r
 136         }\r
 137 }\r
 138 \r
 139 .float gurgle_oldstomachload;\r
 140 void Vore_GurgleSound()\r
 141 {\r
 142         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 143         {\r
 144                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 145 \r
 146                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 147                 self.gurgle_oldstomachload = self.stomach_load;\r
 148         }\r
 149 }\r
 150 \r
 151 void Vore_StomachLoad_Apply()\r
 152 {\r
 153         // apply stomach weight that makes you heavier and larger the more you eat\r
 154         // slowing the player is done in cl_physics.qc\r
 155         if(self.classname != "player")\r
 156                 return;\r
 157 \r
 158         entity e;\r
 159         float prey_mass;\r
 160 \r
 161         // apply the stomach capacity of the predator\r
 162         self.stomach_maxload = cvar("g_balance_vore_load_pred_capacity");\r
 163         if(cvar("g_healthsize"))\r
 164                 self.stomach_maxload *= self.scale;\r
 165         self.stomach_maxload = floor(self.stomach_maxload);\r
 166 \r
 167         self.stomach_load = 0; // start from zero\r
 168         FOR_EACH_PLAYER(e)\r
 169         {\r
 170                 if(e.predator == self)\r
 171                 {\r
 172                         prey_mass = cvar("g_balance_vore_load_prey_mass");\r
 173                         if(cvar("g_healthsize"))\r
 174                                 prey_mass *= e.scale;\r
 175                         self.stomach_load += floor(prey_mass);\r
 176                 }\r
 177         }\r
 178         for(e = world; (e = find(e, classname, "consumable")); )\r
 179         {\r
 180                 if(e.predator == self)\r
 181                         self.stomach_load += floor(e.dmg);\r
 182         }\r
 183 \r
 184         // apply weight\r
 185         self.gravity = 1 + (self.stomach_load / self.stomach_maxload) * cvar("g_balance_vore_load_pred_weight");\r
 186         if(!self.gravity && self.stomach_load)\r
 187                 self.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 188 }\r
 189 \r
 190 void Vore_AutoDigest(entity e)\r
 191 {\r
 192         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 193 \r
 194         if(!cvar("g_vore_digestion") || e.digesting)\r
 195                 return;\r
 196         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 197                 return; // this feature is only for players, not bots\r
 198         if(e.stomach_load)\r
 199                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 200         if(Stomach_TeamMates_check(e))\r
 201                 return; // never begin automatic digestion if we've swallowed a team mate\r
 202 \r
 203         e.digesting = TRUE;\r
 204 }\r
 205 \r
 206 .entity swallow_model;\r
 207 float Vore_SwallowModel_CustomizeEntityForClient()\r
 208 {\r
 209         // use the same system as the weapon model\r
 210 \r
 211         self.viewmodelforclient = self.owner;\r
 212         self.alpha = self.owner.cvar_cl_vore_swallowmodel;\r
 213 \r
 214         if(other.classname == "spectator")\r
 215         if(other.enemy == self.owner)\r
 216         {\r
 217                 self.viewmodelforclient = other;\r
 218                 self.alpha = other.cvar_cl_vore_swallowmodel;\r
 219         }\r
 220 \r
 221         return TRUE;\r
 222 }\r
 223 \r
 224 void Vore_SwallowModel_Think()\r
 225 {\r
 226         // update the position of the swallow model to match our swallow progress\r
 227         float dist;\r
 228         dist = (-0.5 + self.owner.swallow_progress_prey) * cvar("g_vore_swallowmodel_range"); // the model is centered at 0.5 progress\r
 229         if(cvar("g_healthsize"))\r
 230                 dist *= self.scale;\r
 231         self.view_ofs = '1 0 0' * dist;\r
 232 \r
 233         // if our swallow progress is gone or we are dead, the swallow model also goes away\r
 234         if(!self.owner.swallow_progress_prey || self.owner.deadflag != DEAD_NO || self.owner.classname != "player")\r
 235         {\r
 236                 remove(self.owner.swallow_model);\r
 237                 self.owner.swallow_model = world;\r
 238                 return;\r
 239         }\r
 240 \r
 241         // properties that should update whenever possible, but when the predator is not available\r
 242         self.nextthink = time;\r
 243 }\r
 244 \r
 245 void Vore_SwallowModel_Update(entity prey, entity pred)\r
 246 {\r
 247         // if we don't have a swallow model already, spawn one\r
 248         if(!prey.swallow_model)\r
 249         {\r
 250                 prey.swallow_model = spawn();\r
 251                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 252                 prey.swallow_model.solid = SOLID_NOT;\r
 253                 //prey.swallow_model.effects |= EF_NOGUNBOB; // let it bob\r
 254                 prey.swallow_model.effects |= EF_NODEPTHTEST; // don't hide behind walls\r
 255                 prey.swallow_model.owner = prey;\r
 256                 prey.swallow_model.customizeentityforclient = Vore_SwallowModel_CustomizeEntityForClient;\r
 257                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
 258                 prey.swallow_model.nextthink = time;\r
 259         }\r
 260 \r
 261         // properties that should update whenever possible, but when the predator is available\r
 262         string player_swallowmodel;\r
 263         player_swallowmodel = strcat(substring(pred.playermodel, 0, strlen(pred.playermodel) - 4), "_swallow.md3"); // 4 is the extension length\r
 264         if(prey.swallow_model.model != player_swallowmodel) // player model can be changed while the predator is active\r
 265                 setmodel(prey.swallow_model, player_swallowmodel);\r
 266         if(prey.swallow_model.skin != pred.skin) // player skin can be changed while the predator is active\r
 267                 prey.swallow_model.skin = pred.skin;\r
 268         if(cvar("g_healthsize"))\r
 269                 prey.swallow_model.scale = pred.scale / prey.scale; // player size difference\r
 270         if(prey.swallow_model.enemy != pred)\r
 271                 prey.swallow_model.enemy = pred; // enemy is the predator\r
 272         if(prey.swallow_model.colormap != pred.colormap)\r
 273                 prey.swallow_model.colormap = pred.colormap; // pants and shirt color\r
 274         if(prey.swallow_model.glowmod != pred.glowmod)\r
 275                 prey.swallow_model.glowmod = pred.glowmod; // glow color\r
 276 }\r
 277 \r
 278 .entity pusher;\r
 279 .float pushltime;\r
 280 void Vore_Swallow(entity e)\r
 281 {\r
 282         // this player is being swallowed by another player, apply the proper changes\r
 283 \r
 284         e.vore_oldmovetype = e.movetype;\r
 285         e.vore_oldsolid = e.solid;\r
 286         e.punchvector_z = cvar("g_balance_vore_swallow_prey_punchvector");\r
 287 \r
 288         e.predator = self;\r
 289         setorigin(e, e.predator.origin);\r
 290         e.velocity = '0 0 0';\r
 291         e.movetype = MOVETYPE_FOLLOW;\r
 292         e.solid = SOLID_NOT;\r
 293         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 294 \r
 295         // drop keys (KH) and flags (CTF) when we get swallowed\r
 296         kh_Key_DropAll(e, FALSE);\r
 297         if(e.flagcarried)\r
 298                 DropFlag(e.flagcarried, world, e.predator);\r
 299 \r
 300         if(stov(cvar_string("g_vore_regurgitatecolor_color_normal")))\r
 301                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_normal"));\r
 302 \r
 303         if(teams_matter && e.team == e.predator.team)\r
 304         {\r
 305                 if(cvar("g_vore_kick"))\r
 306                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 307                 if(cvar("g_vore_digestion"))\r
 308                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 309         }\r
 310 \r
 311         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 312         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 313         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_predator_punchangle");\r
 314         e.predator.regurgitate_prepare = 0;\r
 315         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 316         e.predator.hitsound += 1; // play this for team mates too, as we could be swallowing them to heal them\r
 317         Vore_AutoDigest(e.predator);\r
 318         Vore_SetPreyPositions(e.predator);\r
 319 \r
 320         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 321         e.predator.weapon_delay = time + button_delay_time;\r
 322         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 323         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 324         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 325 }\r
 326 \r
 327 void Vore_SwallowStep(entity e)\r
 328 {\r
 329         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 330         {\r
 331                 Vore_Swallow(e);\r
 332                 return;\r
 333         }\r
 334 \r
 335         Vore_SwallowModel_Update(e, self);\r
 336 \r
 337         // increase the progress value until it reaches 1, then swallow the player\r
 338         if(e.swallow_progress_prey < 1)\r
 339         {\r
 340                 float fill;\r
 341                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 342                 if(cvar("g_healthsize") && cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 343                         fill *= pow(self.scale / e.scale, cvar("g_balance_vore_swallow_speed_fill_scalediff"));\r
 344                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 345                         fill /= e.stomach_load;\r
 346 \r
 347                 e.swallow_progress_prey += fill;\r
 348         }\r
 349         else\r
 350         {\r
 351                 Vore_Swallow(e);\r
 352                 e.swallow_progress_prey = 0;\r
 353         }\r
 354 \r
 355         // the predator's progress is how much the prey got swallowed\r
 356         self.swallow_progress_pred = e.swallow_progress_prey;\r
 357 }\r
 358 \r
 359 void Vore_Regurgitate(entity e)\r
 360 {\r
 361         // this player is being regurgitated by their predator, apply the proper changes\r
 362 \r
 363         e.movetype = e.vore_oldmovetype;\r
 364         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 365                 e.solid = e.vore_oldsolid;\r
 366         e.view_ofs_z = PL_VIEW_OFS_z;\r
 367         e.punchvector_z = -cvar("g_balance_vore_regurgitate_prey_punchvector");\r
 368 \r
 369         // if the prey has been fully digested, silently detach them\r
 370         if(e.deadflag != DEAD_NO && e.health <= cvar("g_balance_vore_digestion_limit"))\r
 371         {\r
 372                 e.predator = world;\r
 373                 e.modelindex = 0; // hide the dead body\r
 374                 return;\r
 375         }\r
 376 \r
 377         // apply velocities\r
 378         makevectors(e.predator.v_angle);\r
 379         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 380         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 381         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 382         e.pushltime = time + cvar("g_maxpushtime");\r
 383 \r
 384         // if the dead body of the prey is below gibbing health, gib it\r
 385         e.stat_eaten = 0; // necessary for gibs to show\r
 386         PlayerGib(e, e.predator);\r
 387 \r
 388         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 389         if(cvar("g_balance_vore_swallow_speed_fill") && cvar("g_balance_vore_regurgitate_swallowprogress"))\r
 390         {\r
 391                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 392                 Vore_SwallowModel_Update(e, e.predator);\r
 393         }\r
 394 \r
 395         // apply regurgitation damage to the predator\r
 396         if(cvar("g_balance_vore_regurgitate_damage"))\r
 397         {\r
 398                 float regurgitate_dmg;\r
 399                 regurgitate_dmg = cvar("g_balance_vore_regurgitate_damage");\r
 400                 if(cvar("g_healthsize"))\r
 401                         regurgitate_dmg *= e.scale / e.predator.scale;\r
 402                 Damage(e.predator, e, e, regurgitate_dmg, DEATH_REGURGITATION, e.predator.origin, '0 0 0');\r
 403         }\r
 404 \r
 405         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 406         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 407         pointparticles(particleeffectnum("vore_regurgitate"), e.predator.origin, '0 0 0', 1);\r
 408         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_predator_punchangle");\r
 409         e.predator.regurgitate_prepare = 0;\r
 410         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 411         Vore_SetPreyPositions(e.predator);\r
 412 \r
 413         // block firing for a small amount of time, or we'll be firing the next frame\r
 414         e.weapon_delay = time + button_delay_time;\r
 415         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 416         e.predator = world;\r
 417 }\r
 418 \r
 419 void Vore_Disconnect()\r
 420 {\r
 421         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 422 \r
 423         // prey disconnects or goes spectating while inside someone's belly\r
 424         if(self.stat_eaten)\r
 425                 Vore_Regurgitate(self);\r
 426 \r
 427         // pred disconnects or goes spectating with players in their belly\r
 428         entity head;\r
 429         FOR_EACH_PLAYER(head)\r
 430         {\r
 431                 if(head.predator == self)\r
 432                         Vore_Regurgitate(head);\r
 433         }\r
 434         Vore_GurgleSound(); // stop the gurgling sound\r
 435 \r
 436         self.stomach_load = self.gravity = 0; // prevents a bug\r
 437 }\r
 438 \r
 439 .float digestion_step;\r
 440 void Vore_Digest()\r
 441 {\r
 442         // apply digestion to prey\r
 443 \r
 444         if(self.predator.deadflag != DEAD_NO) // dead predators don't digest\r
 445         {\r
 446                 self.predator.digesting = FALSE;\r
 447                 return;\r
 448         }\r
 449         if(self.health <= cvar("g_balance_vore_digestion_limit")) // don't digest below this amount of health\r
 450                 return;\r
 451 \r
 452         if(time > self.digestion_step)\r
 453         {\r
 454                 // if distributed digestion is enabled, reduce digestion strength by the amount of prey in our stomach\r
 455                 float damage, damage_offset;\r
 456 \r
 457                 damage_offset = 1;\r
 458                 if(cvar("g_balance_vore_digestion_distribute")) // apply distributed digestion damage\r
 459                         damage_offset *= self.predator.stomach_load / self.predator.stomach_maxload;\r
 460                 if(cvar("g_healthsize") && cvar("g_balance_vore_digestion_scalediff")) // apply player scale to digestion damage\r
 461                         damage_offset *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_digestion_scalediff"));\r
 462                 damage_offset = ceil(damage_offset);\r
 463 \r
 464                 damage = cvar("g_balance_vore_digestion_damage") / damage_offset;\r
 465                 if(cvar("g_balance_vore_digestion_damage_death") && self.deadflag != DEAD_NO) // amplify digestion damage for dead prey\r
 466                         damage *= cvar("g_balance_vore_digestion_damage_death");\r
 467 \r
 468                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 469                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 470                         self.predator.health += damage * cvar("g_balance_vore_digestion_vampire");\r
 471 \r
 472                 if (self.predator.digestsound_finished < time)\r
 473                 {\r
 474                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 475                         self.predator.digestsound_finished = time + 0.5;\r
 476                 }\r
 477                 self.digestion_step = time + steptime;\r
 478         }\r
 479 \r
 480         if(stov(cvar_string("g_vore_regurgitatecolor_color_digest")))\r
 481                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_digest"));\r
 482 }\r
 483 \r
 484 .float teamheal_step;\r
 485 void Vore_Teamheal()\r
 486 {\r
 487         // apply teamheal\r
 488 \r
 489         if(self.deadflag != DEAD_NO)\r
 490                 return;\r
 491 \r
 492         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 493         if(time > self.teamheal_step)\r
 494         {\r
 495                 self.health += cvar("g_balance_vore_teamheal");\r
 496                 self.teamheal_step = time + steptime;\r
 497 \r
 498                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 499                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 500                 {\r
 501                         play2(self, "misc/beep.wav");\r
 502                         play2(self.predator, "misc/beep.wav");\r
 503                 }\r
 504         }\r
 505 }\r
 506 \r
 507 .float kick_pressed;\r
 508 void Vore_StomachKick()\r
 509 {\r
 510         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 511 \r
 512         if(self.deadflag != DEAD_NO)\r
 513                 return;\r
 514 \r
 515         if(time > self.stomachkick_delay && !self.kick_pressed)\r
 516         {\r
 517                 float damage, vol;\r
 518                 vector force;\r
 519                 damage = cvar("g_balance_vore_kick_damage");\r
 520                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 521                 vol = VOL_BASE;\r
 522 \r
 523                 // apply player scale to the damage / force of the kick\r
 524                 if(cvar("g_healthsize") && cvar("g_balance_vore_kick_scalediff"))\r
 525                 {\r
 526                         damage *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 527                         force *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 528                         vol *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff")); // kick sound volume based on the same scale\r
 529                 }\r
 530                 vol = bound(0, vol, 1);\r
 531 \r
 532                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 533                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), vol, ATTN_NORM);\r
 534                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 535                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 536 \r
 537                 // abort the predator's scheduled regurgitation\r
 538                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 539                         self.predator.regurgitate_prepare = 0;\r
 540 \r
 541                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 542                 if(cvar("g_balance_vore_kick_repress"))\r
 543                 if not(clienttype(self) == CLIENTTYPE_BOT) // not for bots, to prevent an issue\r
 544                         self.kick_pressed = TRUE;\r
 545         }\r
 546 }\r
 547 \r
 548 void Vore_StomachLeave()\r
 549 {\r
 550         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 551 \r
 552         if(self.deadflag != DEAD_NO)\r
 553                 return;\r
 554 \r
 555         if(Vore_CanLeave())\r
 556                 Vore_Regurgitate(self);\r
 557         else if(time > self.complain_vore)\r
 558         {\r
 559                 play2(self, "misc/forbidden.wav");\r
 560                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 561                 self.complain_vore = time + complain_delay_time;\r
 562         }\r
 563 }\r
 564 \r
 565 void Vore_AutoTaunt()\r
 566 {\r
 567         // triggers ambient vore taunts, for both pred and prey\r
 568 \r
 569         float taunt_time;\r
 570 \r
 571         // predator taunts\r
 572         if((self.swallow_progress_pred || (self.stomach_load && Stomach_HasLivePrey(self))) && !Stomach_TeamMates_check(self))\r
 573         {\r
 574                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 575                 {\r
 576                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 577                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 578                 }\r
 579         }\r
 580         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 581         {\r
 582                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 583                 SetAutoTaunt(self, 0, 0);\r
 584         }\r
 585 \r
 586         // prey taunts\r
 587         if((self.swallow_progress_prey || (self.stat_eaten && !(teams_matter && self.team == self.predator.team))) && self.deadflag == DEAD_NO)\r
 588         {\r
 589                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 590                 {\r
 591                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 592                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 593                 }\r
 594         }\r
 595         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 596         {\r
 597                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 598                 SetAutoTaunt(self, 0, 0);\r
 599         }\r
 600 }\r
 601 \r
 602 void Vore_SetSbarRings()\r
 603 {\r
 604         // first clear the ring stats, then configure them if needed\r
 605         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 606         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 607 \r
 608         if(self.stat_eaten)\r
 609         {\r
 610                 if(time <= self.stomachkick_delay)\r
 611                 {\r
 612                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 613                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 614                 }\r
 615         }\r
 616         else\r
 617         {\r
 618                 if(self.swallow_progress_pred)\r
 619                 {\r
 620                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 621                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 622                 }\r
 623                 else if(time <= self.action_delay)\r
 624                 {\r
 625                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 626                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 627                 }\r
 628 \r
 629                 if(self.swallow_progress_prey)\r
 630                 {\r
 631                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 632                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 633                 }\r
 634                 else if(time <= self.regurgitate_prepare)\r
 635                 {\r
 636                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 637                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 638                 }\r
 639         }\r
 640 }\r
 641 \r
 642 .float regurgitatecolor_particles_tick;\r
 643 void Vore()\r
 644 {\r
 645         // main vore code, this is where it all happens\r
 646 \r
 647         Vore_AutoTaunt();\r
 648 \r
 649         if(!self.stat_eaten)\r
 650         if(self.modelindex) // not if we're a gibbed dead body or not visible any more\r
 651         if(self.colormod)\r
 652         if(self.colormod != '1 1 1')\r
 653         {\r
 654                 // slowly wash stomach fluids off players once they're out of the stomach\r
 655                 if(cvar("g_vore_regurgitatecolor_fade"))\r
 656                 if(self.deadflag == DEAD_NO) // not for dead bodies\r
 657                 {\r
 658                         float goo_fade;\r
 659                         goo_fade = cvar("g_vore_regurgitatecolor_fade") * frametime;\r
 660                         goo_fade *= 1 + self.waterlevel; // fade faster when underwater\r
 661 \r
 662                         self.colormod_x += goo_fade;\r
 663                         if(self.colormod_x > 1)\r
 664                                 self.colormod_x = 1;\r
 665                         self.colormod_y += goo_fade;\r
 666                         if(self.colormod_y > 1)\r
 667                                 self.colormod_y = 1;\r
 668                         self.colormod_z += goo_fade;\r
 669                         if(self.colormod_z > 1)\r
 670                                 self.colormod_z = 1;\r
 671                 }\r
 672 \r
 673                 // constant particles falling off dirty players\r
 674                 if(cvar("g_vore_regurgitatecolor_particles"))\r
 675                 if(self.regurgitatecolor_particles_tick < time)\r
 676                 {\r
 677                         pointparticles(particleeffectnum("vore_regurgitate_constant"), self.origin, '0 0 0', 1);\r
 678                         self.regurgitatecolor_particles_tick = time + cvar("g_vore_regurgitatecolor_particles") * vlen(self.colormod); // particle time depends on how dirty the player is\r
 679                 }\r
 680         }\r
 681 \r
 682         // set all vore stats\r
 683         Vore_SetSbarRings();\r
 684         if(self.predator.classname == "player")\r
 685         {\r
 686                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 687                 self.stat_stomachmaxload = self.predator.stomach_maxload; // necessary for the stomach board\r
 688                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 689                 self.stat_eaten = num_for_edict(self.predator);\r
 690         }\r
 691         else\r
 692         {\r
 693                 self.stat_stomachload = self.stomach_load;\r
 694                 self.stat_stomachmaxload = self.stomach_maxload;\r
 695                 self.stat_digesting = self.digesting;\r
 696                 self.stat_eaten = 0;\r
 697         }\r
 698         self.stat_canleave = Vore_CanLeave();\r
 699 \r
 700         // don't allow a player inside a player inside another player :)\r
 701         // prevent this by checking if such has happened, and taking the proper measures\r
 702         // this code has a high priority and must not be stopped by any delay, so run it here\r
 703         if(self.predator.stat_eaten)\r
 704         {\r
 705                 entity target_predator, target_predator_predator, oldself;\r
 706                 target_predator = self.predator;\r
 707                 target_predator_predator = self.predator.predator;\r
 708 \r
 709                 Vore_Regurgitate(self);\r
 710 \r
 711                 // now steal our prey's prey if this probability applies\r
 712                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 713                 {\r
 714                         oldself = self;\r
 715                         self = target_predator_predator;\r
 716                         if(Swallow_condition_check(oldself))\r
 717                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 718                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 719                                 Vore_Swallow(oldself);\r
 720                         self = oldself;\r
 721                 }\r
 722         }\r
 723 \r
 724         // the swallow progress of prey and preds idly decrease by this amount\r
 725         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 726         {\r
 727                 if(self.swallow_progress_pred)\r
 728                 {\r
 729                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 730                         if(self.swallow_progress_pred < 0)\r
 731                                 self.swallow_progress_pred = 0;\r
 732                 }\r
 733                 if(self.swallow_progress_prey)\r
 734                 {\r
 735                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 736                         if(self.swallow_progress_prey < 0)\r
 737                                 self.swallow_progress_prey = 0;\r
 738                 }\r
 739         }\r
 740 \r
 741         // set the predator's stomach load and capacity\r
 742         Vore_StomachLoad_Apply();\r
 743 \r
 744         // apply delays and skip the vore system under some circumstances\r
 745         if(!cvar("g_vore")) // the vore system is disabled\r
 746         {\r
 747                 Vore_Disconnect();\r
 748                 return;\r
 749         }\r
 750         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 751         {\r
 752                 Vore_Disconnect();\r
 753                 return;\r
 754         }\r
 755         if(self.spectatee_status)\r
 756                 return;\r
 757         if(time < self.system_delay)\r
 758                 return;\r
 759 \r
 760 // --------------------------------\r
 761 // Code that addresses predators:\r
 762 // --------------------------------\r
 763 \r
 764         entity prey;\r
 765         prey = Swallow_player_check();\r
 766 \r
 767         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 768         self.stat_canswallow = 0;\r
 769         if(Swallow_condition_check(prey))\r
 770         {\r
 771                 // canswallow stat, used by the HUD\r
 772                 if(teams_matter && prey.team == self.team)\r
 773                         self.stat_canswallow = 2;\r
 774                 else\r
 775                         self.stat_canswallow = 1;\r
 776 \r
 777                 if(self.BUTTON_ATCK)\r
 778                         Vore_SwallowStep(prey);\r
 779         }\r
 780         else if(prey != world)\r
 781                 self.stat_canswallow = -1;\r
 782 \r
 783         // toggle digestion, if the player has someone in their stomach\r
 784         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 785         {\r
 786                 if(self.stomach_load)\r
 787                 {\r
 788                         if(time > self.digest_button_delay_time)\r
 789                         {\r
 790                                 self.digesting = !self.digesting;\r
 791                                 self.digest_button_delay_time = time + button_delay_time;\r
 792                         }\r
 793                 }\r
 794                 else if(time > self.complain_vore)\r
 795                 {\r
 796                         play2(self, "misc/forbidden.wav");\r
 797                         sprint(self, "There is nothing to digest\n");\r
 798                         self.complain_vore = time + complain_delay_time;\r
 799                 }\r
 800         }\r
 801         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 802                 self.digesting = FALSE;\r
 803 \r
 804         // predator wishes to regurgitate his prey\r
 805         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 806         {\r
 807                 if(self.stomach_load)\r
 808                 {\r
 809                         if(time > self.regurgitate_button_delay_time)\r
 810                         {\r
 811                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 812                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 813                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE); // looks good for preparing regurgitation\r
 814                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 815                         }\r
 816                 }\r
 817                 else if(time > self.complain_vore)\r
 818                 {\r
 819                         play2(self, "misc/forbidden.wav");\r
 820                         sprint(self, "There is nothing to regurgitate\n");\r
 821                         self.complain_vore = time + complain_delay_time;\r
 822                 }\r
 823         }\r
 824 \r
 825         if(cvar("g_vore_gurglesound"))\r
 826                 Vore_GurgleSound();\r
 827 \r
 828 // --------------------------------\r
 829 // Code that addresses the prey:\r
 830 // --------------------------------\r
 831 \r
 832         if(!self.stat_eaten)\r
 833                 return;\r
 834 \r
 835         if(self.deadflag != DEAD_NO && self.health < cvar("g_balance_vore_digestion_limit")) // make sure health doesn't go below the limit\r
 836                 self.health = cvar("g_balance_vore_digestion_limit");\r
 837 \r
 838         // automatically regurgitate prey that has reached their digestion limit\r
 839         if(cvar("g_balance_vore_digestion_limit_regurgitate"))\r
 840         if(self.health <= cvar("g_balance_vore_digestion_limit"))\r
 841         {\r
 842                 Vore_Regurgitate(self);\r
 843                 return;\r
 844         }\r
 845 \r
 846         // do we stick around inside dead furries? x_x\r
 847         if(self.predator.deadflag != DEAD_NO)\r
 848         {\r
 849                 if(!cvar("g_balance_vore_deadpredator") || !self.predator.modelindex) // if the predator is gibbed, we are out\r
 850                 {\r
 851                         Vore_Regurgitate(self);\r
 852                         return;\r
 853                 }\r
 854                 if(self.predator.regurgitate_prepare) // abort scheduled regurgitation\r
 855                         self.predator.regurgitate_prepare = 0;\r
 856         }\r
 857 \r
 858         if(self.predator.stomach_load > self.predator.stomach_maxload) // the predator got beyond his capacity after eating, so some prey must pop out\r
 859         {\r
 860                 Vore_Regurgitate(self);\r
 861                 return;\r
 862         }\r
 863         if(cvar("g_balance_vore_load_pred_speedcap") && vlen(self.predator.velocity) >= cvar("g_balance_vore_load_pred_speedcap") / (self.predator.stomach_load / self.predator.stomach_maxload)) // predator's going too fast, gets sick and throws up\r
 864         {\r
 865                 Vore_Regurgitate(self);\r
 866                 return;\r
 867         }\r
 868 \r
 869         // apply delayed regurgitating if it was scheduled\r
 870         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 871         {\r
 872                 self.predator.regurgitate_prepare = 0;\r
 873                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 874                 Vore_Regurgitate(self);\r
 875         }\r
 876 \r
 877         // execute digesting and team healing\r
 878         if(self.predator.digesting == TRUE)\r
 879                 Vore_Digest();\r
 880         if(teams_matter && self.team == self.predator.team)\r
 881         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 882                 Vore_Teamheal();\r
 883 \r
 884         // execute prey commands\r
 885         if(self.BUTTON_ATCK)\r
 886         {\r
 887                 if(cvar("g_vore_kick"))\r
 888                         Vore_StomachKick();\r
 889         }\r
 890         else\r
 891                 self.kick_pressed = FALSE;\r
 892         if(self.BUTTON_JUMP)\r
 893                 Vore_StomachLeave();\r
 894 \r
 895         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 896         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 897         kh_Key_DropAll(self, FALSE);\r
 898 \r
 899         // always position camera at the center of the stomach, to reduce probability of the view poking out\r
 900         self.view_ofs_z = PL_PREY_VIEW_OFS_z * self.predator.scale;\r
 901 }