qcsrc/common/mutators/mutator/campcheck/campcheck.qc

   1 #ifdef IMPLEMENTATION
   2 float autocvar_g_campcheck_damage;
   3 float autocvar_g_campcheck_distance;
   4 float autocvar_g_campcheck_interval;
   5
   6 REGISTER_MUTATOR(campcheck, cvar("g_campcheck"));
   7
   8 .float campcheck_nextcheck;
   9 .float campcheck_traveled_distance;
  10
  11 MUTATOR_HOOKFUNCTION(campcheck, PlayerDies)
  12 {
  13         entity frag_target = M_ARGV(2, entity);
  14
  15         Kill_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CPID_CAMPCHECK);
  16         return false;
  17 }
  18
  19 MUTATOR_HOOKFUNCTION(campcheck, PlayerDamage_Calculate)
  20 {
  21         entity frag_attacker = M_ARGV(1, entity);
  22         entity frag_target = M_ARGV(2, entity);
  23
  24         if(IS_PLAYER(frag_target))
  25         if(IS_PLAYER(frag_attacker))
  26         if(frag_attacker != frag_target)
  27         {
  28                 frag_target.campcheck_traveled_distance = autocvar_g_campcheck_distance;
  29                 frag_attacker.campcheck_traveled_distance = autocvar_g_campcheck_distance;
  30         }
  31
  32         return false;
  33 }
  34
  35 MUTATOR_HOOKFUNCTION(campcheck, PlayerPreThink)
  36 {
  37         entity player = M_ARGV(0, entity);
  38
  39         if(!gameover)
  40         if(!warmup_stage) // don't consider it camping during warmup?
  41         if(time >= game_starttime)
  42         if(IS_PLAYER(player))
  43         if(IS_REAL_CLIENT(player)) // bots may camp, but that's no reason to constantly kill them
  44         if(!IS_DEAD(player))
  45         if(!STAT(FROZEN, player))
  46         if(!PHYS_INPUT_BUTTON_CHAT(player))
  47         if(autocvar_g_campcheck_interval)
  48         {
  49                 vector dist;
  50
  51                 // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
  52                 dist = player.prevorigin - player.origin;
  53                 dist.z = 0;
  54                 player.campcheck_traveled_distance += fabs(vlen(dist));
  55
  56                 if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime) || (round_handler_IsActive() && !round_handler_IsRoundStarted()))
  57                 {
  58                         player.campcheck_nextcheck = time + autocvar_g_campcheck_interval * 2;
  59                         player.campcheck_traveled_distance = 0;
  60                 }
  61
  62                 if(time > player.campcheck_nextcheck)
  63                 {
  64                         if(player.campcheck_traveled_distance < autocvar_g_campcheck_distance)
  65                         {
  66                                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_CAMPCHECK);
  67                                 if(player.vehicle)
  68                                         Damage(player.vehicle, world, world, autocvar_g_campcheck_damage * 2, DEATH_CAMP.m_id, player.vehicle.origin, '0 0 0');
  69                                 else
  70                                         Damage(player, world, world, bound(0, autocvar_g_campcheck_damage, player.health + player.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP.m_id, player.origin, '0 0 0');
  71                         }
  72                         player.campcheck_nextcheck = time + autocvar_g_campcheck_interval;
  73                         player.campcheck_traveled_distance = 0;
  74                 }
  75
  76                 return;
  77         }
  78
  79         player.campcheck_nextcheck = time + autocvar_g_campcheck_interval; // one of the above checks failed, so keep the timer up to date
  80 }
  81
  82 MUTATOR_HOOKFUNCTION(campcheck, PlayerSpawn)
  83 {
  84         entity player = M_ARGV(0, entity);
  85
  86         player.campcheck_nextcheck = time + autocvar_g_campcheck_interval * 2;
  87         player.campcheck_traveled_distance = 0;
  88 }
  89
  90 MUTATOR_HOOKFUNCTION(campcheck, BuildMutatorsString)
  91 {
  92         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":CampCheck");;
  93 }
  94 #endif