qcsrc/common/mutators/mutator/spawn_near_teammate/sv_spawn_near_teammate.qc

   1 #include "sv_spawn_near_teammate.qh"
   2
   3 const float FLOAT_MAX = 340282346638528859811704183484516925440.0f;
   4
   5 float autocvar_g_spawn_near_teammate_distance;
   6 int autocvar_g_spawn_near_teammate_ignore_spawnpoint;
   7 float autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
   8 float autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death;
   9 bool autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health;
  10 bool autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath;
  11
  12 REGISTER_MUTATOR(spawn_near_teammate, cvar("g_spawn_near_teammate"));
  13
  14 .entity msnt_lookat;
  15
  16 .float msnt_timer;
  17
  18 .float cvar_cl_spawn_near_teammate;
  19
  20 MUTATOR_HOOKFUNCTION(spawn_near_teammate, Spawn_Score)
  21 {
  22         entity player = M_ARGV(0, entity);
  23         entity spawn_spot = M_ARGV(1, entity);
  24         vector spawn_score = M_ARGV(2, vector);
  25
  26         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint == 1 || (autocvar_g_spawn_near_teammate_ignore_spawnpoint == 2 && player.cvar_cl_spawn_near_teammate))
  27                 return;
  28
  29         spawn_spot.msnt_lookat = NULL;
  30
  31         if(!teamplay)
  32                 return;
  33
  34         RandomSelection_Init();
  35         FOREACH_CLIENT(IS_PLAYER(it) && it != player && SAME_TEAM(it, player) && !IS_DEAD(it), LAMBDA(
  36                 if(vdist(spawn_spot.origin - it.origin, >, autocvar_g_spawn_near_teammate_distance))
  37                         continue;
  38                 if(vdist(spawn_spot.origin - it.origin, <, 48))
  39                         continue;
  40                 if(!checkpvs(spawn_spot.origin, it))
  41                         continue;
  42                 RandomSelection_AddEnt(it, 1, 1);
  43         ));
  44
  45         if(RandomSelection_chosen_ent)
  46         {
  47                 spawn_spot.msnt_lookat = RandomSelection_chosen_ent;
  48                 spawn_score.x += SPAWN_PRIO_NEAR_TEAMMATE_FOUND;
  49         }
  50         else if(player.team == spawn_spot.team)
  51                 spawn_score.x += SPAWN_PRIO_NEAR_TEAMMATE_SAMETEAM; // prefer same team, if we can't find a spawn near teammate
  52
  53         M_ARGV(2, vector) = spawn_score;
  54 }
  55
  56 MUTATOR_HOOKFUNCTION(spawn_near_teammate, PlayerSpawn)
  57 {
  58         if(!teamplay) { return; }
  59         entity player = M_ARGV(0, entity);
  60         entity spawn_spot = M_ARGV(1, entity);
  61
  62         int num_red = 0, num_blue = 0, num_yellow = 0, num_pink = 0;
  63         FOREACH_CLIENT(IS_PLAYER(it),
  64         {
  65                 switch(it.team)
  66                 {
  67                         case NUM_TEAM_1: ++num_red; break;
  68                         case NUM_TEAM_2: ++num_blue; break;
  69                         case NUM_TEAM_3: ++num_yellow; break;
  70                         case NUM_TEAM_4: ++num_pink; break;
  71                 }
  72         });
  73
  74         if(num_red == 1 || num_blue == 1 || num_yellow == 1 || num_pink == 1)
  75                 return; // at least 1 team has only 1 player, let's not give the bigger team too much of an advantage!
  76
  77         // Note: when entering this, fixangle is already set.
  78         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint == 1 || (autocvar_g_spawn_near_teammate_ignore_spawnpoint == 2 && player.cvar_cl_spawn_near_teammate))
  79         {
  80                 if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death)
  81                         player.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death;
  82
  83                 entity best_mate = NULL;
  84                 vector best_pos = '0 0 0';
  85                 float best_dist2 = FLOAT_MAX;
  86                 FOREACH_CLIENT_RANDOM(IS_PLAYER(it), LAMBDA(
  87                         if (!SAME_TEAM(player, it)) continue;
  88                         if (autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health && it.health < autocvar_g_balance_health_regenstable) continue;
  89                         if (IS_DEAD(it)) continue;
  90                         if (time < it.msnt_timer) continue;
  91                         if (time < it.spawnshieldtime) continue;
  92                         if (forbidWeaponUse(it)) continue;
  93                         if (it == player) continue;
  94
  95                         vector horiz_vel = vec2(it.velocity);
  96                         // when walking slowly sideways, we assume the player wants a clear shot ahead - spawn behind him according to where he's looking
  97                         // when running fast, spawn behind him according to his direction of movement to prevent colliding with the newly spawned player
  98                         if (vdist(horiz_vel, >, autocvar_sv_maxspeed + 50))
  99                                 fixedmakevectors(vectoangles(horiz_vel));
 100                         else
 101                                 fixedmakevectors(it.angles); // .angles is the angle of the model - usually/always 0 pitch
 102
 103                         // test different spots close to mate - trace upwards so it works on uneven surfaces
 104                         // don't spawn in front of player or directly behind to avoid players shooting each other
 105                         // test the potential spots in pairs (first pair is better than second and so on) but don't prefer one side
 106                         RandomSelection_Init();
 107                         for(int i = 0; i < 6; ++i)
 108                         {
 109                                 switch(i)
 110                                 {
 111                                         case 0:
 112                                                 tracebox(it.origin, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin - v_forward * 64 + v_right * 128 + v_up * 64, MOVE_NOMONSTERS, it);
 113                                                 break;
 114                                         case 1:
 115                                                 tracebox(it.origin, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin - v_forward * 64 - v_right * 128 + v_up * 64, MOVE_NOMONSTERS, it);
 116                                                 break;
 117                                         case 2:
 118                                                 tracebox(it.origin, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin + v_right * 192 + v_up * 64, MOVE_NOMONSTERS, it);
 119                                                 break;
 120                                         case 3:
 121                                                 tracebox(it.origin, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin - v_right * 192 + v_up * 64, MOVE_NOMONSTERS, it);
 122                                                 break;
 123                                         case 4:
 124                                                 tracebox(it.origin, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin - v_forward * 128 + v_right * 64 + v_up * 64, MOVE_NOMONSTERS, it);
 125                                                 break;
 126                                         case 5:
 127                                                 tracebox(it.origin, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin - v_forward * 128 - v_right * 64 + v_up * 64, MOVE_NOMONSTERS, it);
 128                                                 break;
 129                                 }
 130
 131                                 vector horizontal_trace_endpos = trace_endpos;
 132                                 //te_lightning1(NULL, it.origin, horizontal_trace_endpos);
 133                                 if (trace_fraction != 1.0) goto skip;
 134
 135                                 // 400 is about the height of a typical laser jump (in overkill)
 136                                 // not traceline because we need space for the whole player, not just his origin
 137                                 tracebox(horizontal_trace_endpos, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), horizontal_trace_endpos - '0 0 400', MOVE_NORMAL, it);
 138                                 vector vectical_trace_endpos = trace_endpos;
 139                                 //te_lightning1(NULL, horizontal_trace_endpos, vectical_trace_endpos);
 140                                 if (trace_startsolid) goto skip; // inside another player
 141                                 if (trace_fraction == 1.0) goto skip; // above void or too high
 142                                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY) goto skip;
 143                                 if (pointcontents(vectical_trace_endpos) != CONTENT_EMPTY) goto skip; // no lava or slime (or water which i assume would be annoying anyway)
 144                                 if (tracebox_hits_trigger_hurt(horizontal_trace_endpos, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), vectical_trace_endpos)) goto skip;
 145
 146                                 // make sure the spawned player will have floor ahead (or at least a wall - he shouldn't fall as soon as he starts moving)
 147                                 vector floor_test_start = vectical_trace_endpos + v_up * STAT(PL_MAX, NULL).z + v_forward * STAT(PL_MAX, NULL).x; // top front of player's bbox - highest point we know is not inside solid
 148                                 traceline(floor_test_start, floor_test_start + v_forward * 100 - v_up * 128, MOVE_NOMONSTERS, it);
 149                                 //te_beam(NULL, floor_test_start, trace_endpos);
 150                                 if (trace_fraction == 1.0) goto skip;
 151
 152                                 if (autocvar_g_nades) {
 153                                         bool nade_in_range = false;
 154                                         IL_EACH(g_projectiles, it.classname == "nade",
 155                                         {
 156                                                 if (vdist(it.origin - vectical_trace_endpos, <, autocvar_g_nades_nade_radius)) {
 157                                                         nade_in_range = true;
 158                                                         goto skip;
 159                                                 }
 160                                         });
 161                                         if (nade_in_range) goto skip;
 162                                 }
 163
 164                                 // here, we know we found a good spot
 165                                 RandomSelection_Add(it, 0, string_null, vectical_trace_endpos, 1, 1);
 166                                 //te_lightning1(NULL, vectical_trace_endpos, vectical_trace_endpos + v_forward * 10);
 167
 168 LABEL(skip)
 169                                 if (i % 2 == 1 && RandomSelection_chosen_ent)
 170                                 {
 171                                         if (autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath)
 172                                         {
 173                                                 float dist2 = vlen2(RandomSelection_chosen_ent.origin - player.death_origin);
 174                                                 if (dist2 < best_dist2)
 175                                                 {
 176                                                         best_dist2 = dist2;
 177                                                         best_pos = RandomSelection_chosen_vec;
 178                                                         best_mate = RandomSelection_chosen_ent;
 179                                                 }
 180                                         }
 181                                         else
 182                                         {
 183                                                 setorigin(player, RandomSelection_chosen_vec);
 184                                                 player.angles = RandomSelection_chosen_ent.angles;
 185                                                 player.angles_z = 0; // never spawn tilted even if the spot says to
 186                                                 RandomSelection_chosen_ent.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
 187                                                 return;
 188                                         }
 189                                         break; // don't test the other spots near this teammate, go to the next one
 190                                 }
 191                         }
 192                 ));
 193
 194                 if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath)
 195                 if(best_mate)
 196                 {
 197                         setorigin(player, best_pos);
 198                         player.angles = best_mate.angles;
 199                         player.angles_z = 0; // never spawn tilted even if the spot says to
 200                         best_mate.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
 201                 }
 202         }
 203         else if(spawn_spot.msnt_lookat)
 204         {
 205                 player.angles = vectoangles(spawn_spot.msnt_lookat.origin - player.origin);
 206                 player.angles_x = -player.angles.x;
 207                 player.angles_z = 0; // never spawn tilted even if the spot says to
 208                 /*
 209                 sprint(player, "You should be looking at ", spawn_spot.msnt_lookat.netname, "^7.\n");
 210                 sprint(player, "distance: ", vtos(spawn_spot.msnt_lookat.origin - player.origin), "\n");
 211                 sprint(player, "angles: ", vtos(player.angles), "\n");
 212                 */
 213         }
 214 }
 215
 216 REPLICATE(cvar_cl_spawn_near_teammate, bool, "cl_spawn_near_teammate");