qcsrc/common/gamemodes/gamemode/keepaway/keepaway.qc

   1 #include "keepaway.qh"
   2
   3 // TODO: keepaway
   4 #ifdef SVQC
   5 #include <common/effects/all.qh>
   6
   7 .entity ballcarried;
   8
   9 int autocvar_g_keepaway_ballcarrier_effects;
  10 float autocvar_g_keepaway_ballcarrier_damage;
  11 float autocvar_g_keepaway_ballcarrier_force;
  12 float autocvar_g_keepaway_ballcarrier_highspeed;
  13 float autocvar_g_keepaway_ballcarrier_selfdamage;
  14 float autocvar_g_keepaway_ballcarrier_selfforce;
  15 float autocvar_g_keepaway_noncarrier_damage;
  16 float autocvar_g_keepaway_noncarrier_force;
  17 float autocvar_g_keepaway_noncarrier_selfdamage;
  18 float autocvar_g_keepaway_noncarrier_selfforce;
  19 bool autocvar_g_keepaway_noncarrier_warn;
  20 int autocvar_g_keepaway_score_bckill;
  21 int autocvar_g_keepaway_score_killac;
  22 int autocvar_g_keepaway_score_timepoints;
  23 float autocvar_g_keepaway_score_timeinterval;
  24 float autocvar_g_keepawayball_damageforcescale;
  25 int autocvar_g_keepawayball_effects;
  26 float autocvar_g_keepawayball_respawntime;
  27 int autocvar_g_keepawayball_trail_color;
  28
  29 bool ka_ballcarrier_waypointsprite_visible_for_player(entity this, entity player, entity view) // runs on waypoints which are attached to ballcarriers, updates once per frame
  30 {
  31         if(view.ballcarried)
  32                 if(IS_SPEC(player))
  33                         return false; // we don't want spectators of the ballcarrier to see the attached waypoint on the top of their screen
  34
  35         // TODO: Make the ballcarrier lack a waypointsprite whenever they have the invisibility powerup
  36
  37         return true;
  38 }
  39
  40 void ka_EventLog(string mode, entity actor) // use an alias for easy changing and quick editing later
  41 {
  42         if(autocvar_sv_eventlog)
  43                 GameLogEcho(strcat(":ka:", mode, ((actor != NULL) ? (strcat(":", ftos(actor.playerid))) : "")));
  44 }
  45
  46 void ka_TouchEvent(entity this, entity toucher);
  47 void ka_RespawnBall(entity this) // runs whenever the ball needs to be relocated
  48 {
  49         if(game_stopped) return;
  50         vector oldballorigin = this.origin;
  51
  52         if(!MoveToRandomMapLocation(this, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, 10, 1024, 256))
  53         {
  54                 entity spot = SelectSpawnPoint(this, true);
  55                 setorigin(this, spot.origin);
  56                 this.angles = spot.angles;
  57         }
  58
  59         makevectors(this.angles);
  60         set_movetype(this, MOVETYPE_BOUNCE);
  61         this.velocity = '0 0 200';
  62         this.angles = '0 0 0';
  63         this.effects = autocvar_g_keepawayball_effects;
  64         settouch(this, ka_TouchEvent);
  65         setthink(this, ka_RespawnBall);
  66         this.nextthink = time + autocvar_g_keepawayball_respawntime;
  67         navigation_dynamicgoal_set(this);
  68
  69         Send_Effect(EFFECT_ELECTRO_COMBO, oldballorigin, '0 0 0', 1);
  70         Send_Effect(EFFECT_ELECTRO_COMBO, this.origin, '0 0 0', 1);
  71
  72         WaypointSprite_Spawn(WP_KaBall, 0, 0, this, '0 0 64', NULL, this.team, this, waypointsprite_attachedforcarrier, false, RADARICON_FLAGCARRIER);
  73         WaypointSprite_Ping(this.waypointsprite_attachedforcarrier);
  74
  75         sound(this, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
  76 }
  77
  78 void ka_TimeScoring(entity this)
  79 {
  80         if(this.owner.ballcarried)
  81         { // add points for holding the ball after a certain amount of time
  82                 if(autocvar_g_keepaway_score_timepoints)
  83                         GameRules_scoring_add(this.owner, SCORE, autocvar_g_keepaway_score_timepoints);
  84
  85                 GameRules_scoring_add(this.owner, KEEPAWAY_BCTIME, (autocvar_g_keepaway_score_timeinterval / 1)); // interval is divided by 1 so that time always shows "seconds"
  86                 this.nextthink = time + autocvar_g_keepaway_score_timeinterval;
  87         }
  88 }
  89
  90 void ka_TouchEvent(entity this, entity toucher) // runs any time that the ball comes in contact with something
  91 {
  92         if (!this || game_stopped || time < game_starttime)
  93                 return;
  94
  95         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  96         { // The ball fell off the map, respawn it since players can't get to it
  97                 ka_RespawnBall(this);
  98                 return;
  99         }
 100         if(IS_DEAD(toucher)) { return; }
 101         if(STAT(FROZEN, toucher)) { return; }
 102         if (!IS_PLAYER(toucher))
 103         {  // The ball just touched an object, most likely the world
 104                 Send_Effect(EFFECT_BALL_SPARKS, this.origin, '0 0 0', 1);
 105                 sound(this, CH_TRIGGER, SND_KA_TOUCH, VOL_BASE, ATTEN_NORM);
 106                 return;
 107         }
 108         else if(this.wait > time) { return; }
 109
 110         // attach the ball to the player
 111         this.owner = toucher;
 112         toucher.ballcarried = this;
 113         GameRules_scoring_vip(toucher, true);
 114         setattachment(this, toucher, "");
 115         setorigin(this, '0 0 0');
 116
 117         // make the ball invisible/unable to do anything/set up time scoring
 118         this.velocity = '0 0 0';
 119         set_movetype(this, MOVETYPE_NONE);
 120         this.effects |= EF_NODRAW;
 121         settouch(this, func_null);
 122         setthink(this, ka_TimeScoring);
 123         this.nextthink = time + autocvar_g_keepaway_score_timeinterval;
 124         this.takedamage = DAMAGE_NO;
 125         navigation_dynamicgoal_unset(this);
 126
 127         // apply effects to player
 128         toucher.glow_color = autocvar_g_keepawayball_trail_color;
 129         toucher.glow_trail = true;
 130         toucher.effects |= autocvar_g_keepaway_ballcarrier_effects;
 131
 132         // messages and sounds
 133         ka_EventLog("pickup", toucher);
 134         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_KEEPAWAY_PICKUP, toucher.netname);
 135         Send_Notification(NOTIF_ALL_EXCEPT, toucher, MSG_CENTER, CENTER_KEEPAWAY_PICKUP, toucher.netname);
 136         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_KEEPAWAY_PICKUP_SELF);
 137         sound(this.owner, CH_TRIGGER, SND_KA_PICKEDUP, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 138
 139         // scoring
 140         GameRules_scoring_add(toucher, KEEPAWAY_PICKUPS, 1);
 141
 142         // waypoints
 143         WaypointSprite_AttachCarrier(WP_KaBallCarrier, toucher, RADARICON_FLAGCARRIER);
 144         toucher.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = ka_ballcarrier_waypointsprite_visible_for_player;
 145         WaypointSprite_UpdateRule(toucher.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 146         WaypointSprite_Ping(toucher.waypointsprite_attachedforcarrier);
 147         WaypointSprite_Kill(this.waypointsprite_attachedforcarrier);
 148 }
 149
 150 void ka_DropEvent(entity plyr) // runs any time that a player is supposed to lose the ball
 151 {
 152         entity ball;
 153         ball = plyr.ballcarried;
 154
 155         if(!ball) { return; }
 156
 157         // reset the ball
 158         setattachment(ball, NULL, "");
 159         set_movetype(ball, MOVETYPE_BOUNCE);
 160         ball.wait = time + 1;
 161         settouch(ball, ka_TouchEvent);
 162         setthink(ball, ka_RespawnBall);
 163         ball.nextthink = time + autocvar_g_keepawayball_respawntime;
 164         ball.takedamage = DAMAGE_YES;
 165         ball.effects &= ~EF_NODRAW;
 166         setorigin(ball, plyr.origin + '0 0 10');
 167         ball.velocity = '0 0 200' + '0 100 0'*crandom() + '100 0 0'*crandom();
 168         ball.owner = NULL;
 169         plyr.ballcarried = NULL;
 170         GameRules_scoring_vip(plyr, false);
 171         navigation_dynamicgoal_set(ball);
 172
 173         // reset the player effects
 174         plyr.glow_trail = false;
 175         plyr.effects &= ~autocvar_g_keepaway_ballcarrier_effects;
 176
 177         // messages and sounds
 178         ka_EventLog("dropped", plyr);
 179         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_KEEPAWAY_DROPPED, plyr.netname);
 180         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEEPAWAY_DROPPED, plyr.netname);
 181         sound(NULL, CH_TRIGGER, SND_KA_DROPPED, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 182
 183         // scoring
 184         // GameRules_scoring_add(plyr, KEEPAWAY_DROPS, 1); Not anymore, this is 100% the same as pickups and is useless.
 185
 186         // waypoints
 187         WaypointSprite_Spawn(WP_KaBall, 0, 0, ball, '0 0 64', NULL, ball.team, ball, waypointsprite_attachedforcarrier, false, RADARICON_FLAGCARRIER);
 188         WaypointSprite_UpdateRule(ball.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 189         WaypointSprite_Ping(ball.waypointsprite_attachedforcarrier);
 190         WaypointSprite_Kill(plyr.waypointsprite_attachedforcarrier);
 191 }
 192
 193 /** used to clear the ballcarrier whenever the match switches from warmup to normal */
 194 void ka_Reset(entity this)
 195 {
 196         if((this.owner) && (IS_PLAYER(this.owner)))
 197                 ka_DropEvent(this.owner);
 198
 199         if(time < game_starttime)
 200         {
 201                 setthink(this, ka_RespawnBall);
 202                 settouch(this, func_null);
 203                 this.nextthink = game_starttime;
 204         }
 205         else
 206                 ka_RespawnBall(this);
 207 }
 208
 209 .bool pushable;
 210
 211 MODEL(KA_BALL, "models/orbs/orbblue.md3");
 212
 213 void ka_SpawnBall() // loads various values for the ball, runs only once at start of match
 214 {
 215         entity e = new(keepawayball);
 216         setmodel(e, MDL_KA_BALL);
 217         setsize(e, '-16 -16 -20', '16 16 20'); // 20 20 20 was too big, player is only 16 16 24... gotta cheat with the Z (20) axis so that the particle isn't cut off
 218         e.damageforcescale = autocvar_g_keepawayball_damageforcescale;
 219         e.takedamage = DAMAGE_YES;
 220         e.solid = SOLID_TRIGGER;
 221         set_movetype(e, MOVETYPE_BOUNCE);
 222         e.glow_color = autocvar_g_keepawayball_trail_color;
 223         e.glow_trail = true;
 224         e.flags = FL_ITEM;
 225         IL_PUSH(g_items, e);
 226         e.pushable = true;
 227         e.reset = ka_Reset;
 228         settouch(e, ka_TouchEvent);
 229         e.owner = NULL;
 230         ka_ball = e;
 231         navigation_dynamicgoal_init(ka_ball, false);
 232
 233         InitializeEntity(e, ka_RespawnBall, INITPRIO_SETLOCATION); // is this the right priority? Neh, I have no idea.. Well-- it works! So.
 234 }
 235
 236 void ka_Initialize() // run at the start of a match, initiates game mode
 237 {
 238         ka_SpawnBall();
 239 }
 240
 241 // ================
 242 // Bot player logic
 243 // ================
 244
 245 void havocbot_goalrating_ball(entity this, float ratingscale, vector org)
 246 {
 247         float t;
 248         entity ball_owner;
 249         ball_owner = ka_ball.owner;
 250
 251         if (ball_owner == this)
 252                 return;
 253
 254         // If ball is carried by player then hunt them down.
 255         if (ball_owner)
 256         {
 257                 t = (GetResourceAmount(this, RESOURCE_HEALTH) + GetResourceAmount(this, RESOURCE_ARMOR)) / (GetResourceAmount(ball_owner, RESOURCE_HEALTH) + GetResourceAmount(ball_owner, RESOURCE_ARMOR));
 258                 navigation_routerating(this, ball_owner, t * ratingscale, 2000);
 259         }
 260         else // Ball has been dropped so collect.
 261                 navigation_routerating(this, ka_ball, ratingscale, 2000);
 262 }
 263
 264 void havocbot_role_ka_carrier(entity this)
 265 {
 266         if (IS_DEAD(this))
 267                 return;
 268
 269         if (navigation_goalrating_timeout(this))
 270         {
 271                 navigation_goalrating_start(this);
 272                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
 273                 havocbot_goalrating_enemyplayers(this, 20000, this.origin, 10000);
 274                 havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
 275                 navigation_goalrating_end(this);
 276
 277                 navigation_goalrating_timeout_set(this);
 278         }
 279
 280         if (!this.ballcarried)
 281         {
 282                 this.havocbot_role = havocbot_role_ka_collector;
 283                 navigation_goalrating_timeout_expire(this, 2);
 284         }
 285 }
 286
 287 void havocbot_role_ka_collector(entity this)
 288 {
 289         if (IS_DEAD(this))
 290                 return;
 291
 292         if (navigation_goalrating_timeout(this))
 293         {
 294                 navigation_goalrating_start(this);
 295                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
 296                 havocbot_goalrating_enemyplayers(this, 1000, this.origin, 10000);
 297                 havocbot_goalrating_ball(this, 20000, this.origin);
 298                 navigation_goalrating_end(this);
 299
 300                 navigation_goalrating_timeout_set(this);
 301         }
 302
 303         if (this.ballcarried)
 304         {
 305                 this.havocbot_role = havocbot_role_ka_carrier;
 306                 navigation_goalrating_timeout_expire(this, 2);
 307         }
 308 }
 309
 310
 311 // ==============
 312 // Hook Functions
 313 // ==============
 314
 315 MUTATOR_HOOKFUNCTION(ka, PlayerDies)
 316 {
 317         entity frag_attacker = M_ARGV(1, entity);
 318         entity frag_target = M_ARGV(2, entity);
 319
 320         if((frag_attacker != frag_target) && (IS_PLAYER(frag_attacker)))
 321         {
 322                 if(frag_target.ballcarried) { // add to amount of times killing carrier
 323                         GameRules_scoring_add(frag_attacker, KEEPAWAY_CARRIERKILLS, 1);
 324                         if(autocvar_g_keepaway_score_bckill) // add bckills to the score
 325                                 GameRules_scoring_add(frag_attacker, SCORE, autocvar_g_keepaway_score_bckill);
 326                 }
 327                 else if(!frag_attacker.ballcarried)
 328                         if(autocvar_g_keepaway_noncarrier_warn)
 329                                 Send_Notification(NOTIF_ONE_ONLY, frag_attacker, MSG_CENTER, CENTER_KEEPAWAY_WARN);
 330
 331                 if(frag_attacker.ballcarried) // add to amount of kills while ballcarrier
 332                         GameRules_scoring_add(frag_attacker, SCORE, autocvar_g_keepaway_score_killac);
 333         }
 334
 335         if(frag_target.ballcarried) { ka_DropEvent(frag_target); } // a player with the ball has died, drop it
 336 }
 337
 338 MUTATOR_HOOKFUNCTION(ka, GiveFragsForKill)
 339 {
 340         M_ARGV(2, float) = 0; // no frags counted in keepaway
 341         return true; // you deceptive little bugger ;3 This needs to be true in order for this function to even count.
 342 }
 343
 344 MUTATOR_HOOKFUNCTION(ka, PlayerPreThink)
 345 {
 346         entity player = M_ARGV(0, entity);
 347
 348         // clear the item used for the ball in keepaway
 349         player.items &= ~IT_KEY1;
 350
 351         // if the player has the ball, make sure they have the item for it (Used for HUD primarily)
 352         if(player.ballcarried)
 353                 player.items |= IT_KEY1;
 354 }
 355
 356 MUTATOR_HOOKFUNCTION(ka, PlayerUseKey)
 357 {
 358         entity player = M_ARGV(0, entity);
 359
 360         if(MUTATOR_RETURNVALUE == 0)
 361         if(player.ballcarried)
 362         {
 363                 ka_DropEvent(player);
 364                 return true;
 365         }
 366 }
 367
 368 MUTATOR_HOOKFUNCTION(ka, Damage_Calculate) // for changing damage and force values that are applied to players in g_damage.qc
 369 {
 370         entity frag_attacker = M_ARGV(1, entity);
 371         entity frag_target = M_ARGV(2, entity);
 372         float frag_damage = M_ARGV(4, float);
 373         vector frag_force = M_ARGV(6, vector);
 374
 375         if(frag_attacker.ballcarried) // if the attacker is a ballcarrier
 376         {
 377                 if(frag_target == frag_attacker) // damage done to yourself
 378                 {
 379                         frag_damage *= autocvar_g_keepaway_ballcarrier_selfdamage;
 380                         frag_force *= autocvar_g_keepaway_ballcarrier_selfforce;
 381                 }
 382                 else // damage done to noncarriers
 383                 {
 384                         frag_damage *= autocvar_g_keepaway_ballcarrier_damage;
 385                         frag_force *= autocvar_g_keepaway_ballcarrier_force;
 386                 }
 387         }
 388         else if (!frag_target.ballcarried) // if the target is a noncarrier
 389         {
 390                 if(frag_target == frag_attacker) // damage done to yourself
 391                 {
 392                         frag_damage *= autocvar_g_keepaway_noncarrier_selfdamage;
 393                         frag_force *= autocvar_g_keepaway_noncarrier_selfforce;
 394                 }
 395                 else // damage done to other noncarriers
 396                 {
 397                         frag_damage *= autocvar_g_keepaway_noncarrier_damage;
 398                         frag_force *= autocvar_g_keepaway_noncarrier_force;
 399                 }
 400         }
 401
 402         M_ARGV(4, float) = frag_damage;
 403         M_ARGV(6, vector) = frag_force;
 404 }
 405
 406 MUTATOR_HOOKFUNCTION(ka, ClientDisconnect)
 407 {
 408         entity player = M_ARGV(0, entity);
 409
 410         if(player.ballcarried) { ka_DropEvent(player); } // a player with the ball has left the match, drop it
 411 }
 412
 413 MUTATOR_HOOKFUNCTION(ka, MakePlayerObserver)
 414 {
 415         entity player = M_ARGV(0, entity);
 416
 417         if(player.ballcarried) { ka_DropEvent(player); } // a player with the ball has left the match, drop it
 418 }
 419
 420 MUTATOR_HOOKFUNCTION(ka, PlayerPowerups)
 421 {
 422         entity player = M_ARGV(0, entity);
 423
 424         // In the future this hook is supposed to allow me to do some extra stuff with waypointsprites and invisibility powerup
 425         // So bare with me until I can fix a certain bug with ka_ballcarrier_waypointsprite_visible_for_player()
 426
 427         player.effects &= ~autocvar_g_keepaway_ballcarrier_effects;
 428
 429         if(player.ballcarried)
 430                 player.effects |= autocvar_g_keepaway_ballcarrier_effects;
 431 }
 432
 433
 434 MUTATOR_HOOKFUNCTION(ka, PlayerPhysics_UpdateStats)
 435 {
 436         entity player = M_ARGV(0, entity);
 437         // these automatically reset, no need to worry
 438
 439         if(player.ballcarried)
 440                 STAT(MOVEVARS_HIGHSPEED, player) *= autocvar_g_keepaway_ballcarrier_highspeed;
 441 }
 442
 443 MUTATOR_HOOKFUNCTION(ka, BotShouldAttack)
 444 {
 445         entity bot = M_ARGV(0, entity);
 446         entity targ = M_ARGV(1, entity);
 447
 448         // if neither player has ball then don't attack unless the ball is on the ground
 449         if(!targ.ballcarried && !bot.ballcarried && ka_ball.owner)
 450                 return true;
 451 }
 452
 453 MUTATOR_HOOKFUNCTION(ka, HavocBot_ChooseRole)
 454 {
 455         entity bot = M_ARGV(0, entity);
 456
 457         if (bot.ballcarried)
 458                 bot.havocbot_role = havocbot_role_ka_carrier;
 459         else
 460                 bot.havocbot_role = havocbot_role_ka_collector;
 461         return true;
 462 }
 463
 464 MUTATOR_HOOKFUNCTION(ka, DropSpecialItems)
 465 {
 466         entity frag_target = M_ARGV(0, entity);
 467
 468         if(frag_target.ballcarried)
 469                 ka_DropEvent(frag_target);
 470 }
 471
 472 #endif