data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(cvar("g_healthsize")) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         makevectors(self.angles);\r
  22         vore_w_shotorg = self.origin;\r
  23         vore_w_shotdir = v_forward;\r
  24 \r
  25         if(self.antilag_debug)\r
  26                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, self.antilag_debug);\r
  27         else\r
  28                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  29         if(trace_fraction < 1)\r
  30         if(trace_ent.classname == "player")\r
  31                 return trace_ent;\r
  32         return world;\r
  33 }\r
  34 \r
  35 float Swallow_condition_check(entity prey)\r
  36 {\r
  37         // checks the necessary conditions for swallowing a player\r
  38 \r
  39         if(prey != self)\r
  40         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  41         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  42         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  43         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_speedcap") / (1 + self.stomach_load))\r
  44         {\r
  45                 string swallow_complain;\r
  46                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  47                         swallow_complain = "You cannot swallow your team mates\n";\r
  48                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  49                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  50                 else if(self.stomach_load >= self.stat_stomachmaxload)\r
  51                         swallow_complain = "You do not have any more room to swallow this player.\n";\r
  52                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  53                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  54                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  55                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  56 \r
  57                 if(swallow_complain != "")\r
  58                 {\r
  59                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  60                         {\r
  61                                 play2(self, "misc/forbidden.wav");\r
  62                                 sprint(self, swallow_complain);\r
  63                                 self.complain_vore = time + complain_delay_time;\r
  64                         }\r
  65                         return FALSE;\r
  66                 }\r
  67                 return TRUE;\r
  68         }\r
  69         return FALSE;\r
  70 }\r
  71 \r
  72 float Prey_Mass(entity prey)\r
  73 {\r
  74         float vore_mass;\r
  75         vore_mass = cvar("g_balance_vore_load_mass");\r
  76         if(cvar("g_healthsize"))\r
  77                 vore_mass *= prey.scale;\r
  78         vore_mass = ceil(vore_mass);\r
  79         return vore_mass;\r
  80 }\r
  81 \r
  82 float Stomach_TeamMates_check(entity pred)\r
  83 {\r
  84         // checks if a player's stomach contains any team mates\r
  85 \r
  86         entity head;\r
  87         if(teams_matter)\r
  88         {\r
  89                 FOR_EACH_PLAYER(head)\r
  90                 {\r
  91                         if(head.predator == pred && head.team == pred.team)\r
  92                                 return TRUE;\r
  93                 }\r
  94         }\r
  95         return FALSE;\r
  96 }\r
  97 \r
  98 float Vore_CanLeave()\r
  99 {\r
 100         if(self.stat_eaten)\r
 101         {\r
 102                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
 103                         return TRUE;\r
 104                 if(teams_matter && self.team == self.predator.team)\r
 105                         return TRUE;\r
 106                 if(g_rpg && cvar("g_rpg_canleave"))\r
 107                         return TRUE;\r
 108         }\r
 109         return FALSE;\r
 110 }\r
 111 \r
 112 // position the camera properly for prey\r
 113 void Vore_SetPreyPositions()\r
 114 {\r
 115         // self is the predator and head is the prey\r
 116 \r
 117         local entity head;\r
 118         local vector origin_apply;\r
 119         local float position_counter;\r
 120 \r
 121         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 122         // else all players overlap in the center. To do this, we run a loop on all players in the same stomach.\r
 123         // For each player, the origin is updated, then a new origin is used for the next player.\r
 124         // This requires that no more than 9 players may be in the stomach at a time!\r
 125         FOR_EACH_PLAYER(head)\r
 126         {\r
 127                 if(head.predator == self)\r
 128                 {\r
 129                         switch(position_counter)\r
 130                         {\r
 131                                 case 0:\r
 132                                         origin_apply = '0 0 0'; // first occupant sits in the middle\r
 133                                         break;\r
 134                                 case 1:\r
 135                                         origin_apply = '1 0 0'; // second occupant sits in the front\r
 136                                         break;\r
 137                                 case 2:\r
 138                                         origin_apply = '-1 0 0'; // third occupant sits in the back\r
 139                                         break;\r
 140                                 case 3:\r
 141                                         origin_apply = '0 1 0'; // fourth occupant sits in the right\r
 142                                         break;\r
 143                                 case 4:\r
 144                                         origin_apply = '0 -1 0'; // fifth occupant sits in the left\r
 145                                         break;\r
 146                                 case 5:\r
 147                                         origin_apply = '1 1 0'; // sixth occupant sits in the front-right\r
 148                                         break;\r
 149                                 case 6:\r
 150                                         origin_apply = '-1 1 0'; // seventh occupant sits in the back-right\r
 151                                         break;\r
 152                                 case 7:\r
 153                                         origin_apply = '1 -1 0'; // eigth occupant sits in the front-left\r
 154                                         break;\r
 155                                 case 8:\r
 156                                         origin_apply = '-1 -1 0'; // ninth occupant sits in the back-left\r
 157                                         break;\r
 158                                 default:\r
 159                                         break;\r
 160                         }\r
 161 \r
 162                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 163                         head.view_ofs = PL_PREY_VIEW_OFS + origin_apply * cvar("g_vore_neighborprey_distance");\r
 164                         head.view_ofs_z *= self.scale; // stomach center depends on predator scale\r
 165 \r
 166                         // change prey height based on scale\r
 167                         float prey_height;\r
 168                                 prey_height = (head.scale - self.scale) * cvar("g_healthsize_vore_pos");\r
 169                         head.view_ofs_z += prey_height;\r
 170 \r
 171                         position_counter += 1;\r
 172                 }\r
 173         }\r
 174 }\r
 175 \r
 176 .float gurgle_oldstomachload;\r
 177 void Vore_GurgleSound()\r
 178 {\r
 179         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 180         {\r
 181                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 182 \r
 183                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 184                 self.gurgle_oldstomachload = self.stomach_load;\r
 185         }\r
 186 }\r
 187 \r
 188 void Vore_WeightApply(entity e)\r
 189 {\r
 190         // apply stomach weight that makes you heavier the more you eat\r
 191         // slowing the player is done in cl_physics.qc\r
 192 \r
 193         if(e.stomach_load != e.vore_oldstomachload)\r
 194                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
 195         if(e.gravity == 0)\r
 196                 e.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 197         e.vore_oldstomachload = e.stomach_load;\r
 198 }\r
 199 \r
 200 void Vore_AutoDigest(entity e)\r
 201 {\r
 202         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 203 \r
 204         if(!cvar("g_vore_digestion") || e.digesting)\r
 205                 return;\r
 206         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 207                 return; // this feature is only for players, not bots\r
 208         if(e.stomach_load > 1)\r
 209                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 210         if(Stomach_TeamMates_check(e))\r
 211                 return; // never begin automatic digestion if we've swallowed a team mate\r
 212 \r
 213         e.digesting = TRUE;\r
 214 }\r
 215 \r
 216 .entity swallow_model;\r
 217 float Vore_SwallowModel_CustomizeEntityForClient()\r
 218 {\r
 219         // use the same system as the weapon model\r
 220 \r
 221         self.viewmodelforclient = self.owner;\r
 222         self.alpha = self.owner.cvar_cl_vore_swallowmodel;\r
 223 \r
 224         if(other.classname == "spectator")\r
 225         if(other.enemy == self.owner)\r
 226         {\r
 227                 self.viewmodelforclient = other;\r
 228                 self.alpha = other.cvar_cl_vore_swallowmodel;\r
 229         }\r
 230 \r
 231         return TRUE;\r
 232 }\r
 233 \r
 234 void Vore_SwallowModel_Think()\r
 235 {\r
 236         // update the position of the swallow model to match our swallow progress\r
 237         float dist;\r
 238         dist = (-0.5 + self.owner.swallow_progress_prey) * cvar("g_vore_swallowmodel_range"); // the model is centered at 0.5 progress\r
 239         if(cvar("g_healthsize"))\r
 240                 dist *= self.scale;\r
 241         self.view_ofs = '1 0 0' * dist;\r
 242 \r
 243         // if our swallow progress is gone or we are dead, the swallow model also goes away\r
 244         if(!self.owner.swallow_progress_prey || self.owner.deadflag != DEAD_NO || self.owner.classname != "player")\r
 245         {\r
 246                 remove(self.owner.swallow_model);\r
 247                 self.owner.swallow_model = world;\r
 248                 return;\r
 249         }\r
 250 \r
 251         // properties that should update whenever possible, but when the predator is not available\r
 252         self.nextthink = time;\r
 253 }\r
 254 \r
 255 void Vore_SwallowModel_Update(entity prey, entity pred)\r
 256 {\r
 257         // if we don't have a swallow model already, spawn one\r
 258         if(!prey.swallow_model)\r
 259         {\r
 260                 prey.swallow_model = spawn();\r
 261                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 262                 prey.swallow_model.solid = SOLID_NOT;\r
 263                 //prey.swallow_model.effects |= EF_NOGUNBOB; // let it bob\r
 264                 prey.swallow_model.effects |= EF_NODEPTHTEST; // don't hide behind walls\r
 265                 prey.swallow_model.owner = prey;\r
 266                 prey.swallow_model.customizeentityforclient = Vore_SwallowModel_CustomizeEntityForClient;\r
 267                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
 268                 prey.swallow_model.nextthink = time;\r
 269         }\r
 270 \r
 271         // properties that should update whenever possible, but when the predator is available\r
 272         string player_swallowmodel;\r
 273         player_swallowmodel = strcat(substring(pred.playermodel, 0, strlen(pred.playermodel) - 4), "_swallow.md3"); // 4 is the extension length\r
 274         if(prey.swallow_model.model != player_swallowmodel) // player model can be changed while the predator is active\r
 275                 setmodel(prey.swallow_model, player_swallowmodel);\r
 276         if(prey.swallow_model.skin != pred.skin) // player skin can be changed while the predator is active\r
 277                 prey.swallow_model.skin = pred.skin;\r
 278         if(cvar("g_healthsize"))\r
 279                 prey.swallow_model.scale = pred.scale / prey.scale; // player size difference\r
 280         if(prey.swallow_model.enemy != pred)\r
 281                 prey.swallow_model.enemy = pred; // enemy is the predator\r
 282         if(prey.swallow_model.colormap != pred.colormap)\r
 283                 prey.swallow_model.colormap = pred.colormap; // pants and shirt color\r
 284         if(prey.swallow_model.glowmod != pred.glowmod)\r
 285                 prey.swallow_model.glowmod = pred.glowmod; // glow color\r
 286 }\r
 287 \r
 288 .entity pusher;\r
 289 .float pushltime;\r
 290 void Vore_Swallow(entity e)\r
 291 {\r
 292         // this player is being swallowed by another player, apply the proper changes\r
 293 \r
 294         e.vore_oldmovetype = e.movetype;\r
 295         e.vore_oldsolid = e.solid;\r
 296 \r
 297         e.predator = self;\r
 298         setorigin(e, e.predator.origin);\r
 299         e.velocity = '0 0 0';\r
 300         e.movetype = MOVETYPE_FOLLOW;\r
 301         e.solid = SOLID_NOT;\r
 302         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 303 \r
 304         // drop keys (KH) and flags (CTF) when we get swallowed\r
 305         kh_Key_DropAll(e, FALSE);\r
 306         if(e.flagcarried)\r
 307                 DropFlag(e.flagcarried, world, e.predator);\r
 308 \r
 309         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 310                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 311 \r
 312         if(teams_matter && e.team == e.predator.team)\r
 313         {\r
 314                 if(cvar("g_vore_kick"))\r
 315                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 316                 if(cvar("g_vore_digestion"))\r
 317                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 318         }\r
 319 \r
 320         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 321         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 322         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 323         e.predator.stomach_load += Prey_Mass(e);\r
 324         e.predator.regurgitate_prepare = 0;\r
 325         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 326         e.predator.hitsound += 1; // play this for team mates too, as we could be swallowing them to heal them\r
 327         Vore_WeightApply(e.predator);\r
 328         Vore_AutoDigest(e.predator);\r
 329 \r
 330         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 331         e.predator.weapon_delay = time + button_delay_time;\r
 332         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 333         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 334         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 335 }\r
 336 \r
 337 void Vore_SwallowStep(entity e)\r
 338 {\r
 339         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 340         {\r
 341                 Vore_Swallow(e);\r
 342                 return;\r
 343         }\r
 344 \r
 345         Vore_SwallowModel_Update(e, self);\r
 346 \r
 347         // increase the progress value until it reaches 1, then swallow the player\r
 348         if(e.swallow_progress_prey < 1)\r
 349         {\r
 350                 float fill;\r
 351                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 352                 if(cvar("g_healthsize") && cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 353                         fill *= pow(self.scale / e.scale, cvar("g_balance_vore_swallow_speed_fill_scalediff"));\r
 354                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 355                         fill /= e.stomach_load;\r
 356 \r
 357                 e.swallow_progress_prey += fill;\r
 358         }\r
 359         else\r
 360         {\r
 361                 Vore_Swallow(e);\r
 362                 e.swallow_progress_prey = 0;\r
 363         }\r
 364 \r
 365         // the predator's progress is how much the prey got swallowed\r
 366         self.swallow_progress_pred = e.swallow_progress_prey;\r
 367 }\r
 368 \r
 369 void Vore_Regurgitate(entity e)\r
 370 {\r
 371         // this player is being regurgitated by their predator, apply the proper changes\r
 372 \r
 373         e.movetype = e.vore_oldmovetype;\r
 374         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 375                 e.solid = e.vore_oldsolid;\r
 376         e.view_ofs_z = PL_VIEW_OFS_z;\r
 377 \r
 378         // apply velocities\r
 379         local vector oldforward, oldright, oldup;\r
 380         oldforward = v_forward;\r
 381         oldright = v_right;\r
 382         oldup = v_up;\r
 383         makevectors(e.predator.v_angle);\r
 384         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 385         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 386         v_forward = oldforward;\r
 387         v_right = oldright;\r
 388         v_up = oldup;\r
 389 \r
 390         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 391         e.pushltime = time + cvar("g_maxpushtime");\r
 392 \r
 393         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 394         if(cvar("g_balance_vore_swallow_speed_fill") && cvar("g_balance_vore_regurgitate_swallowprogress"))\r
 395         {\r
 396                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 397                 Vore_SwallowModel_Update(e, e.predator);\r
 398         }\r
 399 \r
 400         // apply regurgitation damage to the predator\r
 401         if(cvar("g_balance_vore_regurgitate_damage"))\r
 402         {\r
 403                 float regurgitate_dmg;\r
 404                 regurgitate_dmg = cvar("g_balance_vore_regurgitate_damage");\r
 405                 if(cvar("g_healthsize"))\r
 406                         regurgitate_dmg *= e.scale / e.predator.scale;\r
 407                 Damage(e.predator, e.predator, e.predator, regurgitate_dmg, DEATH_REGURGITATION, e.predator.origin, '0 0 0');\r
 408         }\r
 409 \r
 410         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 411         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 412         pointparticles(particleeffectnum("vore_regurgitate"), e.predator.origin, '0 0 0', 1);\r
 413         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 414         e.predator.stomach_load -= Prey_Mass(e);\r
 415         e.predator.regurgitate_prepare = 0;\r
 416         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 417         Vore_WeightApply(e.predator);\r
 418 \r
 419         // block firing for a small amount of time, or we'll be firing the next frame\r
 420         e.weapon_delay = time + button_delay_time;\r
 421         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 422         e.predator = world;\r
 423 }\r
 424 \r
 425 void Vore_DeadPrey_Configure(entity e)\r
 426 {\r
 427         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 428 \r
 429         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
 430                 return;\r
 431 \r
 432         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 433         e.fakepredator = e.predator;\r
 434         e.fakeprey = TRUE;\r
 435 \r
 436         // first release the prey from the predator, as dead prey needs to be attached differently\r
 437         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 438         e.predator.stomach_load -= Prey_Mass(e);\r
 439         Vore_WeightApply(e.predator);\r
 440         e.predator = world;\r
 441 \r
 442         // now put our dead prey inside the predator's stomach, but only as an effect\r
 443         e.movetype = MOVETYPE_FOLLOW;\r
 444         e.takedamage = DAMAGE_NO;\r
 445         e.solid = SOLID_NOT;\r
 446         e.aiment = e.fakepredator;\r
 447 }\r
 448 \r
 449 void Vore_DeadPrey_Detach(entity e)\r
 450 {\r
 451         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 452         // should only execute after Vore_DeadPrey_Configure has ran first\r
 453 \r
 454         if not(cvar("g_vore_keepdeadprey"))\r
 455                 return;\r
 456 \r
 457         e.fakepredator = world;\r
 458         e.fakeprey = TRUE; // keep fakeprey status\r
 459         e.stat_eaten = 0;\r
 460         e.aiment = world;\r
 461         e.movetype = MOVETYPE_TOSS;\r
 462 }\r
 463 \r
 464 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 465 {\r
 466         if(pred_disconnect)\r
 467         {\r
 468                 if(e.fakeprey)\r
 469                         Vore_DeadPrey_Detach(e);\r
 470                 else\r
 471                         Vore_Regurgitate(e);\r
 472         }\r
 473         else if(self.stat_eaten && !self.fakeprey)\r
 474         {\r
 475                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 476                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 477                         Vore_DeadPrey_Configure(e);\r
 478                 else\r
 479                         Vore_Regurgitate(e);\r
 480         }\r
 481 }\r
 482 \r
 483 void Vore_Disconnect()\r
 484 {\r
 485         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 486 \r
 487         // prey disconnects or goes spectating while inside someone's belly\r
 488         if(self.stat_eaten)\r
 489                 Vore_PreyRelease(self, TRUE);\r
 490 \r
 491         // pred disconnects or goes spectating with players in their belly\r
 492         entity head;\r
 493         FOR_EACH_PLAYER(head)\r
 494         {\r
 495                 if(head.predator == self || head.fakepredator == self)\r
 496                         Vore_PreyRelease(head, TRUE);\r
 497         }\r
 498         Vore_GurgleSound(); // stop the gurgling sound\r
 499 \r
 500         self.stomach_load = self.gravity = 0; // prevents a bug\r
 501 }\r
 502 \r
 503 .float digestion_step;\r
 504 void Vore_Digest()\r
 505 {\r
 506         // apply digestion to prey\r
 507 \r
 508         if(time > self.digestion_step)\r
 509         {\r
 510                 // if distributed digestion is enabled, reduce digestion strength by the number of prey in our stomach\r
 511                 float reduce;\r
 512                 if(cvar("g_balance_vore_digestion_distribute"))\r
 513                         reduce = self.predator.stomach_load;\r
 514                 else\r
 515                         reduce = 1;\r
 516 \r
 517                 float damage;\r
 518                 damage = cvar("g_balance_vore_digestion_damage") / reduce;\r
 519 \r
 520                 // apply player scale to digestion damage\r
 521                 if(cvar("g_healthsize") && cvar("g_balance_vore_digestion_scalediff"))\r
 522                         damage *= pow(self.predator.scale / self.scale, cvar("g_balance_vore_digestion_scalediff"));\r
 523 \r
 524                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 525                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 526                         self.predator.health += cvar("g_balance_vore_digestion_vampire") / reduce;\r
 527 \r
 528                 if (self.predator.digestsound_finished < time)\r
 529                 {\r
 530                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 531                         self.predator.digestsound_finished = time + 0.5;\r
 532                 }\r
 533                 self.digestion_step = time + steptime;\r
 534         }\r
 535 \r
 536         if(self.deadflag != DEAD_NO)\r
 537         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 538                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 539 }\r
 540 \r
 541 .float teamheal_step;\r
 542 void Vore_Teamheal()\r
 543 {\r
 544         // apply teamheal\r
 545 \r
 546         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 547         if(time > self.teamheal_step)\r
 548         {\r
 549                 self.health += cvar("g_balance_vore_teamheal");\r
 550                 self.teamheal_step = time + steptime;\r
 551 \r
 552                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 553                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 554                 {\r
 555                         play2(self, "misc/beep.wav");\r
 556                         play2(self.predator, "misc/beep.wav");\r
 557                 }\r
 558         }\r
 559 }\r
 560 \r
 561 .float kick_pressed;\r
 562 void Vore_StomachKick()\r
 563 {\r
 564         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 565 \r
 566         if(time > self.stomachkick_delay && !self.kick_pressed)\r
 567         {\r
 568                 float damage, vol;\r
 569                 vector force;\r
 570                 damage = cvar("g_balance_vore_kick_damage");\r
 571                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 572                 vol = VOL_BASE;\r
 573 \r
 574                 // apply player scale to the damage / force of the kick\r
 575                 if(cvar("g_healthsize") && cvar("g_balance_vore_kick_scalediff"))\r
 576                 {\r
 577                         damage *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 578                         force *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 579                         vol *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff")); // kick sound volume based on the same scale\r
 580                 }\r
 581                 vol = bound(0, vol, 1);\r
 582 \r
 583                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 584                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), vol, ATTN_NORM);\r
 585                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 586                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 587 \r
 588                 // abort the predator's scheduled regurgitation\r
 589                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 590                         self.predator.regurgitate_prepare = 0;\r
 591 \r
 592                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 593                 if(cvar("g_balance_vore_kick_repress"))\r
 594                 if not(clienttype(self) == CLIENTTYPE_BOT) // not for bots, to prevent an issue\r
 595                         self.kick_pressed = TRUE;\r
 596         }\r
 597 }\r
 598 \r
 599 void Vore_StomachLeave()\r
 600 {\r
 601         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 602 \r
 603         if(Vore_CanLeave())\r
 604                 Vore_Regurgitate(self);\r
 605         else if(time > self.complain_vore)\r
 606         {\r
 607                 play2(self, "misc/forbidden.wav");\r
 608                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 609                 self.complain_vore = time + complain_delay_time;\r
 610         }\r
 611 }\r
 612 \r
 613 void Vore_AutoTaunt()\r
 614 {\r
 615         // triggers ambient vore taunts, for both pred and prey\r
 616 \r
 617         float taunt_time;\r
 618 \r
 619         // predator taunts\r
 620         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 621         {\r
 622                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 623                 {\r
 624                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 625                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 626                 }\r
 627         }\r
 628         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 629         {\r
 630                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 631                 SetAutoTaunt(self, 0, 0);\r
 632         }\r
 633 \r
 634         // prey taunts\r
 635         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
 636         {\r
 637                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 638                 {\r
 639                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 640                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 641                 }\r
 642         }\r
 643         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 644         {\r
 645                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 646                 SetAutoTaunt(self, 0, 0);\r
 647         }\r
 648 }\r
 649 \r
 650 void Vore_SetSbarRings()\r
 651 {\r
 652         // first clear the ring stats, then configure them if needed\r
 653         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 654         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 655 \r
 656         if(self.stat_eaten)\r
 657         {\r
 658                 if(time <= self.stomachkick_delay)\r
 659                 {\r
 660                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 661                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 662                 }\r
 663         }\r
 664         else\r
 665         {\r
 666                 if(self.swallow_progress_pred)\r
 667                 {\r
 668                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 669                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 670                 }\r
 671                 else if(time <= self.action_delay)\r
 672                 {\r
 673                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 674                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 675                 }\r
 676 \r
 677                 if(self.swallow_progress_prey)\r
 678                 {\r
 679                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 680                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 681                 }\r
 682                 else if(time <= self.regurgitate_prepare)\r
 683                 {\r
 684                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 685                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 686                 }\r
 687         }\r
 688 }\r
 689 \r
 690 void Vore()\r
 691 {\r
 692         // main vore code, this is where it all happens\r
 693 \r
 694         Vore_AutoTaunt();\r
 695 \r
 696         // wash the goo away from players once they leave the stomach\r
 697         if(!self.stat_eaten)\r
 698         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 699         if(self.colormod)\r
 700         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 701         {\r
 702                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 703                 if(self.colormod_x > 1)\r
 704                         self.colormod_x = 1;\r
 705                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 706                 if(self.colormod_y > 1)\r
 707                         self.colormod_y = 1;\r
 708                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 709                 if(self.colormod_z > 1)\r
 710                         self.colormod_z = 1;\r
 711         }\r
 712 \r
 713         // set all vore stats\r
 714         Vore_SetSbarRings();\r
 715         if(self.fakepredator.classname == "player")\r
 716                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 717         else if(self.predator.classname == "player")\r
 718         {\r
 719                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 720                 self.stat_stomachmaxload = self.predator.stat_stomachmaxload; // necessary for the stomach board\r
 721                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 722                 self.stat_eaten = num_for_edict(self.predator);\r
 723         }\r
 724         else\r
 725         {\r
 726                 float vore_capacity;\r
 727                 vore_capacity = cvar("g_balance_vore_load_capacity");\r
 728                 if(cvar("g_healthsize"))\r
 729                         vore_capacity *= self.scale;\r
 730                 vore_capacity = ceil(vore_capacity);\r
 731 \r
 732                 self.stat_stomachload = self.stomach_load;\r
 733                 self.stat_stomachmaxload = vore_capacity;\r
 734                 self.stat_digesting = self.digesting;\r
 735                 self.stat_eaten = 0;\r
 736         }\r
 737         self.stat_canleave = Vore_CanLeave();\r
 738 \r
 739         // don't allow a player inside a player inside another player :)\r
 740         // prevent this by checking if such has happened, and taking the proper measures\r
 741         // this code has a high priority and must not be stopped by any delay, so run it here\r
 742         if(self.predator.stat_eaten)\r
 743         {\r
 744                 entity target_predator, target_predator_predator, oldself;\r
 745                 target_predator = self.predator;\r
 746                 target_predator_predator = self.predator.predator;\r
 747 \r
 748                 Vore_Regurgitate(self);\r
 749 \r
 750                 // now steal our prey's prey if this probability applies\r
 751                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 752                 {\r
 753                         oldself = self;\r
 754                         self = target_predator_predator;\r
 755                         if(Swallow_condition_check(oldself))\r
 756                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 757                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 758                                 Vore_Swallow(oldself);\r
 759                         self = oldself;\r
 760                 }\r
 761         }\r
 762 \r
 763         // the swallow progress of prey and preds idly decrease by this amount\r
 764         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 765         {\r
 766                 if(self.swallow_progress_pred)\r
 767                 {\r
 768                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 769                         if(self.swallow_progress_pred < 0)\r
 770                                 self.swallow_progress_pred = 0;\r
 771                 }\r
 772                 if(self.swallow_progress_prey)\r
 773                 {\r
 774                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 775                         if(self.swallow_progress_prey < 0)\r
 776                                 self.swallow_progress_prey = 0;\r
 777                 }\r
 778         }\r
 779 \r
 780         // apply delays and skip the vore system under some circumstances\r
 781         if(!cvar("g_vore")) // the vore system is disabled\r
 782         {\r
 783                 Vore_Disconnect();\r
 784                 return;\r
 785         }\r
 786         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 787         {\r
 788                 Vore_Disconnect();\r
 789                 return;\r
 790         }\r
 791         if(self.spectatee_status)\r
 792                 return;\r
 793         if(time < self.system_delay)\r
 794                 return;\r
 795 \r
 796 // --------------------------------\r
 797 // Code that addresses predators:\r
 798 // --------------------------------\r
 799 \r
 800         entity prey;\r
 801         prey = Swallow_player_check();\r
 802 \r
 803         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 804         self.stat_canswallow = 0;\r
 805         if(Swallow_condition_check(prey))\r
 806         {\r
 807                 // canswallow stat, used by the HUD\r
 808                 if(teams_matter && prey.team == self.team)\r
 809                         self.stat_canswallow = 2;\r
 810                 else\r
 811                         self.stat_canswallow = 1;\r
 812 \r
 813                 if(self.BUTTON_ATCK)\r
 814                         Vore_SwallowStep(prey);\r
 815         }\r
 816         else if(prey != world)\r
 817                 self.stat_canswallow = -1;\r
 818 \r
 819         // toggle digestion, if the player has someone in their stomach\r
 820         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 821         {\r
 822                 if(self.stomach_load)\r
 823                 {\r
 824                         if(time > self.digest_button_delay_time)\r
 825                         {\r
 826                                 self.digesting = !self.digesting;\r
 827                                 self.digest_button_delay_time = time + button_delay_time;\r
 828                         }\r
 829                 }\r
 830                 else if(time > self.complain_vore)\r
 831                 {\r
 832                         play2(self, "misc/forbidden.wav");\r
 833                         sprint(self, "There is nothing to digest\n");\r
 834                         self.complain_vore = time + complain_delay_time;\r
 835                 }\r
 836         }\r
 837         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 838                 self.digesting = FALSE;\r
 839 \r
 840         // predator wishes to regurgitate his prey\r
 841         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 842         {\r
 843                 if(self.stomach_load)\r
 844                 {\r
 845                         if(time > self.regurgitate_button_delay_time)\r
 846                         {\r
 847                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 848                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 849                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE); // looks good for preparing regurgitation\r
 850                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 851                         }\r
 852                 }\r
 853                 else if(time > self.complain_vore)\r
 854                 {\r
 855                         play2(self, "misc/forbidden.wav");\r
 856                         sprint(self, "There is nothing to regurgitate\n");\r
 857                         self.complain_vore = time + complain_delay_time;\r
 858                 }\r
 859         }\r
 860 \r
 861         if(cvar("g_vore_gurglesound"))\r
 862                 Vore_GurgleSound();\r
 863 \r
 864 // --------------------------------\r
 865 // Code that addresses the prey:\r
 866 // --------------------------------\r
 867 \r
 868         Vore_SetPreyPositions();\r
 869 \r
 870         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 871         if(self.fakeprey)\r
 872         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
 873                 Vore_DeadPrey_Detach(self);\r
 874 \r
 875         if(!self.stat_eaten)\r
 876                 return;\r
 877 \r
 878         if(self.deadflag != DEAD_NO)\r
 879         {\r
 880                 Vore_PreyRelease(self, FALSE);\r
 881                 return;\r
 882         }\r
 883 \r
 884         if(self.predator.deadflag != DEAD_NO)\r
 885                 Vore_Regurgitate(self);\r
 886         else if(vlen(self.predator.velocity) > cvar("g_balance_vore_regurgitate_speedcap") / (1 + self.predator.stomach_load))\r
 887                 Vore_Regurgitate(self);\r
 888 \r
 889         // apply delayed regurgitating if it was scheduled\r
 890         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 891         {\r
 892                 self.predator.regurgitate_prepare = 0;\r
 893                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 894                 Vore_Regurgitate(self);\r
 895         }\r
 896 \r
 897         // execute digesting and team healing\r
 898         if(self.predator.digesting == TRUE)\r
 899                 Vore_Digest();\r
 900         if(teams_matter && self.team == self.predator.team)\r
 901         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 902                 Vore_Teamheal();\r
 903 \r
 904         // execute prey commands\r
 905         if(self.BUTTON_ATCK)\r
 906         {\r
 907                 if(cvar("g_vore_kick"))\r
 908                         Vore_StomachKick();\r
 909         }\r
 910         else\r
 911                 self.kick_pressed = FALSE;\r
 912         if(self.BUTTON_JUMP)\r
 913                 Vore_StomachLeave();\r
 914 \r
 915         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 916         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 917         kh_Key_DropAll(self, FALSE);\r
 918 }