data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   3 .float complain_vore;\r
   4 .float vore_oldmovetype, vore_oldsolid;\r
   5 \r
   6 const float system_delay_time = 0.1;\r
   7 const float complain_delay_time = 1;\r
   8 const float button_delay_time = 0.5;\r
   9 const float steptime = 0.1;\r
  10 \r
  11 entity Swallow_player_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14 \r
  15         float swallow_range;\r
  16         vector vore_w_shotorg, vore_w_shotdir;\r
  17 \r
  18         swallow_range = cvar("g_balance_vore_swallow_range");\r
  19         if(cvar("g_healthsize")) // we can swallow from further or closer based on our size\r
  20                 swallow_range *= self.scale;\r
  21         makevectors(self.angles);\r
  22         vore_w_shotorg = self.origin;\r
  23         vore_w_shotdir = v_forward;\r
  24 \r
  25         if(self.antilag_debug)\r
  26                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, self.antilag_debug);\r
  27         else\r
  28                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  29         if(trace_fraction < 1)\r
  30         if(trace_ent.classname == "player")\r
  31                 return trace_ent;\r
  32         return world;\r
  33 }\r
  34 \r
  35 float Swallow_condition_check(entity prey)\r
  36 {\r
  37         // checks the necessary conditions for swallowing a player\r
  38 \r
  39         if(prey != self)\r
  40         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  41         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  42         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  43         {\r
  44                 float prey_mass;\r
  45                 prey_mass = cvar("g_balance_vore_load_prey_mass");\r
  46                 if(cvar("g_healthsize"))\r
  47                         prey_mass *= prey.scale;\r
  48 \r
  49                 string swallow_complain;\r
  50                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  51                         swallow_complain = "You cannot swallow your team mates\n";\r
  52                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  53                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  54                 else if(self.stomach_load + prey_mass > self.stomach_maxload)\r
  55                         swallow_complain = strcat("You don't have any room to swallow this player. Their mass is ^3", ftos(prey_mass), "^7 and your remaining capacity is ^3", ftos(self.stomach_maxload - self.stomach_load), "\n");\r
  56                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  57                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  58                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  59                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  60 \r
  61                 if(swallow_complain != "")\r
  62                 {\r
  63                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  64                         {\r
  65                                 play2(self, "misc/forbidden.wav");\r
  66                                 sprint(self, swallow_complain);\r
  67                                 self.complain_vore = time + complain_delay_time;\r
  68                         }\r
  69                         return FALSE;\r
  70                 }\r
  71                 return TRUE;\r
  72         }\r
  73         return FALSE;\r
  74 }\r
  75 \r
  76 float Stomach_TeamMates_check(entity pred)\r
  77 {\r
  78         // checks if a player's stomach contains any team mates\r
  79 \r
  80         entity head;\r
  81         if(teams_matter)\r
  82         {\r
  83                 FOR_EACH_PLAYER(head)\r
  84                 {\r
  85                         if(head.predator == pred && head.team == pred.team)\r
  86                                 return TRUE;\r
  87                 }\r
  88         }\r
  89         return FALSE;\r
  90 }\r
  91 \r
  92 float Stomach_HasLivePrey(entity pred)\r
  93 {\r
  94         entity head;\r
  95         FOR_EACH_PLAYER(head)\r
  96         {\r
  97                 if(head.predator == pred)\r
  98                 if(head.deadflag == DEAD_NO)\r
  99                         return TRUE;\r
 100         }\r
 101         return FALSE;\r
 102 }\r
 103 \r
 104 float Vore_CanLeave()\r
 105 {\r
 106         if(self.stat_eaten)\r
 107         {\r
 108                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
 109                         return TRUE;\r
 110                 if(teams_matter && self.team == self.predator.team)\r
 111                         return TRUE;\r
 112                 if(g_rpg && cvar("g_rpg_canleave"))\r
 113                         return TRUE;\r
 114         }\r
 115         return FALSE;\r
 116 }\r
 117 \r
 118 // position the camera properly for prey\r
 119 void Vore_SetPreyPositions(entity pred)\r
 120 {\r
 121         // pred is the predator and head is the prey\r
 122 \r
 123         local entity head;\r
 124         local vector origin_apply;\r
 125 \r
 126         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 127         // else all players overlap in the center. To do this, we use a random origin on all players in the same stomach.\r
 128         FOR_EACH_PLAYER(head)\r
 129         {\r
 130                 if(head.predator == pred)\r
 131                 {\r
 132                         origin_apply_x = PL_PREY_VIEW_OFS_x + crandom() * cvar("g_vore_neighborprey_distance");\r
 133                         origin_apply_y = PL_PREY_VIEW_OFS_y + crandom() * cvar("g_vore_neighborprey_distance");\r
 134                         origin_apply_z = PL_PREY_VIEW_OFS_z;\r
 135 \r
 136                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 137                         head.view_ofs = origin_apply;\r
 138                         head.view_ofs_z *= pred.scale; // stomach center depends on predator scale\r
 139 \r
 140                         // change prey height based on scale\r
 141                         float prey_height;\r
 142                                 prey_height = (head.scale - pred.scale) * cvar("g_healthsize_vore_pos");\r
 143                         head.view_ofs_z += prey_height;\r
 144                 }\r
 145         }\r
 146 }\r
 147 \r
 148 .float gurgle_oldstomachload;\r
 149 void Vore_GurgleSound()\r
 150 {\r
 151         if(time > self.gurglesound_finished || self.gurgle_oldstomachload != self.stomach_load)\r
 152         {\r
 153                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 154 \r
 155                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 156                 self.gurgle_oldstomachload = self.stomach_load;\r
 157         }\r
 158 }\r
 159 \r
 160 void Vore_StomachLoad_Apply()\r
 161 {\r
 162         // apply stomach weight that makes you heavier and larger the more you eat\r
 163         // slowing the player is done in cl_physics.qc\r
 164 \r
 165         entity e;\r
 166         float prey_mass;\r
 167 \r
 168         // apply the stomach capacity of the predator\r
 169         self.stomach_maxload = cvar("g_balance_vore_load_pred_capacity");\r
 170         if(cvar("g_healthsize"))\r
 171                 self.stomach_maxload *= self.scale;\r
 172         self.stomach_maxload = floor(self.stomach_maxload);\r
 173 \r
 174         self.stomach_load = 0; // start from zero\r
 175         FOR_EACH_PLAYER(e)\r
 176         {\r
 177                 if(e.predator == self)\r
 178                 {\r
 179                         prey_mass = cvar("g_balance_vore_load_prey_mass");\r
 180                         if(cvar("g_healthsize"))\r
 181                                 prey_mass *= e.scale;\r
 182                         self.stomach_load += floor(prey_mass);\r
 183                 }\r
 184         }\r
 185 \r
 186         // apply weight\r
 187         self.gravity = 1 + (self.stomach_load / self.stomach_maxload) * cvar("g_balance_vore_load_pred_weight");\r
 188         if(!self.gravity && self.stomach_load)\r
 189                 self.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 190 }\r
 191 \r
 192 void Vore_AutoDigest(entity e)\r
 193 {\r
 194         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 195 \r
 196         if(!cvar("g_vore_digestion") || e.digesting)\r
 197                 return;\r
 198         if(!e.cvar_cl_vore_autodigest || clienttype(e) != CLIENTTYPE_REAL)\r
 199                 return; // this feature is only for players, not bots\r
 200         if(e.stomach_load > 1)\r
 201                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 202         if(Stomach_TeamMates_check(e))\r
 203                 return; // never begin automatic digestion if we've swallowed a team mate\r
 204 \r
 205         e.digesting = TRUE;\r
 206 }\r
 207 \r
 208 .entity swallow_model;\r
 209 float Vore_SwallowModel_CustomizeEntityForClient()\r
 210 {\r
 211         // use the same system as the weapon model\r
 212 \r
 213         self.viewmodelforclient = self.owner;\r
 214         self.alpha = self.owner.cvar_cl_vore_swallowmodel;\r
 215 \r
 216         if(other.classname == "spectator")\r
 217         if(other.enemy == self.owner)\r
 218         {\r
 219                 self.viewmodelforclient = other;\r
 220                 self.alpha = other.cvar_cl_vore_swallowmodel;\r
 221         }\r
 222 \r
 223         return TRUE;\r
 224 }\r
 225 \r
 226 void Vore_SwallowModel_Think()\r
 227 {\r
 228         // update the position of the swallow model to match our swallow progress\r
 229         float dist;\r
 230         dist = (-0.5 + self.owner.swallow_progress_prey) * cvar("g_vore_swallowmodel_range"); // the model is centered at 0.5 progress\r
 231         if(cvar("g_healthsize"))\r
 232                 dist *= self.scale;\r
 233         self.view_ofs = '1 0 0' * dist;\r
 234 \r
 235         // if our swallow progress is gone or we are dead, the swallow model also goes away\r
 236         if(!self.owner.swallow_progress_prey || self.owner.deadflag != DEAD_NO || self.owner.classname != "player")\r
 237         {\r
 238                 remove(self.owner.swallow_model);\r
 239                 self.owner.swallow_model = world;\r
 240                 return;\r
 241         }\r
 242 \r
 243         // properties that should update whenever possible, but when the predator is not available\r
 244         self.nextthink = time;\r
 245 }\r
 246 \r
 247 void Vore_SwallowModel_Update(entity prey, entity pred)\r
 248 {\r
 249         // if we don't have a swallow model already, spawn one\r
 250         if(!prey.swallow_model)\r
 251         {\r
 252                 prey.swallow_model = spawn();\r
 253                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 254                 prey.swallow_model.solid = SOLID_NOT;\r
 255                 //prey.swallow_model.effects |= EF_NOGUNBOB; // let it bob\r
 256                 prey.swallow_model.effects |= EF_NODEPTHTEST; // don't hide behind walls\r
 257                 prey.swallow_model.owner = prey;\r
 258                 prey.swallow_model.customizeentityforclient = Vore_SwallowModel_CustomizeEntityForClient;\r
 259                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
 260                 prey.swallow_model.nextthink = time;\r
 261         }\r
 262 \r
 263         // properties that should update whenever possible, but when the predator is available\r
 264         string player_swallowmodel;\r
 265         player_swallowmodel = strcat(substring(pred.playermodel, 0, strlen(pred.playermodel) - 4), "_swallow.md3"); // 4 is the extension length\r
 266         if(prey.swallow_model.model != player_swallowmodel) // player model can be changed while the predator is active\r
 267                 setmodel(prey.swallow_model, player_swallowmodel);\r
 268         if(prey.swallow_model.skin != pred.skin) // player skin can be changed while the predator is active\r
 269                 prey.swallow_model.skin = pred.skin;\r
 270         if(cvar("g_healthsize"))\r
 271                 prey.swallow_model.scale = pred.scale / prey.scale; // player size difference\r
 272         if(prey.swallow_model.enemy != pred)\r
 273                 prey.swallow_model.enemy = pred; // enemy is the predator\r
 274         if(prey.swallow_model.colormap != pred.colormap)\r
 275                 prey.swallow_model.colormap = pred.colormap; // pants and shirt color\r
 276         if(prey.swallow_model.glowmod != pred.glowmod)\r
 277                 prey.swallow_model.glowmod = pred.glowmod; // glow color\r
 278 }\r
 279 \r
 280 .entity pusher;\r
 281 .float pushltime;\r
 282 void Vore_Swallow(entity e)\r
 283 {\r
 284         // this player is being swallowed by another player, apply the proper changes\r
 285 \r
 286         e.vore_oldmovetype = e.movetype;\r
 287         e.vore_oldsolid = e.solid;\r
 288 \r
 289         e.predator = self;\r
 290         setorigin(e, e.predator.origin);\r
 291         e.velocity = '0 0 0';\r
 292         e.movetype = MOVETYPE_FOLLOW;\r
 293         e.solid = SOLID_NOT;\r
 294         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 295 \r
 296         // drop keys (KH) and flags (CTF) when we get swallowed\r
 297         kh_Key_DropAll(e, FALSE);\r
 298         if(e.flagcarried)\r
 299                 DropFlag(e.flagcarried, world, e.predator);\r
 300 \r
 301         if(stov(cvar_string("g_vore_regurgitatecolor_color_normal")))\r
 302                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_normal"));\r
 303 \r
 304         if(teams_matter && e.team == e.predator.team)\r
 305         {\r
 306                 if(cvar("g_vore_kick"))\r
 307                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 308                 if(cvar("g_vore_digestion"))\r
 309                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 310         }\r
 311 \r
 312         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 313         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 314         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_punchangle");\r
 315         e.predator.regurgitate_prepare = 0;\r
 316         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 317         e.predator.hitsound += 1; // play this for team mates too, as we could be swallowing them to heal them\r
 318         Vore_AutoDigest(e.predator);\r
 319         Vore_SetPreyPositions(e.predator);\r
 320 \r
 321         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 322         e.predator.weapon_delay = time + button_delay_time;\r
 323         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 324         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 325         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 326 }\r
 327 \r
 328 void Vore_SwallowStep(entity e)\r
 329 {\r
 330         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 331         {\r
 332                 Vore_Swallow(e);\r
 333                 return;\r
 334         }\r
 335 \r
 336         Vore_SwallowModel_Update(e, self);\r
 337 \r
 338         // increase the progress value until it reaches 1, then swallow the player\r
 339         if(e.swallow_progress_prey < 1)\r
 340         {\r
 341                 float fill;\r
 342                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 343                 if(cvar("g_healthsize") && cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 344                         fill *= pow(self.scale / e.scale, cvar("g_balance_vore_swallow_speed_fill_scalediff"));\r
 345                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 346                         fill /= e.stomach_load;\r
 347 \r
 348                 e.swallow_progress_prey += fill;\r
 349         }\r
 350         else\r
 351         {\r
 352                 Vore_Swallow(e);\r
 353                 e.swallow_progress_prey = 0;\r
 354         }\r
 355 \r
 356         // the predator's progress is how much the prey got swallowed\r
 357         self.swallow_progress_pred = e.swallow_progress_prey;\r
 358 }\r
 359 \r
 360 void Vore_Regurgitate(entity e)\r
 361 {\r
 362         // this player is being regurgitated by their predator, apply the proper changes\r
 363 \r
 364         e.movetype = e.vore_oldmovetype;\r
 365         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 366                 e.solid = e.vore_oldsolid;\r
 367         e.view_ofs_z = PL_VIEW_OFS_z;\r
 368 \r
 369         // apply velocities\r
 370         local vector oldforward, oldright, oldup;\r
 371         oldforward = v_forward;\r
 372         oldright = v_right;\r
 373         oldup = v_up;\r
 374         makevectors(e.predator.v_angle);\r
 375         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 376         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 377         v_forward = oldforward;\r
 378         v_right = oldright;\r
 379         v_up = oldup;\r
 380 \r
 381         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 382         e.pushltime = time + cvar("g_maxpushtime");\r
 383 \r
 384         // if the dead body of the prey is below gibbing health, gib it\r
 385         e.stat_eaten = 0; // necessary for gibs to show\r
 386         PlayerGib(e, e.predator);\r
 387 \r
 388         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 389         if(cvar("g_balance_vore_swallow_speed_fill") && cvar("g_balance_vore_regurgitate_swallowprogress"))\r
 390         {\r
 391                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 392                 Vore_SwallowModel_Update(e, e.predator);\r
 393         }\r
 394 \r
 395         // apply regurgitation damage to the predator\r
 396         if(cvar("g_balance_vore_regurgitate_damage"))\r
 397         {\r
 398                 float regurgitate_dmg;\r
 399                 regurgitate_dmg = cvar("g_balance_vore_regurgitate_damage");\r
 400                 if(cvar("g_healthsize"))\r
 401                         regurgitate_dmg *= e.scale / e.predator.scale;\r
 402                 Damage(e.predator, e.predator, e.predator, regurgitate_dmg, DEATH_REGURGITATION, e.predator.origin, '0 0 0');\r
 403         }\r
 404 \r
 405         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 406         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 407         pointparticles(particleeffectnum("vore_regurgitate"), e.predator.origin, '0 0 0', 1);\r
 408         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_punchangle");\r
 409         e.predator.regurgitate_prepare = 0;\r
 410         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 411         Vore_SetPreyPositions(e.predator);\r
 412 \r
 413         // block firing for a small amount of time, or we'll be firing the next frame\r
 414         e.weapon_delay = time + button_delay_time;\r
 415         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 416         e.predator = world;\r
 417 }\r
 418 \r
 419 void Vore_Disconnect()\r
 420 {\r
 421         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 422 \r
 423         // prey disconnects or goes spectating while inside someone's belly\r
 424         if(self.stat_eaten)\r
 425                 Vore_Regurgitate(self);\r
 426 \r
 427         // pred disconnects or goes spectating with players in their belly\r
 428         entity head;\r
 429         FOR_EACH_PLAYER(head)\r
 430         {\r
 431                 if(head.predator == self)\r
 432                         Vore_Regurgitate(head);\r
 433         }\r
 434         Vore_GurgleSound(); // stop the gurgling sound\r
 435 \r
 436         self.stomach_load = self.gravity = 0; // prevents a bug\r
 437 }\r
 438 \r
 439 .float digestion_step;\r
 440 void Vore_Digest()\r
 441 {\r
 442         // apply digestion to prey\r
 443 \r
 444         if(self.predator.deadflag != DEAD_NO) // dead predators don't digest\r
 445                 return;\r
 446         if(self.health <= cvar("g_balance_vore_digestion_limit")) // don't digest below this amount of health\r
 447                 return;\r
 448 \r
 449         if(time > self.digestion_step)\r
 450         {\r
 451                 // if distributed digestion is enabled, reduce digestion strength by the amount of prey in our stomach\r
 452                 float damage, damage_offset;\r
 453 \r
 454                 damage_offset = 1;\r
 455                 if(cvar("g_balance_vore_digestion_distribute")) // apply distributed digestion damage\r
 456                         damage_offset *= self.predator.stomach_load / self.predator.stomach_maxload;\r
 457                 if(cvar("g_healthsize") && cvar("g_balance_vore_digestion_scalediff")) // apply player scale to digestion damage\r
 458                         damage_offset *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_digestion_scalediff"));\r
 459                 damage_offset = ceil(damage_offset);\r
 460 \r
 461                 damage = cvar("g_balance_vore_digestion_damage") / damage_offset;\r
 462                 if(cvar("g_balance_vore_digestion_damage_death") && self.deadflag != DEAD_NO) // amplify digestion damage for dead prey\r
 463                         damage *= cvar("g_balance_vore_digestion_damage_death");\r
 464 \r
 465                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 466                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 467                         self.predator.health += damage * cvar("g_balance_vore_digestion_vampire");\r
 468 \r
 469                 if (self.predator.digestsound_finished < time)\r
 470                 {\r
 471                         PlayerSound (self.predator, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 472                         self.predator.digestsound_finished = time + 0.5;\r
 473                 }\r
 474                 self.digestion_step = time + steptime;\r
 475         }\r
 476 \r
 477         if(stov(cvar_string("g_vore_regurgitatecolor_color_digest")))\r
 478                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_digest"));\r
 479 }\r
 480 \r
 481 .float teamheal_step;\r
 482 void Vore_Teamheal()\r
 483 {\r
 484         // apply teamheal\r
 485 \r
 486         if(self.deadflag != DEAD_NO)\r
 487                 return;\r
 488 \r
 489         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 490         if(time > self.teamheal_step)\r
 491         {\r
 492                 self.health += cvar("g_balance_vore_teamheal");\r
 493                 self.teamheal_step = time + steptime;\r
 494 \r
 495                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 496                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 497                 {\r
 498                         play2(self, "misc/beep.wav");\r
 499                         play2(self.predator, "misc/beep.wav");\r
 500                 }\r
 501         }\r
 502 }\r
 503 \r
 504 .float kick_pressed;\r
 505 void Vore_StomachKick()\r
 506 {\r
 507         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 508 \r
 509         if(self.deadflag != DEAD_NO)\r
 510                 return;\r
 511 \r
 512         if(time > self.stomachkick_delay && !self.kick_pressed)\r
 513         {\r
 514                 float damage, vol;\r
 515                 vector force;\r
 516                 damage = cvar("g_balance_vore_kick_damage");\r
 517                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 518                 vol = VOL_BASE;\r
 519 \r
 520                 // apply player scale to the damage / force of the kick\r
 521                 if(cvar("g_healthsize") && cvar("g_balance_vore_kick_scalediff"))\r
 522                 {\r
 523                         damage *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 524                         force *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 525                         vol *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff")); // kick sound volume based on the same scale\r
 526                 }\r
 527                 vol = bound(0, vol, 1);\r
 528 \r
 529                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 530                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), vol, ATTN_NORM);\r
 531                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 532                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 533 \r
 534                 // abort the predator's scheduled regurgitation\r
 535                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 536                         self.predator.regurgitate_prepare = 0;\r
 537 \r
 538                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 539                 if(cvar("g_balance_vore_kick_repress"))\r
 540                 if not(clienttype(self) == CLIENTTYPE_BOT) // not for bots, to prevent an issue\r
 541                         self.kick_pressed = TRUE;\r
 542         }\r
 543 }\r
 544 \r
 545 void Vore_StomachLeave()\r
 546 {\r
 547         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 548 \r
 549         if(self.deadflag != DEAD_NO)\r
 550                 return;\r
 551 \r
 552         if(Vore_CanLeave())\r
 553                 Vore_Regurgitate(self);\r
 554         else if(time > self.complain_vore)\r
 555         {\r
 556                 play2(self, "misc/forbidden.wav");\r
 557                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 558                 self.complain_vore = time + complain_delay_time;\r
 559         }\r
 560 }\r
 561 \r
 562 void Vore_AutoTaunt()\r
 563 {\r
 564         // triggers ambient vore taunts, for both pred and prey\r
 565 \r
 566         float taunt_time;\r
 567 \r
 568         // predator taunts\r
 569         if(self.stomach_load && !Stomach_TeamMates_check(self) && Stomach_HasLivePrey(self))\r
 570         {\r
 571                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 572                 {\r
 573                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 574                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 575                 }\r
 576         }\r
 577         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 578         {\r
 579                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 580                 SetAutoTaunt(self, 0, 0);\r
 581         }\r
 582 \r
 583         // prey taunts\r
 584         if(self.stat_eaten && !(teams_matter && self.team == self.predator.team) && self.deadflag == DEAD_NO)\r
 585         {\r
 586                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 587                 {\r
 588                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 589                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 590                 }\r
 591         }\r
 592         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 593         {\r
 594                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 595                 SetAutoTaunt(self, 0, 0);\r
 596         }\r
 597 }\r
 598 \r
 599 void Vore_SetSbarRings()\r
 600 {\r
 601         // first clear the ring stats, then configure them if needed\r
 602         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 603         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 604 \r
 605         if(self.stat_eaten)\r
 606         {\r
 607                 if(time <= self.stomachkick_delay)\r
 608                 {\r
 609                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 610                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 611                 }\r
 612         }\r
 613         else\r
 614         {\r
 615                 if(self.swallow_progress_pred)\r
 616                 {\r
 617                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 618                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 619                 }\r
 620                 else if(time <= self.action_delay)\r
 621                 {\r
 622                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 623                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 624                 }\r
 625 \r
 626                 if(self.swallow_progress_prey)\r
 627                 {\r
 628                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 629                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 630                 }\r
 631                 else if(time <= self.regurgitate_prepare)\r
 632                 {\r
 633                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 634                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 635                 }\r
 636         }\r
 637 }\r
 638 \r
 639 .float regurgitatecolor_particles_tick;\r
 640 void Vore()\r
 641 {\r
 642         // main vore code, this is where it all happens\r
 643 \r
 644         Vore_AutoTaunt();\r
 645 \r
 646         if(!self.stat_eaten)\r
 647         if(self.modelindex) // not if we're a gibbed dead body or not visible any more\r
 648         if(self.colormod)\r
 649         if(self.colormod != '1 1 1')\r
 650         {\r
 651                 // slowly wash stomach fluids off players once they're out of the stomach\r
 652                 if(cvar("g_vore_regurgitatecolor_fade"))\r
 653                 if(self.deadflag == DEAD_NO) // not for dead bodies\r
 654                 {\r
 655                         float goo_fade;\r
 656                         goo_fade = cvar("g_vore_regurgitatecolor_fade") * frametime;\r
 657                         goo_fade *= 1 + self.waterlevel; // fade faster when underwater\r
 658 \r
 659                         self.colormod_x += goo_fade;\r
 660                         if(self.colormod_x > 1)\r
 661                                 self.colormod_x = 1;\r
 662                         self.colormod_y += goo_fade;\r
 663                         if(self.colormod_y > 1)\r
 664                                 self.colormod_y = 1;\r
 665                         self.colormod_z += goo_fade;\r
 666                         if(self.colormod_z > 1)\r
 667                                 self.colormod_z = 1;\r
 668                 }\r
 669 \r
 670                 // constant particles falling off dirty players\r
 671                 if(cvar("g_vore_regurgitatecolor_particles"))\r
 672                 if(self.regurgitatecolor_particles_tick < time)\r
 673                 {\r
 674                         pointparticles(particleeffectnum("vore_regurgitate_constant"), self.origin, '0 0 0', 1);\r
 675                         self.regurgitatecolor_particles_tick = time + cvar("g_vore_regurgitatecolor_particles") * vlen(self.colormod); // particle time depends on how dirty the player is\r
 676                 }\r
 677         }\r
 678 \r
 679         // set all vore stats\r
 680         Vore_SetSbarRings();\r
 681         if(self.predator.classname == "player")\r
 682         {\r
 683                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 684                 self.stat_stomachmaxload = self.predator.stomach_maxload; // necessary for the stomach board\r
 685                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 686                 self.stat_eaten = num_for_edict(self.predator);\r
 687         }\r
 688         else\r
 689         {\r
 690                 self.stat_stomachload = self.stomach_load;\r
 691                 self.stat_stomachmaxload = self.stomach_maxload;\r
 692                 self.stat_digesting = self.digesting;\r
 693                 self.stat_eaten = 0;\r
 694         }\r
 695         self.stat_canleave = Vore_CanLeave();\r
 696 \r
 697         // don't allow a player inside a player inside another player :)\r
 698         // prevent this by checking if such has happened, and taking the proper measures\r
 699         // this code has a high priority and must not be stopped by any delay, so run it here\r
 700         if(self.predator.stat_eaten)\r
 701         {\r
 702                 entity target_predator, target_predator_predator, oldself;\r
 703                 target_predator = self.predator;\r
 704                 target_predator_predator = self.predator.predator;\r
 705 \r
 706                 Vore_Regurgitate(self);\r
 707 \r
 708                 // now steal our prey's prey if this probability applies\r
 709                 if(random() < cvar("g_balance_vore_swallow_stealprey"))\r
 710                 {\r
 711                         oldself = self;\r
 712                         self = target_predator_predator;\r
 713                         if(Swallow_condition_check(oldself))\r
 714                         if not(teams_matter && self.team == target_predator.team) // don't steal a team mate's prey\r
 715                         if not(teams_matter && self.team == oldself.team) // if the prey we would be stealing is a team mate, don't do it\r
 716                                 Vore_Swallow(oldself);\r
 717                         self = oldself;\r
 718                 }\r
 719         }\r
 720 \r
 721         // the swallow progress of prey and preds idly decrease by this amount\r
 722         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 723         {\r
 724                 if(self.swallow_progress_pred)\r
 725                 {\r
 726                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 727                         if(self.swallow_progress_pred < 0)\r
 728                                 self.swallow_progress_pred = 0;\r
 729                 }\r
 730                 if(self.swallow_progress_prey)\r
 731                 {\r
 732                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 733                         if(self.swallow_progress_prey < 0)\r
 734                                 self.swallow_progress_prey = 0;\r
 735                 }\r
 736         }\r
 737 \r
 738         // set the predator's stomach load and capacity\r
 739         Vore_StomachLoad_Apply();\r
 740 \r
 741         // apply delays and skip the vore system under some circumstances\r
 742         if(!cvar("g_vore")) // the vore system is disabled\r
 743         {\r
 744                 Vore_Disconnect();\r
 745                 return;\r
 746         }\r
 747         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 748         {\r
 749                 Vore_Disconnect();\r
 750                 return;\r
 751         }\r
 752         if(self.spectatee_status)\r
 753                 return;\r
 754         if(time < self.system_delay)\r
 755                 return;\r
 756 \r
 757 // --------------------------------\r
 758 // Code that addresses predators:\r
 759 // --------------------------------\r
 760 \r
 761         entity prey;\r
 762         prey = Swallow_player_check();\r
 763 \r
 764         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 765         self.stat_canswallow = 0;\r
 766         if(Swallow_condition_check(prey))\r
 767         {\r
 768                 // canswallow stat, used by the HUD\r
 769                 if(teams_matter && prey.team == self.team)\r
 770                         self.stat_canswallow = 2;\r
 771                 else\r
 772                         self.stat_canswallow = 1;\r
 773 \r
 774                 if(self.BUTTON_ATCK)\r
 775                         Vore_SwallowStep(prey);\r
 776         }\r
 777         else if(prey != world)\r
 778                 self.stat_canswallow = -1;\r
 779 \r
 780         // toggle digestion, if the player has someone in their stomach\r
 781         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 782         {\r
 783                 if(self.stomach_load)\r
 784                 {\r
 785                         if(time > self.digest_button_delay_time)\r
 786                         {\r
 787                                 self.digesting = !self.digesting;\r
 788                                 self.digest_button_delay_time = time + button_delay_time;\r
 789                         }\r
 790                 }\r
 791                 else if(time > self.complain_vore)\r
 792                 {\r
 793                         play2(self, "misc/forbidden.wav");\r
 794                         sprint(self, "There is nothing to digest\n");\r
 795                         self.complain_vore = time + complain_delay_time;\r
 796                 }\r
 797         }\r
 798         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 799                 self.digesting = FALSE;\r
 800 \r
 801         // predator wishes to regurgitate his prey\r
 802         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 803         {\r
 804                 if(self.stomach_load)\r
 805                 {\r
 806                         if(time > self.regurgitate_button_delay_time)\r
 807                         {\r
 808                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 809                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 810                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE); // looks good for preparing regurgitation\r
 811                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 812                         }\r
 813                 }\r
 814                 else if(time > self.complain_vore)\r
 815                 {\r
 816                         play2(self, "misc/forbidden.wav");\r
 817                         sprint(self, "There is nothing to regurgitate\n");\r
 818                         self.complain_vore = time + complain_delay_time;\r
 819                 }\r
 820         }\r
 821 \r
 822         if(cvar("g_vore_gurglesound"))\r
 823                 Vore_GurgleSound();\r
 824 \r
 825 // --------------------------------\r
 826 // Code that addresses the prey:\r
 827 // --------------------------------\r
 828 \r
 829         if(!self.stat_eaten)\r
 830                 return;\r
 831 \r
 832         if(self.deadflag != DEAD_NO && self.health < cvar("g_balance_vore_digestion_limit")) // make sure health doesn't go below the limit\r
 833                 self.health = cvar("g_balance_vore_digestion_limit");\r
 834 \r
 835         // automatically regurgitate prey that has reached their digestion limit\r
 836         if(cvar("g_balance_vore_digestion_limit_regurgitate"))\r
 837         if(self.health <= cvar("g_balance_vore_digestion_limit"))\r
 838         {\r
 839                 Vore_Regurgitate(self);\r
 840                 return;\r
 841         }\r
 842 \r
 843         // do we stick around inside dead furries? x_x\r
 844         if(self.predator.deadflag != DEAD_NO)\r
 845         if(!cvar("g_balance_vore_deadpredator") || !self.predator.modelindex) // if the predator is gibbed, we are out\r
 846         {\r
 847                 Vore_Regurgitate(self);\r
 848                 return;\r
 849         }\r
 850 \r
 851         if(self.predator.stomach_load > self.predator.stomach_maxload) // the predator got beyond his capacity after eating, so some prey must pop out\r
 852         {\r
 853                 Vore_Regurgitate(self);\r
 854                 return;\r
 855         }\r
 856         if(cvar("g_balance_vore_load_pred_speedcap") && vlen(self.predator.velocity) >= cvar("g_balance_vore_load_pred_speedcap") / (self.predator.stomach_load / self.predator.stomach_maxload)) // predator's going too fast, gets sick and throws up\r
 857         {\r
 858                 Vore_Regurgitate(self);\r
 859                 return;\r
 860         }\r
 861 \r
 862         // apply delayed regurgitating if it was scheduled\r
 863         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 864         {\r
 865                 self.predator.regurgitate_prepare = 0;\r
 866                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 867                 Vore_Regurgitate(self);\r
 868         }\r
 869 \r
 870         // execute digesting and team healing\r
 871         if(self.predator.digesting == TRUE)\r
 872                 Vore_Digest();\r
 873         if(teams_matter && self.team == self.predator.team)\r
 874         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 875                 Vore_Teamheal();\r
 876 \r
 877         // execute prey commands\r
 878         if(self.BUTTON_ATCK)\r
 879         {\r
 880                 if(cvar("g_vore_kick"))\r
 881                         Vore_StomachKick();\r
 882         }\r
 883         else\r
 884                 self.kick_pressed = FALSE;\r
 885         if(self.BUTTON_JUMP)\r
 886                 Vore_StomachLeave();\r
 887 \r
 888         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 889         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 890         kh_Key_DropAll(self, FALSE);\r
 891 }