qcsrc/server/cheats.qc

   1 #include "cheats.qh"
   2 #include "g_damage.qh"
   3 #include "race.qh"
   4 #include "../common/triggers/teleporters.qh"
   5
   6 #if defined(CSQC)
   7 #elif defined(MENUQC)
   8 #elif defined(SVQC)
   9         #include "../dpdefs/progsdefs.qh"
  10     #include "../dpdefs/dpextensions.qh"
  11     #include "../warpzonelib/anglestransform.qh"
  12     #include "../warpzonelib/util_server.qh"
  13     #include "../common/constants.qh"
  14     #include "../common/util.qh"
  15         #include "../common/triggers/func/breakable.qh"
  16     #include "../common/monsters/monsters.qh"
  17     #include "../common/weapons/weapons.qh"
  18     #include "weapons/tracing.qh"
  19     #include "autocvars.qh"
  20     #include "defs.qh"
  21     #include "../common/deathtypes.qh"
  22         #include "../common/triggers/subs.qh"
  23         #include "../common/triggers/func/breakable.qh"
  24     #include "mutators/mutators_include.qh"
  25     #include "../csqcmodellib/sv_model.qh"
  26 #endif
  27
  28 void CopyBody(float keepvelocity);
  29
  30 #ifdef NOCHEATS
  31
  32 float CheatImpulse(float i) { return 0; }
  33 float CheatCommand(float argc) { return 0; }
  34 float CheatFrame() { return 0; }
  35 void CheatInit() { cheatcount_total = world.cheatcount; }
  36 void CheatShutdown() { }
  37 void CheatInitClient() { }
  38 void CheatShutdownClient() { }
  39 void Drag_MoveDrag(entity from, entity to) { }
  40
  41 #else
  42
  43 .float maycheat;
  44 float gamestart_sv_cheats;
  45
  46 const float CHIMPULSE_SPEEDRUN_INIT = 30;
  47 const float CHIMPULSE_GIVE_ALL = 99;
  48 const float CHIMPULSE_CLONE_MOVING = 140;
  49 const float CHIMPULSE_SPEEDRUN = 141;
  50 const float CHIMPULSE_CLONE_STANDING = 142;
  51 const float CHIMPULSE_TELEPORT = 143;
  52 const float CHIMPULSE_R00T = 148;
  53
  54 const float CHRAME_DRAG = 8;
  55
  56 void CheatInit()
  57 {
  58         gamestart_sv_cheats = autocvar_sv_cheats;
  59 }
  60
  61 void CheatShutdown()
  62 {
  63 }
  64
  65 void CheatInitClient()
  66 {
  67 }
  68
  69 void CheatShutdownClient()
  70 {
  71 }
  72
  73 float CheatsAllowed(float i, float argc, float fr) // the cheat gets passed as argument for possible future ACL checking
  74 {
  75         // dead people cannot cheat
  76         if(self.deadflag != DEAD_NO)
  77                 return 0;
  78         if(gamestart_sv_cheats < 2 && !IS_PLAYER(self))
  79                 return 0;
  80
  81         // sv_clones
  82         if(i == CHIMPULSE_CLONE_MOVING || i == CHIMPULSE_CLONE_STANDING)
  83                 if(self.lip < sv_clones)
  84                         return 1;
  85
  86         // haha
  87         if(self.maycheat)
  88                 return 1;
  89
  90         // sv_cheats
  91         if(gamestart_sv_cheats && autocvar_sv_cheats)
  92                 return 1;
  93
  94         // if we get here, player is not allowed to cheat. Log it.
  95         if(i)
  96                 bprintf("Player %s^7 tried to use cheat 'impulse %d'\n", self.netname, i);
  97         else if(argc)
  98                 bprintf("Player %s^7 tried to use cheat '%s'\n", self.netname, argv(0));
  99         else if(fr)
 100                 bprintf("Player %s^7 tried to use cheat frame %d\n", self.netname, fr);
 101         else
 102                 bprintf("Player %s^7 tried to use an unknown cheat\n", self.netname);
 103
 104         return 0;
 105 }
 106
 107 #define BEGIN_CHEAT_FUNCTION() \
 108         float cheating, attempting; \
 109         cheating = 0; attempting = 0
 110 #define DID_CHEAT() \
 111         ++cheating
 112 #define ADD_CHEATS(e,n) \
 113         cheatcount_total += n; \
 114         e.cheatcount += n
 115 #define END_CHEAT_FUNCTION() \
 116         ADD_CHEATS(self,cheating); \
 117         return attempting
 118 #define IS_CHEAT(i,argc,fr) \
 119         if((++attempting, !CheatsAllowed(i,argc,fr))) \
 120                 break
 121
 122 float num_autoscreenshot;
 123 void info_autoscreenshot_findtarget()
 124 {
 125         entity e;
 126         e = find(world, targetname, self.target);
 127         if(!e)
 128         {
 129                 objerror("Missing target. FAIL!");
 130                 return;
 131         }
 132         vector a = vectoangles(e.origin - self.origin);
 133         a.x = -a.x; // don't ask
 134         self.angles_x = a.x;
 135         self.angles_y = a.y;
 136         // we leave Rick Roll alone
 137 }
 138 void spawnfunc_info_autoscreenshot()
 139 {
 140         if(++num_autoscreenshot > autocvar_g_max_info_autoscreenshot)
 141         {
 142                 objerror("Too many info_autoscreenshot entitites. FAIL!");
 143                 return;
 144         }
 145         if(self.target != "")
 146                 InitializeEntity(self, info_autoscreenshot_findtarget, INITPRIO_FINDTARGET);
 147         // this one just has to exist
 148 }
 149
 150 float CheatImpulse(float i)
 151 {
 152         BEGIN_CHEAT_FUNCTION();
 153         switch(i)
 154         {
 155                 entity e, e2;
 156
 157                 case CHIMPULSE_SPEEDRUN_INIT: // deploy personal waypoint
 158                         // shared with regular waypoint init, so this is not a cheat by itself
 159                         if(!self.personal)
 160                         {
 161                                 self.personal = spawn();
 162                                 self.personal.classname = "personal_wp";
 163                         }
 164                         self.personal.origin = self.origin;
 165                         self.personal.v_angle = self.v_angle;
 166                         self.personal.velocity = self.velocity;
 167                         self.personal.ammo_rockets = self.ammo_rockets;
 168                         self.personal.ammo_nails = self.ammo_nails;
 169                         self.personal.ammo_cells = self.ammo_cells;
 170                         self.personal.ammo_plasma = self.ammo_plasma;
 171                         self.personal.ammo_shells = self.ammo_shells;
 172                         self.personal.ammo_fuel = self.ammo_fuel;
 173                         self.personal.health = self.health;
 174                         self.personal.armorvalue = self.armorvalue;
 175                         self.personal.weapons = self.weapons;
 176                         self.personal.items = self.items;
 177                         self.personal.pauserotarmor_finished = self.pauserotarmor_finished;
 178                         self.personal.pauserothealth_finished = self.pauserothealth_finished;
 179                         self.personal.pauserotfuel_finished = self.pauserotfuel_finished;
 180                         self.personal.pauseregen_finished = self.pauseregen_finished;
 181                         self.personal.strength_finished = self.strength_finished;
 182                         self.personal.invincible_finished = self.invincible_finished;
 183                         self.personal.teleport_time = time;
 184                         break; // this part itself doesn't cheat, so let's not count this
 185                 case CHIMPULSE_CLONE_MOVING:
 186                         IS_CHEAT(i, 0, 0);
 187                         makevectors (self.v_angle);
 188                         self.velocity = self.velocity + v_forward * 300;
 189                         CopyBody(1);
 190                         self.lip += 1;
 191                         self.velocity = self.velocity - v_forward * 300;
 192                         DID_CHEAT();
 193                         break;
 194                 case CHIMPULSE_CLONE_STANDING:
 195                         IS_CHEAT(i, 0, 0);
 196                         CopyBody(0);
 197                         self.lip += 1;
 198                         DID_CHEAT();
 199                         break;
 200                 case CHIMPULSE_GIVE_ALL:
 201                         IS_CHEAT(i, 0, 0);
 202                         CheatCommand(tokenize_console("give all"));
 203                         break; // already counted as cheat
 204                 case CHIMPULSE_SPEEDRUN:
 205                         IS_CHEAT(i, 0, 0);
 206                         if(self.personal)
 207                         {
 208                                 self.speedrunning = true;
 209                                 tracebox(self.personal.origin, self.mins, self.maxs, self.personal.origin, MOVE_WORLDONLY, self);
 210                                 if(trace_startsolid)
 211                                 {
 212                                         sprint(self, "Cannot move there, cheater - only waypoints set using g_waypointsprite_personal work\n");
 213                                 }
 214                                 else
 215                                 {
 216                                         // Abort speedrun, teleport back
 217                                         setorigin(self, self.personal.origin);
 218                                         self.oldvelocity = self.velocity = self.personal.velocity;
 219                                         self.angles = self.personal.v_angle;
 220                                         self.fixangle = true;
 221
 222                                         MUTATOR_CALLHOOK(AbortSpeedrun);
 223                                 }
 224
 225                                 self.ammo_rockets = self.personal.ammo_rockets;
 226                                 self.ammo_nails = self.personal.ammo_nails;
 227                                 self.ammo_cells = self.personal.ammo_cells;
 228                                 self.ammo_plasma = self.personal.ammo_plasma;
 229                                 self.ammo_shells = self.personal.ammo_shells;
 230                                 self.ammo_fuel = self.personal.ammo_fuel;
 231                                 self.health = self.personal.health;
 232                                 self.armorvalue = self.personal.armorvalue;
 233                                 self.weapons = self.personal.weapons;
 234                                 self.items = self.personal.items;
 235                                 self.pauserotarmor_finished = time + self.personal.pauserotarmor_finished - self.personal.teleport_time;
 236                                 self.pauserothealth_finished = time + self.personal.pauserothealth_finished - self.personal.teleport_time;
 237                                 self.pauserotfuel_finished = time + self.personal.pauserotfuel_finished - self.personal.teleport_time;
 238                                 self.pauseregen_finished = time + self.personal.pauseregen_finished - self.personal.teleport_time;
 239                                 self.strength_finished = time + self.personal.strength_finished - self.personal.teleport_time;
 240                                 self.invincible_finished = time + self.personal.invincible_finished - self.personal.teleport_time;
 241
 242                                 DID_CHEAT();
 243                                 break;
 244                         }
 245                         if(self.deadflag != DEAD_NO)
 246                                 sprint(self, "UR DEAD AHAHAH))\n");
 247                         else
 248                                 sprint(self, "No waypoint set, cheater (use g_waypointsprite_personal to set one)\n");
 249                         break;
 250                 case CHIMPULSE_TELEPORT:
 251                         IS_CHEAT(i, 0, 0);
 252                         if(self.movetype == MOVETYPE_NOCLIP)
 253                         {
 254                                 e = find(world, classname, "info_autoscreenshot");
 255                                 if(e)
 256                                 {
 257                                         sprint(self, "Emergency teleport used info_autoscreenshot location\n");
 258                                         setorigin(self, e.origin);
 259                                         self.angles = e.angles;
 260                                         remove(e);
 261                                         // should we? self.angles_x = -self.angles_x;
 262                                         self.fixangle = true;
 263                                         self.velocity = '0 0 0';
 264                                         DID_CHEAT();
 265                                         break;
 266                                 }
 267                         }
 268                         if(MoveToRandomMapLocation(self, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((gamestart_sv_cheats < 2) ? 100 : 100000), 384, 384))
 269                         {
 270                                 sprint(self, "Emergency teleport used random location\n");
 271                                 self.angles_x = -self.angles.x;
 272                                 self.fixangle = true;
 273                                 self.velocity = '0 0 0';
 274                                 DID_CHEAT();
 275                                 break;
 276                         }
 277                         sprint(self, "Emergency teleport could not find a good location, forget it!\n");
 278                         break;
 279                 case CHIMPULSE_R00T:
 280                         IS_CHEAT(i, 0, 0);
 281                         RandomSelection_Init();
 282                         FOR_EACH_PLAYER(e)
 283                                 if(e.deadflag == DEAD_NO)
 284                                         if(DIFF_TEAM(e, self))
 285                                                 RandomSelection_Add(e, 0, string_null, 1, 1);
 286                         if(RandomSelection_chosen_ent)
 287                                 e = RandomSelection_chosen_ent;
 288                         else
 289                                 e = self;
 290
 291                         pointparticles(particleeffectnum("rocket_explode"), e.origin, '0 0 0', 1);
 292                         sound(e, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 293
 294                         e2 = spawn();
 295                         setorigin(e2, e.origin);
 296                         RadiusDamage(e2, self, 1000, 0, 128, world, world, 500, DEATH_CHEAT, e);
 297                         remove(e2);
 298
 299                         print("404 Sportsmanship not found.\n");
 300                         DID_CHEAT();
 301                         break;
 302         }
 303
 304         END_CHEAT_FUNCTION();
 305 }
 306
 307 void DragBox_Think();
 308 float drag_lastcnt;
 309 float CheatCommand(float argc)
 310 {
 311         BEGIN_CHEAT_FUNCTION();
 312         string cmd;
 313         cmd = argv(0);
 314         switch(cmd)
 315         {
 316                 entity e;
 317                 float effectnum, f;
 318                 vector start, end;
 319                 entity oldself;
 320
 321                 case "pointparticles":
 322                         IS_CHEAT(0, argc, 0);
 323                         if(argc == 5)
 324                         {
 325                                 // arguments:
 326                                 //   effectname
 327                                 //   origin (0..1, on crosshair line)
 328                                 //   velocity
 329                                 //   howmany
 330                                 effectnum = particleeffectnum(argv(1));
 331                                 f = stof(argv(2));
 332                                 crosshair_trace(self);
 333                                 start = (1-f) * self.origin + f * trace_endpos;
 334                                 end = stov(argv(3));
 335                                 f = stof(argv(4));
 336                                 pointparticles(effectnum, start, end, f);
 337                                 DID_CHEAT();
 338                                 break;
 339                         }
 340                         sprint(self, "Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 341                         break;
 342                 case "trailparticles":
 343                         IS_CHEAT(0, argc, 0);
 344                         if(argc == 2)
 345                         {
 346                                 // arguments:
 347                                 //   effectname
 348                                 effectnum = particleeffectnum(argv(1));
 349                                 W_SetupShot(self, false, false, "", CH_WEAPON_A, 0);
 350                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 351                                 trailparticles(self, effectnum, w_shotorg, trace_endpos);
 352                                 DID_CHEAT();
 353                                 break;
 354                         }
 355                         sprint(self, "Usage: sv_cheats 1; restart; cmd trailparticles effectname\n");
 356                         break;
 357                 case "make":
 358                         IS_CHEAT(0, argc, 0);
 359                         if(argc == 3)
 360                         {
 361                                 // arguments:
 362                                 //   modelname mode
 363                                 f = stof(argv(2));
 364                                 W_SetupShot(self, false, false, "", CH_WEAPON_A, 0);
 365                                 traceline(w_shotorg, w_shotorg + w_shotdir * 2048, MOVE_NORMAL, self);
 366                                 if((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT) || trace_fraction == 1)
 367                                 {
 368                                         sprint(self, "cannot make stuff there (bad surface)\n");
 369                                 }
 370                                 else
 371                                 {
 372                                         e = spawn();
 373                                         e.model = strzone(argv(1));
 374                                         e.mdl = "rocket_explode";
 375                                         e.health = 1000;
 376                                         setorigin(e, trace_endpos);
 377                                         e.effects = EF_NOMODELFLAGS;
 378                                         if(f == 1)
 379                                         {
 380                                                 e.angles = fixedvectoangles2(trace_plane_normal, v_forward);
 381                                                 e.angles = AnglesTransform_ApplyToAngles(e.angles, '-90 0 0'); // so unrotated models work
 382                                         }
 383                                         oldself = self;
 384                                         self = e;
 385                                         spawnfunc_func_breakable();
 386                                         self = oldself;
 387                                         // now, is it valid?
 388                                         if(f == 0)
 389                                         {
 390                                                 tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_NORMAL, e);
 391                                                 if(trace_startsolid)
 392                                                 {
 393                                                         remove(e);
 394                                                         sprint(self, "cannot make stuff there (no space)\n");
 395                                                 }
 396                                                 else
 397                                                         DID_CHEAT();
 398                                         }
 399                                         else
 400                                                 DID_CHEAT();
 401                                 }
 402                         }
 403                         else
 404                                 sprint(self, "Usage: sv_cheats 1; restart; cmd make models/... 0/1/2\n");
 405                         break;
 406                 case "penalty":
 407                         IS_CHEAT(0, argc, 0);
 408                         if(argc == 3)
 409                         {
 410                                 race_ImposePenaltyTime(self, stof(argv(1)), argv(2));
 411                                 DID_CHEAT();
 412                                 break;
 413                         }
 414                         sprint(self, "Usage: sv_cheats 1; restart; cmd penalty 5.0 AHAHAHAHAHAHAH))\n");
 415                         break;
 416                 case "dragbox_spawn":
 417                         IS_CHEAT(0, argc, 0);
 418                         e = spawn();
 419                         e.classname = "dragbox_box";
 420                         e.think = DragBox_Think;
 421                         e.nextthink = time;
 422                         e.solid = -1; // black
 423                         setmodel(e, "null"); // network it
 424                         if(argc == 4)
 425                                 e.cnt = stof(argv(1));
 426                         else
 427                                 e.cnt = max(0, drag_lastcnt);
 428
 429                         e.aiment = spawn();
 430                         e.aiment.classname = "dragbox_corner_1";
 431                         e.aiment.owner = e;
 432                         setmodel(e.aiment, "models/marker.md3");
 433                         e.aiment.skin = 0;
 434                         setsize(e.aiment, '0 0 0', '0 0 0');
 435                         if(argc == 4)
 436                                 setorigin(e.aiment, stov(argv(2)));
 437                         else
 438                         {
 439                                 crosshair_trace(self);
 440                                 setorigin(e.aiment, trace_endpos);
 441                         }
 442
 443                         e.enemy = spawn();
 444                         e.enemy.classname = "dragbox_corner_2";
 445                         e.enemy.owner = e;
 446                         setmodel(e.enemy, "models/marker.md3");
 447                         e.enemy.skin = 1;
 448                         setsize(e.enemy, '0 0 0', '0 0 0');
 449                         end = normalize(self.origin + self.view_ofs - e.aiment.origin);
 450                         end.x = (end.x > 0) * 2 - 1;
 451                         end.y = (end.y > 0) * 2 - 1;
 452                         end.z = (end.z > 0) * 2 - 1;
 453                         if(argc == 4)
 454                                 setorigin(e.enemy, stov(argv(3)));
 455                         else
 456                                 setorigin(e.enemy, e.aiment.origin + 32 * end);
 457
 458                         e.killindicator = spawn();
 459                         e.killindicator.classname = "drag_digit";
 460                         e.killindicator.owner = e;
 461                         setattachment(e.killindicator, e, "");
 462                         setorigin(e.killindicator, '0 0 -8');
 463                         e.killindicator.killindicator = spawn();
 464                         e.killindicator.killindicator.classname = "drag_digit";
 465                         e.killindicator.killindicator.owner = e;
 466                         setattachment(e.killindicator.killindicator, e, "");
 467                         setorigin(e.killindicator.killindicator, '0 0 8');
 468                         DID_CHEAT();
 469                         break;
 470                 case "dragpoint_spawn":
 471                         IS_CHEAT(0, argc, 0);
 472                         e = spawn();
 473                         e.classname = "dragpoint";
 474                         e.think = DragBox_Think;
 475                         e.nextthink = time;
 476                         e.solid = 0; // nothing special
 477                         setmodel(e, "models/marker.md3");
 478                         setsize(e, PL_MIN, PL_MAX);
 479                         e.skin = 2;
 480                         if(argc == 3)
 481                                 e.cnt = stof(argv(1));
 482                         else
 483                                 e.cnt = drag_lastcnt;
 484                         if(argc == 3)
 485                                 setorigin(e, stov(argv(2)));
 486                         else
 487                         {
 488                                 crosshair_trace(self);
 489                                 setorigin(e, trace_endpos + normalize(self.origin + self.view_ofs - trace_endpos));
 490                                 move_out_of_solid(e);
 491                         }
 492
 493                         e.killindicator = spawn();
 494                         e.killindicator.classname = "drag_digit";
 495                         e.killindicator.owner = e;
 496                         setattachment(e.killindicator, e, "");
 497                         setorigin(e.killindicator, '0 0 40');
 498                         e.killindicator.killindicator = spawn();
 499                         e.killindicator.killindicator.classname = "drag_digit";
 500                         e.killindicator.killindicator.owner = e;
 501                         setattachment(e.killindicator.killindicator, e, "");
 502                         setorigin(e.killindicator.killindicator, '0 0 56');
 503                         DID_CHEAT();
 504                         break;
 505                 case "drag_remove":
 506                         IS_CHEAT(0, argc, 0);
 507                         RandomSelection_Init();
 508                         crosshair_trace(self);
 509                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 510                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 511                         for(e = world; (e = find(e, classname, "dragpoint")); )
 512                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 513                         if(RandomSelection_chosen_ent)
 514                         {
 515                                 remove(RandomSelection_chosen_ent.killindicator.killindicator);
 516                                 remove(RandomSelection_chosen_ent.killindicator);
 517                                 if(RandomSelection_chosen_ent.aiment)
 518                                         remove(RandomSelection_chosen_ent.aiment);
 519                                 if(RandomSelection_chosen_ent.enemy)
 520                                         remove(RandomSelection_chosen_ent.enemy);
 521                                 remove(RandomSelection_chosen_ent);
 522                         }
 523                         DID_CHEAT();
 524                         break;
 525                 case "drag_setcnt":
 526                         IS_CHEAT(0, argc, 0);
 527                         if(argc == 2)
 528                         {
 529                                 RandomSelection_Init();
 530                                 crosshair_trace(self);
 531                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 532                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 533                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 534                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 535                                 if(RandomSelection_chosen_ent)
 536                                 {
 537                                         if(substring(argv(1), 0, 1) == "*")
 538                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = RandomSelection_chosen_ent.cnt + stof(substring(argv(1), 1, -1));
 539                                         else
 540                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = stof(argv(1));
 541                                 }
 542                                 DID_CHEAT();
 543                                 break;
 544                         }
 545                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_setcnt cnt\n");
 546                         break;
 547                 case "drag_save":
 548                         IS_CHEAT(0, argc, 0);
 549                         if(argc == 2)
 550                         {
 551                                 f = fopen(argv(1), FILE_WRITE);
 552                                 fputs(f, "cmd drag_clear\n");
 553                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 554                                 {
 555                                         fputs(f, strcat("cmd dragbox_spawn ", ftos(e.cnt), " \"", vtos(e.aiment.origin), "\" \"", vtos(e.enemy.origin), "\"\n"));
 556                                 }
 557                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 558                                 {
 559                                         fputs(f, strcat("cmd dragpoint_spawn ", ftos(e.cnt), " \"", vtos(e.origin), "\"\n"));
 560                                 }
 561                                 fclose(f);
 562                                 DID_CHEAT();
 563                                 break;
 564                         }
 565                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 566                         break;
 567                 case "drag_saveraceent":
 568                         IS_CHEAT(0, argc, 0);
 569                         if(argc == 2)
 570                         {
 571                                 f = fopen(argv(1), FILE_WRITE);
 572                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 573                                 {
 574                                         fputs(f, "{\n");
 575                                         fputs(f, "\"classname\" \"trigger_race_checkpoint\"\n");
 576                                         fputs(f, strcat("\"origin\" \"", ftos(e.absmin.x), " ", ftos(e.absmin.y), " ", ftos(e.absmin.z), "\"\n"));
 577                                         fputs(f, strcat("\"maxs\" \"", ftos(e.absmax.x - e.absmin.x), " ", ftos(e.absmax.y - e.absmin.y), " ", ftos(e.absmax.z - e.absmin.z), "\"\n"));
 578                                         fputs(f, strcat("\"cnt\" \"", ftos(e.cnt), "\"\n"));
 579                                         fputs(f, strcat("\"targetname\" \"checkpoint", ftos(e.cnt), "\"\n"));
 580                                         fputs(f, "}\n");
 581                                 }
 582                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 583                                 {
 584                                         start = '0 0 0';
 585                                         effectnum = 0;
 586                                         for(oldself = world; (oldself = find(oldself, classname, "dragbox_box")); )
 587                                         {
 588                                                 if(e.cnt <= 0 && oldself.cnt == 0 || e.cnt == oldself.cnt)
 589                                                 {
 590                                                         start = start + oldself.origin;
 591                                                         ++effectnum;
 592                                                 }
 593                                         }
 594                                         start *= 1 / effectnum;
 595                                         fputs(f, "{\n");
 596                                         fputs(f, "\"classname\" \"info_player_race\"\n");
 597                                         fputs(f, strcat("\"angle\" \"", ftos(vectoyaw(start - e.origin)), "\"\n"));
 598                                         fputs(f, strcat("\"origin\" \"", ftos(e.origin.x), " ", ftos(e.origin.y), " ", ftos(e.origin.z), "\"\n"));
 599                                         if(e.cnt == -2)
 600                                         {
 601                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 602                                                 fputs(f, "\"race_place\" \"0\"\n");
 603                                         }
 604                                         else if(e.cnt == -1)
 605                                         {
 606                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 607                                                 fputs(f, "\"race_place\" \"-1\"\n");
 608                                         }
 609                                         else
 610                                         {
 611                                                 fputs(f, strcat("\"target\" \"checkpoint", ftos(e.cnt), "\"\n"));
 612                                                 if(e.cnt == 0)
 613                                                 {
 614                                                         // these need race_place
 615                                                         // counting...
 616                                                         effectnum = 1;
 617                                                         for(oldself = world; (oldself = find(oldself, classname, "dragpoint")); )
 618                                                         if(oldself.cnt == 0)
 619                                                         {
 620                                                                 if(vlen(oldself.origin - start) < vlen(e.origin - start))
 621                                                                         ++effectnum;
 622                                                                 else if(vlen(oldself.origin - start) == vlen(e.origin - start) && num_for_edict(oldself) < num_for_edict(e))
 623                                                                         ++effectnum;
 624                                                         }
 625                                                         fputs(f, strcat("\"race_place\" \"", ftos(effectnum), "\"\n"));
 626                                                 }
 627                                         }
 628                                         fputs(f, "}\n");
 629                                 }
 630                                 fclose(f);
 631                                 DID_CHEAT();
 632                                 break;
 633                         }
 634                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 635                         break;
 636                 case "drag_clear":
 637                         IS_CHEAT(0, argc, 0);
 638                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 639                                 remove(e);
 640                         for(e = world; (e = find(e, classname, "dragbox_corner_1")); )
 641                                 remove(e);
 642                         for(e = world; (e = find(e, classname, "dragbox_corner_2")); )
 643                                 remove(e);
 644                         for(e = world; (e = find(e, classname, "dragpoint")); )
 645                                 remove(e);
 646                         for(e = world; (e = find(e, classname, "drag_digit")); )
 647                                 remove(e);
 648                         DID_CHEAT();
 649                         break;
 650                 case "god":
 651                         IS_CHEAT(0, argc, 0);
 652                         BITXOR_ASSIGN(self.flags, FL_GODMODE);
 653                         if(self.flags & FL_GODMODE)
 654                         {
 655                                 sprint(self, "godmode ON\n");
 656                                 DID_CHEAT();
 657                         }
 658                         else
 659                                 sprint(self, "godmode OFF\n");
 660                         break;
 661                 case "notarget":
 662                         IS_CHEAT(0, argc, 0);
 663                         BITXOR_ASSIGN(self.flags, FL_NOTARGET);
 664                         if(self.flags & FL_NOTARGET)
 665                         {
 666                                 sprint(self, "notarget ON\n");
 667                                 DID_CHEAT();
 668                         }
 669                         else
 670                                 sprint(self, "notarget OFF\n");
 671                         break;
 672                 case "noclip":
 673                         IS_CHEAT(0, argc, 0);
 674                         if(self.movetype != MOVETYPE_NOCLIP)
 675                         {
 676                                 self.movetype = MOVETYPE_NOCLIP;
 677                                 sprint(self, "noclip ON\n");
 678                                 DID_CHEAT();
 679                         }
 680                         else
 681                         {
 682                                 self.movetype = MOVETYPE_WALK;
 683                                 sprint(self, "noclip OFF\n");
 684                         }
 685                         break;
 686                 case "fly":
 687                         IS_CHEAT(0, argc, 0);
 688                         if(self.movetype != MOVETYPE_FLY)
 689                         {
 690                                 self.movetype = MOVETYPE_FLY;
 691                                 sprint(self, "flymode ON\n");
 692                                 DID_CHEAT();
 693                         }
 694                         else
 695                         {
 696                                 self.movetype = MOVETYPE_WALK;
 697                                 sprint(self, "flymode OFF\n");
 698                         }
 699                         break;
 700                 case "give":
 701                         IS_CHEAT(0, argc, 0);
 702                         if(GiveItems(self, 1, argc))
 703                                 DID_CHEAT();
 704                         break;
 705                 case "usetarget":
 706                         IS_CHEAT(0, argc, 0);
 707                         e = self;
 708                         self = spawn();
 709                         self.target = argv(1);
 710                         activator = e;
 711                         SUB_UseTargets();
 712                         remove(self);
 713                         self = e;
 714                         DID_CHEAT();
 715                         break;
 716                 case "killtarget":
 717                         IS_CHEAT(0, argc, 0);
 718                         e = self;
 719                         self = spawn();
 720                         self.killtarget = argv(1);
 721                         activator = e;
 722                         SUB_UseTargets();
 723                         remove(self);
 724                         self = e;
 725                         DID_CHEAT();
 726                         break;
 727                 case "teleporttotarget":
 728                         IS_CHEAT(0, argc, 0);
 729                         e = self;
 730                         self = spawn();
 731                         setorigin(self, self.origin);
 732                         self.classname = "cheattriggerteleport";
 733                         self.target = argv(1);
 734                         teleport_findtarget();
 735                         if(!wasfreed(self))
 736                         {
 737                                 Simple_TeleportPlayer(self, e);
 738                                 remove(self);
 739                                 self = e;
 740                                 DID_CHEAT();
 741                         }
 742                         else
 743                                 self = e;
 744                         break;
 745         }
 746
 747         END_CHEAT_FUNCTION();
 748 }
 749
 750 float Drag(float force_allow_pick, float ischeat);
 751 void Drag_Begin(entity dragger, entity draggee, vector touchpoint);
 752 void Drag_Finish(entity dragger);
 753 float Drag_IsDraggable(entity draggee);
 754 float Drag_MayChangeAngles(entity draggee);
 755 void Drag_MoveForward(entity dragger);
 756 void Drag_SetSpeed(entity dragger, float s);
 757 void Drag_MoveBackward(entity dragger);
 758 void Drag_Update(entity dragger);
 759 float Drag_CanDrag(entity dragger);
 760 float Drag_IsDragging(entity dragger);
 761 void Drag_MoveDrag(entity from, entity to);
 762 .entity dragentity;
 763
 764 float CheatFrame()
 765 {
 766         BEGIN_CHEAT_FUNCTION();
 767
 768         // Dragging can be used as either a cheat, or a function for some objects. If sv_cheats is active,
 769         // the cheat dragging is used (unlimited pickup range and any entity can be carried). If sv_cheats
 770         // is disabled, normal dragging is used (limited pickup range and only dragable objects can be carried),
 771         // grabbing itself no longer being accounted as cheating.
 772
 773         switch(0)
 774         {
 775                 default:
 776                         if(self.maycheat || (gamestart_sv_cheats && autocvar_sv_cheats))
 777                         {
 778                                 // use cheat dragging if cheats are enabled
 779                                 crosshair_trace_plusvisibletriggers(self);
 780                                 Drag(true, true);
 781                         }
 782                         else
 783                         {
 784                                 Drag(false, false); // execute dragging
 785                         }
 786                         break;
 787         }
 788
 789         END_CHEAT_FUNCTION();
 790 }
 791
 792
 793
 794
 795
 796 // ENTITY DRAGGING
 797
 798 // on dragger:
 799 .float draggravity;
 800 .float dragspeed; // speed of mouse wheel action
 801 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
 802 .vector draglocalvector; // local attachment vector of the dragentity
 803 .float draglocalangle;
 804 // on draggee:
 805 .entity draggedby;
 806 .float dragmovetype;
 807
 808 float Drag(float force_allow_pick, float ischeat)
 809 {
 810         BEGIN_CHEAT_FUNCTION();
 811
 812         // returns true when an entity has been picked up
 813         // If pick is true, the object can also be picked up if it's not being held already
 814         // If pick is false, only keep dragging the object if it's already being held
 815
 816         switch(0)
 817         {
 818                 default:
 819                         if(Drag_IsDragging(self))
 820                         {
 821                                 if(self.BUTTON_DRAG)
 822                                 {
 823                                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 824                                         {
 825                                                 Drag_MoveForward(self);
 826                                                 self.impulse = 0;
 827                                         }
 828                                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
 829                                         {
 830                                                 Drag_MoveBackward(self);
 831                                                 self.impulse = 0;
 832                                         }
 833                                         else if(self.impulse >= 1 && self.impulse <= 9)
 834                                         {
 835                                                 Drag_SetSpeed(self, self.impulse - 1);
 836                                         }
 837                                         else if(self.impulse == 14)
 838                                         {
 839                                                 Drag_SetSpeed(self, 9);
 840                                         }
 841
 842                                         if(frametime)
 843                                                 Drag_Update(self);
 844                                 }
 845                                 else
 846                                 {
 847                                         Drag_Finish(self);
 848                                 }
 849                         }
 850                         else
 851                         {
 852                                 if(Drag_CanDrag(self))
 853                                         if(self.BUTTON_DRAG)
 854                                         {
 855                                                 crosshair_trace_plusvisibletriggers(self);
 856                                                 entity e = trace_ent;
 857                                                 float pick = force_allow_pick;
 858                                                 if (e && !pick)
 859                                                 {
 860                                                         // pick is true if the object can be picked up. While an object is being carried, the Drag() function
 861                                                         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 862                                                         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 863                                                         // it goes out of range while slinging it around.
 864
 865                                                         if(vlen(self.origin - e.origin) <= autocvar_g_grab_range)
 866                                                         {
 867                                                                 switch(e.grab)
 868                                                                 {
 869                                                                         case 0: // can't grab
 870                                                                                 break;
 871                                                                         case 1: // owner can grab
 872                                                                                 if(e.owner == self || e.realowner == self)
 873                                                                                         pick = true;
 874                                                                                 break;
 875                                                                         case 2: // owner and team mates can grab
 876                                                                                 if(SAME_TEAM(e.owner, self) || SAME_TEAM(e.realowner, self) || e.team == self.team)
 877                                                                                         pick = true;
 878                                                                                 break;
 879                                                                         case 3: // anyone can grab
 880                                                                                 pick = true;
 881                                                                                 break;
 882                                                                         default:
 883                                                                                 break;
 884                                                                 }
 885                                                         }
 886                                                 }
 887                                                 // Find e and pick
 888                                                 if(e && pick)
 889                                                         if(Drag_IsDraggable(e))
 890                                                         {
 891                                                                 if(ischeat)
 892                                                                         IS_CHEAT(0, 0, CHRAME_DRAG);
 893                                                                 if(e.draggedby)
 894                                                                         Drag_Finish(e.draggedby);
 895                                                                 if(e.tag_entity)
 896                                                                         detach_sameorigin(e);
 897                                                                 Drag_Begin(self, e, trace_endpos);
 898                                                                 if(ischeat)
 899                                                                         DID_CHEAT();
 900                                                                 return true;
 901                                                         }
 902                                         }
 903                         }
 904                         break;
 905         }
 906         return false;
 907 }
 908
 909 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
 910 {
 911         float tagscale;
 912
 913         draggee.dragmovetype = draggee.movetype;
 914         draggee.draggravity = draggee.gravity;
 915         draggee.movetype = MOVETYPE_WALK;
 916         draggee.gravity = 0.00001;
 917         draggee.flags &= ~FL_ONGROUND;
 918         draggee.draggedby = dragger;
 919
 920         dragger.dragentity = draggee;
 921
 922         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
 923         dragger.draglocalangle = draggee.angles.y - dragger.v_angle.y;
 924         touchpoint = touchpoint - gettaginfo(draggee, 0);
 925         tagscale = pow(vlen(v_forward), -2);
 926         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
 927         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
 928         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
 929
 930         dragger.dragspeed = 64;
 931 }
 932
 933 void Drag_Finish(entity dragger)
 934 {
 935         entity draggee;
 936         draggee = dragger.dragentity;
 937         if(dragger)
 938                 dragger.dragentity = world;
 939         draggee.draggedby = world;
 940         draggee.movetype = draggee.dragmovetype;
 941         draggee.gravity = draggee.draggravity;
 942
 943         switch(draggee.movetype)
 944         {
 945                 case MOVETYPE_TOSS:
 946                 case MOVETYPE_WALK:
 947                 case MOVETYPE_STEP:
 948                 case MOVETYPE_FLYMISSILE:
 949                 case MOVETYPE_BOUNCE:
 950                 case MOVETYPE_BOUNCEMISSILE:
 951                 case MOVETYPE_PHYSICS:
 952                         break;
 953                 default:
 954                         draggee.velocity = '0 0 0';
 955                         break;
 956         }
 957
 958         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
 959         {
 960                 draggee.velocity = '0 0 0';
 961                 draggee.flags |= FL_ONGROUND; // floating items are FUN
 962         }
 963 }
 964
 965 float Drag_IsDraggable(entity draggee)
 966 {
 967         // TODO add more checks for bad stuff here
 968         if(draggee == world)
 969                 return false;
 970         if(draggee.classname == "func_bobbing")
 971                 return false;
 972         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
 973                 return false;
 974         if(draggee.classname == "plat")
 975                 return false;
 976         if(draggee.classname == "func_button")
 977                 return false;
 978 //      if(draggee.model == "")
 979 //              return false;
 980         if(IS_SPEC(draggee))
 981                 return false;
 982         if(IS_OBSERVER(draggee))
 983                 return false;
 984         if(draggee.classname == "exteriorweaponentity")
 985                 return false;
 986         if(draggee.classname == "weaponentity")
 987                 return false;
 988
 989         return true;
 990 }
 991
 992 float Drag_MayChangeAngles(entity draggee)
 993 {
 994         // TODO add more checks for bad stuff here
 995         if(substring(draggee.model, 0, 1) == "*")
 996                 return false;
 997         return true;
 998 }
 999
1000 void Drag_MoveForward(entity dragger)
1001 {
1002         dragger.dragdistance += dragger.dragspeed;
1003 }
1004
1005 void Drag_SetSpeed(entity dragger, float s)
1006 {
1007         dragger.dragspeed = pow(2, s);
1008 }
1009
1010 void Drag_MoveBackward(entity dragger)
1011 {
1012         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
1013 }
1014
1015 void Drag_Update(entity dragger)
1016 {
1017         vector curorigin, neworigin, goodvelocity;
1018         float f;
1019         entity draggee;
1020
1021         draggee = dragger.dragentity;
1022         draggee.flags &= ~FL_ONGROUND;
1023
1024         curorigin = gettaginfo(draggee, 0);
1025         curorigin = curorigin + v_forward * dragger.draglocalvector.x + v_right * dragger.draglocalvector.y + v_up * dragger.draglocalvector.z;
1026         makevectors(dragger.v_angle);
1027         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
1028         goodvelocity = (neworigin - curorigin) * (1 / frametime);
1029
1030         while(draggee.angles.y - dragger.v_angle.y - dragger.draglocalangle > 180)
1031                 dragger.draglocalangle += 360;
1032         while(draggee.angles.y - dragger.v_angle.y - dragger.draglocalangle <= -180)
1033                 dragger.draglocalangle -= 360;
1034
1035         f = min(frametime * 10, 1);
1036         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
1037
1038         if(Drag_MayChangeAngles(draggee))
1039                 draggee.angles_y = draggee.angles.y * (1 - f) + (dragger.v_angle.y + dragger.draglocalangle) * f;
1040
1041         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
1042
1043         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
1044 }
1045
1046 float Drag_CanDrag(entity dragger)
1047 {
1048         return (dragger.deadflag == DEAD_NO) || (IS_PLAYER(dragger));
1049 }
1050
1051 float Drag_IsDragging(entity dragger)
1052 {
1053         if(!dragger.dragentity)
1054                 return false;
1055         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
1056         {
1057                 dragger.dragentity = world;
1058                 return false;
1059         }
1060         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
1061         {
1062                 Drag_Finish(dragger);
1063                 return false;
1064         }
1065         return true;
1066 }
1067
1068 void Drag_MoveDrag(entity from, entity to)
1069 {
1070         if(from.draggedby)
1071         {
1072                 to.draggedby = from.draggedby;
1073                 to.draggedby.dragentity = to;
1074                 from.draggedby = world;
1075         }
1076 }
1077
1078 void DragBox_Think()
1079 {
1080         if(self.aiment && self.enemy)
1081         {
1082                 self.origin_x = (self.aiment.origin.x + self.enemy.origin.x) * 0.5;
1083                 self.origin_y = (self.aiment.origin.y + self.enemy.origin.y) * 0.5;
1084                 self.origin_z = (self.aiment.origin.z + self.enemy.origin.z) * 0.5;
1085                 self.maxs_x = fabs(self.aiment.origin.x - self.enemy.origin.x) * 0.5;
1086                 self.maxs_y = fabs(self.aiment.origin.y - self.enemy.origin.y) * 0.5;
1087                 self.maxs_z = fabs(self.aiment.origin.z - self.enemy.origin.z) * 0.5;
1088                 self.mins = -1 * self.maxs;
1089                 setorigin(self, self.origin); setsize(self, self.mins, self.maxs); // link edict
1090         }
1091
1092         if(self.cnt == -1) // actually race_place -1
1093         {
1094                 // show "10 10" for qualifying spawns
1095                 setmodel(self.killindicator, "models/sprites/10.spr32");
1096                 setmodel(self.killindicator.killindicator, "models/sprites/10.spr32");
1097         }
1098         else if(self.cnt == -2) // actually race_place 0
1099         {
1100                 // show "10 0" for loser spawns
1101                 setmodel(self.killindicator, "models/sprites/10.spr32");
1102                 setmodel(self.killindicator.killindicator, "models/sprites/0.spr32");
1103         }
1104         else
1105         {
1106                 setmodel(self.killindicator, strcat("models/sprites/", ftos(self.cnt % 10), ".spr32"));
1107                 setmodel(self.killindicator.killindicator, strcat("models/sprites/", ftos(floor(self.cnt / 10)), ".spr32"));
1108         }
1109
1110         self.nextthink = time;
1111 }
1112
1113 #endif