qcsrc/server/cl_client.qc

   1 #include "waypointsprites.qh"
   2
   3 #include "cl_impulse.qh"
   4 #include "cl_player.qh"
   5 #include "ent_cs.qh"
   6 #include "g_subs.qh"
   7 #include "ipban.qh"
   8 #include "miscfunctions.qh"
   9 #include "portals.qh"
  10 #include "teamplay.qh"
  11 #include "playerdemo.qh"
  12 #include "secret.qh"
  13
  14 #include "bot/bot.qh"
  15 #include "bot/navigation.qh"
  16
  17 #include "weapons/hitplot.qh"
  18 #include "weapons/weaponsystem.qh"
  19
  20 #include "../common/net_notice.qh"
  21
  22 #include "../common/monsters/sv_monsters.qh"
  23
  24 #include "../warpzonelib/server.qh"
  25
  26 float c1, c2, c3, c4;
  27
  28 void send_CSQC_teamnagger() {
  29         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  30         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  31 }
  32
  33 float ClientData_Send(entity to, int sf)
  34 {
  35         if(to != self.owner)
  36         {
  37                 error("wtf");
  38                 return false;
  39         }
  40
  41         entity e;
  42
  43         e = to;
  44         if(IS_SPEC(to))
  45                 e = to.enemy;
  46
  47         sf = 0;
  48
  49         if(e.race_completed)
  50                 sf |= 1; // forced scoreboard
  51         if(to.spectatee_status)
  52                 sf |= 2; // spectator ent number follows
  53         if(e.zoomstate)
  54                 sf |= 4; // zoomed
  55         if(e.porto_v_angle_held)
  56                 sf |= 8; // angles held
  57
  58         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  59         WriteByte(MSG_ENTITY, sf);
  60
  61         if(sf & 2)
  62                 WriteByte(MSG_ENTITY, to.spectatee_status);
  63
  64         if(sf & 8)
  65         {
  66                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  67                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  68         }
  69
  70         return true;
  71 }
  72
  73 void ClientData_Attach()
  74 {
  75         Net_LinkEntity(self.clientdata = spawn(), false, 0, ClientData_Send);
  76         self.clientdata.drawonlytoclient = self;
  77         self.clientdata.owner = self;
  78 }
  79
  80 void ClientData_Detach()
  81 {
  82         remove(self.clientdata);
  83         self.clientdata = world;
  84 }
  85
  86 void ClientData_Touch(entity e)
  87 {
  88         e.clientdata.SendFlags = 1;
  89
  90         // make it spectatable
  91         entity e2;
  92         FOR_EACH_REALCLIENT(e2)
  93         {
  94                 if(e2 != e)
  95                         if(IS_SPEC(e2))
  96                                 if(e2.enemy == e)
  97                                         e2.clientdata.SendFlags = 1;
  98         }
  99 }
 100
 101 .string netname_previous;
 102
 103 void SetSpectator(entity player, entity spectatee);
 104
 105
 106 /*
 107 =============
 108 CheckPlayerModel
 109
 110 Checks if the argument string can be a valid playermodel.
 111 Returns a valid one in doubt.
 112 =============
 113 */
 114 string FallbackPlayerModel;
 115 string CheckPlayerModel(string plyermodel) {
 116         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 117         {
 118                 // note: we cannot summon Don Strunzone here, some player may
 119                 // still have the model string set. In case anyone manages how
 120                 // to change a cvar default, we'll have a small leak here.
 121                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 122         }
 123         // only in right path
 124         if( substring(plyermodel,0,14) != "models/player/")
 125                 return FallbackPlayerModel;
 126         // only good file extensions
 127         if(substring(plyermodel,-4,4) != ".zym")
 128         if(substring(plyermodel,-4,4) != ".dpm")
 129         if(substring(plyermodel,-4,4) != ".iqm")
 130         if(substring(plyermodel,-4,4) != ".md3")
 131         if(substring(plyermodel,-4,4) != ".psk")
 132                 return FallbackPlayerModel;
 133         // forbid the LOD models
 134         if(substring(plyermodel, -9,5) == "_lod1")
 135                 return FallbackPlayerModel;
 136         if(substring(plyermodel, -9,5) == "_lod2")
 137                 return FallbackPlayerModel;
 138         if(plyermodel != strtolower(plyermodel))
 139                 return FallbackPlayerModel;
 140         // also, restrict to server models
 141         if(autocvar_sv_servermodelsonly)
 142         {
 143                 if(!fexists(plyermodel))
 144                         return FallbackPlayerModel;
 145         }
 146         return plyermodel;
 147 }
 148
 149 void setplayermodel(entity e, string modelname)
 150 {
 151         precache_model(modelname);
 152         setmodel(e, modelname);
 153         player_setupanimsformodel();
 154         UpdatePlayerSounds();
 155 }
 156
 157 /*
 158 =============
 159 PutObserverInServer
 160
 161 putting a client as observer in the server
 162 =============
 163 */
 164 void FixPlayermodel();
 165 void PutObserverInServer (void)
 166 {
 167         entity  spot;
 168     self.hud = HUD_NORMAL;
 169
 170         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 171
 172         spot = SelectSpawnPoint (true);
 173         if(!spot)
 174                 error("No spawnpoints for observers?!?\n");
 175         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 176
 177         if(IS_REAL_CLIENT(self))
 178         {
 179                 msg_entity = self;
 180                 WriteByte(MSG_ONE, SVC_SETVIEW);
 181                 WriteEntity(MSG_ONE, self);
 182         }
 183
 184         self.frags = FRAGS_SPECTATOR;
 185
 186         MUTATOR_CALLHOOK(MakePlayerObserver);
 187
 188         Portal_ClearAll(self);
 189
 190         Unfreeze(self);
 191
 192         if(self.alivetime)
 193         {
 194                 if(!warmup_stage)
 195                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 196                 self.alivetime = 0;
 197         }
 198
 199         if(self.vehicle)
 200                 vehicles_exit(VHEF_RELESE);
 201
 202         WaypointSprite_PlayerDead();
 203
 204         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 205                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 206
 207         if(self.killcount != -666)
 208         {
 209                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 210                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 211                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 212
 213                 if(self.just_joined == false) {
 214                         LogTeamchange(self.playerid, -1, 4);
 215                 } else
 216                         self.just_joined = false;
 217         }
 218
 219         PlayerScore_Clear(self); // clear scores when needed
 220
 221         accuracy_resend(self);
 222
 223         self.spectatortime = time;
 224
 225         self.classname = "observer";
 226         self.iscreature = false;
 227         self.teleportable = TELEPORT_SIMPLE;
 228         self.damagedbycontents = false;
 229         self.health = -666;
 230         self.takedamage = DAMAGE_NO;
 231         self.solid = SOLID_NOT;
 232         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 233         self.flags = FL_CLIENT | FL_NOTARGET;
 234         self.armorvalue = 666;
 235         self.effects = 0;
 236         self.armorvalue = autocvar_g_balance_armor_start;
 237         self.pauserotarmor_finished = 0;
 238         self.pauserothealth_finished = 0;
 239         self.pauseregen_finished = 0;
 240         self.damageforcescale = 0;
 241         self.death_time = 0;
 242         self.respawn_flags = 0;
 243         self.respawn_time = 0;
 244         self.stat_respawn_time = 0;
 245         self.alpha = 0;
 246         self.scale = 0;
 247         self.fade_time = 0;
 248         self.pain_frame = 0;
 249         self.pain_finished = 0;
 250         self.strength_finished = 0;
 251         self.invincible_finished = 0;
 252         self.superweapons_finished = 0;
 253         self.pushltime = 0;
 254         self.istypefrag = 0;
 255         self.think = func_null;
 256         self.nextthink = 0;
 257         self.hook_time = 0;
 258         self.deadflag = DEAD_NO;
 259         self.angles = spot.angles;
 260         self.angles_z = 0;
 261         self.fixangle = true;
 262         self.crouch = false;
 263         self.revival_time = 0;
 264
 265         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 266         self.prevorigin = self.origin;
 267         self.items = 0;
 268         self.weapons = '0 0 0';
 269         self.model = "";
 270         FixPlayermodel();
 271         setmodel(self, "null");
 272         self.drawonlytoclient = self;
 273
 274         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 275         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 276
 277         self.weapon = 0;
 278         self.weaponname = "";
 279         self.switchingweapon = 0;
 280         self.weaponmodel = "";
 281         self.weaponentity = world;
 282         self.exteriorweaponentity = world;
 283         self.killcount = -666;
 284         self.velocity = '0 0 0';
 285         self.avelocity = '0 0 0';
 286         self.punchangle = '0 0 0';
 287         self.punchvector = '0 0 0';
 288         self.oldvelocity = self.velocity;
 289         self.fire_endtime = -1;
 290         self.event_damage = func_null;
 291 }
 292
 293 .float model_randomizer;
 294 void FixPlayermodel()
 295 {
 296         string defaultmodel;
 297         float defaultskin, chmdl, oldskin, n, i;
 298         vector m1, m2;
 299
 300         defaultmodel = "";
 301         defaultskin = 0;
 302         chmdl = false;
 303
 304         if(autocvar_sv_defaultcharacter)
 305         {
 306                 if(teamplay)
 307                 {
 308                         string s;
 309                         s = Static_Team_ColorName_Lower(self.team);
 310                         if(s != "neutral")
 311                         {
 312                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 313                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 314                         }
 315                 }
 316
 317                 if(defaultmodel == "")
 318                 {
 319                         defaultmodel = autocvar_sv_defaultplayermodel;
 320                         defaultskin = autocvar_sv_defaultplayerskin;
 321                 }
 322
 323                 n = tokenize_console(defaultmodel);
 324                 if(n > 0)
 325                 {
 326                         defaultmodel = argv(floor(n * self.model_randomizer));
 327                         // However, do NOT randomize if the player-selected model is in the list.
 328                         for (i = 0; i < n; ++i)
 329                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 330                                         defaultmodel = argv(i);
 331                 }
 332
 333                 i = strstrofs(defaultmodel, ":", 0);
 334                 if(i >= 0)
 335                 {
 336                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 337                         defaultmodel = substring(defaultmodel, 0, i);
 338                 }
 339         }
 340
 341         if(defaultmodel != "")
 342         {
 343                 if (defaultmodel != self.model)
 344                 {
 345                         m1 = self.mins;
 346                         m2 = self.maxs;
 347                         setplayermodel (self, defaultmodel);
 348                         setsize (self, m1, m2);
 349                         chmdl = true;
 350                 }
 351
 352                 oldskin = self.skin;
 353                 self.skin = defaultskin;
 354         } else {
 355                 if (self.playermodel != self.model || self.playermodel == "")
 356                 {
 357                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 358                         m1 = self.mins;
 359                         m2 = self.maxs;
 360                         setplayermodel (self, self.playermodel);
 361                         setsize (self, m1, m2);
 362                         chmdl = true;
 363                 }
 364
 365                 oldskin = self.skin;
 366                 self.skin = stof(self.playerskin);
 367         }
 368
 369         if(chmdl || oldskin != self.skin) // model or skin has changed
 370         {
 371                 self.species = player_getspecies(); // update species
 372                 UpdatePlayerSounds(); // update skin sounds
 373         }
 374
 375         if(!teamplay)
 376                 if(strlen(autocvar_sv_defaultplayercolors))
 377                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 378                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 379 }
 380
 381 /*
 382 =============
 383 PutClientInServer
 384
 385 Called when a client spawns in the server
 386 =============
 387 */
 388 void PutClientInServer (void)
 389 {
 390         if(IS_BOT_CLIENT(self))
 391                 self.classname = "player";
 392         else if(IS_REAL_CLIENT(self))
 393         {
 394                 msg_entity = self;
 395                 WriteByte(MSG_ONE, SVC_SETVIEW);
 396                 WriteEntity(MSG_ONE, self);
 397         }
 398
 399         SetSpectator(self, world);
 400
 401         // reset player keys
 402         self.itemkeys = 0;
 403
 404         MUTATOR_CALLHOOK(PutClientInServer);
 405
 406         if(gameover)
 407                 self.classname = "observer";
 408
 409         if(IS_PLAYER(self))
 410         {
 411                 entity spot, oldself;
 412
 413                 accuracy_resend(self);
 414
 415                 if(self.team < 0)
 416                         JoinBestTeam(self, false, true);
 417
 418                 spot = SelectSpawnPoint (false);
 419                 if(!spot)
 420                 {
 421                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 422                         return; // spawn failed
 423                 }
 424
 425                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 426
 427                 if(self.vehicle)
 428                         vehicles_exit(VHEF_RELESE);
 429
 430                 self.classname = "player";
 431                 self.wasplayer = true;
 432                 self.iscreature = true;
 433                 self.teleportable = TELEPORT_NORMAL;
 434                 self.damagedbycontents = true;
 435                 self.movetype = MOVETYPE_WALK;
 436                 self.solid = SOLID_SLIDEBOX;
 437                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 438                 if(autocvar_g_playerclip_collisions)
 439                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 440                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 441                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 442                 self.frags = FRAGS_PLAYER;
 443                 if(INDEPENDENT_PLAYERS)
 444                         MAKE_INDEPENDENT_PLAYER(self);
 445                 self.flags = FL_CLIENT;
 446                 if(autocvar__notarget)
 447                         self.flags |= FL_NOTARGET;
 448                 self.takedamage = DAMAGE_AIM;
 449                 self.effects = 0;
 450                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 451                 self.air_finished = time + 12;
 452                 self.dmg = 2;
 453                 if(WEP_CVAR(vortex, charge))
 454                 {
 455                         if(WEP_CVAR_SEC(vortex, chargepool))
 456                                 self.vortex_chargepool_ammo = 1;
 457                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 458                 }
 459
 460                 if(warmup_stage)
 461                 {
 462                         self.ammo_shells = warmup_start_ammo_shells;
 463                         self.ammo_nails = warmup_start_ammo_nails;
 464                         self.ammo_rockets = warmup_start_ammo_rockets;
 465                         self.ammo_cells = warmup_start_ammo_cells;
 466                         self.ammo_plasma = warmup_start_ammo_plasma;
 467                         self.ammo_fuel = warmup_start_ammo_fuel;
 468                         self.health = warmup_start_health;
 469                         self.armorvalue = warmup_start_armorvalue;
 470                         self.weapons = WARMUP_START_WEAPONS;
 471                 }
 472                 else
 473                 {
 474                         self.ammo_shells = start_ammo_shells;
 475                         self.ammo_nails = start_ammo_nails;
 476                         self.ammo_rockets = start_ammo_rockets;
 477                         self.ammo_cells = start_ammo_cells;
 478                         self.ammo_plasma = start_ammo_plasma;
 479                         self.ammo_fuel = start_ammo_fuel;
 480                         self.health = start_health;
 481                         self.armorvalue = start_armorvalue;
 482                         self.weapons = start_weapons;
 483                 }
 484
 485                 if(self.weapons & WEPSET_SUPERWEAPONS)
 486                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 487                 else
 488                         self.superweapons_finished = 0;
 489
 490                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 491                 {
 492                         if(g_weaponarena_random_with_blaster)
 493                                 self.weapons &= ~WEPSET_BLASTER;
 494                         W_RandomWeapons(self, g_weaponarena_random);
 495                         if(g_weaponarena_random_with_blaster)
 496                                 self.weapons |= WEPSET_BLASTER;
 497                 }
 498
 499                 self.items = start_items;
 500
 501                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 502                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 503                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 504                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 505                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 506                 //extend the pause of rotting if client was reset at the beginning of the countdown
 507                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 508                         self.spawnshieldtime += game_starttime - time;
 509                         self.pauserotarmor_finished += game_starttime - time;
 510                         self.pauserothealth_finished += game_starttime - time;
 511                         self.pauseregen_finished += game_starttime - time;
 512                 }
 513                 self.damageforcescale = 2;
 514                 self.death_time = 0;
 515                 self.respawn_flags = 0;
 516                 self.respawn_time = 0;
 517                 self.stat_respawn_time = 0;
 518                 self.scale = 0;
 519                 self.fade_time = 0;
 520                 self.pain_frame = 0;
 521                 self.pain_finished = 0;
 522                 self.strength_finished = 0;
 523                 self.invincible_finished = 0;
 524                 self.pushltime = 0;
 525                 // players have no think function
 526                 self.think = func_null;
 527                 self.nextthink = 0;
 528                 self.hook_time = 0;
 529                 self.dmg_team = 0;
 530                 self.ballistics_density = autocvar_g_ballistics_density_player;
 531
 532                 self.metertime = 0;
 533
 534                 self.deadflag = DEAD_NO;
 535
 536                 self.angles = spot.angles;
 537
 538                 self.angles_z = 0; // never spawn tilted even if the spot says to
 539                 if(IS_BOT_CLIENT(self))
 540                         self.v_angle = self.angles;
 541                 self.fixangle = true; // turn this way immediately
 542                 self.velocity = '0 0 0';
 543                 self.avelocity = '0 0 0';
 544                 self.punchangle = '0 0 0';
 545                 self.punchvector = '0 0 0';
 546                 self.oldvelocity = self.velocity;
 547                 self.fire_endtime = -1;
 548                 self.revival_time = 0;
 549
 550                 entity spawnevent = spawn();
 551                 spawnevent.owner = self;
 552                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 553
 554                 // Cut off any still running player sounds.
 555                 stopsound(self, CH_PLAYER_SINGLE);
 556
 557                 self.model = "";
 558                 FixPlayermodel();
 559                 self.drawonlytoclient = world;
 560
 561                 self.crouch = false;
 562                 self.view_ofs = PL_VIEW_OFS;
 563                 setsize (self, PL_MIN, PL_MAX);
 564                 self.spawnorigin = spot.origin;
 565                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins.z - 24));
 566                 // don't reset back to last position, even if new position is stuck in solid
 567                 self.oldorigin = self.origin;
 568                 self.prevorigin = self.origin;
 569                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 570                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 571         self.hud = HUD_NORMAL;
 572
 573                 self.event_damage = PlayerDamage;
 574
 575                 self.bot_attack = true;
 576                 self.monster_attack = true;
 577
 578                 self.spider_slowness = 0;
 579
 580                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 581
 582                 if(self.killcount == -666) {
 583                         PlayerScore_Clear(self);
 584                         self.killcount = 0;
 585                 }
 586
 587                 CL_SpawnWeaponentity();
 588                 self.alpha = default_player_alpha;
 589                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 590                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 591
 592                 self.speedrunning = false;
 593
 594                 //stuffcmd(self, "chase_active 0");
 595                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 596
 597                 target_voicescript_clear(self);
 598
 599                 // reset fields the weapons may use
 600                 for (int j = WEP_FIRST; j <= WEP_LAST; ++j)
 601                 {
 602                         WEP_ACTION(j, WR_RESETPLAYER);
 603
 604                         // all weapons must be fully loaded when we spawn
 605                         entity e = get_weaponinfo(j);
 606                         if (e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 607                                 self.(weapon_load[j]) = e.reloading_ammo;
 608                 }
 609
 610                 oldself = self;
 611                 self = spot;
 612                         activator = oldself;
 613                                 string s;
 614                                 s = self.target;
 615                                 self.target = string_null;
 616                                 SUB_UseTargets();
 617                                 self.target = s;
 618                         activator = world;
 619                 self = oldself;
 620
 621                 Unfreeze(self);
 622
 623                 spawn_spot = spot;
 624                 MUTATOR_CALLHOOK(PlayerSpawn);
 625
 626                 if(autocvar_spawn_debug)
 627                 {
 628                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 629                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 630                 }
 631
 632                 self.switchweapon = w_getbestweapon(self);
 633                 self.cnt = -1; // W_LastWeapon will not complain
 634                 self.weapon = 0;
 635                 self.weaponname = "";
 636                 self.switchingweapon = 0;
 637
 638                 if(!warmup_stage)
 639                         if(!self.alivetime)
 640                                 self.alivetime = time;
 641
 642                 antilag_clear(self);
 643         }
 644         else if(IS_OBSERVER(self))
 645         {
 646                 PutObserverInServer ();
 647         }
 648 }
 649
 650 .float ebouncefactor, ebouncestop; // electro's values
 651 // TODO do we need all these fields, or should we stop autodetecting runtime
 652 // changes and just have a console command to update this?
 653 float ClientInit_SendEntity(entity to, int sf)
 654 {
 655         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 656         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 657         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 658         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 659         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 660         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 661         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 662         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 663         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 664         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 665
 666         if(sv_foginterval && world.fog != "")
 667                 WriteString(MSG_ENTITY, world.fog);
 668         else
 669                 WriteString(MSG_ENTITY, "");
 670         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 671         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 672         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 673         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 674         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 675         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 676         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 677         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 678         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 679         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 680         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 681         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 682         return true;
 683 }
 684
 685 void ClientInit_CheckUpdate()
 686 {
 687         self.nextthink = time;
 688         if(self.count != autocvar_g_balance_armor_blockpercent)
 689         {
 690                 self.count = autocvar_g_balance_armor_blockpercent;
 691                 self.SendFlags |= 1;
 692         }
 693         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 694         {
 695                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 696                 self.SendFlags |= 1;
 697         }
 698         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 699         {
 700                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 701                 self.SendFlags |= 1;
 702         }
 703         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 704         {
 705                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 706                 self.SendFlags |= 1;
 707         }
 708         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 709         {
 710                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 711                 self.SendFlags |= 1;
 712         }
 713 }
 714
 715 void ClientInit_Spawn()
 716 {
 717         entity o;
 718         entity e;
 719         e = spawn();
 720         e.classname = "clientinit";
 721         e.think = ClientInit_CheckUpdate;
 722         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 723
 724         o = self;
 725         self = e;
 726         ClientInit_CheckUpdate();
 727         self = o;
 728 }
 729
 730 /*
 731 =============
 732 SetNewParms
 733 =============
 734 */
 735 void SetNewParms (void)
 736 {
 737         // initialize parms for a new player
 738         parm1 = -(86400 * 366);
 739 }
 740
 741 /*
 742 =============
 743 SetChangeParms
 744 =============
 745 */
 746 void SetChangeParms (void)
 747 {
 748         // save parms for level change
 749         parm1 = self.parm_idlesince - time;
 750 }
 751
 752 /*
 753 =============
 754 DecodeLevelParms
 755 =============
 756 */
 757 void DecodeLevelParms (void)
 758 {
 759         // load parms
 760         self.parm_idlesince = parm1;
 761         if(self.parm_idlesince == -(86400 * 366))
 762                 self.parm_idlesince = time;
 763
 764         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 765         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 766 }
 767
 768 /*
 769 =============
 770 ClientKill
 771
 772 Called when a client types 'kill' in the console
 773 =============
 774 */
 775
 776 .float clientkill_nexttime;
 777 void ClientKill_Now_TeamChange()
 778 {
 779         if(self.killindicator_teamchange == -1)
 780         {
 781                 JoinBestTeam( self, false, true );
 782         }
 783         else if(self.killindicator_teamchange == -2)
 784         {
 785                 if(blockSpectators)
 786                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 787                 PutObserverInServer();
 788         }
 789         else
 790                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 791         self.killindicator_teamchange = 0;
 792 }
 793
 794 void ClientKill_Now()
 795 {
 796         if(self.vehicle)
 797         {
 798             vehicles_exit(VHEF_RELESE);
 799             if(!self.killindicator_teamchange)
 800             {
 801             self.vehicle_health = -1;
 802             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 803             }
 804         }
 805
 806         if(self.killindicator && !wasfreed(self.killindicator))
 807                 remove(self.killindicator);
 808
 809         self.killindicator = world;
 810
 811         if(self.killindicator_teamchange)
 812                 ClientKill_Now_TeamChange();
 813
 814         if(IS_PLAYER(self))
 815                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 816
 817         // now I am sure the player IS dead
 818 }
 819 void KillIndicator_Think()
 820 {
 821         if (gameover)
 822         {
 823                 self.owner.killindicator = world;
 824                 remove(self);
 825                 return;
 826         }
 827
 828         if (self.owner.alpha < 0 && !self.owner.vehicle)
 829         {
 830                 self.owner.killindicator = world;
 831                 remove(self);
 832                 return;
 833         }
 834
 835         if(self.cnt <= 0)
 836         {
 837                 self = self.owner;
 838                 ClientKill_Now(); // no oldself needed
 839                 return;
 840         }
 841     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 842     {
 843         self.nextthink = time + 1;
 844         self.cnt -= 1;
 845     }
 846         else
 847         {
 848                 if(self.cnt <= 10)
 849                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 850                 if(IS_REAL_CLIENT(self.owner))
 851                 {
 852                         if(self.cnt <= 10)
 853                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 854                 }
 855                 self.nextthink = time + 1;
 856                 self.cnt -= 1;
 857         }
 858 }
 859
 860 float clientkilltime;
 861 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 862 {
 863         float killtime;
 864         float starttime;
 865         entity e;
 866
 867         if (gameover)
 868                 return;
 869
 870         killtime = autocvar_g_balance_kill_delay;
 871
 872         if(g_race_qualifying || g_cts)
 873                 killtime = 0;
 874
 875     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 876     {
 877                 remove(self.killindicator);
 878                 self.killindicator = world;
 879
 880         ClientKill_Now(); // allow instant kill in this case
 881         return;
 882     }
 883
 884         self.killindicator_teamchange = targetteam;
 885
 886     if(!self.killindicator)
 887         {
 888                 if(self.deadflag == DEAD_NO)
 889                 {
 890                         killtime = max(killtime, self.clientkill_nexttime - time);
 891                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 892                 }
 893
 894                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 895                 {
 896                         ClientKill_Now();
 897                 }
 898                 else
 899                 {
 900                         starttime = max(time, clientkilltime);
 901
 902                         self.killindicator = spawn();
 903                         self.killindicator.owner = self;
 904                         self.killindicator.scale = 0.5;
 905                         setattachment(self.killindicator, self, "");
 906                         setorigin(self.killindicator, '0 0 52');
 907                         self.killindicator.think = KillIndicator_Think;
 908                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 909                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 910                         self.killindicator.cnt = ceil(killtime);
 911                         self.killindicator.count = bound(0, ceil(killtime), 10);
 912                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 913
 914                         for(e = world; (e = find(e, classname, "body")) != world; )
 915                         {
 916                                 if(e.enemy != self)
 917                                         continue;
 918                                 e.killindicator = spawn();
 919                                 e.killindicator.owner = e;
 920                                 e.killindicator.scale = 0.5;
 921                                 setattachment(e.killindicator, e, "");
 922                                 setorigin(e.killindicator, '0 0 52');
 923                                 e.killindicator.think = KillIndicator_Think;
 924                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 925                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 926                                 e.killindicator.cnt = ceil(killtime);
 927                         }
 928                         self.lip = 0;
 929                 }
 930         }
 931         if(self.killindicator)
 932         {
 933                 if(targetteam == 0) // just die
 934                 {
 935                         self.killindicator.colormod = '0 0 0';
 936                         if(IS_REAL_CLIENT(self))
 937                         if(self.killindicator.cnt > 0)
 938                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 939                 }
 940                 else if(targetteam == -1) // auto
 941                 {
 942                         self.killindicator.colormod = '0 1 0';
 943                         if(IS_REAL_CLIENT(self))
 944                         if(self.killindicator.cnt > 0)
 945                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 946                 }
 947                 else if(targetteam == -2) // spectate
 948                 {
 949                         self.killindicator.colormod = '0.5 0.5 0.5';
 950                         if(IS_REAL_CLIENT(self))
 951                         if(self.killindicator.cnt > 0)
 952                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 953                 }
 954                 else
 955                 {
 956                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 957                         if(IS_REAL_CLIENT(self))
 958                         if(self.killindicator.cnt > 0)
 959                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 960                 }
 961         }
 962
 963 }
 964
 965 void ClientKill (void)
 966 {
 967         if(gameover) return;
 968         if(self.player_blocked) return;
 969         if(self.frozen) return;
 970
 971         ClientKill_TeamChange(0);
 972 }
 973
 974 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 975 {
 976     e.killindicator = spawn();
 977     e.killindicator.owner = e;
 978     e.killindicator.think = KillIndicator_Think;
 979     e.killindicator.nextthink = time + (e.lip) * 0.05;
 980     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 981     e.killindicator.health = 1; // this is used to indicate that it should be silent
 982     e.lip = 0;
 983 }
 984
 985 void FixClientCvars(entity e)
 986 {
 987         // send prediction settings to the client
 988         stuffcmd(e, "\nin_bindmap 0 0\n");
 989         if(g_race || g_cts)
 990                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 991         if(autocvar_g_antilag == 3) // client side hitscan
 992                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 993         if(autocvar_sv_gentle)
 994                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 995 }
 996
 997 float PlayerInIDList(entity p, string idlist)
 998 {
 999         float n, i;
1000         string s;
1001
1002         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1003         if (!p.crypto_idfp)
1004                 return 0;
1005
1006         // this function allows abbreviated player IDs too!
1007         n = tokenize_console(idlist);
1008         for(i = 0; i < n; ++i)
1009         {
1010                 s = argv(i);
1011                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1012                         return 1;
1013         }
1014
1015         return 0;
1016 }
1017
1018 #ifdef DP_EXT_PRECONNECT
1019 /*
1020 =============
1021 ClientPreConnect
1022
1023 Called once (not at each match start) when a client begins a connection to the server
1024 =============
1025 */
1026 void ClientPreConnect (void)
1027 {
1028         if(autocvar_sv_eventlog)
1029         {
1030                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1031                         self.playerid,
1032                         num_for_edict(self),
1033                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
1034                 ));
1035         }
1036 }
1037 #endif
1038
1039 /*
1040 =============
1041 ClientConnect
1042
1043 Called when a client connects to the server
1044 =============
1045 */
1046 void DecodeLevelParms (void);
1047 //void dom_player_join_team(entity pl);
1048 void set_dom_state(entity e);
1049 void ClientConnect (void)
1050 {
1051         float t;
1052
1053         if(IS_CLIENT(self))
1054         {
1055                 print("Warning: ClientConnect, but already connected!\n");
1056                 return;
1057         }
1058
1059         if(Ban_MaybeEnforceBanOnce(self))
1060                 return;
1061
1062         DecodeLevelParms();
1063
1064 #ifdef WATERMARK
1065         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1066 #endif
1067
1068         self.classname = "player_joining";
1069
1070         self.flags = FL_CLIENT;
1071         self.version_nagtime = time + 10 + random() * 10;
1072
1073         if(player_count<0)
1074         {
1075                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1076                 player_count = 0;
1077         }
1078
1079         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1080
1081         PlayerScore_Attach(self);
1082         ClientData_Attach();
1083         accuracy_init(self);
1084
1085         bot_clientconnect();
1086
1087         playerdemo_init();
1088
1089         anticheat_init();
1090
1091         // identify the right forced team
1092         if(autocvar_g_campaign)
1093         {
1094                 if(IS_REAL_CLIENT(self)) // only players, not bots
1095                 {
1096                         switch(autocvar_g_campaign_forceteam)
1097                         {
1098                                 case 1: self.team_forced = NUM_TEAM_1; break;
1099                                 case 2: self.team_forced = NUM_TEAM_2; break;
1100                                 case 3: self.team_forced = NUM_TEAM_3; break;
1101                                 case 4: self.team_forced = NUM_TEAM_4; break;
1102                                 default: self.team_forced = 0;
1103                         }
1104                 }
1105         }
1106         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1107                 self.team_forced = NUM_TEAM_1;
1108         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1109                 self.team_forced = NUM_TEAM_2;
1110         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1111                 self.team_forced = NUM_TEAM_3;
1112         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1113                 self.team_forced = NUM_TEAM_4;
1114         else if(autocvar_g_forced_team_otherwise == "red")
1115                 self.team_forced = NUM_TEAM_1;
1116         else if(autocvar_g_forced_team_otherwise == "blue")
1117                 self.team_forced = NUM_TEAM_2;
1118         else if(autocvar_g_forced_team_otherwise == "yellow")
1119                 self.team_forced = NUM_TEAM_3;
1120         else if(autocvar_g_forced_team_otherwise == "pink")
1121                 self.team_forced = NUM_TEAM_4;
1122         else if(autocvar_g_forced_team_otherwise == "spectate")
1123                 self.team_forced = -1;
1124         else if(autocvar_g_forced_team_otherwise == "spectator")
1125                 self.team_forced = -1;
1126         else
1127                 self.team_forced = 0;
1128
1129         if(!teamplay)
1130                 if(self.team_forced > 0)
1131                         self.team_forced = 0;
1132
1133         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1134
1135         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1136                 self.classname = "observer";
1137         } else {
1138                 if(teamplay)
1139                 {
1140                         if(autocvar_g_balance_teams)
1141                         {
1142                                 self.classname = "player";
1143                                 campaign_bots_may_start = 1;
1144                         }
1145                         else
1146                         {
1147                                 self.classname = "observer"; // do it anyway
1148                         }
1149                 }
1150                 else
1151                 {
1152                         self.classname = "player";
1153                         campaign_bots_may_start = 1;
1154                 }
1155         }
1156
1157         self.playerid = (playerid_last = playerid_last + 1);
1158
1159         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1160
1161     if(IS_BOT_CLIENT(self))
1162         PlayerStats_GameReport_AddPlayer(self);
1163
1164         if(autocvar_sv_eventlog)
1165                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1166
1167         LogTeamchange(self.playerid, self.team, 1);
1168
1169         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1170
1171         self.netname_previous = strzone(self.netname);
1172
1173         if(IS_PLAYER(self) && teamplay)
1174                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1175         else
1176                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1177
1178         stuffcmd(self, strcat(clientstuff, "\n"));
1179         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1180
1181         FixClientCvars(self);
1182
1183         // spawnfunc_waypoint sprites
1184         WaypointSprite_InitClient(self);
1185
1186         // Wazat's grappling hook
1187         SetGrappleHookBindings();
1188
1189         // Jetpack binds
1190         stuffcmd(self, "alias +jetpack +button10\n");
1191         stuffcmd(self, "alias -jetpack -button10\n");
1192
1193         // get version info from player
1194         stuffcmd(self, "cmd clientversion $gameversion\n");
1195
1196         // get other cvars from player
1197         GetCvars(0);
1198
1199         // notify about available teams
1200         if(teamplay)
1201         {
1202                 CheckAllowedTeams(self);
1203                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1204                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1205         }
1206         else
1207                 stuffcmd(self, "set _teams_available 0\n");
1208
1209         attach_entcs();
1210
1211         bot_relinkplayerlist();
1212
1213         self.spectatortime = time;
1214         if(blockSpectators)
1215         {
1216                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1217         }
1218
1219         self.jointime = time;
1220         self.allowed_timeouts = autocvar_sv_timeout_number;
1221
1222         if(IS_REAL_CLIENT(self))
1223         {
1224                 if(!autocvar_g_campaign)
1225                 {
1226                         self.motd_actived_time = -1;
1227                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1228                 }
1229
1230                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1231                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1232         }
1233
1234         if(!sv_foginterval && world.fog != "")
1235                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1236
1237         W_HitPlotOpen(self);
1238
1239         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1240                 send_CSQC_teamnagger();
1241
1242         CheatInitClient();
1243
1244         CSQCMODEL_AUTOINIT();
1245
1246         self.model_randomizer = random();
1247
1248         if(IS_REAL_CLIENT(self))
1249                 sv_notice_join();
1250
1251         for (entity e = world; (e = findfloat(e, init_for_player_needed, 1)); ) {
1252                 entity oldself = self;
1253                 self = e;
1254                 e.init_for_player(oldself);
1255                 self = oldself;
1256         }
1257
1258         MUTATOR_CALLHOOK(ClientConnect);
1259 }
1260 /*
1261 =============
1262 ClientDisconnect
1263
1264 Called when a client disconnects from the server
1265 =============
1266 */
1267 .entity chatbubbleentity;
1268 void ReadyCount();
1269 void ClientDisconnect (void)
1270 {
1271         if(self.vehicle)
1272             vehicles_exit(VHEF_RELESE);
1273
1274         if (!IS_CLIENT(self))
1275         {
1276                 print("Warning: ClientDisconnect without ClientConnect\n");
1277                 return;
1278         }
1279
1280         PlayerStats_GameReport_FinalizePlayer(self);
1281
1282         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1283
1284         CheatShutdownClient();
1285
1286         W_HitPlotClose(self);
1287
1288         anticheat_report();
1289         anticheat_shutdown();
1290
1291         playerdemo_shutdown();
1292
1293         bot_clientdisconnect();
1294
1295         if(self.entcs)
1296                 detach_entcs();
1297
1298         if(autocvar_sv_eventlog)
1299                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1300
1301         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1302
1303         MUTATOR_CALLHOOK(ClientDisconnect);
1304
1305         Portal_ClearAll(self);
1306
1307         Unfreeze(self);
1308
1309         RemoveGrapplingHook(self);
1310
1311         // Here, everything has been done that requires this player to be a client.
1312
1313         self.flags &= ~FL_CLIENT;
1314
1315         if (self.chatbubbleentity)
1316                 remove (self.chatbubbleentity);
1317
1318         if (self.killindicator)
1319                 remove (self.killindicator);
1320
1321         WaypointSprite_PlayerGone();
1322
1323         bot_relinkplayerlist();
1324
1325         accuracy_free(self);
1326         ClientData_Detach();
1327         PlayerScore_Detach(self);
1328
1329         if(self.netname_previous)
1330                 strunzone(self.netname_previous);
1331         if(self.clientstatus)
1332                 strunzone(self.clientstatus);
1333         if(self.weaponorder_byimpulse)
1334                 strunzone(self.weaponorder_byimpulse);
1335
1336         ClearPlayerSounds();
1337
1338         if(self.personal)
1339                 remove(self.personal);
1340
1341         self.playerid = 0;
1342         ReadyCount();
1343
1344         // free cvars
1345         GetCvars(-1);
1346 }
1347
1348 .float BUTTON_CHAT;
1349 void ChatBubbleThink()
1350 {
1351         self.nextthink = time;
1352         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1353         {
1354                 if(self.owner) // but why can that ever be world?
1355                         self.owner.chatbubbleentity = world;
1356                 remove(self);
1357                 return;
1358         }
1359         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1360 #ifdef TETRIS
1361                 || self.owner.tetris_on
1362 #endif
1363         )
1364                 self.model = self.mdl;
1365         else
1366                 self.model = "";
1367 }
1368
1369 void UpdateChatBubble()
1370 {
1371         if (self.alpha < 0)
1372                 return;
1373         // spawn a chatbubble entity if needed
1374         if (!self.chatbubbleentity)
1375         {
1376                 self.chatbubbleentity = spawn();
1377                 self.chatbubbleentity.owner = self;
1378                 self.chatbubbleentity.exteriormodeltoclient = self;
1379                 self.chatbubbleentity.think = ChatBubbleThink;
1380                 self.chatbubbleentity.nextthink = time;
1381                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1382                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1383                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs.z * '0 0 1');
1384                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1385                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1386                 self.chatbubbleentity.model = "";
1387                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1388         }
1389 }
1390
1391
1392 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1393 // added to the model skins
1394 /*void UpdateColorModHack()
1395 {
1396         float c;
1397         c = self.clientcolors & 15;
1398         // LordHavoc: only bothering to support white, green, red, yellow, blue
1399              if (!teamplay) self.colormod = '0 0 0';
1400         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1401         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1402         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1403         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1404         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1405         else self.colormod = '1 1 1';
1406 }*/
1407
1408 void respawn(void)
1409 {
1410         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1411         {
1412                 self.solid = SOLID_NOT;
1413                 self.takedamage = DAMAGE_NO;
1414                 self.movetype = MOVETYPE_FLY;
1415                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1416                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1417                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1418                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1419                 if(autocvar_g_respawn_ghosts_maxtime)
1420                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1421         }
1422
1423         CopyBody(1);
1424
1425         self.effects |= EF_NODRAW; // prevent another CopyBody
1426         PutClientInServer();
1427 }
1428
1429 void play_countdown(float finished, string samp)
1430 {
1431         if(IS_REAL_CLIENT(self))
1432                 if(floor(finished - time - frametime) != floor(finished - time))
1433                         if(finished - time < 6)
1434                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1435 }
1436
1437 void player_powerups (void)
1438 {
1439         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1440         olditems = self.items;
1441
1442         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1443                 self.modelflags |= MF_ROCKET;
1444         else
1445                 self.modelflags &= ~MF_ROCKET;
1446
1447         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1448
1449         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1450                 return;
1451
1452         Fire_ApplyDamage(self);
1453         Fire_ApplyEffect(self);
1454
1455         if (!g_instagib)
1456         {
1457                 if (self.items & IT_STRENGTH)
1458                 {
1459                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1460                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1461                         if (time > self.strength_finished)
1462                         {
1463                                 self.items = self.items - (self.items & IT_STRENGTH);
1464                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1465                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1466                         }
1467                 }
1468                 else
1469                 {
1470                         if (time < self.strength_finished)
1471                         {
1472                                 self.items = self.items | IT_STRENGTH;
1473                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1474                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1475                         }
1476                 }
1477                 if (self.items & IT_INVINCIBLE)
1478                 {
1479                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1480                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1481                         if (time > self.invincible_finished)
1482                         {
1483                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1484                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1485                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1486                         }
1487                 }
1488                 else
1489                 {
1490                         if (time < self.invincible_finished)
1491                         {
1492                                 self.items = self.items | IT_INVINCIBLE;
1493                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1494                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1495                         }
1496                 }
1497                 if (self.items & IT_SUPERWEAPON)
1498                 {
1499                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1500                         {
1501                                 self.superweapons_finished = 0;
1502                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1503                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1504                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1505                         }
1506                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1507                         {
1508                                 // don't let them run out
1509                         }
1510                         else
1511                         {
1512                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1513                                 if (time > self.superweapons_finished)
1514                                 {
1515                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1516                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1517                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1518                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1519                                 }
1520                         }
1521                 }
1522                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1523                 {
1524                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1525                         {
1526                                 self.items = self.items | IT_SUPERWEAPON;
1527                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1528                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1529                         }
1530                         else
1531                         {
1532                                 self.superweapons_finished = 0;
1533                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1534                         }
1535                 }
1536                 else
1537                 {
1538                         self.superweapons_finished = 0;
1539                 }
1540         }
1541
1542         if(autocvar_g_nodepthtestplayers)
1543                 self.effects = self.effects | EF_NODEPTHTEST;
1544
1545         if(autocvar_g_fullbrightplayers)
1546                 self.effects = self.effects | EF_FULLBRIGHT;
1547
1548         if (time >= game_starttime)
1549         if (time < self.spawnshieldtime)
1550                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1551
1552         MUTATOR_CALLHOOK(PlayerPowerups);
1553 }
1554
1555 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1556 {
1557         if(current > stable)
1558                 return current;
1559         else if(current > stable - 0.25) // when close enough, "snap"
1560                 return stable;
1561         else
1562                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1563 }
1564
1565 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1566 {
1567         if(current < stable)
1568                 return current;
1569         else if(current < stable + 0.25) // when close enough, "snap"
1570                 return stable;
1571         else
1572                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1573 }
1574
1575 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1576 {
1577         if(current > rotstable)
1578         {
1579                 if(rotframetime > 0)
1580                 {
1581                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1582                         current = max(rotstable, current - rotlinear * rotframetime);
1583                 }
1584         }
1585         else if(current < regenstable)
1586         {
1587                 if(regenframetime > 0)
1588                 {
1589                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1590                         current = min(regenstable, current + regenlinear * regenframetime);
1591                 }
1592         }
1593
1594         if(current > limit)
1595                 current = limit;
1596
1597         return current;
1598 }
1599
1600 void player_regen (void)
1601 {
1602         float max_mod, regen_mod, rot_mod, limit_mod;
1603         max_mod = regen_mod = rot_mod = limit_mod = 1;
1604         regen_mod_max = max_mod;
1605         regen_mod_regen = regen_mod;
1606         regen_mod_rot = rot_mod;
1607         regen_mod_limit = limit_mod;
1608         if(!MUTATOR_CALLHOOK(PlayerRegen))
1609         if(!self.frozen)
1610         {
1611                 float minh, mina, maxh, maxa, limith, limita;
1612                 maxh = autocvar_g_balance_health_rotstable;
1613                 maxa = autocvar_g_balance_armor_rotstable;
1614                 minh = autocvar_g_balance_health_regenstable;
1615                 mina = autocvar_g_balance_armor_regenstable;
1616                 limith = autocvar_g_balance_health_limit;
1617                 limita = autocvar_g_balance_armor_limit;
1618
1619                 max_mod = regen_mod_max;
1620                 regen_mod = regen_mod_regen;
1621                 rot_mod = regen_mod_rot;
1622                 limit_mod = regen_mod_limit;
1623
1624                 maxh = maxh * max_mod;
1625                 minh = minh * max_mod;
1626                 limith = limith * limit_mod;
1627                 limita = limita * limit_mod;
1628
1629                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1630                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1631         }
1632
1633         // if player rotted to death...  die!
1634         // check this outside above checks, as player may still be able to rot to death
1635         if(self.health < 1)
1636                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1637
1638         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1639         {
1640                 float minf, maxf, limitf;
1641
1642                 maxf = autocvar_g_balance_fuel_rotstable;
1643                 minf = autocvar_g_balance_fuel_regenstable;
1644                 limitf = autocvar_g_balance_fuel_limit;
1645
1646                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1647         }
1648 }
1649
1650 float zoomstate_set;
1651 void SetZoomState(float z)
1652 {
1653         if(z != self.zoomstate)
1654         {
1655                 self.zoomstate = z;
1656                 ClientData_Touch(self);
1657         }
1658         zoomstate_set = 1;
1659 }
1660
1661 void GetPressedKeys(void) {
1662         MUTATOR_CALLHOOK(GetPressedKeys);
1663         if (self.movement.x > 0) // get if movement keys are pressed
1664         {       // forward key pressed
1665                 self.pressedkeys |= KEY_FORWARD;
1666                 self.pressedkeys &= ~KEY_BACKWARD;
1667         }
1668         else if (self.movement.x < 0)
1669         {       // backward key pressed
1670                 self.pressedkeys |= KEY_BACKWARD;
1671                 self.pressedkeys &= ~KEY_FORWARD;
1672         }
1673         else
1674         {       // no x input
1675                 self.pressedkeys &= ~KEY_FORWARD;
1676                 self.pressedkeys &= ~KEY_BACKWARD;
1677         }
1678
1679         if (self.movement.y > 0)
1680         {       // right key pressed
1681                 self.pressedkeys |= KEY_RIGHT;
1682                 self.pressedkeys &= ~KEY_LEFT;
1683         }
1684         else if (self.movement.y < 0)
1685         {       // left key pressed
1686                 self.pressedkeys |= KEY_LEFT;
1687                 self.pressedkeys &= ~KEY_RIGHT;
1688         }
1689         else
1690         {       // no y input
1691                 self.pressedkeys &= ~KEY_RIGHT;
1692                 self.pressedkeys &= ~KEY_LEFT;
1693         }
1694
1695         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1696                 self.pressedkeys |= KEY_JUMP;
1697         else
1698                 self.pressedkeys &= ~KEY_JUMP;
1699         if (self.BUTTON_CROUCH)
1700                 self.pressedkeys |= KEY_CROUCH;
1701         else
1702                 self.pressedkeys &= ~KEY_CROUCH;
1703
1704         if (self.BUTTON_ATCK)
1705                 self.pressedkeys |= KEY_ATCK;
1706         else
1707                 self.pressedkeys &= ~KEY_ATCK;
1708         if (self.BUTTON_ATCK2)
1709                 self.pressedkeys |= KEY_ATCK2;
1710         else
1711                 self.pressedkeys &= ~KEY_ATCK2;
1712 }
1713
1714 /*
1715 ======================
1716 spectate mode routines
1717 ======================
1718 */
1719
1720 void SpectateCopy(entity spectatee) {
1721         other = spectatee;
1722         MUTATOR_CALLHOOK(SpectateCopy);
1723         self.armortype = spectatee.armortype;
1724         self.armorvalue = spectatee.armorvalue;
1725         self.ammo_cells = spectatee.ammo_cells;
1726         self.ammo_plasma = spectatee.ammo_plasma;
1727         self.ammo_shells = spectatee.ammo_shells;
1728         self.ammo_nails = spectatee.ammo_nails;
1729         self.ammo_rockets = spectatee.ammo_rockets;
1730         self.ammo_fuel = spectatee.ammo_fuel;
1731         self.clip_load = spectatee.clip_load;
1732         self.clip_size = spectatee.clip_size;
1733         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1734         self.health = spectatee.health;
1735         self.impulse = 0;
1736         self.items = spectatee.items;
1737         self.last_pickup = spectatee.last_pickup;
1738         self.hit_time = spectatee.hit_time;
1739         self.metertime = spectatee.metertime;
1740         self.strength_finished = spectatee.strength_finished;
1741         self.invincible_finished = spectatee.invincible_finished;
1742         self.pressedkeys = spectatee.pressedkeys;
1743         self.weapons = spectatee.weapons;
1744         self.switchweapon = spectatee.switchweapon;
1745         self.switchingweapon = spectatee.switchingweapon;
1746         self.weapon = spectatee.weapon;
1747         self.vortex_charge = spectatee.vortex_charge;
1748         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1749         self.hagar_load = spectatee.hagar_load;
1750         self.arc_heat_percent = spectatee.arc_heat_percent;
1751         self.minelayer_mines = spectatee.minelayer_mines;
1752         self.punchangle = spectatee.punchangle;
1753         self.view_ofs = spectatee.view_ofs;
1754         self.velocity = spectatee.velocity;
1755         self.dmg_take = spectatee.dmg_take;
1756         self.dmg_save = spectatee.dmg_save;
1757         self.dmg_inflictor = spectatee.dmg_inflictor;
1758         self.v_angle = spectatee.v_angle;
1759         self.angles = spectatee.v_angle;
1760         self.frozen = spectatee.frozen;
1761         self.revive_progress = spectatee.revive_progress;
1762         if(!self.BUTTON_USE)
1763                 self.fixangle = true;
1764         setorigin(self, spectatee.origin);
1765         setsize(self, spectatee.mins, spectatee.maxs);
1766         SetZoomState(spectatee.zoomstate);
1767
1768     anticheat_spectatecopy(spectatee);
1769         self.hud = spectatee.hud;
1770         if(spectatee.vehicle)
1771     {
1772         self.fixangle = false;
1773         //self.velocity = spectatee.vehicle.velocity;
1774         self.vehicle_health = spectatee.vehicle_health;
1775         self.vehicle_shield = spectatee.vehicle_shield;
1776         self.vehicle_energy = spectatee.vehicle_energy;
1777         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1778         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1779         self.vehicle_reload1 = spectatee.vehicle_reload1;
1780         self.vehicle_reload2 = spectatee.vehicle_reload2;
1781
1782         msg_entity = self;
1783
1784         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1785             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1786             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1787             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1788
1789         //WriteByte (MSG_ONE, SVC_SETVIEW);
1790         //    WriteEntity(MSG_ONE, self);
1791         //makevectors(spectatee.v_angle);
1792         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1793     }
1794 }
1795
1796 float SpectateUpdate()
1797 {
1798         if(!self.enemy)
1799             return 0;
1800
1801         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1802         {
1803                 SetSpectator(self, world);
1804                 return 0;
1805         }
1806
1807         SpectateCopy(self.enemy);
1808
1809         return 1;
1810 }
1811
1812 float SpectateSet()
1813 {
1814         if(self.enemy.classname != "player")
1815                 return false;
1816         /*if(self.enemy.vehicle)
1817         {
1818
1819                 msg_entity = self;
1820                 WriteByte(MSG_ONE, SVC_SETVIEW);
1821                 WriteEntity(MSG_ONE, self.enemy);
1822                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1823
1824                 self.movetype = MOVETYPE_NONE;
1825                 accuracy_resend(self);
1826         }
1827         else
1828         {*/
1829                 msg_entity = self;
1830                 WriteByte(MSG_ONE, SVC_SETVIEW);
1831                 WriteEntity(MSG_ONE, self.enemy);
1832                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1833                 self.movetype = MOVETYPE_NONE;
1834                 accuracy_resend(self);
1835
1836                 if(!SpectateUpdate())
1837                         PutObserverInServer();
1838         //}
1839         return true;
1840 }
1841
1842 void SetSpectator(entity player, entity spectatee)
1843 {
1844         entity old_spectatee = player.enemy;
1845
1846         player.enemy = spectatee;
1847
1848         // WEAPONTODO
1849         // these are required to fix the spectator bug with arc
1850         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1851         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1852 }
1853
1854 float Spectate(entity pl)
1855 {
1856         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1857         if(pl.team != self.team)
1858                 return 0;
1859
1860         SetSpectator(self, pl);
1861         return SpectateSet();
1862 }
1863
1864 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1865 entity CA_SpectateNext(entity start) {
1866         if (start.team == self.team) {
1867                 return start;
1868         }
1869
1870         other = start;
1871         // continue from current player
1872         while(other && other.team != self.team) {
1873                 other = find(other, classname, "player");
1874         }
1875
1876         if (!other) {
1877                 // restart from begining
1878                 other = find(other, classname, "player");
1879                 while(other && other.team != self.team) {
1880                         other = find(other, classname, "player");
1881                 }
1882         }
1883
1884         return other;
1885 }
1886
1887 float SpectateNext()
1888 {
1889         other = find(self.enemy, classname, "player");
1890
1891         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1892                 // CA and ca players when spectating enemies is forbidden
1893                 other = CA_SpectateNext(other);
1894         } else {
1895                 // other modes and ca spectators or spectating enemies is allowed
1896                 if (!other)
1897                         other = find(other, classname, "player");
1898         }
1899
1900         if(other) { SetSpectator(self, other); }
1901
1902         return SpectateSet();
1903 }
1904
1905 float SpectatePrev()
1906 {
1907         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1908         other = findchain(classname, "player");
1909         if (!other) // no player
1910                 return false;
1911
1912         entity first = other;
1913         // skip players until current spectated player
1914         if(self.enemy)
1915         while(other && other != self.enemy)
1916                 other = other.chain;
1917
1918         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1919         {
1920                 do { other = other.chain; }
1921                 while(other && other.team != self.team);
1922
1923                 if (!other)
1924                 {
1925                         other = first;
1926                         while(other.team != self.team)
1927                                 other = other.chain;
1928                         if(other == self.enemy)
1929                                 return true;
1930                 }
1931         }
1932         else
1933         {
1934                 if(other.chain)
1935                         other = other.chain;
1936                 else
1937                         other = first;
1938         }
1939         SetSpectator(self, other);
1940         return SpectateSet();
1941 }
1942
1943 /*
1944 =============
1945 ShowRespawnCountdown()
1946
1947 Update a respawn countdown display.
1948 =============
1949 */
1950 void ShowRespawnCountdown()
1951 {
1952         float number;
1953         if(self.deadflag == DEAD_NO) // just respawned?
1954                 return;
1955         else
1956         {
1957                 number = ceil(self.respawn_time - time);
1958                 if(number <= 0)
1959                         return;
1960                 if(number <= self.respawn_countdown)
1961                 {
1962                         self.respawn_countdown = number - 1;
1963                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1964                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1965                 }
1966         }
1967 }
1968
1969 void LeaveSpectatorMode()
1970 {
1971         if(self.caplayer)
1972                 return;
1973         if(nJoinAllowed(self))
1974         {
1975                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1976                 {
1977                         self.classname = "player";
1978                         nades_RemoveBonus(self);
1979
1980                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1981                                 { JoinBestTeam(self, false, true); }
1982
1983                         if(autocvar_g_campaign)
1984                                 { campaign_bots_may_start = 1; }
1985
1986                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1987
1988                         PutClientInServer();
1989
1990                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1991                 }
1992                 else
1993                         stuffcmd(self, "menu_showteamselect\n");
1994         }
1995         else
1996         {
1997                 // Player may not join because g_maxplayers is set
1998                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1999         }
2000 }
2001
2002 /**
2003  * Determines whether the player is allowed to join. This depends on cvar
2004  * g_maxplayers, if it isn't used this function always return true, otherwise
2005  * it checks whether the number of currently playing players exceeds g_maxplayers.
2006  * @return int number of free slots for players, 0 if none
2007  */
2008 float nJoinAllowed(entity ignore) {
2009         if(!ignore)
2010         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2011         // so report 0 free slots if restricted
2012         {
2013                 if(autocvar_g_forced_team_otherwise == "spectate")
2014                         return 0;
2015                 if(autocvar_g_forced_team_otherwise == "spectator")
2016                         return 0;
2017         }
2018
2019         if(self.team_forced < 0)
2020                 return 0; // forced spectators can never join
2021
2022         // TODO simplify this
2023         entity e;
2024         float totalClients = 0;
2025         FOR_EACH_CLIENT(e)
2026                 if(e != ignore)
2027                         totalClients += 1;
2028
2029         if (!autocvar_g_maxplayers)
2030                 return maxclients - totalClients;
2031
2032         float currentlyPlaying = 0;
2033         FOR_EACH_REALCLIENT(e)
2034                 if(IS_PLAYER(e) || e.caplayer)
2035                         currentlyPlaying += 1;
2036
2037         if(currentlyPlaying < autocvar_g_maxplayers)
2038                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2039
2040         return 0;
2041 }
2042
2043 /**
2044  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2045  * g_maxplayers_spectator_blocktime seconds
2046  */
2047 void checkSpectatorBlock() {
2048         if(IS_SPEC(self) || IS_OBSERVER(self))
2049         if(!self.caplayer)
2050         if(IS_REAL_CLIENT(self))
2051         {
2052                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2053                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2054                         dropclient(self);
2055                 }
2056         }
2057 }
2058
2059 void PrintWelcomeMessage()
2060 {
2061         if(self.motd_actived_time == 0)
2062         {
2063                 if (autocvar_g_campaign) {
2064                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2065                                 self.motd_actived_time = time;
2066                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2067                         }
2068                 } else {
2069                         if (self.BUTTON_INFO) {
2070                                 self.motd_actived_time = time;
2071                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2072                         }
2073                 }
2074         }
2075         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2076         {
2077                 if (autocvar_g_campaign) {
2078                         if (self.BUTTON_INFO)
2079                                 self.motd_actived_time = time;
2080                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2081                                 self.motd_actived_time = 0;
2082                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2083                         }
2084                 } else {
2085                         if (self.BUTTON_INFO)
2086                                 self.motd_actived_time = time;
2087                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2088                                 self.motd_actived_time = 0;
2089                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2090                         }
2091                 }
2092         }
2093         else //if(self.motd_actived_time < 0) // just connected, motd is active
2094         {
2095                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2096                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2097                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2098                 {
2099                         // instanctly hide MOTD
2100                         self.motd_actived_time = 0;
2101                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2102                 }
2103         }
2104 }
2105
2106 void ObserverThink()
2107 {
2108         float prefered_movetype;
2109         if (self.flags & FL_JUMPRELEASED) {
2110                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2111                         self.flags &= ~FL_JUMPRELEASED;
2112                         self.flags |= FL_SPAWNING;
2113                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2114                         self.flags &= ~FL_JUMPRELEASED;
2115                         if(SpectateNext()) {
2116                                 self.classname = "spectator";
2117                         }
2118                 } else {
2119                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2120                         if (self.movetype != prefered_movetype)
2121                                 self.movetype = prefered_movetype;
2122                 }
2123         } else {
2124                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2125                         self.flags |= FL_JUMPRELEASED;
2126                         if(self.flags & FL_SPAWNING)
2127                         {
2128                                 self.flags &= ~FL_SPAWNING;
2129                                 LeaveSpectatorMode();
2130                                 return;
2131                         }
2132                 }
2133         }
2134 }
2135
2136 void SpectatorThink()
2137 {
2138         if (self.flags & FL_JUMPRELEASED) {
2139                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2140                         self.flags &= ~FL_JUMPRELEASED;
2141                         self.flags |= FL_SPAWNING;
2142                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2143                         self.flags &= ~FL_JUMPRELEASED;
2144                         if(SpectateNext()) {
2145                                 self.classname = "spectator";
2146                         } else {
2147                                 self.classname = "observer";
2148                                 PutClientInServer();
2149                         }
2150                         self.impulse = 0;
2151                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2152                         self.flags &= ~FL_JUMPRELEASED;
2153                         if(SpectatePrev()) {
2154                                 self.classname = "spectator";
2155                         } else {
2156                                 self.classname = "observer";
2157                                 PutClientInServer();
2158                         }
2159                         self.impulse = 0;
2160                 } else if (self.BUTTON_ATCK2) {
2161                         self.flags &= ~FL_JUMPRELEASED;
2162                         self.classname = "observer";
2163                         PutClientInServer();
2164                 } else {
2165                         if(!SpectateUpdate())
2166                                 PutObserverInServer();
2167                 }
2168         } else {
2169                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2170                         self.flags |= FL_JUMPRELEASED;
2171                         if(self.flags & FL_SPAWNING)
2172                         {
2173                                 self.flags &= ~FL_SPAWNING;
2174                                 LeaveSpectatorMode();
2175                                 return;
2176                         }
2177                 }
2178                 if(!SpectateUpdate())
2179                         PutObserverInServer();
2180         }
2181
2182         self.flags |= FL_CLIENT | FL_NOTARGET;
2183 }
2184
2185 void PlayerUseKey()
2186 {
2187         if (!IS_PLAYER(self))
2188                 return;
2189
2190         if(self.vehicle)
2191         {
2192         vehicles_exit(VHEF_NORMAL);
2193         return;
2194         }
2195
2196         // a use key was pressed; call handlers
2197         MUTATOR_CALLHOOK(PlayerUseKey);
2198 }
2199
2200 float isInvisibleString(string s)
2201 {
2202         float i, n, c;
2203         s = strdecolorize(s);
2204         for((i = 0), (n = strlen(s)); i < n; ++i)
2205         {
2206                 c = str2chr(s, i);
2207                 switch(c)
2208                 {
2209                         case 0:
2210                         case 32: // space
2211                                 break;
2212                         case 192: // charmap space
2213                                 if (!autocvar_utf8_enable)
2214                                         break;
2215                                 return false;
2216                         case 160: // space in unicode fonts
2217                         case 0xE000 + 192: // utf8 charmap space
2218                                 if (autocvar_utf8_enable)
2219                                         break;
2220                         default:
2221                                 return false;
2222                 }
2223         }
2224         return true;
2225 }
2226
2227 /*
2228 =============
2229 PlayerPreThink
2230
2231 Called every frame for each client before the physics are run
2232 =============
2233 */
2234 .float usekeypressed;
2235 void() nexball_setstatus;
2236 .int items_added;
2237 void PlayerPreThink (void)
2238 {
2239         WarpZone_PlayerPhysics_FixVAngle();
2240
2241         self.stat_game_starttime = game_starttime;
2242         self.stat_round_starttime = round_starttime;
2243         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2244         self.stat_leadlimit = autocvar_leadlimit;
2245
2246         if(frametime)
2247         {
2248                 // physics frames: update anticheat stuff
2249                 anticheat_prethink();
2250         }
2251
2252         if(blockSpectators && frametime)
2253                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2254                 checkSpectatorBlock();
2255
2256         zoomstate_set = 0;
2257
2258         // Savage: Check for nameless players
2259         if (isInvisibleString(self.netname)) {
2260                 string new_name = strzone(strcat("Player@", self.netaddress));
2261                 if(autocvar_sv_eventlog)
2262                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2263                 if(self.netname_previous)
2264                         strunzone(self.netname_previous);
2265                 self.netname_previous = strzone(new_name);
2266                 self.netname = self.netname_previous;
2267                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2268         } else if(self.netname_previous != self.netname) {
2269                 if(autocvar_sv_eventlog)
2270                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2271                 if(self.netname_previous)
2272                         strunzone(self.netname_previous);
2273                 self.netname_previous = strzone(self.netname);
2274         }
2275
2276         // version nagging
2277         if(self.version_nagtime)
2278                 if(self.cvar_g_xonoticversion)
2279                         if(time > self.version_nagtime)
2280                         {
2281                                 // don't notify git users
2282                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2283                                 {
2284                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2285                                         {
2286                                                 // notify release users if connecting to git
2287                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2288                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2289                                         }
2290                                         else
2291                                         {
2292                                                 float r;
2293                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2294                                                 if(r < 0)
2295                                                 {
2296                                                         // give users new version
2297                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2298                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2299                                                 }
2300                                                 else if(r > 0)
2301                                                 {
2302                                                         // notify users about old server version
2303                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2304                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2305                                                 }
2306                                         }
2307                                 }
2308                                 self.version_nagtime = 0;
2309                         }
2310
2311         // GOD MODE info
2312         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2313         {
2314                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2315                 self.max_armorvalue = 0;
2316         }
2317
2318 #ifdef TETRIS
2319         if (TetrisPreFrame())
2320                 return;
2321 #endif
2322
2323         if(self.frozen == 2)
2324         {
2325                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2326                 self.health = max(1, self.revive_progress * start_health);
2327                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2328
2329                 if(self.revive_progress >= 1)
2330                         Unfreeze(self);
2331         }
2332         else if(self.frozen == 3)
2333         {
2334                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2335                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2336
2337                 if(self.health < 1)
2338                 {
2339                         if(self.vehicle)
2340                                 vehicles_exit(VHEF_RELESE);
2341                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2342                 }
2343                 else if ( self.revive_progress <= 0 )
2344                         Unfreeze(self);
2345         }
2346
2347         MUTATOR_CALLHOOK(PlayerPreThink);
2348
2349         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2350         {
2351                 if(self.BUTTON_USE && !self.usekeypressed)
2352                         PlayerUseKey();
2353                 self.usekeypressed = self.BUTTON_USE;
2354         }
2355
2356         if(IS_REAL_CLIENT(self))
2357                 PrintWelcomeMessage();
2358
2359         if(IS_PLAYER(self))
2360         {
2361
2362                 CheckRules_Player();
2363
2364                 if (intermission_running)
2365                 {
2366                         IntermissionThink ();   // otherwise a button could be missed between
2367                         return;                                 // the think tics
2368                 }
2369
2370                 //don't allow the player to turn around while game is paused!
2371                 if(timeout_status == TIMEOUT_ACTIVE) {
2372                         // FIXME turn this into CSQC stuff
2373                         self.v_angle = self.lastV_angle;
2374                         self.angles = self.lastV_angle;
2375                         self.fixangle = true;
2376                 }
2377
2378                 if(frametime)
2379                 {
2380                         if(self.weapon == WEP_VORTEX && WEP_CVAR(vortex, charge))
2381                         {
2382                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2383                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2384                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2385
2386                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2387                                 {
2388                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2389                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2390                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2391                                 }
2392                         }
2393                         else
2394                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2395
2396                         player_powerups();
2397                 }
2398
2399                 if (self.deadflag != DEAD_NO)
2400                 {
2401                         if(self.personal && g_race_qualifying)
2402                         {
2403                                 if(time > self.respawn_time)
2404                                 {
2405                                         self.respawn_time = time + 1; // only retry once a second
2406                                         self.stat_respawn_time = self.respawn_time;
2407                                         respawn();
2408                                         self.impulse = 141;
2409                                 }
2410                         }
2411                         else
2412                         {
2413                                 float button_pressed;
2414                                 if(frametime)
2415                                         player_anim();
2416                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2417
2418                                 if (self.deadflag == DEAD_DYING)
2419                                 {
2420                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2421                                                 self.deadflag = DEAD_RESPAWNING;
2422                                         else if(!button_pressed)
2423                                                 self.deadflag = DEAD_DEAD;
2424                                 }
2425                                 else if (self.deadflag == DEAD_DEAD)
2426                                 {
2427                                         if(button_pressed)
2428                                                 self.deadflag = DEAD_RESPAWNABLE;
2429                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2430                                                 self.deadflag = DEAD_RESPAWNING;
2431                                 }
2432                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2433                                 {
2434                                         if(!button_pressed)
2435                                                 self.deadflag = DEAD_RESPAWNING;
2436                                 }
2437                                 else if (self.deadflag == DEAD_RESPAWNING)
2438                                 {
2439                                         if(time > self.respawn_time)
2440                                         {
2441                                                 self.respawn_time = time + 1; // only retry once a second
2442                                                 self.respawn_time_max = self.respawn_time;
2443                                                 respawn();
2444                                         }
2445                                 }
2446
2447                                 ShowRespawnCountdown();
2448
2449                                 if(self.respawn_flags & RESPAWN_SILENT)
2450                                         self.stat_respawn_time = 0;
2451                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2452                                         self.stat_respawn_time = self.respawn_time_max;
2453                                 else
2454                                         self.stat_respawn_time = self.respawn_time;
2455                         }
2456
2457                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2458                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2459                                 self.stat_respawn_time *= -1;
2460
2461                         return;
2462                 }
2463
2464                 self.prevorigin = self.origin;
2465
2466                 float do_crouch = self.BUTTON_CROUCH;
2467                 if(self.hook.state)
2468                         do_crouch = 0;
2469                 if(self.vehicle)
2470                         do_crouch = 0;
2471                 if(self.frozen)
2472                         do_crouch = 0;
2473
2474                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2475                 // It cannot be predicted by the engine!
2476                 if((self.weapon == WEP_SHOCKWAVE || self.weapon == WEP_SHOTGUN) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2477                         do_crouch = 0;
2478
2479                 if (do_crouch)
2480                 {
2481                         if (!self.crouch)
2482                         {
2483                                 self.crouch = true;
2484                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2485                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2486                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2487                         }
2488                 }
2489                 else
2490                 {
2491                         if (self.crouch)
2492                         {
2493                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, false, self);
2494                                 if (!trace_startsolid)
2495                                 {
2496                                         self.crouch = false;
2497                                         self.view_ofs = PL_VIEW_OFS;
2498                                         setsize (self, PL_MIN, PL_MAX);
2499                                 }
2500                         }
2501                 }
2502
2503                 FixPlayermodel();
2504
2505                 GrapplingHookFrame();
2506
2507                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2508                 //if(frametime)
2509                 {
2510                         self.items &= ~self.items_added;
2511
2512                         W_WeaponFrame();
2513
2514                         self.items_added = 0;
2515                         if(self.items & IT_JETPACK)
2516                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2517                                         self.items_added |= IT_FUEL;
2518
2519                         self.items |= self.items_added;
2520                 }
2521
2522                 player_regen();
2523
2524                 // WEAPONTODO: Add a weapon request for this
2525                 // rot vortex charge to the charge limit
2526                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2527                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2528
2529                 if(frametime)
2530                         player_anim();
2531
2532                 // secret status
2533                 secrets_setstatus();
2534
2535                 // monsters status
2536                 monsters_setstatus();
2537
2538                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2539
2540                 //self.angles_y=self.v_angle_y + 90;   // temp
2541         } else if(gameover) {
2542                 if (intermission_running)
2543                         IntermissionThink ();   // otherwise a button could be missed between
2544                 return;
2545         } else if(IS_OBSERVER(self)) {
2546                 ObserverThink();
2547         } else if(IS_SPEC(self)) {
2548                 SpectatorThink();
2549         }
2550
2551         // WEAPONTODO: Add weapon request for this
2552         if(!zoomstate_set)
2553                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2554
2555         float oldspectatee_status;
2556         oldspectatee_status = self.spectatee_status;
2557         if(IS_SPEC(self))
2558                 self.spectatee_status = num_for_edict(self.enemy);
2559         else if(IS_OBSERVER(self))
2560                 self.spectatee_status = num_for_edict(self);
2561         else
2562                 self.spectatee_status = 0;
2563         if(self.spectatee_status != oldspectatee_status)
2564         {
2565                 ClientData_Touch(self);
2566         }
2567
2568         if(self.teamkill_soundtime)
2569         if(time > self.teamkill_soundtime)
2570         {
2571                 self.teamkill_soundtime = 0;
2572
2573                 entity oldpusher, oldself;
2574
2575                 oldself = self; self = self.teamkill_soundsource;
2576                 oldpusher = self.pusher; self.pusher = oldself;
2577
2578                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2579
2580                 self.pusher = oldpusher;
2581                 self = oldself;
2582         }
2583
2584         if(self.taunt_soundtime)
2585         if(time > self.taunt_soundtime)
2586         {
2587                 self.taunt_soundtime = 0;
2588                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2589         }
2590
2591         target_voicescript_next(self);
2592
2593         // WEAPONTODO: Move into weaponsystem somehow
2594         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2595         if(!self.weapon)
2596                 self.clip_load = self.clip_size = 0;
2597 }
2598
2599 /*
2600 =============
2601 PlayerPostThink
2602
2603 Called every frame for each client after the physics are run
2604 =============
2605 */
2606 .float idlekick_lasttimeleft;
2607 void PlayerPostThink (void)
2608 {
2609         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2610         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2611         {
2612                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2613                 {
2614                         if(self.idlekick_lasttimeleft)
2615                         {
2616                                 self.idlekick_lasttimeleft = 0;
2617                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2618                         }
2619                 }
2620                 else
2621                 {
2622                         float timeleft;
2623                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2624                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2625                         {
2626                                 if(!self.idlekick_lasttimeleft)
2627                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2628                         }
2629                         if(timeleft <= 0)
2630                         {
2631                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2632                                 dropclient(self);
2633                                 return;
2634                         }
2635                         else if(timeleft <= 10)
2636                         {
2637                                 if(timeleft != self.idlekick_lasttimeleft)
2638                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2639                                 self.idlekick_lasttimeleft = timeleft;
2640                         }
2641                 }
2642         }
2643
2644 #ifdef TETRIS
2645         if(self.impulse == 100)
2646                 ImpulseCommands();
2647         if (!TetrisPostFrame())
2648         {
2649 #endif
2650
2651         CheatFrame();
2652
2653         //CheckPlayerJump();
2654
2655         if(IS_PLAYER(self)) {
2656                 CheckRules_Player();
2657                 UpdateChatBubble();
2658                 if (self.impulse)
2659                         ImpulseCommands();
2660                 if (intermission_running)
2661                         return;         // intermission or finale
2662                 GetPressedKeys();
2663         }
2664
2665 #ifdef TETRIS
2666         }
2667 #endif
2668
2669         /*
2670         float i;
2671         for(i = 0; i < 1000; ++i)
2672         {
2673                 vector end;
2674                 end = self.origin + '0 0 1024' + 512 * randomvec();
2675                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2676                 if(trace_fraction < 1)
2677                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2678                 {
2679                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2680                         break;
2681                 }
2682         }
2683         */
2684
2685         if(self.waypointsprite_attachedforcarrier)
2686                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2687
2688         playerdemo_write();
2689
2690         CSQCMODEL_AUTOUPDATE();
2691 }