data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(cvar("g_healthsize")) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         makevectors(self.angles);\r
  22         vore_w_shotorg = self.origin;\r
  23         vore_w_shotdir = v_forward;\r
  24 \r
  25         if(self.antilag_debug)\r
  26                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, self.antilag_debug);\r
  27         else\r
  28                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  29         if(trace_fraction < 1)\r
  30         if(trace_ent.classname == "player")\r
  31                 return trace_ent;\r
  32         return world;\r
  33 }\r
  34 \r
  35 float Swallow_condition_check(entity prey)\r
  36 {\r
  37         // checks the necessary conditions for swallowing a player\r
  38 \r
  39         if(prey != self)\r
  40         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  41         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  42         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  43         if not(cvar("g_balance_vore_load_pred_speedcap") && vlen(self.velocity) >= (self.stomach_load / self.stomach_maxload) / cvar("g_balance_vore_load_pred_speedcap"))\r
  44         {\r
  45                 string swallow_complain;\r
  46                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  47                         swallow_complain = "You cannot swallow your team mates\n";\r
  48                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  49                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  50                 else if(self.stomach_load >= self.stomach_maxload)\r
  51                         swallow_complain = "You do not have any more room to swallow this player.\n";\r
  52                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  53                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  54                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  55                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  56 \r
  57                 if(swallow_complain != "")\r
  58                 {\r
  59                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  60                         {\r
  61                                 play2(self, "misc/forbidden.wav");\r
  62                                 sprint(self, swallow_complain);\r
  63                                 self.complain_vore = time + complain_delay_time;\r
  64                         }\r
  65                         return FALSE;\r
  66                 }\r
  67                 return TRUE;\r
  68         }\r
  69         return FALSE;\r
  70 }\r
  71 \r
  72 float Stomach_TeamMates_check(entity pred)\r
  73 {\r
  74         // checks if a player's stomach contains any team mates\r
  75 \r
  76         entity head;\r
  77         if(teams_matter)\r
  78         {\r
  79                 FOR_EACH_PLAYER(head)\r
  80                 {\r
  81                         if(head.predator == pred && head.team == pred.team)\r
  82                                 return TRUE;\r
  83                 }\r
  84         }\r
  85         return FALSE;\r
  86 }\r
  87 \r
  88 float Vore_CanLeave()\r
  89 {\r
  90         if(self.stat_eaten)\r
  91         {\r
  92                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  93                         return TRUE;\r
  94                 if(teams_matter && self.team == self.predator.team)\r
  95                         return TRUE;\r
  96                 if(g_rpg && cvar("g_rpg_canleave"))\r
  97                         return TRUE;\r
  98         }\r
  99         return FALSE;\r
 100 }\r
 101 \r
 102 // position the camera properly for prey\r
 103 void Vore_SetPreyPositions()\r
 104 {\r
 105         // self is the predator and head is the prey\r
 106 \r
 107         local entity head;\r
 108         local vector origin_apply;\r
 109         local float position_counter;\r
 110 \r
 111         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 112         // else all players overlap in the center. To do this, we run a loop on all players in the same stomach.\r
 113         // For each player, the origin is updated, then a new origin is used for the next player.\r
 114         // This requires that no more than 9 players may be in the stomach at a time!\r
 115         FOR_EACH_PLAYER(head)\r
 116         {\r
 117                 if(head.predator == self)\r
 118                 {\r
 119                         switch(position_counter)\r
 120                         {\r
 121                                 case 0:\r
 122                                         origin_apply = '0 0 0'; // first occupant sits in the middle\r
 123                                         break;\r
 124                                 case 1:\r
 125                                         origin_apply = '1 0 0'; // second occupant sits in the front\r
 126                                         break;\r
 127                                 case 2:\r
 128                                         origin_apply = '-1 0 0'; // third occupant sits in the back\r
 129                                         break;\r
 130                                 case 3:\r
 131                                         origin_apply = '0 1 0'; // fourth occupant sits in the right\r
 132                                         break;\r
 133                                 case 4:\r
 134                                         origin_apply = '0 -1 0'; // fifth occupant sits in the left\r
 135                                         break;\r
 136                                 case 5:\r
 137                                         origin_apply = '1 1 0'; // sixth occupant sits in the front-right\r
 138                                         break;\r
 139                                 case 6:\r
 140                                         origin_apply = '-1 1 0'; // seventh occupant sits in the back-right\r
 141                                         break;\r
 142                                 case 7:\r
 143                                         origin_apply = '1 -1 0'; // eigth occupant sits in the front-left\r
 144                                         break;\r
 145                                 case 8:\r
 146                                         origin_apply = '-1 -1 0'; // ninth occupant sits in the back-left\r
 147                                         break;\r
 148                                 default:\r
 149                                         break;\r
 150                         }\r
 151 \r
 152                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 153                         head.view_ofs = PL_PREY_VIEW_OFS + origin_apply * cvar("g_vore_neighborprey_distance");\r
 154                         head.view_ofs_z *= self.scale; // stomach center depends on predator scale\r
 155 \r
 156                         // change prey height based on scale\r
 157                         float prey_height;\r
 158                                 prey_height = (head.scale - self.scale) * cvar("g_healthsize_vore_pos");\r
 159                         head.view_ofs_z += prey_height;\r
 160 \r
 161                         position_counter += 1;\r
 162                 }\r
 163         }\r
 164 }\r
 165 \r
 166 .float gurgle_oldstomachload;\r
 167 void Vore_GurgleSound()\r
 168 {\r
 169         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 170         {\r
 171                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 172 \r
 173                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 174                 self.gurgle_oldstomachload = self.stomach_load;\r
 175         }\r
 176 }\r
 177 \r
 178 void Vore_StomachLoad_Apply()\r
 179 {\r
 180         // apply stomach weight that makes you heavier and larger the more you eat\r
 181         // slowing the player is done in cl_physics.qc\r
 182 \r
 183         entity e;\r
 184         float vore_mass;\r
 185 \r
 186         // apply the stomach capacity of the predator\r
 187         self.stomach_maxload = cvar("g_balance_vore_load_pred_capacity");\r
 188         if(cvar("g_healthsize"))\r
 189                 self.stomach_maxload *= self.scale;\r
 190         self.stomach_maxload = floor(self.stomach_maxload);\r
 191 \r
 192         self.stomach_load = 0; // start from zero\r
 193         FOR_EACH_PLAYER(e)\r
 194         {\r
 195                 if(e.predator == self && e.classname == "player")\r
 196                 {\r
 197                         vore_mass = cvar("g_balance_vore_load_prey_mass");\r
 198                         if(cvar("g_healthsize"))\r
 199                                 vore_mass *= e.scale;\r
 200                         self.stomach_load += floor(vore_mass);\r
 201                 }\r
 202         }\r
 203 \r
 204         // apply weight\r
 205         self.gravity = 1 + (self.stomach_load / self.stomach_maxload) * cvar("g_balance_vore_load_pred_weight");\r
 206         if(!self.gravity && self.stomach_load)\r
 207                 self.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 208 }\r
 209 \r
 210 void Vore_AutoDigest(entity e)\r
 211 {\r
 212         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 213 \r
 214         if(!cvar("g_vore_digestion") || e.digesting)\r
 215                 return;\r
 216         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 217                 return; // this feature is only for players, not bots\r
 218         if(e.stomach_load > 1)\r
 219                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 220         if(Stomach_TeamMates_check(e))\r
 221                 return; // never begin automatic digestion if we've swallowed a team mate\r
 222 \r
 223         e.digesting = TRUE;\r
 224 }\r
 225 \r
 226 .entity swallow_model;\r
 227 float Vore_SwallowModel_CustomizeEntityForClient()\r
 228 {\r
 229         // use the same system as the weapon model\r
 230 \r
 231         self.viewmodelforclient = self.owner;\r
 232         self.alpha = self.owner.cvar_cl_vore_swallowmodel;\r
 233 \r
 234         if(other.classname == "spectator")\r
 235         if(other.enemy == self.owner)\r
 236         {\r
 237                 self.viewmodelforclient = other;\r
 238                 self.alpha = other.cvar_cl_vore_swallowmodel;\r
 239         }\r
 240 \r
 241         return TRUE;\r
 242 }\r
 243 \r
 244 void Vore_SwallowModel_Think()\r
 245 {\r
 246         // update the position of the swallow model to match our swallow progress\r
 247         float dist;\r
 248         dist = (-0.5 + self.owner.swallow_progress_prey) * cvar("g_vore_swallowmodel_range"); // the model is centered at 0.5 progress\r
 249         if(cvar("g_healthsize"))\r
 250                 dist *= self.scale;\r
 251         self.view_ofs = '1 0 0' * dist;\r
 252 \r
 253         // if our swallow progress is gone or we are dead, the swallow model also goes away\r
 254         if(!self.owner.swallow_progress_prey || self.owner.deadflag != DEAD_NO || self.owner.classname != "player")\r
 255         {\r
 256                 remove(self.owner.swallow_model);\r
 257                 self.owner.swallow_model = world;\r
 258                 return;\r
 259         }\r
 260 \r
 261         // properties that should update whenever possible, but when the predator is not available\r
 262         self.nextthink = time;\r
 263 }\r
 264 \r
 265 void Vore_SwallowModel_Update(entity prey, entity pred)\r
 266 {\r
 267         // if we don't have a swallow model already, spawn one\r
 268         if(!prey.swallow_model)\r
 269         {\r
 270                 prey.swallow_model = spawn();\r
 271                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 272                 prey.swallow_model.solid = SOLID_NOT;\r
 273                 //prey.swallow_model.effects |= EF_NOGUNBOB; // let it bob\r
 274                 prey.swallow_model.effects |= EF_NODEPTHTEST; // don't hide behind walls\r
 275                 prey.swallow_model.owner = prey;\r
 276                 prey.swallow_model.customizeentityforclient = Vore_SwallowModel_CustomizeEntityForClient;\r
 277                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
 278                 prey.swallow_model.nextthink = time;\r
 279         }\r
 280 \r
 281         // properties that should update whenever possible, but when the predator is available\r
 282         string player_swallowmodel;\r
 283         player_swallowmodel = strcat(substring(pred.playermodel, 0, strlen(pred.playermodel) - 4), "_swallow.md3"); // 4 is the extension length\r
 284         if(prey.swallow_model.model != player_swallowmodel) // player model can be changed while the predator is active\r
 285                 setmodel(prey.swallow_model, player_swallowmodel);\r
 286         if(prey.swallow_model.skin != pred.skin) // player skin can be changed while the predator is active\r
 287                 prey.swallow_model.skin = pred.skin;\r
 288         if(cvar("g_healthsize"))\r
 289                 prey.swallow_model.scale = pred.scale / prey.scale; // player size difference\r
 290         if(prey.swallow_model.enemy != pred)\r
 291                 prey.swallow_model.enemy = pred; // enemy is the predator\r
 292         if(prey.swallow_model.colormap != pred.colormap)\r
 293                 prey.swallow_model.colormap = pred.colormap; // pants and shirt color\r
 294         if(prey.swallow_model.glowmod != pred.glowmod)\r
 295                 prey.swallow_model.glowmod = pred.glowmod; // glow color\r
 296 }\r
 297 \r
 298 .entity pusher;\r
 299 .float pushltime;\r
 300 void Vore_Swallow(entity e)\r
 301 {\r
 302         // this player is being swallowed by another player, apply the proper changes\r
 303 \r
 304         e.vore_oldmovetype = e.movetype;\r
 305         e.vore_oldsolid = e.solid;\r
 306 \r
 307         e.predator = self;\r
 308         setorigin(e, e.predator.origin);\r
 309         e.velocity = '0 0 0';\r
 310         e.movetype = MOVETYPE_FOLLOW;\r
 311         e.solid = SOLID_NOT;\r
 312         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 313 \r
 314         // drop keys (KH) and flags (CTF) when we get swallowed\r
 315         kh_Key_DropAll(e, FALSE);\r
 316         if(e.flagcarried)\r
 317                 DropFlag(e.flagcarried, world, e.predator);\r
 318 \r
 319         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 320                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 321 \r
 322         if(teams_matter && e.team == e.predator.team)\r
 323         {\r
 324                 if(cvar("g_vore_kick"))\r
 325                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 326                 if(cvar("g_vore_digestion"))\r
 327                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 328         }\r
 329 \r
 330         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 331         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 332         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 333         e.predator.regurgitate_prepare = 0;\r
 334         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 335         e.predator.hitsound += 1; // play this for team mates too, as we could be swallowing them to heal them\r
 336         Vore_AutoDigest(e.predator);\r
 337 \r
 338         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 339         e.predator.weapon_delay = time + button_delay_time;\r
 340         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 341         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 342         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 343 }\r
 344 \r
 345 void Vore_SwallowStep(entity e)\r
 346 {\r
 347         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 348         {\r
 349                 Vore_Swallow(e);\r
 350                 return;\r
 351         }\r
 352 \r
 353         Vore_SwallowModel_Update(e, self);\r
 354 \r
 355         // increase the progress value until it reaches 1, then swallow the player\r
 356         if(e.swallow_progress_prey < 1)\r
 357         {\r
 358                 float fill;\r
 359                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 360                 if(cvar("g_healthsize") && cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 361                         fill *= pow(self.scale / e.scale, cvar("g_balance_vore_swallow_speed_fill_scalediff"));\r
 362                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 363                         fill /= e.stomach_load;\r
 364 \r
 365                 e.swallow_progress_prey += fill;\r
 366         }\r
 367         else\r
 368         {\r
 369                 Vore_Swallow(e);\r
 370                 e.swallow_progress_prey = 0;\r
 371         }\r
 372 \r
 373         // the predator's progress is how much the prey got swallowed\r
 374         self.swallow_progress_pred = e.swallow_progress_prey;\r
 375 }\r
 376 \r
 377 void Vore_Regurgitate(entity e)\r
 378 {\r
 379         // this player is being regurgitated by their predator, apply the proper changes\r
 380 \r
 381         e.movetype = e.vore_oldmovetype;\r
 382         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 383                 e.solid = e.vore_oldsolid;\r
 384         e.view_ofs_z = PL_VIEW_OFS_z;\r
 385 \r
 386         // apply velocities\r
 387         local vector oldforward, oldright, oldup;\r
 388         oldforward = v_forward;\r
 389         oldright = v_right;\r
 390         oldup = v_up;\r
 391         makevectors(e.predator.v_angle);\r
 392         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 393         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 394         v_forward = oldforward;\r
 395         v_right = oldright;\r
 396         v_up = oldup;\r
 397 \r
 398         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 399         e.pushltime = time + cvar("g_maxpushtime");\r
 400 \r
 401         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 402         if(cvar("g_balance_vore_swallow_speed_fill") && cvar("g_balance_vore_regurgitate_swallowprogress"))\r
 403         {\r
 404                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 405                 Vore_SwallowModel_Update(e, e.predator);\r
 406         }\r
 407 \r
 408         // apply regurgitation damage to the predator\r
 409         if(cvar("g_balance_vore_regurgitate_damage"))\r
 410         {\r
 411                 float regurgitate_dmg;\r
 412                 regurgitate_dmg = cvar("g_balance_vore_regurgitate_damage");\r
 413                 if(cvar("g_healthsize"))\r
 414                         regurgitate_dmg *= e.scale / e.predator.scale;\r
 415                 Damage(e.predator, e.predator, e.predator, regurgitate_dmg, DEATH_REGURGITATION, e.predator.origin, '0 0 0');\r
 416         }\r
 417 \r
 418         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 419         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 420         pointparticles(particleeffectnum("vore_regurgitate"), e.predator.origin, '0 0 0', 1);\r
 421         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 422         e.predator.regurgitate_prepare = 0;\r
 423         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 424 \r
 425         // block firing for a small amount of time, or we'll be firing the next frame\r
 426         e.weapon_delay = time + button_delay_time;\r
 427         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 428         e.predator = world;\r
 429 }\r
 430 \r
 431 void Vore_DeadPrey_Configure(entity e)\r
 432 {\r
 433         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 434 \r
 435         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
 436                 return;\r
 437 \r
 438         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 439         e.fakepredator = e.predator;\r
 440         e.fakeprey = TRUE;\r
 441 \r
 442         // first release the prey from the predator, as dead prey needs to be attached differently\r
 443         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 444         e.predator = world;\r
 445 \r
 446         // now put our dead prey inside the predator's stomach, but only as an effect\r
 447         e.movetype = MOVETYPE_FOLLOW;\r
 448         e.takedamage = DAMAGE_NO;\r
 449         e.solid = SOLID_NOT;\r
 450         e.aiment = e.fakepredator;\r
 451 }\r
 452 \r
 453 void Vore_DeadPrey_Detach(entity e)\r
 454 {\r
 455         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 456         // should only execute after Vore_DeadPrey_Configure has ran first\r
 457 \r
 458         if not(cvar("g_vore_keepdeadprey"))\r
 459                 return;\r
 460 \r
 461         e.fakepredator = world;\r
 462         e.fakeprey = TRUE; // keep fakeprey status\r
 463         e.stat_eaten = 0;\r
 464         e.aiment = world;\r
 465         e.movetype = MOVETYPE_TOSS;\r
 466 }\r
 467 \r
 468 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 469 {\r
 470         if(pred_disconnect)\r
 471         {\r
 472                 if(e.fakeprey)\r
 473                         Vore_DeadPrey_Detach(e);\r
 474                 else\r
 475                         Vore_Regurgitate(e);\r
 476         }\r
 477         else if(self.stat_eaten && !self.fakeprey)\r
 478         {\r
 479                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 480                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 481                         Vore_DeadPrey_Configure(e);\r
 482                 else\r
 483                         Vore_Regurgitate(e);\r
 484         }\r
 485 }\r
 486 \r
 487 void Vore_Disconnect()\r
 488 {\r
 489         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 490 \r
 491         // prey disconnects or goes spectating while inside someone's belly\r
 492         if(self.stat_eaten)\r
 493                 Vore_PreyRelease(self, TRUE);\r
 494 \r
 495         // pred disconnects or goes spectating with players in their belly\r
 496         entity head;\r
 497         FOR_EACH_PLAYER(head)\r
 498         {\r
 499                 if(head.predator == self || head.fakepredator == self)\r
 500                         Vore_PreyRelease(head, TRUE);\r
 501         }\r
 502         Vore_GurgleSound(); // stop the gurgling sound\r
 503 \r
 504         self.stomach_load = self.gravity = 0; // prevents a bug\r
 505 }\r
 506 \r
 507 .float digestion_step;\r
 508 void Vore_Digest()\r
 509 {\r
 510         // apply digestion to prey\r
 511 \r
 512         if(time > self.digestion_step)\r
 513         {\r
 514                 // if distributed digestion is enabled, reduce digestion strength by the amount of prey in our stomach\r
 515                 float vore_offset;\r
 516                 if(cvar("g_balance_vore_digestion_distribute"))\r
 517                         vore_offset = self.predator.stomach_maxload / self.predator.stomach_load;\r
 518                 else\r
 519                         vore_offset = 1;\r
 520 \r
 521                 float damage;\r
 522                 damage = cvar("g_balance_vore_digestion_damage") / vore_offset;\r
 523 \r
 524                 // apply player scale to digestion damage\r
 525                 if(cvar("g_healthsize") && cvar("g_balance_vore_digestion_scalediff"))\r
 526                         damage *= pow(self.predator.scale / self.scale, cvar("g_balance_vore_digestion_scalediff"));\r
 527 \r
 528                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 529                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 530                         self.predator.health += cvar("g_balance_vore_digestion_vampire") / vore_offset;\r
 531 \r
 532                 if (self.predator.digestsound_finished < time)\r
 533                 {\r
 534                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 535                         self.predator.digestsound_finished = time + 0.5;\r
 536                 }\r
 537                 self.digestion_step = time + steptime;\r
 538         }\r
 539 \r
 540         if(self.deadflag != DEAD_NO)\r
 541         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 542                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 543 }\r
 544 \r
 545 .float teamheal_step;\r
 546 void Vore_Teamheal()\r
 547 {\r
 548         // apply teamheal\r
 549 \r
 550         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 551         if(time > self.teamheal_step)\r
 552         {\r
 553                 self.health += cvar("g_balance_vore_teamheal");\r
 554                 self.teamheal_step = time + steptime;\r
 555 \r
 556                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 557                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 558                 {\r
 559                         play2(self, "misc/beep.wav");\r
 560                         play2(self.predator, "misc/beep.wav");\r
 561                 }\r
 562         }\r
 563 }\r
 564 \r
 565 .float kick_pressed;\r
 566 void Vore_StomachKick()\r
 567 {\r
 568         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 569 \r
 570         if(time > self.stomachkick_delay && !self.kick_pressed)\r
 571         {\r
 572                 float damage, vol;\r
 573                 vector force;\r
 574                 damage = cvar("g_balance_vore_kick_damage");\r
 575                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 576                 vol = VOL_BASE;\r
 577 \r
 578                 // apply player scale to the damage / force of the kick\r
 579                 if(cvar("g_healthsize") && cvar("g_balance_vore_kick_scalediff"))\r
 580                 {\r
 581                         damage *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 582                         force *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 583                         vol *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff")); // kick sound volume based on the same scale\r
 584                 }\r
 585                 vol = bound(0, vol, 1);\r
 586 \r
 587                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 588                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), vol, ATTN_NORM);\r
 589                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 590                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 591 \r
 592                 // abort the predator's scheduled regurgitation\r
 593                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 594                         self.predator.regurgitate_prepare = 0;\r
 595 \r
 596                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 597                 if(cvar("g_balance_vore_kick_repress"))\r
 598                 if not(clienttype(self) == CLIENTTYPE_BOT) // not for bots, to prevent an issue\r
 599                         self.kick_pressed = TRUE;\r
 600         }\r
 601 }\r
 602 \r
 603 void Vore_StomachLeave()\r
 604 {\r
 605         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 606 \r
 607         if(Vore_CanLeave())\r
 608                 Vore_Regurgitate(self);\r
 609         else if(time > self.complain_vore)\r
 610         {\r
 611                 play2(self, "misc/forbidden.wav");\r
 612                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 613                 self.complain_vore = time + complain_delay_time;\r
 614         }\r
 615 }\r
 616 \r
 617 void Vore_AutoTaunt()\r
 618 {\r
 619         // triggers ambient vore taunts, for both pred and prey\r
 620 \r
 621         float taunt_time;\r
 622 \r
 623         // predator taunts\r
 624         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 625         {\r
 626                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 627                 {\r
 628                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 629                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 630                 }\r
 631         }\r
 632         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 633         {\r
 634                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 635                 SetAutoTaunt(self, 0, 0);\r
 636         }\r
 637 \r
 638         // prey taunts\r
 639         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
 640         {\r
 641                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 642                 {\r
 643                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 644                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 645                 }\r
 646         }\r
 647         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 648         {\r
 649                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 650                 SetAutoTaunt(self, 0, 0);\r
 651         }\r
 652 }\r
 653 \r
 654 void Vore_SetSbarRings()\r
 655 {\r
 656         // first clear the ring stats, then configure them if needed\r
 657         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 658         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 659 \r
 660         if(self.stat_eaten)\r
 661         {\r
 662                 if(time <= self.stomachkick_delay)\r
 663                 {\r
 664                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 665                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 666                 }\r
 667         }\r
 668         else\r
 669         {\r
 670                 if(self.swallow_progress_pred)\r
 671                 {\r
 672                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 673                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 674                 }\r
 675                 else if(time <= self.action_delay)\r
 676                 {\r
 677                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 678                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 679                 }\r
 680 \r
 681                 if(self.swallow_progress_prey)\r
 682                 {\r
 683                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 684                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 685                 }\r
 686                 else if(time <= self.regurgitate_prepare)\r
 687                 {\r
 688                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 689                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 690                 }\r
 691         }\r
 692 }\r
 693 \r
 694 void Vore()\r
 695 {\r
 696         // main vore code, this is where it all happens\r
 697 \r
 698         Vore_AutoTaunt();\r
 699 \r
 700         // wash the goo away from players once they leave the stomach\r
 701         if(!self.stat_eaten)\r
 702         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 703         if(self.colormod)\r
 704         if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 705         {\r
 706                 self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 707                 if(self.colormod_x > 1)\r
 708                         self.colormod_x = 1;\r
 709                 self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 710                 if(self.colormod_y > 1)\r
 711                         self.colormod_y = 1;\r
 712                 self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 713                 if(self.colormod_z > 1)\r
 714                         self.colormod_z = 1;\r
 715         }\r
 716 \r
 717         // set all vore stats\r
 718         Vore_SetSbarRings();\r
 719         if(self.fakepredator.classname == "player")\r
 720                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 721         else if(self.predator.classname == "player")\r
 722         {\r
 723                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 724                 self.stat_stomachmaxload = self.predator.stomach_maxload; // necessary for the stomach board\r
 725                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 726                 self.stat_eaten = num_for_edict(self.predator);\r
 727         }\r
 728         else\r
 729         {\r
 730                 self.stat_stomachload = self.stomach_load;\r
 731                 self.stat_stomachmaxload = self.stomach_maxload;\r
 732                 self.stat_digesting = self.digesting;\r
 733                 self.stat_eaten = 0;\r
 734         }\r
 735         self.stat_canleave = Vore_CanLeave();\r
 736 \r
 737         // don't allow a player inside a player inside another player :)\r
 738         // prevent this by checking if such has happened, and taking the proper measures\r
 739         // this code has a high priority and must not be stopped by any delay, so run it here\r
 740         if(self.predator.stat_eaten)\r
 741         {\r
 742                 entity target_predator, target_predator_predator, oldself;\r
 743                 target_predator = self.predator;\r
 744                 target_predator_predator = self.predator.predator;\r
 745 \r
 746                 Vore_Regurgitate(self);\r
 747 \r
 748                 // now steal our prey's prey if this probability applies\r
 749                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 750                 {\r
 751                         oldself = self;\r
 752                         self = target_predator_predator;\r
 753                         if(Swallow_condition_check(oldself))\r
 754                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 755                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 756                                 Vore_Swallow(oldself);\r
 757                         self = oldself;\r
 758                 }\r
 759         }\r
 760 \r
 761         // the swallow progress of prey and preds idly decrease by this amount\r
 762         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 763         {\r
 764                 if(self.swallow_progress_pred)\r
 765                 {\r
 766                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 767                         if(self.swallow_progress_pred < 0)\r
 768                                 self.swallow_progress_pred = 0;\r
 769                 }\r
 770                 if(self.swallow_progress_prey)\r
 771                 {\r
 772                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 773                         if(self.swallow_progress_prey < 0)\r
 774                                 self.swallow_progress_prey = 0;\r
 775                 }\r
 776         }\r
 777 \r
 778         // apply delays and skip the vore system under some circumstances\r
 779         if(!cvar("g_vore")) // the vore system is disabled\r
 780         {\r
 781                 Vore_Disconnect();\r
 782                 return;\r
 783         }\r
 784         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 785         {\r
 786                 Vore_Disconnect();\r
 787                 return;\r
 788         }\r
 789         if(self.spectatee_status)\r
 790                 return;\r
 791         if(time < self.system_delay)\r
 792                 return;\r
 793 \r
 794 // --------------------------------\r
 795 // Code that addresses predators:\r
 796 // --------------------------------\r
 797 \r
 798         entity prey;\r
 799         prey = Swallow_player_check();\r
 800 \r
 801         // set the predator's stomach load and capacity\r
 802         Vore_StomachLoad_Apply();\r
 803 \r
 804         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 805         self.stat_canswallow = 0;\r
 806         if(Swallow_condition_check(prey))\r
 807         {\r
 808                 // canswallow stat, used by the HUD\r
 809                 if(teams_matter && prey.team == self.team)\r
 810                         self.stat_canswallow = 2;\r
 811                 else\r
 812                         self.stat_canswallow = 1;\r
 813 \r
 814                 if(self.BUTTON_ATCK)\r
 815                         Vore_SwallowStep(prey);\r
 816         }\r
 817         else if(prey != world)\r
 818                 self.stat_canswallow = -1;\r
 819 \r
 820         // toggle digestion, if the player has someone in their stomach\r
 821         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 822         {\r
 823                 if(self.stomach_load)\r
 824                 {\r
 825                         if(time > self.digest_button_delay_time)\r
 826                         {\r
 827                                 self.digesting = !self.digesting;\r
 828                                 self.digest_button_delay_time = time + button_delay_time;\r
 829                         }\r
 830                 }\r
 831                 else if(time > self.complain_vore)\r
 832                 {\r
 833                         play2(self, "misc/forbidden.wav");\r
 834                         sprint(self, "There is nothing to digest\n");\r
 835                         self.complain_vore = time + complain_delay_time;\r
 836                 }\r
 837         }\r
 838         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 839                 self.digesting = FALSE;\r
 840 \r
 841         // predator wishes to regurgitate his prey\r
 842         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 843         {\r
 844                 if(self.stomach_load)\r
 845                 {\r
 846                         if(time > self.regurgitate_button_delay_time)\r
 847                         {\r
 848                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 849                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 850                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE); // looks good for preparing regurgitation\r
 851                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 852                         }\r
 853                 }\r
 854                 else if(time > self.complain_vore)\r
 855                 {\r
 856                         play2(self, "misc/forbidden.wav");\r
 857                         sprint(self, "There is nothing to regurgitate\n");\r
 858                         self.complain_vore = time + complain_delay_time;\r
 859                 }\r
 860         }\r
 861 \r
 862         if(cvar("g_vore_gurglesound"))\r
 863                 Vore_GurgleSound();\r
 864 \r
 865 // --------------------------------\r
 866 // Code that addresses the prey:\r
 867 // --------------------------------\r
 868 \r
 869         Vore_SetPreyPositions();\r
 870 \r
 871         // keepdeadprey - detach dead prey if their predator died or got swallowed\r
 872         if(self.fakeprey)\r
 873         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
 874                 Vore_DeadPrey_Detach(self);\r
 875 \r
 876         if(!self.stat_eaten)\r
 877                 return;\r
 878 \r
 879         if(self.deadflag != DEAD_NO)\r
 880         {\r
 881                 Vore_PreyRelease(self, FALSE);\r
 882                 return;\r
 883         }\r
 884 \r
 885         if(self.predator.deadflag != DEAD_NO)\r
 886                 Vore_Regurgitate(self);\r
 887         else if(cvar("g_balance_vore_load_pred_speedcap") && vlen(self.velocity) >= (self.stomach_load / self.stomach_maxload) / cvar("g_balance_vore_load_pred_speedcap"))\r
 888                 Vore_Regurgitate(self);\r
 889 \r
 890         // apply delayed regurgitating if it was scheduled\r
 891         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 892         {\r
 893                 self.predator.regurgitate_prepare = 0;\r
 894                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 895                 Vore_Regurgitate(self);\r
 896         }\r
 897 \r
 898         // execute digesting and team healing\r
 899         if(self.predator.digesting == TRUE)\r
 900                 Vore_Digest();\r
 901         if(teams_matter && self.team == self.predator.team)\r
 902         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 903                 Vore_Teamheal();\r
 904 \r
 905         // execute prey commands\r
 906         if(self.BUTTON_ATCK)\r
 907         {\r
 908                 if(cvar("g_vore_kick"))\r
 909                         Vore_StomachKick();\r
 910         }\r
 911         else\r
 912                 self.kick_pressed = FALSE;\r
 913         if(self.BUTTON_JUMP)\r
 914                 Vore_StomachLeave();\r
 915 \r
 916         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 917         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 918         kh_Key_DropAll(self, FALSE);\r
 919 }