qcsrc/lib/spawnfunc.qh

   1 #pragma once
   2
   3 // remove this ifdef when client or menu will actually make use of this stuff
   4 #ifdef SVQC
   5
   6 /** If this global exists, only functions with spawnfunc_ name prefix qualify as spawn functions */
   7 noref bool require_spawnfunc_prefix;
   8 .bool spawnfunc_checked;
   9 /** Not for production use, provides access to a dump of the entity's fields when it is parsed from map data */
  10 noref string __fullspawndata;
  11 .string fullspawndata;
  12
  13 // Optional type checking; increases compile time too much to be enabled by default
  14 #if 0
  15         bool entityfieldassignablefromeditor(int i)
  16         {
  17                 switch (entityfieldtype(i))
  18                 {
  19                         case FIELD_STRING:
  20                         case FIELD_FLOAT:
  21                         case FIELD_VECTOR:
  22                                 return true;
  23                 }
  24                 return false;
  25         }
  26
  27         #define _spawnfunc_checktypes(fld) \
  28                 if (s == #fld) \
  29                         if (!entityfieldassignablefromeditor(i)) LOG_FATALF("Entity field '%s' cannot be whitelisted", s);
  30 #else
  31         #define _spawnfunc_checktypes(fld)
  32 #endif
  33         #define _spawnfunc_check(fld) \
  34                 if (s == #fld) continue;
  35
  36         noref int __spawnfunc_expecting;
  37         noref entity __spawnfunc_expect;
  38         noref bool __spawnfunc_unreachable_workaround = true;
  39
  40     .void(entity) __spawnfunc_constructor;
  41     noref IntrusiveList g_spawn_queue;
  42
  43     #define SPAWNFUNC_INTERNAL_FIELDS(X) \
  44         X(string, classname, "spawnfunc") \
  45         X(string, target, string_null) \
  46         X(string, target2, string_null) \
  47         X(string, target3, string_null) \
  48         X(string, target4, string_null) \
  49         X(string, targetname, string_null) \
  50         /**/
  51
  52     #define X(T, fld, def) .T fld, __spawnfunc_##fld;
  53     SPAWNFUNC_INTERNAL_FIELDS(X)
  54     #undef X
  55
  56     void __spawnfunc_defer(entity prototype, void(entity) constructor)
  57     {
  58         IL_PUSH(g_spawn_queue, prototype);
  59         #define X(T, fld, def) { prototype.__spawnfunc_##fld = prototype.fld; prototype.fld = def; }
  60         SPAWNFUNC_INTERNAL_FIELDS(X);
  61         #undef X
  62         prototype.__spawnfunc_constructor = constructor;
  63     }
  64
  65     noref IntrusiveList g_map_entities;
  66     #define __spawnfunc_spawn_all() MACRO_BEGIN \
  67         g_map_entities = IL_NEW(); \
  68         IL_EACH(g_spawn_queue, true, __spawnfunc_spawn(it)); \
  69     MACRO_END
  70 #ifdef SVQC
  71     void _SV_OnEntityPreSpawnFunction(entity this);
  72 #endif
  73     void __spawnfunc_spawn(entity prototype)
  74     {
  75         entity e = new(clone);
  76         copyentity_qc(prototype, e);
  77         IL_PUSH(g_map_entities, e);
  78         #define X(T, fld, def) { e.fld = e.__spawnfunc_##fld; e.__spawnfunc_##fld = def; }
  79         SPAWNFUNC_INTERNAL_FIELDS(X);
  80         #undef X
  81 #ifdef SVQC
  82         _SV_OnEntityPreSpawnFunction(e);
  83         if (wasfreed(e)) {
  84             return;
  85         }
  86 #endif
  87         e.__spawnfunc_constructor(e);
  88     }
  89
  90         #define FIELD_SCALAR(fld, n) \
  91                 fld(n)
  92         #define FIELD_VEC(fld, n) \
  93                 fld(n) \
  94                 fld(n##_x) \
  95                 fld(n##_y) \
  96                 fld(n##_z)
  97
  98         #define FIELDS_NONE(fld)
  99         #define FIELDS_ALL(fld) if (false)
 100
 101         #define FIELDS_COMMON(fld) \
 102                 FIELD_SCALAR(fld, classname) \
 103                 FIELD_SCALAR(fld, sourceLoc) \
 104                 FIELD_SCALAR(fld, spawnfunc_checked) \
 105                 FIELD_VEC(fld, origin) \
 106                 /**/
 107
 108         #define FIELDS_UNION(fld) \
 109                 FIELD_SCALAR(fld, Version) \
 110                 FIELD_SCALAR(fld, ammo_cells) \
 111                 FIELD_SCALAR(fld, ammo_nails) \
 112                 FIELD_SCALAR(fld, ammo_rockets) \
 113                 FIELD_SCALAR(fld, antiwall_flag) \
 114                 FIELD_SCALAR(fld, armorvalue) \
 115                 FIELD_SCALAR(fld, atten) \
 116                 FIELD_SCALAR(fld, bgmscriptdecay) \
 117                 FIELD_SCALAR(fld, bgmscriptsustain) \
 118                 FIELD_SCALAR(fld, bgmscript) \
 119                 FIELD_SCALAR(fld, button0) \
 120                 FIELD_SCALAR(fld, chmap) \
 121                 FIELD_SCALAR(fld, cnt) \
 122                 FIELD_SCALAR(fld, colormap) \
 123                 FIELD_SCALAR(fld, count) \
 124                 FIELD_SCALAR(fld, curvetarget) \
 125                 FIELD_SCALAR(fld, cvarfilter) \
 126                 FIELD_SCALAR(fld, debrisdamageforcescale) \
 127                 FIELD_SCALAR(fld, debrisfadetime) \
 128                 FIELD_SCALAR(fld, debrismovetype) \
 129                 FIELD_SCALAR(fld, debrisskin) \
 130                 FIELD_SCALAR(fld, debristimejitter) \
 131                 FIELD_SCALAR(fld, debristime) \
 132                 FIELD_SCALAR(fld, debris) \
 133                 FIELD_SCALAR(fld, delay) \
 134                 FIELD_SCALAR(fld, dmgtime) \
 135                 FIELD_SCALAR(fld, dmg) \
 136                 FIELD_SCALAR(fld, dmg_edge) \
 137                 FIELD_SCALAR(fld, dmg_force) \
 138                 FIELD_SCALAR(fld, dmg_radius) \
 139                 FIELD_SCALAR(fld, effects) \
 140                 FIELD_SCALAR(fld, falloff) \
 141                 FIELD_SCALAR(fld, flags) \
 142                 FIELD_SCALAR(fld, fog) \
 143                 FIELD_SCALAR(fld, frags) \
 144                 FIELD_SCALAR(fld, frame) \
 145                 FIELD_SCALAR(fld, gametype) \
 146                 FIELD_SCALAR(fld, gametypefilter) \
 147                 FIELD_SCALAR(fld, geomtype) \
 148                 FIELD_SCALAR(fld, gravity) \
 149                 FIELD_SCALAR(fld, health) \
 150                 FIELD_SCALAR(fld, height) \
 151                 FIELD_SCALAR(fld, impulse) \
 152                 FIELD_SCALAR(fld, invincible_finished) \
 153                 FIELD_SCALAR(fld, invisibility_finished) \
 154                 FIELD_SCALAR(fld, item_pickupsound) \
 155                 FIELD_SCALAR(fld, killtarget) \
 156                 FIELD_SCALAR(fld, lerpfrac) \
 157                 FIELD_SCALAR(fld, light_lev) \
 158                 FIELD_SCALAR(fld, lip) \
 159                 FIELD_SCALAR(fld, loddistance1) \
 160                 FIELD_SCALAR(fld, lodmodel1) \
 161                 FIELD_SCALAR(fld, lodmodel2) \
 162                 FIELD_SCALAR(fld, ltime) \
 163                 FIELD_SCALAR(fld, map) \
 164                 FIELD_SCALAR(fld, max_health) \
 165                 FIELD_SCALAR(fld, mdl) \
 166                 FIELD_SCALAR(fld, message2) \
 167                 FIELD_SCALAR(fld, message) \
 168                 FIELD_SCALAR(fld, modelindex) \
 169                 FIELD_SCALAR(fld, modelscale) \
 170                 FIELD_SCALAR(fld, model) \
 171                 FIELD_SCALAR(fld, monsterid) \
 172                 FIELD_SCALAR(fld, monster_moveflags) \
 173                 FIELD_SCALAR(fld, monster_name) \
 174                 FIELD_SCALAR(fld, movetype) \
 175                 FIELD_SCALAR(fld, move_movetype) \
 176                 FIELD_SCALAR(fld, music) \
 177                 FIELD_SCALAR(fld, netname) \
 178                 FIELD_SCALAR(fld, nextthink) \
 179                 FIELD_SCALAR(fld, noalign) \
 180                 FIELD_SCALAR(fld, noise1) \
 181                 FIELD_SCALAR(fld, noise2) \
 182                 FIELD_SCALAR(fld, noise3) \
 183                 FIELD_SCALAR(fld, noise) \
 184                 FIELD_SCALAR(fld, notcpm) \
 185                 FIELD_SCALAR(fld, notfree) \
 186                 FIELD_SCALAR(fld, notsingle) \
 187                 FIELD_SCALAR(fld, notta) \
 188                 FIELD_SCALAR(fld, notteam) \
 189                 FIELD_SCALAR(fld, notvq3) \
 190                 FIELD_SCALAR(fld, phase) \
 191                 FIELD_SCALAR(fld, platmovetype) \
 192                 FIELD_SCALAR(fld, race_place) \
 193                 FIELD_SCALAR(fld, speed_finished) \
 194                 FIELD_SCALAR(fld, strength_finished) \
 195                 FIELD_SCALAR(fld, radius) \
 196                 FIELD_SCALAR(fld, respawntimestart) \
 197                 FIELD_SCALAR(fld, respawntimejitter) \
 198                 FIELD_SCALAR(fld, respawntime) \
 199                 FIELD_SCALAR(fld, restriction) \
 200                 FIELD_SCALAR(fld, scale) \
 201                 FIELD_SCALAR(fld, skin) \
 202                 FIELD_SCALAR(fld, solid) \
 203                 FIELD_SCALAR(fld, sound1) \
 204                 FIELD_SCALAR(fld, sounds) \
 205                 FIELD_SCALAR(fld, spawnflags) \
 206                 FIELD_SCALAR(fld, spawnmob) \
 207                 FIELD_SCALAR(fld, speed) \
 208                 FIELD_SCALAR(fld, strength) \
 209                 FIELD_SCALAR(fld, style) \
 210                 FIELD_SCALAR(fld, target2) \
 211                 FIELD_SCALAR(fld, target3) \
 212                 FIELD_SCALAR(fld, target4) \
 213                 FIELD_SCALAR(fld, targetname) \
 214                 FIELD_SCALAR(fld, target) \
 215                 FIELD_SCALAR(fld, target_random) \
 216                 FIELD_SCALAR(fld, target_range) \
 217                 FIELD_SCALAR(fld, team) \
 218                 FIELD_SCALAR(fld, trigger_reverse) \
 219                 FIELD_SCALAR(fld, turret_scale_aim) \
 220                 FIELD_SCALAR(fld, turret_scale_ammo) \
 221                 FIELD_SCALAR(fld, turret_scale_damage) \
 222                 FIELD_SCALAR(fld, turret_scale_health) \
 223                 FIELD_SCALAR(fld, turret_scale_range) \
 224                 FIELD_SCALAR(fld, turret_scale_refire) \
 225                 FIELD_SCALAR(fld, turret_scale_respawn) \
 226                 FIELD_SCALAR(fld, volume) \
 227                 FIELD_SCALAR(fld, wait) \
 228                 FIELD_SCALAR(fld, warpzone_fadeend) \
 229                 FIELD_SCALAR(fld, warpzone_fadestart) \
 230                 FIELD_SCALAR(fld, weapon) \
 231                 FIELD_SCALAR(fld, worldtype) \
 232                 FIELD_VEC(fld, absmax) \
 233                 FIELD_VEC(fld, absmin) \
 234                 FIELD_VEC(fld, angles) \
 235                 FIELD_VEC(fld, avelocity) \
 236                 FIELD_VEC(fld, beam_color)\
 237                 FIELD_VEC(fld, debrisavelocityjitter) \
 238                 FIELD_VEC(fld, debrisvelocity) \
 239                 FIELD_VEC(fld, debrisvelocityjitter) \
 240                 FIELD_VEC(fld, color) \
 241                 FIELD_VEC(fld, mangle) \
 242                 FIELD_VEC(fld, maxs) \
 243                 FIELD_VEC(fld, mins) \
 244                 FIELD_VEC(fld, modelscale_vec) \
 245                 FIELD_VEC(fld, velocity) \
 246                 /**/
 247
 248 ERASEABLE
 249 void _checkWhitelisted(entity this, string id)
 250 {
 251         for (int i = 0, n = numentityfields(); i < n; ++i)
 252         {
 253                 string value = getentityfieldstring(i, this);
 254                 string s = entityfieldname(i);
 255                 FIELDS_UNION(_spawnfunc_checktypes)
 256                 if (value == "") continue;
 257                 if (s == "") continue;
 258                 FIELDS_COMMON(_spawnfunc_check)
 259                 FIELDS_UNION(_spawnfunc_check)
 260                 LOG_WARNF(_("Entity field %s.%s (%s) is not whitelisted. If you believe this is an error, please file an issue."), id, s, value);
 261         }
 262 }
 263
 264 // this function simply avoids expanding IL_NEW during compilation
 265 // for each spawning entity
 266 void g_spawn_queue_spawn() { g_spawn_queue = IL_NEW(); }
 267
 268 noref bool __spawnfunc_first;
 269
 270 #define spawnfunc(id) \
 271         void __spawnfunc_##id(entity this); \
 272         ACCUMULATE void spawnfunc_##id(entity this) \
 273         { \
 274                 if (!__spawnfunc_first) { \
 275                         __spawnfunc_first = true; \
 276                         static_init_early(); \
 277                 } \
 278                 bool dospawn = true; \
 279                 if (__spawnfunc_expecting > 1) { __spawnfunc_expecting = 0; } \
 280                 else if (__spawnfunc_expecting) { \
 281                         /* engine call */ \
 282                         if (!g_spawn_queue) g_spawn_queue_spawn(); \
 283                         __spawnfunc_expecting = 0; \
 284                         this = __spawnfunc_expect; \
 285                         __spawnfunc_expect = NULL; \
 286                         dospawn = false; \
 287                 } else { \
 288                         /* userland call */ \
 289                         assert(this); \
 290                 } \
 291                 if (!this.sourceLoc) { \
 292                         this.sourceLoc = __FILE__":"STR(__LINE__); \
 293                 } \
 294                 this.classname = #id; \
 295                 if (!this.spawnfunc_checked) { \
 296                         _checkWhitelisted(this, #id); \
 297                         if (__fullspawndata) { \
 298                                 /* not supported in old DP */ \
 299                                 /* must be read inside the real spawnfunc */ \
 300                                 this.fullspawndata = __fullspawndata; \
 301                         } \
 302                         this.spawnfunc_checked = true; \
 303                         if (this) { \
 304                                 /* not worldspawn, delay spawn */ \
 305                                 /* clear some dangerous fields (TODO: properly support these in the map!) */ \
 306                                 this.think = func_null; \
 307                                 this.nextthink = 0; \
 308                                 __spawnfunc_defer(this, __spawnfunc_##id); \
 309                         } else { \
 310                                 /* world might not be "worldspawn" */ \
 311                                 this.__spawnfunc_constructor = __spawnfunc_##id; \
 312                         } \
 313                 } \
 314                 if (dospawn) { __spawnfunc_##id(this); } \
 315                 if (__spawnfunc_unreachable_workaround) return; \
 316         } \
 317         void __spawnfunc_##id(entity this)
 318
 319 #endif