qcsrc/common/mutators/mutator/campcheck/campcheck.qc

   1 #ifdef IMPLEMENTATION
   2 float autocvar_g_campcheck_damage;
   3 float autocvar_g_campcheck_distance;
   4 float autocvar_g_campcheck_interval;
   5
   6 REGISTER_MUTATOR(campcheck, cvar("g_campcheck"));
   7
   8 .float campcheck_nextcheck;
   9 .float campcheck_traveled_distance;
  10
  11 MUTATOR_HOOKFUNCTION(campcheck, PlayerDies)
  12 {
  13         Kill_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CPID_CAMPCHECK);
  14         return false;
  15 }
  16
  17 MUTATOR_HOOKFUNCTION(campcheck, PlayerDamage_Calculate)
  18 {
  19         entity frag_attacker = M_ARGV(1, entity);
  20         entity frag_target = M_ARGV(2, entity);
  21
  22         if(IS_PLAYER(frag_target))
  23         if(IS_PLAYER(frag_attacker))
  24         if(frag_attacker != frag_target)
  25         {
  26                 frag_target.campcheck_traveled_distance = autocvar_g_campcheck_distance;
  27                 frag_attacker.campcheck_traveled_distance = autocvar_g_campcheck_distance;
  28         }
  29
  30         return false;
  31 }
  32
  33 MUTATOR_HOOKFUNCTION(campcheck, PlayerPreThink)
  34 {SELFPARAM();
  35         if(!gameover)
  36         if(!warmup_stage) // don't consider it camping during warmup?
  37         if(time >= game_starttime)
  38         if(IS_PLAYER(self))
  39         if(IS_REAL_CLIENT(self)) // bots may camp, but that's no reason to constantly kill them
  40         if(!IS_DEAD(self))
  41         if(!STAT(FROZEN, self))
  42         if(!PHYS_INPUT_BUTTON_CHAT(self))
  43         if(autocvar_g_campcheck_interval)
  44         {
  45                 vector dist;
  46
  47                 // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
  48                 dist = self.prevorigin - self.origin;
  49                 dist.z = 0;
  50                 self.campcheck_traveled_distance += fabs(vlen(dist));
  51
  52                 if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime) || (round_handler_IsActive() && !round_handler_IsRoundStarted()))
  53                 {
  54                         self.campcheck_nextcheck = time + autocvar_g_campcheck_interval * 2;
  55                         self.campcheck_traveled_distance = 0;
  56                 }
  57
  58                 if(time > self.campcheck_nextcheck)
  59                 {
  60                         if(self.campcheck_traveled_distance < autocvar_g_campcheck_distance)
  61                         {
  62                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_CAMPCHECK);
  63                                 if(self.vehicle)
  64                                         Damage(self.vehicle, world, world, autocvar_g_campcheck_damage * 2, DEATH_CAMP.m_id, self.vehicle.origin, '0 0 0');
  65                                 else
  66                                         Damage(self, world, world, bound(0, autocvar_g_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP.m_id, self.origin, '0 0 0');
  67                         }
  68                         self.campcheck_nextcheck = time + autocvar_g_campcheck_interval;
  69                         self.campcheck_traveled_distance = 0;
  70                 }
  71
  72                 return false;
  73         }
  74
  75         self.campcheck_nextcheck = time + autocvar_g_campcheck_interval; // one of the above checks failed, so keep the timer up to date
  76         return false;
  77 }
  78
  79 MUTATOR_HOOKFUNCTION(campcheck, PlayerSpawn)
  80 {
  81         entity player = M_ARGV(0, entity);
  82
  83         player.campcheck_nextcheck = time + autocvar_g_campcheck_interval * 2;
  84         player.campcheck_traveled_distance = 0;
  85 }
  86
  87 MUTATOR_HOOKFUNCTION(campcheck, BuildMutatorsString)
  88 {
  89         ret_string = strcat(ret_string, ":CampCheck");
  90         return false;
  91 }
  92 #endif