qcsrc/common/effects/qc/damageeffects.qc

   1 #include "damageeffects.qh"
   2
   3 REGISTER_NET_LINKED(ENT_CLIENT_DAMAGEINFO)
   4
   5 #ifdef SVQC
   6
   7 bool Damage_DamageInfo_SendEntity(entity this, entity to, int sf)
   8 {
   9         vector org = vec3(floor(this.origin.x), floor(this.origin.y), floor(this.origin.z));
  10         WriteHeader(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
  11         WriteShort(MSG_ENTITY, this.projectiledeathtype);
  12         WriteVector(MSG_ENTITY, org);
  13         WriteByte(MSG_ENTITY, bound(1, this.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, this.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, this.dmg_edge, 255));
  16         WriteVector(MSG_ENTITY, this.velocity);
  17         WriteByte(MSG_ENTITY, this.species);
  18         return true;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, int deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = new_pure(damageinfo);
  32         // origin is just data to be sent
  33         //setorigin(e, org);
  34         e.origin = org;
  35         e.projectiledeathtype = deathtype;
  36         e.dmg = coredamage;
  37         e.dmg_edge = edgedamage;
  38         e.dmg_radius = rad;
  39         e.dmg_force = vlen(force);
  40         e.velocity = force;
  41         e.species = bloodtype;
  42
  43         Net_LinkEntity(e, false, 0.2, Damage_DamageInfo_SendEntity);
  44 }
  45
  46 #endif
  47
  48 #ifdef CSQC
  49
  50 /** number of effects which currently are attached to a player */
  51 .int total_damages;
  52
  53 .entity tag_entity;
  54
  55 .float cnt;
  56 .int state;
  57
  58 .bool silent;
  59
  60 void DamageEffect_Think(entity this)
  61 {
  62         // if particle distribution is enabled, slow ticrate by total number of damages
  63         if(autocvar_cl_damageeffect_distribute)
  64                 this.nextthink = time + autocvar_cl_damageeffect_ticrate * this.owner.total_damages;
  65         else
  66                 this.nextthink = time + autocvar_cl_damageeffect_ticrate;
  67
  68         if(time >= this.cnt || !this.owner || !this.owner.modelindex || !this.owner.drawmask)
  69         {
  70                 // time is up or the player got gibbed / disconnected
  71                 this.owner.total_damages = max(0, this.owner.total_damages - 1);
  72                 delete(this);
  73                 return;
  74         }
  75         if(this.state && !this.owner.csqcmodel_isdead)
  76         {
  77                 // if the player was dead but is now alive, it means he respawned
  78                 // if so, clear his damage effects, or damages from his dead body will be copied back
  79                 this.owner.total_damages = max(0, this.owner.total_damages - 1);
  80                 delete(this);
  81                 return;
  82         }
  83         this.state = this.owner.csqcmodel_isdead;
  84         if((this.owner.isplayermodel & ISPLAYER_LOCAL) && !autocvar_chase_active)
  85                 return; // if we aren't using a third person camera, hide our own effects
  86
  87         // now generate the particles
  88         vector org = gettaginfo(this, 0); // origin at attached location
  89         __pointparticles(this.team, org, '0 0 0', 1);
  90 }
  91
  92 string species_prefix(int specnum)
  93 {
  94         switch(specnum)
  95         {
  96                 case SPECIES_HUMAN:       return "";
  97                 case SPECIES_ALIEN:       return "alien_";
  98                 case SPECIES_ROBOT_SHINY: return "robot_";
  99                 case SPECIES_ROBOT_RUSTY: return "robot_"; // use the same effects, only different gibs
 100                 case SPECIES_ROBOT_SOLID: return "robot_"; // use the same effects, only different gibs
 101                 case SPECIES_ANIMAL:      return "animal_";
 102                 case SPECIES_RESERVED:    return "reserved_";
 103                 default:         return "";
 104         }
 105 }
 106
 107 void DamageEffect(entity this, vector hitorg, float thedamage, int type, int specnum)
 108 {
 109         // particle effects for players and objects damaged by weapons (eg: flames coming out of victims shot with rockets)
 110
 111         int nearestbone = 0;
 112         float life;
 113         string effectname;
 114         entity e, wep;
 115
 116         if(!autocvar_cl_damageeffect || autocvar_cl_gentle || autocvar_cl_gentle_damage)
 117                 return;
 118         if(!this || !this.modelindex || !this.drawmask)
 119                 return;
 120
 121         // if this is a rigged mesh, the effect will show on the bone where damage was dealt
 122         // we do this by choosing the skeletal bone closest to the impact, and attaching our entity to it
 123         // if there's no skeleton, object origin will automatically be selected
 124         FOR_EACH_TAG(this)
 125         {
 126                 if(!tagnum)
 127                         continue; // skip empty bones
 128                 // blacklist bones positioned outside the mesh, or the effect will be floating
 129                 // TODO: Do we have to do it this way? Why do these bones exist at all?
 130                 if(gettaginfo_name == "master" || gettaginfo_name == "knee_L" || gettaginfo_name == "knee_R" || gettaginfo_name == "leg_L" || gettaginfo_name == "leg_R")
 131                         continue; // player model bone blacklist
 132
 133                 // now choose the bone closest to impact origin
 134                 if(nearestbone == 0 || vlen2(hitorg - gettaginfo(this, tagnum)) <= vlen2(hitorg - gettaginfo(this, nearestbone)))
 135                         nearestbone = tagnum;
 136         }
 137         gettaginfo(this, nearestbone); // set gettaginfo_name
 138
 139         // return if we reached our damage effect limit or damages are disabled
 140         // TODO: When the limit is reached, it would be better if the oldest damage was removed instead of not adding a new one
 141         if(nearestbone)
 142         {
 143                 if(this.total_damages >= autocvar_cl_damageeffect_bones)
 144                         return; // allow multiple damages on skeletal models
 145         }
 146         else
 147         {
 148                 if(autocvar_cl_damageeffect < 2 || this.total_damages)
 149                         return; // allow a single damage on non-skeletal models
 150         }
 151
 152         life = bound(autocvar_cl_damageeffect_lifetime_min, thedamage * autocvar_cl_damageeffect_lifetime, autocvar_cl_damageeffect_lifetime_max);
 153
 154         wep = DEATH_WEAPONOF(type);
 155         effectname = strcat("damage_", wep.netname);
 156         if((wep.spawnflags & WEP_FLAG_BLEED))
 157         {
 158                 // if this weapon induces bleeding, use the effect name with the proper species prefix (blood type)
 159                 if((this.isplayermodel & ISPLAYER_MODEL))
 160                 {
 161                         string specstr = species_prefix(specnum);
 162                         effectname = strcat(specstr, effectname);
 163                 }
 164                 else { return; } // objects don't bleed
 165         }
 166
 167         e = new(damage);
 168         setmodel(e, MDL_Null); // necessary to attach and read origin
 169         setattachment(e, this, gettaginfo_name); // attach to the given bone
 170         e.owner = this;
 171         e.cnt = time + life;
 172         e.team = _particleeffectnum(effectname);
 173         setthink(e, DamageEffect_Think);
 174         e.nextthink = time;
 175         this.total_damages += 1;
 176 }
 177
 178 NET_HANDLE(ENT_CLIENT_DAMAGEINFO, bool isNew)
 179 {
 180         float thedamage, rad, edge, thisdmg;
 181         bool hitplayer = false;
 182         int species, forcemul;
 183         vector force, thisforce;
 184
 185         w_deathtype = ReadShort();
 186         w_issilent = (w_deathtype & 0x8000);
 187         w_deathtype = (w_deathtype & 0x7FFF);
 188
 189         w_org = ReadVector();
 190
 191         thedamage = ReadByte();
 192         rad = ReadByte();
 193         edge = ReadByte();
 194         force = ReadVector();
 195         species = ReadByte();
 196
 197         return = true;
 198
 199         if (!isNew)
 200                 return;
 201
 202         if(rad < 0)
 203         {
 204                 rad = -rad;
 205                 forcemul = -1;
 206         }
 207         else
 208                 forcemul = 1;
 209
 210         FOREACH_ENTITY_RADIUS(w_org, rad + MAX_DAMAGEEXTRARADIUS, !it.tag_entity, {
 211                 vector nearest = NearestPointOnBox(it, w_org);
 212                 if (rad)
 213                 {
 214                         thisdmg = ((vlen(nearest - w_org) - bound(MIN_DAMAGEEXTRARADIUS, it.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
 215                         if(thisdmg >= 1)
 216                                 continue;
 217                         if(thisdmg < 0)
 218                                 thisdmg = 0;
 219                         if(thedamage)
 220                         {
 221                                 thisdmg = thedamage + (edge - thedamage) * thisdmg;
 222                                 thisforce = forcemul * vlen(force) * (thisdmg / thedamage) * normalize(it.origin - w_org);
 223                         }
 224                         else
 225                         {
 226                                 thisdmg = 0;
 227                                 thisforce = forcemul * vlen(force) * normalize(it.origin - w_org);
 228                         }
 229                 }
 230                 else
 231                 {
 232                         if(vdist((nearest - w_org), >, bound(MIN_DAMAGEEXTRARADIUS, it.damageextraradius, MAX_DAMAGEEXTRARADIUS)))
 233                                 continue;
 234
 235                         thisdmg = thedamage;
 236                         thisforce = forcemul * force;
 237                 }
 238
 239                 if(it.damageforcescale)
 240                         if(vdist(thisforce, !=, 0))
 241                         {
 242                                 it.velocity = it.velocity + damage_explosion_calcpush(it.damageforcescale * thisforce, it.velocity, damagepush_speedfactor);
 243                                 UNSET_ONGROUND(it);
 244                         }
 245
 246                 if(w_issilent)
 247                         it.silent = 1;
 248
 249                 if(it.event_damage)
 250                         it.event_damage(it, thisdmg, w_deathtype, w_org, thisforce);
 251
 252                 DamageEffect(it, w_org, thisdmg, w_deathtype, species);
 253
 254                 if((it.isplayermodel & ISPLAYER_MODEL))
 255                         hitplayer = true; // this impact damaged a player
 256         });
 257
 258         if(DEATH_ISVEHICLE(w_deathtype))
 259         {
 260                 vector force_dir = normalize(force);
 261                 traceline(w_org - force_dir * 16, w_org + force_dir * 16, MOVE_NOMONSTERS, NULL);
 262                 if(trace_plane_normal != '0 0 0')
 263                         w_backoff = trace_plane_normal;
 264                 else
 265                         w_backoff = -1 * normalize(w_org - (w_org + force_dir * 16));
 266
 267                 setorigin(this, w_org + w_backoff * 2); // for sound() calls
 268
 269                 switch(DEATH_ENT(w_deathtype))
 270                 {
 271                         case DEATH_VH_CRUSH:
 272                                 break;
 273
 274                         // spiderbot
 275                         case DEATH_VH_SPID_MINIGUN:
 276                                 sound(this, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_NORM);
 277                                 pointparticles(EFFECT_SPIDERBOT_MINIGUN_IMPACT, this.origin, w_backoff * 1000, 1);
 278                                 break;
 279                         case DEATH_VH_SPID_ROCKET:
 280                                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 281                                 pointparticles(EFFECT_SPIDERBOT_ROCKET_EXPLODE, this.origin, w_backoff * 1000, 1);
 282                                 break;
 283                         case DEATH_VH_SPID_DEATH:
 284                                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_LOW);
 285                                 pointparticles(EFFECT_EXPLOSION_BIG, this.origin, w_backoff * 1000, 1);
 286                                 break;
 287
 288                         case DEATH_VH_WAKI_GUN:
 289                                 sound(this, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTEN_NORM);
 290                                 pointparticles(EFFECT_RACER_IMPACT, this.origin, w_backoff * 1000, 1);
 291                                 break;
 292                         case DEATH_VH_WAKI_ROCKET:
 293                                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 294                                 pointparticles(EFFECT_RACER_ROCKET_EXPLODE, this.origin, w_backoff * 1000, 1);
 295                                 break;
 296                         case DEATH_VH_WAKI_DEATH:
 297                                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_LOW);
 298                                 pointparticles(EFFECT_EXPLOSION_BIG, this.origin, w_backoff * 1000, 1);
 299                                 break;
 300
 301                         case DEATH_VH_RAPT_CANNON:
 302                                 sound(this, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTEN_NORM);
 303                                 pointparticles(EFFECT_RAPTOR_CANNON_IMPACT, this.origin, w_backoff * 1000, 1);
 304                                 break;
 305                         case DEATH_VH_RAPT_FRAGMENT:
 306                                 float i;
 307                                 vector ang, vel;
 308                                 for(i = 1; i < 4; ++i)
 309                                 {
 310                                         vel = normalize(w_org - (w_org + force_dir * 16)) + randomvec() * 128;
 311                                         ang = vectoangles(vel);
 312                                         RaptorCBShellfragToss(w_org, vel, ang + '0 0 1' * (120 * i));
 313                                 }
 314                                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 315                                 pointparticles(EFFECT_RAPTOR_BOMB_SPREAD, this.origin, w_backoff * 1000, 1);
 316                                 break;
 317                         case DEATH_VH_RAPT_BOMB:
 318                                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 319                                 pointparticles(EFFECT_RAPTOR_BOMB_IMPACT, this.origin, w_backoff * 1000, 1);
 320                                 break;
 321                         case DEATH_VH_RAPT_DEATH:
 322                                 sound(this, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTEN_LOW);
 323                                 pointparticles(EFFECT_EXPLOSION_BIG, this.origin, w_backoff * 1000, 1);
 324                                 break;
 325                         case DEATH_VH_BUMB_GUN:
 326                                 sound(this, CH_SHOTS, SND_FIREBALL_IMPACT2, VOL_BASE, ATTEN_NORM);
 327                                 pointparticles(EFFECT_BIGPLASMA_IMPACT, this.origin, w_backoff * 1000, 1);
 328                                 break;
 329                 }
 330         }
 331
 332
 333         if(DEATH_ISTURRET(w_deathtype))
 334         {
 335                 vector force_dir = normalize(force);
 336                 traceline(w_org - force_dir * 16, w_org + force_dir * 16, MOVE_NOMONSTERS, NULL);
 337                 if(trace_plane_normal != '0 0 0')
 338                         w_backoff = trace_plane_normal;
 339                 else
 340                         w_backoff = -1 * normalize(w_org - (w_org + force_dir * 16));
 341
 342                 setorigin(this, w_org + w_backoff * 2); // for sound() calls
 343
 344                 switch(DEATH_ENT(w_deathtype))
 345                 {
 346                         case DEATH_TURRET_EWHEEL:
 347                                 sound(this, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTEN_LOW);
 348                                 pointparticles(EFFECT_BLASTER_IMPACT, this.origin, w_backoff * 1000, 1);
 349                                 break;
 350
 351                         case DEATH_TURRET_FLAC:
 352                                 pointparticles(EFFECT_HAGAR_EXPLODE, w_org, '0 0 0', 1);
 353                                 sound(this, CH_SHOTS, SND_HAGEXP_RANDOM(), VOL_BASE, ATTEN_NORM);
 354                                 break;
 355
 356                         case DEATH_TURRET_MLRS:
 357                         case DEATH_TURRET_HK:
 358                         case DEATH_TURRET_WALK_ROCKET:
 359                         case DEATH_TURRET_HELLION:
 360                                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_LOW);
 361                                 pointparticles(EFFECT_ROCKET_EXPLODE, this.origin, w_backoff * 1000, 1);
 362                                 break;
 363
 364                         case DEATH_TURRET_MACHINEGUN:
 365                         case DEATH_TURRET_WALK_GUN:
 366                                 sound(this, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_NORM);
 367                                 pointparticles(EFFECT_MACHINEGUN_IMPACT, this.origin, w_backoff * 1000, 1);
 368                                 break;
 369
 370                         case DEATH_TURRET_PLASMA:
 371                                 sound(this, CH_SHOTS, SND_ELECTRO_IMPACT, VOL_BASE, ATTEN_LOW);
 372                                 pointparticles(EFFECT_ELECTRO_IMPACT, this.origin, w_backoff * 1000, 1);
 373                                 break;
 374
 375                         case DEATH_TURRET_WALK_MELEE:
 376                                 sound(this, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_LOW);
 377                                 pointparticles(EFFECT_TE_SPARK, this.origin, w_backoff * 1000, 1);
 378                                 break;
 379
 380                         case DEATH_TURRET_PHASER:
 381                                 break;
 382
 383                         case DEATH_TURRET_TESLA:
 384                                 te_smallflash(this.origin);
 385                                 break;
 386                 }
 387         }
 388
 389         MUTATOR_CALLHOOK(DamageInfo, this, w_deathtype, w_org);
 390
 391         // TODO spawn particle effects and sounds based on w_deathtype
 392         if(!DEATH_ISSPECIAL(w_deathtype))
 393         if(!hitplayer || rad) // don't show ground impacts for hitscan weapons if a player was hit
 394         {
 395                 Weapon hitwep = DEATH_WEAPONOF(w_deathtype);
 396                 w_random = prandom();
 397
 398                 vector force_dir = normalize(force);
 399                 // this traceline usually starts in solid when a hitscan shot hits a surface with a very small angle
 400                 // if so, try another traceline starting further back (may still start in solid but only with extremely small angles)
 401                 traceline(w_org - force_dir * 16, w_org + force_dir * 16, MOVE_NOMONSTERS, NULL);
 402                 if(trace_startsolid)
 403                         traceline(w_org - force_dir * 40, w_org + force_dir * 16, MOVE_NOMONSTERS, NULL);
 404                 if(trace_fraction < 1)
 405                         w_backoff = trace_plane_normal;
 406                 else
 407                         w_backoff = -force_dir;
 408                 setorigin(this, w_org + w_backoff * 2); // for sound() calls
 409
 410                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
 411                 {
 412                         if(!MUTATOR_CALLHOOK(Weapon_ImpactEffect, hitwep, this))
 413                                 hitwep.wr_impacteffect(hitwep, this);
 414                 }
 415         }
 416 }
 417
 418 #endif