qcsrc/server/items/items.qc

   1 #include "items.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/gamemodes/gamemode/cts/cts.qh>
   6 #include <common/items/_mod.qh>
   7 #include <common/mapobjects/subs.qh>
   8 #include <common/mapobjects/triggers.qh>
   9 #include <common/monsters/_mod.qh>
  10 #include <common/mutators/mutator/buffs/buffs.qh>
  11 #include <common/mutators/mutator/buffs/sv_buffs.qh>
  12 #include <common/mutators/mutator/powerups/_mod.qh>
  13 #include <common/mutators/mutator/status_effects/_mod.qh>
  14 #include <common/net_linked.qh>
  15 #include <common/notifications/all.qh>
  16 #include <common/resources/resources.qh>
  17 #include <common/util.qh>
  18 #include <common/weapons/_all.qh>
  19 #include <common/wepent.qh>
  20 #include <lib/warpzone/common.qh>
  21 #include <lib/warpzone/util_server.qh>
  22 #include <server/bot/api.qh>
  23 #include <server/command/vote.qh>
  24 #include <server/damage.qh>
  25 #include <server/mutators/_mod.qh>
  26 #include <server/teamplay.qh>
  27 #include <server/weapons/common.qh>
  28 #include <server/weapons/selection.qh>
  29 #include <server/weapons/weaponsystem.qh>
  30 #include <server/world.qh>
  31
  32 bool ItemSend(entity this, entity to, int sf)
  33 {
  34         if(this.gravity)
  35                 sf |= ISF_DROP;
  36         else
  37                 sf &= ~ISF_DROP;
  38
  39         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
  40         WriteByte(MSG_ENTITY, sf);
  41
  42         //WriteByte(MSG_ENTITY, this.cnt);
  43         if(sf & ISF_LOCATION)
  44         {
  45                 WriteVector(MSG_ENTITY, this.origin);
  46         }
  47
  48         if(sf & ISF_ANGLES)
  49         {
  50                 WriteAngleVector(MSG_ENTITY, this.angles);
  51         }
  52
  53         // sets size on the client, unused on server
  54         //if(sf & ISF_SIZE)
  55
  56         if(sf & ISF_STATUS)
  57                 WriteByte(MSG_ENTITY, this.ItemStatus);
  58
  59         if(sf & ISF_MODEL)
  60         {
  61                 WriteShort(MSG_ENTITY, bound(0, this.fade_end, 32767));
  62
  63                 if(this.mdl == "")
  64                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
  65
  66                 WriteString(MSG_ENTITY, this.mdl);
  67                 WriteByte(MSG_ENTITY, bound(0, this.skin, 255));
  68         }
  69
  70         if(sf & ISF_COLORMAP)
  71         {
  72                 WriteShort(MSG_ENTITY, this.colormap);
  73                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
  74                 WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
  75                 WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
  76         }
  77
  78         if(sf & ISF_DROP)
  79         {
  80                 WriteVector(MSG_ENTITY, this.velocity);
  81         }
  82
  83         return true;
  84 }
  85
  86 void ItemUpdate(entity this)
  87 {
  88         this.oldorigin = this.origin;
  89         this.SendFlags |= ISF_LOCATION;
  90 }
  91
  92 void UpdateItemAfterTeleport(entity this)
  93 {
  94         if(getSendEntity(this) == ItemSend)
  95                 ItemUpdate(this);
  96 }
  97
  98 bool have_pickup_item(entity this)
  99 {
 100         if (this.itemdef.spawnflags & ITEM_FLAG_MUTATORBLOCKED)
 101                 return false;
 102
 103         if(!this.itemdef.instanceOfPowerup)
 104         {
 105                 if(autocvar_g_pickup_items > 0)
 106                         return true;
 107                 if(autocvar_g_pickup_items == 0)
 108                         return false;
 109                 if(g_weaponarena)
 110                         if(STAT(WEAPONS, this) || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 111                                 return false;
 112         }
 113         return true;
 114 }
 115
 116 void Item_Show(entity e, int mode)
 117 {
 118         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 119         e.ItemStatus &= ~ITS_STAYWEP;
 120         entity def = e.itemdef;
 121         if (mode > 0)
 122         {
 123                 // make the item look normal, and be touchable
 124                 e.model = e.mdl;
 125                 e.solid = SOLID_TRIGGER;
 126                 e.spawnshieldtime = 1;
 127                 e.ItemStatus |= ITS_AVAILABLE;
 128         }
 129         else if (mode < 0)
 130         {
 131                 // hide the item completely
 132                 e.model = string_null;
 133                 e.solid = SOLID_NOT;
 134                 e.spawnshieldtime = 1;
 135                 e.ItemStatus &= ~ITS_AVAILABLE;
 136         }
 137         else
 138         {
 139                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.m_wepset & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 140                         || e.team // weapon stay isn't supported for teamed weapons
 141                         ;
 142                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 143                 {
 144                         // make the item translucent and not touchable
 145                         e.model = e.mdl;
 146                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 147                         e.effects |= EF_STARDUST;
 148                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 149                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 150                 }
 151                 else
 152                 {
 153                         e.solid = SOLID_NOT;
 154                         e.spawnshieldtime = 1;
 155                         e.ItemStatus &= ~ITS_AVAILABLE;
 156                 }
 157         }
 158
 159         if (def.m_glow)
 160                 e.ItemStatus |= ITS_GLOW;
 161
 162         if (autocvar_g_nodepthtestitems)
 163                 e.effects |= EF_NODEPTHTEST;
 164
 165         if (autocvar_g_fullbrightitems)
 166                 e.ItemStatus |= ITS_ALLOWFB;
 167         else
 168                 e.ItemStatus &= ~ITS_ALLOWFB;
 169
 170         if (autocvar_sv_simple_items)
 171                 e.ItemStatus |= ITS_ALLOWSI;
 172
 173         // relink entity (because solid may have changed)
 174         setorigin(e, e.origin);
 175         e.SendFlags |= ISF_STATUS;
 176 }
 177
 178 void Item_Think(entity this)
 179 {
 180         if (ITEM_IS_LOOT(this))
 181         {
 182                 if (time < this.wait - IT_DESPAWNFX_TIME)
 183                         this.nextthink = min(time + IT_UPDATE_INTERVAL, this.wait - IT_DESPAWNFX_TIME); // ensuring full time for effects
 184                 else
 185                 {
 186                         // despawning soon, start effects
 187                         this.ItemStatus |= ITS_EXPIRING;
 188                         this.SendFlags |= ISF_STATUS;
 189                         if (time < this.wait - IT_UPDATE_INTERVAL)
 190                                 this.nextthink = time + IT_UPDATE_INTERVAL;
 191                         else
 192                         {
 193                                 setthink(this, RemoveItem);
 194                                 this.nextthink = this.wait;
 195                         }
 196                 }
 197
 198                 if (this.itemdef.instanceOfPowerup)
 199                         powerups_DropItem_Think(this);
 200
 201                 // caution: kludge FIXME (with sv_legacy_bbox_expand)
 202                 // this works around prediction errors caused by bbox discrepancy between SVQC and CSQC
 203                 if (this.velocity == '0 0 0' && IS_ONGROUND(this))
 204                         this.gravity = 0; // don't send ISF_DROP anymore
 205
 206                 // send slow updates even if the item didn't move
 207                 // recovers prediction desyncs where server thinks item stopped, client thinks it didn't
 208                 ItemUpdate(this);
 209         }
 210         else
 211         {
 212                 // bones_was_here: TODO: predict movers, enable client prediction of items with a groundentity,
 213                 // and then send those less often too (and not all on the same frame)
 214                 this.nextthink = time;
 215
 216                 if(this.origin != this.oldorigin)
 217                         ItemUpdate(this);
 218         }
 219 }
 220
 221 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 222 bool Item_ItemsTime_Allow(GameItem it);
 223 float Item_ItemsTime_UpdateTime(entity e, float t);
 224 void Item_ItemsTime_SetTime(entity e, float t);
 225 void Item_ItemsTime_SetTimesForAllPlayers();
 226
 227 void Item_Respawn(entity this)
 228 {
 229         Item_Show(this, 1);
 230         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 231
 232         if (Item_ItemsTime_Allow(this.itemdef) || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
 233         {
 234                 float t = Item_ItemsTime_UpdateTime(this, 0);
 235                 Item_ItemsTime_SetTime(this, t);
 236                 Item_ItemsTime_SetTimesForAllPlayers();
 237         }
 238
 239         setthink(this, Item_Think);
 240         this.nextthink = time;
 241 }
 242
 243 void Item_RespawnCountdown(entity this)
 244 {
 245         if(this.item_respawncounter >= ITEM_RESPAWN_TICKS)
 246         {
 247                 if(this.waypointsprite_attached)
 248                         WaypointSprite_Kill(this.waypointsprite_attached);
 249                 Item_Respawn(this);
 250         }
 251         else
 252         {
 253                 this.nextthink = time + 1;
 254                 this.item_respawncounter += 1;
 255                 if(this.item_respawncounter == 1)
 256                 {
 257                         do {
 258                                 {
 259                                         entity wi = REGISTRY_GET(Weapons, this.weapon);
 260                                         if (wi != WEP_Null) {
 261                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 262                                                 wp.wp_extra = wi.m_id;
 263                                                 break;
 264                                         }
 265                                 }
 266                                 {
 267                                         entity ii = this.itemdef;
 268                                         if (ii != NULL) {
 269                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 270                                                 wp.wp_extra = ii.m_id;
 271                                                 break;
 272                                         }
 273                                 }
 274                         } while (0);
 275                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 276                         if(this.waypointsprite_attached)
 277                         {
 278                                 GameItem def = this.itemdef;
 279                                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 280                                         WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 281                                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 282                         }
 283                 }
 284
 285                 if(this.waypointsprite_attached)
 286                 {
 287                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 288                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 289                                 {
 290                                         msg_entity = it;
 291                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM, 0); // play respawn sound
 292                                 }
 293                         });
 294
 295                         WaypointSprite_Ping(this.waypointsprite_attached);
 296                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.item_respawncounter);
 297                 }
 298         }
 299 }
 300
 301 void Item_RespawnThink(entity this)
 302 {
 303         this.nextthink = time;
 304         if(this.origin != this.oldorigin)
 305                 ItemUpdate(this);
 306
 307         if(time >= this.wait)
 308                 Item_Respawn(this);
 309 }
 310
 311 void Item_ScheduleRespawnIn(entity e, float t)
 312 {
 313         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 314         if ((Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 315         {
 316                 setthink(e, Item_RespawnCountdown);
 317                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 318                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 319                 e.item_respawncounter = 0;
 320                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
 321                 {
 322                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 323                         Item_ItemsTime_SetTime(e, t);
 324                         Item_ItemsTime_SetTimesForAllPlayers();
 325                 }
 326         }
 327         else
 328         {
 329                 setthink(e, Item_RespawnThink);
 330                 e.nextthink = time;
 331                 e.scheduledrespawntime = time + t;
 332                 e.wait = time + t;
 333
 334                 if(Item_ItemsTime_Allow(e.itemdef) || (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
 335                 {
 336                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 337                         Item_ItemsTime_SetTime(e, t);
 338                         Item_ItemsTime_SetTimesForAllPlayers();
 339                 }
 340         }
 341 }
 342
 343 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
 344 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
 345 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
 346
 347 /// Adjust respawn time according to the number of players.
 348 float adjust_respawntime(float normal_respawntime) {
 349         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
 350         float o = autocvar_g_pickup_respawntime_scaling_offset;
 351         float l = autocvar_g_pickup_respawntime_scaling_linear;
 352
 353         if (r == 0 && l == 1) {
 354                 return normal_respawntime;
 355         }
 356
 357         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 358         TeamBalance_GetTeamCounts(balance, NULL);
 359         int players = 0;
 360         for (int i = 1; i <= NUM_TEAMS; ++i)
 361         {
 362                 if (TeamBalance_IsTeamAllowed(balance, i))
 363                 {
 364                         players += TeamBalance_GetNumberOfPlayers(balance, i);
 365                 }
 366         }
 367         TeamBalance_Destroy(balance);
 368
 369         if (players >= 2) {
 370                 return normal_respawntime * (r / (players + o) + l);
 371         } else {
 372                 return normal_respawntime;
 373         }
 374 }
 375
 376 void Item_ScheduleRespawn(entity e)
 377 {
 378         if(e.respawntime > 0)
 379         {
 380                 Item_Show(e, 0);
 381
 382                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
 383                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
 384
 385                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
 386                 float respawn_in = adjusted_respawntime + crandom() * e.respawntimejitter;
 387                 Item_ScheduleRespawnIn(e, respawn_in);
 388         }
 389         else // if respawntime is -1, this item does not respawn
 390                 Item_Show(e, -1);
 391 }
 392
 393 AUTOCVAR(g_pickup_respawntime_initial_random, int, 1,
 394         "For items that don't start spawned: 0: spawn after their normal respawntime; 1: spawn after `random * respawntime` with the *same* random; 2: same as 1 but each item has separate random");
 395
 396 void Item_ScheduleInitialRespawn(entity e)
 397 {
 398         Item_Show(e, 0);
 399
 400         float spawn_in;
 401         if (autocvar_g_pickup_respawntime_initial_random == 0)
 402         {
 403                 // range: respawntime .. respawntime + respawntimejitter
 404                 spawn_in = e.respawntime + random() * e.respawntimejitter;
 405         }
 406         else
 407         {
 408                 float rnd;
 409                 if (autocvar_g_pickup_respawntime_initial_random == 1)
 410                 {
 411                         static float shared_random = 0;
 412                         // NOTE this code works only if items are scheduled at the same time (normal case)
 413                         // NOTE2 random() can't return exactly 1 so this check always work as intended
 414                         if (!shared_random || floor(time) > shared_random)
 415                                 shared_random = floor(time) + random();
 416                         rnd = shared_random - floor(time);
 417                 }
 418                 else
 419                         rnd = random();
 420
 421                 // range:
 422                 // if respawntime >= ITEM_RESPAWN_TICKS: ITEM_RESPAWN_TICKS .. respawntime + respawntimejitter
 423                 // else: 0 .. ITEM_RESPAWN_TICKS
 424                 // this is to prevent powerups spawning unexpectedly without waypoints
 425                 spawn_in = ITEM_RESPAWN_TICKS + rnd * (e.respawntime + e.respawntimejitter - ITEM_RESPAWN_TICKS);
 426         }
 427
 428         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : spawn_in));
 429 }
 430
 431 void GiveRandomWeapons(entity receiver, int num_weapons, string weapon_names,
 432         entity ammo_entity)
 433 {
 434         if (num_weapons == 0)
 435         {
 436                 return;
 437         }
 438         int num_potential_weapons = tokenize_console(weapon_names);
 439         for (int give_attempt = 0; give_attempt < num_weapons; ++give_attempt)
 440         {
 441                 RandomSelection_Init();
 442                 for (int weapon_index = 0; weapon_index < num_potential_weapons;
 443                         ++weapon_index)
 444                 {
 445                         string weapon = argv(weapon_index);
 446                         FOREACH(Weapons, it != WEP_Null,
 447                         {
 448                                 // Finding a weapon which player doesn't have.
 449                                 if (!(STAT(WEAPONS, receiver) & it.m_wepset) && (it.netname == weapon))
 450                                 {
 451                                         RandomSelection_AddEnt(it, 1, 1);
 452                                         break;
 453                                 }
 454                         });
 455                 }
 456                 if (RandomSelection_chosen_ent == NULL)
 457                 {
 458                         return;
 459                 }
 460                 STAT(WEAPONS, receiver) |= RandomSelection_chosen_ent.m_wepset;
 461                 if (RandomSelection_chosen_ent.ammo_type == RES_NONE)
 462                 {
 463                         continue;
 464                 }
 465                 if (GetResource(receiver,
 466                         RandomSelection_chosen_ent.ammo_type) != 0)
 467                 {
 468                         continue;
 469                 }
 470                 GiveResource(receiver, RandomSelection_chosen_ent.ammo_type,
 471                         GetResource(ammo_entity,
 472                         RandomSelection_chosen_ent.ammo_type));
 473         }
 474 }
 475
 476 bool Item_GiveAmmoTo(entity item, entity player, Resource res_type, float ammomax)
 477 {
 478         float amount = GetResource(item, res_type);
 479         if (amount == 0)
 480         {
 481                 return false;
 482         }
 483         float player_amount = GetResource(player, res_type);
 484         if (item.spawnshieldtime)
 485         {
 486                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
 487                         return false;
 488         }
 489         else if (g_weapon_stay == 2)
 490         {
 491                 ammomax = min(amount, ammomax);
 492                 if(player_amount >= ammomax)
 493                         return false;
 494         }
 495         else
 496                 return false;
 497         if (amount < 0)
 498                 TakeResourceWithLimit(player, res_type, -amount, ammomax);
 499         else
 500                 GiveResourceWithLimit(player, res_type, amount, ammomax);
 501         return true;
 502 }
 503
 504 void Item_NotifyWeapon(entity player, int wep)
 505 {
 506         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (it == player || (IS_SPEC(it) && it.enemy == player)), {
 507                 msg_entity = it;
 508                 WriteHeader(MSG_ONE, TE_CSQC_WEAPONPICKUP);
 509                 WriteByte(MSG_ONE, wep);
 510         });
 511 }
 512
 513 bool Item_GiveTo(entity item, entity player)
 514 {
 515         // if nothing happens to player, just return without taking the item
 516         int _switchweapon = 0;
 517         // in case the player has autoswitch enabled do the following:
 518         // if the player is using their best weapon before items are given, they
 519         // probably want to switch to an even better weapon after items are given
 520
 521         if(CS_CVAR(player).cvar_cl_autoswitch)
 522         {
 523                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 524                 {
 525                         .entity weaponentity = weaponentities[slot];
 526                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 527                         {
 528                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 529                                         _switchweapon |= BIT(slot);
 530
 531                                 if(!(STAT(WEAPONS, player) & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 532                                         _switchweapon |= BIT(slot);
 533                         }
 534                 }
 535         }
 536         bool pickedup = false;
 537         pickedup |= Item_GiveAmmoTo(item, player, RES_HEALTH, item.max_health);
 538         pickedup |= Item_GiveAmmoTo(item, player, RES_ARMOR, item.max_armorvalue);
 539         pickedup |= Item_GiveAmmoTo(item, player, RES_SHELLS, g_pickup_shells_max);
 540         pickedup |= Item_GiveAmmoTo(item, player, RES_BULLETS, g_pickup_nails_max);
 541         pickedup |= Item_GiveAmmoTo(item, player, RES_ROCKETS, g_pickup_rockets_max);
 542         pickedup |= Item_GiveAmmoTo(item, player, RES_CELLS, g_pickup_cells_max);
 543         pickedup |= Item_GiveAmmoTo(item, player, RES_PLASMA, g_pickup_plasma_max);
 544         pickedup |= Item_GiveAmmoTo(item, player, RES_FUEL, g_pickup_fuel_max);
 545         if (item.itemdef.instanceOfWeaponPickup)
 546         {
 547                 WepSet w, wp;
 548                 w = STAT(WEAPONS, item);
 549                 wp = w & ~STAT(WEAPONS, player);
 550
 551                 if (wp || (item.spawnshieldtime && item.pickup_anyway > 0))
 552                 {
 553                         pickedup = true;
 554                         FOREACH(Weapons, it != WEP_Null, {
 555                                 if(w & (it.m_wepset))
 556                                         Item_NotifyWeapon(player, it.m_id);
 557
 558                                 if(wp & (it.m_wepset))
 559                                 {
 560                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 561                                         {
 562                                                 .entity weaponentity = weaponentities[slot];
 563                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 564                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 565                                         }
 566                                         W_GiveWeapon(player, it.m_id);
 567                                 }
 568                         });
 569                 }
 570         }
 571
 572         if (item.itemdef.instanceOfPowerup)
 573         {
 574                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 575                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 576                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 577                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 578         }
 579
 580         int its;
 581         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 582         {
 583                 pickedup = true;
 584                 player.items |= its;
 585                 // TODO: we probably want to show a message in the console, but not this one!
 586                 //Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 587         }
 588
 589         if (item.strength_finished)
 590         {
 591                 pickedup = true;
 592                 float t = max(StatusEffects_gettime(STATUSEFFECT_Strength, player), time);
 593                 if (autocvar_g_powerups_stack)
 594                         t += item.strength_finished;
 595                 else
 596                         t = max(t, time + item.strength_finished);
 597                 StatusEffects_apply(STATUSEFFECT_Strength, player, t, 0);
 598         }
 599         if (item.invincible_finished)
 600         {
 601                 pickedup = true;
 602                 float t = max(StatusEffects_gettime(STATUSEFFECT_Shield, player), time);
 603                 if (autocvar_g_powerups_stack)
 604                         t += item.invincible_finished;
 605                 else
 606                         t = max(t, time + item.invincible_finished);
 607                 StatusEffects_apply(STATUSEFFECT_Shield, player, t, 0);
 608         }
 609         if (item.speed_finished)
 610         {
 611                 pickedup = true;
 612                 float t = max(StatusEffects_gettime(STATUSEFFECT_Speed, player), time);
 613                 if (autocvar_g_powerups_stack)
 614                         t += item.speed_finished;
 615                 else
 616                         t = max(t, time + item.speed_finished);
 617                 StatusEffects_apply(STATUSEFFECT_Speed, player, t, 0);
 618         }
 619         if (item.invisibility_finished)
 620         {
 621                 pickedup = true;
 622                 float t = max(StatusEffects_gettime(STATUSEFFECT_Invisibility, player), time);
 623                 if (autocvar_g_powerups_stack)
 624                         t += item.invisibility_finished;
 625                 else
 626                         t = max(t, time + item.invisibility_finished);
 627                 StatusEffects_apply(STATUSEFFECT_Invisibility, player, t, 0);
 628         }
 629         if (item.superweapons_finished)
 630         {
 631                 pickedup = true;
 632                 StatusEffects_apply(STATUSEFFECT_Superweapons, player, max(StatusEffects_gettime(STATUSEFFECT_Superweapons, player), time) + item.superweapons_finished, 0);
 633         }
 634
 635         // always eat teamed entities
 636         if(item.team)
 637                 pickedup = true;
 638
 639         if (!pickedup)
 640                 return false;
 641
 642         // crude hack to enforce switching weapons
 643         if(g_cts && item.itemdef.instanceOfWeaponPickup && !CS_CVAR(player).cvar_cl_cts_noautoswitch)
 644         {
 645                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 646                 {
 647                         .entity weaponentity = weaponentities[slot];
 648                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 649                                 W_SwitchWeapon_Force(player, REGISTRY_GET(Weapons, item.weapon), weaponentity);
 650                 }
 651                 return true;
 652         }
 653
 654         if(_switchweapon)
 655         {
 656                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 657                 {
 658                         .entity weaponentity = weaponentities[slot];
 659                         if(_switchweapon & BIT(slot))
 660                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 661                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 662                 }
 663         }
 664
 665         return true;
 666 }
 667
 668 void Item_Touch(entity this, entity toucher)
 669 {
 670         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 671         if (ITEM_IS_LOOT(this))
 672         {
 673                 if (ITEM_TOUCH_NEEDKILL())
 674                 {
 675                         this.SendFlags |= ISF_REMOVEFX;
 676                         RemoveItem(this);
 677                         return;
 678                 }
 679         }
 680
 681         if(!(toucher.flags & FL_PICKUPITEMS)
 682         || STAT(FROZEN, toucher)
 683         || IS_DEAD(toucher)
 684         || (this.solid != SOLID_TRIGGER)
 685         || (this.owner == toucher)
 686         || (time < this.item_spawnshieldtime)
 687         ) { return; }
 688
 689         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 690         {
 691                 case MUT_ITEMTOUCH_RETURN: { return; }
 692                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 693         }
 694
 695         toucher = M_ARGV(1, entity);
 696
 697         if (ITEM_IS_EXPIRING(this))
 698         {
 699                 this.strength_finished = max(0, this.strength_finished - time);
 700                 this.invincible_finished = max(0, this.invincible_finished - time);
 701                 this.speed_finished = max(0, this.speed_finished - time);
 702                 this.invisibility_finished = max(0, this.invisibility_finished - time);
 703                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 704         }
 705         bool gave = ITEM_HANDLE(Pickup, this.itemdef, this, toucher);
 706         if (!gave)
 707         {
 708                 if (ITEM_IS_EXPIRING(this))
 709                 {
 710                         // undo what we did above
 711                         this.strength_finished += time;
 712                         this.invincible_finished += time;
 713                         this.speed_finished += time;
 714                         this.invisibility_finished += time;
 715                         this.superweapons_finished += time;
 716                 }
 717                 return;
 718         }
 719
 720 LABEL(pickup)
 721
 722         if(this.target && this.target != "" && this.target != "###item###") // defrag support
 723                 SUB_UseTargets(this, toucher, NULL);
 724
 725         STAT(LAST_PICKUP, toucher) = time;
 726
 727         GameItem def = this.itemdef;
 728         int ch = ((def.instanceOfPowerup && def.m_itemid != IT_RESOURCE) ? CH_TRIGGER_SINGLE : CH_TRIGGER);
 729         _sound(toucher, ch, this.item_pickupsound, VOL_BASE, ATTEN_NORM);
 730
 731         MUTATOR_CALLHOOK(ItemTouched, this, toucher);
 732         if (wasfreed(this))
 733         {
 734                 return;
 735         }
 736
 737         if (ITEM_IS_LOOT(this))
 738         {
 739                 this.SendFlags |= ISF_REMOVEFX;
 740                 RemoveItem(this);
 741                 return;
 742         }
 743         if (!this.spawnshieldtime)
 744         {
 745                 return;
 746         }
 747         entity e;
 748         if (this.team)
 749         {
 750                 RandomSelection_Init();
 751                 IL_EACH(g_items, it.team == this.team,
 752                 {
 753                         if (it.itemdef) // is a registered item
 754                         {
 755                                 Item_Show(it, -1);
 756                                 it.scheduledrespawntime = 0;
 757                                 RandomSelection_AddEnt(it, it.cnt, 0);
 758                         }
 759                 });
 760                 e = RandomSelection_chosen_ent;
 761                 Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 762         }
 763         else
 764                 e = this;
 765         Item_ScheduleRespawn(e);
 766 }
 767
 768 void Item_Reset(entity this)
 769 {
 770         Item_Show(this, !this.state);
 771
 772         if (ITEM_IS_LOOT(this))
 773         {
 774                 return;
 775         }
 776         setthink(this, Item_Think);
 777         this.nextthink = time;
 778         if (this.waypointsprite_attached)
 779         {
 780                 WaypointSprite_Kill(this.waypointsprite_attached);
 781         }
 782         if (this.itemdef.instanceOfPowerup || (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 783         {
 784                 Item_ScheduleInitialRespawn(this);
 785         }
 786 }
 787
 788 void Item_FindTeam(entity this)
 789 {
 790         if(!(this.effects & EF_NOGUNBOB)) // marker for item team search
 791                 return;
 792
 793         LOG_TRACE("Initializing item team ", ftos(this.team));
 794         RandomSelection_Init();
 795         IL_EACH(g_items, it.team == this.team,
 796         {
 797                 if(it.itemdef) // is a registered item
 798                         RandomSelection_AddEnt(it, it.cnt, 0);
 799         });
 800
 801         entity e = RandomSelection_chosen_ent;
 802         if (!e)
 803                 return;
 804
 805         IL_EACH(g_items, it.team == this.team,
 806         {
 807                 if(it.itemdef) // is a registered item
 808                 {
 809                         if(it != e)
 810                         {
 811                                 Item_Show(it, -1); // make it non-spawned
 812                                 if (it.waypointsprite_attached)
 813                                         WaypointSprite_Kill(it.waypointsprite_attached);
 814                                 it.nextthink = 0; // disable any scheduled powerup spawn
 815                         }
 816                         else
 817                                 Item_Reset(it);
 818
 819                         // leave 'this' marked so Item_FindTeam() works when called again via this.reset
 820                         if(it != this)
 821                                 it.effects &= ~EF_NOGUNBOB;
 822                 }
 823         });
 824 }
 825
 826 void Item_CopyFields(entity this, entity to)
 827 {
 828         setorigin(to, this.origin);
 829         to.spawnflags = this.spawnflags;
 830         to.noalign = ITEM_SHOULD_KEEP_POSITION(this);
 831         to.cnt = this.cnt;
 832         to.team = this.team;
 833         to.spawnfunc_checked = true;
 834         // TODO: copy respawn times? this may not be desirable in some cases
 835         //to.respawntime = this.respawntime;
 836         //to.respawntimejitter = this.respawntimejitter;
 837 }
 838
 839 // Savage: used for item garbage-collection
 840 void RemoveItem(entity this)
 841 {
 842         if(wasfreed(this) || !this) { return; }
 843         if(this.waypointsprite_attached)
 844                 WaypointSprite_Kill(this.waypointsprite_attached);
 845
 846         if (this.SendFlags & ISF_REMOVEFX)
 847         {
 848                 // delay removal until ISF_REMOVEFX has been sent
 849                 setthink(this, RemoveItem);
 850                 this.nextthink = time + 2 * autocvar_sys_ticrate; // micro optimisation: next frame will be too soon
 851                 this.solid = SOLID_NOT; // untouchable
 852         }
 853         else
 854                 delete(this);
 855 }
 856
 857 // pickup evaluation functions
 858 // these functions decide how desirable an item is to the bots
 859
 860 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 861
 862 float weapon_pickupevalfunc(entity player, entity item)
 863 {
 864         // See if I have it already
 865         if(STAT(WEAPONS, player) & STAT(WEAPONS, item))
 866         {
 867                 // If I can pick it up
 868                 if(!item.spawnshieldtime)
 869                         return 0;
 870                 return ammo_pickupevalfunc(player, item);
 871         }
 872
 873         // reduce weapon value if bot already got a good arsenal
 874         float c = 1;
 875         int weapons_value = 0;
 876         FOREACH(Weapons, it != WEP_Null && (STAT(WEAPONS, player) & it.m_wepset), {
 877                 weapons_value += it.bot_pickupbasevalue;
 878         });
 879         c -= bound(0, weapons_value / 20000, 1) * 0.5;
 880
 881         return item.bot_pickupbasevalue * c;
 882 }
 883
 884 float ammo_pickupevalfunc(entity player, entity item)
 885 {
 886         entity item_resource = NULL; // pointer to the resource that may be associated with the given item
 887         entity wpn = NULL;
 888         float c = 0;
 889         float rating = 0;
 890
 891         // detect needed ammo
 892         if(item.itemdef.instanceOfWeaponPickup)
 893         {
 894                 entity res = item.itemdef.m_weapon.ammo_type;
 895                 entity ammo = (res != RES_NONE) ? GetAmmoItem(res) : NULL;
 896                 if(!ammo)
 897                         return 0;
 898                 if(res != RES_NONE && GetResource(item, res))
 899                         item_resource = res;
 900
 901                 wpn = item;
 902                 rating = ammo.m_botvalue;
 903         }
 904         else
 905         {
 906                 FOREACH(Weapons, it != WEP_Null, {
 907                         if(!(STAT(WEAPONS, player) & (it.m_wepset)))
 908                                 continue;
 909                         if(it.ammo_type == RES_NONE)
 910                                 continue;
 911
 912                         if(GetResource(item, it.ammo_type))
 913                         {
 914                                 item_resource = it.ammo_type;
 915                                 break;
 916                         }
 917                 });
 918                 rating = item.bot_pickupbasevalue;
 919         }
 920
 921         float noammorating = 0.5;
 922
 923         if(item_resource && (GetResource(player, item_resource) < GetResourceLimit(player, item_resource)))
 924                 c = GetResource(item, item_resource) / max(noammorating, GetResource(player, item_resource));
 925
 926         rating *= min(c, 2);
 927         if(wpn)
 928                 rating += wpn.bot_pickupbasevalue * 0.1;
 929         return rating;
 930 }
 931
 932 float healtharmor_pickupevalfunc(entity player, entity item)
 933 {
 934         float c = 0;
 935         float rating = item.bot_pickupbasevalue;
 936
 937         float itemarmor = GetResource(item, RES_ARMOR);
 938         float itemhealth = GetResource(item, RES_HEALTH);
 939
 940         if(item.item_group)
 941         {
 942                 itemarmor *= min(4, item.item_group_count);
 943                 itemhealth *= min(4, item.item_group_count);
 944         }
 945
 946         if (itemarmor && (GetResource(player, RES_ARMOR) < item.max_armorvalue))
 947                 c = itemarmor / max(1, GetResource(player, RES_ARMOR) * 2/3 + GetResource(player, RES_HEALTH) * 1/3);
 948
 949         if (itemhealth && (GetResource(player, RES_HEALTH) < item.max_health))
 950                 c = itemhealth / max(1, GetResource(player, RES_HEALTH));
 951
 952         rating *= min(2, c);
 953         return rating;
 954 }
 955
 956 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 957 {
 958         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 959                 RemoveItem(this);
 960 }
 961
 962 void item_use(entity this, entity actor, entity trigger)
 963 {
 964         // use the touch function to handle collection
 965         gettouch(this)(this, actor);
 966 }
 967
 968 void StartItem(entity this, entity def)
 969 {
 970         if (def.m_spawnfunc_hookreplace)
 971                 def = def.m_spawnfunc_hookreplace(def, this);
 972         this.itemdef = def;
 973         if (def.m_canonical_spawnfunc != "") // FIXME why do weapons set itemdef to an entity that doesn't have this?
 974                 this.classname = def.m_canonical_spawnfunc;
 975
 976         startitem_failed = true; // early return means failure
 977
 978         // some mutators check for resources set by m_iteminit in FilterItem
 979         if(def.m_iteminit)
 980                 def.m_iteminit(def, this);
 981
 982         // also checked by some mutators in FilterItem
 983         this.items = def.m_itemid;
 984         this.weapon = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
 985         if(this.weapon)
 986                 STAT(WEAPONS, this) = WepSet_FromWeapon(REGISTRY_GET(Weapons, this.weapon));
 987         this.flags = FL_ITEM | def.m_itemflags;
 988
 989         // FilterItem may change any field of a specific instance of an item, but
 990         // it must not change any itemdef field (would cause mutators to break other mutators),
 991         // and must not convert items into different ones (StartItem could be refactored to support that).
 992         if(MUTATOR_CALLHOOK(FilterItem, this))
 993         {
 994                 delete(this);
 995                 return;
 996         }
 997
 998         if (!this.item_model_ent)
 999                 this.item_model_ent = def.m_model;
1000
1001         if (!this.item_pickupsound_ent)
1002                 this.item_pickupsound_ent = def.m_sound;
1003         if (!this.item_pickupsound && this.item_pickupsound_ent)
1004                 this.item_pickupsound = Sound_fixpath(this.item_pickupsound_ent);
1005         if (this.item_pickupsound == "")
1006                 LOG_WARNF("No pickup sound set for a %s", this.classname);
1007
1008         if(!this.pickup_anyway && def.m_pickupanyway)
1009                 this.pickup_anyway = def.m_pickupanyway();
1010
1011         // bones_was_here TODO: implement sv_cullentities_dist and replace g_items_maxdist with it
1012         if(!this.fade_end)
1013                 this.fade_end = autocvar_g_items_maxdist;
1014
1015         // bones_was_here TODO: can we do this after we're sure the entity won't be deleted?
1016         IL_PUSH(g_items, this);
1017
1018         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1019         setmodel(this, MDL_Null); // precision set below
1020         // set item size before we spawn a waypoint or droptofloor or MoveOutOfSolid
1021         setsize (this, this.pos1 = def.m_mins, this.pos2 = def.m_maxs);
1022
1023         if (ITEM_IS_LOOT(this))
1024         {
1025                 this.reset = RemoveItem;
1026
1027                 set_movetype(this, MOVETYPE_TOSS);
1028                 this.gravity = 1;
1029
1030                 setthink(this, Item_Think);
1031                 this.nextthink = time + IT_UPDATE_INTERVAL;
1032                 this.wait = time + autocvar_g_items_dropped_lifetime;
1033
1034                 this.owner = NULL; // anyone can pick this up, including the player who threw it
1035                 this.item_spawnshieldtime = time + 0.5; // but not straight away
1036
1037                 this.takedamage = DAMAGE_YES;
1038                 this.event_damage = Item_Damage;
1039                 // enable this to have thrown items burn in lava
1040                 //this.damagedbycontents = true;
1041                 //IL_PUSH(g_damagedbycontents, this);
1042
1043                 if (ITEM_IS_EXPIRING(this))
1044                 {
1045                         // if item is worthless after a timer, have it expire then
1046                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1047                 }
1048
1049                 // don't drop if in a NODROP zone (such as lava)
1050                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1051                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1052                 {
1053                         delete(this);
1054                         return;
1055                 }
1056         }
1057         else
1058         {
1059                 this.reset = Item_Reset;
1060
1061                 // must be done after def.m_iteminit() as that may set ITEM_FLAG_MUTATORBLOCKED
1062                 if(!have_pickup_item(this))
1063                 {
1064                         delete(this);
1065                         return;
1066                 }
1067
1068                 // must be done before Item_Reset() and after MUTATORBLOCKED check (blocked items may have null func ptrs)
1069                 if(!this.respawntime) // both need to be set
1070                 {
1071                         if (def.m_respawntime)
1072                                 this.respawntime = def.m_respawntime();
1073                         else
1074                                 LOG_WARNF("Default respawntime for a %s is unavailable from its itemdef", this.classname);
1075
1076                         if (def.m_respawntimejitter)
1077                                 this.respawntimejitter = def.m_respawntimejitter();
1078                         else
1079                                 LOG_WARNF("Default respawntimejitter for a %s is unavailable from its itemdef", this.classname);
1080                 }
1081
1082                 if(this.angles != '0 0 0')
1083                         this.SendFlags |= ISF_ANGLES;
1084
1085                 if(q3compat && !this.team)
1086                 {
1087                         string t = GetField_fullspawndata(this, "team");
1088                         // bones_was_here: this hack is cheaper than changing to a .string strcmp()
1089                         if(t) this.team = crc16(false, t);
1090                 }
1091
1092                 // it's a level item
1093                 if(this.spawnflags & 1)
1094                         this.noalign = 1;
1095                 if (this.noalign > 0)
1096                         set_movetype(this, MOVETYPE_NONE);
1097                 else
1098                         set_movetype(this, MOVETYPE_TOSS);
1099                 // do item filtering according to game mode and other things
1100                 if (this.noalign <= 0)
1101                 {
1102                         // first nudge it off the floor a little bit to avoid math errors
1103                         setorigin(this, this.origin + '0 0 1');
1104                         // note droptofloor returns false if stuck/or would fall too far
1105                         if (!this.noalign)
1106                                 droptofloor(this);
1107                         waypoint_spawnforitem(this);
1108                 }
1109
1110                 /*
1111                  * can't do it that way, as it would break maps
1112                  * TODO make a target_give like entity another way, that perhaps has
1113                  * the weapon name in a key
1114                 if(this.targetname)
1115                 {
1116                         // target_give not yet supported; maybe later
1117                         print("removed targeted ", this.classname, "\n");
1118                         delete(this);
1119                         return;
1120                 }
1121                 */
1122
1123                 if(this.targetname != "" && (this.spawnflags & 16))
1124                         this.use = item_use;
1125
1126                 if(autocvar_spawn_debug >= 2)
1127                 {
1128                         // why not flags & fl_item?
1129                         FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1130                                 LOG_TRACE("XXX Found duplicated item: ", def.m_name, vtos(this.origin));
1131                                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1132                                 error("Mapper sucks.");
1133                         });
1134                         this.is_item = true;
1135                 }
1136
1137                 weaponsInMap |= WepSet_FromWeapon(REGISTRY_GET(Weapons, this.weapon));
1138
1139                 if (        def.instanceOfPowerup
1140                         ||  def.instanceOfWeaponPickup
1141                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1142                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1143                         || (def.m_itemid & (IT_KEY1 | IT_KEY2))
1144                 )
1145                 {
1146                         if(!this.target || this.target == "")
1147                                 this.target = "###item###"; // for finding the nearest item using findnearest
1148                 }
1149
1150                 Item_ItemsTime_SetTime(this, 0);
1151
1152                 this.glowmod = def.m_color;
1153         }
1154
1155         this.bot_pickup = true;
1156         this.bot_pickupevalfunc = def.m_pickupevalfunc;
1157         this.bot_pickupbasevalue = def.m_botvalue;
1158         this.netname = def.m_name;
1159         settouch(this, Item_Touch);
1160         //this.effects |= EF_LOWPRECISION;
1161
1162         // support skinned models for powerups
1163         if(!this.skin)
1164                 this.skin = def.m_skin;
1165
1166         if (!(this.spawnflags & 1024)) {
1167                 if(def.instanceOfPowerup)
1168                         this.ItemStatus |= ITS_ANIMATE1;
1169
1170                 if(GetResource(this, RES_ARMOR) || GetResource(this, RES_HEALTH))
1171                         this.ItemStatus |= ITS_ANIMATE2;
1172         }
1173
1174         if(def.instanceOfWeaponPickup)
1175         {
1176                 if (!ITEM_IS_LOOT(this)) // if dropped, colormap is already set up nicely
1177                         this.colormap = 1024; // color shirt=0 pants=0 grey
1178                 if (!(this.spawnflags & 1024))
1179                         this.ItemStatus |= ITS_ANIMATE1;
1180                 this.SendFlags |= ISF_COLORMAP;
1181         }
1182
1183         this.state = 0;
1184         if(this.team)
1185         {
1186                 if(!this.cnt)
1187                         this.cnt = 1; // item probability weight
1188
1189                 this.effects |= EF_NOGUNBOB; // marker for item team search
1190                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1191                 this.reset = Item_FindTeam;
1192         }
1193         else
1194                 Item_Reset(this);
1195
1196         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1197
1198         // call this hook after everything else has been done
1199         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1200         {
1201                 delete(this);
1202                 return;
1203         }
1204
1205         // we should be sure this item will spawn before loading its assets
1206         // CSQC handles model precaching: it may not use this model (eg simple items) and may not have connected yet
1207         //precache_model(this.mdl);
1208         precache_sound(this.item_pickupsound);
1209
1210         setItemGroup(this);
1211
1212         startitem_failed = false;
1213 }
1214
1215 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1216 int group_count = 1;
1217
1218 void setItemGroup(entity this)
1219 {
1220         if(!IS_SMALL(this.itemdef) || ITEM_IS_LOOT(this))
1221                 return;
1222
1223         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1224         {
1225                 if(!this.item_group)
1226                 {
1227                         if(!it.item_group)
1228                         {
1229                                 it.item_group = group_count;
1230                                 group_count++;
1231                         }
1232                         this.item_group = it.item_group;
1233                 }
1234                 else // spawning item is already part of a item_group X
1235                 {
1236                         if(!it.item_group)
1237                                 it.item_group = this.item_group;
1238                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1239                         {
1240                                 int grY = it.item_group;
1241                                 // move all items of item_group Y to item_group X
1242                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1243                                 {
1244                                         if(it.item_group == grY)
1245                                                 it.item_group = this.item_group;
1246                                 });
1247                         }
1248                 }
1249         });
1250 }
1251
1252 void setItemGroupCount()
1253 {
1254         for (int k = 1; k <= group_count; k++)
1255         {
1256                 int count = 0;
1257                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1258                 if (count)
1259                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1260         }
1261 }
1262
1263 void target_items_use(entity this, entity actor, entity trigger)
1264 {
1265         if(ITEM_IS_LOOT(actor))
1266         {
1267                 EXACTTRIGGER_TOUCH(this, trigger);
1268                 delete(actor);
1269                 return;
1270         }
1271
1272         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1273                 return;
1274
1275         if(trigger.solid == SOLID_TRIGGER)
1276         {
1277                 EXACTTRIGGER_TOUCH(this, trigger);
1278         }
1279
1280         IL_EACH(g_items, it.enemy == actor && ITEM_IS_LOOT(it),
1281         {
1282                 delete(it);
1283         });
1284
1285         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1286                 centerprint(actor, this.message);
1287 }
1288
1289 spawnfunc(target_items)
1290 {
1291         this.use = target_items_use;
1292         if(!this.strength_finished)
1293                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1294         if(!this.invincible_finished)
1295                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1296         if(!this.speed_finished)
1297                 this.speed_finished = autocvar_g_balance_powerup_speed_time;
1298         if(!this.invisibility_finished)
1299                 this.invisibility_finished = autocvar_g_balance_powerup_invisibility_time;
1300         if(!this.superweapons_finished)
1301                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1302
1303         string str;
1304         int n = tokenize_console(this.netname);
1305         if(argv(0) == "give")
1306         {
1307                 str = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1308         }
1309         else
1310         {
1311                 for(int j = 0; j < n; ++j)
1312                 {
1313                         // this is from a time when unlimited superweapons were handled together with ammo in some parts of the code
1314                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS;
1315                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_AMMO;
1316                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1317                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1318                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1319                         else if(argv(j) == "speed")                  this.items |= ITEM_Speed.m_itemid;
1320                         else if(argv(j) == "invisibility")           this.items |= ITEM_Invisibility.m_itemid;
1321                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1322                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1323                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1324                         else
1325                         {
1326                                 FOREACH(StatusEffect, it.instanceOfBuff,
1327                                 {
1328                                         string s = Buff_CompatName(argv(j));
1329                                         if(s == it.netname)
1330                                         {
1331                                                 this.buffdef = it;
1332                                                 if(!this.buffs_finished)
1333                                                         this.buffs_finished = it.m_time(it);
1334                                                 break;
1335                                         }
1336                                 });
1337                                 FOREACH(Weapons, it != WEP_Null, {
1338                                         string s = argv(j);
1339                                         if(s == it.netname || s == it.m_deprecated_netname)
1340                                         {
1341                                                 STAT(WEAPONS, this) |= (it.m_wepset);
1342                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1343                                                         it.wr_init(it);
1344                                                 break;
1345                                         }
1346                                 });
1347                         }
1348                 }
1349
1350                 string itemprefix, valueprefix;
1351                 if(this.spawnflags == 0)
1352                 {
1353                         itemprefix = "";
1354                         valueprefix = "";
1355                 }
1356                 else if(this.spawnflags == 1)
1357                 {
1358                         itemprefix = "max ";
1359                         valueprefix = "max ";
1360                 }
1361                 else if(this.spawnflags == 2)
1362                 {
1363                         itemprefix = "min ";
1364                         valueprefix = "min ";
1365                 }
1366                 else if(this.spawnflags == 4)
1367                 {
1368                         itemprefix = "minus ";
1369                         valueprefix = "max ";
1370                 }
1371                 else
1372                 {
1373                         error("invalid spawnflags");
1374                         itemprefix = valueprefix = string_null;
1375                 }
1376
1377                 str = "";
1378                 str = sprintf("%s %s%d %s", str, itemprefix, boolean(this.items & IT_UNLIMITED_AMMO), "unlimited_weapon_ammo");
1379                 str = sprintf("%s %s%d %s", str, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1380                 str = sprintf("%s %s%d %s", str, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1381                 str = sprintf("%s %s%d %s", str, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1382                 str = sprintf("%s %s%d %s", str, valueprefix, this.invisibility_finished * boolean(this.items & ITEM_Invisibility.m_itemid), "invisibility");
1383                 str = sprintf("%s %s%d %s", str, valueprefix, this.speed_finished * boolean(this.items & ITEM_Speed.m_itemid), "speed");
1384                 str = sprintf("%s %s%d %s", str, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1385                 str = sprintf("%s %s%d %s", str, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1386                 str = sprintf("%s %s%d %s", str, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1387                 float res;
1388                 res = GetResource(this, RES_SHELLS);  if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "shells");
1389                 res = GetResource(this, RES_BULLETS); if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "nails");
1390                 res = GetResource(this, RES_ROCKETS); if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "rockets");
1391                 res = GetResource(this, RES_CELLS);   if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "cells");
1392                 res = GetResource(this, RES_PLASMA);  if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "plasma");
1393                 res = GetResource(this, RES_FUEL);    if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "fuel");
1394                 res = GetResource(this, RES_HEALTH);  if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "health");
1395                 res = GetResource(this, RES_ARMOR);   if(res != 0) str = sprintf("%s %s%d %s", str, valueprefix, max(0, res), "armor");
1396                 FOREACH(StatusEffect, it.instanceOfBuff, str = sprintf("%s %s%d %s", str, valueprefix, this.buffs_finished * boolean(this.buffdef == it), it.netname));
1397                 FOREACH(Weapons, it != WEP_Null, str = sprintf("%s %s%d %s", str, itemprefix, !!(STAT(WEAPONS, this) & (it.m_wepset)), it.netname));
1398         }
1399         this.netname = strzone(str);
1400
1401         n = tokenize_console(this.netname);
1402         for(int j = 0; j < n; ++j)
1403         {
1404                 string cmd = argv(j);
1405                 FOREACH(Weapons, it != WEP_Null && (cmd == it.netname || cmd == it.m_deprecated_netname), {
1406                         it.wr_init(it);
1407                         break;
1408                 });
1409         }
1410 }
1411
1412 float GiveWeapon(entity e, float wpn, float op, float val)
1413 {
1414         WepSet v0, v1;
1415         WepSet s = WepSet_FromWeapon(REGISTRY_GET(Weapons, wpn));
1416         v0 = (STAT(WEAPONS, e) & s);
1417         switch(op)
1418         {
1419                 case OP_SET:
1420                         if(val > 0)
1421                                 STAT(WEAPONS, e) |= s;
1422                         else
1423                                 STAT(WEAPONS, e) &= ~s;
1424                         break;
1425                 case OP_MIN:
1426                 case OP_PLUS:
1427                         if(val > 0)
1428                                 STAT(WEAPONS, e) |= s;
1429                         break;
1430                 case OP_MAX:
1431                         if(val <= 0)
1432                                 STAT(WEAPONS, e) &= ~s;
1433                         break;
1434                 case OP_MINUS:
1435                         if(val > 0)
1436                                 STAT(WEAPONS, e) &= ~s;
1437                         break;
1438         }
1439         v1 = (STAT(WEAPONS, e) & s);
1440         return (v0 != v1);
1441 }
1442
1443 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1444 {
1445         bool had_buff = StatusEffects_active(thebuff, e);
1446         float new_buff_time = ((had_buff) ? StatusEffects_gettime(thebuff, e) : 0);
1447         switch (op)
1448         {
1449                 case OP_SET:
1450                         new_buff_time = val;
1451                         break;
1452                 case OP_MIN:
1453                         new_buff_time = max(new_buff_time, val);
1454                         break;
1455                 case OP_MAX:
1456                         new_buff_time = min(new_buff_time, val);
1457                         break;
1458                 case OP_PLUS:
1459                         new_buff_time += val;
1460                         break;
1461                 case OP_MINUS:
1462                         new_buff_time -= val;
1463                         break;
1464         }
1465         if(new_buff_time <= 0)
1466         {
1467                 if(had_buff) // only trigger removal mechanics if there is an effect to remove!
1468                         StatusEffects_remove(thebuff, e, STATUSEFFECT_REMOVE_NORMAL);
1469         }
1470         else
1471         {
1472                 buff_RemoveAll(e, STATUSEFFECT_REMOVE_CLEAR); // clear old buffs on the player first!
1473                 StatusEffects_apply(thebuff, e, new_buff_time, 0);
1474         }
1475         bool have_buff = StatusEffects_active(thebuff, e);
1476         return (had_buff != have_buff);
1477 }
1478
1479 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1480 {
1481         if(v1 == v0)
1482                 return;
1483         if(v1 <= v0 - t)
1484         {
1485                 if(snd_decr != NULL)
1486                         sound(e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1487         }
1488         else if(v0 >= v0 + t)
1489         {
1490                 if(snd_incr != NULL)
1491                         sound(e, ((snd_incr == SND_POWERUP) ? CH_TRIGGER_SINGLE : CH_TRIGGER), snd_incr, VOL_BASE, ATTEN_NORM);
1492         }
1493 }
1494
1495 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1496 {
1497         if(v0 < v1)
1498                 e.(rotfield) = max(e.(rotfield), time + rottime);
1499         else if(v0 > v1)
1500                 e.(regenfield) = max(e.(regenfield), time + regentime);
1501 }
1502 bool GiveResourceValue(entity e, Resource res_type, int op, int val)
1503 {
1504         int v0 = GetResource(e, res_type);
1505         float new_val = 0;
1506         switch (op)
1507         {
1508                 // min 100 cells = at least 100 cells
1509                 case OP_SET: new_val = val; break;
1510                 case OP_MIN: new_val = max(v0, val); break;
1511                 case OP_MAX: new_val = min(v0, val); break;
1512                 case OP_PLUS: new_val = v0 + val; break;
1513                 case OP_MINUS: new_val = v0 - val; break;
1514                 default: return false;
1515         }
1516
1517         return SetResourceExplicit(e, res_type, new_val);
1518 }
1519 bool GiveStatusEffect(entity e, StatusEffects this, int op, float val)
1520 {
1521         bool had_eff = StatusEffects_active(this, e);
1522         float new_eff_time = ((had_eff) ? StatusEffects_gettime(this, e) : 0);
1523         switch (op)
1524         {
1525                 case OP_SET:
1526                         new_eff_time = val;
1527                         break;
1528                 case OP_MIN:
1529                         new_eff_time = max(new_eff_time, val);
1530                         break;
1531                 case OP_MAX:
1532                         new_eff_time = min(new_eff_time, val);
1533                         break;
1534                 case OP_PLUS:
1535                         new_eff_time += val;
1536                         break;
1537                 case OP_MINUS:
1538                         new_eff_time -= val;
1539                         break;
1540         }
1541         if(new_eff_time <= 0)
1542         {
1543                 if(had_eff) // only trigger removal mechanics if there is an effect to remove!
1544                         StatusEffects_remove(this, e, STATUSEFFECT_REMOVE_NORMAL);
1545         }
1546         else
1547                 StatusEffects_apply(this, e, new_eff_time, 0);
1548         bool have_eff = StatusEffects_active(this, e);
1549         return (had_eff != have_eff);
1550 }
1551
1552 float GiveItems(entity e, float beginarg, float endarg)
1553 {
1554         float got, i, val, op;
1555         string cmd;
1556
1557         val = 999;
1558         op = OP_SET;
1559
1560         got = 0;
1561
1562         int _switchweapon = 0;
1563
1564         if(CS_CVAR(e).cvar_cl_autoswitch)
1565         {
1566                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1567                 {
1568                         .entity weaponentity = weaponentities[slot];
1569                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1570                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1571                                 _switchweapon |= BIT(slot);
1572                 }
1573         }
1574
1575         if(e.statuseffects)
1576         {
1577                 FOREACH(StatusEffect, true,
1578                 {
1579                         e.statuseffects.statuseffect_time[it.m_id] = max(0, e.statuseffects.statuseffect_time[it.m_id] - time);
1580                 });
1581         }
1582
1583         PREGIVE(e, items);
1584         PREGIVE_WEAPONS(e);
1585         PREGIVE_STATUSEFFECT(e, STATUSEFFECT_Strength);
1586         PREGIVE_STATUSEFFECT(e, STATUSEFFECT_Shield);
1587         PREGIVE_STATUSEFFECT(e, STATUSEFFECT_Speed);
1588         PREGIVE_STATUSEFFECT(e, STATUSEFFECT_Invisibility);
1589         //PREGIVE_STATUSEFFECT(e, STATUSEFFECT_Superweapons);
1590         PREGIVE_RESOURCE(e, RES_BULLETS);
1591         PREGIVE_RESOURCE(e, RES_CELLS);
1592         PREGIVE_RESOURCE(e, RES_PLASMA);
1593         PREGIVE_RESOURCE(e, RES_SHELLS);
1594         PREGIVE_RESOURCE(e, RES_ROCKETS);
1595         PREGIVE_RESOURCE(e, RES_FUEL);
1596         PREGIVE_RESOURCE(e, RES_ARMOR);
1597         PREGIVE_RESOURCE(e, RES_HEALTH);
1598
1599         for(i = beginarg; i < endarg; ++i)
1600         {
1601                 cmd = argv(i);
1602
1603                 if(cmd == "0" || stof(cmd))
1604                 {
1605                         val = stof(cmd);
1606                         continue;
1607                 }
1608                 switch(cmd)
1609                 {
1610                         case "no":
1611                                 op = OP_MAX;
1612                                 val = 0;
1613                                 continue;
1614                         case "max":
1615                                 op = OP_MAX;
1616                                 continue;
1617                         case "min":
1618                                 op = OP_MIN;
1619                                 continue;
1620                         case "plus":
1621                                 op = OP_PLUS;
1622                                 continue;
1623                         case "minus":
1624                                 op = OP_MINUS;
1625                                 continue;
1626                         case "ALL":
1627                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1628                                 FOREACH(StatusEffect, it.instanceOfPowerups, got += GiveStatusEffect(e, it, op, val));
1629                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS, op, val);
1630                         case "all":
1631                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1632                                 got += GiveResourceValue(e, RES_HEALTH, op, val);
1633                                 got += GiveResourceValue(e, RES_ARMOR, op, val);
1634                         case "allweapons":
1635                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)), got += GiveWeapon(e, it.m_id, op, val));
1636                         //case "allbuffs": // all buffs makes a player god, do not want!
1637                                 //FOREACH(StatusEffect, it.instanceOfBuff, got += GiveBuff(e, it, op, val));
1638                         case "allammo":
1639                                 got += GiveResourceValue(e, RES_CELLS, op, val);
1640                                 got += GiveResourceValue(e, RES_PLASMA, op, val);
1641                                 got += GiveResourceValue(e, RES_SHELLS, op, val);
1642                                 got += GiveResourceValue(e, RES_BULLETS, op, val);
1643                                 got += GiveResourceValue(e, RES_ROCKETS, op, val);
1644                                 got += GiveResourceValue(e, RES_FUEL, op, val);
1645                                 break;
1646                         case "unlimited_ammo":
1647                                 // this is from a time when unlimited superweapons were handled together with ammo in some parts of the code
1648                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS, op, val);
1649                                 break;
1650                         case "unlimited_weapon_ammo":
1651                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1652                                 break;
1653                         case "unlimited_superweapons":
1654                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1655                                 break;
1656                         case "jetpack":
1657                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1658                                 break;
1659                         case "fuel_regen":
1660                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1661                                 break;
1662                         case "strength":
1663                                 got += GiveStatusEffect(e, STATUSEFFECT_Strength, op, val);
1664                                 break;
1665                         case "invincible":
1666                         case "shield":
1667                                 got += GiveStatusEffect(e, STATUSEFFECT_Shield, op, val);
1668                                 break;
1669                         case "speed":
1670                                 got += GiveStatusEffect(e, STATUSEFFECT_Speed, op, val);
1671                                 break;
1672                         case "invisibility":
1673                                 got += GiveStatusEffect(e, STATUSEFFECT_Invisibility, op, val);
1674                                 break;
1675                         case "superweapons":
1676                                 got += GiveStatusEffect(e, STATUSEFFECT_Superweapons, op, val);
1677                                 break;
1678                         case "cells":
1679                                 got += GiveResourceValue(e, RES_CELLS, op, val);
1680                                 break;
1681                         case "plasma":
1682                                 got += GiveResourceValue(e, RES_PLASMA, op, val);
1683                                 break;
1684                         case "shells":
1685                                 got += GiveResourceValue(e, RES_SHELLS, op, val);
1686                                 break;
1687                         case "nails":
1688                         case "bullets":
1689                                 got += GiveResourceValue(e, RES_BULLETS, op, val);
1690                                 break;
1691                         case "rockets":
1692                                 got += GiveResourceValue(e, RES_ROCKETS, op, val);
1693                                 break;
1694                         case "health":
1695                                 got += GiveResourceValue(e, RES_HEALTH, op, val);
1696                                 break;
1697                         case "armor":
1698                                 got += GiveResourceValue(e, RES_ARMOR, op, val);
1699                                 break;
1700                         case "fuel":
1701                                 got += GiveResourceValue(e, RES_FUEL, op, val);
1702                                 break;
1703                         default:
1704                                 FOREACH(StatusEffect, it.instanceOfBuff && buff_Available(it) && Buff_CompatName(cmd) == it.netname,
1705                                 {
1706                                         got += GiveBuff(e, it, op, val);
1707                                         break;
1708                                 });
1709                                 FOREACH(Weapons, it != WEP_Null && (cmd == it.netname || cmd == it.m_deprecated_netname), {
1710                     got += GiveWeapon(e, it.m_id, op, val);
1711                     break;
1712                                 });
1713                                 break;
1714                 }
1715                 val = 999;
1716                 op = OP_SET;
1717         }
1718
1719         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1720         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1721         POSTGIVE_BIT(e, items, IT_UNLIMITED_AMMO, SND_POWERUP, SND_POWEROFF);
1722         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1723         FOREACH(Weapons, it != WEP_Null, {
1724                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1725                 if(!(save_weapons & (it.m_wepset)))
1726                         if(STAT(WEAPONS, e) & (it.m_wepset))
1727                                 it.wr_init(it);
1728         });
1729         POSTGIVE_STATUSEFFECT(e, STATUSEFFECT_Strength, SND_POWERUP, SND_POWEROFF);
1730         POSTGIVE_STATUSEFFECT(e, STATUSEFFECT_Shield, SND_POWERUP, SND_POWEROFF);
1731         POSTGIVE_STATUSEFFECT(e, STATUSEFFECT_Speed, SND_POWERUP, SND_POWEROFF);
1732         POSTGIVE_STATUSEFFECT(e, STATUSEFFECT_Invisibility, SND_POWERUP, SND_POWEROFF);
1733         POSTGIVE_RESOURCE(e, RES_BULLETS, 0, SND_ITEMPICKUP, SND_Null);
1734         POSTGIVE_RESOURCE(e, RES_CELLS, 0, SND_ITEMPICKUP, SND_Null);
1735         POSTGIVE_RESOURCE(e, RES_PLASMA, 0, SND_ITEMPICKUP, SND_Null);
1736         POSTGIVE_RESOURCE(e, RES_SHELLS, 0, SND_ITEMPICKUP, SND_Null);
1737         POSTGIVE_RESOURCE(e, RES_ROCKETS, 0, SND_ITEMPICKUP, SND_Null);
1738         POSTGIVE_RES_ROT(e, RES_FUEL, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1739         POSTGIVE_RES_ROT(e, RES_ARMOR, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1740         POSTGIVE_RES_ROT(e, RES_HEALTH, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1741
1742         if(!StatusEffects_active(STATUSEFFECT_Superweapons, e))
1743         {
1744                 if(!g_weaponarena && (STAT(WEAPONS, e) & WEPSET_SUPERWEAPONS))
1745                         StatusEffects_apply(STATUSEFFECT_Superweapons, e, autocvar_g_balance_superweapons_time, 0);
1746         }
1747
1748         if(e.statuseffects)
1749         {
1750                 FOREACH(StatusEffect, true,
1751                 {
1752                         if(e.statuseffects.statuseffect_time[it.m_id] <= 0)
1753                                 e.statuseffects.statuseffect_time[it.m_id] = 0;
1754                         else
1755                                 e.statuseffects.statuseffect_time[it.m_id] += time;
1756                 });
1757
1758                 StatusEffects_update(e);
1759         }
1760
1761         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1762         {
1763                 .entity weaponentity = weaponentities[slot];
1764                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1765                 if(!(STAT(WEAPONS, e) & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1766                         _switchweapon |= BIT(slot);
1767         }
1768
1769         if(_switchweapon)
1770         {
1771                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1772                 {
1773                         .entity weaponentity = weaponentities[slot];
1774                         if(_switchweapon & BIT(slot))
1775                         {
1776                                 Weapon wep = w_getbestweapon(e, weaponentity);
1777                                 if(wep != e.(weaponentity).m_switchweapon)
1778                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1779                         }
1780                 }
1781         }
1782
1783         return got;
1784 }