data/qcsrc/server/vore.qc

   1 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   2 .float complain_vore;\r
   3 .float vore_oldmovetype, vore_oldsolid;\r
   4 \r
   5 const float system_delay_time = 0.1;\r
   6 const float complain_delay_time = 1;\r
   7 const float button_delay_time = 0.5;\r
   8 \r
   9 entity Swallow_player_check()\r
  10 {\r
  11         // check if we can swallow a player instead of firing our weapon\r
  12 \r
  13         float swallow_range;\r
  14         vector vore_w_shotorg, vore_w_shotdir;\r
  15 \r
  16         swallow_range = cvar("g_balance_vore_swallow_range");\r
  17         if(cvar("g_healthsize")) // we can swallow from further or closer based on our size\r
  18                 swallow_range *= self.scale;\r
  19         makevectors(self.angles);\r
  20         vore_w_shotorg = self.origin;\r
  21         vore_w_shotdir = v_forward;\r
  22 \r
  23         if(self.antilag_debug)\r
  24                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, self.antilag_debug);\r
  25         else\r
  26                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  27         if(trace_fraction < 1)\r
  28         if(trace_ent.classname == "player")\r
  29                 return trace_ent;\r
  30         return world;\r
  31 }\r
  32 \r
  33 float Swallow_condition_check(entity prey)\r
  34 {\r
  35         // checks the necessary conditions for swallowing a player\r
  36 \r
  37         if(prey != self)\r
  38         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  39         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  40         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  41         {\r
  42                 float prey_mass;\r
  43                 prey_mass = cvar("g_balance_vore_load_prey_mass");\r
  44                 if(cvar("g_healthsize"))\r
  45                         prey_mass *= prey.scale;\r
  46 \r
  47                 string swallow_complain;\r
  48                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  49                         swallow_complain = "You cannot swallow your team mates\n";\r
  50                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  51                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  52                 else if(self.stomach_load + prey_mass > self.stomach_maxload)\r
  53                         swallow_complain = strcat("You don't have any room to swallow this player. Their mass is ^3", ftos(prey_mass), "^7 and your remaining capacity is ^3", ftos(self.stomach_maxload - self.stomach_load), "\n");\r
  54                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  55                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  56                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  57                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  58 \r
  59                 if(swallow_complain != "")\r
  60                 {\r
  61                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  62                         {\r
  63                                 play2(self, "misc/forbidden.wav");\r
  64                                 sprint(self, swallow_complain);\r
  65                                 self.complain_vore = time + complain_delay_time;\r
  66                         }\r
  67                         return FALSE;\r
  68                 }\r
  69                 return TRUE;\r
  70         }\r
  71         return FALSE;\r
  72 }\r
  73 \r
  74 float Stomach_TeamMates_check(entity pred)\r
  75 {\r
  76         // checks if a player's stomach contains any team mates\r
  77 \r
  78         entity head;\r
  79         if(teams_matter)\r
  80         {\r
  81                 FOR_EACH_PLAYER(head)\r
  82                 {\r
  83                         if(head.predator == pred && head.team == pred.team)\r
  84                                 return TRUE;\r
  85                 }\r
  86         }\r
  87         return FALSE;\r
  88 }\r
  89 \r
  90 float Stomach_HasLivePrey(entity pred)\r
  91 {\r
  92         entity head;\r
  93         FOR_EACH_PLAYER(head)\r
  94         {\r
  95                 if(head.predator == pred)\r
  96                 if(head.deadflag == DEAD_NO)\r
  97                         return TRUE;\r
  98         }\r
  99         return FALSE;\r
 100 }\r
 101 \r
 102 float Vore_CanLeave()\r
 103 {\r
 104         if(self.stat_eaten)\r
 105         {\r
 106                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
 107                         return TRUE;\r
 108                 if(teams_matter && self.team == self.predator.team)\r
 109                         return TRUE;\r
 110                 if(g_rpg && cvar("g_rpg_canleave"))\r
 111                         return TRUE;\r
 112         }\r
 113         return FALSE;\r
 114 }\r
 115 \r
 116 // position the camera properly for prey\r
 117 void Vore_SetPreyPositions(entity pred)\r
 118 {\r
 119         // pred is the predator and head is the prey\r
 120 \r
 121         local entity head;\r
 122 \r
 123         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 124         // else all players overlap in the center. To do this, we use a random origin on all players in the same stomach.\r
 125         FOR_EACH_PLAYER(head)\r
 126         {\r
 127                 if(head.predator == pred)\r
 128                 {\r
 129                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 130                         head.view_ofs_x = PL_PREY_VIEW_OFS_x + crandom() * cvar("g_vore_neighborprey_distance");\r
 131                         head.view_ofs_y = PL_PREY_VIEW_OFS_y + crandom() * cvar("g_vore_neighborprey_distance");\r
 132                         head.view_ofs_z = PL_PREY_VIEW_OFS_z;\r
 133                 }\r
 134         }\r
 135 }\r
 136 \r
 137 .float gurgle_oldstomachload;\r
 138 void Vore_GurgleSound()\r
 139 {\r
 140         if(time > self.gurglesound_finished || (self.gurgle_oldstomachload != self.stomach_load && !self.digesting))\r
 141         {\r
 142                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE, VOL_BASE);\r
 143 \r
 144                 // yes, hard coded sound length. I know it's bad but what can I do?\r
 145                 if(cvar("g_healthsize") && cvar("g_healthsize_pitch"))\r
 146                         self.gurglesound_finished = time + 11 * pow(self.scale, -cvar("g_healthsize_pitch")); // modified sound pitch, based on player scale\r
 147                 else\r
 148                         self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 149 \r
 150                 self.gurgle_oldstomachload = self.stomach_load;\r
 151         }\r
 152 }\r
 153 \r
 154 void Vore_AutoDigest(entity e)\r
 155 {\r
 156         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 157 \r
 158         if(!cvar("g_vore_digestion") || e.digesting)\r
 159                 return;\r
 160         if(clienttype(e) != CLIENTTYPE_REAL)\r
 161                 return; // this feature is only for players, not bots\r
 162         if(e.stomach_load)\r
 163                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 164         if(Stomach_TeamMates_check(e))\r
 165                 return; // never begin automatic digestion if we've swallowed a team mate\r
 166 \r
 167         e.digesting = TRUE;\r
 168 }\r
 169 \r
 170 void Vore_StomachLoad_Apply()\r
 171 {\r
 172         // apply stomach weight that makes you heavier and larger the more you eat\r
 173         // slowing the player is done in cl_physics.qc\r
 174         if(self.classname != "player")\r
 175                 return;\r
 176 \r
 177         entity e;\r
 178         float prey_mass, final_load;\r
 179 \r
 180         // apply the stomach capacity of the predator\r
 181         self.stomach_maxload = cvar("g_balance_vore_load_pred_capacity");\r
 182         if(cvar("g_healthsize"))\r
 183                 self.stomach_maxload *= self.scale;\r
 184         self.stomach_maxload = ceil(self.stomach_maxload);\r
 185 \r
 186         FOR_EACH_PLAYER(e)\r
 187         {\r
 188                 if(e.predator == self)\r
 189                 {\r
 190                         prey_mass = cvar("g_balance_vore_load_prey_mass");\r
 191                         if(cvar("g_healthsize"))\r
 192                                 prey_mass *= e.scale;\r
 193                         final_load += ceil(prey_mass);\r
 194                         if(self.cvar_cl_vore_autodigest > 1)\r
 195                                 Vore_AutoDigest(self);\r
 196                 }\r
 197         }\r
 198         for(e = world; (e = find(e, classname, "consumable")); )\r
 199         {\r
 200                 if(e.predator == self)\r
 201                 {\r
 202                         final_load += ceil(e.dmg);\r
 203                         if(self.cvar_cl_vore_autodigest > 0)\r
 204                                 Vore_AutoDigest(self);\r
 205                 }\r
 206         }\r
 207         self.stomach_load = final_load;\r
 208 \r
 209         // apply weight\r
 210         self.gravity = 1 + (self.stomach_load / self.stomach_maxload) * cvar("g_balance_vore_load_pred_weight");\r
 211         if(!self.gravity && self.stomach_load)\r
 212                 self.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 213 }\r
 214 \r
 215 .entity swallow_model;\r
 216 float Vore_SwallowModel_CustomizeEntityForClient()\r
 217 {\r
 218         // use the same system as the weapon model\r
 219 \r
 220         self.viewmodelforclient = self.owner;\r
 221         self.alpha = self.owner.cvar_cl_vore_swallowmodel;\r
 222 \r
 223         if(other.classname == "spectator")\r
 224         if(other.enemy == self.owner)\r
 225         {\r
 226                 self.viewmodelforclient = other;\r
 227                 self.alpha = other.cvar_cl_vore_swallowmodel;\r
 228         }\r
 229 \r
 230         return TRUE;\r
 231 }\r
 232 \r
 233 void Vore_SwallowModel_Think()\r
 234 {\r
 235         // update the position of the swallow model to match our swallow progress\r
 236         float dist;\r
 237         dist = (-0.5 + self.owner.swallow_progress_prey) * cvar("g_vore_swallowmodel_range"); // the model is centered at 0.5 progress\r
 238         if(cvar("g_healthsize"))\r
 239                 dist *= self.scale;\r
 240         self.view_ofs = '1 0 0' * dist;\r
 241 \r
 242         // if our swallow progress is gone or we are dead, the swallow model also goes away\r
 243         if(!self.owner.swallow_progress_prey || self.owner.deadflag != DEAD_NO || self.owner.classname != "player")\r
 244         {\r
 245                 remove(self.owner.swallow_model);\r
 246                 self.owner.swallow_model = world;\r
 247                 return;\r
 248         }\r
 249 \r
 250         // properties that should update whenever possible, but when the predator is not available\r
 251         self.nextthink = time;\r
 252 }\r
 253 \r
 254 void Vore_SwallowModel_Update(entity prey, entity pred)\r
 255 {\r
 256         // if we don't have a swallow model already, spawn one\r
 257         if(!prey.swallow_model)\r
 258         {\r
 259                 prey.swallow_model = spawn();\r
 260                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 261                 prey.swallow_model.solid = SOLID_NOT;\r
 262                 //prey.swallow_model.effects |= EF_NOGUNBOB; // let it bob\r
 263                 prey.swallow_model.effects |= EF_NODEPTHTEST; // don't hide behind walls\r
 264                 prey.swallow_model.owner = prey;\r
 265                 prey.swallow_model.customizeentityforclient = Vore_SwallowModel_CustomizeEntityForClient;\r
 266                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
 267                 prey.swallow_model.nextthink = time;\r
 268         }\r
 269 \r
 270         // properties that should update whenever possible, but when the predator is available\r
 271         string player_swallowmodel;\r
 272         player_swallowmodel = strcat(substring(pred.playermodel, 0, strlen(pred.playermodel) - 4), "_swallow.md3"); // 4 is the extension length\r
 273         if(prey.swallow_model.model != player_swallowmodel) // player model can be changed while the predator is active\r
 274                 setmodel(prey.swallow_model, player_swallowmodel);\r
 275         if(prey.swallow_model.skin != pred.skin) // player skin can be changed while the predator is active\r
 276                 prey.swallow_model.skin = pred.skin;\r
 277         if(cvar("g_healthsize"))\r
 278                 prey.swallow_model.scale = pred.scale / prey.scale; // player size difference\r
 279         if(prey.swallow_model.enemy != pred)\r
 280                 prey.swallow_model.enemy = pred; // enemy is the predator\r
 281         if(prey.swallow_model.colormap != pred.colormap)\r
 282                 prey.swallow_model.colormap = pred.colormap; // pants and shirt color\r
 283         if(prey.swallow_model.glowmod != pred.glowmod)\r
 284                 prey.swallow_model.glowmod = pred.glowmod; // glow color\r
 285 }\r
 286 \r
 287 .entity pusher;\r
 288 .float pushltime;\r
 289 void Vore_Swallow(entity e)\r
 290 {\r
 291         // this player is being swallowed by another player, apply the proper changes\r
 292 \r
 293         e.vore_oldmovetype = e.movetype;\r
 294         e.vore_oldsolid = e.solid;\r
 295         e.punchvector_z = cvar("g_balance_vore_swallow_prey_punchvector");\r
 296 \r
 297         e.predator = self;\r
 298         setorigin(e, e.predator.origin);\r
 299         e.velocity = '0 0 0';\r
 300         e.movetype = MOVETYPE_FOLLOW;\r
 301         e.solid = SOLID_NOT;\r
 302         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 303 \r
 304         float scalediff;\r
 305         scalediff = cvar("g_healthsize") ? e.scale / e.predator.scale : 1; // the tighter the gut, the greater the effect\r
 306 \r
 307         // drop keys (KH) and flags (CTF) when we get swallowed\r
 308         kh_Key_DropAll(e, FALSE);\r
 309         if(e.flagcarried)\r
 310                 DropFlag(e.flagcarried, world, e.predator);\r
 311 \r
 312         if(stov(cvar_string("g_vore_regurgitatecolor_color_normal")))\r
 313                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_normal"));\r
 314 \r
 315         if(teams_matter && e.team == e.predator.team)\r
 316         {\r
 317                 if(cvar("g_vore_kick"))\r
 318                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 319                 if(cvar("g_vore_digestion"))\r
 320                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 321         }\r
 322 \r
 323         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 324         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 325         e.predator.punchangle_x = crandom() * cvar("g_balance_vore_swallow_predator_punchangle") * scalediff;\r
 326         e.predator.punchangle_y = crandom() * cvar("g_balance_vore_swallow_predator_punchangle") * scalediff;\r
 327         e.predator.punchangle_z = crandom() * cvar("g_balance_vore_swallow_predator_punchangle") * scalediff;\r
 328         e.predator.regurgitate_prepare = 0;\r
 329         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 330         e.predator.hitsound += 1; // play this for team mates too, as we could be swallowing them to heal them\r
 331         Vore_SetPreyPositions(e.predator);\r
 332 \r
 333         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 334         e.predator.weapon_delay = time + button_delay_time;\r
 335         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 336         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 337         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 338 }\r
 339 \r
 340 void Vore_SwallowStep(entity e)\r
 341 {\r
 342         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 343         {\r
 344                 Vore_Swallow(e);\r
 345                 return;\r
 346         }\r
 347 \r
 348         // when the predator starts swallowing, play his grab sound\r
 349         if(!self.swallow_progress_pred)\r
 350                 PlayerSound(self, playersound_grab, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 351 \r
 352         Vore_SwallowModel_Update(e, self);\r
 353 \r
 354         // increase the progress value until it reaches 1, then swallow the player\r
 355         if(e.swallow_progress_prey < 1)\r
 356         {\r
 357                 float fill;\r
 358                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 359                 if(cvar("g_healthsize") && cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 360                         fill *= pow(self.scale / e.scale, cvar("g_balance_vore_swallow_speed_fill_scalediff"));\r
 361                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 362                         fill *= (1 - ((e.stomach_load / e.stomach_maxload) * bound(0, cvar("g_balance_vore_swallow_speed_fill_stomachload"), 1)));\r
 363 \r
 364                 e.swallow_progress_prey += fill;\r
 365         }\r
 366         else\r
 367         {\r
 368                 Vore_Swallow(e);\r
 369                 e.swallow_progress_prey = 0;\r
 370         }\r
 371 \r
 372         // the predator's progress is how much the prey got swallowed\r
 373         self.swallow_progress_pred = e.swallow_progress_prey;\r
 374 }\r
 375 \r
 376 void Vore_Regurgitate(entity e)\r
 377 {\r
 378         // this player is being regurgitated by their predator, apply the proper changes\r
 379 \r
 380         e.movetype = e.vore_oldmovetype;\r
 381         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 382                 e.solid = e.vore_oldsolid;\r
 383         e.view_ofs_z = PL_VIEW_OFS_z;\r
 384         e.punchvector_z = -cvar("g_balance_vore_regurgitate_prey_punchvector");\r
 385 \r
 386         // if the prey has been fully digested, silently detach them\r
 387         if(cvar("g_balance_vore_regurgitate_death_silent"))\r
 388         if(e.deadflag != DEAD_NO && e.health <= cvar("g_balance_vore_digestion_limit"))\r
 389         {\r
 390                 e.predator = world;\r
 391                 e.modelindex = 0; // hide the dead body\r
 392                 return;\r
 393         }\r
 394 \r
 395         float scalediff;\r
 396         scalediff = cvar("g_healthsize") ? e.scale / e.predator.scale : 1; // the tighter the gut, the greater the effect\r
 397 \r
 398         // apply velocities\r
 399         makevectors(e.predator.v_angle);\r
 400         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force") * scalediff;\r
 401         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce") * scalediff;\r
 402         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 403         e.pushltime = time + cvar("g_maxpushtime");\r
 404 \r
 405         // if the dead body of the prey is below gibbing health, gib it\r
 406         e.stat_eaten = 0; // necessary for gibs to show\r
 407         PlayerGib(e, e.predator);\r
 408 \r
 409         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 410         if(cvar("g_balance_vore_swallow_speed_fill") && cvar("g_balance_vore_regurgitate_swallowprogress"))\r
 411         {\r
 412                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 413                 Vore_SwallowModel_Update(e, e.predator);\r
 414         }\r
 415 \r
 416         // apply regurgitation damage to the predator\r
 417         if(cvar("g_balance_vore_regurgitate_damage"))\r
 418         {\r
 419                 float regurgitate_dmg;\r
 420                 regurgitate_dmg = cvar("g_balance_vore_regurgitate_damage");\r
 421                 if(cvar("g_healthsize"))\r
 422                         regurgitate_dmg *= e.scale / e.predator.scale;\r
 423                 Damage(e.predator, e, e, regurgitate_dmg, DEATH_REGURGITATION, e.predator.origin, '0 0 0');\r
 424         }\r
 425 \r
 426         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 427         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 428         pointparticles(particleeffectnum("vore_regurgitate"), e.predator.origin, '0 0 0', 1);\r
 429         e.predator.punchangle_x = crandom() * cvar("g_balance_vore_regurgitate_predator_punchangle") * scalediff;\r
 430         e.predator.punchangle_y = crandom() * cvar("g_balance_vore_regurgitate_predator_punchangle") * scalediff;\r
 431         e.predator.punchangle_z = crandom() * cvar("g_balance_vore_regurgitate_predator_punchangle") * scalediff;\r
 432         e.predator.regurgitate_prepare = 0;\r
 433         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 434         Vore_SetPreyPositions(e.predator);\r
 435 \r
 436         // block firing for a small amount of time, or we'll be firing the next frame\r
 437         e.weapon_delay = time + button_delay_time;\r
 438         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 439         e.predator = world;\r
 440 }\r
 441 \r
 442 void Vore_Disconnect()\r
 443 {\r
 444         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 445         entity e;\r
 446 \r
 447         // prey disconnects or goes spectating while inside someone's belly\r
 448         if(self.stat_eaten)\r
 449                 Vore_Regurgitate(self);\r
 450 \r
 451         // pred disconnects or goes spectating with players in their belly\r
 452         entity head;\r
 453         FOR_EACH_PLAYER(head)\r
 454         {\r
 455                 if(head.predator == self)\r
 456                         Vore_Regurgitate(head);\r
 457         }\r
 458         // remove consumable items when we disconnect\r
 459         for(e = world; (e = find(e, classname, "consumable")); )\r
 460         {\r
 461                 if(e.predator == self)\r
 462                         Item_Consumable_Remove(e, TRUE);\r
 463         }\r
 464 \r
 465         self.stomach_load = self.gravity = 0; // prevents a bug\r
 466         Vore_GurgleSound(); // stop the gurgling sound\r
 467 }\r
 468 \r
 469 .float digestion_step;\r
 470 void Vore_Digest()\r
 471 {\r
 472         // apply digestion to prey\r
 473 \r
 474         if(self.predator.deadflag != DEAD_NO) // dead predators don't digest\r
 475         {\r
 476                 self.predator.digesting = FALSE;\r
 477                 return;\r
 478         }\r
 479         if(self.health <= cvar("g_balance_vore_digestion_limit")) // don't digest below this amount of health\r
 480                 return;\r
 481 \r
 482         if(time > self.digestion_step)\r
 483         {\r
 484                 // if distributed digestion is enabled, reduce digestion strength by the amount of prey in our stomach\r
 485                 float damage, damage_offset;\r
 486 \r
 487                 damage_offset = 1;\r
 488                 if(cvar("g_balance_vore_digestion_distribute")) // apply distributed digestion damage\r
 489                         damage_offset /= (1 - (self.predator.stomach_load / self.predator.stomach_maxload) * bound(0, cvar("g_balance_vore_digestion_distribute"), 1));\r
 490                 if(cvar("g_healthsize") && cvar("g_balance_vore_digestion_scalediff")) // apply player scale to digestion damage\r
 491                         damage_offset *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_digestion_scalediff"));\r
 492 \r
 493                 if(self.deadflag != DEAD_NO)\r
 494                         damage = cvar("g_balance_vore_digestion_damage_death") / damage_offset;\r
 495                 else\r
 496                         damage = cvar("g_balance_vore_digestion_damage") / damage_offset;\r
 497 \r
 498                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 499                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 500                 {\r
 501                         self.predator.health += damage * cvar("g_balance_vore_digestion_vampire");\r
 502                         self.predator.pauserothealth_finished = max(self.predator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));\r
 503                 }\r
 504 \r
 505                 self.digestion_step = time + vore_steptime;\r
 506         }\r
 507 \r
 508         if(stov(cvar_string("g_vore_regurgitatecolor_color_digest")))\r
 509                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_digest"));\r
 510 }\r
 511 \r
 512 .float teamheal_step;\r
 513 void Vore_Teamheal()\r
 514 {\r
 515         // apply teamheal\r
 516 \r
 517         if(self.deadflag != DEAD_NO)\r
 518                 return;\r
 519 \r
 520         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 521         if(time > self.teamheal_step)\r
 522         {\r
 523                 self.health += cvar("g_balance_vore_teamheal");\r
 524                 self.teamheal_step = time + vore_steptime;\r
 525 \r
 526                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 527                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 528                 {\r
 529                         play2(self, "misc/beep.wav");\r
 530                         play2(self.predator, "misc/beep.wav");\r
 531                 }\r
 532         }\r
 533 }\r
 534 \r
 535 .float kick_pressed;\r
 536 void Vore_StomachKick()\r
 537 {\r
 538         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 539 \r
 540         if(self.deadflag != DEAD_NO)\r
 541                 return;\r
 542 \r
 543         float scalediff;\r
 544         scalediff = pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 545 \r
 546         if(time > self.stomachkick_delay && !self.kick_pressed)\r
 547         {\r
 548                 float damage, vol, pitch;\r
 549                 vector force;\r
 550                 damage = cvar("g_balance_vore_kick_damage");\r
 551                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 552                 vol = VOL_BASE;\r
 553 \r
 554                 // modified sound pitch, based on player scale\r
 555                 if(cvar("g_healthsize") && cvar("g_healthsize_pitch"))\r
 556                         pitch = pow(self.predator.scale, -cvar("g_healthsize_pitch"));\r
 557 \r
 558                 // apply player scale to the damage / force of the kick\r
 559                 if(cvar("g_healthsize") && cvar("g_balance_vore_kick_scalediff"))\r
 560                 {\r
 561                         damage *= scalediff;\r
 562                         force *= scalediff;\r
 563                         vol *= scalediff; // kick sound volume based on the same scale\r
 564                 }\r
 565                 vol = bound(0, vol, 1);\r
 566 \r
 567                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 568                 sound7(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), vol, ATTN_NORM, 100 * pitch, 0);\r
 569                 self.predator.punchangle_x = crandom() * cvar("g_balance_vore_kick_predator_punchangle") * scalediff;\r
 570                 self.predator.punchangle_y = crandom() * cvar("g_balance_vore_kick_predator_punchangle") * scalediff;\r
 571                 self.predator.punchangle_z = crandom() * cvar("g_balance_vore_kick_predator_punchangle") * scalediff;\r
 572                 self.punchangle_x = crandom() * cvar("g_balance_vore_kick_prey_punchangle") * scalediff;\r
 573                 self.punchangle_y = crandom() * cvar("g_balance_vore_kick_prey_punchangle") * scalediff;\r
 574                 self.punchangle_z = crandom() * cvar("g_balance_vore_kick_prey_punchangle") * scalediff;\r
 575 \r
 576                 // abort the predator's scheduled regurgitation\r
 577                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 578                         self.predator.regurgitate_prepare = 0;\r
 579 \r
 580                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 581                 if(cvar("g_balance_vore_kick_repress"))\r
 582                 if not(clienttype(self) == CLIENTTYPE_BOT) // not for bots, to prevent an issue\r
 583                         self.kick_pressed = TRUE;\r
 584         }\r
 585 }\r
 586 \r
 587 void Vore_StomachLeave()\r
 588 {\r
 589         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 590 \r
 591         if(self.deadflag != DEAD_NO)\r
 592                 return;\r
 593 \r
 594         if(Vore_CanLeave())\r
 595                 Vore_Regurgitate(self);\r
 596         else if(time > self.complain_vore)\r
 597         {\r
 598                 play2(self, "misc/forbidden.wav");\r
 599                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 600                 self.complain_vore = time + complain_delay_time;\r
 601         }\r
 602 }\r
 603 \r
 604 void Vore_AutoTaunt()\r
 605 {\r
 606         // triggers ambient vore taunts, for both pred and prey\r
 607 \r
 608         float taunt_time;\r
 609 \r
 610         // predator taunts\r
 611         if((self.swallow_progress_pred || (self.stomach_load && Stomach_HasLivePrey(self))) && !Stomach_TeamMates_check(self))\r
 612         {\r
 613                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 614                 {\r
 615                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 616                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 617                 }\r
 618         }\r
 619         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 620         {\r
 621                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 622                 SetAutoTaunt(self, 0, 0);\r
 623         }\r
 624 \r
 625         // prey taunts\r
 626         if((self.swallow_progress_prey || (self.stat_eaten && !(teams_matter && self.team == self.predator.team))) && self.deadflag == DEAD_NO)\r
 627         {\r
 628                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 629                 {\r
 630                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 631                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 632                 }\r
 633         }\r
 634         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 635         {\r
 636                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 637                 SetAutoTaunt(self, 0, 0);\r
 638         }\r
 639 }\r
 640 \r
 641 void Vore_SetSbarRings()\r
 642 {\r
 643         // first clear the ring stats, then configure them if needed\r
 644         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 645         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 646 \r
 647         if(self.stat_eaten)\r
 648         {\r
 649                 if(time <= self.stomachkick_delay)\r
 650                 {\r
 651                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 652                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 653                 }\r
 654         }\r
 655         else\r
 656         {\r
 657                 if(self.swallow_progress_pred)\r
 658                 {\r
 659                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 660                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 661                 }\r
 662                 else if(time <= self.action_delay)\r
 663                 {\r
 664                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 665                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 666                 }\r
 667 \r
 668                 if(self.swallow_progress_prey)\r
 669                 {\r
 670                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 671                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 672                 }\r
 673                 else if(time <= self.regurgitate_prepare)\r
 674                 {\r
 675                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 676                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 677                 }\r
 678         }\r
 679 }\r
 680 \r
 681 .float regurgitatecolor_particles_tick;\r
 682 void Vore()\r
 683 {\r
 684         // main vore code, this is where it all happens\r
 685 \r
 686         Vore_AutoTaunt();\r
 687 \r
 688         if(!self.stat_eaten)\r
 689         if(self.modelindex) // not if we're a gibbed dead body or not visible any more\r
 690         if(self.colormod)\r
 691         if(self.colormod != '1 1 1')\r
 692         {\r
 693                 // slowly wash stomach fluids off players once they're out of the stomach\r
 694                 if(cvar("g_vore_regurgitatecolor_fade"))\r
 695                 if(self.deadflag == DEAD_NO) // not for dead bodies\r
 696                 {\r
 697                         float goo_fade;\r
 698                         goo_fade = cvar("g_vore_regurgitatecolor_fade") * frametime;\r
 699                         goo_fade *= 1 + self.waterlevel; // fade faster when underwater\r
 700 \r
 701                         self.colormod_x += goo_fade;\r
 702                         if(self.colormod_x > 1)\r
 703                                 self.colormod_x = 1;\r
 704                         self.colormod_y += goo_fade;\r
 705                         if(self.colormod_y > 1)\r
 706                                 self.colormod_y = 1;\r
 707                         self.colormod_z += goo_fade;\r
 708                         if(self.colormod_z > 1)\r
 709                                 self.colormod_z = 1;\r
 710                 }\r
 711 \r
 712                 // constant particles falling off dirty players\r
 713                 if(cvar("g_vore_regurgitatecolor_particles"))\r
 714                 if(self.regurgitatecolor_particles_tick < time)\r
 715                 {\r
 716                         pointparticles(particleeffectnum("vore_regurgitate_constant"), self.origin, '0 0 0', 1);\r
 717                         self.regurgitatecolor_particles_tick = time + cvar("g_vore_regurgitatecolor_particles") * vlen(self.colormod); // particle time depends on how dirty the player is\r
 718                 }\r
 719         }\r
 720 \r
 721         // set all vore stats\r
 722         Vore_SetSbarRings();\r
 723         if(self.predator.classname == "player")\r
 724         {\r
 725                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 726                 self.stat_stomachmaxload = self.predator.stomach_maxload; // necessary for the stomach board\r
 727                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 728                 self.stat_eaten = num_for_edict(self.predator);\r
 729         }\r
 730         else\r
 731         {\r
 732                 self.stat_stomachload = self.stomach_load;\r
 733                 self.stat_stomachmaxload = self.stomach_maxload;\r
 734                 self.stat_digesting = self.digesting;\r
 735                 self.stat_eaten = 0;\r
 736         }\r
 737         self.stat_canleave = Vore_CanLeave();\r
 738 \r
 739         // don't allow a player inside a player inside another player :)\r
 740         // prevent this by checking if such has happened, and taking the proper measures\r
 741         // this code has a high priority and must not be stopped by any delay, so run it here\r
 742         if(self.predator.stat_eaten)\r
 743                 Vore_Regurgitate(self);\r
 744 \r
 745         // the swallow progress of prey and preds idly decrease by this amount\r
 746         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 747         {\r
 748                 if(self.swallow_progress_pred)\r
 749                 {\r
 750                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 751                         if(self.swallow_progress_pred < 0)\r
 752                                 self.swallow_progress_pred = 0;\r
 753                 }\r
 754                 if(self.swallow_progress_prey)\r
 755                 {\r
 756                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 757                         if(self.swallow_progress_prey < 0)\r
 758                                 self.swallow_progress_prey = 0;\r
 759                 }\r
 760         }\r
 761 \r
 762         // set the predator's stomach load and capacity\r
 763         Vore_StomachLoad_Apply();\r
 764 \r
 765         // apply delays and skip the vore system under some circumstances\r
 766         if(!cvar("g_vore")) // the vore system is disabled\r
 767         {\r
 768                 Vore_Disconnect();\r
 769                 return;\r
 770         }\r
 771         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 772         {\r
 773                 Vore_Disconnect();\r
 774                 return;\r
 775         }\r
 776         if(self.spectatee_status)\r
 777                 return;\r
 778         if(time < self.system_delay)\r
 779                 return;\r
 780 \r
 781 // --------------------------------\r
 782 // Code that addresses predators:\r
 783 // --------------------------------\r
 784 \r
 785         entity prey;\r
 786         prey = Swallow_player_check();\r
 787 \r
 788         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 789         self.stat_canswallow = 0;\r
 790         if(Swallow_condition_check(prey))\r
 791         {\r
 792                 // canswallow stat, used by the HUD\r
 793                 if(teams_matter && prey.team == self.team)\r
 794                         self.stat_canswallow = 2;\r
 795                 else\r
 796                         self.stat_canswallow = 1;\r
 797 \r
 798                 if(self.BUTTON_ATCK)\r
 799                         Vore_SwallowStep(prey);\r
 800         }\r
 801         else if(prey != world)\r
 802                 self.stat_canswallow = -1;\r
 803 \r
 804         // toggle digestion, if the player has someone in their stomach\r
 805         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 806         {\r
 807                 if(self.stomach_load)\r
 808                 {\r
 809                         if(time > self.digest_button_delay_time)\r
 810                         {\r
 811                                 self.digesting = !self.digesting;\r
 812                                 self.digest_button_delay_time = time + button_delay_time;\r
 813                         }\r
 814                 }\r
 815                 else if(time > self.complain_vore)\r
 816                 {\r
 817                         play2(self, "misc/forbidden.wav");\r
 818                         sprint(self, "There is nothing to digest\n");\r
 819                         self.complain_vore = time + complain_delay_time;\r
 820                 }\r
 821         }\r
 822         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 823                 self.digesting = FALSE;\r
 824 \r
 825         // predator wishes to regurgitate his prey\r
 826         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 827         if(!self.regurgitate_prepare)\r
 828         {\r
 829                 if(self.stomach_load)\r
 830                 {\r
 831                         if(time > self.regurgitate_button_delay_time)\r
 832                         {\r
 833                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 834                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 835                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE); // looks good for preparing regurgitation\r
 836                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 837                         }\r
 838                 }\r
 839                 else if(time > self.complain_vore)\r
 840                 {\r
 841                         play2(self, "misc/forbidden.wav");\r
 842                         sprint(self, "There is nothing to regurgitate\n");\r
 843                         self.complain_vore = time + complain_delay_time;\r
 844                 }\r
 845         }\r
 846 \r
 847         if(self.stomach_load > self.stomach_maxload) // the predator got beyond his capacity after eating, so some prey must pop out\r
 848         {\r
 849                 self.regurgitate_prepare = -1;\r
 850                 return;\r
 851         }\r
 852         if(cvar("g_balance_vore_load_pred_speedcap") && self.stomach_load)\r
 853         if(vlen(self.velocity) >= cvar("g_balance_vore_load_pred_speedcap") / (self.stomach_load / self.stomach_maxload)) // predator's going too fast, gets sick and throws up\r
 854         {\r
 855                 self.regurgitate_prepare = -1;\r
 856                 return;\r
 857         }\r
 858 \r
 859         if (self.digesting && self.digestsound_finished < time)\r
 860         {\r
 861                 PlayerSound (self, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 862                 self.digestsound_finished = time + 0.5;\r
 863         }\r
 864         if(cvar("g_vore_gurglesound"))\r
 865                 Vore_GurgleSound();\r
 866 \r
 867 // --------------------------------\r
 868 // Code that addresses the prey:\r
 869 // --------------------------------\r
 870 \r
 871         if(!self.stat_eaten)\r
 872                 return;\r
 873 \r
 874         if(self.deadflag != DEAD_NO && self.health < cvar("g_balance_vore_digestion_limit")) // make sure health doesn't go below the limit\r
 875                 self.health = cvar("g_balance_vore_digestion_limit");\r
 876 \r
 877         // automatically regurgitate prey that has reached their digestion limit\r
 878         if(cvar("g_balance_vore_digestion_limit_regurgitate"))\r
 879         if(self.health <= cvar("g_balance_vore_digestion_limit"))\r
 880         {\r
 881                 Vore_Regurgitate(self);\r
 882                 return;\r
 883         }\r
 884 \r
 885         // do we stick around inside dead furries? x_x\r
 886         if(self.predator.deadflag != DEAD_NO)\r
 887         {\r
 888                 if(!cvar("g_balance_vore_deadpredator") || !self.predator.modelindex) // if the predator is gibbed, we are out\r
 889                 {\r
 890                         Vore_Regurgitate(self);\r
 891                         return;\r
 892                 }\r
 893                 if(self.predator.regurgitate_prepare) // abort scheduled regurgitation\r
 894                         self.predator.regurgitate_prepare = 0;\r
 895         }\r
 896 \r
 897         // apply delayed regurgitating if it was scheduled\r
 898         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 899         {\r
 900                 Vore_Regurgitate(self);\r
 901                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 902         }\r
 903 \r
 904         // execute digesting and team healing\r
 905         if(self.predator.digesting == TRUE)\r
 906                 Vore_Digest();\r
 907         if(teams_matter && self.team == self.predator.team)\r
 908         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 909                 Vore_Teamheal();\r
 910 \r
 911         // execute prey commands\r
 912         if(self.BUTTON_ATCK)\r
 913         {\r
 914                 if(cvar("g_vore_kick"))\r
 915                         Vore_StomachKick();\r
 916         }\r
 917         else\r
 918                 self.kick_pressed = FALSE;\r
 919         if(self.BUTTON_JUMP)\r
 920                 Vore_StomachLeave();\r
 921 \r
 922         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 923         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 924         kh_Key_DropAll(self, FALSE);\r
 925 \r
 926         // always position camera at the center of the stomach, to reduce probability of the view poking out\r
 927         self.view_ofs_z = PL_PREY_VIEW_OFS_z * self.predator.scale;\r
 928 }