data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(cvar("g_healthsize")) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         makevectors(self.angles);\r
  22         vore_w_shotorg = self.origin;\r
  23         vore_w_shotdir = v_forward;\r
  24 \r
  25         if(self.antilag_debug)\r
  26                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, self.antilag_debug);\r
  27         else\r
  28                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  29         if(trace_fraction < 1)\r
  30         if(trace_ent.classname == "player")\r
  31                 return trace_ent;\r
  32         return world;\r
  33 }\r
  34 \r
  35 float Swallow_condition_check(entity prey)\r
  36 {\r
  37         // checks the necessary conditions for swallowing a player\r
  38 \r
  39         if(prey != self)\r
  40         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  41         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  42         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  43         {\r
  44                 float prey_mass;\r
  45                 prey_mass = cvar("g_balance_vore_load_prey_mass");\r
  46                 if(cvar("g_healthsize"))\r
  47                         prey_mass *= prey.scale;\r
  48 \r
  49                 string swallow_complain;\r
  50                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  51                         swallow_complain = "You cannot swallow your team mates\n";\r
  52                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  53                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  54                 else if(self.stomach_load + prey_mass > self.stomach_maxload)\r
  55                         swallow_complain = strcat("You don't have any room to swallow this player. Their mass is ^3", ftos(prey_mass), "^7 and your remaining capacity is ^3", ftos(self.stomach_maxload - self.stomach_load), "\n");\r
  56                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  57                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  58                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  59                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  60 \r
  61                 if(swallow_complain != "")\r
  62                 {\r
  63                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  64                         {\r
  65                                 play2(self, "misc/forbidden.wav");\r
  66                                 sprint(self, swallow_complain);\r
  67                                 self.complain_vore = time + complain_delay_time;\r
  68                         }\r
  69                         return FALSE;\r
  70                 }\r
  71                 return TRUE;\r
  72         }\r
  73         return FALSE;\r
  74 }\r
  75 \r
  76 float Stomach_TeamMates_check(entity pred)\r
  77 {\r
  78         // checks if a player's stomach contains any team mates\r
  79 \r
  80         entity head;\r
  81         if(teams_matter)\r
  82         {\r
  83                 FOR_EACH_PLAYER(head)\r
  84                 {\r
  85                         if(head.predator == pred && head.team == pred.team)\r
  86                                 return TRUE;\r
  87                 }\r
  88         }\r
  89         return FALSE;\r
  90 }\r
  91 \r
  92 float Vore_CanLeave()\r
  93 {\r
  94         if(self.stat_eaten)\r
  95         {\r
  96                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
  97                         return TRUE;\r
  98                 if(teams_matter && self.team == self.predator.team)\r
  99                         return TRUE;\r
 100                 if(g_rpg && cvar("g_rpg_canleave"))\r
 101                         return TRUE;\r
 102         }\r
 103         return FALSE;\r
 104 }\r
 105 \r
 106 // position the camera properly for prey\r
 107 void Vore_SetPreyPositions(entity pred)\r
 108 {\r
 109         // pred is the predator and head is the prey\r
 110 \r
 111         local entity head;\r
 112         local vector origin_apply;\r
 113 \r
 114         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 115         // else all players overlap in the center. To do this, we use a random origin on all players in the same stomach.\r
 116         FOR_EACH_PLAYER(head)\r
 117         {\r
 118                 if(head.predator == pred)\r
 119                 {\r
 120                         origin_apply_x = PL_PREY_VIEW_OFS_x + crandom() * cvar("g_vore_neighborprey_distance");\r
 121                         origin_apply_y = PL_PREY_VIEW_OFS_y + crandom() * cvar("g_vore_neighborprey_distance");\r
 122                         origin_apply_z = PL_PREY_VIEW_OFS_z;\r
 123 \r
 124                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 125                         head.view_ofs = origin_apply;\r
 126                         head.view_ofs_z *= pred.scale; // stomach center depends on predator scale\r
 127 \r
 128                         // change prey height based on scale\r
 129                         float prey_height;\r
 130                                 prey_height = (head.scale - pred.scale) * cvar("g_healthsize_vore_pos");\r
 131                         head.view_ofs_z += prey_height;\r
 132                 }\r
 133         }\r
 134 }\r
 135 \r
 136 .float gurgle_oldstomachload;\r
 137 void Vore_GurgleSound()\r
 138 {\r
 139         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 140         {\r
 141                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 142 \r
 143                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 144                 self.gurgle_oldstomachload = self.stomach_load;\r
 145         }\r
 146 }\r
 147 \r
 148 void Vore_StomachLoad_Apply()\r
 149 {\r
 150         // apply stomach weight that makes you heavier and larger the more you eat\r
 151         // slowing the player is done in cl_physics.qc\r
 152 \r
 153         entity e;\r
 154         float prey_mass;\r
 155 \r
 156         // apply the stomach capacity of the predator\r
 157         self.stomach_maxload = cvar("g_balance_vore_load_pred_capacity");\r
 158         if(cvar("g_healthsize"))\r
 159                 self.stomach_maxload *= self.scale;\r
 160         self.stomach_maxload = floor(self.stomach_maxload);\r
 161 \r
 162         self.stomach_load = 0; // start from zero\r
 163         FOR_EACH_PLAYER(e)\r
 164         {\r
 165                 if(e.predator == self)\r
 166                 {\r
 167                         prey_mass = cvar("g_balance_vore_load_prey_mass");\r
 168                         if(cvar("g_healthsize"))\r
 169                                 prey_mass *= e.scale;\r
 170                         self.stomach_load += floor(prey_mass);\r
 171                 }\r
 172         }\r
 173 \r
 174         // apply weight\r
 175         self.gravity = 1 + (self.stomach_load / self.stomach_maxload) * cvar("g_balance_vore_load_pred_weight");\r
 176         if(!self.gravity && self.stomach_load)\r
 177                 self.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 178 }\r
 179 \r
 180 void Vore_AutoDigest(entity e)\r
 181 {\r
 182         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 183 \r
 184         if(!cvar("g_vore_digestion") || e.digesting)\r
 185                 return;\r
 186         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 187                 return; // this feature is only for players, not bots\r
 188         if(e.stomach_load > 1)\r
 189                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 190         if(Stomach_TeamMates_check(e))\r
 191                 return; // never begin automatic digestion if we've swallowed a team mate\r
 192 \r
 193         e.digesting = TRUE;\r
 194 }\r
 195 \r
 196 .entity swallow_model;\r
 197 float Vore_SwallowModel_CustomizeEntityForClient()\r
 198 {\r
 199         // use the same system as the weapon model\r
 200 \r
 201         self.viewmodelforclient = self.owner;\r
 202         self.alpha = self.owner.cvar_cl_vore_swallowmodel;\r
 203 \r
 204         if(other.classname == "spectator")\r
 205         if(other.enemy == self.owner)\r
 206         {\r
 207                 self.viewmodelforclient = other;\r
 208                 self.alpha = other.cvar_cl_vore_swallowmodel;\r
 209         }\r
 210 \r
 211         return TRUE;\r
 212 }\r
 213 \r
 214 void Vore_SwallowModel_Think()\r
 215 {\r
 216         // update the position of the swallow model to match our swallow progress\r
 217         float dist;\r
 218         dist = (-0.5 + self.owner.swallow_progress_prey) * cvar("g_vore_swallowmodel_range"); // the model is centered at 0.5 progress\r
 219         if(cvar("g_healthsize"))\r
 220                 dist *= self.scale;\r
 221         self.view_ofs = '1 0 0' * dist;\r
 222 \r
 223         // if our swallow progress is gone or we are dead, the swallow model also goes away\r
 224         if(!self.owner.swallow_progress_prey || self.owner.deadflag != DEAD_NO || self.owner.classname != "player")\r
 225         {\r
 226                 remove(self.owner.swallow_model);\r
 227                 self.owner.swallow_model = world;\r
 228                 return;\r
 229         }\r
 230 \r
 231         // properties that should update whenever possible, but when the predator is not available\r
 232         self.nextthink = time;\r
 233 }\r
 234 \r
 235 void Vore_SwallowModel_Update(entity prey, entity pred)\r
 236 {\r
 237         // if we don't have a swallow model already, spawn one\r
 238         if(!prey.swallow_model)\r
 239         {\r
 240                 prey.swallow_model = spawn();\r
 241                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 242                 prey.swallow_model.solid = SOLID_NOT;\r
 243                 //prey.swallow_model.effects |= EF_NOGUNBOB; // let it bob\r
 244                 prey.swallow_model.effects |= EF_NODEPTHTEST; // don't hide behind walls\r
 245                 prey.swallow_model.owner = prey;\r
 246                 prey.swallow_model.customizeentityforclient = Vore_SwallowModel_CustomizeEntityForClient;\r
 247                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
 248                 prey.swallow_model.nextthink = time;\r
 249         }\r
 250 \r
 251         // properties that should update whenever possible, but when the predator is available\r
 252         string player_swallowmodel;\r
 253         player_swallowmodel = strcat(substring(pred.playermodel, 0, strlen(pred.playermodel) - 4), "_swallow.md3"); // 4 is the extension length\r
 254         if(prey.swallow_model.model != player_swallowmodel) // player model can be changed while the predator is active\r
 255                 setmodel(prey.swallow_model, player_swallowmodel);\r
 256         if(prey.swallow_model.skin != pred.skin) // player skin can be changed while the predator is active\r
 257                 prey.swallow_model.skin = pred.skin;\r
 258         if(cvar("g_healthsize"))\r
 259                 prey.swallow_model.scale = pred.scale / prey.scale; // player size difference\r
 260         if(prey.swallow_model.enemy != pred)\r
 261                 prey.swallow_model.enemy = pred; // enemy is the predator\r
 262         if(prey.swallow_model.colormap != pred.colormap)\r
 263                 prey.swallow_model.colormap = pred.colormap; // pants and shirt color\r
 264         if(prey.swallow_model.glowmod != pred.glowmod)\r
 265                 prey.swallow_model.glowmod = pred.glowmod; // glow color\r
 266 }\r
 267 \r
 268 .entity pusher;\r
 269 .float pushltime;\r
 270 void Vore_Swallow(entity e)\r
 271 {\r
 272         // this player is being swallowed by another player, apply the proper changes\r
 273 \r
 274         e.vore_oldmovetype = e.movetype;\r
 275         e.vore_oldsolid = e.solid;\r
 276 \r
 277         e.predator = self;\r
 278         setorigin(e, e.predator.origin);\r
 279         e.velocity = '0 0 0';\r
 280         e.movetype = MOVETYPE_FOLLOW;\r
 281         e.solid = SOLID_NOT;\r
 282         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 283 \r
 284         // drop keys (KH) and flags (CTF) when we get swallowed\r
 285         kh_Key_DropAll(e, FALSE);\r
 286         if(e.flagcarried)\r
 287                 DropFlag(e.flagcarried, world, e.predator);\r
 288 \r
 289         if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 290                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_release"));\r
 291 \r
 292         if(teams_matter && e.team == e.predator.team)\r
 293         {\r
 294                 if(cvar("g_vore_kick"))\r
 295                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 296                 if(cvar("g_vore_digestion"))\r
 297                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 298         }\r
 299 \r
 300         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 301         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 302         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 303         e.predator.regurgitate_prepare = 0;\r
 304         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 305         e.predator.hitsound += 1; // play this for team mates too, as we could be swallowing them to heal them\r
 306         Vore_AutoDigest(e.predator);\r
 307         Vore_SetPreyPositions(e.predator);\r
 308 \r
 309         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 310         e.predator.weapon_delay = time + button_delay_time;\r
 311         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 312         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 313         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 314 }\r
 315 \r
 316 void Vore_SwallowStep(entity e)\r
 317 {\r
 318         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 319         {\r
 320                 Vore_Swallow(e);\r
 321                 return;\r
 322         }\r
 323 \r
 324         Vore_SwallowModel_Update(e, self);\r
 325 \r
 326         // increase the progress value until it reaches 1, then swallow the player\r
 327         if(e.swallow_progress_prey < 1)\r
 328         {\r
 329                 float fill;\r
 330                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 331                 if(cvar("g_healthsize") && cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 332                         fill *= pow(self.scale / e.scale, cvar("g_balance_vore_swallow_speed_fill_scalediff"));\r
 333                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 334                         fill /= e.stomach_load;\r
 335 \r
 336                 e.swallow_progress_prey += fill;\r
 337         }\r
 338         else\r
 339         {\r
 340                 Vore_Swallow(e);\r
 341                 e.swallow_progress_prey = 0;\r
 342         }\r
 343 \r
 344         // the predator's progress is how much the prey got swallowed\r
 345         self.swallow_progress_pred = e.swallow_progress_prey;\r
 346 }\r
 347 \r
 348 void Vore_Regurgitate(entity e)\r
 349 {\r
 350         // this player is being regurgitated by their predator, apply the proper changes\r
 351 \r
 352         e.movetype = e.vore_oldmovetype;\r
 353         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 354                 e.solid = e.vore_oldsolid;\r
 355         e.view_ofs_z = PL_VIEW_OFS_z;\r
 356 \r
 357         // apply velocities\r
 358         local vector oldforward, oldright, oldup;\r
 359         oldforward = v_forward;\r
 360         oldright = v_right;\r
 361         oldup = v_up;\r
 362         makevectors(e.predator.v_angle);\r
 363         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 364         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 365         v_forward = oldforward;\r
 366         v_right = oldright;\r
 367         v_up = oldup;\r
 368 \r
 369         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 370         e.pushltime = time + cvar("g_maxpushtime");\r
 371 \r
 372         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 373         if(cvar("g_balance_vore_swallow_speed_fill") && cvar("g_balance_vore_regurgitate_swallowprogress"))\r
 374         {\r
 375                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 376                 Vore_SwallowModel_Update(e, e.predator);\r
 377         }\r
 378 \r
 379         // apply regurgitation damage to the predator\r
 380         if(cvar("g_balance_vore_regurgitate_damage"))\r
 381         {\r
 382                 float regurgitate_dmg;\r
 383                 regurgitate_dmg = cvar("g_balance_vore_regurgitate_damage");\r
 384                 if(cvar("g_healthsize"))\r
 385                         regurgitate_dmg *= e.scale / e.predator.scale;\r
 386                 Damage(e.predator, e.predator, e.predator, regurgitate_dmg, DEATH_REGURGITATION, e.predator.origin, '0 0 0');\r
 387         }\r
 388 \r
 389         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 390         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 391         pointparticles(particleeffectnum("vore_regurgitate"), e.predator.origin, '0 0 0', 1);\r
 392         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 393         e.predator.regurgitate_prepare = 0;\r
 394         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 395         Vore_SetPreyPositions(e.predator);\r
 396 \r
 397         // block firing for a small amount of time, or we'll be firing the next frame\r
 398         e.weapon_delay = time + button_delay_time;\r
 399         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 400         e.predator = world;\r
 401 }\r
 402 \r
 403 void Vore_DeadPrey_Configure(entity e)\r
 404 {\r
 405         // ran when the keepdeadprey feature is enabled and prey stays inside the stomach after dying\r
 406 \r
 407         if(e.fakeprey || !e.stat_eaten) // we already configured everything\r
 408                 return;\r
 409 \r
 410         // this entity is like e.predator but for dead prey, to avoid conflicts\r
 411         e.fakepredator = e.predator;\r
 412         e.fakeprey = TRUE;\r
 413         Vore_SetPreyPositions(e.predator);\r
 414 \r
 415         // first release the prey from the predator, as dead prey needs to be attached differently\r
 416         // the predator's stomach load is also decreased, as dead prey doesn't count any more\r
 417         e.predator = world;\r
 418 \r
 419         // now put our dead prey inside the predator's stomach, but only as an effect\r
 420         e.movetype = MOVETYPE_FOLLOW;\r
 421         e.takedamage = DAMAGE_NO;\r
 422         e.solid = SOLID_NOT;\r
 423         e.aiment = e.fakepredator;\r
 424 }\r
 425 \r
 426 void Vore_DeadPrey_Detach(entity e)\r
 427 {\r
 428         // ran when dead prey must be detached from the stomach (eg: they are respawning)\r
 429         // should only execute after Vore_DeadPrey_Configure has ran first\r
 430 \r
 431         if not(cvar("g_vore_keepdeadprey"))\r
 432                 return;\r
 433 \r
 434         e.fakepredator = world;\r
 435         e.fakeprey = TRUE; // keep fakeprey status\r
 436         e.stat_eaten = 0;\r
 437         e.aiment = world;\r
 438         e.movetype = MOVETYPE_TOSS;\r
 439 }\r
 440 \r
 441 void Vore_PreyRelease(entity e, float pred_disconnect)\r
 442 {\r
 443         if(pred_disconnect)\r
 444         {\r
 445                 if(e.fakeprey)\r
 446                         Vore_DeadPrey_Detach(e);\r
 447                 else\r
 448                         Vore_Regurgitate(e);\r
 449         }\r
 450         else if(self.stat_eaten && !self.fakeprey)\r
 451         {\r
 452                 // if the keepdeadprey feature is on, don't spit a dead prey's carcass out\r
 453                 if(e.deadflag != DEAD_NO && random() < cvar("g_vore_keepdeadprey"))\r
 454                         Vore_DeadPrey_Configure(e);\r
 455                 else\r
 456                         Vore_Regurgitate(e);\r
 457         }\r
 458 }\r
 459 \r
 460 void Vore_Disconnect()\r
 461 {\r
 462         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 463 \r
 464         // prey disconnects or goes spectating while inside someone's belly\r
 465         if(self.stat_eaten)\r
 466                 Vore_PreyRelease(self, TRUE);\r
 467 \r
 468         // pred disconnects or goes spectating with players in their belly\r
 469         entity head;\r
 470         FOR_EACH_PLAYER(head)\r
 471         {\r
 472                 if(head.predator == self || head.fakepredator == self)\r
 473                         Vore_PreyRelease(head, TRUE);\r
 474         }\r
 475         Vore_GurgleSound(); // stop the gurgling sound\r
 476 \r
 477         self.stomach_load = self.gravity = 0; // prevents a bug\r
 478 }\r
 479 \r
 480 .float digestion_step;\r
 481 void Vore_Digest()\r
 482 {\r
 483         // apply digestion to prey\r
 484 \r
 485         if(time > self.digestion_step)\r
 486         {\r
 487                 // if distributed digestion is enabled, reduce digestion strength by the amount of prey in our stomach\r
 488                 float vore_offset;\r
 489                 vore_offset = 1;\r
 490                 if(cvar("g_balance_vore_digestion_distribute")) // apply distributed digestion damage\r
 491                         vore_offset *= self.predator.stomach_load / self.predator.stomach_maxload;\r
 492                 if(cvar("g_healthsize") && cvar("g_balance_vore_digestion_scalediff")) // apply player scale to digestion damage\r
 493                         vore_offset *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_digestion_scalediff"));\r
 494                 vore_offset = ceil(vore_offset);\r
 495 \r
 496                 float damage;\r
 497                 damage = cvar("g_balance_vore_digestion_damage") / vore_offset;\r
 498 \r
 499                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 500                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 501                         self.predator.health += cvar("g_balance_vore_digestion_vampire") / vore_offset;\r
 502 \r
 503                 if (self.predator.digestsound_finished < time)\r
 504                 {\r
 505                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 506                         self.predator.digestsound_finished = time + 0.5;\r
 507                 }\r
 508                 self.digestion_step = time + steptime;\r
 509         }\r
 510 \r
 511         if(self.deadflag != DEAD_NO)\r
 512         if(stov(cvar_string("g_vore_regurgitatecolor_digest")))\r
 513                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digest"));\r
 514 }\r
 515 \r
 516 .float teamheal_step;\r
 517 void Vore_Teamheal()\r
 518 {\r
 519         // apply teamheal\r
 520 \r
 521         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 522         if(time > self.teamheal_step)\r
 523         {\r
 524                 self.health += cvar("g_balance_vore_teamheal");\r
 525                 self.teamheal_step = time + steptime;\r
 526 \r
 527                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 528                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 529                 {\r
 530                         play2(self, "misc/beep.wav");\r
 531                         play2(self.predator, "misc/beep.wav");\r
 532                 }\r
 533         }\r
 534 }\r
 535 \r
 536 .float kick_pressed;\r
 537 void Vore_StomachKick()\r
 538 {\r
 539         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 540 \r
 541         if(time > self.stomachkick_delay && !self.kick_pressed)\r
 542         {\r
 543                 float damage, vol;\r
 544                 vector force;\r
 545                 damage = cvar("g_balance_vore_kick_damage");\r
 546                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 547                 vol = VOL_BASE;\r
 548 \r
 549                 // apply player scale to the damage / force of the kick\r
 550                 if(cvar("g_healthsize") && cvar("g_balance_vore_kick_scalediff"))\r
 551                 {\r
 552                         damage *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 553                         force *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 554                         vol *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff")); // kick sound volume based on the same scale\r
 555                 }\r
 556                 vol = bound(0, vol, 1);\r
 557 \r
 558                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 559                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), vol, ATTN_NORM);\r
 560                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 561                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 562 \r
 563                 // abort the predator's scheduled regurgitation\r
 564                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 565                         self.predator.regurgitate_prepare = 0;\r
 566 \r
 567                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 568                 if(cvar("g_balance_vore_kick_repress"))\r
 569                 if not(clienttype(self) == CLIENTTYPE_BOT) // not for bots, to prevent an issue\r
 570                         self.kick_pressed = TRUE;\r
 571         }\r
 572 }\r
 573 \r
 574 void Vore_StomachLeave()\r
 575 {\r
 576         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 577 \r
 578         if(Vore_CanLeave())\r
 579                 Vore_Regurgitate(self);\r
 580         else if(time > self.complain_vore)\r
 581         {\r
 582                 play2(self, "misc/forbidden.wav");\r
 583                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 584                 self.complain_vore = time + complain_delay_time;\r
 585         }\r
 586 }\r
 587 \r
 588 void Vore_AutoTaunt()\r
 589 {\r
 590         // triggers ambient vore taunts, for both pred and prey\r
 591 \r
 592         float taunt_time;\r
 593 \r
 594         // predator taunts\r
 595         if(self.stomach_load && !Stomach_TeamMates_check(self))\r
 596         {\r
 597                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 598                 {\r
 599                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 600                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 601                 }\r
 602         }\r
 603         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 604         {\r
 605                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 606                 SetAutoTaunt(self, 0, 0);\r
 607         }\r
 608 \r
 609         // prey taunts\r
 610         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team))\r
 611         {\r
 612                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 613                 {\r
 614                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 615                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 616                 }\r
 617         }\r
 618         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 619         {\r
 620                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 621                 SetAutoTaunt(self, 0, 0);\r
 622         }\r
 623 }\r
 624 \r
 625 void Vore_SetSbarRings()\r
 626 {\r
 627         // first clear the ring stats, then configure them if needed\r
 628         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 629         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 630 \r
 631         if(self.stat_eaten)\r
 632         {\r
 633                 if(time <= self.stomachkick_delay)\r
 634                 {\r
 635                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 636                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 637                 }\r
 638         }\r
 639         else\r
 640         {\r
 641                 if(self.swallow_progress_pred)\r
 642                 {\r
 643                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 644                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 645                 }\r
 646                 else if(time <= self.action_delay)\r
 647                 {\r
 648                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 649                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 650                 }\r
 651 \r
 652                 if(self.swallow_progress_prey)\r
 653                 {\r
 654                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 655                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 656                 }\r
 657                 else if(time <= self.regurgitate_prepare)\r
 658                 {\r
 659                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 660                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 661                 }\r
 662         }\r
 663 }\r
 664 \r
 665 .float regurgitatecolor_particles_tick;\r
 666 void Vore()\r
 667 {\r
 668         // main vore code, this is where it all happens\r
 669 \r
 670         Vore_AutoTaunt();\r
 671 \r
 672         if(!self.stat_eaten)\r
 673         if(self.colormod)\r
 674         if(self.colormod != '1 1 1')\r
 675         {\r
 676                 // wash the goo away from players once they leave the stomach\r
 677                 if(stov(cvar_string("g_vore_regurgitatecolor_release")))\r
 678                 if(cvar("g_vore_regurgitatecolor_release_fade"))\r
 679                 {\r
 680                         self.colormod_x += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 681                         if(self.colormod_x > 1)\r
 682                                 self.colormod_x = 1;\r
 683                         self.colormod_y += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 684                         if(self.colormod_y > 1)\r
 685                                 self.colormod_y = 1;\r
 686                         self.colormod_z += cvar("g_vore_regurgitatecolor_release_fade") * frametime;\r
 687                         if(self.colormod_z > 1)\r
 688                                 self.colormod_z = 1;\r
 689                 }\r
 690 \r
 691                 // constant particles falling off dirty players\r
 692                 if(cvar("g_vore_regurgitatecolor_particles"))\r
 693                 if(self.regurgitatecolor_particles_tick < time)\r
 694                 {\r
 695                         pointparticles(particleeffectnum("vore_regurgitate_constant"), self.origin, '0 0 0', 1);\r
 696                         self.regurgitatecolor_particles_tick = time + cvar("g_vore_regurgitatecolor_particles") * vlen(self.colormod); // particle time depends on how dirty the player is\r
 697                 }\r
 698         }\r
 699 \r
 700         // set all vore stats\r
 701         Vore_SetSbarRings();\r
 702         if(self.fakepredator.classname == "player")\r
 703                 self.stat_eaten = num_for_edict(self.fakepredator);\r
 704         else if(self.predator.classname == "player")\r
 705         {\r
 706                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 707                 self.stat_stomachmaxload = self.predator.stomach_maxload; // necessary for the stomach board\r
 708                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 709                 self.stat_eaten = num_for_edict(self.predator);\r
 710         }\r
 711         else\r
 712         {\r
 713                 self.stat_stomachload = self.stomach_load;\r
 714                 self.stat_stomachmaxload = self.stomach_maxload;\r
 715                 self.stat_digesting = self.digesting;\r
 716                 self.stat_eaten = 0;\r
 717         }\r
 718         self.stat_canleave = Vore_CanLeave();\r
 719 \r
 720         // don't allow a player inside a player inside another player :)\r
 721         // prevent this by checking if such has happened, and taking the proper measures\r
 722         // this code has a high priority and must not be stopped by any delay, so run it here\r
 723         if(self.predator.stat_eaten)\r
 724         {\r
 725                 entity target_predator, target_predator_predator, oldself;\r
 726                 target_predator = self.predator;\r
 727                 target_predator_predator = self.predator.predator;\r
 728 \r
 729                 Vore_Regurgitate(self);\r
 730 \r
 731                 // now steal our prey's prey if this probability applies\r
 732                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 733                 {\r
 734                         oldself = self;\r
 735                         self = target_predator_predator;\r
 736                         if(Swallow_condition_check(oldself))\r
 737                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 738                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 739                                 Vore_Swallow(oldself);\r
 740                         self = oldself;\r
 741                 }\r
 742         }\r
 743 \r
 744         // the swallow progress of prey and preds idly decrease by this amount\r
 745         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 746         {\r
 747                 if(self.swallow_progress_pred)\r
 748                 {\r
 749                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 750                         if(self.swallow_progress_pred < 0)\r
 751                                 self.swallow_progress_pred = 0;\r
 752                 }\r
 753                 if(self.swallow_progress_prey)\r
 754                 {\r
 755                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 756                         if(self.swallow_progress_prey < 0)\r
 757                                 self.swallow_progress_prey = 0;\r
 758                 }\r
 759         }\r
 760 \r
 761         // set the predator's stomach load and capacity\r
 762         Vore_StomachLoad_Apply();\r
 763 \r
 764         // apply delays and skip the vore system under some circumstances\r
 765         if(!cvar("g_vore")) // the vore system is disabled\r
 766         {\r
 767                 Vore_Disconnect();\r
 768                 return;\r
 769         }\r
 770         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 771         {\r
 772                 Vore_Disconnect();\r
 773                 return;\r
 774         }\r
 775         if(self.spectatee_status)\r
 776                 return;\r
 777         if(time < self.system_delay)\r
 778                 return;\r
 779 \r
 780 // --------------------------------\r
 781 // Code that addresses predators:\r
 782 // --------------------------------\r
 783 \r
 784         entity prey;\r
 785         prey = Swallow_player_check();\r
 786 \r
 787         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 788         self.stat_canswallow = 0;\r
 789         if(Swallow_condition_check(prey))\r
 790         {\r
 791                 // canswallow stat, used by the HUD\r
 792                 if(teams_matter && prey.team == self.team)\r
 793                         self.stat_canswallow = 2;\r
 794                 else\r
 795                         self.stat_canswallow = 1;\r
 796 \r
 797                 if(self.BUTTON_ATCK)\r
 798                         Vore_SwallowStep(prey);\r
 799         }\r
 800         else if(prey != world)\r
 801                 self.stat_canswallow = -1;\r
 802 \r
 803         // toggle digestion, if the player has someone in their stomach\r
 804         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 805         {\r
 806                 if(self.stomach_load)\r
 807                 {\r
 808                         if(time > self.digest_button_delay_time)\r
 809                         {\r
 810                                 self.digesting = !self.digesting;\r
 811                                 self.digest_button_delay_time = time + button_delay_time;\r
 812                         }\r
 813                 }\r
 814                 else if(time > self.complain_vore)\r
 815                 {\r
 816                         play2(self, "misc/forbidden.wav");\r
 817                         sprint(self, "There is nothing to digest\n");\r
 818                         self.complain_vore = time + complain_delay_time;\r
 819                 }\r
 820         }\r
 821         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 822                 self.digesting = FALSE;\r
 823 \r
 824         // predator wishes to regurgitate his prey\r
 825         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 826         {\r
 827                 if(self.stomach_load)\r
 828                 {\r
 829                         if(time > self.regurgitate_button_delay_time)\r
 830                         {\r
 831                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 832                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 833                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE); // looks good for preparing regurgitation\r
 834                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 835                         }\r
 836                 }\r
 837                 else if(time > self.complain_vore)\r
 838                 {\r
 839                         play2(self, "misc/forbidden.wav");\r
 840                         sprint(self, "There is nothing to regurgitate\n");\r
 841                         self.complain_vore = time + complain_delay_time;\r
 842                 }\r
 843         }\r
 844 \r
 845         if(cvar("g_vore_gurglesound"))\r
 846                 Vore_GurgleSound();\r
 847 \r
 848 // --------------------------------\r
 849 // Code that addresses the prey:\r
 850 // --------------------------------\r
 851 \r
 852         if(!self.stat_eaten)\r
 853                 return;\r
 854 \r
 855         if(self.deadflag != DEAD_NO) // we're dead, do what we must\r
 856         {\r
 857                 Vore_PreyRelease(self, FALSE);\r
 858                 return;\r
 859         }\r
 860 \r
 861         if(self.fakeprey) // detach dead prey if their predator died or got eaten\r
 862         if(self.fakepredator.deadflag != DEAD_NO || self.fakepredator.stat_eaten)\r
 863                 Vore_DeadPrey_Detach(self);\r
 864         if(self.predator.deadflag != DEAD_NO) // do we want to be in a dead furry x_x\r
 865         {\r
 866                 Vore_Regurgitate(self);\r
 867                 return;\r
 868         }\r
 869         if(self.predator.stomach_load > self.predator.stomach_maxload) // the predator got beyond his capacity after eating, so some prey must pop out\r
 870         {\r
 871                 Vore_Regurgitate(self);\r
 872                 return;\r
 873         }\r
 874         if(cvar("g_balance_vore_load_pred_speedcap") && vlen(self.predator.velocity) >= cvar("g_balance_vore_load_pred_speedcap") / (self.predator.stomach_load / self.predator.stomach_maxload)) // predator's going too fast, gets sick and throws up\r
 875         {\r
 876                 Vore_Regurgitate(self);\r
 877                 return;\r
 878         }\r
 879 \r
 880         // apply delayed regurgitating if it was scheduled\r
 881         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 882         {\r
 883                 self.predator.regurgitate_prepare = 0;\r
 884                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 885                 Vore_Regurgitate(self);\r
 886         }\r
 887 \r
 888         // execute digesting and team healing\r
 889         if(self.predator.digesting == TRUE)\r
 890                 Vore_Digest();\r
 891         if(teams_matter && self.team == self.predator.team)\r
 892         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 893                 Vore_Teamheal();\r
 894 \r
 895         // execute prey commands\r
 896         if(self.BUTTON_ATCK)\r
 897         {\r
 898                 if(cvar("g_vore_kick"))\r
 899                         Vore_StomachKick();\r
 900         }\r
 901         else\r
 902                 self.kick_pressed = FALSE;\r
 903         if(self.BUTTON_JUMP)\r
 904                 Vore_StomachLeave();\r
 905 \r
 906         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 907         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 908         kh_Key_DropAll(self, FALSE);\r
 909 }