qcsrc/server/mutators/mutator/gamemode_race.qc

   1 #include "gamemode_race.qh"
   2
   3 #ifndef GAMEMODE_RACE_H
   4 #define GAMEMODE_RACE_H
   5
   6 void rc_SetLimits();
   7 void race_Initialize();
   8
   9 REGISTER_MUTATOR(rc, false)
  10 {
  11         MUTATOR_ONADD
  12         {
  13                 if (time > 1) // game loads at time 1
  14                         error("This is a game type and it cannot be added at runtime.");
  15
  16                 rc_SetLimits();
  17                 race_Initialize();
  18         }
  19
  20         MUTATOR_ONROLLBACK_OR_REMOVE
  21         {
  22                 // we actually cannot roll back race_Initialize here
  23                 // BUT: we don't need to! If this gets called, adding always
  24                 // succeeds.
  25         }
  26
  27         MUTATOR_ONREMOVE
  28         {
  29                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
  30                 return -1;
  31         }
  32
  33         return 0;
  34 }
  35
  36 #endif
  37
  38 #ifdef IMPLEMENTATION
  39
  40 #include <server/race.qh>
  41
  42 #define autocvar_g_race_laps_limit cvar("g_race_laps_limit")
  43 float autocvar_g_race_qualifying_timelimit;
  44 float autocvar_g_race_qualifying_timelimit_override;
  45 int autocvar_g_race_teams;
  46
  47 // legacy bot roles
  48 .float race_checkpoint;
  49 void havocbot_role_race(entity this)
  50 {
  51         if(IS_DEAD(this))
  52                 return;
  53
  54         entity e;
  55         if (this.bot_strategytime < time)
  56         {
  57                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
  58                 navigation_goalrating_start(this);
  59
  60                 for(e = world; (e = find(e, classname, "trigger_race_checkpoint")) != world; )
  61                 {
  62                         if(e.cnt == this.race_checkpoint)
  63                         {
  64                                 navigation_routerating(this, e, 1000000, 5000);
  65                         }
  66                         else if(this.race_checkpoint == -1)
  67                         {
  68                                 navigation_routerating(this, e, 1000000, 5000);
  69                         }
  70                 }
  71
  72                 navigation_goalrating_end(this);
  73         }
  74 }
  75
  76 void race_ScoreRules()
  77 {
  78         ScoreRules_basics(race_teams, 0, 0, false);
  79         if(race_teams)
  80         {
  81                 ScoreInfo_SetLabel_TeamScore(  ST_RACE_LAPS,    "laps",      SFL_SORT_PRIO_PRIMARY);
  82                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_LAPS,    "laps",      SFL_SORT_PRIO_PRIMARY);
  83                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_TIME,    "time",      SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  84                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_FASTEST, "fastest",   SFL_LOWER_IS_BETTER | SFL_TIME);
  85         }
  86         else if(g_race_qualifying)
  87         {
  88                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_FASTEST, "fastest",   SFL_SORT_PRIO_PRIMARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  89         }
  90         else
  91         {
  92                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_LAPS,    "laps",      SFL_SORT_PRIO_PRIMARY);
  93                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_TIME,    "time",      SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  94                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_FASTEST, "fastest",   SFL_LOWER_IS_BETTER | SFL_TIME);
  95         }
  96         ScoreRules_basics_end();
  97 }
  98
  99 void race_EventLog(string mode, entity actor) // use an alias for easy changing and quick editing later
 100 {
 101         if(autocvar_sv_eventlog)
 102                 GameLogEcho(strcat(":race:", mode, ":", ((actor != world) ? (strcat(":", ftos(actor.playerid))) : "")));
 103 }
 104
 105 float WinningCondition_Race(float fraglimit)
 106 {
 107         float wc;
 108         float n, c;
 109
 110         n = 0;
 111         c = 0;
 112         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 113                 ++n;
 114                 if(it.race_completed)
 115                         ++c;
 116         ));
 117         if(n && (n == c))
 118                 return WINNING_YES;
 119         wc = WinningCondition_Scores(fraglimit, 0);
 120
 121         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
 122         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
 123         // do NOT support equality when the laps are all raced!
 124                 return WINNING_STARTSUDDENDEATHOVERTIME;
 125         else
 126                 return WINNING_NEVER;
 127 }
 128
 129 float WinningCondition_QualifyingThenRace(float limit)
 130 {
 131         float wc;
 132         wc = WinningCondition_Scores(limit, 0);
 133
 134         // NEVER initiate overtime
 135         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
 136         {
 137                 return WINNING_YES;
 138         }
 139
 140         return wc;
 141 }
 142
 143 MUTATOR_HOOKFUNCTION(rc, PlayerPhysics)
 144 {SELFPARAM();
 145         self.race_movetime_frac += PHYS_INPUT_TIMELENGTH;
 146         float f = floor(self.race_movetime_frac);
 147         self.race_movetime_frac -= f;
 148         self.race_movetime_count += f;
 149         self.race_movetime = self.race_movetime_frac + self.race_movetime_count;
 150
 151 #ifdef SVQC
 152         if(IS_PLAYER(self))
 153         {
 154                 if (self.race_penalty)
 155                         if (time > self.race_penalty)
 156                                 self.race_penalty = 0;
 157                 if(self.race_penalty)
 158                 {
 159                         self.velocity = '0 0 0';
 160                         self.movetype = MOVETYPE_NONE;
 161                         self.disableclientprediction = 2;
 162                 }
 163         }
 164 #endif
 165
 166         // force kbd movement for fairness
 167         float wishspeed;
 168         vector wishvel;
 169
 170         // if record times matter
 171         // ensure nothing EVIL is being done (i.e. div0_evade)
 172         // this hinders joystick users though
 173         // but it still gives SOME analog control
 174         wishvel.x = fabs(self.movement.x);
 175         wishvel.y = fabs(self.movement.y);
 176         if(wishvel.x != 0 && wishvel.y != 0 && wishvel.x != wishvel.y)
 177         {
 178                 wishvel.z = 0;
 179                 wishspeed = vlen(wishvel);
 180                 if(wishvel.x >= 2 * wishvel.y)
 181                 {
 182                         // pure X motion
 183                         if(self.movement.x > 0)
 184                                 self.movement_x = wishspeed;
 185                         else
 186                                 self.movement_x = -wishspeed;
 187                         self.movement_y = 0;
 188                 }
 189                 else if(wishvel.y >= 2 * wishvel.x)
 190                 {
 191                         // pure Y motion
 192                         self.movement_x = 0;
 193                         if(self.movement.y > 0)
 194                                 self.movement_y = wishspeed;
 195                         else
 196                                 self.movement_y = -wishspeed;
 197                 }
 198                 else
 199                 {
 200                         // diagonal
 201                         if(self.movement.x > 0)
 202                                 self.movement_x = M_SQRT1_2 * wishspeed;
 203                         else
 204                                 self.movement_x = -M_SQRT1_2 * wishspeed;
 205                         if(self.movement.y > 0)
 206                                 self.movement_y = M_SQRT1_2 * wishspeed;
 207                         else
 208                                 self.movement_y = -M_SQRT1_2 * wishspeed;
 209                 }
 210         }
 211
 212         return false;
 213 }
 214
 215 MUTATOR_HOOKFUNCTION(rc, reset_map_global)
 216 {
 217         float s;
 218
 219         Score_NicePrint(world);
 220
 221         race_ClearRecords();
 222         PlayerScore_Sort(race_place, 0, 1, 0);
 223
 224         FOREACH_CLIENT(true, LAMBDA(
 225                 if(it.race_place)
 226                 {
 227                         s = PlayerScore_Add(it, SP_RACE_FASTEST, 0);
 228                         if(!s)
 229                                 it.race_place = 0;
 230                 }
 231                 race_EventLog(ftos(it.race_place), it);
 232         ));
 233
 234         if(g_race_qualifying == 2)
 235         {
 236                 g_race_qualifying = 0;
 237                 independent_players = 0;
 238                 cvar_set("fraglimit", ftos(race_fraglimit));
 239                 cvar_set("leadlimit", ftos(race_leadlimit));
 240                 cvar_set("timelimit", ftos(race_timelimit));
 241                 race_ScoreRules();
 242         }
 243
 244         return false;
 245 }
 246
 247 MUTATOR_HOOKFUNCTION(rc, ClientConnect)
 248 {
 249         entity player = M_ARGV(0, entity);
 250
 251         race_PreparePlayer(player);
 252         player.race_checkpoint = -1;
 253
 254         string rr = RACE_RECORD;
 255
 256         if(IS_REAL_CLIENT(player))
 257         {
 258                 msg_entity = player;
 259                 race_send_recordtime(MSG_ONE);
 260                 race_send_speedaward(MSG_ONE);
 261
 262                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
 263                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
 264                 race_send_speedaward_alltimebest(MSG_ONE);
 265
 266                 float i;
 267                 for (i = 1; i <= RANKINGS_CNT; ++i)
 268                 {
 269                         race_SendRankings(i, 0, 0, MSG_ONE);
 270                 }
 271         }
 272
 273         return false;
 274 }
 275
 276 MUTATOR_HOOKFUNCTION(rc, MakePlayerObserver)
 277 {
 278         entity player = M_ARGV(0, entity);
 279
 280         if(g_race_qualifying)
 281         if(PlayerScore_Add(player, SP_RACE_FASTEST, 0))
 282                 player.frags = FRAGS_LMS_LOSER;
 283         else
 284                 player.frags = FRAGS_SPECTATOR;
 285
 286         race_PreparePlayer(player);
 287         player.race_checkpoint = -1;
 288 }
 289
 290 MUTATOR_HOOKFUNCTION(rc, PlayerSpawn)
 291 {
 292         entity player = M_ARGV(0, entity);
 293         entity spawn_spot = M_ARGV(1, entity);
 294
 295         if(spawn_spot.target == "")
 296                 // Emergency: this wasn't a real spawnpoint. Can this ever happen?
 297                 race_PreparePlayer(player);
 298
 299         // if we need to respawn, do it right
 300         player.race_respawn_checkpoint = player.race_checkpoint;
 301         player.race_respawn_spotref = spawn_spot;
 302
 303         player.race_place = 0;
 304
 305         return false;
 306 }
 307
 308 MUTATOR_HOOKFUNCTION(rc, PutClientInServer)
 309 {
 310         entity player = M_ARGV(0, entity);
 311
 312         if(IS_PLAYER(player))
 313         if(!gameover)
 314         {
 315                 if(player.killcount == FRAGS_SPECTATOR /* initial spawn */ || g_race_qualifying) // spawn
 316                         race_PreparePlayer(player);
 317                 else // respawn
 318                         race_RetractPlayer(player);
 319
 320                 race_AbandonRaceCheck(player);
 321         }
 322         return false;
 323 }
 324
 325 MUTATOR_HOOKFUNCTION(rc, PlayerDies)
 326 {
 327         entity frag_target = M_ARGV(2, entity);
 328
 329         frag_target.respawn_flags |= RESPAWN_FORCE;
 330         race_AbandonRaceCheck(frag_target);
 331         return false;
 332 }
 333
 334 MUTATOR_HOOKFUNCTION(rc, HavocBot_ChooseRole)
 335 {
 336         entity bot = M_ARGV(0, entity);
 337
 338         bot.havocbot_role = havocbot_role_race;
 339         return true;
 340 }
 341
 342 MUTATOR_HOOKFUNCTION(rc, GetPressedKeys)
 343 {SELFPARAM();
 344         if(self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
 345         {
 346                 if (!self.stored_netname)
 347                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
 348                 if(self.stored_netname != self.netname)
 349                 {
 350                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
 351                         strunzone(self.stored_netname);
 352                         self.stored_netname = strzone(self.netname);
 353                 }
 354         }
 355
 356         if (!IS_OBSERVER(self))
 357         {
 358                 if (vlen(self.velocity - self.velocity_z * '0 0 1') > speedaward_speed)
 359                 {
 360                         speedaward_speed = vlen(self.velocity - self.velocity_z * '0 0 1');
 361                         speedaward_holder = self.netname;
 362                         speedaward_uid = self.crypto_idfp;
 363                         speedaward_lastupdate = time;
 364                 }
 365                 if (speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1)
 366                 {
 367                         string rr = RACE_RECORD;
 368                         race_send_speedaward(MSG_ALL);
 369                         speedaward_lastsent = speedaward_speed;
 370                         if (speedaward_speed > speedaward_alltimebest && speedaward_uid != "")
 371                         {
 372                                 speedaward_alltimebest = speedaward_speed;
 373                                 speedaward_alltimebest_holder = speedaward_holder;
 374                                 speedaward_alltimebest_uid = speedaward_uid;
 375                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
 376                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp"), speedaward_alltimebest_uid);
 377                                 race_send_speedaward_alltimebest(MSG_ALL);
 378                         }
 379                 }
 380         }
 381         return false;
 382 }
 383
 384 MUTATOR_HOOKFUNCTION(rc, ForbidPlayerScore_Clear)
 385 {
 386         if(g_race_qualifying)
 387                 return true; // in qualifying, you don't lose score by observing
 388
 389         return false;
 390 }
 391
 392 MUTATOR_HOOKFUNCTION(rc, GetTeamCount, CBC_ORDER_EXCLUSIVE)
 393 {
 394         M_ARGV(0, float) = race_teams;
 395 }
 396
 397 MUTATOR_HOOKFUNCTION(rc, Scores_CountFragsRemaining)
 398 {
 399         // announce remaining frags if not in qualifying mode
 400         if(!g_race_qualifying)
 401                 return true;
 402
 403         return false;
 404 }
 405
 406 MUTATOR_HOOKFUNCTION(rc, GetRecords)
 407 {
 408         int record_page = M_ARGV(0, int);
 409         string ret_string = M_ARGV(1, string);
 410
 411         for(int i = record_page * 200; i < MapInfo_count && i < record_page * 200 + 200; ++i)
 412         {
 413                 if(MapInfo_Get_ByID(i))
 414                 {
 415                         float r = race_readTime(MapInfo_Map_bspname, 1);
 416
 417                         if(!r)
 418                                 continue;
 419
 420                         string h = race_readName(MapInfo_Map_bspname, 1);
 421                         ret_string = strcat(ret_string, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
 422                 }
 423         }
 424
 425         M_ARGV(1, string) = ret_string;
 426 }
 427
 428 MUTATOR_HOOKFUNCTION(rc, FixClientCvars)
 429 {
 430         entity player = M_ARGV(0, entity);
 431
 432         stuffcmd(player, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 433 }
 434
 435 MUTATOR_HOOKFUNCTION(rc, CheckRules_World)
 436 {
 437         float checkrules_timelimit = M_ARGV(1, float);
 438         float checkrules_fraglimit = M_ARGV(2, float);
 439
 440         if(checkrules_timelimit >= 0)
 441         {
 442                 if(!g_race_qualifying)
 443                 {
 444                         M_ARGV(0, float) = WinningCondition_Race(checkrules_fraglimit);
 445                         return true;
 446                 }
 447                 else if(g_race_qualifying == 2)
 448                 {
 449                         M_ARGV(0, float) = WinningCondition_QualifyingThenRace(checkrules_fraglimit);
 450                         return true;
 451                 }
 452         }
 453
 454         return false;
 455 }
 456
 457 MUTATOR_HOOKFUNCTION(rc, ReadLevelCvars)
 458 {
 459         if(g_race_qualifying == 2)
 460                 warmup_stage = 0;
 461         return false;
 462 }
 463
 464 void race_Initialize()
 465 {
 466         race_ScoreRules();
 467         if(g_race_qualifying == 2)
 468                 warmup_stage = 0;
 469 }
 470
 471 void rc_SetLimits()
 472 {
 473         int fraglimit_override, leadlimit_override;
 474         float timelimit_override, qualifying_override;
 475
 476         if(autocvar_g_race_teams)
 477         {
 478                 ActivateTeamplay();
 479                 race_teams = bound(2, autocvar_g_race_teams, 4);
 480                 have_team_spawns = -1; // request team spawns
 481         }
 482         else
 483                 race_teams = 0;
 484
 485         qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 486         fraglimit_override = autocvar_g_race_laps_limit;
 487         leadlimit_override = 0; // currently not supported by race
 488         timelimit_override = autocvar_timelimit_override;
 489
 490         float want_qualifying = ((qualifying_override >= 0) ? qualifying_override : autocvar_g_race_qualifying_timelimit) > 0;
 491
 492         if(autocvar_g_campaign)
 493         {
 494                 g_race_qualifying = 1;
 495                 independent_players = 1;
 496         }
 497         else if(want_qualifying)
 498         {
 499                 g_race_qualifying = 2;
 500                 independent_players = 1;
 501                 race_fraglimit = (fraglimit_override >= 0) ? fraglimit_override : autocvar_fraglimit;
 502                 race_leadlimit = (leadlimit_override >= 0) ? leadlimit_override : autocvar_leadlimit;
 503                 race_timelimit = (timelimit_override >= 0) ? timelimit_override : autocvar_timelimit;
 504                 qualifying_override = (qualifying_override >= 0) ? qualifying_override : autocvar_g_race_qualifying_timelimit;
 505                 fraglimit_override = 0;
 506                 leadlimit_override = 0;
 507                 timelimit_override = qualifying_override;
 508         }
 509         else
 510                 g_race_qualifying = 0;
 511         SetLimits(fraglimit_override, leadlimit_override, timelimit_override, qualifying_override);
 512 }
 513
 514 #endif