qcsrc/common/minigames/minigame/nmm.qc

   1 #include "nmm.qh"
   2
   3 REGISTER_MINIGAME(nmm, _("Nine Men's Morris"));
   4
   5 const int NMM_TURN_PLACE = 0x0100; // player has to place a piece on the board
   6 const int NMM_TURN_MOVE  = 0x0200; // player has to move a piece by one tile
   7 const int NMM_TURN_FLY   = 0x0400; // player has to move a piece anywhere
   8 const int NMM_TURN_TAKE  = 0x0800; // player has to take a non-mill piece
   9 const int NMM_TURN_TAKEANY=0x1000; // combine with NMM_TURN_TAKE, can take mill pieces
  10 const int NMM_TURN_WIN   = 0x2000; // player has won
  11 const int NMM_TURN_TYPE  = 0xff00;
  12 const int NMM_TURN_TEAM1 = 0x0001;
  13 const int NMM_TURN_TEAM2 = 0x0002;
  14 const int NMM_TURN_TEAM  = 0x00ff;
  15
  16 const int NMM_PIECE_DEAD  = 0x0; // captured by the enemy
  17 const int NMM_PIECE_HOME  = 0x1; // not yet placed
  18 const int NMM_PIECE_BOARD = 0x2; // placed on the board
  19
  20 .int  nmm_tile_distance;
  21 .entity nmm_tile_piece;
  22 .string nmm_tile_hmill;
  23 .string nmm_tile_vmill;
  24
  25 // build a string containing the indices of the tile to check for a horizontal mill
  26 string nmm_tile_build_hmill(entity tile)
  27 {
  28         int number = minigame_tile_number(tile.netname);
  29         int letter = minigame_tile_letter(tile.netname);
  30         if ( number == letter || number+letter == 6 )
  31         {
  32                 int add = letter < 3 ? 1 : -1;
  33                 return strcat(tile.netname," ",
  34                         minigame_tile_buildname(letter+add*tile.nmm_tile_distance,number)," ",
  35                         minigame_tile_buildname(letter+add*2*tile.nmm_tile_distance,number) );
  36         }
  37         else if ( letter == 3 )
  38                 return strcat(minigame_tile_buildname(letter-tile.nmm_tile_distance,number)," ",
  39                         tile.netname," ",
  40                         minigame_tile_buildname(letter+tile.nmm_tile_distance,number) );
  41         else if ( letter < 3 )
  42                 return strcat(minigame_tile_buildname(0,number)," ",
  43                         minigame_tile_buildname(1,number)," ",
  44                         minigame_tile_buildname(2,number) );
  45         else
  46                 return strcat(minigame_tile_buildname(4,number)," ",
  47                         minigame_tile_buildname(5,number)," ",
  48                         minigame_tile_buildname(6,number) );
  49 }
  50
  51 // build a string containing the indices of the tile to check for a vertical mill
  52 string nmm_tile_build_vmill(entity tile)
  53 {
  54         int letter = minigame_tile_letter(tile.netname);
  55         int number = minigame_tile_number(tile.netname);
  56         if ( letter == number || letter+number == 6 )
  57         {
  58                 int add = number < 3 ? 1 : -1;
  59                 return strcat(tile.netname," ",
  60                         minigame_tile_buildname(letter,number+add*tile.nmm_tile_distance)," ",
  61                         minigame_tile_buildname(letter,number+add*2*tile.nmm_tile_distance) );
  62         }
  63         else if ( number == 3 )
  64                 return strcat(minigame_tile_buildname(letter,number-tile.nmm_tile_distance)," ",
  65                         tile.netname," ",
  66                         minigame_tile_buildname(letter,number+tile.nmm_tile_distance) );
  67         else if ( number < 3 )
  68                 return strcat(minigame_tile_buildname(letter,0)," ",
  69                         minigame_tile_buildname(letter,1)," ",
  70                         minigame_tile_buildname(letter,2) );
  71         else
  72                 return strcat(minigame_tile_buildname(letter,4)," ",
  73                         minigame_tile_buildname(letter,5)," ",
  74                         minigame_tile_buildname(letter,6) );
  75 }
  76
  77 // Create an new tile
  78 // \param id       Tile index (eg: a1)
  79 // \param minig    Owner minigame instance
  80 // \param distance Distance from adjacent tiles
  81 void nmm_spawn_tile(string id, entity minig, int distance)
  82 {
  83         // TODO global variable + list_next for simpler tile loops
  84         entity e = new(minigame_nmm_tile);
  85         e.origin = minigame_tile_pos(id,7,7);
  86         e.netname = id;
  87         e.owner = minig;
  88         e.team = 0;
  89         e.nmm_tile_distance = distance;
  90         e.nmm_tile_hmill = strzone(nmm_tile_build_hmill(e));
  91         e.nmm_tile_vmill = strzone(nmm_tile_build_vmill(e));
  92 }
  93
  94 // Create a tile square and recursively create inner squares
  95 // \param minig    Owner minigame instance
  96 // \param offset   Index offset (eg: 1 to start the square at b2, 0 at a1 etc.)
  97 // \param skip     Number of indices to skip between tiles (eg 1: a1, a3)
  98 void nmm_spawn_tile_square( entity minig, int offset, int skip )
  99 {
 100         int letter = offset;
 101         int number = offset;
 102         for ( int i = 0; i < 3; i++ )
 103         {
 104                 number = offset;
 105                 for ( int j = 0; j < 3; j++ )
 106                 {
 107                         if ( i != 1 || j != 1 )
 108                                 nmm_spawn_tile(strzone(minigame_tile_buildname(letter,number)),minig, skip+1);
 109                         number += skip+1;
 110                 }
 111                 letter += skip+1;
 112         }
 113
 114         if ( skip > 0 )
 115                 nmm_spawn_tile_square(minig,offset+1,skip-1);
 116 }
 117
 118 // Remove tiles of a NMM minigame
 119 void nmm_kill_tiles(entity minig)
 120 {
 121         entity e = NULL;
 122         while ( ( e = findentity(e,owner,minig) ) )
 123                 if ( e.classname == "minigame_nmm_tile" )
 124                 {
 125                         strfree(e.netname);
 126                         strfree(e.nmm_tile_hmill);
 127                         strfree(e.nmm_tile_vmill);
 128                         delete(e);
 129                 }
 130 }
 131
 132 // Create the tiles of a NMM minigame
 133 void nmm_init_tiles(entity minig)
 134 {
 135         nmm_spawn_tile_square(minig,0,2);
 136 }
 137
 138 // Find a tile by its id
 139 entity nmm_find_tile(entity minig, string id)
 140 {
 141         entity e = NULL;
 142         while ( ( e = findentity(e,owner,minig) ) )
 143                 if ( e.classname == "minigame_nmm_tile" && e.netname == id )
 144                         return e;
 145         return NULL;
 146 }
 147
 148 // Check whether two tiles are adjacent
 149 bool nmm_tile_adjacent(entity tile1, entity tile2)
 150 {
 151
 152         int dnumber = fabs ( minigame_tile_number(tile1.netname) - minigame_tile_number(tile2.netname) );
 153         int dletter = fabs ( minigame_tile_letter(tile1.netname) - minigame_tile_letter(tile2.netname) );
 154
 155         return ( dnumber == 0 && ( dletter == 1 || dletter == tile1.nmm_tile_distance ) ) ||
 156                 ( dletter == 0 && ( dnumber == 1 || dnumber == tile1.nmm_tile_distance ) );
 157 }
 158
 159 // Returns 1 if there is at least 1 free adjacent tile
 160 bool nmm_tile_canmove(entity tile)
 161 {
 162         entity e = NULL;
 163         while ( ( e = findentity(e,owner,tile.owner) ) )
 164                 if ( e.classname == "minigame_nmm_tile" && !e.nmm_tile_piece
 165                                 && nmm_tile_adjacent(e,tile) )
 166                 {
 167                         return true;
 168                 }
 169         return false;
 170 }
 171
 172 // Check if the given tile id appears in the string
 173 bool nmm_in_mill_string(entity tile, string s)
 174 {
 175         int argc = tokenize(s);
 176         for ( int i = 0; i < argc; i++ )
 177         {
 178                 entity e = nmm_find_tile(tile.owner,argv(i));
 179                 if ( !e || !e.nmm_tile_piece || e.nmm_tile_piece.team != tile.nmm_tile_piece.team )
 180                         return false;
 181         }
 182         return true;
 183 }
 184
 185 // Check if a tile is in a mill
 186 bool nmm_in_mill(entity tile)
 187 {
 188         return tile.nmm_tile_piece &&  (
 189                 nmm_in_mill_string(tile,tile.nmm_tile_hmill) ||
 190                 nmm_in_mill_string(tile,tile.nmm_tile_vmill) );
 191 }
 192
 193
 194 #ifdef SVQC
 195 // Find a NMM piece matching some of the given flags and team number
 196 entity nmm_find_piece(entity start, entity minigame, int teamn, int pieceflags)
 197 {
 198         entity e = start;
 199         while ( ( e = findentity(e,owner,minigame) ) )
 200                 if ( e.classname == "minigame_board_piece" &&
 201                                 (e.minigame_flags & pieceflags) && e.team == teamn )
 202                         return e;
 203         return NULL;
 204 }
 205
 206 // Count NMM pieces matching flags and team number
 207 int nmm_count_pieces(entity minigame, int teamn, int pieceflags)
 208 {
 209         int n = 0;
 210         entity e = NULL;
 211         while (( e = nmm_find_piece(e,minigame, teamn, pieceflags) ))
 212                 n++;
 213         return n;
 214 }
 215
 216 // required function, handle server side events
 217 int nmm_server_event(entity minigame, string event, ...)
 218 {
 219         if ( event == "start" )
 220         {
 221                 minigame.minigame_flags = NMM_TURN_PLACE|NMM_TURN_TEAM1;
 222                 nmm_init_tiles(minigame);
 223                 entity e;
 224                 for ( int i = 0; i < 7; i++ )
 225                 {
 226                         e = msle_spawn(minigame,"minigame_board_piece");
 227                         e.team = 1;
 228                         e.minigame_flags = NMM_PIECE_HOME;
 229                         e = msle_spawn(minigame,"minigame_board_piece");
 230                         e.team = 2;
 231                         e.minigame_flags = NMM_PIECE_HOME;
 232                 }
 233
 234                 return 1;
 235         }
 236         else if ( event == "end" )
 237         {
 238                 nmm_kill_tiles(minigame);
 239         }
 240         else if ( event == "join" )
 241         {
 242                 int n = 0;
 243                 entity e;
 244                 for ( e = minigame.minigame_players; e; e = e.list_next )
 245                         n++;
 246                 if ( n >= 2 )
 247                         return 0;
 248                 if ( minigame.minigame_players && minigame.minigame_players.team == 1 )
 249                         return 2;
 250                 return 1;
 251         }
 252         else if ( event == "cmd" )
 253         {
 254                 entity e = ...(0,entity);
 255                 int argc = ...(1,int);
 256                 entity tile = NULL;
 257                 entity piece = NULL;
 258                 bool move_ok = false;
 259
 260                 if ( e && argc >= 2 && argv(0) == "move" &&
 261                         ( minigame.minigame_flags & NMM_TURN_TEAM ) == e.team )
 262                 {
 263                         tile = nmm_find_tile(minigame,argv(1));
 264                         if ( !tile )
 265                         {
 266                                 move_ok = false;
 267                         }
 268                         else if ( minigame.minigame_flags & NMM_TURN_PLACE )
 269                         {
 270                                 piece = nmm_find_piece(NULL,minigame,e.team,NMM_PIECE_HOME);
 271                                 if ( !tile.nmm_tile_piece && piece )
 272                                 {
 273                                         tile.nmm_tile_piece = piece;
 274                                         piece.minigame_flags = NMM_PIECE_BOARD;
 275                                         piece.origin = tile.origin;
 276                                         piece.SendFlags |= MINIG_SF_UPDATE;
 277                                         move_ok = true;
 278                                 }
 279                         }
 280                         else if ( minigame.minigame_flags & NMM_TURN_MOVE )
 281                         {
 282                                 if ( tile.nmm_tile_piece && tile.nmm_tile_piece.team == e.team )
 283                                 {
 284                                         piece = tile.nmm_tile_piece;
 285                                         entity tile2 = nmm_find_tile(minigame,argv(2));
 286                                         if ( tile2 && nmm_tile_adjacent(tile,tile2) && !tile2.nmm_tile_piece )
 287                                         {
 288                                                 tile.nmm_tile_piece = NULL;
 289                                                 tile2.nmm_tile_piece = piece;
 290                                                 piece.origin = tile2.origin;
 291                                                 piece.SendFlags |= MINIG_SF_UPDATE;
 292                                                 tile = tile2;
 293                                                 move_ok = true;
 294                                         }
 295                                 }
 296
 297                         }
 298                         else if ( minigame.minigame_flags & NMM_TURN_FLY )
 299                         {
 300                                 if ( tile.nmm_tile_piece && tile.nmm_tile_piece.team == e.team )
 301                                 {
 302                                         piece = tile.nmm_tile_piece;
 303                                         entity tile2 = nmm_find_tile(minigame,argv(2));
 304                                         if ( tile2 && !tile2.nmm_tile_piece )
 305                                         {
 306                                                 tile.nmm_tile_piece = NULL;
 307                                                 tile2.nmm_tile_piece = piece;
 308                                                 piece.origin = tile2.origin;
 309                                                 piece.SendFlags |= MINIG_SF_UPDATE;
 310                                                 tile = tile2;
 311                                                 move_ok = true;
 312                                         }
 313                                 }
 314
 315                         }
 316                         else if ( minigame.minigame_flags & NMM_TURN_TAKE )
 317                         {
 318                                 piece = tile.nmm_tile_piece;
 319                                 if ( piece && piece.nmm_tile_piece.team != e.team )
 320                                 {
 321                                         tile.nmm_tile_piece = NULL;
 322                                         piece.minigame_flags = NMM_PIECE_DEAD;
 323                                         piece.SendFlags |= MINIG_SF_UPDATE;
 324                                         move_ok = true;
 325                                 }
 326                         }
 327
 328                         int nextteam = e.team % 2 + 1;
 329                         int npieces = nmm_count_pieces(minigame,nextteam,NMM_PIECE_HOME|NMM_PIECE_BOARD);
 330
 331                         if ( npieces < 3 )
 332                         {
 333                                 minigame.minigame_flags = NMM_TURN_WIN | e.team;
 334                                 minigame.SendFlags |= MINIG_SF_UPDATE;
 335                         }
 336                         else if ( move_ok)
 337                         {
 338                                 if ( !(minigame.minigame_flags & NMM_TURN_TAKE) && nmm_in_mill(tile) )
 339                                 {
 340                                         minigame.minigame_flags = NMM_TURN_TAKE|e.team;
 341                                         int takemill = NMM_TURN_TAKEANY;
 342                                         entity f = NULL;
 343                                         while ( ( f = findentity(f,owner,minigame) ) )
 344                                                 if ( f.classname == "minigame_nmm_tile" && f.nmm_tile_piece  &&
 345                                                                 f.nmm_tile_piece.team == nextteam && !nmm_in_mill(f) )
 346                                                 {
 347                                                         takemill = 0;
 348                                                         break;
 349                                                 }
 350                                         minigame.minigame_flags |= takemill;
 351                                 }
 352                                 else
 353                                 {
 354                                         if ( nmm_find_piece(NULL,minigame,nextteam,NMM_PIECE_HOME) )
 355                                                 minigame.minigame_flags = NMM_TURN_PLACE|nextteam;
 356                                         else if ( npieces == 3 )
 357                                                 minigame.minigame_flags = NMM_TURN_FLY|nextteam;
 358                                         else
 359                                         {
 360                                                 minigame.minigame_flags = NMM_TURN_WIN|e.team;
 361                                                 entity f = NULL;
 362                                                 while ( ( f = findentity(f,owner,minigame) ) )
 363                                                         if ( f.classname == "minigame_nmm_tile" && f.nmm_tile_piece  &&
 364                                                                 f.nmm_tile_piece.team == nextteam && nmm_tile_canmove(f) )
 365                                                         {
 366                                                                 minigame.minigame_flags = NMM_TURN_MOVE|nextteam;
 367                                                                 break;
 368                                                         }
 369                                         }
 370                                 }
 371                                 minigame.SendFlags |= MINIG_SF_UPDATE;
 372                         }
 373                         else
 374                                 LOG_TRACE("Invalid move: ", ...(2, string));
 375                         return 1;
 376                 }
 377         }
 378         return 0;
 379 }
 380
 381 #elif defined(CSQC)
 382
 383 entity nmm_currtile;
 384 entity nmm_fromtile;
 385
 386 vector nmm_boardpos;
 387 vector nmm_boardsize;
 388
 389 // whether the given tile is a valid selection
 390 bool nmm_valid_selection(entity tile)
 391 {
 392         if ( ( tile.owner.minigame_flags & NMM_TURN_TEAM ) != minigame_self.team )
 393                 return false; // not our turn
 394         if ( tile.owner.minigame_flags & NMM_TURN_PLACE )
 395                 return !tile.nmm_tile_piece; // need to put a piece on an empty spot
 396         if ( tile.owner.minigame_flags & NMM_TURN_MOVE )
 397         {
 398                 if ( tile.nmm_tile_piece && tile.nmm_tile_piece.team == minigame_self.team &&
 399                                 nmm_tile_canmove(tile) )
 400                         return true; //  movable tile
 401                 if ( nmm_fromtile ) // valid destination
 402                         return !tile.nmm_tile_piece && nmm_tile_adjacent(nmm_fromtile,tile);
 403                 return false;
 404         }
 405         if ( tile.owner.minigame_flags & NMM_TURN_FLY )
 406         {
 407                 if ( nmm_fromtile )
 408                         return !tile.nmm_tile_piece;
 409                 else
 410                         return tile.nmm_tile_piece && tile.nmm_tile_piece.team == minigame_self.team;
 411         }
 412         if ( tile.owner.minigame_flags & NMM_TURN_TAKE )
 413                 return tile.nmm_tile_piece && tile.nmm_tile_piece.team != minigame_self.team &&
 414                         ( (tile.owner.minigame_flags & NMM_TURN_TAKEANY) || !nmm_in_mill(tile) );
 415         return false;
 416 }
 417
 418 // whether it should highlight valid tile selections
 419 bool nmm_draw_avaliable(entity tile)
 420 {
 421         if ( ( tile.owner.minigame_flags & NMM_TURN_TEAM ) != minigame_self.team )
 422                 return false;
 423         if ( (tile.owner.minigame_flags & NMM_TURN_TAKE) )
 424                 return true;
 425         if ( (tile.owner.minigame_flags & (NMM_TURN_FLY|NMM_TURN_MOVE)) && nmm_fromtile )
 426                 return !tile.nmm_tile_piece;
 427         return false;
 428 }
 429
 430 // Required function, draw the game board
 431 void nmm_hud_board(vector pos, vector mySize)
 432 {
 433         minigame_hud_fitsqare(pos, mySize);
 434         nmm_boardpos = pos;
 435         nmm_boardsize = mySize;
 436         minigame_hud_simpleboard(pos,mySize,minigame_texture("nmm/board"));
 437
 438         vector tile_size = minigame_hud_denormalize_size('1 1 0'/7,pos,mySize);
 439         vector tile_pos;
 440         entity e;
 441         FOREACH_MINIGAME_ENTITY(e)
 442         {
 443                 if ( e.classname == "minigame_nmm_tile" )
 444                 {
 445                         tile_pos = minigame_hud_denormalize(e.origin,pos,mySize);
 446
 447                         if ( e == nmm_fromtile )
 448                         {
 449                                 minigame_drawpic_centered( tile_pos, minigame_texture("nmm/tile_active"),
 450                                         tile_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 451                         }
 452                         else if ( nmm_draw_avaliable(e) && nmm_valid_selection(e) )
 453                         {
 454                                 minigame_drawpic_centered( tile_pos, minigame_texture("nmm/tile_available"),
 455                                         tile_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 456                         }
 457
 458                         if ( e == nmm_currtile )
 459                         {
 460                                 minigame_drawpic_centered( tile_pos, minigame_texture("nmm/tile_selected"),
 461                                         tile_size, '1 1 1', panel_fg_alpha, DRAWFLAG_ADDITIVE );
 462                         }
 463
 464                         if ( e.nmm_tile_piece )
 465                         {
 466                                 minigame_drawpic_centered( tile_pos,
 467                                         minigame_texture(strcat("nmm/piece",ftos(e.nmm_tile_piece.team))),
 468                                         tile_size*0.8, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 469                         }
 470
 471                         //drawstring(tile_pos, e.netname, hud_fontsize, '1 0 0', 1, DRAWFLAG_NORMAL);
 472                 }
 473         }
 474
 475         if ( active_minigame.minigame_flags & NMM_TURN_WIN )
 476         {
 477                 vector winfs = hud_fontsize*2;
 478                 string pname = "";
 479                 FOREACH_MINIGAME_ENTITY(e)
 480                         if ( e.classname == "minigame_player" &&
 481                                         e.team == (active_minigame.minigame_flags & NMM_TURN_TEAM) )
 482                                 pname = entcs_GetName(e.minigame_playerslot-1);
 483
 484                 vector win_pos = pos+eY*(mySize_y-winfs_y)/2;
 485                 vector win_sz;
 486                 win_sz = minigame_drawcolorcodedstring_wrapped(mySize_x,win_pos,
 487                         sprintf(_("%s^7 won the game!"), pname),
 488                         winfs, 0, DRAWFLAG_NORMAL, 0.5);
 489
 490                 drawfill(win_pos-eY*hud_fontsize_y,win_sz+2*eY*hud_fontsize_y,'1 1 1',0.5,DRAWFLAG_ADDITIVE);
 491
 492                 minigame_drawcolorcodedstring_wrapped(mySize_x,win_pos,
 493                         sprintf(_("%s^7 won the game!"), pname),
 494                         winfs, panel_fg_alpha, DRAWFLAG_NORMAL, 0.5);
 495         }
 496 }
 497
 498 // Required function, draw the game status panel
 499 void nmm_hud_status(vector pos, vector mySize)
 500 {
 501         HUD_Panel_DrawBg();
 502         vector ts;
 503         ts = minigame_drawstring_wrapped(mySize_x,pos,active_minigame.descriptor.message,
 504                 hud_fontsize * 2, '0.25 0.47 0.72', panel_fg_alpha, DRAWFLAG_NORMAL,0.5);
 505         pos_y += ts_y;
 506         mySize_y -= ts_y;
 507
 508         vector player_fontsize = hud_fontsize * 1.75;
 509         ts_y = ( mySize_y - 2*player_fontsize_y ) / 2;
 510         ts_x = mySize_x;
 511
 512         float player1x = 0;
 513         float player2x = 0;
 514         vector piece_sz = '48 48 0';
 515         float piece_space = piece_sz_x + ( ts_x - 7 * piece_sz_x ) / 6;
 516         vector mypos;
 517         float piece_light = 1;
 518         entity e = NULL;
 519
 520         mypos = pos;
 521         if ( (active_minigame.minigame_flags&NMM_TURN_TEAM) == 2 )
 522                 mypos_y  += player_fontsize_y + ts_y;
 523         drawfill(mypos,eX*mySize_x+eY*player_fontsize_y,'1 1 1',0.5,DRAWFLAG_ADDITIVE);
 524         mypos_y += player_fontsize_y;
 525         drawfill(mypos,eX*mySize_x+eY*piece_sz_y,'1 1 1',0.25,DRAWFLAG_ADDITIVE);
 526
 527         FOREACH_MINIGAME_ENTITY(e)
 528         {
 529                 if ( e.classname == "minigame_player" )
 530                 {
 531                         mypos = pos;
 532                         if ( e.team == 2 )
 533                                 mypos_y  += player_fontsize_y + ts_y;
 534                         minigame_drawcolorcodedstring_trunc(mySize_x,mypos,
 535                                 entcs_GetName(e.minigame_playerslot-1),
 536                                 player_fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
 537                 }
 538                 else if ( e.classname == "minigame_board_piece" )
 539                 {
 540                         mypos = pos;
 541                         mypos_y += player_fontsize_y;
 542                         if ( e.team == 2 )
 543                         {
 544                                 mypos_x += player2x;
 545                                 player2x += piece_space;
 546                                 mypos_y  += player_fontsize_y + ts_y;
 547                         }
 548                         else
 549                         {
 550                                 mypos_x += player1x;
 551                                 player1x += piece_space;
 552                         }
 553                         if ( e.minigame_flags == NMM_PIECE_HOME )
 554                                 piece_light = 0.5;
 555                         else if ( e.minigame_flags == NMM_PIECE_BOARD )
 556                                 piece_light = 1;
 557                         else
 558                                 piece_light = 0.15;
 559
 560                         drawpic(mypos, minigame_texture(strcat("nmm/piece",ftos(e.team))), piece_sz,
 561                                 '1 1 1'*piece_light, panel_fg_alpha, DRAWFLAG_NORMAL );
 562                 }
 563         }
 564 }
 565
 566 // Make the correct move
 567 void nmm_make_move(entity minigame)
 568 {
 569         if ( nmm_currtile )
 570         {
 571                 if ( minigame.minigame_flags & (NMM_TURN_PLACE|NMM_TURN_TAKE) )
 572                 {
 573                         minigame_cmd("move ",nmm_currtile.netname);
 574                         nmm_fromtile = NULL;
 575                 }
 576                 else if ( (minigame.minigame_flags & (NMM_TURN_MOVE|NMM_TURN_FLY)) )
 577                 {
 578                         if ( nmm_fromtile == nmm_currtile )
 579                         {
 580                                 nmm_fromtile = NULL;
 581                         }
 582                         else if ( nmm_currtile.nmm_tile_piece && nmm_currtile.nmm_tile_piece.team == minigame_self.team )
 583                         {
 584                                 nmm_fromtile = nmm_currtile;
 585                         }
 586                         else if ( nmm_fromtile )
 587                         {
 588                                 minigame_cmd("move ",nmm_fromtile.netname," ",nmm_currtile.netname);
 589                                 nmm_fromtile = NULL;
 590                         }
 591                 }
 592         }
 593         else
 594                 nmm_fromtile = NULL;
 595 }
 596
 597 string nmm_turn_to_string(int turnflags)
 598 {
 599         if ( turnflags & NMM_TURN_WIN )
 600         {
 601                 if ( (turnflags&NMM_TURN_TEAM) != minigame_self.team )
 602                         return _("You lost the game!");
 603                 return _("You win!");
 604         }
 605
 606         if ( (turnflags&NMM_TURN_TEAM) != minigame_self.team )
 607                 return _("Wait for your opponent to make their move");
 608         if ( turnflags & NMM_TURN_PLACE )
 609                 return _("Click on the game board to place your piece");
 610         if ( turnflags & NMM_TURN_MOVE )
 611                 return _("You can select one of your pieces to move it in one of the surrounding places");
 612         if ( turnflags & NMM_TURN_FLY )
 613                 return _("You can select one of your pieces to move it anywhere on the board");
 614         if ( turnflags & NMM_TURN_TAKE )
 615                 return _("You can take one of the opponent's pieces");
 616
 617         return "";
 618 }
 619
 620 // Required function, handle client events
 621 int nmm_client_event(entity minigame, string event, ...)
 622 {
 623         if ( event == "activate" )
 624         {
 625                 nmm_fromtile = NULL;
 626                 nmm_init_tiles(minigame);
 627                 strcpy(minigame.message, nmm_turn_to_string(minigame.minigame_flags));
 628         }
 629         else if ( event == "deactivate" )
 630         {
 631                 nmm_fromtile = NULL;
 632                 nmm_kill_tiles(minigame);
 633                 strfree(minigame.message);
 634         }
 635         else if ( event == "key_pressed" && (minigame.minigame_flags&NMM_TURN_TEAM) == minigame_self.team )
 636         {
 637                 switch ( ...(0,int) )
 638                 {
 639                         case K_RIGHTARROW:
 640                         case K_KP_RIGHTARROW:
 641                                 if ( ! nmm_currtile )
 642                                         nmm_currtile = nmm_find_tile(active_minigame,"a7");
 643                                 else
 644                                 {
 645                                         string tileid = nmm_currtile.netname;
 646                                         nmm_currtile = NULL;
 647                                         while ( !nmm_currtile )
 648                                         {
 649                                                 tileid = minigame_relative_tile(tileid,1,0,7,7);
 650                                                 nmm_currtile = nmm_find_tile(active_minigame,tileid);
 651                                         }
 652                                 }
 653                                 return 1;
 654                         case K_LEFTARROW:
 655                         case K_KP_LEFTARROW:
 656                                 if ( ! nmm_currtile )
 657                                         nmm_currtile = nmm_find_tile(active_minigame,"g7");
 658                                 else
 659                                 {
 660                                         string tileid = nmm_currtile.netname;
 661                                         nmm_currtile = NULL;
 662                                         while ( !nmm_currtile )
 663                                         {
 664                                                 tileid = minigame_relative_tile(tileid,-1,0,7,7);
 665                                                 nmm_currtile = nmm_find_tile(active_minigame,tileid);
 666                                         }
 667                                 }
 668                                 return 1;
 669                         case K_UPARROW:
 670                         case K_KP_UPARROW:
 671                                 if ( ! nmm_currtile )
 672                                         nmm_currtile = nmm_find_tile(active_minigame,"a1");
 673                                 else
 674                                 {
 675                                         string tileid = nmm_currtile.netname;
 676                                         nmm_currtile = NULL;
 677                                         while ( !nmm_currtile )
 678                                         {
 679                                                 tileid = minigame_relative_tile(tileid,0,1,7,7);
 680                                                 nmm_currtile = nmm_find_tile(active_minigame,tileid);
 681                                         }
 682                                 }
 683                                 return 1;
 684                         case K_DOWNARROW:
 685                         case K_KP_DOWNARROW:
 686                                 if ( ! nmm_currtile )
 687                                         nmm_currtile = nmm_find_tile(active_minigame,"a7");
 688                                 else
 689                                 {
 690                                         string tileid = nmm_currtile.netname;
 691                                         nmm_currtile = NULL;
 692                                         while ( !nmm_currtile )
 693                                         {
 694                                                 tileid = minigame_relative_tile(tileid,0,-1,7,7);
 695                                                 nmm_currtile = nmm_find_tile(active_minigame,tileid);
 696                                         }
 697                                 }
 698                                 return 1;
 699                         case K_ENTER:
 700                         case K_KP_ENTER:
 701                         case K_SPACE:
 702                                 nmm_make_move(minigame);
 703                                 return 1;
 704                 }
 705                 return 0;
 706         }
 707         else if ( event == "mouse_pressed" && ...(0,int) == K_MOUSE1 )
 708         {
 709                 nmm_make_move(minigame);
 710                 return 1;
 711         }
 712         else if ( event == "mouse_moved" )
 713         {
 714                 nmm_currtile = NULL;
 715                 vector tile_pos;
 716                 vector tile_size = minigame_hud_denormalize_size('1 1 0'/7,nmm_boardpos,nmm_boardsize);
 717                 entity e;
 718                 FOREACH_MINIGAME_ENTITY(e)
 719                 {
 720                         if ( e.classname == "minigame_nmm_tile" )
 721                         {
 722                                 tile_pos = minigame_hud_denormalize(e.origin,nmm_boardpos,nmm_boardsize)-tile_size/2;
 723                                 if ( minigame_hud_mouse_in(tile_pos, tile_size) && nmm_valid_selection(e) )
 724                                 {
 725                                         nmm_currtile = e;
 726                                         break;
 727                                 }
 728                         }
 729                 }
 730                 return 1;
 731         }
 732         else if ( event == "network_receive" )
 733         {
 734                 entity sent = ...(0,entity);
 735
 736                 if ( sent.classname == "minigame_board_piece" && ( ...(1,int) & MINIG_SF_UPDATE ) )
 737                 {
 738                         entity e;
 739                         string tileid = "";
 740                         if ( sent.minigame_flags & NMM_PIECE_BOARD )
 741                                 tileid = minigame_tile_name(sent.origin,7,7);
 742                         FOREACH_MINIGAME_ENTITY(e)
 743                         {
 744                                 if ( e.classname == "minigame_nmm_tile" )
 745                                 {
 746                                         if ( e.nmm_tile_piece == sent )
 747                                                 e.nmm_tile_piece = NULL;
 748                                         if ( e.netname == tileid )
 749                                                 e.nmm_tile_piece = sent;
 750                                 }
 751                         }
 752                 }
 753                 else if ( sent.classname == "minigame" && ( ...(1,int) & MINIG_SF_UPDATE ) )
 754                 {
 755                         strcpy(sent.message, nmm_turn_to_string(sent.minigame_flags));
 756                         if ( sent.minigame_flags & minigame_self.team )
 757                                 minigame_prompt();
 758                 }
 759         }
 760
 761         return 0;
 762 }
 763
 764 #endif