qcsrc/server/command/sv_cmd.qc

   1 #include "sv_cmd.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/effects/all.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/mapinfo.qh>
   7 #include <common/monsters/sv_monsters.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/teams.qh>
  11 #include <common/util.qh>
  12 #include <server/anticheat.qh>
  13 #include <server/bot/api.qh>
  14 #include <server/campaign.qh>
  15 #include <server/client.qh>
  16 #include <server/command/_mod.qh>
  17 #include <server/command/banning.qh>
  18 #include <server/command/cmd.qh>
  19 #include <server/command/common.qh>
  20 #include <server/command/getreplies.qh>
  21 #include <server/command/radarmap.qh>
  22 #include <server/intermission.qh>
  23 #include <server/ipban.qh>
  24 #include <server/mutators/_mod.qh>
  25 #include <server/player.qh>
  26 #include <server/scores_rules.qh>
  27 #include <server/teamplay.qh>
  28 #include <server/world.qh>
  29
  30 //  used by GameCommand_make_mapinfo()
  31 void make_mapinfo_Think(entity this)
  32 {
  33         if (_MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  34         {
  35                 LOG_INFO("Done rebuiling mapinfos.");
  36                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  37                 delete(this);
  38         }
  39         else
  40         {
  41                 setthink(this, make_mapinfo_Think);
  42                 this.nextthink = time;
  43         }
  44 }
  45
  46 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  47 void changematchtime(float delta, float mi, float ma)
  48 {
  49         float cur;
  50         float update;
  51         float lim;
  52
  53         if (delta == 0) return;
  54         if (autocvar_timelimit < 0) return;
  55
  56         if (mi <= 10) mi = 10;  // at least ten sec in the future
  57         cur = time - game_starttime;
  58         if (cur > 0) mi += cur; // from current time!
  59
  60         lim = autocvar_timelimit * 60;
  61
  62         if (delta > 0)
  63         {
  64                 if (lim == 0) return; // cannot increase any further
  65                 else if (lim < ma) update = min(ma, lim + delta);
  66                 else                  // already above maximum: FAIL
  67                         return;
  68         }
  69         else
  70         {
  71                 if (lim == 0)      // infinite: try reducing to max, if we are allowed to
  72                         update = max(mi, ma);
  73                 else if (lim > mi) // above minimum: decrease
  74                         update = max(mi, lim + delta);
  75                 else               // already below minimum: FAIL
  76                         return;
  77         }
  78
  79         cvar_set("timelimit", ftos(update / 60));
  80 }
  81
  82
  83 // =======================
  84 //  Command Sub-Functions
  85 // =======================
  86
  87 void GameCommand_adminmsg(int request, int argc)
  88 {
  89         switch (request)
  90         {
  91                 case CMD_REQUEST_COMMAND:
  92                 {
  93                         if (!world_initialized)
  94                         {
  95                                 LOG_HELPF("This command works only when the server is running.");
  96                                 return;
  97                         }
  98                         entity client;
  99                         float accepted;
 100
 101                         string targets = strreplace(",", " ", argv(1));
 102                         string original_targets = strreplace(" ", ", ", targets);
 103                         string admin_message = argv(2);
 104                         float infobartime = stof(argv(3));
 105
 106                         string successful, t;
 107                         successful = string_null;
 108
 109                         if ((targets) && (admin_message))
 110                         {
 111                                 for ( ; targets; )
 112                                 {
 113                                         t = car(targets);
 114                                         targets = cdr(targets);
 115
 116                                         // Check to see if the player is a valid target
 117                                         client = GetFilteredEntity(t);
 118                                         accepted = VerifyClientEntity(client, true, false);
 119
 120                                         if (accepted <= 0)
 121                                         {
 122                                                 LOG_INFO("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : "."));
 123                                                 continue;
 124                                         }
 125
 126                                         // send the centerprint/console print or infomessage
 127                                         if (infobartime)
 128                                         {
 129                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 130                                         }
 131                                         else
 132                                         {
 133                                                 centerprint(client, strcat("^3", GetCallerName(NULL), ":\n^7", admin_message));
 134                                                 sprint(client, strcat("\{1}\{13}^3", GetCallerName(NULL), "^7: ", admin_message, "\n"));
 135                                         }
 136
 137                                         successful = strcat(successful, (successful ? ", " : ""), playername(client.netname, client.team, false));
 138                                         LOG_TRACE("Message sent to ", playername(client.netname, client.team, false));
 139                                         continue;
 140                                 }
 141
 142                                 if (successful) bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 143                                 else LOG_INFO("No players given (", original_targets, ") could receive the message.");
 144
 145                                 return;
 146                         }
 147                 }
 148
 149                 default:
 150                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 151                 case CMD_REQUEST_USAGE:
 152                 {
 153                         LOG_HELP("Usage:^3 sv_cmd adminmsg <clients> \"<message>\" [<infobartime>]");
 154                         LOG_HELP("  <clients> is a list (separated by commas) of player entity ID's or nicknames");
 155                         LOG_HELP("  If <infobartime> is provided, the message will be sent to infobar.");
 156                         LOG_HELP("  Otherwise, it will just be sent as a centerprint message.");
 157                         LOG_HELP("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10");
 158                         LOG_HELP("          adminmsg 2,5 \"this message will be a centerprint\"");
 159                         return;
 160                 }
 161         }
 162 }
 163
 164 void GameCommand_allready(int request)
 165 {
 166         switch (request)
 167         {
 168                 case CMD_REQUEST_COMMAND:
 169                 {
 170                         if (!world_initialized)
 171                         {
 172                                 LOG_HELPF("This command works only when the server is running.");
 173                                 return;
 174                         }
 175                         if(warmup_stage)
 176                         {
 177                                 ReadyRestart(true);
 178                         }
 179                         else
 180                                 LOG_INFO("Not in warmup.");
 181
 182                         return;
 183                 }
 184
 185                 default:
 186                 case CMD_REQUEST_USAGE:
 187                 {
 188                         LOG_HELP("Usage:^3 sv_cmd allready");
 189                         LOG_HELP("  No arguments required.");
 190                         return;
 191                 }
 192         }
 193 }
 194
 195 void GameCommand_allspec(int request, int argc)
 196 {
 197         switch (request)
 198         {
 199                 case CMD_REQUEST_COMMAND:
 200                 {
 201                         if (!world_initialized)
 202                         {
 203                                 LOG_HELPF("This command works only when the server is running.");
 204                                 return;
 205                         }
 206                         string reason = argv(1);
 207                         int n = 0;
 208                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 209                                 PutObserverInServer(it, true, true);
 210                                 ++n;
 211                         });
 212                         if (n)   bprint(strcat("Successfully forced all (", ftos(n), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n"));
 213                         else   LOG_INFO("No players found to spectate.");
 214                         return;
 215                 }
 216
 217                 default:
 218                 case CMD_REQUEST_USAGE:
 219                 {
 220                         LOG_HELP("Usage:^3 sv_cmd allspec [<reason>]");
 221                         LOG_HELP("  Where <reason> is an optional argument for explanation of allspec command.");
 222                         LOG_HELP("See also: ^2moveplayer, shuffleteams^7");
 223                         return;
 224                 }
 225         }
 226 }
 227
 228 void GameCommand_anticheat(int request, int argc)
 229 {
 230         switch (request)
 231         {
 232                 case CMD_REQUEST_COMMAND:
 233                 {
 234                         if (!world_initialized)
 235                         {
 236                                 LOG_HELPF("This command works only when the server is running.");
 237                                 return;
 238                         }
 239                         entity client = GetIndexedEntity(argc, 1);
 240                         float accepted = VerifyClientEntity(client, false, false);
 241
 242                         if (accepted > 0)
 243                         {
 244                                 anticheat_report_to_eventlog(client);
 245                                 return;
 246                         }
 247                         else
 248                         {
 249                                 LOG_INFO("anticheat: ", GetClientErrorString(accepted, argv(1)), ".");
 250                         }
 251                 }
 252
 253                 default:
 254                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 255                 case CMD_REQUEST_USAGE:
 256                 {
 257                         LOG_HELP("Usage:^3 sv_cmd anticheat <client>");
 258                         LOG_HELP("  <client> is the entity number or name of the player.");
 259                         return;
 260                 }
 261         }
 262 }
 263
 264 void GameCommand_bbox(int request)
 265 {
 266         switch (request)
 267         {
 268                 case CMD_REQUEST_COMMAND:
 269                 {
 270                         vector size_min = '0 0 0';
 271                         vector size_max = '0 0 0';
 272                         tracebox('1 0 0' * world.absmin.x,
 273                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 274                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 275                                 '1 0 0' * world.absmax.x,
 276                                 MOVE_WORLDONLY,
 277                                 NULL);
 278                         size_min.x = (trace_startsolid) ? world.absmin.x : trace_endpos.x;
 279
 280                         tracebox('0 1 0' * world.absmin.y,
 281                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 282                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 283                                 '0 1 0' * world.absmax.y,
 284                                 MOVE_WORLDONLY,
 285                                 NULL);
 286                         size_min.y = (trace_startsolid) ? world.absmin.y : trace_endpos.y;
 287
 288                         tracebox('0 0 1' * world.absmin.z,
 289                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 290                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 291                                 '0 0 1' * world.absmax.z,
 292                                 MOVE_WORLDONLY,
 293                                 NULL);
 294                         size_min.z = (trace_startsolid) ? world.absmin.z : trace_endpos.z;
 295
 296                         tracebox('1 0 0' * world.absmax.x,
 297                                 '0 1 0' * world.absmin.y + '0 0 1' * world.absmin.z,
 298                                 '0 1 0' * world.absmax.y + '0 0 1' * world.absmax.z,
 299                                 '1 0 0' * world.absmin.x,
 300                                 MOVE_WORLDONLY,
 301                                 NULL);
 302                         size_max.x = (trace_startsolid) ? world.absmax.x : trace_endpos.x;
 303
 304                         tracebox('0 1 0' * world.absmax.y,
 305                                 '1 0 0' * world.absmin.x + '0 0 1' * world.absmin.z,
 306                                 '1 0 0' * world.absmax.x + '0 0 1' * world.absmax.z,
 307                                 '0 1 0' * world.absmin.y,
 308                                 MOVE_WORLDONLY,
 309                                 NULL);
 310                         size_max.y = (trace_startsolid) ? world.absmax.y : trace_endpos.y;
 311
 312                         tracebox('0 0 1' * world.absmax.z,
 313                                 '1 0 0' * world.absmin.x + '0 1 0' * world.absmin.y,
 314                                 '1 0 0' * world.absmax.x + '0 1 0' * world.absmax.y,
 315                                 '0 0 1' * world.absmin.z,
 316                                 MOVE_WORLDONLY,
 317                                 NULL);
 318                         size_max.z = (trace_startsolid) ? world.absmax.z : trace_endpos.z;
 319
 320                         LOG_INFOF("Original size: %v %v", world.absmin, world.absmax);
 321                         LOG_INFOF("Currently set size: %v %v", world.mins, world.maxs);
 322                         LOG_INFOF("Solid bounding box size: %v %v", size_min, size_max);
 323                         return;
 324                 }
 325
 326                 default:
 327                 case CMD_REQUEST_USAGE:
 328                 {
 329                         LOG_HELP("Usage:^3 sv_cmd bbox");
 330                         LOG_HELP("  No arguments required.");
 331                         LOG_HELP("See also: ^2gettaginfo, trace^7");
 332                         return;
 333                 }
 334         }
 335 }
 336
 337 void GameCommand_bot_cmd(int request, int argc, string command)
 338 {
 339         switch (request)
 340         {
 341                 case CMD_REQUEST_COMMAND:
 342                 {
 343                         if (!world_initialized)
 344                         {
 345                                 LOG_HELPF("This command works only when the server is running.");
 346                                 return;
 347                         }
 348                         entity bot;
 349
 350                         if (argv(1) == "reset")
 351                         {
 352                                 bot_resetqueues();
 353                                 return;
 354                         }
 355                         else if (argv(1) == "setbots")
 356                         {
 357                                 cvar_settemp("bot_vs_human", "0");
 358                                 cvar_settemp("minplayers", "0");
 359                                 cvar_settemp("minplayers_per_team", "0");
 360                                 cvar_settemp("bot_number", "0");
 361                                 bot_fixcount(false);  // Kill all bots.
 362                                 cvar_settemp("bot_number", argv(2));
 363                                 if (!bot_fixcount(true)) LOG_INFO("Sorry, could not set requested bot count");
 364                                 return;
 365                         }
 366                         else if (argv(1) == "load" && argc == 3)
 367                         {
 368                                 float fh, i;
 369                                 string s;
 370                                 fh = fopen(argv(2), FILE_READ);
 371                                 if (fh < 0)
 372                                 {
 373                                         LOG_INFO("cannot open the file");
 374                                         return;
 375                                 }
 376
 377                                 i = 0;
 378                                 while ((s = fgets(fh)))
 379                                 {
 380                                         argc = tokenize_console(s);
 381
 382                                         if (argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 383                                         {
 384                                                 if (argv(2) == "reset")
 385                                                 {
 386                                                         bot_resetqueues();
 387                                                 }
 388                                                 else if (argv(2) == "setbots")
 389                                                 {
 390                                                         cvar_settemp("bot_vs_human", "0");
 391                                                         cvar_settemp("minplayers", "0");
 392                                                         cvar_settemp("minplayers_per_team", "0");
 393                                                         cvar_settemp("bot_number", "0");
 394                                                         bot_fixcount(false);  // Kill all bots.
 395                                                         cvar_settemp("bot_number", argv(3));
 396                                                         if (!bot_fixcount(true)) LOG_INFO("Sorry, could not set requested bot count");
 397                                                 }
 398                                                 else
 399                                                 {
 400                                                         if(argv(2) == "*" || argv(2) == "all")
 401                                                                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 402                                                                         bot_queuecommand(it, substring(s, argv_start_index(3), -1));
 403                                                                 });
 404                                                         else
 405                                                         {
 406                                                                 bot = find_bot_by_number(stof(argv(2)));
 407                                                                 if (bot == NULL) bot = find_bot_by_name(argv(2));
 408                                                                 if (bot) bot_queuecommand(bot, substring(s, argv_start_index(3), -1));
 409                                                         }
 410                                                 }
 411                                         }
 412                                         else
 413                                         {
 414                                                 localcmd(strcat(s, "\n"));
 415                                         }
 416
 417                                         ++i;
 418                                 }
 419                                 LOG_INFO(ftos(i), " commands read");
 420                                 fclose(fh);
 421                                 return;
 422                         }
 423                         else if (argv(1) == "help")
 424                         {
 425                                 if (argv(2)) bot_cmdhelp(argv(2));
 426                                 else bot_list_commands();
 427                                 return;
 428                         }
 429                         else if (argc >= 3)  // this comes last
 430                         {
 431                                 if(argv(1) == "*" || argv(1) == "all")
 432                                 {
 433                                         int bot_num = 0;
 434                                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 435                                                 bot_queuecommand(it, substring(command, argv_start_index(2), -1));
 436                                                 bot_num++;
 437                                         });
 438                                         if(bot_num)
 439                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to all bots (", ftos(bot_num), ")");
 440                                         return;
 441                                 }
 442                                 else
 443                                 {
 444                                         bot = find_bot_by_number(stof(argv(1)));
 445                                         if (bot == NULL) bot = find_bot_by_name(argv(1));
 446                                         if (bot)
 447                                         {
 448                                                 LOG_INFO("Command '", substring(command, argv_start_index(2), -1), "' sent to bot ", bot.netname);
 449                                                 bot_queuecommand(bot, substring(command, argv_start_index(2), -1));
 450                                                 return;
 451                                         }
 452                                         else
 453                                         {
 454                                                 LOG_INFO("Error: Can't find bot with the name or id '", argv(1), "' - Did you mistype the command?");  // don't return so that usage is shown
 455                                         }
 456                                 }
 457                         }
 458                 }
 459
 460                 default:
 461                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 462                 case CMD_REQUEST_USAGE:
 463                 {
 464                         LOG_HELP("Usage:^3 sv_cmd bot_cmd <client> <command> [<arguments>]");
 465                         LOG_HELP("  <client> can be either the name of the bot or a progressive number (not the entity number!)");
 466                         LOG_HELP("           can also be '*' or 'all' to allow sending the command to all the bots");
 467                         LOG_HELP("  For full list of commands, see bot_cmd help [<command>].");
 468                         LOG_HELP("Examples: sv_cmd bot_cmd 1 cc \"say something\"");
 469                         LOG_HELP("          sv_cmd bot_cmd 1 presskey jump");
 470                         LOG_HELP("          sv_cmd bot_cmd * pause");
 471                         return;
 472                 }
 473         }
 474 }
 475
 476 void GameCommand_cointoss(int request, int argc)
 477 {
 478         switch (request)
 479         {
 480                 case CMD_REQUEST_COMMAND:
 481                 {
 482                         if (!world_initialized)
 483                         {
 484                                 LOG_HELPF("This command works only when the server is running.");
 485                                 return;
 486                         }
 487                         string result1 = (argv(2) ? strcat("^7", argv(1)) : "^1HEADS");
 488                         string result2 = (argv(2) ? strcat("^7", argv(2)) : "^4TAILS");
 489                         string choice = ((random() > 0.5) ? result1 : result2);
 490
 491                         Send_Notification(NOTIF_ALL, NULL, MSG_MULTI, MULTI_COINTOSS, choice);
 492                         return;
 493                 }
 494
 495                 default:
 496                 case CMD_REQUEST_USAGE:
 497                 {
 498                         LOG_HELP("Usage:^3 sv_cmd cointoss [<result1> <result2>]");
 499                         LOG_HELP("  Where <result1> and <result2> are user created options.");
 500                         return;
 501                 }
 502         }
 503 }
 504
 505 void GameCommand_database(int request, int argc)
 506 {
 507         switch (request)
 508         {
 509                 case CMD_REQUEST_COMMAND:
 510                 {
 511                         if (argc == 3)
 512                         {
 513                                 if (argv(1) == "save")
 514                                 {
 515                                         db_save(ServerProgsDB, argv(2));
 516                                         LOG_INFO("Copied serverprogs database to '", argv(2), "' in the data directory.");
 517                                         return;
 518                                 }
 519                                 else if (argv(1) == "dump")
 520                                 {
 521                                         db_dump(ServerProgsDB, argv(2));
 522                                         LOG_INFO("DB dumped.");  // wtf does this do?
 523                                         return;
 524                                 }
 525                                 else if (argv(1) == "load")
 526                                 {
 527                                         db_close(ServerProgsDB);
 528                                         ServerProgsDB = db_load(argv(2));
 529                                         LOG_INFO("Loaded '", argv(2), "' as new serverprogs database.");
 530                                         return;
 531                                 }
 532                         }
 533                 }
 534
 535                 default:
 536                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 537                 case CMD_REQUEST_USAGE:
 538                 {
 539                         LOG_HELP("Usage:^3 sv_cmd database <action> <filename>");
 540                         LOG_HELP("  Where <action> is the command to complete,");
 541                         LOG_HELP("  and <filename> is what it acts upon.");
 542                         LOG_HELP("  Full list of commands here: save, dump, load.");
 543                         return;
 544                 }
 545         }
 546 }
 547
 548 void GameCommand_defer_clear(int request, int argc)
 549 {
 550         switch (request)
 551         {
 552                 case CMD_REQUEST_COMMAND:
 553                 {
 554                         if (!world_initialized)
 555                         {
 556                                 LOG_HELPF("This command works only when the server is running.");
 557                                 return;
 558                         }
 559                         entity client;
 560                         float accepted;
 561
 562                         if (argc >= 2)
 563                         {
 564                                 client = GetIndexedEntity(argc, 1);
 565                                 accepted = VerifyClientEntity(client, true, false);
 566
 567                                 if (accepted > 0)
 568                                 {
 569                                         stuffcmd(client, "defer clear\n");
 570                                         LOG_INFO("defer clear stuffed to ", playername(client.netname, client.team, false));
 571                                 }
 572                                 else { LOG_INFO("defer_clear: ", GetClientErrorString(accepted, argv(1)), "."); }
 573
 574                                 return;
 575                         }
 576                 }
 577
 578                 default:
 579                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 580                 case CMD_REQUEST_USAGE:
 581                 {
 582                         LOG_HELP("Usage:^3 sv_cmd defer_clear <client>");
 583                         LOG_HELP("  <client> is the entity number or name of the player.");
 584                         LOG_HELP("See also: ^2defer_clear_all^7");
 585                         return;
 586                 }
 587         }
 588 }
 589
 590 void GameCommand_defer_clear_all(int request)
 591 {
 592         switch (request)
 593         {
 594                 case CMD_REQUEST_COMMAND:
 595                 {
 596                         if (!world_initialized)
 597                         {
 598                                 LOG_HELPF("This command works only when the server is running.");
 599                                 return;
 600                         }
 601                         int n = 0;
 602                         int argc;
 603
 604                         FOREACH_CLIENT(true, {
 605                                 argc = tokenize_console(strcat("defer_clear ", ftos(etof(it))));
 606                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 607                                 ++n;
 608                         });
 609                         if (n)   LOG_INFO("Successfully stuffed defer clear to all clients (", ftos(n), ")");  // should a message be added if no players were found?
 610                         return;
 611                 }
 612
 613                 default:
 614                 case CMD_REQUEST_USAGE:
 615                 {
 616                         LOG_HELP("Usage:^3 sv_cmd defer_clear_all");
 617                         LOG_HELP("  No arguments required.");
 618                         LOG_HELP("See also: ^2defer_clear^7");
 619                         return;
 620                 }
 621         }
 622 }
 623
 624 void GameCommand_delrec(int request, int argc)  // perhaps merge later with records and printstats and such?
 625 {
 626         switch (request)
 627         {
 628                 case CMD_REQUEST_COMMAND:
 629                 {
 630                         if (argv(1))
 631                         {
 632                                 if (argv(2)) race_deleteTime(argv(2), stof(argv(1)));
 633                                 else race_deleteTime(GetMapname(), stof(argv(1)));
 634                                 return;
 635                         }
 636                 }
 637
 638                 default:
 639                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 640                 case CMD_REQUEST_USAGE:
 641                 {
 642                         LOG_HELP("Usage:^3 sv_cmd delrec <ranking> [<map>]");
 643                         LOG_HELP("  <ranking> is which ranking level to clear up to, ");
 644                         LOG_HELP("  it will clear all records up to nth place.");
 645                         LOG_HELP("  if <map> is not provided it will use current map.");
 646                         return;
 647                 }
 648         }
 649 }
 650
 651 void print_Effect_Index(int d, string effect_name)
 652 {
 653         // this is inside a function to avoid expanding it on compilation everytime
 654         LOG_INFO("effect ", effect_name, " is ", ftos(_particleeffectnum(effect_name)), "\n");
 655         db_put(d, effect_name, "1");
 656 }
 657
 658 void GameCommand_effectindexdump(int request)
 659 {
 660         switch (request)
 661         {
 662                 case CMD_REQUEST_COMMAND:
 663                 {
 664                         float fh, d;
 665                         string s;
 666
 667                         d = db_create();
 668                         LOG_INFO("begin of effects list");
 669
 670                         print_Effect_Index(d, "TE_GUNSHOT");
 671                         print_Effect_Index(d, "TE_GUNSHOTQUAD");
 672                         print_Effect_Index(d, "TE_SPIKE");
 673                         print_Effect_Index(d, "TE_SPIKEQUAD");
 674                         print_Effect_Index(d, "TE_SUPERSPIKE");
 675                         print_Effect_Index(d, "TE_SUPERSPIKEQUAD");
 676                         print_Effect_Index(d, "TE_WIZSPIKE");
 677                         print_Effect_Index(d, "TE_KNIGHTSPIKE");
 678                         print_Effect_Index(d, "TE_EXPLOSION");
 679                         print_Effect_Index(d, "TE_EXPLOSIONQUAD");
 680                         print_Effect_Index(d, "TE_TAREXPLOSION");
 681                         print_Effect_Index(d, "TE_TELEPORT");
 682                         print_Effect_Index(d, "TE_LAVASPLASH");
 683                         print_Effect_Index(d, "TE_SMALLFLASH");
 684                         print_Effect_Index(d, "TE_FLAMEJET");
 685                         print_Effect_Index(d, "EF_FLAME");
 686                         print_Effect_Index(d, "TE_BLOOD");
 687                         print_Effect_Index(d, "TE_SPARK");
 688                         print_Effect_Index(d, "TE_PLASMABURN");
 689                         print_Effect_Index(d, "TE_TEI_G3");
 690                         print_Effect_Index(d, "TE_TEI_SMOKE");
 691                         print_Effect_Index(d, "TE_TEI_BIGEXPLOSION");
 692                         print_Effect_Index(d, "TE_TEI_PLASMAHIT");
 693                         print_Effect_Index(d, "EF_STARDUST");
 694                         print_Effect_Index(d, "TR_ROCKET");
 695                         print_Effect_Index(d, "TR_GRENADE");
 696                         print_Effect_Index(d, "TR_BLOOD");
 697                         print_Effect_Index(d, "TR_WIZSPIKE");
 698                         print_Effect_Index(d, "TR_SLIGHTBLOOD");
 699                         print_Effect_Index(d, "TR_KNIGHTSPIKE");
 700                         print_Effect_Index(d, "TR_VORESPIKE");
 701                         print_Effect_Index(d, "TR_NEHAHRASMOKE");
 702                         print_Effect_Index(d, "TR_NEXUIZPLASMA");
 703                         print_Effect_Index(d, "TR_GLOWTRAIL");
 704                         print_Effect_Index(d, "TR_SEEKER");
 705                         print_Effect_Index(d, "SVC_PARTICLE");
 706
 707                         fh = fopen("effectinfo.txt", FILE_READ);
 708                         while ((s = fgets(fh)))
 709                         {
 710                                 tokenize_console(s);
 711                                 if (argv(0) == "effect")
 712                                 {
 713                                         if (db_get(d, argv(1)) != "1")
 714                                         {
 715                                                 int i = _particleeffectnum(argv(1));
 716                                                 if (i >= 0) LOG_INFO("effect ", argv(1), " is ", ftos(i));
 717                                                 db_put(d, argv(1), "1");
 718                                         }
 719                                 }
 720                         }
 721                         LOG_INFO("end of effects list");
 722
 723                         db_close(d);
 724                         return;
 725                 }
 726
 727                 default:
 728                 case CMD_REQUEST_USAGE:
 729                 {
 730                         LOG_HELP("Usage:^3 sv_cmd effectindexdump");
 731                         LOG_HELP("  No arguments required.");
 732                         return;
 733                 }
 734         }
 735 }
 736
 737 void GameCommand_extendmatchtime(int request)
 738 {
 739         switch (request)
 740         {
 741                 case CMD_REQUEST_COMMAND:
 742                 {
 743                         if (!world_initialized)
 744                         {
 745                                 LOG_HELPF("This command works only when the server is running.");
 746                                 return;
 747                         }
 748                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 749                         return;
 750                 }
 751
 752                 default:
 753                 case CMD_REQUEST_USAGE:
 754                 {
 755                         LOG_HELP("Usage:^3 sv_cmd extendmatchtime");
 756                         LOG_HELP("  No arguments required.");
 757                         LOG_HELP("See also: ^2reducematchtime^7");
 758                         return;
 759                 }
 760         }
 761 }
 762
 763 void GameCommand_gametype(int request, int argc)
 764 {
 765         switch (request)
 766         {
 767                 case CMD_REQUEST_COMMAND:
 768                 {
 769                         if (!world_initialized)
 770                         {
 771                                 LOG_HELPF("This command works only when the server is running.");
 772                                 return;
 773                         }
 774                         if (argv(1) != "")
 775                         {
 776                                 string s = argv(1);
 777                                 Gametype t = MapInfo_Type_FromString(s, false, false), tsave = MapInfo_CurrentGametype();
 778
 779                                 if (t)
 780                                 {
 781                                         MapInfo_SwitchGameType(t);
 782                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 783                                         if (MapInfo_count > 0)
 784                                         {
 785                                                 // update lsmaps in case the gametype changed, this way people can easily list maps for it
 786                                                 if (lsmaps_reply != "")   strunzone(lsmaps_reply);
 787                                                 lsmaps_reply = strzone(getlsmaps());
 788                                                 bprint("Game type successfully switched to ", s, "\n");
 789                                         }
 790                                         else
 791                                         {
 792                                                 bprint("Cannot use this game type: no map for it found\n");
 793                                                 MapInfo_SwitchGameType(tsave);
 794                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 795                                         }
 796                                 }
 797                                 else
 798                                 {
 799                                         bprint("Failed to switch to ", s, ": this game type does not exist!\n");
 800                                 }
 801
 802                                 return;
 803                         }
 804                 }
 805
 806                 default:
 807                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 808                 case CMD_REQUEST_USAGE:
 809                 {
 810                         LOG_HELP("Usage:^3 sv_cmd gametype <mode>");
 811                         LOG_HELP("  Where <mode> is the gametype mode to switch to.");
 812                         LOG_HELP("See also: ^2gotomap^7");
 813                         return;
 814                 }
 815         }
 816 }
 817
 818 void GameCommand_gettaginfo(int request, int argc)
 819 {
 820         switch (request)
 821         {
 822                 case CMD_REQUEST_COMMAND:
 823                 {
 824                         entity tmp_entity;
 825                         float i;
 826                         vector v;
 827
 828                         if (argc >= 4)
 829                         {
 830                                 tmp_entity = spawn();
 831                                 if (argv(1) == "w")
 832                                 {
 833                                         .entity weaponentity = weaponentities[0];
 834                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 835                                 }
 836                                 else
 837                                 {
 838                                         precache_model(argv(1));
 839                                         _setmodel(tmp_entity, argv(1));
 840                                 }
 841                                 tmp_entity.frame = stof(argv(2));
 842                                 if (substring(argv(3), 0, 1) == "#") i = stof(substring(argv(3), 1, -1));
 843                                 else i = gettagindex(tmp_entity, argv(3));
 844                                 if (i)
 845                                 {
 846                                         v = gettaginfo(tmp_entity, i);
 847                                         LOG_HELPF("model %s frame %s tag %s index %s parent %s",
 848                                                 tmp_entity.model, ftos(tmp_entity.frame), gettaginfo_name, ftos(i), ftos(gettaginfo_parent)
 849                                         );
 850                                         LOG_HELPF(" vector = %s %s %s", ftos(v.x), ftos(v.y), ftos(v.z));
 851                                         LOG_HELPF(" offset = %s %s %s", ftos(gettaginfo_offset.x), ftos(gettaginfo_offset.y), ftos(gettaginfo_offset.z));
 852                                         LOG_HELPF(" forward = %s %s %s", ftos(gettaginfo_forward.x), ftos(gettaginfo_forward.y), ftos(gettaginfo_forward.z));
 853                                         LOG_HELPF(" right = %s %s %s", ftos(gettaginfo_right.x), ftos(gettaginfo_right.y), ftos(gettaginfo_right.z));
 854                                         LOG_HELPF(" up = %s %s %s", ftos(gettaginfo_up.x), ftos(gettaginfo_up.y), ftos(gettaginfo_up.z));
 855                                         if (argc >= 6)
 856                                         {
 857                                                 v.y = -v.y;
 858                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 859                                         }
 860                                 }
 861                                 else
 862                                 {
 863                                         LOG_INFO("bone not found");
 864                                 }
 865
 866                                 delete(tmp_entity);
 867                                 return;
 868                         }
 869                 }
 870
 871                 default:
 872                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 873                 case CMD_REQUEST_USAGE:
 874                 {
 875                         LOG_HELP("Usage:^3 sv_cmd gettaginfo <model> <frame> <index> [<command1>] [<command2>]");
 876                         LOG_HELP("See also: ^2bbox, trace^7");
 877                         return;
 878                 }
 879         }
 880 }
 881
 882 void GameCommand_animbench(int request, int argc)
 883 {
 884         switch (request)
 885         {
 886                 case CMD_REQUEST_COMMAND:
 887                 {
 888                         entity tmp_entity;
 889
 890                         if (argc >= 4)
 891                         {
 892                                 tmp_entity = spawn();
 893                                 if (argv(1) == "w")
 894                                 {
 895                                         .entity weaponentity = weaponentities[0];
 896                                         _setmodel(tmp_entity, (nextent(NULL)).(weaponentity).model);
 897                                 }
 898                                 else
 899                                 {
 900                                         precache_model(argv(1));
 901                                         _setmodel(tmp_entity, argv(1));
 902                                 }
 903                                 float f1 = stof(argv(2));
 904                                 float f2 = stof(argv(3));
 905                                 float t0;
 906                                 float t1 = 0;
 907                                 float t2 = 0;
 908                                 float n = 0;
 909
 910                                 while (t1 + t2 < 1)
 911                                 {
 912                                         tmp_entity.frame = f1;
 913                                         t0 = gettime(GETTIME_HIRES);
 914                                         getsurfacepoint(tmp_entity, 0, 0);
 915                                         t1 += gettime(GETTIME_HIRES) - t0;
 916                                         tmp_entity.frame = f2;
 917                                         t0 = gettime(GETTIME_HIRES);
 918                                         getsurfacepoint(tmp_entity, 0, 0);
 919                                         t2 += gettime(GETTIME_HIRES) - t0;
 920                                         n += 1;
 921                                 }
 922                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f1), " animtime ", ftos(n / t1), "/s");
 923                                 LOG_INFO("model ", tmp_entity.model, " frame ", ftos(f2), " animtime ", ftos(n / t2), "/s");
 924
 925                                 delete(tmp_entity);
 926                                 return;
 927                         }
 928                 }
 929
 930                 default:
 931                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 932                 case CMD_REQUEST_USAGE:
 933                 {
 934                         LOG_HELP("Usage:^3 sv_cmd animbench <model> <frame1> <frame2>");
 935                         LOG_HELP("See also: ^2bbox, trace^7");
 936                         return;
 937                 }
 938         }
 939 }
 940
 941 void GameCommand_gotomap(int request, int argc)
 942 {
 943         switch (request)
 944         {
 945                 case CMD_REQUEST_COMMAND:
 946                 {
 947                         if (!world_initialized)
 948                         {
 949                                 LOG_HELPF("This command works only when the server is running.");
 950                                 return;
 951                         }
 952                         if (argv(1))
 953                         {
 954                                 LOG_INFO(GotoMap(argv(1)));
 955                                 return;
 956                         }
 957                 }
 958
 959                 default:
 960                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 961                 case CMD_REQUEST_USAGE:
 962                 {
 963                         LOG_HELP("Usage:^3 sv_cmd gotomap <map>");
 964                         LOG_HELP("  Where <map> is the *.bsp file to change to.");
 965                         LOG_HELP("See also: ^2gametype^7");
 966                         return;
 967                 }
 968         }
 969 }
 970
 971 void GameCommand_lockteams(int request)
 972 {
 973         switch (request)
 974         {
 975                 case CMD_REQUEST_COMMAND:
 976                 {
 977                         if (!world_initialized)
 978                         {
 979                                 LOG_HELPF("This command works only when the server is running.");
 980                                 return;
 981                         }
 982                         if (teamplay)
 983                         {
 984                                 lockteams = 1;
 985                                 bprint("^1The teams are now locked.\n");
 986                         }
 987                         else
 988                         {
 989                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 990                         }
 991                         return;
 992                 }
 993
 994                 default:
 995                 case CMD_REQUEST_USAGE:
 996                 {
 997                         LOG_HELP("Usage:^3 sv_cmd lockteams");
 998                         LOG_HELP("  No arguments required.");
 999                         LOG_HELP("See also: ^2unlockteams^7");
1000                         return;
1001                 }
1002         }
1003 }
1004
1005 void GameCommand_make_mapinfo(int request)
1006 {
1007         switch (request)
1008         {
1009                 case CMD_REQUEST_COMMAND:
1010                 {
1011                         entity tmp_entity;
1012
1013                         tmp_entity = new(make_mapinfo);
1014                         setthink(tmp_entity, make_mapinfo_Think);
1015                         tmp_entity.nextthink = time;
1016                         MapInfo_Enumerate();
1017                         return;
1018                 }
1019
1020                 default:
1021                 case CMD_REQUEST_USAGE:
1022                 {
1023                         LOG_HELP("Usage:^3 sv_cmd make_mapinfo");
1024                         LOG_HELP("  No arguments required.");
1025                         LOG_HELP("See also: ^2radarmap^7");
1026                         return;
1027                 }
1028         }
1029 }
1030
1031 void GameCommand_moveplayer(int request, int argc)
1032 {
1033         switch (request)
1034         {
1035                 case CMD_REQUEST_COMMAND:
1036                 {
1037                         if (!world_initialized)
1038                         {
1039                                 LOG_HELPF("This command works only when the server is running.");
1040                                 return;
1041                         }
1042                         float accepted;
1043                         entity client;
1044
1045                         string targets = strreplace(",", " ", argv(1));
1046                         string original_targets = strreplace(" ", ", ", targets);
1047                         string destination = argv(2);
1048                         if (destination == "spec")
1049                                 destination = "spectator";
1050
1051                         if ((targets) && (destination))
1052                         {
1053                                 string successful = string_null;
1054                                 string t;
1055                                 for ( ; targets; )
1056                                 {
1057                                         t = car(targets);
1058                                         targets = cdr(targets);
1059
1060                                         // Check to see if the player is a valid target
1061                                         client = GetFilteredEntity(t);
1062                                         accepted = VerifyClientEntity(client, false, false);
1063                                         string client_num_str = ftos(etof(client));
1064
1065                                         if (accepted <= 0)
1066                                         {
1067                                                 LOG_INFO("moveplayer: ", GetClientErrorString(accepted, t), ".");
1068                                         }
1069                                         else if (destination == "spectator")
1070                                         {
1071                                                 string pl_name = playername(client.netname, client.team, false);
1072                                                 if (!IS_SPEC(client) && !IS_OBSERVER(client))
1073                                                 {
1074                                                         PutObserverInServer(client, true, true);
1075
1076                                                         successful = strcat(successful, (successful ? ", " : ""), pl_name);
1077                                                 }
1078                                                 else
1079                                                 {
1080                                                         LOG_INFO("Player #", client_num_str, " (", pl_name, ") is already spectating.");
1081                                                 }
1082                                         }
1083                                         else
1084                                         {
1085                                                 if (!teamplay)
1086                                                 {
1087                                                         LOG_INFO("Can't change teams when currently not playing a team game.");
1088                                                         return;
1089                                                 }
1090
1091                                                 string pl_name = playername(client.netname, client.team, false);
1092                                                 if (IS_SPEC(client) || IS_OBSERVER(client))
1093                                                 {
1094                                                         // well technically we could, but should we allow that? :P
1095                                                         LOG_INFO("Player #", client_num_str, " (", pl_name, ") is not in the game.");
1096                                                         continue;
1097                                                 }
1098
1099                                                 // set up
1100                                                 int save = Player_GetForcedTeamIndex(client);
1101                                                 Player_SetForcedTeamIndex(client, TEAM_FORCE_DEFAULT);
1102
1103                                                 // find the team to move the player to
1104                                                 int team_num = Team_ColorToTeam(destination);
1105                                                 entity balance;
1106                                                 if (team_num == client.team)  // already on the destination team
1107                                                 {
1108                                                         // keep the forcing undone
1109                                                         LOG_INFO("Player #", client_num_str, " (", pl_name, ") is already on the ", Team_ColoredFullName(team_num), "^7.");
1110                                                         continue;
1111                                                 }
1112                                                 else if (team_num == 0)  // auto team
1113                                                 {
1114                                                         balance = TeamBalance_CheckAllowedTeams(client);
1115                                                         team_num = Team_IndexToTeam(TeamBalance_FindBestTeam(balance, client, false));
1116                                                 }
1117                                                 else
1118                                                 {
1119                                                         balance = TeamBalance_CheckAllowedTeams(client);
1120                                                 }
1121                                                 Player_SetForcedTeamIndex(client, save);
1122
1123                                                 // Check to see if the destination team is even available
1124                                                 int team_id = Team_TeamToIndex(team_num);
1125                                                 if (team_id == -1)
1126                                                 {
1127                                                         LOG_INFO("Can't move player to ", destination, " team because it doesn't exist.");
1128                                                         TeamBalance_Destroy(balance);
1129                                                         return;
1130                                                 }
1131                                                 if (!IsTeamAvailable(team_num))
1132                                                 {
1133                                                         LOG_INFO("Can't move player to ", destination, " team because it isn't available.");
1134                                                         TeamBalance_Destroy(balance);
1135                                                         return;
1136                                                 }
1137                                                 if (!TeamBalance_IsTeamAllowed(balance, team_id))
1138                                                 {
1139                                                         LOG_INFO("Player #", client_num_str, " (", pl_name, ") is not allowed to join the ", Team_ColoredFullName(team_num), "^7.");
1140                                                         TeamBalance_Destroy(balance);
1141                                                         continue;
1142                                                 }
1143                                                 TeamBalance_Destroy(balance);
1144
1145                                                 // If so, lets continue and finally move the player
1146                                                 Player_SetForcedTeamIndex(client, TEAM_FORCE_DEFAULT);
1147                                                 if (MoveToTeam(client, team_id, 6))
1148                                                 {
1149                                                         successful = strcat(successful, (successful ? ", " : ""), pl_name);
1150                                                         LOG_INFO("Player #", client_num_str, " (", pl_name, ") has been moved to the ", Team_ColoredFullName(team_num), "^7.");
1151                                                 }
1152                                                 else
1153                                                 {
1154                                                         LOG_INFO("Unable to move player #", client_num_str, " (", pl_name, ")");
1155                                                 }
1156                                         }
1157                                 } // loop end
1158
1159                                 if (successful) bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1160                                 else LOG_INFO("No players given (", original_targets, ") are able to move.");
1161
1162                                 return;  // still correct parameters so return to avoid usage print
1163                         }
1164                 }
1165
1166                 default:
1167                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1168                 case CMD_REQUEST_USAGE:
1169                 {
1170                         LOG_HELP("Usage:^3 sv_cmd moveplayer <clients> <destination>");
1171                         LOG_HELP("  <clients> is a list (separated by commas) of player entity ID's or nicknames");
1172                         LOG_HELP("  <destination> is what to send the player to, be it team or spectating");
1173                         LOG_HELP("  Full list of destinations here: spec, spectator, red, blue, yellow, pink, auto.");
1174                         LOG_HELP("Examples: sv_cmd moveplayer 1,3,5 red");
1175                         LOG_HELP("          sv_cmd moveplayer 2 spec");
1176                         LOG_HELP("See also: ^2allspec, shuffleteams^7");
1177                         return;
1178                 }
1179         }
1180 }
1181
1182 void GameCommand_nospectators(int request)
1183 {
1184         switch (request)
1185         {
1186                 case CMD_REQUEST_COMMAND:
1187                 {
1188                         if (!world_initialized)
1189                         {
1190                                 LOG_HELPF("This command works only when the server is running.");
1191                                 return;
1192                         }
1193                         blockSpectators = 1;
1194                         // give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1195                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_SPEC(it) || IS_OBSERVER(it)) && !INGAME(it), {
1196                                 CS(it).spectatortime = time;
1197                                 Send_Notification(NOTIF_ONE_ONLY, it, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1198                         });
1199                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1200                         return;
1201                 }
1202
1203                 default:
1204                 case CMD_REQUEST_USAGE:
1205                 {
1206                         LOG_HELP("Usage:^3 sv_cmd nospectators");
1207                         LOG_HELP("  No arguments required.");
1208                         return;
1209                 }
1210         }
1211 }
1212
1213 void GameCommand_printstats(int request)
1214 {
1215         switch (request)
1216         {
1217                 case CMD_REQUEST_COMMAND:
1218                 {
1219                         if (!world_initialized)
1220                         {
1221                                 LOG_HELPF("This command works only when the server is running.");
1222                                 return;
1223                         }
1224                         DumpStats(false);
1225                         LOG_INFO("stats dumped.");
1226                         return;
1227                 }
1228
1229                 default:
1230                 case CMD_REQUEST_USAGE:
1231                 {
1232                         LOG_HELP("Usage:^3 sv_cmd printstats");
1233                         LOG_HELP("  No arguments required.");
1234                         return;
1235                 }
1236         }
1237 }
1238
1239 void GameCommand_radarmap(int request, int argc)
1240 {
1241         switch (request)
1242         {
1243                 case CMD_REQUEST_COMMAND:
1244                 {
1245                         if (RadarMap_Make(argc)) return;
1246                 }
1247
1248                 default:
1249                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1250                 case CMD_REQUEST_USAGE:
1251                 {
1252                         LOG_HELP("Usage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]");
1253                         LOG_HELP("  The quality factor Q is roughly proportional to the time taken.");
1254                         LOG_HELP("  trace supports no quality factor; its result should look like --block with infinite quality factor.");
1255                         LOG_HELP("See also: ^2make_mapinfo^7");
1256                         return;
1257                 }
1258         }
1259 }
1260
1261 void GameCommand_reducematchtime(int request)
1262 {
1263         switch (request)
1264         {
1265                 case CMD_REQUEST_COMMAND:
1266                 {
1267                         if (!world_initialized)
1268                         {
1269                                 LOG_HELPF("This command works only when the server is running.");
1270                                 return;
1271                         }
1272                         changematchtime(autocvar_timelimit_decrement * -60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1273                         return;
1274                 }
1275
1276                 default:
1277                 case CMD_REQUEST_USAGE:
1278                 {
1279                         LOG_HELP("Usage:^3 sv_cmd reducematchtime");
1280                         LOG_HELP("  No arguments required.");
1281                         LOG_HELP("See also: ^2extendmatchtime^7");
1282                         return;
1283                 }
1284         }
1285 }
1286
1287 void GameCommand_setbots(int request, int argc)
1288 {
1289         switch (request)
1290         {
1291                 case CMD_REQUEST_COMMAND:
1292                 {
1293                         if (argc >= 2)
1294                         {
1295                                 cvar_settemp("minplayers", "0");
1296                                 cvar_settemp("minplayers_per_team", "0");
1297                                 cvar_settemp("bot_number", argv(1));
1298                                 bot_fixcount(true);
1299                                 return;
1300                         }
1301                 }
1302
1303                 default:
1304                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1305                 case CMD_REQUEST_USAGE:
1306                 {
1307                         LOG_HELP("Usage:^3 sv_cmd setbots <botnumber>");
1308                         LOG_HELP("  Where <botnumber> is the amount of bots to set bot_number cvar to.");
1309                         LOG_HELP("See also: ^2bot_cmd^7");
1310                         return;
1311                 }
1312         }
1313 }
1314
1315 void shuffleteams()
1316 {
1317         if (!teamplay)
1318         {
1319                 LOG_INFO("Can't shuffle teams when currently not playing a team game.");
1320                 return;
1321         }
1322
1323         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), {
1324                 if (Player_HasRealForcedTeam(it)) {
1325                         // we could theoretically assign forced players to their teams
1326                         // and shuffle the rest to fill the empty spots but in practise
1327                         // either all players or none are gonna have forced teams
1328                         LOG_INFO("Can't shuffle teams because at least one player has a forced team.");
1329                         return;
1330                 }
1331         });
1332
1333         int number_of_teams = 0;
1334         entity balance = TeamBalance_CheckAllowedTeams(NULL);
1335         for (int i = 1; i <= NUM_TEAMS; ++i)
1336         {
1337                 if (TeamBalance_IsTeamAllowed(balance, i))
1338                 {
1339                         number_of_teams = max(i, number_of_teams);
1340                 }
1341         }
1342         TeamBalance_Destroy(balance);
1343
1344         int team_index = 0;
1345         FOREACH_CLIENT_RANDOM(IS_PLAYER(it) || INGAME(it), {
1346                 int target_team_index = team_index + 1;
1347                 if (Entity_GetTeamIndex(it) != target_team_index)
1348                 {
1349                         MoveToTeam(it, target_team_index, 6);
1350                 }
1351                 team_index = (team_index + 1) % number_of_teams;
1352         });
1353
1354         bprint("Successfully shuffled the players around randomly.\n");
1355 }
1356
1357 void GameCommand_shuffleteams(int request)
1358 {
1359         switch (request)
1360         {
1361                 case CMD_REQUEST_COMMAND:
1362                 {
1363                         if (!world_initialized)
1364                         {
1365                                 LOG_HELPF("This command works only when the server is running.");
1366                                 return;
1367                         }
1368                         if (shuffleteams_on_reset_map)
1369                         {
1370                                 bprint("Players will be shuffled when this round is over.\n");
1371                                 shuffleteams_on_reset_map = true;
1372                         }
1373                         else
1374                                 shuffleteams();
1375                         return;
1376                 }
1377
1378                 default:
1379                 case CMD_REQUEST_USAGE:
1380                 {
1381                         LOG_HELP("Usage:^3 sv_cmd shuffleteams");
1382                         LOG_HELP("  No arguments required.");
1383                         LOG_HELP("See also: ^2moveplayer, allspec^7");
1384                         return;
1385                 }
1386         }
1387 }
1388
1389 void GameCommand_resetmatch(int request)
1390 {
1391         switch (request)
1392         {
1393                 case CMD_REQUEST_COMMAND:
1394                 {
1395                         if (!world_initialized)
1396                         {
1397                                 LOG_HELPF("This command works only when the server is running.");
1398                                 return;
1399                         }
1400                         ReadyRestart(false);
1401                         return;
1402                 }
1403
1404                 default:
1405                 case CMD_REQUEST_USAGE:
1406                 {
1407                         LOG_HELP("Usage:^3 sv_cmd resetmatch");
1408                         LOG_HELP("  No arguments required.");
1409                         return;
1410                 }
1411         }
1412 }
1413
1414 void GameCommand_stuffto(int request, int argc)
1415 {
1416         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1417         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1418         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1419
1420 #ifdef STUFFTO_ENABLED
1421                 switch (request)
1422                 {
1423                         case CMD_REQUEST_COMMAND:
1424                         {
1425                                 if (!world_initialized)
1426                                 {
1427                                         LOG_HELPF("This command works only when the server is running.");
1428                                         return;
1429                                 }
1430                                 if (argv(2))
1431                                 {
1432                                         entity client = GetIndexedEntity(argc, 1);
1433                                         float accepted = VerifyClientEntity(client, true, false);
1434
1435                                         if (accepted > 0)
1436                                         {
1437                                                 stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1438                                                 LOG_INFO("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1), ").");
1439                                         }
1440                                         else
1441                                         {
1442                                                 LOG_INFO("stuffto: ", GetClientErrorString(accepted, argv(1)), ".");
1443                                         }
1444
1445                                         return;
1446                                 }
1447                         }
1448
1449                         default:
1450                                 LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1451                         case CMD_REQUEST_USAGE:
1452                         {
1453                                 LOG_HELP("Usage:^3 sv_cmd stuffto <client> \"<command>\"");
1454                                 LOG_HELP("  <client> is the entity number or name of the player,");
1455                                 LOG_HELP("  and <command> is the command to be sent to that player.");
1456                                 return;
1457                         }
1458                 }
1459 #else
1460                 if (request)
1461                 {
1462                         LOG_HELP("stuffto command is not enabled on this server.");
1463                         return;
1464                 }
1465 #endif
1466 }
1467
1468 void GameCommand_trace(int request, int argc)
1469 {
1470         switch (request)
1471         {
1472                 case CMD_REQUEST_COMMAND:
1473                 {
1474                         entity e;
1475                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1476                         float i, f, safe, unsafe, dq, dqf;
1477
1478                         switch (argv(1))
1479                         {
1480                                 case "debug":
1481                                 {
1482                                         float hitcount = 0;
1483                                         LOG_INFO("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.");
1484                                         float worst_endpos_bug = 0;
1485                                         for ( ; ; )
1486                                         {
1487                                                 org = world.mins;
1488                                                 delta = world.maxs - world.mins;
1489
1490                                                 start.x = org.x + random() * delta.x;
1491                                                 start.y = org.y + random() * delta.y;
1492                                                 start.z = org.z + random() * delta.z;
1493
1494                                                 end.x = org.x + random() * delta.x;
1495                                                 end.y = org.y + random() * delta.y;
1496                                                 end.z = org.z + random() * delta.z;
1497
1498                                                 start = stov(vtos(start));
1499                                                 end = stov(vtos(end));
1500
1501                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1502                                                 if (!trace_startsolid && trace_fraction < 1)
1503                                                 {
1504                                                         p = trace_endpos;
1505                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, p, MOVE_NOMONSTERS, NULL);
1506                                                         if (trace_startsolid)
1507                                                         {
1508                                                                 rint(42);  // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1509                                                                 tracebox(start, PL_MIN_CONST, PL_MAX_CONST, end, MOVE_NOMONSTERS, NULL);
1510
1511                                                                 // how much do we need to back off?
1512                                                                 safe = 1;
1513                                                                 unsafe = 0;
1514                                                                 for ( ; ; )
1515                                                                 {
1516                                                                         pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1517                                                                         tracebox(pos, PL_MIN_CONST, PL_MAX_CONST, pos, MOVE_NOMONSTERS, NULL);
1518                                                                         if (trace_startsolid)
1519                                                                         {
1520                                                                                 if ((safe + unsafe) * 0.5 == unsafe) break;
1521                                                                                 unsafe = (safe + unsafe) * 0.5;
1522                                                                         }
1523                                                                         else
1524                                                                         {
1525                                                                                 if ((safe + unsafe) * 0.5 == safe) break;
1526                                                                                 safe = (safe + unsafe) * 0.5;
1527                                                                         }
1528                                                                 }
1529
1530                                                                 LOG_INFO("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu");
1531                                                                 LOG_INFO("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu");
1532
1533                                                                 tracebox(p, PL_MIN_CONST + '0.1 0.1 0.1', PL_MAX_CONST - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, NULL);
1534                                                                 if (trace_startsolid) LOG_INFO("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1535                                                                 else LOG_INFO("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1536                                                                 if (++hitcount >= 10) break;
1537                                                         }
1538                                                         else
1539                                                         {
1540                                                                 q0 = p;
1541                                                                 dq = 0;
1542                                                                 dqf = 1;
1543                                                                 for ( ; ; )
1544                                                                 {
1545                                                                         q = p + normalize(end - p) * (dq + dqf);
1546                                                                         if (q == q0) break;
1547                                                                         tracebox(p, PL_MIN_CONST, PL_MAX_CONST, q, MOVE_NOMONSTERS, NULL);
1548                                                                         if (trace_startsolid) error("THIS ONE cannot happen");
1549                                                                         if (trace_fraction > 0) dq += dqf * trace_fraction;
1550                                                                         dqf *= 0.5;
1551                                                                         q0 = q;
1552                                                                 }
1553                                                                 if (dq > worst_endpos_bug)
1554                                                                 {
1555                                                                         worst_endpos_bug = dq;
1556                                                                         LOG_INFO("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p));
1557                                                                         LOG_INFO("could go ", ftos(dq), " units further to ", vtos(q));
1558                                                                         if (++hitcount >= 10) break;
1559                                                                 }
1560                                                         }
1561                                                 }
1562                                         }
1563                                         return;
1564                                 }
1565
1566                                 case "debug2":
1567                                 {
1568                                         e = nextent(NULL);
1569                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1570                                         vv = trace_endpos;
1571                                         if (trace_fraction == 1)
1572                                         {
1573                                                 LOG_INFO("not above ground, aborting");
1574                                                 return;
1575                                         }
1576                                         f = 0;
1577                                         for (i = 0; i < 100000; ++i)
1578                                         {
1579                                                 dv = randomvec();
1580                                                 if (dv.z > 0) dv = -1 * dv;
1581                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1582                                                 if (trace_startsolid) LOG_INFO("bug 1");
1583                                                 if (trace_fraction == 1)
1584                                                 {
1585                                                         if (dv.z < f)
1586                                                         {
1587                                                                 LOG_INFO("bug 2: ", ftos(dv.x), " ", ftos(dv.y), " ", ftos(dv.z));
1588                                                                 LOG_INFO(" (", ftos(asin(dv.z / vlen(dv)) * 180 / M_PI), " degrees)");
1589                                                                 f = dv.z;
1590                                                         }
1591                                                 }
1592                                         }
1593                                         LOG_INFO("highest possible dist: ", ftos(f));
1594                                         return;
1595                                 }
1596
1597                                 case "walk":
1598                                 {
1599                                         if (argc == 4 || argc == 5)
1600                                         {
1601                                                 e = nextent(NULL);
1602                                                 int dphitcontentsmask_save = e.dphitcontentsmask;
1603                                                 e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
1604                                                 if (tracewalk(e, stov(argv(2)), e.mins, e.maxs, stov(argv(3)), stof(argv(4)), MOVE_NORMAL))
1605                                                         LOG_INFO("can walk");
1606                                                 else
1607                                                         LOG_INFO("cannot walk");
1608                                                 e.dphitcontentsmask = dphitcontentsmask_save;
1609                                                 return;
1610                                         }
1611                                 }
1612
1613                                 case "showline":
1614                                 {
1615                                         if (argc == 4)
1616                                         {
1617                                                 vv = stov(argv(2));
1618                                                 dv = stov(argv(3));
1619                                                 traceline(vv, dv, MOVE_NORMAL, NULL);
1620                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_NEXUIZPLASMA), vv, trace_endpos);
1621                                                 __trailparticles(NULL, particleeffectnum(EFFECT_TR_CRYLINKPLASMA), trace_endpos, dv);
1622                                                 return;
1623                                         }
1624                                 }
1625
1626                                 // no default case, just go straight to invalid
1627                         }
1628                 }
1629
1630                 default:
1631                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
1632                 case CMD_REQUEST_USAGE:
1633                 {
1634                         LOG_HELP("Usage:^3 sv_cmd trace <command> [<startpos> <endpos>] [<endpos_height>]");
1635                         LOG_HELP("  Where <startpos> and <endpos> are parameters for the 'walk' and 'showline' commands,");
1636                         LOG_HELP("  <endpos_height> is an optional parameter for the 'walk' command,");
1637                         LOG_HELP("  Full list of commands here: debug, debug2, walk, showline.");
1638                         LOG_HELP("See also: ^2bbox, gettaginfo^7");
1639                         return;
1640                 }
1641         }
1642 }
1643
1644 void GameCommand_unlockteams(int request)
1645 {
1646         switch (request)
1647         {
1648                 case CMD_REQUEST_COMMAND:
1649                 {
1650                         if (!world_initialized)
1651                         {
1652                                 LOG_HELPF("This command works only when the server is running.");
1653                                 return;
1654                         }
1655                         if (teamplay)
1656                         {
1657                                 lockteams = 0;
1658                                 bprint("^1The teams are now unlocked.\n");
1659                         }
1660                         else
1661                         {
1662                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1663                         }
1664                         return;
1665                 }
1666
1667                 default:
1668                 case CMD_REQUEST_USAGE:
1669                 {
1670                         LOG_HELP("Usage:^3 sv_cmd unlockteams");
1671                         LOG_HELP("  No arguments required.");
1672                         LOG_HELP("See also: ^2lockteams^7");
1673                         return;
1674                 }
1675         }
1676 }
1677
1678 void GameCommand_warp(int request, int argc)
1679 {
1680         switch (request)
1681         {
1682                 case CMD_REQUEST_COMMAND:
1683                 {
1684                         if (!world_initialized)
1685                         {
1686                                 LOG_HELPF("This command works only when the server is running.");
1687                                 return;
1688                         }
1689                         if (autocvar_g_campaign)
1690                         {
1691                                 if (argc >= 2)
1692                                 {
1693                                         CampaignLevelWarp(stof(argv(1)));
1694                                         LOG_INFO("Successfully warped to campaign level ", argv(1), ".");
1695                                 }
1696                                 else
1697                                 {
1698                                         CampaignLevelWarp(-1);
1699                                         LOG_INFO("Successfully warped to next campaign level.");
1700                                 }
1701                         }
1702                         else
1703                         {
1704                                 LOG_INFO("Not in campaign, can't level warp");
1705                         }
1706                         return;
1707                 }
1708
1709                 default:
1710                 case CMD_REQUEST_USAGE:
1711                 {
1712                         LOG_HELP("Usage:^3 sv_cmd warp [<level>]");
1713                         LOG_HELP("  <level> is the level to change campaign mode to.");
1714                         LOG_HELP("  if <level> is not provided it will change to the next level.");
1715                         return;
1716                 }
1717         }
1718 }
1719
1720 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1721 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1722 void GameCommand_(int request)
1723 {
1724     switch(request)
1725     {
1726         case CMD_REQUEST_COMMAND:
1727         {
1728                     if (!world_initialized)
1729                     {
1730                         LOG_HELPF("This command works only when the server is running.");
1731                         return;
1732                     }
1733
1734             return;
1735         }
1736
1737         default:
1738         case CMD_REQUEST_USAGE:
1739         {
1740             LOG_HELP("Usage:^3 sv_cmd ");
1741             LOG_HELP("  No arguments required.");
1742             return;
1743         }
1744     }
1745 }
1746 */
1747
1748
1749 // ==================================
1750 //  Macro system for server commands
1751 // ==================================
1752
1753 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1754 SERVER_COMMAND(adminmsg, "Send an admin message to a client directly") { GameCommand_adminmsg(request, arguments); }
1755 SERVER_COMMAND(allready, "Ends warmup and starts the match") { GameCommand_allready(request); }
1756 SERVER_COMMAND(allspec, "Force all players to spectate") { GameCommand_allspec(request, arguments); }
1757 SERVER_COMMAND(anticheat, "Create an anticheat report for a client") { GameCommand_anticheat(request, arguments); }
1758 SERVER_COMMAND(animbench, "Benchmark model animation (LAGS)") { GameCommand_animbench(request, arguments); }
1759 SERVER_COMMAND(bbox, "Print detailed information about world size") { GameCommand_bbox(request); }
1760 SERVER_COMMAND(bot_cmd, "Control and send commands to bots") { GameCommand_bot_cmd(request, arguments, command); }
1761 SERVER_COMMAND(cointoss, "Flip a virtual coin and give random result") { GameCommand_cointoss(request, arguments); }
1762 SERVER_COMMAND(database, "Extra controls of the serverprogs database") { GameCommand_database(request, arguments); }
1763 SERVER_COMMAND(defer_clear, "Clear all queued defer commands for a specific client") { GameCommand_defer_clear(request, arguments); }
1764 SERVER_COMMAND(defer_clear_all, "Clear all queued defer commands for all clients") { GameCommand_defer_clear_all(request); }
1765 SERVER_COMMAND(delrec, "Delete race time record for a map") { GameCommand_delrec(request, arguments); }
1766 SERVER_COMMAND(effectindexdump, "Dump list of effects from code and effectinfo.txt") { GameCommand_effectindexdump(request); }
1767 SERVER_COMMAND(extendmatchtime, "Increase the timelimit value incrementally") { GameCommand_extendmatchtime(request); }
1768 SERVER_COMMAND(gametype, "Simple command to change the active gametype") { GameCommand_gametype(request, arguments); }
1769 SERVER_COMMAND(gettaginfo, "Get specific information about a weapon model") { GameCommand_gettaginfo(request, arguments); }
1770 SERVER_COMMAND(gotomap, "Simple command to switch to another map") { GameCommand_gotomap(request, arguments); }
1771 SERVER_COMMAND(lockteams, "Disable the ability for players to switch or enter teams") { GameCommand_lockteams(request); }
1772 SERVER_COMMAND(make_mapinfo, "Automatically rebuild mapinfo files") { GameCommand_make_mapinfo(request); }
1773 SERVER_COMMAND(moveplayer, "Change the team/status of a player") { GameCommand_moveplayer(request, arguments); }
1774 SERVER_COMMAND(nospectators, "Automatically remove spectators from a match") { GameCommand_nospectators(request); }
1775 SERVER_COMMAND(printstats, "Dump eventlog player stats and other score information") { GameCommand_printstats(request); }
1776 SERVER_COMMAND(radarmap, "Generate a radar image of the map") { GameCommand_radarmap(request, arguments); }
1777 SERVER_COMMAND(reducematchtime, "Decrease the timelimit value incrementally") { GameCommand_reducematchtime(request); }
1778 SERVER_COMMAND(resetmatch, "Soft restart the game without changing teams; goes back to warmup if enabled") { GameCommand_resetmatch(request); }
1779 SERVER_COMMAND(setbots, "Adjust how many bots are in the match") { GameCommand_setbots(request, arguments); }
1780 SERVER_COMMAND(shuffleteams, "Randomly move players to different teams") { GameCommand_shuffleteams(request); }
1781 SERVER_COMMAND(stuffto, "Send a command to be executed on a client") { GameCommand_stuffto(request, arguments); }
1782 SERVER_COMMAND(trace, "Various debugging tools with tracing") { GameCommand_trace(request, arguments); }
1783 SERVER_COMMAND(unlockteams, "Enable the ability for players to switch or enter teams") { GameCommand_unlockteams(request); }
1784 SERVER_COMMAND(warp, "Choose different level in campaign") { GameCommand_warp(request, arguments); }
1785
1786 void GameCommand_macro_help()
1787 {
1788         FOREACH(SERVER_COMMANDS, true, { LOG_HELPF("  ^2%s^7: %s", it.m_name, it.m_description); });
1789 }
1790
1791 float GameCommand_macro_command(int argc, string command)
1792 {
1793         string c = strtolower(argv(0));
1794         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1795                 it.m_invokecmd(it, CMD_REQUEST_COMMAND, NULL, argc, command);
1796                 return true;
1797         });
1798         return false;
1799 }
1800
1801 float GameCommand_macro_usage(int argc)
1802 {
1803         string c = strtolower(argv(1));
1804         FOREACH(SERVER_COMMANDS, it.m_name == c, {
1805                 it.m_invokecmd(it, CMD_REQUEST_USAGE, NULL, argc, "");
1806                 return true;
1807         });
1808         return false;
1809 }
1810
1811 void GameCommand_macro_write_aliases(float fh)
1812 {
1813         FOREACH(SERVER_COMMANDS, true, { CMD_Write_Alias("qc_cmd_sv", it.m_name, it.m_description); });
1814 }
1815
1816
1817 // =========================================
1818 //  Main Function Called By Engine (sv_cmd)
1819 // =========================================
1820 // If this function exists, game code handles gamecommand instead of the engine code.
1821
1822 void GameCommand(string command)
1823 {
1824         int argc = tokenize_console(command);
1825
1826         // Guide for working with argc arguments by example:
1827         // argc:   1    - 2      - 3     - 4
1828         // argv:   0    - 1      - 2     - 3
1829         // cmd     vote - master - login - password
1830
1831         if (strtolower(argv(0)) == "help")
1832         {
1833                 if (argc == 1)
1834                 {
1835                         LOG_HELP("Server console commands:");
1836                         GameCommand_macro_help();
1837
1838                         LOG_HELP("\nBanning commands:");
1839                         BanCommand_macro_help();
1840
1841                         LOG_HELP("\nCommon networked commands:");
1842                         CommonCommand_macro_help(NULL);
1843
1844                         LOG_HELP("\nGeneric commands shared by all programs:");
1845                         GenericCommand_macro_help();
1846
1847                         LOG_HELP("\nUsage:^3 sv_cmd <command>^7, where possible commands are listed above.\n"
1848                                 "For help about a specific command, type sv_cmd help <command>");
1849
1850                         return;
1851                 }
1852                 else if (BanCommand_macro_usage(argc))  // Instead of trying to call a command, we're going to see detailed information about it
1853                 {
1854                         return;
1855                 }
1856                 else if (CommonCommand_macro_usage(argc, NULL))  // same here, but for common commands instead
1857                 {
1858                         return;
1859                 }
1860                 else if (GenericCommand_macro_usage(argc))  // same here, but for generic commands instead
1861                 {
1862                         return;
1863                 }
1864                 else if (GameCommand_macro_usage(argc))  // finally try for normal commands too
1865                 {
1866                         return;
1867                 }
1868         }
1869         else if (MUTATOR_CALLHOOK(SV_ParseServerCommand, strtolower(argv(0)), argc, command))
1870         {
1871                 return;  // handled by a mutator
1872         }
1873         else if (BanCommand(command))
1874         {
1875                 return;  // handled by server/command/ipban.qc
1876         }
1877         else if (CommonCommand_macro_command(argc, NULL, command))
1878         {
1879                 return;  // handled by server/command/common.qc
1880         }
1881         else if (GenericCommand(command))
1882         {
1883                 return;                                        // handled by common/command/generic.qc
1884         }
1885         else if (GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1886         {
1887                 return;                                        // handled by one of the above GameCommand_* functions
1888         }
1889
1890         // nothing above caught the command, must be invalid
1891         LOG_INFO(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.");
1892 }