data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(cvar("g_healthsize")) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         makevectors(self.angles);\r
  22         vore_w_shotorg = self.origin;\r
  23         vore_w_shotdir = v_forward;\r
  24 \r
  25         if(self.antilag_debug)\r
  26                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, self.antilag_debug);\r
  27         else\r
  28                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  29         if(trace_fraction < 1)\r
  30         if(trace_ent.classname == "player")\r
  31                 return trace_ent;\r
  32         return world;\r
  33 }\r
  34 \r
  35 float Swallow_condition_check(entity prey)\r
  36 {\r
  37         // checks the necessary conditions for swallowing a player\r
  38 \r
  39         if(prey != self)\r
  40         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  41         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  42         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  43         {\r
  44                 float prey_mass;\r
  45                 prey_mass = cvar("g_balance_vore_load_prey_mass");\r
  46                 if(cvar("g_healthsize"))\r
  47                         prey_mass *= prey.scale;\r
  48 \r
  49                 string swallow_complain;\r
  50                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  51                         swallow_complain = "You cannot swallow your team mates\n";\r
  52                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  53                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  54                 else if(self.stomach_load + prey_mass > self.stomach_maxload)\r
  55                         swallow_complain = strcat("You don't have any room to swallow this player. Their mass is ^3", ftos(prey_mass), "^7 and your remaining capacity is ^3", ftos(self.stomach_maxload - self.stomach_load), "\n");\r
  56                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  57                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  58                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  59                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  60 \r
  61                 if(swallow_complain != "")\r
  62                 {\r
  63                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  64                         {\r
  65                                 play2(self, "misc/forbidden.wav");\r
  66                                 sprint(self, swallow_complain);\r
  67                                 self.complain_vore = time + complain_delay_time;\r
  68                         }\r
  69                         return FALSE;\r
  70                 }\r
  71                 return TRUE;\r
  72         }\r
  73         return FALSE;\r
  74 }\r
  75 \r
  76 float Stomach_TeamMates_check(entity pred)\r
  77 {\r
  78         // checks if a player's stomach contains any team mates\r
  79 \r
  80         entity head;\r
  81         if(teams_matter)\r
  82         {\r
  83                 FOR_EACH_PLAYER(head)\r
  84                 {\r
  85                         if(head.predator == pred && head.team == pred.team)\r
  86                                 return TRUE;\r
  87                 }\r
  88         }\r
  89         return FALSE;\r
  90 }\r
  91 \r
  92 float Stomach_HasLivePrey(entity pred)\r
  93 {\r
  94         entity head;\r
  95         FOR_EACH_PLAYER(head)\r
  96         {\r
  97                 if(head.predator == pred)\r
  98                 if(head.deadflag == DEAD_NO)\r
  99                         return TRUE;\r
 100         }\r
 101         return FALSE;\r
 102 }\r
 103 \r
 104 float Vore_CanLeave()\r
 105 {\r
 106         if(self.stat_eaten)\r
 107         {\r
 108                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
 109                         return TRUE;\r
 110                 if(teams_matter && self.team == self.predator.team)\r
 111                         return TRUE;\r
 112                 if(g_rpg && cvar("g_rpg_canleave"))\r
 113                         return TRUE;\r
 114         }\r
 115         return FALSE;\r
 116 }\r
 117 \r
 118 // position the camera properly for prey\r
 119 void Vore_SetPreyPositions(entity pred)\r
 120 {\r
 121         // pred is the predator and head is the prey\r
 122 \r
 123         local entity head;\r
 124         local vector origin_apply;\r
 125 \r
 126         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 127         // else all players overlap in the center. To do this, we use a random origin on all players in the same stomach.\r
 128         FOR_EACH_PLAYER(head)\r
 129         {\r
 130                 if(head.predator == pred)\r
 131                 {\r
 132                         origin_apply_x = PL_PREY_VIEW_OFS_x + crandom() * cvar("g_vore_neighborprey_distance");\r
 133                         origin_apply_y = PL_PREY_VIEW_OFS_y + crandom() * cvar("g_vore_neighborprey_distance");\r
 134                         origin_apply_z = PL_PREY_VIEW_OFS_z;\r
 135 \r
 136                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 137                         head.view_ofs = origin_apply;\r
 138                 }\r
 139         }\r
 140 }\r
 141 \r
 142 .float gurgle_oldstomachload;\r
 143 void Vore_GurgleSound()\r
 144 {\r
 145         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 146         {\r
 147                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 148 \r
 149                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 150                 self.gurgle_oldstomachload = self.stomach_load;\r
 151         }\r
 152 }\r
 153 \r
 154 void Vore_StomachLoad_Apply()\r
 155 {\r
 156         // apply stomach weight that makes you heavier and larger the more you eat\r
 157         // slowing the player is done in cl_physics.qc\r
 158 \r
 159         entity e;\r
 160         float prey_mass;\r
 161 \r
 162         // apply the stomach capacity of the predator\r
 163         self.stomach_maxload = cvar("g_balance_vore_load_pred_capacity");\r
 164         if(cvar("g_healthsize"))\r
 165                 self.stomach_maxload *= self.scale;\r
 166         self.stomach_maxload = floor(self.stomach_maxload);\r
 167 \r
 168         self.stomach_load = 0; // start from zero\r
 169         FOR_EACH_PLAYER(e)\r
 170         {\r
 171                 if(e.predator == self)\r
 172                 {\r
 173                         prey_mass = cvar("g_balance_vore_load_prey_mass");\r
 174                         if(cvar("g_healthsize"))\r
 175                                 prey_mass *= e.scale;\r
 176                         self.stomach_load += floor(prey_mass);\r
 177                 }\r
 178         }\r
 179 \r
 180         // apply weight\r
 181         self.gravity = 1 + (self.stomach_load / self.stomach_maxload) * cvar("g_balance_vore_load_pred_weight");\r
 182         if(!self.gravity && self.stomach_load)\r
 183                 self.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 184 }\r
 185 \r
 186 void Vore_AutoDigest(entity e)\r
 187 {\r
 188         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 189 \r
 190         if(!cvar("g_vore_digestion") || e.digesting)\r
 191                 return;\r
 192         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 193                 return; // this feature is only for players, not bots\r
 194         if(e.stomach_load > 1)\r
 195                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 196         if(Stomach_TeamMates_check(e))\r
 197                 return; // never begin automatic digestion if we've swallowed a team mate\r
 198 \r
 199         e.digesting = TRUE;\r
 200 }\r
 201 \r
 202 .entity swallow_model;\r
 203 float Vore_SwallowModel_CustomizeEntityForClient()\r
 204 {\r
 205         // use the same system as the weapon model\r
 206 \r
 207         self.viewmodelforclient = self.owner;\r
 208         self.alpha = self.owner.cvar_cl_vore_swallowmodel;\r
 209 \r
 210         if(other.classname == "spectator")\r
 211         if(other.enemy == self.owner)\r
 212         {\r
 213                 self.viewmodelforclient = other;\r
 214                 self.alpha = other.cvar_cl_vore_swallowmodel;\r
 215         }\r
 216 \r
 217         return TRUE;\r
 218 }\r
 219 \r
 220 void Vore_SwallowModel_Think()\r
 221 {\r
 222         // update the position of the swallow model to match our swallow progress\r
 223         float dist;\r
 224         dist = (-0.5 + self.owner.swallow_progress_prey) * cvar("g_vore_swallowmodel_range"); // the model is centered at 0.5 progress\r
 225         if(cvar("g_healthsize"))\r
 226                 dist *= self.scale;\r
 227         self.view_ofs = '1 0 0' * dist;\r
 228 \r
 229         // if our swallow progress is gone or we are dead, the swallow model also goes away\r
 230         if(!self.owner.swallow_progress_prey || self.owner.deadflag != DEAD_NO || self.owner.classname != "player")\r
 231         {\r
 232                 remove(self.owner.swallow_model);\r
 233                 self.owner.swallow_model = world;\r
 234                 return;\r
 235         }\r
 236 \r
 237         // properties that should update whenever possible, but when the predator is not available\r
 238         self.nextthink = time;\r
 239 }\r
 240 \r
 241 void Vore_SwallowModel_Update(entity prey, entity pred)\r
 242 {\r
 243         // if we don't have a swallow model already, spawn one\r
 244         if(!prey.swallow_model)\r
 245         {\r
 246                 prey.swallow_model = spawn();\r
 247                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 248                 prey.swallow_model.solid = SOLID_NOT;\r
 249                 //prey.swallow_model.effects |= EF_NOGUNBOB; // let it bob\r
 250                 prey.swallow_model.effects |= EF_NODEPTHTEST; // don't hide behind walls\r
 251                 prey.swallow_model.owner = prey;\r
 252                 prey.swallow_model.customizeentityforclient = Vore_SwallowModel_CustomizeEntityForClient;\r
 253                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
 254                 prey.swallow_model.nextthink = time;\r
 255         }\r
 256 \r
 257         // properties that should update whenever possible, but when the predator is available\r
 258         string player_swallowmodel;\r
 259         player_swallowmodel = strcat(substring(pred.playermodel, 0, strlen(pred.playermodel) - 4), "_swallow.md3"); // 4 is the extension length\r
 260         if(prey.swallow_model.model != player_swallowmodel) // player model can be changed while the predator is active\r
 261                 setmodel(prey.swallow_model, player_swallowmodel);\r
 262         if(prey.swallow_model.skin != pred.skin) // player skin can be changed while the predator is active\r
 263                 prey.swallow_model.skin = pred.skin;\r
 264         if(cvar("g_healthsize"))\r
 265                 prey.swallow_model.scale = pred.scale / prey.scale; // player size difference\r
 266         if(prey.swallow_model.enemy != pred)\r
 267                 prey.swallow_model.enemy = pred; // enemy is the predator\r
 268         if(prey.swallow_model.colormap != pred.colormap)\r
 269                 prey.swallow_model.colormap = pred.colormap; // pants and shirt color\r
 270         if(prey.swallow_model.glowmod != pred.glowmod)\r
 271                 prey.swallow_model.glowmod = pred.glowmod; // glow color\r
 272 }\r
 273 \r
 274 .entity pusher;\r
 275 .float pushltime;\r
 276 void Vore_Swallow(entity e)\r
 277 {\r
 278         // this player is being swallowed by another player, apply the proper changes\r
 279 \r
 280         e.vore_oldmovetype = e.movetype;\r
 281         e.vore_oldsolid = e.solid;\r
 282 \r
 283         e.predator = self;\r
 284         setorigin(e, e.predator.origin);\r
 285         e.velocity = '0 0 0';\r
 286         e.movetype = MOVETYPE_FOLLOW;\r
 287         e.solid = SOLID_NOT;\r
 288         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 289 \r
 290         // drop keys (KH) and flags (CTF) when we get swallowed\r
 291         kh_Key_DropAll(e, FALSE);\r
 292         if(e.flagcarried)\r
 293                 DropFlag(e.flagcarried, world, e.predator);\r
 294 \r
 295         if(stov(cvar_string("g_vore_regurgitatecolor_color_normal")))\r
 296                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_normal"));\r
 297 \r
 298         if(teams_matter && e.team == e.predator.team)\r
 299         {\r
 300                 if(cvar("g_vore_kick"))\r
 301                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 302                 if(cvar("g_vore_digestion"))\r
 303                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 304         }\r
 305 \r
 306         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 307         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 308         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 309         e.predator.regurgitate_prepare = 0;\r
 310         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 311         e.predator.hitsound += 1; // play this for team mates too, as we could be swallowing them to heal them\r
 312         Vore_AutoDigest(e.predator);\r
 313         Vore_SetPreyPositions(e.predator);\r
 314 \r
 315         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 316         e.predator.weapon_delay = time + button_delay_time;\r
 317         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 318         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 319         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 320 }\r
 321 \r
 322 void Vore_SwallowStep(entity e)\r
 323 {\r
 324         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 325         {\r
 326                 Vore_Swallow(e);\r
 327                 return;\r
 328         }\r
 329 \r
 330         Vore_SwallowModel_Update(e, self);\r
 331 \r
 332         // increase the progress value until it reaches 1, then swallow the player\r
 333         if(e.swallow_progress_prey < 1)\r
 334         {\r
 335                 float fill;\r
 336                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 337                 if(cvar("g_healthsize") && cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 338                         fill *= pow(self.scale / e.scale, cvar("g_balance_vore_swallow_speed_fill_scalediff"));\r
 339                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 340                         fill /= e.stomach_load;\r
 341 \r
 342                 e.swallow_progress_prey += fill;\r
 343         }\r
 344         else\r
 345         {\r
 346                 Vore_Swallow(e);\r
 347                 e.swallow_progress_prey = 0;\r
 348         }\r
 349 \r
 350         // the predator's progress is how much the prey got swallowed\r
 351         self.swallow_progress_pred = e.swallow_progress_prey;\r
 352 }\r
 353 \r
 354 void Vore_Regurgitate(entity e)\r
 355 {\r
 356         // this player is being regurgitated by their predator, apply the proper changes\r
 357 \r
 358         e.movetype = e.vore_oldmovetype;\r
 359         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 360                 e.solid = e.vore_oldsolid;\r
 361         e.view_ofs_z = PL_VIEW_OFS_z;\r
 362 \r
 363         // if the prey has been fully digested, silently detach them\r
 364         if(e.deadflag != DEAD_NO && e.health <= cvar("g_balance_vore_digestion_limit"))\r
 365         {\r
 366                 e.predator = world;\r
 367                 e.modelindex = 0; // hide the dead body\r
 368                 return;\r
 369         }\r
 370 \r
 371         // apply velocities\r
 372         local vector oldforward, oldright, oldup;\r
 373         oldforward = v_forward;\r
 374         oldright = v_right;\r
 375         oldup = v_up;\r
 376         makevectors(e.predator.v_angle);\r
 377         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 378         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 379         v_forward = oldforward;\r
 380         v_right = oldright;\r
 381         v_up = oldup;\r
 382 \r
 383         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 384         e.pushltime = time + cvar("g_maxpushtime");\r
 385 \r
 386         // if the dead body of the prey is below gibbing health, gib it\r
 387         e.stat_eaten = 0; // necessary for gibs to show\r
 388         PlayerGib(e, e.predator);\r
 389 \r
 390         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 391         if(cvar("g_balance_vore_swallow_speed_fill") && cvar("g_balance_vore_regurgitate_swallowprogress"))\r
 392         {\r
 393                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 394                 Vore_SwallowModel_Update(e, e.predator);\r
 395         }\r
 396 \r
 397         // apply regurgitation damage to the predator\r
 398         if(cvar("g_balance_vore_regurgitate_damage"))\r
 399         {\r
 400                 float regurgitate_dmg;\r
 401                 regurgitate_dmg = cvar("g_balance_vore_regurgitate_damage");\r
 402                 if(cvar("g_healthsize"))\r
 403                         regurgitate_dmg *= e.scale / e.predator.scale;\r
 404                 Damage(e.predator, e, e, regurgitate_dmg, DEATH_REGURGITATION, e.predator.origin, '0 0 0');\r
 405         }\r
 406 \r
 407         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 408         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 409         pointparticles(particleeffectnum("vore_regurgitate"), e.predator.origin, '0 0 0', 1);\r
 410         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 411         e.predator.regurgitate_prepare = 0;\r
 412         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 413         Vore_SetPreyPositions(e.predator);\r
 414 \r
 415         // block firing for a small amount of time, or we'll be firing the next frame\r
 416         e.weapon_delay = time + button_delay_time;\r
 417         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 418         e.predator = world;\r
 419 }\r
 420 \r
 421 void Vore_Disconnect()\r
 422 {\r
 423         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 424 \r
 425         // prey disconnects or goes spectating while inside someone's belly\r
 426         if(self.stat_eaten)\r
 427                 Vore_Regurgitate(self);\r
 428 \r
 429         // pred disconnects or goes spectating with players in their belly\r
 430         entity head;\r
 431         FOR_EACH_PLAYER(head)\r
 432         {\r
 433                 if(head.predator == self)\r
 434                         Vore_Regurgitate(head);\r
 435         }\r
 436         Vore_GurgleSound(); // stop the gurgling sound\r
 437 \r
 438         self.stomach_load = self.gravity = 0; // prevents a bug\r
 439 }\r
 440 \r
 441 .float digestion_step;\r
 442 void Vore_Digest()\r
 443 {\r
 444         // apply digestion to prey\r
 445 \r
 446         if(self.predator.deadflag != DEAD_NO) // dead predators don't digest\r
 447         {\r
 448                 self.predator.digesting = FALSE;\r
 449                 return;\r
 450         }\r
 451         if(self.health <= cvar("g_balance_vore_digestion_limit")) // don't digest below this amount of health\r
 452                 return;\r
 453 \r
 454         if(time > self.digestion_step)\r
 455         {\r
 456                 // if distributed digestion is enabled, reduce digestion strength by the amount of prey in our stomach\r
 457                 float damage, damage_offset;\r
 458 \r
 459                 damage_offset = 1;\r
 460                 if(cvar("g_balance_vore_digestion_distribute")) // apply distributed digestion damage\r
 461                         damage_offset *= self.predator.stomach_load / self.predator.stomach_maxload;\r
 462                 if(cvar("g_healthsize") && cvar("g_balance_vore_digestion_scalediff")) // apply player scale to digestion damage\r
 463                         damage_offset *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_digestion_scalediff"));\r
 464                 damage_offset = ceil(damage_offset);\r
 465 \r
 466                 damage = cvar("g_balance_vore_digestion_damage") / damage_offset;\r
 467                 if(cvar("g_balance_vore_digestion_damage_death") && self.deadflag != DEAD_NO) // amplify digestion damage for dead prey\r
 468                         damage *= cvar("g_balance_vore_digestion_damage_death");\r
 469 \r
 470                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 471                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 472                         self.predator.health += damage * cvar("g_balance_vore_digestion_vampire");\r
 473 \r
 474                 if (self.predator.digestsound_finished < time)\r
 475                 {\r
 476                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 477                         self.predator.digestsound_finished = time + 0.5;\r
 478                 }\r
 479                 self.digestion_step = time + steptime;\r
 480         }\r
 481 \r
 482         if(stov(cvar_string("g_vore_regurgitatecolor_color_digest")))\r
 483                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_digest"));\r
 484 }\r
 485 \r
 486 .float teamheal_step;\r
 487 void Vore_Teamheal()\r
 488 {\r
 489         // apply teamheal\r
 490 \r
 491         if(self.deadflag != DEAD_NO)\r
 492                 return;\r
 493 \r
 494         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 495         if(time > self.teamheal_step)\r
 496         {\r
 497                 self.health += cvar("g_balance_vore_teamheal");\r
 498                 self.teamheal_step = time + steptime;\r
 499 \r
 500                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 501                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 502                 {\r
 503                         play2(self, "misc/beep.wav");\r
 504                         play2(self.predator, "misc/beep.wav");\r
 505                 }\r
 506         }\r
 507 }\r
 508 \r
 509 .float kick_pressed;\r
 510 void Vore_StomachKick()\r
 511 {\r
 512         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 513 \r
 514         if(self.deadflag != DEAD_NO)\r
 515                 return;\r
 516 \r
 517         if(time > self.stomachkick_delay && !self.kick_pressed)\r
 518         {\r
 519                 float damage, vol;\r
 520                 vector force;\r
 521                 damage = cvar("g_balance_vore_kick_damage");\r
 522                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 523                 vol = VOL_BASE;\r
 524 \r
 525                 // apply player scale to the damage / force of the kick\r
 526                 if(cvar("g_healthsize") && cvar("g_balance_vore_kick_scalediff"))\r
 527                 {\r
 528                         damage *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 529                         force *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 530                         vol *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff")); // kick sound volume based on the same scale\r
 531                 }\r
 532                 vol = bound(0, vol, 1);\r
 533 \r
 534                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 535                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), vol, ATTN_NORM);\r
 536                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 537                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 538 \r
 539                 // abort the predator's scheduled regurgitation\r
 540                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 541                         self.predator.regurgitate_prepare = 0;\r
 542 \r
 543                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 544                 if(cvar("g_balance_vore_kick_repress"))\r
 545                 if not(clienttype(self) == CLIENTTYPE_BOT) // not for bots, to prevent an issue\r
 546                         self.kick_pressed = TRUE;\r
 547         }\r
 548 }\r
 549 \r
 550 void Vore_StomachLeave()\r
 551 {\r
 552         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 553 \r
 554         if(self.deadflag != DEAD_NO)\r
 555                 return;\r
 556 \r
 557         if(Vore_CanLeave())\r
 558                 Vore_Regurgitate(self);\r
 559         else if(time > self.complain_vore)\r
 560         {\r
 561                 play2(self, "misc/forbidden.wav");\r
 562                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 563                 self.complain_vore = time + complain_delay_time;\r
 564         }\r
 565 }\r
 566 \r
 567 void Vore_AutoTaunt()\r
 568 {\r
 569         // triggers ambient vore taunts, for both pred and prey\r
 570 \r
 571         float taunt_time;\r
 572 \r
 573         // predator taunts\r
 574         if(self.stomach_load && !Stomach_TeamMates_check(self) && Stomach_HasLivePrey(self))\r
 575         {\r
 576                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 577                 {\r
 578                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 579                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 580                 }\r
 581         }\r
 582         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 583         {\r
 584                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 585                 SetAutoTaunt(self, 0, 0);\r
 586         }\r
 587 \r
 588         // prey taunts\r
 589         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team) && self.deadflag == DEAD_NO)\r
 590         {\r
 591                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 592                 {\r
 593                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 594                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 595                 }\r
 596         }\r
 597         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 598         {\r
 599                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 600                 SetAutoTaunt(self, 0, 0);\r
 601         }\r
 602 }\r
 603 \r
 604 void Vore_SetSbarRings()\r
 605 {\r
 606         // first clear the ring stats, then configure them if needed\r
 607         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 608         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 609 \r
 610         if(self.stat_eaten)\r
 611         {\r
 612                 if(time <= self.stomachkick_delay)\r
 613                 {\r
 614                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 615                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 616                 }\r
 617         }\r
 618         else\r
 619         {\r
 620                 if(self.swallow_progress_pred)\r
 621                 {\r
 622                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 623                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 624                 }\r
 625                 else if(time <= self.action_delay)\r
 626                 {\r
 627                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 628                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 629                 }\r
 630 \r
 631                 if(self.swallow_progress_prey)\r
 632                 {\r
 633                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 634                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 635                 }\r
 636                 else if(time <= self.regurgitate_prepare)\r
 637                 {\r
 638                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 639                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 640                 }\r
 641         }\r
 642 }\r
 643 \r
 644 .float regurgitatecolor_particles_tick;\r
 645 void Vore()\r
 646 {\r
 647         // main vore code, this is where it all happens\r
 648 \r
 649         Vore_AutoTaunt();\r
 650 \r
 651         if(!self.stat_eaten)\r
 652         if(self.modelindex) // not if we're a gibbed dead body or not visible any more\r
 653         if(self.colormod)\r
 654         if(self.colormod != '1 1 1')\r
 655         {\r
 656                 // slowly wash stomach fluids off players once they're out of the stomach\r
 657                 if(cvar("g_vore_regurgitatecolor_fade"))\r
 658                 if(self.deadflag == DEAD_NO) // not for dead bodies\r
 659                 {\r
 660                         float goo_fade;\r
 661                         goo_fade = cvar("g_vore_regurgitatecolor_fade") * frametime;\r
 662                         goo_fade *= 1 + self.waterlevel; // fade faster when underwater\r
 663 \r
 664                         self.colormod_x += goo_fade;\r
 665                         if(self.colormod_x > 1)\r
 666                                 self.colormod_x = 1;\r
 667                         self.colormod_y += goo_fade;\r
 668                         if(self.colormod_y > 1)\r
 669                                 self.colormod_y = 1;\r
 670                         self.colormod_z += goo_fade;\r
 671                         if(self.colormod_z > 1)\r
 672                                 self.colormod_z = 1;\r
 673                 }\r
 674 \r
 675                 // constant particles falling off dirty players\r
 676                 if(cvar("g_vore_regurgitatecolor_particles"))\r
 677                 if(self.regurgitatecolor_particles_tick < time)\r
 678                 {\r
 679                         pointparticles(particleeffectnum("vore_regurgitate_constant"), self.origin, '0 0 0', 1);\r
 680                         self.regurgitatecolor_particles_tick = time + cvar("g_vore_regurgitatecolor_particles") * vlen(self.colormod); // particle time depends on how dirty the player is\r
 681                 }\r
 682         }\r
 683 \r
 684         // set all vore stats\r
 685         Vore_SetSbarRings();\r
 686         if(self.predator.classname == "player")\r
 687         {\r
 688                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 689                 self.stat_stomachmaxload = self.predator.stomach_maxload; // necessary for the stomach board\r
 690                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 691                 self.stat_eaten = num_for_edict(self.predator);\r
 692         }\r
 693         else\r
 694         {\r
 695                 self.stat_stomachload = self.stomach_load;\r
 696                 self.stat_stomachmaxload = self.stomach_maxload;\r
 697                 self.stat_digesting = self.digesting;\r
 698                 self.stat_eaten = 0;\r
 699         }\r
 700         self.stat_canleave = Vore_CanLeave();\r
 701 \r
 702         // don't allow a player inside a player inside another player :)\r
 703         // prevent this by checking if such has happened, and taking the proper measures\r
 704         // this code has a high priority and must not be stopped by any delay, so run it here\r
 705         if(self.predator.stat_eaten)\r
 706         {\r
 707                 entity target_predator, target_predator_predator, oldself;\r
 708                 target_predator = self.predator;\r
 709                 target_predator_predator = self.predator.predator;\r
 710 \r
 711                 Vore_Regurgitate(self);\r
 712 \r
 713                 // now steal our prey's prey if this probability applies\r
 714                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 715                 {\r
 716                         oldself = self;\r
 717                         self = target_predator_predator;\r
 718                         if(Swallow_condition_check(oldself))\r
 719                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 720                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 721                                 Vore_Swallow(oldself);\r
 722                         self = oldself;\r
 723                 }\r
 724         }\r
 725 \r
 726         // the swallow progress of prey and preds idly decrease by this amount\r
 727         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 728         {\r
 729                 if(self.swallow_progress_pred)\r
 730                 {\r
 731                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 732                         if(self.swallow_progress_pred < 0)\r
 733                                 self.swallow_progress_pred = 0;\r
 734                 }\r
 735                 if(self.swallow_progress_prey)\r
 736                 {\r
 737                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 738                         if(self.swallow_progress_prey < 0)\r
 739                                 self.swallow_progress_prey = 0;\r
 740                 }\r
 741         }\r
 742 \r
 743         // set the predator's stomach load and capacity\r
 744         Vore_StomachLoad_Apply();\r
 745 \r
 746         // apply delays and skip the vore system under some circumstances\r
 747         if(!cvar("g_vore")) // the vore system is disabled\r
 748         {\r
 749                 Vore_Disconnect();\r
 750                 return;\r
 751         }\r
 752         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 753         {\r
 754                 Vore_Disconnect();\r
 755                 return;\r
 756         }\r
 757         if(self.spectatee_status)\r
 758                 return;\r
 759         if(time < self.system_delay)\r
 760                 return;\r
 761 \r
 762 // --------------------------------\r
 763 // Code that addresses predators:\r
 764 // --------------------------------\r
 765 \r
 766         entity prey;\r
 767         prey = Swallow_player_check();\r
 768 \r
 769         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 770         self.stat_canswallow = 0;\r
 771         if(Swallow_condition_check(prey))\r
 772         {\r
 773                 // canswallow stat, used by the HUD\r
 774                 if(teams_matter && prey.team == self.team)\r
 775                         self.stat_canswallow = 2;\r
 776                 else\r
 777                         self.stat_canswallow = 1;\r
 778 \r
 779                 if(self.BUTTON_ATCK)\r
 780                         Vore_SwallowStep(prey);\r
 781         }\r
 782         else if(prey != world)\r
 783                 self.stat_canswallow = -1;\r
 784 \r
 785         // toggle digestion, if the player has someone in their stomach\r
 786         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 787         {\r
 788                 if(self.stomach_load)\r
 789                 {\r
 790                         if(time > self.digest_button_delay_time)\r
 791                         {\r
 792                                 self.digesting = !self.digesting;\r
 793                                 self.digest_button_delay_time = time + button_delay_time;\r
 794                         }\r
 795                 }\r
 796                 else if(time > self.complain_vore)\r
 797                 {\r
 798                         play2(self, "misc/forbidden.wav");\r
 799                         sprint(self, "There is nothing to digest\n");\r
 800                         self.complain_vore = time + complain_delay_time;\r
 801                 }\r
 802         }\r
 803         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 804                 self.digesting = FALSE;\r
 805 \r
 806         // predator wishes to regurgitate his prey\r
 807         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 808         {\r
 809                 if(self.stomach_load)\r
 810                 {\r
 811                         if(time > self.regurgitate_button_delay_time)\r
 812                         {\r
 813                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 814                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 815                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE); // looks good for preparing regurgitation\r
 816                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 817                         }\r
 818                 }\r
 819                 else if(time > self.complain_vore)\r
 820                 {\r
 821                         play2(self, "misc/forbidden.wav");\r
 822                         sprint(self, "There is nothing to regurgitate\n");\r
 823                         self.complain_vore = time + complain_delay_time;\r
 824                 }\r
 825         }\r
 826 \r
 827         if(cvar("g_vore_gurglesound"))\r
 828                 Vore_GurgleSound();\r
 829 \r
 830 // --------------------------------\r
 831 // Code that addresses the prey:\r
 832 // --------------------------------\r
 833 \r
 834         if(!self.stat_eaten)\r
 835                 return;\r
 836 \r
 837         if(self.deadflag != DEAD_NO && self.health < cvar("g_balance_vore_digestion_limit")) // make sure health doesn't go below the limit\r
 838                 self.health = cvar("g_balance_vore_digestion_limit");\r
 839 \r
 840         // automatically regurgitate prey that has reached their digestion limit\r
 841         if(cvar("g_balance_vore_digestion_limit_regurgitate"))\r
 842         if(self.health <= cvar("g_balance_vore_digestion_limit"))\r
 843         {\r
 844                 Vore_Regurgitate(self);\r
 845                 return;\r
 846         }\r
 847 \r
 848         // do we stick around inside dead furries? x_x\r
 849         if(self.predator.deadflag != DEAD_NO)\r
 850         {\r
 851                 if(!cvar("g_balance_vore_deadpredator") || !self.predator.modelindex) // if the predator is gibbed, we are out\r
 852                 {\r
 853                         Vore_Regurgitate(self);\r
 854                         return;\r
 855                 }\r
 856                 if(self.predator.regurgitate_prepare) // abort scheduled regurgitation\r
 857                         self.predator.regurgitate_prepare = 0;\r
 858         }\r
 859 \r
 860         if(self.predator.stomach_load > self.predator.stomach_maxload) // the predator got beyond his capacity after eating, so some prey must pop out\r
 861         {\r
 862                 Vore_Regurgitate(self);\r
 863                 return;\r
 864         }\r
 865         if(cvar("g_balance_vore_load_pred_speedcap") && vlen(self.predator.velocity) >= cvar("g_balance_vore_load_pred_speedcap") / (self.predator.stomach_load / self.predator.stomach_maxload)) // predator's going too fast, gets sick and throws up\r
 866         {\r
 867                 Vore_Regurgitate(self);\r
 868                 return;\r
 869         }\r
 870 \r
 871         // apply delayed regurgitating if it was scheduled\r
 872         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 873         {\r
 874                 self.predator.regurgitate_prepare = 0;\r
 875                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 876                 Vore_Regurgitate(self);\r
 877         }\r
 878 \r
 879         // execute digesting and team healing\r
 880         if(self.predator.digesting == TRUE)\r
 881                 Vore_Digest();\r
 882         if(teams_matter && self.team == self.predator.team)\r
 883         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 884                 Vore_Teamheal();\r
 885 \r
 886         // execute prey commands\r
 887         if(self.BUTTON_ATCK)\r
 888         {\r
 889                 if(cvar("g_vore_kick"))\r
 890                         Vore_StomachKick();\r
 891         }\r
 892         else\r
 893                 self.kick_pressed = FALSE;\r
 894         if(self.BUTTON_JUMP)\r
 895                 Vore_StomachLeave();\r
 896 \r
 897         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 898         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 899         kh_Key_DropAll(self, FALSE);\r
 900 }