Merge branch 'master' into matthiaskrgr/screenshotcmd

[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / triggers / trigger / heal.qc

diff --git a/qcsrc/common/triggers/trigger/heal.qc b/qcsrc/common/triggers/trigger/heal.qc
new file mode 100644 (file)
index 0000000..5a2bc78
--- /dev/null
+++ b/qcsrc/common/triggers/trigger/heal.qc
@@ -0,0 +1,42 @@
+#ifdef SVQC
+.float triggerhealtime;
+void trigger_heal_touch(entity this, entity toucher)
+{
+       if (this.active != ACTIVE_ACTIVE)
+               return;
+
+       // only do the EXACTTRIGGER_TOUCH checks when really needed (saves some cpu)
+       if (toucher.iscreature)
+       {
+               if (toucher.takedamage)
+               if (!IS_DEAD(toucher))
+               if (toucher.triggerhealtime < time)
+               {
+                       EXACTTRIGGER_TOUCH(this, toucher);
+                       toucher.triggerhealtime = time + 1;
+
+                       if (toucher.health < this.max_health)
+                       {
+                               toucher.health = min(toucher.health + this.health, this.max_health);
+                               toucher.pauserothealth_finished = max(toucher.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
+                               _sound (toucher, CH_TRIGGER, this.noise, VOL_BASE, ATTEN_NORM);
+                       }
+               }
+       }
+}
+
+spawnfunc(trigger_heal)
+{
+       this.active = ACTIVE_ACTIVE;
+
+       EXACTTRIGGER_INIT;
+       settouch(this, trigger_heal_touch);
+       if (!this.health)
+               this.health = 10;
+       if (!this.max_health)
+               this.max_health = 200; //Max health topoff for field
+       if(this.noise == "")
+               this.noise = "misc/mediumhealth.wav";
+       precache_sound(this.noise);
+}
+#endif