qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59
  60 float IsDifferentTeam(entity a, entity b)
  61 {
  62         if(teamplay)
  63         {
  64                 if(a.team == b.team)
  65                         return 0;
  66         }
  67         else
  68         {
  69                 if(a == b)
  70                         return 0;
  71         }
  72         return 1;
  73 }
  74
  75 float IsFlying(entity a)
  76 {
  77         if(a.flags & FL_ONGROUND)
  78                 return 0;
  79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  80                 return 0;
  81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  82         if(trace_fraction < 1)
  83                 return 0;
  84         return 1;
  85 }
  86
  87 void UpdateFrags(entity player, float f)
  88 {
  89         PlayerTeamScore_AddScore(player, f);
  90 }
  91
  92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  93 void W_SwitchWeapon_Force(entity e, float w);
  94 entity GiveFrags_randomweapons;
  95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  96 {
  97         // TODO route through PlayerScores instead
  98         if(gameover) return;
  99
 100         if(f < 0)
 101         {
 102                 if(targ == attacker)
 103                 {
 104                         // suicide
 105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 106                 }
 107                 else
 108                 {
 109                         // teamkill
 110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 111                 }
 112         }
 113         else
 114         {
 115                 // regular frag
 116                 PlayerScore_Add(attacker, SP_KILLS, 1);
 117                 if(targ.playerid)
 118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 119         }
 120
 121         PlayerScore_Add(targ, SP_DEATHS, 1);
 122
 123         if(g_arena || g_ca)
 124                 if(autocvar_g_arena_roundbased)
 125                         return;
 126
 127         if(targ != attacker) // not for suicides
 128         if(g_weaponarena_random)
 129         {
 130                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 131                 float culprit;
 132                 culprit = DEATH_WEAPONOF(deathtype);
 133                 if(!culprit)
 134                         culprit = attacker.weapon;
 135                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 136                         culprit = attacker.weapon;
 137
 138                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 139                 {
 140                         // no exchange
 141                 }
 142                 else
 143                 {
 144                         if(!GiveFrags_randomweapons)
 145                         {
 146                                 GiveFrags_randomweapons = spawn();
 147                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 148                         }
 149
 150                         if(inWarmupStage)
 151                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 152                         else
 153                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 154
 155                         // all others (including the culprit): remove
 156                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 157                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 158
 159                         // among the remaining ones, choose one by random
 160                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 161
 162                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 163                         {
 164                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 165                                 WEPSET_ANDNOT_EW(attacker, culprit);
 166                         }
 167                 }
 168
 169                 // after a frag, choose another random weapon set
 170                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 171                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 172         }
 173
 174         // FIXME fix the mess this is (we have REAL points now!)
 175         entity oldself;
 176         oldself = self;
 177         self = attacker;
 178         frag_attacker = attacker;
 179         frag_target = targ;
 180         frag_score = f;
 181         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 182         {
 183                 f = frag_score;
 184                 self = oldself;
 185         }
 186         else
 187         {
 188                 self = oldself;
 189                 if(g_runematch)
 190                 {
 191                         f = RunematchHandleFrags(attacker, targ, f);
 192                 }
 193                 else if(g_lms)
 194                 {
 195                         // remove a life
 196                         float tl;
 197                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 198                         if(tl < lms_lowest_lives)
 199                                 lms_lowest_lives = tl;
 200                         if(tl <= 0)
 201                         {
 202                                 if(!lms_next_place)
 203                                         lms_next_place = player_count;
 204                                 else
 205                                         lms_next_place = min(lms_next_place, player_count);
 206                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 207                                 --lms_next_place;
 208                         }
 209                         f = 0;
 210                 }
 211         }
 212
 213         attacker.totalfrags += f;
 214
 215         if(f)
 216                 UpdateFrags(attacker, f);
 217 }
 218
 219 string AppendItemcodes(string s, entity player)
 220 {
 221         float w;
 222         w = player.weapon;
 223         //if(w == 0)
 224         //      w = player.switchweapon;
 225         if(w == 0)
 226                 w = player.cnt; // previous weapon!
 227         s = strcat(s, ftos(w));
 228         if(time < player.strength_finished)
 229                 s = strcat(s, "S");
 230         if(time < player.invincible_finished)
 231                 s = strcat(s, "I");
 232         if(player.flagcarried != world)
 233                 s = strcat(s, "F");
 234         if(player.BUTTON_CHAT)
 235                 s = strcat(s, "T");
 236         if(player.kh_next)
 237                 s = strcat(s, "K");
 238         if(player.runes)
 239                 s = strcat(s, "|", ftos(player.runes));
 240         return s;
 241 }
 242
 243 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 244 {
 245         string s;
 246         if(!autocvar_sv_eventlog)
 247                 return;
 248         s = strcat(":kill:", mode);
 249         s = strcat(s, ":", ftos(killer.playerid));
 250         s = strcat(s, ":", ftos(killed.playerid));
 251         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 252         s = strcat(s, ":items=");
 253         s = AppendItemcodes(s, killer);
 254         if(killed != killer)
 255         {
 256                 s = strcat(s, ":victimitems=");
 257                 s = AppendItemcodes(s, killed);
 258         }
 259         GameLogEcho(s);
 260 }
 261
 262 #define INFO_NO_MSG 0 // so that compilation works with the INFO_##msg_death stuff
 263 void Obituary_SpecialDeath(entity notif_target, float murder, float deathtype, string s1, string s2, string s3, float f1, float f2, float f3)
 264 {
 265         float handled = 0, hits = 0;
 266         if(DEATH_ISSPECIAL(deathtype))
 267         {
 268                 #define DEATHTYPE(name,msg_death,msg_death_by,position) \
 269                         { if(deathtype == max(0, name)) \
 270                         { \
 271                                 #if msg_death != NO_MSG \
 272                                         if not(murder) \
 273                                         { \
 274                                                 Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_MULTI, msg_death, s1, s2, s3, "", f1, f2, f3, 0); \
 275                                                 Send_Notification_WOVA(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, INFO_##msg_death, s1, s2, s3, "", f1, f2, f3, 0); \
 276                                                 ++handled; \
 277                                         } \
 278                                 #endif \
 279                                 #if msg_death_by != NO_MSG \
 280                                         if(murder) \
 281                                         { \
 282                                                 Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_MULTI, msg_death_by, s1, s2, s3, "", f1, f2, f3, 0); \
 283                                                 Send_Notification_WOVA(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, INFO_##msg_death_by, s1, s2, s3, "", f1, f2, f3, 0); \
 284                                                 ++handled; \
 285                                         } \
 286                                 #endif \
 287                                 ++hits; \
 288                         } }
 289
 290                 DEATHTYPES
 291                 #undef DEATHTYPE
 292
 293                 if not(hits)
 294                 {
 295                         backtrace("Obituary_SpecialDeath(): Unhandled deathtype- Please notify Samual!\n");
 296                 }
 297                 if not(handled)
 298                 {
 299                         dprint(sprintf("Obituary_SpecialDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification!\n", Deathtype_Name(deathtype), deathtype));
 300                         return;
 301                 }
 302         }
 303 }
 304
 305 float w_deathtype;
 306 float Obituary_WeaponDeath(entity notif_target, float murder, float deathtype, string s1, string s2, string s3, float f1, float f2)
 307 {
 308         float death_weapon = DEATH_WEAPONOF(deathtype);
 309         if(death_weapon)
 310         {
 311                 w_deathtype = deathtype;
 312                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 313                 w_deathtype = FALSE;
 314
 315                 if(death_message)
 316                 {
 317                         Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_MULTI, death_message, s1, s2, s3, "", f1, f2, 0, 0);
 318                         Send_Notification_WOVA(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, msg_multi_notifs[death_message - 1].nent_msginfo.nent_id, s1, s2, s3, "", f1, f2, 0, 0);
 319                 }
 320                 else { dprint(sprintf("Obituary_WeaponDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification for weapon %d!\n", Deathtype_Name(deathtype), deathtype, death_weapon)); }
 321
 322                 return TRUE;
 323         }
 324         return FALSE;
 325 }
 326
 327 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 328 {
 329         // Sanity check
 330         if not(targ.classname == STR_PLAYER) { backtrace("Obituary called on non-player?!\n"); return; }
 331
 332         // Declarations
 333         float notif_firstblood = FALSE;
 334         float kill_count_to_attacker, kill_count_to_target;
 335
 336         // Set final information for the death
 337         targ.death_origin = targ.origin;
 338         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 339         string deathlocation = NearestLocation(targ.death_origin);
 340
 341         #ifdef NOTIFICATIONS_DEBUG
 342         dprint(
 343                 sprintf("Obituary(%s, %s, %s, %s = %d);\n",
 344                         attacker.netname,
 345                         inflictor.netname,
 346                         targ.netname,
 347                         Deathtype_Name(deathtype),
 348                         deathtype
 349                 )
 350         );
 351         #endif
 352
 353         // =======
 354         // SUICIDE
 355         // =======
 356         if(targ == attacker)
 357         {
 358                 if(DEATH_ISSPECIAL(deathtype))
 359                 {
 360                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 361                         {
 362                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
 363                         }
 364                         else
 365                         {
 366                                 switch(deathtype)
 367                                 {
 368                                         case DEATH_MIRRORDAMAGE:
 369                                         {
 370                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 371                                                 break;
 372                                         }
 373
 374                                         default:
 375                                         {
 376                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 377                                                 break;
 378                                         }
 379                                 }
 380                                 LogDeath("suicide", deathtype, targ, targ);
 381                                 GiveFrags(attacker, targ, -1, deathtype);
 382                         }
 383                 }
 384                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
 385                 {
 386                         backtrace("SUICIDE: what the hell happened here?\n");
 387                 }
 388         }
 389
 390         // ======
 391         // MURDER
 392         // ======
 393         else if(attacker.classname == "player")
 394         {
 395                 if(!IsDifferentTeam(attacker, targ))
 396                 {
 397                         LogDeath("tk", deathtype, attacker, targ);
 398                         GiveFrags(attacker, targ, -1, deathtype);
 399
 400                         attacker.killcount = 0;
 401
 402                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
 403                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
 404                         Send_Notification(NOTIF_ANY, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, targ.killcount);
 405
 406                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 407                         // No need for specific death/weapon messages...
 408                 }
 409                 else
 410                 {
 411                         LogDeath("frag", deathtype, attacker, targ);
 412                         GiveFrags(attacker, targ, 1, deathtype);
 413
 414                         attacker.taunt_soundtime = time + 1;
 415                         attacker.killcount = attacker.killcount + 1;
 416
 417                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 418                                 case counta: \
 419                                 { \
 420                                         AnnounceTo(attacker, strcat(#countb, "kills")); \
 421                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
 422                                         break; \
 423                                 }
 424                         switch(attacker.killcount)
 425                         {
 426                                 KILL_SPREE_LIST
 427                                 default: break;
 428                         }
 429                         #undef SPREE_ITEM
 430
 431                         if(!checkrules_firstblood)
 432                         {
 433                                 checkrules_firstblood = TRUE;
 434                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 435                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 436                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 437
 438                                 // tell spree_inf and spree_cen that this is a first-blood and first-victim event
 439                                 kill_count_to_attacker = -1;
 440                                 kill_count_to_target = -2;
 441                         }
 442                         else
 443                         {
 444                                 kill_count_to_attacker = attacker.killcount;
 445                                 kill_count_to_target = 0;
 446                         }
 447
 448                         if(targ.istypefrag)
 449                         {
 450                                 if(attacker.FRAG_VERBOSE)
 451                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 452                                 else
 453                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG, targ.netname, kill_count_to_attacker);
 454
 455                                 if(targ.FRAG_VERBOSE)
 456                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 457                                 else
 458                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED, attacker.netname, kill_count_to_target);
 459                         }
 460                         else
 461                         {
 462                                 if(attacker.FRAG_VERBOSE)
 463                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 464                                 else
 465                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG, targ.netname, kill_count_to_attacker);
 466
 467                                 if(targ.FRAG_VERBOSE)
 468                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 469                                 else
 470                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED, attacker.netname, kill_count_to_target);
 471                         }
 472
 473                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
 474                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
 475                 }
 476         }
 477
 478         // =============
 479         // ACCIDENT/TRAP
 480         // =============
 481         else
 482         {
 483                 switch(deathtype)
 484                 {
 485                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 486                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 487                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 488                         /*case DEATH_HURTTRIGGER:
 489                         {
 490                                 s1 = targ.netname;
 491                                 s2 = inflictor.message;
 492                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 493                                 break;
 494                         }*/
 495
 496                         case DEATH_CUSTOM:
 497                         {
 498                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
 499                                         targ.netname,
 500                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
 501                                         deathlocation,
 502                                         targ.killcount,
 503                                         0,
 504                                         0);
 505                                 break;
 506                         }
 507
 508                         default:
 509                         {
 510                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 511                                 break;
 512                         }
 513                 }
 514
 515                 LogDeath("accident", deathtype, targ, targ);
 516                 GiveFrags(targ, targ, -1, deathtype);
 517
 518                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 519                 {
 520                         AnnounceTo(targ, "botlike");
 521                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 522                 }
 523         }
 524
 525         // reset target kill count
 526         if(targ.killcount) { targ.killcount = 0; }
 527 }
 528
 529 // these are updated by each Damage call for use in button triggering and such
 530 entity damage_targ;
 531 entity damage_inflictor;
 532 entity damage_attacker;
 533
 534 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 535 {
 536         float mirrordamage;
 537         float mirrorforce;
 538         float complainteamdamage = 0;
 539         entity attacker_save;
 540         mirrordamage = 0;
 541         mirrorforce = 0;
 542
 543         if (gameover || targ.killcount == -666)
 544                 return;
 545
 546         entity oldself;
 547         oldself = self;
 548         self = targ;
 549         damage_targ = targ;
 550         damage_inflictor = inflictor;
 551         damage_attacker = attacker;
 552                 attacker_save = attacker;
 553
 554         if(targ.classname == "player")
 555                 if(targ.hook)
 556                         if(targ.hook.aiment)
 557                                 if(targ.hook.aiment == attacker)
 558                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 559
 560         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 561         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 562         {
 563                 if(targ.classname == "player")
 564                         if not(IsDifferentTeam(targ, attacker))
 565                         {
 566                                 self = oldself;
 567                                 return;
 568                         }
 569         }
 570
 571         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 572         {
 573                 // These are ALWAYS lethal
 574                 // No damage modification here
 575                 // Instead, prepare the victim for his death...
 576                 targ.armorvalue = 0;
 577                 targ.spawnshieldtime = 0;
 578                 targ.health = 0.9; // this is < 1
 579                 targ.flags -= targ.flags & FL_GODMODE;
 580                 damage = 100000;
 581         }
 582         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 583         {
 584                 // no processing
 585         }
 586         else
 587         {
 588                 /*
 589                 skill based bot damage? gtfo. (tZork)
 590                 if (targ.classname == "player")
 591                 if (attacker.classname == "player")
 592                 if (!targ.isbot)
 593                 if (attacker.isbot)
 594                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 595         */
 596
 597                 // nullify damage if teamplay is on
 598                 if(deathtype != DEATH_TELEFRAG)
 599                 if(attacker.classname == "player")
 600                 {
 601                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 602                         {
 603                                 damage = 0;
 604                                 force = '0 0 0';
 605                         }
 606                         else if(!IsDifferentTeam(attacker, targ))
 607                         {
 608                                 if(autocvar_teamplay_mode == 1)
 609                                         damage = 0;
 610                                 else if(attacker != targ)
 611                                 {
 612                                         if(autocvar_teamplay_mode == 3)
 613                                                 damage = 0;
 614                                         else if(autocvar_teamplay_mode == 4)
 615                                         {
 616                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 617                                                 {
 618                                                         attacker.dmg_team = attacker.dmg_team + damage;
 619                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
 620                                                         if(complainteamdamage > 0 && !g_ca) // FIXME why is g_ca ruled out here? Why not just g_mirrordamage 0 on CA servers?
 621                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
 622                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 623                                                         if(g_minstagib)
 624                                                         {
 625                                                                 if(autocvar_g_friendlyfire == 0)
 626                                                                         damage = 0;
 627                                                         }
 628                                                         else if(g_ca)
 629                                                                 damage = 0;
 630                                                         else
 631                                                                 damage = autocvar_g_friendlyfire * damage;
 632                                                         // mirrordamage will be used LATER
 633
 634                                                         if(autocvar_g_mirrordamage_virtual)
 635                                                         {
 636                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 637                                                                 attacker.dmg_take += v_x;
 638                                                                 attacker.dmg_save += v_y;
 639                                                                 attacker.dmg_inflictor = inflictor;
 640                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 641                                                                 mirrorforce = 0;
 642                                                         }
 643
 644                                                         if(autocvar_g_friendlyfire_virtual)
 645                                                         {
 646                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 647                                                                 targ.dmg_take += v_x;
 648                                                                 targ.dmg_save += v_y;
 649                                                                 targ.dmg_inflictor = inflictor;
 650                                                                 damage = 0;
 651                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 652                                                                         force = '0 0 0';
 653                                                         }
 654                                                 }
 655                                                 else
 656                                                         damage = 0;
 657                                         }
 658                                 }
 659                         }
 660                 }
 661
 662                 if(targ.classname == "player")
 663                 if(attacker.classname == "player")
 664                 if(attacker != targ)
 665                 {
 666                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 667                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 668                 }
 669
 670                 if(targ.classname == "player")
 671                 if (g_minstagib)
 672                 {
 673                         if ((deathtype == DEATH_FALL)  ||
 674                                 (deathtype == DEATH_DROWN) ||
 675                                 (deathtype == DEATH_SLIME) ||
 676                                 (deathtype == DEATH_LAVA)  ||
 677                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 678                         {
 679                                 self = oldself;
 680                                 return;
 681                         }
 682                         if(damage > 0)
 683                             damage = 10000;
 684                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 685                         {
 686                                 targ.armorvalue -= 1;
 687                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 688                                 damage = 0;
 689                                 targ.hitsound += 1;
 690                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 691                         }
 692                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 693                         {
 694                                 damage = 0;
 695                                 mirrordamage = 0;
 696                                 complainteamdamage = 0;
 697                                 if (targ != attacker)
 698                                 {
 699                                         if ((targ.health >= 1) && (targ.classname == "player"))
 700                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 701                                         force = '0 0 0';
 702                                         // keep mirrorforce
 703                                         attacker = targ;
 704                                 }
 705                         }
 706                 }
 707
 708                 if not(DEATH_ISSPECIAL(deathtype))
 709                 {
 710                         damage *= g_weapondamagefactor;
 711                         mirrordamage *= g_weapondamagefactor;
 712                         complainteamdamage *= g_weapondamagefactor;
 713                         force = force * g_weaponforcefactor;
 714                         mirrorforce *= g_weaponforcefactor;
 715                 }
 716
 717                 // should this be changed at all? If so, in what way?
 718                 frag_attacker = attacker;
 719                 frag_target = targ;
 720                 frag_damage = damage;
 721                 frag_force = force;
 722         frag_deathtype = deathtype;
 723                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 724                 damage = frag_damage;
 725                 force = frag_force;
 726
 727                 // apply strength multiplier
 728                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 729                 {
 730                         if(targ == attacker)
 731                         {
 732                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 733                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 734                         }
 735                         else
 736                         {
 737                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 738                                 force = force * autocvar_g_balance_powerup_strength_force;
 739                         }
 740                 }
 741
 742                 // apply invincibility multiplier
 743                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 744                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 745
 746                 if (targ == attacker)
 747                 {
 748                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 749                                 damage = 0;
 750                         else
 751                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 752                 }
 753
 754                 if(g_runematch)
 755                 {
 756                         // apply strength rune
 757                         if (attacker.runes & RUNE_STRENGTH)
 758                         {
 759                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 760                                 {
 761                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 762                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 763                                 }
 764                                 else
 765                                 {
 766                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 767                                         force = force * autocvar_g_balance_rune_strength_force;
 768                                 }
 769                         }
 770                         else if (attacker.runes & CURSE_WEAK)
 771                         {
 772                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 773                                 force = force * autocvar_g_balance_curse_weak_force;
 774                         }
 775
 776                         // apply defense rune
 777                         if (targ.runes & RUNE_DEFENSE)
 778                         {
 779                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 780                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 781                                 else
 782                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 783                         }
 784                         else if (targ.runes & CURSE_VULNER)
 785                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 786                 }
 787
 788                 // count the damage
 789                 if(attacker)
 790                 if(!targ.deadflag)
 791                 if(targ.takedamage == DAMAGE_AIM)
 792                 if(targ != attacker)
 793                 {
 794                         entity victim;
 795                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 796                                 victim = targ.owner;
 797                         else
 798                                 victim = targ;
 799
 800                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 801                         {
 802                                 if(IsDifferentTeam(victim, attacker))
 803                                 {
 804                                         if(damage > 0)
 805                                         {
 806                                                 if(deathtype != DEATH_FIRE)
 807                                                 {
 808                                                         if(victim.BUTTON_CHAT)
 809                                                                 attacker.typehitsound += 1;
 810                                                         else
 811                                                                 attacker.hitsound += 1;
 812                                                 }
 813
 814                                                 damage_goodhits += 1;
 815                                                 damage_gooddamage += damage;
 816
 817                                                 if not(DEATH_ISSPECIAL(deathtype))
 818                                                 {
 819                                                         if(targ.classname == "player") // don't do this for vehicles
 820                                                         if(!g_minstagib)
 821                                                         if(IsFlying(victim))
 822                                                                 yoda = 1;
 823
 824                                                         if(g_minstagib)
 825                                                         if(victim.items & IT_STRENGTH)
 826                                                                 yoda = 1;
 827                                                 }
 828                                         }
 829                                 }
 830                                 else
 831                                 {
 832                                         if(deathtype != DEATH_FIRE)
 833                                         {
 834                                                 attacker.typehitsound += 1;
 835                                         }
 836                                         if(complainteamdamage > 0)
 837                                                 if(time > attacker.teamkill_complain)
 838                                                 {
 839                                                         attacker.teamkill_complain = time + 5;
 840                                                         attacker.teamkill_soundtime = time + 0.4;
 841                                                         attacker.teamkill_soundsource = targ;
 842                                                 }
 843                                 }
 844                         }
 845                 }
 846         }
 847
 848         // apply push
 849         if (self.damageforcescale)
 850         if (vlen(force))
 851         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 852         {
 853                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 854                 if(self.movetype == MOVETYPE_PHYSICS)
 855                 {
 856                         entity farcent;
 857                         farcent = spawn();
 858                         farcent.classname = "farce";
 859                         farcent.enemy = self;
 860                         farcent.movedir = farce * 10;
 861                         if(self.mass)
 862                                 farcent.movedir = farcent.movedir * self.mass;
 863                         farcent.origin = hitloc;
 864                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 865                         farcent.nextthink = time + 0.1;
 866                         farcent.think = SUB_Remove;
 867                 }
 868                 else
 869                         self.velocity = self.velocity + farce;
 870                 self.flags &~= FL_ONGROUND;
 871                 UpdateCSQCProjectile(self);
 872         }
 873         // apply damage
 874         if (damage != 0 || (self.damageforcescale && vlen(force)))
 875         if (self.event_damage)
 876                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 877         self = oldself;
 878
 879         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 880         {
 881                 if(g_runematch)
 882                 {
 883                         if (attacker.runes & RUNE_VAMPIRE)
 884                         {
 885                         // apply vampire rune
 886                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 887                                 {
 888                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 889                                         attacker.health = bound(
 890                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 891                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 892                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 893                                 }
 894                                 else
 895                                 {
 896                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 897                                         attacker.health = bound(
 898                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 899                                                                                         // empathy won't let you gain health in the same way...
 900                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 901                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 902                                         }
 903                         }
 904                         // apply empathy curse
 905                         else if (attacker.runes & CURSE_EMPATHY)
 906                         {
 907                                 attacker.health = bound(
 908                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 909                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 910                                         attacker.health);
 911                         }
 912                 }
 913         }
 914
 915         // apply mirror damage if any
 916         if(mirrordamage > 0 || mirrorforce > 0)
 917         {
 918                 attacker = attacker_save;
 919                 if(g_minstagib)
 920                 if(mirrordamage > 0)
 921                 {
 922                         // just lose extra LIVES, don't kill the player for mirror damage
 923                         if(attacker.armorvalue > 0)
 924                         {
 925                                 attacker.armorvalue = attacker.armorvalue - 1;
 926                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 927                                 attacker.hitsound += 1;
 928                         }
 929                         mirrordamage = 0;
 930                 }
 931
 932                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 933                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 934         }
 935 }
 936
 937 float RadiusDamage_running;
 938 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 939         // Returns total damage applies to creatures
 940 {
 941         entity  targ;
 942         vector  blastorigin;
 943         vector  force;
 944         float   total_damage_to_creatures;
 945         entity  next;
 946         float   tfloordmg;
 947         float   tfloorforce;
 948
 949         float stat_damagedone;
 950
 951         if(RadiusDamage_running)
 952         {
 953                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 954                 return 0;
 955         }
 956
 957         RadiusDamage_running = 1;
 958
 959         tfloordmg = autocvar_g_throughfloor_damage;
 960         tfloorforce = autocvar_g_throughfloor_force;
 961
 962         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 963         total_damage_to_creatures = 0;
 964
 965         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 966                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 967                 {
 968                         force = inflictor.velocity;
 969                         if(vlen(force) == 0)
 970                                 force = '0 0 -1';
 971                         else
 972                                 force = normalize(force);
 973                         if(forceintensity >= 0)
 974                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
 975                         else
 976                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
 977                 }
 978
 979         stat_damagedone = 0;
 980
 981         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
 982         while (targ)
 983         {
 984                 next = targ.chain;
 985                 if (targ != inflictor)
 986                         if (ignore != targ) if(targ.takedamage)
 987                         {
 988                                 vector nearest;
 989                                 vector diff;
 990                                 float power;
 991
 992                                 // LordHavoc: measure distance to nearest point on target (not origin)
 993                                 // (this guarentees 100% damage on a touch impact)
 994                                 nearest = targ.WarpZone_findradius_nearest;
 995                                 diff = targ.WarpZone_findradius_dist;
 996                                 // round up a little on the damage to ensure full damage on impacts
 997                                 // and turn the distance into a fraction of the radius
 998                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
 999                                 //bprint(" ");
1000                                 //bprint(ftos(power));
1001                                 //if (targ == attacker)
1002                                 //      print(ftos(power), "\n");
1003                                 if (power > 0)
1004                                 {
1005                                         float finaldmg;
1006                                         if (power > 1)
1007                                                 power = 1;
1008                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1009                                         if (finaldmg > 0)
1010                                         {
1011                                                 float a;
1012                                                 float c;
1013                                                 vector hitloc;
1014                                                 vector myblastorigin;
1015                                                 vector center;
1016
1017                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1018
1019                                                 // if it's a player, use the view origin as reference
1020                                                 center = CENTER_OR_VIEWOFS(targ);
1021
1022                                                 force = normalize(center - myblastorigin);
1023                                                 force = force * (finaldmg / coredamage) * forceintensity;
1024                                                 hitloc = nearest;
1025
1026                                                 if(targ != directhitentity)
1027                                                 {
1028                                                         float hits;
1029                                                         float total;
1030                                                         float hitratio;
1031                                                         float mininv_f, mininv_d;
1032
1033                                                         // test line of sight to multiple positions on box,
1034                                                         // and do damage if any of them hit
1035                                                         hits = 0;
1036
1037                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1038                                                         // so for a given max stddev:
1039                                                         // n = (1 / (2 * max stddev of hitratio))^2
1040
1041                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1042                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1043
1044                                                         if(autocvar_g_throughfloor_debug)
1045                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1046
1047                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1048
1049                                                         if(autocvar_g_throughfloor_debug)
1050                                                                 print(sprintf(" steps=%f", total));
1051
1052                                                         if (targ.classname == "player")
1053                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1054                                                         else
1055                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1056
1057                                                         if(autocvar_g_throughfloor_debug)
1058                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1059
1060                                                         for(c = 0; c < total; ++c)
1061                                                         {
1062                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1063                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1064                                                                 if (trace_fraction == 1 || trace_ent == targ)
1065                                                                 {
1066                                                                         ++hits;
1067                                                                         if (hits > 1)
1068                                                                                 hitloc = hitloc + nearest;
1069                                                                         else
1070                                                                                 hitloc = nearest;
1071                                                                 }
1072                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1073                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1074                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1075                                                         }
1076
1077                                                         nearest = hitloc * (1 / max(1, hits));
1078                                                         hitratio = (hits / total);
1079                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1080                                                         finaldmg = finaldmg * a;
1081                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1082                                                         force = force * a;
1083
1084                                                         if(autocvar_g_throughfloor_debug)
1085                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1086                                                 }
1087
1088                                                 // laser force adjustments :P
1089                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1090                                                 {
1091                                                         if (targ == attacker)
1092                                                         {
1093                                                                 vector vel;
1094
1095                                                                 float force_zscale;
1096                                                                 float force_velocitybiasramp;
1097                                                                 float force_velocitybias;
1098
1099                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1100                                                                 if(deathtype & HITTYPE_SECONDARY)
1101                                                                 {
1102                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1103                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1104                                                                 }
1105                                                                 else
1106                                                                 {
1107                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1108                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1109                                                                 }
1110
1111                                                                 vel = targ.velocity;
1112                                                                 vel_z = 0;
1113                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1114                                                                 force =
1115                                                                         vlen(force)
1116                                                                         *
1117                                                                         normalize(normalize(force) + vel);
1118
1119                                                                 force_z *= force_zscale;
1120                                                         }
1121                                                         else
1122                                                         {
1123                                                                 if(deathtype & HITTYPE_SECONDARY)
1124                                                                 {
1125                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1126                                                                 }
1127                                                                 else
1128                                                                 {
1129                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1130                                                                 }
1131                                                         }
1132                                                 }
1133
1134                                                 //if (targ == attacker)
1135                                                 //{
1136                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1137                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1138                                                 //      print(" (", ftos(a), ")\n");
1139                                                 //}
1140                                                 if(finaldmg || vlen(force))
1141                                                 {
1142                                                         if(targ.iscreature)
1143                                                         {
1144                                                                 total_damage_to_creatures += finaldmg;
1145
1146                                                                 if(accuracy_isgooddamage(attacker, targ))
1147                                                                         stat_damagedone += finaldmg;
1148                                                         }
1149
1150                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1151                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1152                                                         else
1153                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1154                                                 }
1155                                         }
1156                                 }
1157                         }
1158                 targ = next;
1159         }
1160
1161         RadiusDamage_running = 0;
1162
1163         if(!DEATH_ISSPECIAL(deathtype))
1164                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1165
1166         return total_damage_to_creatures;
1167 }
1168
1169 .float fire_damagepersec;
1170 .float fire_endtime;
1171 .float fire_deathtype;
1172 .entity fire_owner;
1173 .float fire_hitsound;
1174 .entity fire_burner;
1175
1176 void fireburner_think();
1177
1178 float Fire_IsBurning(entity e)
1179 {
1180         return (time < e.fire_endtime);
1181 }
1182
1183 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1184 {
1185         float dps;
1186         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1187
1188         if(e.classname == "player")
1189         {
1190                 if(e.deadflag)
1191                         return -1;
1192         }
1193         else
1194         {
1195                 if(!e.fire_burner)
1196                 {
1197                         // print("adding a fire burner to ", e.classname, "\n");
1198                         e.fire_burner = spawn();
1199                         e.fire_burner.classname = "fireburner";
1200                         e.fire_burner.think = fireburner_think;
1201                         e.fire_burner.nextthink = time;
1202                         e.fire_burner.owner = e;
1203                 }
1204         }
1205
1206         t = max(t, 0.1);
1207         dps = d / t;
1208         if(Fire_IsBurning(e))
1209         {
1210                 mintime = e.fire_endtime - time;
1211                 maxtime = max(mintime, t);
1212
1213                 mindps = e.fire_damagepersec;
1214                 maxdps = max(mindps, dps);
1215
1216                 if(maxtime > mintime || maxdps > mindps)
1217                 {
1218                         // Constraints:
1219
1220                         // damage we have right now
1221                         mindamage = mindps * mintime;
1222
1223                         // damage we want to get
1224                         maxdamage = mindamage + d;
1225
1226                         // but we can't exceed maxtime * maxdps!
1227                         totaldamage = min(maxdamage, maxtime * maxdps);
1228
1229                         // LEMMA:
1230                         // Look at:
1231                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1232                         // We see:
1233                         // totaldamage <= maxtime * maxdps
1234                         // ==> totaldamage / maxdps <= maxtime.
1235                         // We also see:
1236                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1237                         //                     >= min(mintime, maxtime)
1238                         // ==> totaldamage / maxdps >= mintime.
1239
1240                         /*
1241                         // how long do we damage then?
1242                         // at least as long as before
1243                         // but, never exceed maxdps
1244                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1245                         */
1246
1247                         // alternate:
1248                         // at most as long as maximum allowed
1249                         // but, never below mindps
1250                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1251
1252                         // assuming t > mintime, dps > mindps:
1253                         // we get d = t * dps = maxtime * maxdps
1254                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1255                         // totaldamage / maxdps = maxtime
1256                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1257                         // FROM THIS:
1258                         // a) totaltime = max(mintime, maxtime) = maxtime
1259                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1260
1261                         // assuming t <= mintime:
1262                         // we get maxtime = mintime
1263                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1264                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1265
1266                         // assuming dps <= mindps:
1267                         // we get mindps = maxdps.
1268                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1269                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1270                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1271
1272                         e.fire_damagepersec = totaldamage / totaltime;
1273                         e.fire_endtime = time + totaltime;
1274                         if(totaldamage > 1.2 * mindamage)
1275                         {
1276                                 e.fire_deathtype = dt;
1277                                 if(e.fire_owner != o)
1278                                 {
1279                                         e.fire_owner = o;
1280                                         e.fire_hitsound = FALSE;
1281                                 }
1282                         }
1283                         if(accuracy_isgooddamage(o, e))
1284                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1285                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1286                 }
1287                 else
1288                         return 0;
1289         }
1290         else
1291         {
1292                 e.fire_damagepersec = dps;
1293                 e.fire_endtime = time + t;
1294                 e.fire_deathtype = dt;
1295                 e.fire_owner = o;
1296                 e.fire_hitsound = FALSE;
1297                 if(accuracy_isgooddamage(o, e))
1298                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1299                 return d;
1300         }
1301 }
1302
1303 void Fire_ApplyDamage(entity e)
1304 {
1305         float t, d, hi, ty;
1306         entity o;
1307
1308         if not(Fire_IsBurning(e))
1309                 return;
1310
1311         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1312         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1313                 o = e.fire_owner;
1314
1315         // water and slime stop fire
1316         if(e.waterlevel)
1317         if(e.watertype != CONTENT_LAVA)
1318                 e.fire_endtime = 0;
1319
1320         // ice stops fire
1321         if(e.freezetag_frozen)
1322                 e.fire_endtime = 0;
1323
1324         t = min(frametime, e.fire_endtime - time);
1325         d = e.fire_damagepersec * t;
1326
1327         hi = e.fire_owner.hitsound;
1328         ty = e.fire_owner.typehitsound;
1329         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1330         if(e.fire_hitsound && e.fire_owner)
1331         {
1332                 e.fire_owner.hitsound = hi;
1333                 e.fire_owner.typehitsound = ty;
1334         }
1335         e.fire_hitsound = TRUE;
1336
1337         if not(IS_INDEPENDENT_PLAYER(e))
1338         FOR_EACH_PLAYER(other) if(e != other)
1339         {
1340                 if(other.classname == "player")
1341                 if(other.deadflag == DEAD_NO)
1342                 if not(IS_INDEPENDENT_PLAYER(other))
1343                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1344                 {
1345                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1346                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1347                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1348                 }
1349         }
1350 }
1351
1352 void Fire_ApplyEffect(entity e)
1353 {
1354         if(Fire_IsBurning(e))
1355                 e.effects |= EF_FLAME;
1356         else
1357                 e.effects &~= EF_FLAME;
1358 }
1359
1360 void fireburner_think()
1361 {
1362         // for players, this is done in the regular loop
1363         if(wasfreed(self.owner))
1364         {
1365                 remove(self);
1366                 return;
1367         }
1368         Fire_ApplyEffect(self.owner);
1369         if(!Fire_IsBurning(self.owner))
1370         {
1371                 self.owner.fire_burner = world;
1372                 remove(self);
1373                 return;
1374         }
1375         Fire_ApplyDamage(self.owner);
1376         self.nextthink = time;
1377 }