qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include <client/mutators/_mod.qh>
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/net_notice.qh>
  21 #include <common/debug.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/gamemodes/_mod.qh>
  24 #include <common/physics/player.qh>
  25 #include <common/stats.qh>
  26 #include <common/mapobjects/target/music.qh>
  27 #include <common/teams.qh>
  28 #include <common/wepent.qh>
  29
  30 #include <common/weapons/weapon/tuba.qh>
  31
  32 #include <common/vehicles/all.qh>
  33 #include <common/weapons/_all.qh>
  34 #include <common/mutators/mutator/overkill/oknex.qh>
  35 #include <common/mutators/mutator/waypoints/all.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/mapobjects/trigger/viewloc.qh>
  38 #include <common/minigames/cl_minigames.qh>
  39 #include <common/minigames/cl_minigames_hud.qh>
  40
  41 #include <lib/csqcmodel/cl_player.qh>
  42 #include <lib/csqcmodel/cl_model.qh>
  43 #include "csqcmodel_hooks.qh"
  44
  45 #include <lib/warpzone/client.qh>
  46 #include <lib/warpzone/common.qh>
  47
  48 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  49
  50 float autocvar_cl_viewmodel_scale;
  51 float autocvar_cl_viewmodel_alpha;
  52
  53 bool autocvar_cl_bobmodel;
  54 float autocvar_cl_bobmodel_speed;
  55 float autocvar_cl_bobmodel_side;
  56 float autocvar_cl_bobmodel_up;
  57
  58 float autocvar_cl_followmodel;
  59 float autocvar_cl_followmodel_speed = 0.3;
  60 float autocvar_cl_followmodel_limit = 135;
  61 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  62 float autocvar_cl_followmodel_highpass = 0.05;
  63 float autocvar_cl_followmodel_lowpass = 0.03;
  64 bool autocvar_cl_followmodel_velocity_absolute;
  65
  66 float autocvar_cl_leanmodel;
  67 float autocvar_cl_leanmodel_speed = 0.3;
  68 float autocvar_cl_leanmodel_limit = 30;
  69 float autocvar_cl_leanmodel_highpass1 = 0.2;
  70 float autocvar_cl_leanmodel_highpass = 0.2;
  71 float autocvar_cl_leanmodel_lowpass = 0.05;
  72
  73 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  74
  75 #define lowpass(value, frac, ref_store, ret) \
  76         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  77
  78 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  79         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  80         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  81 MACRO_END
  82
  83 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  84         float __f = 0; lowpass(value, frac, ref_store, __f); \
  85         ret = (value) - __f; \
  86 MACRO_END
  87
  88 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  89         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  90         ret = (value) - __f; \
  91 MACRO_END
  92
  93 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  94         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  95         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  96 MACRO_END
  97
  98 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  99         highpass(value.x, frac, ref_store.x, ref_out.x); \
 100         highpass(value.y, frac, ref_store.y, ref_out.y); \
 101 MACRO_END
 102
 103 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 104         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 105         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 106 MACRO_END
 107
 108 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 109         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 110         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 111         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 112 MACRO_END
 113
 114 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 115         highpass(value.x, frac, ref_store.x, ref_out.x); \
 116         highpass(value.y, frac, ref_store.y, ref_out.y); \
 117         highpass(value.z, frac, ref_store.z, ref_out.z); \
 118 MACRO_END
 119
 120 void calc_followmodel_ofs(entity view)
 121 {
 122         if(cl_followmodel_time == time)
 123                 return; // cl_followmodel_ofs already calculated for this frame
 124
 125         float frac;
 126         vector gunorg = '0 0 0';
 127         static vector vel_average;
 128         static vector gunorg_adjustment_highpass;
 129         static vector gunorg_adjustment_lowpass;
 130
 131         vector vel;
 132         if (autocvar_cl_followmodel_velocity_absolute)
 133                 vel = view.velocity;
 134         else
 135         {
 136                 vector forward, right, up;
 137                 MAKE_VECTORS(view_angles, forward, right, up);
 138                 vel.x = view.velocity * forward;
 139                 vel.y = view.velocity * right * -1;
 140                 vel.z = view.velocity * up;
 141         }
 142
 143         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 144         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 145         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 146
 147         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 148         lowpass3(vel, frac, vel_average, gunorg);
 149
 150         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 151
 152         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 153         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 154         frac = avg_factor(autocvar_cl_followmodel_highpass);
 155         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 156         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 157         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 158
 159         if (autocvar_cl_followmodel_velocity_absolute)
 160         {
 161                 vector fixed_gunorg;
 162                 vector forward, right, up;
 163                 MAKE_VECTORS(view_angles, forward, right, up);
 164                 fixed_gunorg.x = gunorg * forward;
 165                 fixed_gunorg.y = gunorg * right * -1;
 166                 fixed_gunorg.z = gunorg * up;
 167                 gunorg = fixed_gunorg;
 168         }
 169
 170         cl_followmodel_ofs = gunorg;
 171         cl_followmodel_time = time;
 172 }
 173
 174 vector leanmodel_ofs(entity view)
 175 {
 176         float frac;
 177         vector gunangles = '0 0 0';
 178         static vector gunangles_prev = '0 0 0';
 179         static vector gunangles_highpass = '0 0 0';
 180         static vector gunangles_adjustment_highpass;
 181         static vector gunangles_adjustment_lowpass;
 182
 183         if (view.csqcmodel_teleported)
 184                 gunangles_prev = view_angles;
 185
 186         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 187         gunangles_highpass += gunangles_prev;
 188         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 189         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 190         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 191         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 192         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 193         gunangles_prev = view_angles;
 194         gunangles_highpass -= gunangles_prev;
 195
 196         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 197         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 198
 199         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 200         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 201         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 202         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 203         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 204
 205         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 206
 207         return gunangles;
 208 }
 209
 210 vector bobmodel_ofs(entity view)
 211 {
 212         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 213         static bool oldonground;
 214         static float hitgroundtime;
 215         if (clonground)
 216         {
 217                 float f = time; // cl.movecmd[0].time
 218                 if (!oldonground)
 219                         hitgroundtime = f;
 220         }
 221         oldonground = clonground;
 222
 223         // calculate for swinging gun model
 224         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 225         vector gunorg = '0 0 0';
 226         static float bobmodel_scale = 0;
 227         static float time_ofs = 0; // makes the effect always restart in the same way
 228         if (clonground)
 229         {
 230                 if (time - hitgroundtime > 0.05)
 231                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 232         }
 233         else
 234                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 235
 236         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 237         if (bobmodel_scale && xyspeed)
 238         {
 239                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 240                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 241                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 242                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 243         }
 244         else
 245                 time_ofs = time;
 246
 247         return gunorg;
 248 }
 249
 250 void viewmodel_animate(entity this)
 251 {
 252         if (autocvar_chase_active) return;
 253         if (STAT(HEALTH) <= 0) return;
 254
 255         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 256
 257         if (autocvar_cl_followmodel)
 258         {
 259                 calc_followmodel_ofs(view);
 260                 this.origin += cl_followmodel_ofs;
 261         }
 262
 263         if (autocvar_cl_leanmodel)
 264                 this.angles += leanmodel_ofs(view);
 265
 266         // vertical view bobbing code
 267         // TODO: cl_bob
 268
 269         // horizontal view bobbing code
 270         // TODO: cl_bob2
 271
 272         // fall bobbing code
 273         // causes the view to swing down and back up when touching the ground
 274         // TODO: cl_bobfall
 275
 276         // gun model bobbing code
 277         if (autocvar_cl_bobmodel)
 278                 this.origin += bobmodel_ofs(view);
 279 }
 280
 281 .vector viewmodel_origin, viewmodel_angles;
 282 .float weapon_nextthink;
 283 .float weapon_eta_last;
 284 .float weapon_switchdelay;
 285
 286 .string name_last;
 287
 288 void viewmodel_draw(entity this)
 289 {
 290         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 291                 return;
 292         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 293         float a = ((autocvar_cl_viewmodel_alpha) ? bound(-1, autocvar_cl_viewmodel_alpha, this.m_alpha) : this.m_alpha);
 294         int wepskin = this.m_skin;
 295         bool invehicle = player_localentnum > maxclients;
 296         if (invehicle) a = -1;
 297         Weapon wep = this.activeweapon;
 298         int c = entcs_GetClientColors(current_player);
 299         vector g = weaponentity_glowmod(wep, NULL, c, this);
 300         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 301         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 302                 | EF_NODEPTHTEST)
 303                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 304         for (entity e = this; e; e = e.weaponchild)
 305         {
 306                 e.drawmask = mask;
 307                 e.alpha = a;
 308                 e.skin = wepskin;
 309                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 310                 e.glowmod = g;
 311                 e.csqcmodel_effects = fx;
 312                 CSQCModel_Effects_Apply(e);
 313         }
 314         if(a >= 0)
 315         {
 316                 string name = wep.mdl;
 317                 string newname = wep.wr_viewmodel(wep, this);
 318                 if(newname)
 319                         name = newname;
 320                 bool swap = name != this.name_last;
 321                 // if (swap)
 322                 {
 323                         this.name_last = name;
 324                         CL_WeaponEntity_SetModel(this, name, swap);
 325                         this.viewmodel_origin = this.origin;
 326                         this.viewmodel_angles = this.angles;
 327                 }
 328                 anim_update(this);
 329                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 330                         anim_set(this, this.anim_idle, true, false, false);
 331         }
 332         float f = 0; // 0..1; 0: fully active
 333         float rate = STAT(WEAPONRATEFACTOR);
 334         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 335         if (eta <= 0) f = this.weapon_eta_last;
 336         else switch (this.state)
 337         {
 338                 case WS_RAISE:
 339                 {
 340                         f = eta / max(eta, this.weapon_switchdelay);
 341                         break;
 342                 }
 343                 case WS_DROP:
 344                 {
 345                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 346                         break;
 347                 }
 348                 case WS_CLEAR:
 349                 {
 350                         f = 1;
 351                         break;
 352                 }
 353         }
 354         this.weapon_eta_last = f;
 355         this.origin = this.viewmodel_origin;
 356         this.angles = this.viewmodel_angles;
 357         this.angles_x = (-90 * f * f);
 358         viewmodel_animate(this);
 359         MUTATOR_CALLHOOK(DrawViewModel, this);
 360         setorigin(this, this.origin);
 361 }
 362
 363 STATIC_INIT(viewmodel) {
 364     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         viewmodels[slot] = new(viewmodel);
 366 }
 367
 368 float showfps_prevfps;
 369 float showfps_prevfps_time;
 370 int showfps_framecounter;
 371
 372 void fpscounter_update()
 373 {
 374         if(!STAT(SHOWFPS))
 375                 return;
 376
 377         float currentTime = gettime(GETTIME_REALTIME);
 378         showfps_framecounter += 1;
 379         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 380         {
 381                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
 382                 showfps_framecounter = 0;
 383                 showfps_prevfps_time = currentTime;
 384
 385                 int channel = MSG_C2S;
 386                 WriteHeader(channel, fpsreport);
 387                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
 388         }
 389 }
 390
 391 STATIC_INIT(fpscounter_init)
 392 {
 393         float currentTime = gettime(GETTIME_REALTIME);
 394         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 395 }
 396
 397 float drawtime;
 398 float avgspeed;
 399 vector GetCurrentFov(float fov)
 400 {
 401         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 402         float velocityzoom, curspeed;
 403         vector v;
 404
 405         zoomsensitivity = autocvar_cl_zoomsensitivity;
 406         zoomfactor = autocvar_cl_zoomfactor;
 407         if(zoomfactor < 1 || zoomfactor > 30)
 408                 zoomfactor = 2.5;
 409         zoomspeed = autocvar_cl_zoomspeed;
 410         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
 411                 zoomspeed = 3.5;
 412
 413         zoomdir = button_zoom;
 414
 415         if(hud == HUD_NORMAL && !spectatee_status)
 416         {
 417                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 418                 {
 419                         entity wepent = viewmodels[slot];
 420                         if(wepent.switchweapon != wepent.activeweapon)
 421                                 continue;
 422                         Weapon wep = wepent.activeweapon;
 423                         if(wep != WEP_Null && wep.wr_zoomdir)
 424                         {
 425                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 426                                 zoomdir += do_zoom;
 427                         }
 428                 }
 429         }
 430         if(spectatee_status > 0 || isdemo())
 431         {
 432                 if(spectatorbutton_zoom)
 433                 {
 434                         if(zoomdir)
 435                                 zoomdir = 0;
 436                         else
 437                                 zoomdir = 1;
 438                 }
 439                 // fteqcc failed twice here already, don't optimize this
 440         }
 441
 442         if(zoomdir) { zoomin_effect = 0; }
 443
 444         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 445         {
 446                 current_viewzoom = 1;
 447         }
 448         else if (camera_active)
 449         {
 450                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 451         }
 452         else if(autocvar_cl_spawnzoom && zoomin_effect)
 453         {
 454                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 455
 456                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 457                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 458                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 459         }
 460         else
 461         {
 462                 if(zoomspeed < 0) // instant zoom
 463                 {
 464                         if(zoomdir)
 465                                 current_viewzoom = 1 / zoomfactor;
 466                         else
 467                                 current_viewzoom = 1;
 468                 }
 469                 else
 470                 {
 471                         if(zoomdir)
 472                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 473                         else
 474                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 475                 }
 476         }
 477
 478         if(almost_equals(current_viewzoom, 1))
 479                 current_zoomfraction = 0;
 480         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 481                 current_zoomfraction = 1;
 482         else
 483                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 484
 485         if(zoomsensitivity < 1)
 486                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 487         else
 488                 setsensitivityscale(1);
 489
 490         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 491         {
 492                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
 493                         curspeed = 0;
 494                 else
 495                 {
 496                         vector forward, right, up;
 497                         MAKE_VECTORS(view_angles, forward, right, up);
 498                         v = pmove_vel;
 499                         if(csqcplayer)
 500                                 v = csqcplayer.velocity;
 501
 502                         switch(autocvar_cl_velocityzoom_type)
 503                         {
 504                                 case 3: curspeed = max(0, forward * v); break;
 505                                 case 2: curspeed = (forward * v); break;
 506                                 case 1: default: curspeed = vlen(v); break;
 507                         }
 508                 }
 509
 510                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 511                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 512                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 513
 514                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 515         }
 516         else
 517                 velocityzoom = 1;
 518
 519         float frustumx, frustumy, fovx, fovy;
 520         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 521         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 522         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 523         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 524
 525         return '1 0 0' * fovx + '0 1 0' * fovy;
 526 }
 527
 528 vector GetViewLocationFOV(float fov)
 529 {
 530         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 531         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 532         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 533         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 534         return '1 0 0' * fovx + '0 1 0' * fovy;
 535 }
 536
 537 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 538 {
 539         float fovx, fovy;
 540         float width = (ov_worldmax.x - ov_worldmin.x);
 541         float height = (ov_worldmax.y - ov_worldmin.y);
 542         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 543         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 544         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 545         return '1 0 0' * fovx + '0 1 0' * fovy;
 546 }
 547
 548 // this function must match W_SetupShot!
 549 float zoomscript_caught;
 550
 551 bool minigame_wasactive;
 552
 553 vector wcross_origin;
 554 float wcross_scale_prev, wcross_alpha_prev;
 555 vector wcross_color_prev;
 556 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 557 vector wcross_color_goal_prev;
 558 float wcross_changedonetime;
 559
 560 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 561 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 562 float wcross_name_changestarttime, wcross_name_changedonetime;
 563 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 564
 565 float wcross_ring_prev;
 566
 567 entity trueaim;
 568 entity trueaim_rifle;
 569
 570 const float SHOTTYPE_HITTEAM = 1;
 571 const float SHOTTYPE_HITOBSTRUCTION = 2;
 572 const float SHOTTYPE_HITWORLD = 3;
 573 const float SHOTTYPE_HITENEMY = 4;
 574
 575 void TrueAim_Init()
 576 {
 577         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 578         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 579 }
 580
 581 float EnemyHitCheck()
 582 {
 583         float t, n;
 584         wcross_origin = project_3d_to_2d(trace_endpos);
 585         wcross_origin.z = 0;
 586         if(trace_ent)
 587                 n = trace_ent.entnum;
 588         else
 589                 n = trace_networkentity;
 590         if(n < 1)
 591                 return SHOTTYPE_HITWORLD;
 592         if(n > maxclients)
 593                 return SHOTTYPE_HITWORLD;
 594         t = entcs_GetTeam(n - 1);
 595         if(teamplay)
 596                 if(t == myteam)
 597                         return SHOTTYPE_HITTEAM;
 598         if(t == NUM_SPECTATOR)
 599                 return SHOTTYPE_HITWORLD;
 600         return SHOTTYPE_HITENEMY;
 601 }
 602
 603 float TrueAimCheck(entity wepent)
 604 {
 605         if(wepent.activeweapon.spawnflags & WEP_FLAG_NOTRUEAIM)
 606                 return SHOTTYPE_HITWORLD;
 607
 608         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 609         vector vecs, trueaimpoint, w_shotorg;
 610         vector mi, ma, dv;
 611         float shottype;
 612         entity ta;
 613         float mv;
 614
 615         mi = ma = '0 0 0';
 616         ta = trueaim;
 617         mv = MOVE_NOMONSTERS;
 618
 619         switch(wepent.activeweapon) // WEAPONTODO
 620         {
 621                 case WEP_VORTEX:
 622                 case WEP_OVERKILL_NEX:
 623                 case WEP_VAPORIZER:
 624                         mv = MOVE_NORMAL;
 625                         break;
 626                 case WEP_RIFLE:
 627                         ta = trueaim_rifle;
 628                         mv = MOVE_NORMAL;
 629                         if(zoomscript_caught)
 630                         {
 631                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 632                                 return EnemyHitCheck();
 633                         }
 634                         break;
 635                 case WEP_DEVASTATOR: // projectile has a size!
 636                         mi = '-3 -3 -3';
 637                         ma = '3 3 3';
 638                         break;
 639                 case WEP_FIREBALL: // projectile has a size!
 640                         mi = '-16 -16 -16';
 641                         ma = '16 16 16';
 642                         break;
 643                 case WEP_SEEKER: // projectile has a size!
 644                         mi = '-2 -2 -2';
 645                         ma = '2 2 2';
 646                         break;
 647                 case WEP_ELECTRO: // projectile has a size!
 648                         mi = '0 0 -3';
 649                         ma = '0 0 -3';
 650                         break;
 651         }
 652
 653         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 654
 655         vecs = decompressShotOrigin(STAT(SHOTORG));
 656
 657         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 658         trueaimpoint = trace_endpos;
 659
 660         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 661                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 662
 663         if(vecs.x > 0)
 664                 vecs.y = -vecs.y;
 665         else
 666                 vecs = '0 0 0';
 667
 668         dv = view_right * vecs.y + view_up * vecs.z;
 669         w_shotorg = traceorigin + dv;
 670
 671         // now move the vecs forward as much as requested if possible
 672         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 673         w_shotorg = trace_endpos - view_forward * nudge;
 674
 675         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 676         shottype = EnemyHitCheck();
 677         if(shottype != SHOTTYPE_HITWORLD)
 678                 return shottype;
 679
 680 #if 0
 681         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 682         // or rather, I know why, but see no fix
 683         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 684                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 685                 return SHOTTYPE_HITOBSTRUCTION;
 686 #endif
 687
 688         return SHOTTYPE_HITWORLD;
 689 }
 690
 691 float camera_mode;
 692 const float CAMERA_FREE = 1;
 693 const float CAMERA_CHASE = 2;
 694 float reticle_type;
 695 string NextFrameCommand;
 696
 697 vector freeze_org, freeze_ang;
 698 entity nightvision_noise, nightvision_noise2;
 699
 700 const float MAX_TIME_DIFF = 5;
 701 float pickup_crosshair_time, pickup_crosshair_size;
 702 float hitindication_crosshair_size;
 703 float use_vortex_chargepool;
 704
 705 float myhealth, myhealth_prev;
 706 float myhealth_flash;
 707
 708 float old_blurradius, old_bluralpha;
 709 float old_sharpen_intensity;
 710
 711 vector myhealth_gentlergb;
 712
 713 float contentavgalpha, liquidalpha_prev;
 714 vector liquidcolor_prev;
 715
 716 float eventchase_current_distance;
 717 float eventchase_running;
 718 int WantEventchase(entity this, bool want_vehiclechase)
 719 {
 720         if(autocvar_cl_orthoview)
 721                 return 0;
 722         if(STAT(GAME_STOPPED) || intermission)
 723                 return 1;
 724         if(this.viewloc)
 725                 return 1;
 726         if(spectatee_status >= 0)
 727         {
 728                 if(want_vehiclechase)
 729                         return 1;
 730                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 731                         return 1;
 732                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 733                         return 1;
 734                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 735                 {
 736                         if(autocvar_cl_eventchase_death == 2)
 737                         {
 738                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 739                                 if(this.velocity == '0 0 0' || eventchase_running)
 740                                         return 1;
 741                         }
 742                         else return 1;
 743                 }
 744                 if (spectatee_status > 0 && autocvar_cl_eventchase_spectated_change)
 745                 {
 746                         if (time <= spectatee_status_changed_time + min(3, autocvar_cl_eventchase_spectated_change_time))
 747                                 return 1;
 748                         else if (eventchase_running)
 749                                 return -1; // disable chase_active while eventchase is still enabled so to avoid a glicth
 750                 }
 751         }
 752         return 0;
 753 }
 754
 755 void HUD_Crosshair_Vehicle(entity this)
 756 {
 757         if(hud != HUD_BUMBLEBEE_GUN)
 758         {
 759                 Vehicle info = Vehicles_from(hud);
 760                 info.vr_crosshair(info, this);
 761         }
 762 }
 763
 764 vector damage_blurpostprocess, content_blurpostprocess;
 765
 766 float unaccounted_damage = 0;
 767 void UpdateDamage()
 768 {
 769         // accumulate damage with each stat update
 770         static float damage_total_prev = 0;
 771         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 772         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 773         damage_total_prev = damage_total;
 774
 775         static float damage_dealt_time_prev = 0;
 776         float damage_dealt_time = STAT(HIT_TIME);
 777         if (damage_dealt_time != damage_dealt_time_prev)
 778         {
 779                 unaccounted_damage += unaccounted_damage_new;
 780                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 781         }
 782         damage_dealt_time_prev = damage_dealt_time;
 783
 784         // prevent hitsound when switching spectatee
 785         static float spectatee_status_prev = 0;
 786         if (spectatee_status != spectatee_status_prev)
 787                 unaccounted_damage = 0;
 788         spectatee_status_prev = spectatee_status;
 789 }
 790
 791 void HitSound()
 792 {
 793         // varying sound pitch
 794
 795         bool have_arc = false;
 796         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 797         {
 798                 entity wepent = viewmodels[slot];
 799
 800                 if(wepent.activeweapon == WEP_ARC)
 801                         have_arc = true;
 802         }
 803
 804         static float hitsound_time_prev = 0;
 805         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 806         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 807         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 808         {
 809                 if (autocvar_cl_hitsound && unaccounted_damage)
 810                 {
 811                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 812                         float a = autocvar_cl_hitsound_max_pitch;
 813                         float b = autocvar_cl_hitsound_min_pitch;
 814                         float c = autocvar_cl_hitsound_nom_damage;
 815                         float d = unaccounted_damage;
 816                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 817
 818                         // if sound variation is disabled, set pitch_shift to 1
 819                         if (autocvar_cl_hitsound == 1)
 820                                 pitch_shift = 1;
 821
 822                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 823                         if (autocvar_cl_hitsound == 3)
 824                         {
 825                                 float mirror_value = (a-b)/2 + b;
 826                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 827                         }
 828
 829                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 830
 831                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 832                         // todo: normalize sound pressure levels? seems unnecessary
 833
 834                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 835                 }
 836                 unaccounted_damage = 0;
 837                 hitsound_time_prev = time;
 838         }
 839
 840         static float typehit_time_prev = 0;
 841         float typehit_time = STAT(TYPEHIT_TIME);
 842         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 843         {
 844                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 845                 typehit_time_prev = typehit_time;
 846         }
 847
 848         static float kill_time_prev = 0;
 849         float kill_time = STAT(KILL_TIME);
 850         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 851         {
 852                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 853                 kill_time_prev = kill_time;
 854         }
 855 }
 856
 857 vector crosshair_getcolor(entity this, float health_stat)
 858 {
 859         static float rainbow_last_flicker;
 860         static vector rainbow_prev_color;
 861         vector wcross_color = '0 0 0';
 862         switch(autocvar_crosshair_color_special)
 863         {
 864                 case 1: // crosshair_color_per_weapon
 865                 {
 866                         if(this != WEP_Null && hud == HUD_NORMAL)
 867                         {
 868                                 wcross_color = this.wpcolor;
 869                                 break;
 870                         }
 871                         else { goto normalcolor; }
 872                 }
 873
 874                 case 2: // crosshair_color_by_health
 875                 {
 876                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 877                         float hp = floor(v.x + 1);
 878
 879                         //x = red
 880                         //y = green
 881                         //z = blue
 882
 883                         wcross_color.z = 0;
 884
 885                         if(hp > 200)
 886                         {
 887                                 wcross_color.x = 0;
 888                                 wcross_color.y = 1;
 889                         }
 890                         else if(hp > 150)
 891                         {
 892                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 893                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 894                         }
 895                         else if(hp > 100)
 896                         {
 897                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 898                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 899                                 wcross_color.z = 1 - (hp-100)*0.02;
 900                         }
 901                         else if(hp > 50)
 902                         {
 903                                 wcross_color.x = 1;
 904                                 wcross_color.y = 1;
 905                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 906                         }
 907                         else if(hp > 20)
 908                         {
 909                                 wcross_color.x = 1;
 910                                 wcross_color.y = (hp-20)*90/27/100;
 911                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 912                         }
 913                         else
 914                         {
 915                                 wcross_color.x = 1;
 916                                 wcross_color.y = 0;
 917                         }
 918                         break;
 919                 }
 920
 921                 case 3: // crosshair_color_rainbow
 922                 {
 923                         if(time >= rainbow_last_flicker)
 924                         {
 925                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 926                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 927                         }
 928                         wcross_color = rainbow_prev_color;
 929                         break;
 930                 }
 931 LABEL(normalcolor)
 932                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 933         }
 934
 935         return wcross_color;
 936 }
 937
 938 void HUD_Crosshair(entity this)
 939 {
 940         float f, i, j;
 941         vector v;
 942         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
 943                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 944                 !HUD_MinigameMenu_IsOpened() )
 945         {
 946                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 947                         return;
 948
 949                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 950                         return;
 951
 952                 if (hud != HUD_NORMAL)
 953                 {
 954                         HUD_Crosshair_Vehicle(this);
 955                         return;
 956                 }
 957
 958                 string wcross_style;
 959                 float wcross_alpha, wcross_resolution;
 960                 wcross_style = autocvar_crosshair;
 961                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
 962                         wcross_style = autocvar_crosshair_2d;
 963                 if (wcross_style == "0")
 964                         return;
 965                 wcross_resolution = autocvar_crosshair_size;
 966                 if (wcross_resolution == 0)
 967                         return;
 968                 wcross_alpha = autocvar_crosshair_alpha;
 969                 if (wcross_alpha == 0)
 970                         return;
 971
 972                 // TrueAim check
 973                 float shottype;
 974
 975                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 976                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
 977                         wcross_origin = viewloc_mousepos;
 978                 else if(autocvar_chase_active > 0 && autocvar_crosshair_chase)
 979                 {
 980                         vector player_org = ((csqcplayer) ? csqcplayer.origin + csqcplayer.view_ofs : view_origin);
 981                         if(csqcplayer && crosshair_chase_playeralpha && crosshair_chase_playeralpha < 1)
 982                         {
 983                                 traceline(view_origin, view_origin + max_shot_distance * view_forward, MOVE_NORMAL, NULL);
 984                                 float myalpha = (!csqcplayer.m_alpha) ? 1 : csqcplayer.m_alpha;
 985                                 if(trace_ent == csqcplayer && STAT(HEALTH) > 0)
 986                                         csqcplayer.alpha = min(crosshair_chase_playeralpha, myalpha);
 987                                 else
 988                                         csqcplayer.alpha = csqcplayer.m_alpha;
 989                         }
 990                         traceline(player_org, player_org + max_shot_distance * view_forward, MOVE_WORLDONLY, NULL);
 991                         wcross_origin = project_3d_to_2d(trace_endpos);
 992                 }
 993                 else
 994                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
 995                 wcross_origin.z = 0;
 996                 if(autocvar_crosshair_hittest)
 997                 {
 998                         vector wcross_oldorigin;
 999                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1000                         wcross_oldorigin = wcross_origin;
1001                         shottype = TrueAimCheck(thiswep);
1002                         if(shottype == SHOTTYPE_HITWORLD)
1003                         {
1004                                 v = wcross_origin - wcross_oldorigin;
1005                                 v.x /= vid_conwidth;
1006                                 v.y /= vid_conheight;
1007                                 if(vdist(v, >, 0.01))
1008                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1009                         }
1010                         if(!autocvar_crosshair_hittest_showimpact)
1011                                 wcross_origin = wcross_oldorigin;
1012                 }
1013                 else
1014                         shottype = SHOTTYPE_HITWORLD;
1015
1016                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1017                 string wcross_name = "";
1018                 float wcross_scale, wcross_blur;
1019
1020         entity e = WEP_Null;
1021                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1022                 {
1023                         entity wepent = viewmodels[0]; // TODO: unhardcode
1024                         e = wepent.switchingweapon;
1025                         if(e)
1026                         {
1027                                 if(autocvar_crosshair_per_weapon)
1028                                 {
1029                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1030                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1031                                         //if (wcross_resolution == 0)
1032                                                 //return;
1033
1034                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1035                                         wcross_resolution *= e.w_crosshair_size;
1036                                         wcross_name = e.w_crosshair;
1037                                 }
1038                         }
1039                 }
1040
1041                 if(wcross_name == "")
1042                         wcross_name = strcat("gfx/crosshair", wcross_style);
1043
1044                 // MAIN CROSSHAIR COLOR DECISION
1045                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1046
1047                 if(autocvar_crosshair_effect_scalefade)
1048                 {
1049                         wcross_scale = wcross_resolution;
1050                         wcross_resolution = 1;
1051                 }
1052                 else
1053                 {
1054                         wcross_scale = 1;
1055                 }
1056
1057                 if(autocvar_crosshair_pickup)
1058                 {
1059                         float stat_pickup_time = STAT(LAST_PICKUP);
1060
1061                         if(pickup_crosshair_time < stat_pickup_time)
1062                         {
1063                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1064                                         pickup_crosshair_size = 1;
1065
1066                                 pickup_crosshair_time = stat_pickup_time;
1067                         }
1068
1069                         if(pickup_crosshair_size > 0)
1070                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1071                         else
1072                                 pickup_crosshair_size = 0;
1073
1074                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1075                 }
1076
1077                 // todo: make crosshair hit indication dependent on damage dealt
1078                 if(autocvar_crosshair_hitindication)
1079                 {
1080                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1081
1082                         if(unaccounted_damage)
1083                         {
1084                                 hitindication_crosshair_size = 1;
1085                         }
1086
1087                         if(hitindication_crosshair_size > 0)
1088                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1089                         else
1090                                 hitindication_crosshair_size = 0;
1091
1092                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1093                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1094                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1095                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1096                 }
1097
1098                 // no effects needed for targeting enemies, this can't possibly span all valid targets!
1099                 // just show for teammates to give a sign that they're an invalid target
1100                 //if(shottype == SHOTTYPE_HITENEMY)
1101                         //wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1102                 if(shottype == SHOTTYPE_HITTEAM)
1103                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1104
1105                 f = fabs(autocvar_crosshair_effect_time);
1106                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1107                 {
1108                         wcross_changedonetime = time + f;
1109                 }
1110                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1111                 {
1112                         wcross_name_changestarttime = time;
1113                         wcross_name_changedonetime = time + f;
1114                         if(wcross_name_goal_prev_prev)
1115                                 strunzone(wcross_name_goal_prev_prev);
1116                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1117                         wcross_name_goal_prev = strzone(wcross_name);
1118                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1119                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1120                         wcross_resolution_goal_prev = wcross_resolution;
1121                 }
1122
1123                 wcross_scale_goal_prev = wcross_scale;
1124                 wcross_alpha_goal_prev = wcross_alpha;
1125                 wcross_color_goal_prev = wcross_color;
1126
1127                 if(shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active)
1128                 {
1129                         wcross_blur = 1;
1130                         wcross_alpha *= 0.75;
1131                 }
1132                 else
1133                         wcross_blur = 0;
1134
1135                 // *_prev is at time-frametime
1136                 // * is at wcross_changedonetime+f
1137                 // what do we have at time?
1138                 if(time < wcross_changedonetime)
1139                 {
1140                         f = frametime / (wcross_changedonetime - time + frametime);
1141                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1142                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1143                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1144                 }
1145
1146                 wcross_scale_prev = wcross_scale;
1147                 wcross_alpha_prev = wcross_alpha;
1148                 wcross_color_prev = wcross_color;
1149
1150                 MUTATOR_CALLHOOK(UpdateCrosshair);
1151
1152                 wcross_scale *= 1 - autocvar__menu_alpha;
1153                 wcross_alpha *= 1 - autocvar__menu_alpha;
1154                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1155
1156                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1157                 {
1158                         // crosshair rings for weapon stats
1159                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1160                         {
1161                                 // declarations and stats
1162                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1163                                 string ring_image = string_null, ring_inner_image = string_null;
1164                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1165
1166                                 ring_scale = autocvar_crosshair_ring_size;
1167
1168                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1169
1170                                 int weapon_clipload = wepent.clip_load;
1171                                 int weapon_clipsize = wepent.clip_size;
1172
1173                                 float arc_heat = wepent.arc_heat_percent;
1174                                 float vcharge = wepent.vortex_charge;
1175                                 float vchargepool = wepent.vortex_chargepool_ammo;
1176                                 float oknex_charge_ = wepent.oknex_charge;
1177                                 float oknex_chargepool_ = wepent.oknex_chargepool_ammo;
1178
1179                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1180                                         vortex_charge_movingavg = vcharge;
1181
1182                                 // handle the values
1183                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1184                                 {
1185                                         if (vchargepool || use_vortex_chargepool) {
1186                                                 use_vortex_chargepool = 1;
1187                                                 ring_inner_value = vchargepool;
1188                                         } else {
1189                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1190                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1191                                         }
1192
1193                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1194                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1195                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1196
1197                                         // draw the outer ring to show the current charge of the weapon
1198                                         ring_value = vcharge;
1199                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1200                                         ring_rgb = wcross_color;
1201                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1202                                 }
1203                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_NEX) && oknex_charge_ && autocvar_crosshair_ring_vortex)
1204                                 {
1205                                         if (oknex_chargepool_ || use_vortex_chargepool) {
1206                                                 use_vortex_chargepool = 1;
1207                                                 ring_inner_value = oknex_chargepool_;
1208                                         } else {
1209                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * oknex_charge_;
1210                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (oknex_charge_ - vortex_charge_movingavg), 1);
1211                                         }
1212
1213                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1214                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1215                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1216
1217                                         // draw the outer ring to show the current charge of the weapon
1218                                         ring_value = oknex_charge_;
1219                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1220                                         ring_rgb = wcross_color;
1221                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1222                                 }
1223                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1224                                 {
1225                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1226                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1227                                         ring_rgb = wcross_color;
1228                                         ring_image = "gfx/crosshair_ring.tga";
1229                                 }
1230                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1231                                 {
1232                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1233                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1234                                         ring_rgb = wcross_color;
1235                                         ring_image = "gfx/crosshair_ring.tga";
1236                                 }
1237                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1238                                 {
1239                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1240                                         ring_scale = autocvar_crosshair_ring_reload_size;
1241                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1242                                         ring_rgb = wcross_color;
1243
1244                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1245                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1246                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1247                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1248                                         else
1249                                                 ring_image = "gfx/crosshair_ring.tga";
1250                                 }
1251                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1252                                 {
1253                                         ring_value = arc_heat;
1254                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1255                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1256                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1257                                         ring_image = "gfx/crosshair_ring.tga";
1258                                 }
1259
1260                                 // if in weapon switch animation, fade ring out/in
1261                                 if(autocvar_crosshair_effect_time > 0)
1262                                 {
1263                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1264                                         if (f >= 1)
1265                                         {
1266                                                 wcross_ring_prev = ((ring_image) ? true : false);
1267                                         }
1268
1269                                         if(wcross_ring_prev)
1270                                         {
1271                                                 if(f < 1)
1272                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1273                                         }
1274                                         else
1275                                         {
1276                                                 if(f < 1)
1277                                                         ring_alpha *= bound(0, f, 1);
1278                                         }
1279                                 }
1280
1281                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1282                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1283
1284                                 if (ring_value)
1285                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1286                         }
1287
1288 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1289                         MACRO_BEGIN \
1290                                 vector scaled_sz = sz * wcross_size; \
1291                                 if(wcross_blur > 0) \
1292                                 { \
1293                                         for(i = -2; i <= 2; ++i) \
1294                                         for(j = -2; j <= 2; ++j) \
1295                                         M(i,j,sz,scaled_sz,wcross_name,wcross_alpha*0.04); \
1296                                 } \
1297                                 else \
1298                                 { \
1299                                         M(0,0,sz,scaled_sz,wcross_name,wcross_alpha); \
1300                                 } \
1301                         MACRO_END
1302
1303 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,scaled_sz,wcross_name,wcross_alpha) \
1304                         drawpic(wcross_origin - ('0.5 0 0' * (scaled_sz.x + i * wcross_blur) + '0 0.5 0' * (scaled_sz.y + j * wcross_blur)), wcross_name, scaled_sz, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1305
1306 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1307                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1308
1309                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1310                         {
1311                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1312                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1313                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1314                                 f = 1 - f;
1315                         }
1316                         else
1317                         {
1318                                 f = 1;
1319                         }
1320                         wcross_name_alpha_goal_prev = f;
1321
1322                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1323                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1324
1325                         if(autocvar_crosshair_dot)
1326                         {
1327                                 vector wcross_color_old;
1328                                 wcross_color_old = wcross_color;
1329
1330                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1331                                         wcross_color = stov(autocvar_crosshair_dot_color);
1332
1333                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1334                                 // FIXME why don't we use wcross_alpha here?
1335                                 wcross_color = wcross_color_old;
1336                         }
1337                 }
1338         }
1339         else
1340         {
1341                 wcross_scale_prev = 0;
1342                 wcross_alpha_prev = 0;
1343                 wcross_scale_goal_prev = 0;
1344                 wcross_alpha_goal_prev = 0;
1345                 wcross_changedonetime = 0;
1346                 strfree(wcross_name_goal_prev);
1347                 strfree(wcross_name_goal_prev_prev);
1348                 wcross_name_changestarttime = 0;
1349                 wcross_name_changedonetime = 0;
1350                 wcross_name_alpha_goal_prev = 0;
1351                 wcross_name_alpha_goal_prev_prev = 0;
1352                 wcross_resolution_goal_prev = 0;
1353                 wcross_resolution_goal_prev_prev = 0;
1354         }
1355 }
1356
1357 const int MAX_SPECIALCOMMAND = 15;
1358 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1359 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1360 const float SPECIALCOMMAND_SPEED = 150;
1361 const float SPECIALCOMMAND_TURNSPEED = 2;
1362 const float SPECIALCOMMAND_SIZE = 0.025;
1363 const float SPECIALCOMMAND_CHANCE = 0.35;
1364 float sc_spawntime, sc_changetime;
1365 vector sc_color = '1 1 1';
1366 void SpecialCommand()
1367 {
1368         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1369                 return;
1370
1371         if(time >= sc_changetime)
1372         {
1373                 sc_changetime = time + 1;
1374                 sc_color = randomvec() * 1.5;
1375                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1376                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1377                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1378         }
1379         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1380
1381         if(!precache_pic("gfx/smile"))
1382                 return; // damn party poopers
1383
1384         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1385         {
1386                 vector slot = specialcommand_slots[j];
1387                 if(slot.y)
1388                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1389                 //if(slot.z)
1390                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1391                 if(slot.y >= vid_conheight)
1392                         slot = '0 0 0';
1393
1394                 if(slot == '0 0 0')
1395                 {
1396                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1397                         {
1398                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1399                                 slot.y = 1; // start it off 0 so we can use it
1400                                 slot.z = floor(random() * Weapons_MAX);
1401                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1402                                 vector newcolor = randomvec() * 2;
1403                                 newcolor.x = bound(0.4, newcolor.x, 1);
1404                                 newcolor.y = bound(0.4, newcolor.y, 1);
1405                                 newcolor.z = bound(0.4, newcolor.z, 1);
1406                                 specialcommand_colors[j] = newcolor;
1407                         }
1408                 }
1409                 else
1410                 {
1411                         vector splash_size = '0 0 0';
1412                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1413                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1414                         entity wep = Weapons_from(slot.z);
1415                         if(wep == WEP_Null)
1416                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1417                         else
1418                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1419                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1420                 }
1421
1422                 specialcommand_slots[j] = slot;
1423         }
1424 }
1425
1426 void HUD_Draw(entity this)
1427 {
1428         // if we don't know gametype and scores yet avoid drawing the scoreboard
1429         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1430         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1431         // cl_deathscoreboard would show the scoreboard and so on
1432         if(!gametype)
1433                 return;
1434
1435         Hud_Dynamic_Frame();
1436
1437         if(!intermission)
1438         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1439         {
1440                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1441         }
1442         else if(STAT(FROZEN))
1443         {
1444                 vector col = '0.25 0.90 1';
1445                 if(STAT(REVIVE_PROGRESS))
1446                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1447                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1448         }
1449
1450         HUD_Scale_Enable();
1451         if(!intermission)
1452         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1453         {
1454                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1455                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1456                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1457         }
1458         else if(STAT(CAPTURE_PROGRESS))
1459         {
1460                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1461                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1462         }
1463         else if(STAT(REVIVE_PROGRESS))
1464         {
1465                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1466                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1467         }
1468         HUD_Scale_Disable();
1469
1470         if(autocvar_r_letterbox == 0)
1471                 if(autocvar_viewsize < 120)
1472                 {
1473                         if(!(ISGAMETYPE(RACE) || ISGAMETYPE(CTS)))
1474                                 Accuracy_LoadLevels();
1475
1476                         HUD_Main();
1477                         HUD_Scale_Disable();
1478                 }
1479
1480         // crosshair goes VERY LAST
1481         SpecialCommand();
1482         UpdateDamage();
1483         HUD_Crosshair(this);
1484         HitSound();
1485 }
1486
1487 void ViewLocation_Mouse()
1488 {
1489         if(spectatee_status)
1490                 return; // don't draw it as spectator!
1491
1492         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1493         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1494         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1495
1496         //float cursor_alpha = 1 - autocvar__menu_alpha;
1497         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1498 }
1499
1500 void HUD_Cursor_Show()
1501 {
1502         float cursor_alpha = 1 - autocvar__menu_alpha;
1503         if(cursor_type == CURSOR_NORMAL)
1504                 draw_cursor_normal(mousepos, '1 1 1', cursor_alpha);
1505         else if(cursor_type == CURSOR_MOVE)
1506                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1507         else if(cursor_type == CURSOR_RESIZE)
1508                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize", '1 1 1', cursor_alpha);
1509         else if(cursor_type == CURSOR_RESIZE2)
1510                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize2", '1 1 1', cursor_alpha);
1511 }
1512
1513 void HUD_Mouse(entity player)
1514 {
1515         if(autocvar__menu_alpha == 1)
1516                 return;
1517
1518         if(!cursor_active)
1519         {
1520                 if(player.viewloc && (player.viewloc.spawnflags & VIEWLOC_FREEAIM))
1521                         ViewLocation_Mouse(); // NOTE: doesn't use cursormode
1522                 return;
1523         }
1524
1525         if (cursor_active == -1) // starting to display the cursor
1526         {
1527                 // since HUD_Mouse is called by CSQC_UpdateView before CSQC_InputEvent,
1528                 // in the first frame mousepos is the mouse position of the last time
1529                 // the cursor was displayed, thus we ignore it to avoid a glictch
1530                 cursor_active = 1;
1531                 return;
1532         }
1533
1534         if(!autocvar_hud_cursormode)
1535                 update_mousepos();
1536
1537         if(autocvar__hud_configure)
1538                 HUD_Panel_Mouse();
1539         else
1540         {
1541                 if (HUD_MinigameMenu_IsOpened())
1542                         HUD_Minigame_Mouse();
1543                 if (QuickMenu_IsOpened())
1544                         QuickMenu_Mouse();
1545                 if (HUD_Radar_Clickable())
1546                         HUD_Radar_Mouse();
1547         }
1548
1549         prevMouseClicked = mouseClicked;
1550
1551         HUD_Cursor_Show();
1552 }
1553
1554 bool ov_enabled;
1555 float oldr_nearclip;
1556 float oldr_farclip_base;
1557 float oldr_farclip_world;
1558 float oldr_novis;
1559 float oldr_useportalculling;
1560 float oldr_useinfinitefarclip;
1561
1562 float prev_myteam;
1563 int lasthud;
1564 float vh_notice_time;
1565 void CSQC_UpdateView(entity this, float w, float h)
1566 {
1567         TC(int, w); TC(int, h);
1568         entity e;
1569         float fov;
1570         float f;
1571         vector vf_size, vf_min;
1572         float a;
1573
1574         execute_next_frame();
1575
1576         ++framecount;
1577
1578         stats_get();
1579         hud = STAT(HUD);
1580
1581         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1582                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1583
1584         lasthud = hud;
1585
1586         ReplicateVars(false);
1587         if (ReplicateVars_NOT_SENDING())
1588                 ReplicateVars_DELAY(0.8 + random() * 0.4); // no need to check cvars every frame
1589
1590         HUD_Scale_Disable();
1591
1592         if(autocvar__hud_showbinds_reload) // menu can set this one
1593         {
1594                 db_close(binddb);
1595                 binddb = db_create();
1596                 cvar_set("_hud_showbinds_reload", "0");
1597         }
1598
1599         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1600                 view_quality = getproperty(VF_MINFPS_QUALITY);
1601         else
1602                 view_quality = 1;
1603
1604         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1605         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1606
1607         vf_size = getpropertyvec(VF_SIZE);
1608         vf_min = getpropertyvec(VF_MIN);
1609         vid_width = vf_size.x;
1610         vid_height = vf_size.y;
1611
1612         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1613         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1614
1615         WaypointSprite_Load();
1616
1617         CSQCPlayer_SetCamera();
1618
1619         if(player_localentnum <= maxclients) // is it a client?
1620                 current_player = player_localentnum - 1;
1621         else // then player_localentnum is the vehicle I'm driving
1622                 current_player = player_localnum;
1623         myteam = entcs_GetTeam(current_player);
1624
1625         if(myteam != prev_myteam)
1626         {
1627                 myteamcolors = colormapPaletteColor(myteam, 1);
1628                 FOREACH(hud_panels, true, it.update_time = time);
1629                 prev_myteam = myteam;
1630         }
1631
1632         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1633
1634         float is_dead = (STAT(HEALTH) <= 0);
1635
1636         // FIXME do we need this hack?
1637         if(isdemo())
1638         {
1639                 // in demos, input_buttons do not work
1640                 button_zoom = (autocvar__togglezoom == "-");
1641         }
1642         else if(button_zoom
1643                 && autocvar_cl_unpress_zoom_on_death
1644                 && (spectatee_status >= 0)
1645                 && (is_dead || intermission))
1646         {
1647                 // no zoom while dead or in intermission please
1648                 localcmd("-zoom\n");
1649                 button_zoom = false;
1650         }
1651
1652         // abused multiple places below
1653         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1654         if(!local_player)
1655                 local_player = this; // fall back!
1656
1657         // event chase camera
1658         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1659         {
1660                 if(STAT(CAMERA_SPECTATOR))
1661                 {
1662                         if(spectatee_status > 0)
1663                         {
1664                                 if(!autocvar_chase_active)
1665                                 {
1666                                         cvar_set("chase_active", "-2");
1667                                         goto skip_eventchase_death;
1668                                 }
1669                         }
1670                         else if(autocvar_chase_active == -2)
1671                                 cvar_set("chase_active", "0");
1672
1673                         if(autocvar_chase_active == -2)
1674                                 goto skip_eventchase_death;
1675                 }
1676                 else if(autocvar_chase_active == -2)
1677                         cvar_set("chase_active", "0");
1678
1679                 bool vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1680
1681                 float vehicle_viewdist = 0;
1682                 vector vehicle_viewofs = '0 0 0';
1683
1684                 if(vehicle_chase)
1685                 {
1686                         if(hud != HUD_BUMBLEBEE_GUN)
1687                         {
1688                                 Vehicle info = Vehicles_from(hud);
1689                                 vehicle_viewdist = info.height;
1690                                 vehicle_viewofs = info.view_ofs;
1691                                 if(vehicle_viewdist < 0) // when set below 0, this vehicle doesn't use third person view (gunner slots)
1692                                         vehicle_chase = false;
1693                         }
1694                         else
1695                                 vehicle_chase = false;
1696                 }
1697
1698                 int eventchase = WantEventchase(this, vehicle_chase);
1699                 if (eventchase)
1700                 {
1701                         vector current_view_origin_override = '0 0 0';
1702                         vector view_offset_override = '0 0 0';
1703                         float chase_distance_override = 0;
1704                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1705                         if(custom_eventchase)
1706                         {
1707                                 current_view_origin_override = M_ARGV(0, vector);
1708                                 view_offset_override = M_ARGV(1, vector);
1709                                 chase_distance_override = M_ARGV(0, float);
1710                         }
1711                         eventchase_running = true;
1712
1713                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1714                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1715                         if (custom_eventchase)
1716                                 current_view_origin = current_view_origin_override;
1717
1718                         // detect maximum viewoffset and use it
1719                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1720                         if(vehicle_chase)
1721                         {
1722                                 if(vehicle_viewofs)
1723                                         view_offset = vehicle_viewofs;
1724                                 else
1725                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1726                         }
1727                         if (custom_eventchase)
1728                                 view_offset = view_offset_override;
1729
1730                         if(view_offset)
1731                         {
1732                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1733                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1734                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1735                         }
1736
1737                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1738                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1739                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1740                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1741
1742                         // make the camera smooth back
1743                         float chase_distance = autocvar_cl_eventchase_distance;
1744                         if(vehicle_chase)
1745                         {
1746                                 if(vehicle_viewofs)
1747                                         chase_distance = vehicle_viewdist;
1748                                 else
1749                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1750                         }
1751                         if (custom_eventchase)
1752                                 chase_distance = chase_distance_override;
1753
1754                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1755                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1756                         else if(eventchase_current_distance != chase_distance)
1757                                 eventchase_current_distance = chase_distance;
1758
1759                         vector forward, right, up;
1760                         MAKE_VECTORS(view_angles, forward, right, up);
1761
1762                         vector eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
1763                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1764
1765                         // If the boxtrace fails, revert back to line tracing.
1766                         if(!local_player.viewloc)
1767                         if(trace_startsolid)
1768                         {
1769                                 eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
1770                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1771                                 setproperty(VF_ORIGIN, (trace_endpos - (forward * autocvar_cl_eventchase_mins.z)));
1772                         }
1773                         else { setproperty(VF_ORIGIN, trace_endpos); }
1774
1775                         if(!local_player.viewloc)
1776                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1777                 }
1778
1779                 if (eventchase <= 0 && autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1780                 {
1781                         eventchase_running = false;
1782                         cvar_set("chase_active", "0");
1783                         eventchase_current_distance = 0; // start from 0 next time
1784                 }
1785         }
1786         // workaround for camera stuck between player's legs when using chase_active 1
1787         // because the engine stops updating the chase_active camera when the game ends
1788         else if(intermission)
1789         {
1790                 cvar_settemp("chase_active", "-1");
1791                 eventchase_current_distance = 0;
1792         }
1793
1794         LABEL(skip_eventchase_death);
1795
1796         // do lockview after event chase camera so that it still applies whenever necessary.
1797         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1798         {
1799                 setproperty(VF_ORIGIN, freeze_org);
1800                 setproperty(VF_ANGLES, freeze_ang);
1801         }
1802         else
1803         {
1804                 freeze_org = getpropertyvec(VF_ORIGIN);
1805                 freeze_ang = getpropertyvec(VF_ANGLES);
1806         }
1807
1808         WarpZone_FixView();
1809         //WarpZone_FixPMove();
1810
1811         vector ov_org = '0 0 0';
1812         vector ov_mid = '0 0 0';
1813         vector ov_worldmin = '0 0 0';
1814         vector ov_worldmax = '0 0 0';
1815         if(autocvar_cl_orthoview)
1816         {
1817                 ov_worldmin = mi_picmin;
1818                 ov_worldmax = mi_picmax;
1819
1820                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1821                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1822                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1823
1824                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1825                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1826
1827                 float ov_nearest = vlen(ov_org - vec3(
1828                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1829                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1830                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1831                 ));
1832
1833                 float ov_furthest = 0;
1834                 float dist = 0;
1835
1836                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1837                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1838                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1839                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1840                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1841                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1842                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1843                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1844
1845                 if(!ov_enabled)
1846                 {
1847                         oldr_nearclip = cvar("r_nearclip");
1848                         oldr_farclip_base = cvar("r_farclip_base");
1849                         oldr_farclip_world = cvar("r_farclip_world");
1850                         oldr_novis = cvar("r_novis");
1851                         oldr_useportalculling = cvar("r_useportalculling");
1852                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1853                 }
1854
1855                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1856                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1857                 cvar_settemp("r_farclip_world", "0");
1858                 cvar_settemp("r_novis", "1");
1859                 cvar_settemp("r_useportalculling", "0");
1860                 cvar_settemp("r_useinfinitefarclip", "0");
1861
1862                 setproperty(VF_ORIGIN, ov_org);
1863                 setproperty(VF_ANGLES, '90 0 0');
1864
1865                 ov_enabled = true;
1866
1867                 #if 0
1868                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1869                         vtos(ov_org),
1870                         vtos(getpropertyvec(VF_ANGLES)),
1871                         ov_distance,
1872                         ov_nearest,
1873                         ov_furthest);
1874                 #endif
1875         }
1876         else
1877         {
1878                 if(ov_enabled)
1879                 {
1880                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1881                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1882                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1883                         cvar_set("r_novis", ftos(oldr_novis));
1884                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1885                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1886                 }
1887                 ov_enabled = false;
1888         }
1889
1890         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1891         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1892         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1893                 viewmodel_draw(viewmodels[slot]);
1894
1895         // Render the Scene
1896         view_origin = getpropertyvec(VF_ORIGIN);
1897         view_angles = getpropertyvec(VF_ANGLES);
1898         MAKE_VECTORS(view_angles, view_forward, view_right, view_up);
1899
1900 #ifdef BLURTEST
1901         if(time > blurtest_time0 && time < blurtest_time1)
1902         {
1903                 float r, t;
1904
1905                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1906                 r = t * blurtest_radius;
1907                 f = 1 / (t ** blurtest_power) - 1;
1908
1909                 cvar_set("r_glsl_postprocess", "1");
1910                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1911         }
1912         else
1913         {
1914                 cvar_set("r_glsl_postprocess", "0");
1915                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1916         }
1917 #endif
1918
1919         TargetMusic_Advance();
1920         Fog_Force();
1921         fpscounter_update();
1922
1923         if(drawtime == 0)
1924                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1925         else
1926                 drawframetime = bound(0.000001, time - drawtime, 1);
1927         drawtime = time;
1928
1929         // watch for gametype changes here...
1930         // in ParseStuffCMD the cmd isn't executed yet :/
1931         // might even be better to add the gametype to TE_CSQC_INIT...?
1932         if(!postinit)
1933                 PostInit();
1934
1935         if(intermission && !intermission_time)
1936                 intermission_time = time;
1937
1938         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1939         {
1940                 if(calledhooks & HOOK_START)
1941                 {
1942                         localcmd("\ncl_hook_gameend\n");
1943                         calledhooks |= HOOK_END;
1944                 }
1945         }
1946
1947         Announcer();
1948
1949         fov = autocvar_fov;
1950         if(fov <= 59.5)
1951         {
1952                 if(!zoomscript_caught)
1953                 {
1954                         localcmd("+button9\n");
1955                         zoomscript_caught = 1;
1956                 }
1957         }
1958         else
1959         {
1960                 if(zoomscript_caught)
1961                 {
1962                         localcmd("-button9\n");
1963                         zoomscript_caught = 0;
1964                 }
1965         }
1966
1967         if(active_minigame && HUD_MinigameMenu_IsOpened())
1968         {
1969                 if(!minigame_wasactive)
1970                 {
1971                         localcmd("+button12\n");
1972                         minigame_wasactive = true;
1973                 }
1974         }
1975         else if(minigame_wasactive)
1976         {
1977                 localcmd("-button12\n");
1978                 minigame_wasactive = false;
1979         }
1980
1981         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1982
1983         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1984         {
1985                 entity wepent = viewmodels[slot];
1986
1987                 if(wepent.last_switchweapon != wepent.switchweapon)
1988                 {
1989                         weapontime = time;
1990                         wepent.last_switchweapon = wepent.switchweapon;
1991                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1992                         {
1993                                 localcmd("-zoom\n");
1994                                 button_zoom = false;
1995                         }
1996                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1997                         {
1998                                 localcmd("-fire\n");
1999                                 localcmd("-fire2\n");
2000                                 button_attack2 = false;
2001                         }
2002                 }
2003                 if(wepent.last_activeweapon != wepent.activeweapon)
2004                 {
2005                         wepent.last_activeweapon = wepent.activeweapon;
2006
2007                         e = wepent.activeweapon;
2008                         if(e.netname != "")
2009                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
2010                         else if(slot == 0)
2011                                 localcmd("\ncl_hook_activeweapon none\n");
2012                 }
2013         }
2014
2015         // ALWAYS Clear Current Scene First
2016         clearscene();
2017
2018         setproperty(VF_ORIGIN, view_origin);
2019         setproperty(VF_ANGLES, view_angles);
2020
2021         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
2022         setproperty(VF_SIZE, vf_size);
2023         setproperty(VF_MIN, vf_min);
2024
2025         // Assign Standard Viewflags
2026         // Draw the World (and sky)
2027         setproperty(VF_DRAWWORLD, 1);
2028
2029         // Set the console size vars
2030         vid_conwidth = autocvar_vid_conwidth;
2031         vid_conheight = autocvar_vid_conheight;
2032         vid_pixelheight = autocvar_vid_pixelheight;
2033
2034         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
2035         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
2036         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
2037
2038         if(camera_active) // Camera for demo playback
2039         {
2040                 if(autocvar_camera_enable)
2041                         CSQC_Demo_Camera();
2042                 else
2043                 {
2044                         cvar_set("chase_active", ftos(chase_active_backup));
2045                         cvar_set("cl_demo_mousegrab", "0");
2046                         camera_active = false;
2047                 }
2048         }
2049         else
2050         {
2051 #ifdef CAMERATEST
2052                 if(autocvar_camera_enable)
2053 #else
2054                 if(autocvar_camera_enable && isdemo())
2055 #endif
2056                 {
2057                         // Enable required Darkplaces cvars
2058                         chase_active_backup = autocvar_chase_active;
2059                         cvar_set("chase_active", "2");
2060                         cvar_set("cl_demo_mousegrab", "1");
2061                         camera_active = true;
2062                         camera_mode = false;
2063                 }
2064         }
2065
2066         // Draw the Crosshair
2067         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2068
2069         // Draw the Engine Status Bar (the default Quake HUD)
2070         setproperty(VF_DRAWENGINESBAR, 0);
2071
2072         // Update the mouse position
2073         /*
2074            mousepos_x = vid_conwidth;
2075            mousepos_y = vid_conheight;
2076            mousepos = mousepos*0.5 + getmousepos();
2077          */
2078
2079         IL_EACH(g_drawables, it.draw, it.draw(it));
2080
2081         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
2082         renderscene();
2083
2084         // now switch to 2D drawing mode by calling a 2D drawing function
2085         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2086         // next R_RenderScene call
2087         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2088
2089         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2090         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2091         {
2092                 // apply night vision effect
2093                 vector tc_00, tc_01, tc_10, tc_11;
2094                 vector rgb = '0 0 0';
2095
2096                 if(!nightvision_noise)
2097                 {
2098                         nightvision_noise = new(nightvision_noise);
2099                 }
2100                 if(!nightvision_noise2)
2101                 {
2102                         nightvision_noise2 = new(nightvision_noise2);
2103                 }
2104
2105                 // color tint in yellow
2106                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2107
2108                 // draw BG
2109                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2110                 rgb = '1 1 1';
2111                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2112                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2113                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2114                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2115                 tc_11 = tc_01 + tc_10 - tc_00;
2116                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2117                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2118                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2119                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2120                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2121                 R_EndPolygon();
2122
2123                 // draw FG
2124                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2125                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2126                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2127                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2128                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2129                 tc_11 = tc_01 + tc_10 - tc_00;
2130                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2131                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2132                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2133                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2134                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2135                 R_EndPolygon();
2136         }
2137
2138         if(autocvar_cl_reticle && !MUTATOR_CALLHOOK(DrawReticle))
2139         {
2140                 string reticle_image = string_null;
2141                 bool wep_zoomed = false;
2142                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2143                 {
2144                         entity wepe = viewmodels[slot];
2145                         Weapon wep = wepe.activeweapon;
2146                         if(wep != WEP_Null && wep.wr_zoom)
2147                         {
2148                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2149                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2150                                         reticle_image = wep.w_reticle;
2151                                 wep_zoomed += do_zoom;
2152                         }
2153                 }
2154                 // Draw the aiming reticle for weapons that use it
2155                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2156                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2157                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2158                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2159                 {
2160                         // no zoom reticle while dead
2161                         reticle_type = 0;
2162                 }
2163                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2164                 {
2165                         if(reticle_image) { reticle_type = 2; }
2166                         else { reticle_type = 0; }
2167                 }
2168                 else if(button_zoom || zoomscript_caught)
2169                 {
2170                         // normal zoom
2171                         reticle_type = 1;
2172                 }
2173
2174                 if(reticle_type)
2175                 {
2176                         if(autocvar_cl_reticle_stretch)
2177                         {
2178                                 reticle_size.x = vid_conwidth;
2179                                 reticle_size.y = vid_conheight;
2180                                 reticle_pos.x = 0;
2181                                 reticle_pos.y = 0;
2182                         }
2183                         else
2184                         {
2185                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2186                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2187                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2188                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2189                         }
2190
2191                         if(zoomscript_caught)
2192                                 f = 1;
2193                         else
2194                                 f = current_zoomfraction;
2195
2196                         if(f)
2197                         {
2198                                 switch(reticle_type)
2199                                 {
2200                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2201                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2202                                 }
2203                         }
2204                 }
2205         }
2206         else
2207         {
2208                 if(reticle_type != 0) { reticle_type = 0; }
2209         }
2210
2211
2212         // improved polyblend
2213         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2214         {
2215                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2216                 vector liquidcolor;
2217
2218                 switch(pointcontents(view_origin))
2219                 {
2220                         case CONTENT_WATER:
2221                                 liquidalpha = autocvar_hud_contents_water_alpha;
2222                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2223                                 incontent = 1;
2224                                 break;
2225
2226                         case CONTENT_LAVA:
2227                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2228                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2229                                 incontent = 1;
2230                                 break;
2231
2232                         case CONTENT_SLIME:
2233                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2234                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2235                                 incontent = 1;
2236                                 break;
2237
2238                         default:
2239                                 liquidalpha = 0;
2240                                 liquidcolor = '0 0 0';
2241                                 incontent = 0;
2242                                 break;
2243                 }
2244
2245                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2246                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2247                         contentfadetime = autocvar_hud_contents_fadeintime;
2248                         liquidalpha_prev = liquidalpha;
2249                         liquidcolor_prev = liquidcolor;
2250                 }
2251                 else
2252                         contentfadetime = autocvar_hud_contents_fadeouttime;
2253
2254                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2255                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2256
2257                 if(contentavgalpha)
2258                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2259
2260                 if(autocvar_hud_postprocessing)
2261                 {
2262                         if(autocvar_hud_contents_blur && contentavgalpha)
2263                         {
2264                                 content_blurpostprocess.x = 1;
2265                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2266                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2267                         }
2268                         else
2269                         {
2270                                 content_blurpostprocess.x = 0;
2271                                 content_blurpostprocess.y = 0;
2272                                 content_blurpostprocess.z = 0;
2273                         }
2274                 }
2275         }
2276
2277         if(autocvar_hud_damage && !STAT(FROZEN))
2278         {
2279                 splash_size.x = max(vid_conwidth, vid_conheight);
2280                 splash_size.y = max(vid_conwidth, vid_conheight);
2281                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2282                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2283
2284                 float myhealth_flash_temp;
2285                 myhealth = STAT(HEALTH);
2286
2287                 // fade out
2288                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2289                 // add new damage
2290                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2291
2292                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2293                 pain_threshold = autocvar_hud_damage_pain_threshold;
2294                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2295                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2296
2297                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2298                 {
2299                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2300                 }
2301
2302                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2303
2304                 if(myhealth_prev < 1)
2305                 {
2306                         if(myhealth >= 1)
2307                         {
2308                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2309                                 myhealth_flash_temp = 0;
2310                         }
2311                         else
2312                         {
2313                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2314                         }
2315                 }
2316
2317                 if(spectatee_status == -1 || intermission)
2318                 {
2319                         myhealth_flash = 0; // observing, or match ended
2320                         myhealth_flash_temp = 0;
2321                 }
2322
2323                 myhealth_prev = myhealth;
2324
2325                 // IDEA: change damage color/picture based on player model for robot/alien species?
2326                 // pro: matches model better
2327                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2328                 // maybe different reddish pics?
2329                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2330                 {
2331                         if(autocvar_cl_gentle_damage == 2)
2332                         {
2333                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2334                                         myhealth_gentlergb = randomvec();
2335                         }
2336                         else
2337                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2338
2339                         if(myhealth_flash_temp > 0)
2340                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2341                 }
2342                 else if(myhealth_flash_temp > 0)
2343                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2344
2345                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2346                 {
2347                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2348                         {
2349                                 damage_blurpostprocess.x = 1;
2350                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2351                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2352                         }
2353                         else
2354                         {
2355                                 damage_blurpostprocess.x = 0;
2356                                 damage_blurpostprocess.y = 0;
2357                                 damage_blurpostprocess.z = 0;
2358                         }
2359                 }
2360         }
2361
2362         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2363         float e2 = (autocvar_hud_powerup != 0);
2364         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2365         {
2366                 // enable or disable rendering types if they are used or not
2367                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2368                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2369
2370                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2371                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2372                 {
2373                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2374                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2375                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2376                         {
2377                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2378                                 old_blurradius = blurradius;
2379                                 old_bluralpha = bluralpha;
2380                         }
2381                 }
2382                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2383                 {
2384                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2385                         old_blurradius = 0;
2386                         old_bluralpha = 0;
2387                 }
2388
2389                 // edge detection postprocess handling done second (used by hud_powerup)
2390                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2391                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2392                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2393
2394                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2395
2396                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2397                 {
2398                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2399                         {
2400                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2401                                 old_sharpen_intensity = sharpen_intensity;
2402                         }
2403                 }
2404                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2405                 {
2406                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2407                         old_sharpen_intensity = 0;
2408                 }
2409
2410                 if(cvar("r_glsl_postprocess") == 0)
2411                         cvar_set("r_glsl_postprocess", "2");
2412         }
2413         else if(cvar("r_glsl_postprocess") == 2)
2414                 cvar_set("r_glsl_postprocess", "0");
2415
2416         /*if(ISGAMETYPE(CTF))
2417           {
2418           ctf_view();
2419           } else */
2420
2421         // draw 2D entities
2422         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2423         Draw_ShowNames_All();
2424 #if ENABLE_DEBUGDRAW
2425         Debug_Draw();
2426 #endif
2427
2428         scoreboard_active = Scoreboard_WouldDraw();
2429
2430         HUD_Draw(this); // this parameter for deep vehicle function
2431
2432         if(NextFrameCommand)
2433         {
2434                 localcmd("\n", NextFrameCommand, "\n");
2435                 NextFrameCommand = string_null;
2436         }
2437
2438         // we must do this check AFTER a frame was rendered, or it won't work
2439         if(cs_project_is_b0rked == 0)
2440         {
2441                 string w0, h0;
2442                 w0 = ftos(autocvar_vid_conwidth);
2443                 h0 = ftos(autocvar_vid_conheight);
2444                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2445                 //setproperty(VF_FOV, '90 90 0');
2446                 setproperty(VF_ORIGIN, '0 0 0');
2447                 setproperty(VF_ANGLES, '0 0 0');
2448                 setproperty(VF_PERSPECTIVE, 1);
2449                 vector forward, right, up;
2450                 MAKE_VECTORS('0 0 0', forward, right, up);
2451                 vector v1, v2;
2452                 cvar_set("vid_conwidth", "800");
2453                 cvar_set("vid_conheight", "600");
2454                 v1 = cs_project(forward);
2455                 cvar_set("vid_conwidth", "640");
2456                 cvar_set("vid_conheight", "480");
2457                 v2 = cs_project(forward);
2458                 if(v1 == v2)
2459                         cs_project_is_b0rked = 1;
2460                 else
2461                         cs_project_is_b0rked = -1;
2462                 cvar_set("vid_conwidth", w0);
2463                 cvar_set("vid_conheight", h0);
2464         }
2465
2466         HUD_Mouse(local_player);
2467
2468         cl_notice_run();
2469         unpause_update();
2470         Net_Flush();
2471
2472         // let's reset the view back to normal for the end
2473         setproperty(VF_MIN, '0 0 0');
2474         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2475
2476         IL_ENDFRAME();
2477 }
2478
2479
2480 // following vectors must be global to allow seamless switching between camera modes
2481 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2482 void CSQC_Demo_Camera()
2483 {
2484         float speed, attenuation, dimensions;
2485         vector tmp, delta;
2486
2487         if( autocvar_camera_reset || !camera_mode )
2488         {
2489                 camera_offset = '0 0 0';
2490                 current_angles = '0 0 0';
2491                 camera_direction = '0 0 0';
2492                 camera_offset.z += 30;
2493                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2494                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2495                 current_origin = view_origin;
2496                 current_camera_offset  = camera_offset;
2497                 cvar_set("camera_reset", "0");
2498                 camera_mode = CAMERA_CHASE;
2499         }
2500
2501         // Camera angles
2502         if( camera_roll )
2503                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2504
2505         if(autocvar_camera_look_player)
2506         {
2507                 vector dir;
2508                 float n;
2509
2510                 dir = normalize(view_origin - current_position);
2511                 n = mouse_angles.z;
2512                 mouse_angles = vectoangles(dir);
2513                 mouse_angles.x = mouse_angles.x * -1;
2514                 mouse_angles.z = n;
2515         }
2516         else
2517         {
2518                 tmp = getmousepos() * 0.1;
2519                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2520                 {
2521                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2522                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2523                 }
2524         }
2525
2526         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2527         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2528         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2529         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2530
2531         // Fix difference when angles don't have the same sign
2532         delta = '0 0 0';
2533         if(mouse_angles.y < -60 && current_angles.y > 60)
2534                 delta = '0 360 0';
2535         if(mouse_angles.y > 60 && current_angles.y < -60)
2536                 delta = '0 -360 0';
2537
2538         if(autocvar_camera_look_player)
2539                 attenuation = autocvar_camera_look_attenuation;
2540         else
2541                 attenuation = autocvar_camera_speed_attenuation;
2542
2543         attenuation = 1 / max(1, attenuation);
2544         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2545
2546         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2547         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2548         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2549         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2550
2551         // Camera position
2552         tmp = '0 0 0';
2553         dimensions = 0;
2554
2555         if( camera_direction.x )
2556         {
2557                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2558                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2559                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2560                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2561                 ++dimensions;
2562         }
2563
2564         if( camera_direction.y )
2565         {
2566                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2567                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2568                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2569                 ++dimensions;
2570         }
2571
2572         if( camera_direction.z )
2573         {
2574                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2575                 ++dimensions;
2576         }
2577
2578         if(autocvar_camera_free)
2579                 speed = autocvar_camera_speed_free;
2580         else
2581                 speed = autocvar_camera_speed_chase;
2582
2583         if(dimensions)
2584         {
2585                 speed = speed * sqrt(1 / dimensions);
2586                 camera_offset += tmp * speed;
2587         }
2588
2589         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2590
2591         // Camera modes
2592         if( autocvar_camera_free )
2593         {
2594                 if ( camera_mode == CAMERA_CHASE )
2595                 {
2596                         current_camera_offset = current_origin + current_camera_offset;
2597                         camera_offset = current_origin + camera_offset;
2598                 }
2599
2600                 camera_mode = CAMERA_FREE;
2601                 current_position = current_camera_offset;
2602         }
2603         else
2604         {
2605                 if ( camera_mode == CAMERA_FREE )
2606                 {
2607                         current_origin = view_origin;
2608                         camera_offset = camera_offset - current_origin;
2609                         current_camera_offset = current_camera_offset - current_origin;
2610                 }
2611
2612                 camera_mode = CAMERA_CHASE;
2613
2614                 if(autocvar_camera_chase_smoothly)
2615                         current_origin += (view_origin - current_origin) * attenuation;
2616                 else
2617                         current_origin = view_origin;
2618
2619                 current_position = current_origin + current_camera_offset;
2620         }
2621
2622         setproperty(VF_ANGLES, current_angles);
2623         setproperty(VF_ORIGIN, current_position);
2624 }