qcsrc/client/hud_config.qc

   1 #define HUD_Write(s) fputs(fh, s)
   2 // q: quoted, n: not quoted
   3 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
   4 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
   5 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel_name, cvar_suf))
   6 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel_name, cvar_suf))
   7 // Save the config
   8 void HUD_Panel_ExportCfg(string cfgname)
   9 {
  10         float fh;
  11         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  12         fh = fopen(filename, FILE_WRITE);
  13         if(fh >= 0)
  14         {
  15                 HUD_Write_Cvar_q("hud_skin");
  16                 HUD_Write_Cvar_q("hud_panel_bg");
  17                 HUD_Write_Cvar_q("hud_panel_bg_color");
  18                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  19                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  20                 HUD_Write_Cvar_q("hud_panel_bg_border");
  21                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  22                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  23                 HUD_Write("\n");
  24
  25                 HUD_Write_Cvar_q("hud_dock");
  26                 HUD_Write_Cvar_q("hud_dock_color");
  27                 HUD_Write_Cvar_q("hud_dock_color_team");
  28                 HUD_Write_Cvar_q("hud_dock_alpha");
  29                 HUD_Write("\n");
  30
  31                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  32                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  33                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  34                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  35                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  36                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  37                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  38                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  39                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  40                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  41                 HUD_Write("\n");
  42
  43                 HUD_Write_Cvar_q("_hud_panelorder");
  44                 HUD_Write("\n");
  45
  46                 HUD_Write_Cvar_q("hud_configure_grid");
  47                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  48                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  49                 HUD_Write("\n");
  50
  51                 // common cvars for all panels
  52                 float i;
  53                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  54                 {
  55                         HUD_Panel_GetName(i);
  56
  57                         HUD_Write_PanelCvar_n("");
  58                         HUD_Write_PanelCvar_q("_pos");
  59                         HUD_Write_PanelCvar_q("_size");
  60                         HUD_Write_PanelCvar_q("_bg");
  61                         HUD_Write_PanelCvar_q("_bg_color");
  62                         HUD_Write_PanelCvar_q("_bg_color_team");
  63                         HUD_Write_PanelCvar_q("_bg_alpha");
  64                         HUD_Write_PanelCvar_q("_bg_border");
  65                         HUD_Write_PanelCvar_q("_bg_padding");
  66                         switch(i) {
  67                                 case HUD_PANEL_WEAPONS:
  68                                         HUD_Write_PanelCvar_q("_accuracy");
  69                                         HUD_Write_PanelCvar_q("_label");
  70                                         HUD_Write_PanelCvar_q("_complainbubble");
  71                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  72                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  73                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  74                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  75                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  76                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  77                                         HUD_Write_PanelCvar_q("_ammo");
  78                                         HUD_Write_PanelCvar_q("_ammo_color");
  79                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  80                                         HUD_Write_PanelCvar_q("_aspect");
  81                                         HUD_Write_PanelCvar_q("_timeout");
  82                                         HUD_Write_PanelCvar_q("_timeout_effect");
  83                                         HUD_Write_PanelCvar_q("_onlyowned");
  84                                         break;
  85                                 case HUD_PANEL_AMMO:
  86                                         HUD_Write_PanelCvar_q("_onlycurrent");
  87                                         HUD_Write_PanelCvar_q("_iconalign");
  88                                         HUD_Write_PanelCvar_q("_progressbar");
  89                                         HUD_Write_PanelCvar_q("_progressbar_name");
  90                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
  91                                         HUD_Write_PanelCvar_q("_text");
  92                                         break;
  93                                 case HUD_PANEL_POWERUPS:
  94                                         HUD_Write_PanelCvar_q("_flip");
  95                                         HUD_Write_PanelCvar_q("_iconalign");
  96                                         HUD_Write_PanelCvar_q("_baralign");
  97                                         HUD_Write_PanelCvar_q("_progressbar");
  98                                         HUD_Write_PanelCvar_q("_progressbar_strength");
  99                                         HUD_Write_PanelCvar_q("_progressbar_shield");
 100                                         HUD_Write_PanelCvar_q("_text");
 101                                         break;
 102                                 case HUD_PANEL_HEALTHARMOR:
 103                                         HUD_Write_PanelCvar_q("_flip");
 104                                         HUD_Write_PanelCvar_q("_iconalign");
 105                                         HUD_Write_PanelCvar_q("_baralign");
 106                                         HUD_Write_PanelCvar_q("_progressbar");
 107                                         HUD_Write_PanelCvar_q("_progressbar_health");
 108                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 109                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 110                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 111                                         HUD_Write_PanelCvar_q("_text");
 112                                         break;
 113                                 case HUD_PANEL_NOTIFY:
 114                                         HUD_Write_PanelCvar_q("_flip");
 115                                         HUD_Write_PanelCvar_q("_fontsize");
 116                                         HUD_Write_PanelCvar_q("_print");
 117                                         HUD_Write_PanelCvar_q("_time");
 118                                         HUD_Write_PanelCvar_q("_fadetime");
 119                                         break;
 120                                 case HUD_PANEL_TIMER:
 121                                         HUD_Write_PanelCvar_q("_increment");
 122                                         break;
 123                                 case HUD_PANEL_RADAR:
 124                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 125                                         HUD_Write_PanelCvar_q("_rotation");
 126                                         HUD_Write_PanelCvar_q("_zoommode");
 127                                         HUD_Write_PanelCvar_q("_scale");
 128                                         HUD_Write_PanelCvar_q("_maximized_scale");
 129                                         HUD_Write_PanelCvar_q("_maximized_size");
 130                                         break;
 131                                 case HUD_PANEL_SCORE:
 132                                         HUD_Write_PanelCvar_q("_rankings");
 133                                         break;
 134                                 case HUD_PANEL_VOTE:
 135                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 136                                         break;
 137                                 case HUD_PANEL_MODICONS:
 138                                         HUD_Write_PanelCvar_q("_dom_layout");
 139                                         break;
 140                                 case HUD_PANEL_PRESSEDKEYS:
 141                                         HUD_Write_PanelCvar_q("_attack");
 142                                         HUD_Write_PanelCvar_q("_aspect");
 143                                         break;
 144                                 case HUD_PANEL_ENGINEINFO:
 145                                         HUD_Write_PanelCvar_q("_framecounter_time");
 146                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 147                                         break;
 148                                 case HUD_PANEL_INFOMESSAGES:
 149                                         HUD_Write_PanelCvar_q("_flip");
 150                                         break;
 151                                 case HUD_PANEL_PHYSICS:
 152                                         HUD_Write_PanelCvar_q("_speed_unit");
 153                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 154                                         HUD_Write_PanelCvar_q("_speed_max");
 155                                         HUD_Write_PanelCvar_q("_speed_vertical");
 156                                         HUD_Write_PanelCvar_q("_topspeed");
 157                                         HUD_Write_PanelCvar_q("_topspeed_time");
 158                                         HUD_Write_PanelCvar_q("_acceleration_max");
 159                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 160                                         HUD_Write_PanelCvar_q("_flip");
 161                                         HUD_Write_PanelCvar_q("_baralign");
 162                                         HUD_Write_PanelCvar_q("_progressbar");
 163                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_mode");
 164                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_scale");
 165                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_nonlinear");
 166                                         HUD_Write_PanelCvar_q("_text");
 167                                         HUD_Write_PanelCvar_q("_text_scale");
 168                                         break;
 169                                 case HUD_PANEL_CENTERPRINT:
 170                                         HUD_Write_PanelCvar_q("_align");
 171                                         HUD_Write_PanelCvar_q("_flip");
 172                                         HUD_Write_PanelCvar_q("_fontscale");
 173                                         HUD_Write_PanelCvar_q("_time");
 174                                         HUD_Write_PanelCvar_q("_fade_in");
 175                                         HUD_Write_PanelCvar_q("_fade_out");
 176                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 177                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 178                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 179                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 180                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 181                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 182                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 183                                         break;
 184                                 case HUD_PANEL_ITEMSTIME:
 185                                         HUD_Write_PanelCvar_q("_iconalign");
 186                                         HUD_Write_PanelCvar_q("_progressbar");
 187                                         HUD_Write_PanelCvar_q("_progressbar_name");
 188                                         HUD_Write_PanelCvar_q("_progressbar_reduced");
 189                                         HUD_Write_PanelCvar_q("_showspawned");
 190                                         HUD_Write_PanelCvar_q("_text");
 191                                         HUD_Write_PanelCvar_q("_ratio");
 192                                         HUD_Write_PanelCvar_q("_size_dinamic");
 193                                         break;
 194                         }
 195                         HUD_Write("\n");
 196                 }
 197                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 198
 199                 print(sprintf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename));
 200                 fclose(fh);
 201         }
 202         else
 203                 print(sprintf(_("^1Couldn't write to %s\n"), filename));
 204 }
 205
 206 void HUD_Configure_Exit_Force()
 207 {
 208         if (menu_enabled)
 209         {
 210                 menu_enabled = 0;
 211                 localcmd("togglemenu\n");
 212         }
 213         cvar_set("_hud_configure", "0");
 214 }
 215
 216 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 217 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 218 {
 219         float i;
 220         float myCenter_x, myCenter_y, targCenter_x, targCenter_y;
 221         vector myTarget;
 222         myTarget = myPos;
 223
 224         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 225                 if(i == highlightedPanel || !panel_enabled)
 226                         continue;
 227
 228                 HUD_Panel_UpdatePosSizeForId(i);
 229
 230                 panel_pos -= '1 1 0' * panel_bg_border;
 231                 panel_size += '2 2 0' * panel_bg_border;
 232
 233                 if(myPos_y + mySize_y < panel_pos_y)
 234                         continue;
 235                 if(myPos_y > panel_pos_y + panel_size_y)
 236                         continue;
 237
 238                 if(myPos_x + mySize_x < panel_pos_x)
 239                         continue;
 240                 if(myPos_x > panel_pos_x + panel_size_x)
 241                         continue;
 242
 243                 // OK, there IS a collision.
 244
 245                 myCenter_x = myPos_x + 0.5 * mySize_x;
 246                 myCenter_y = myPos_y + 0.5 * mySize_y;
 247
 248                 targCenter_x = panel_pos_x + 0.5 * panel_size_x;
 249                 targCenter_y = panel_pos_y + 0.5 * panel_size_y;
 250
 251                 if(myCenter_x < targCenter_x && myCenter_y < targCenter_y) // top left (of the target panel)
 252                 {
 253                         if(myPos_x + mySize_x - panel_pos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 254                                 myTarget_x = panel_pos_x - mySize_x;
 255                         else // push it upwards
 256                                 myTarget_y = panel_pos_y - mySize_y;
 257                 }
 258                 else if(myCenter_x > targCenter_x && myCenter_y < targCenter_y) // top right
 259                 {
 260                         if(panel_pos_x + panel_size_x - myPos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 261                                 myTarget_x = panel_pos_x + panel_size_x;
 262                         else // push it upwards
 263                                 myTarget_y = panel_pos_y - mySize_y;
 264                 }
 265                 else if(myCenter_x < targCenter_x && myCenter_y > targCenter_y) // bottom left
 266                 {
 267                         if(myPos_x + mySize_x - panel_pos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 268                                 myTarget_x = panel_pos_x - mySize_x;
 269                         else // push it downwards
 270                                 myTarget_y = panel_pos_y + panel_size_y;
 271                 }
 272                 else if(myCenter_x > targCenter_x && myCenter_y > targCenter_y) // bottom right
 273                 {
 274                         if(panel_pos_x + panel_size_x - myPos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 275                                 myTarget_x = panel_pos_x + panel_size_x;
 276                         else // push it downwards
 277                                 myTarget_y = panel_pos_y + panel_size_y;
 278                 }
 279                 //if(cvar("hud_configure_checkcollisions_debug"))
 280                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 281         }
 282
 283         return myTarget;
 284 }
 285
 286 void HUD_Panel_SetPos(vector pos)
 287 {
 288         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 289         vector mySize;
 290         mySize = panel_size;
 291
 292         //if(cvar("hud_configure_checkcollisions_debug"))
 293                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 294
 295         if(autocvar_hud_configure_grid)
 296         {
 297                 pos_x = floor((pos_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 298                 pos_y = floor((pos_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 299         }
 300
 301         if(hud_configure_checkcollisions)
 302                 pos = HUD_Panel_CheckMove(pos, mySize);
 303
 304         pos_x = bound(0, pos_x, vid_conwidth - mySize_x);
 305         pos_y = bound(0, pos_y, vid_conheight - mySize_y);
 306
 307         string s;
 308         s = strcat(ftos(pos_x/vid_conwidth), " ", ftos(pos_y/vid_conheight));
 309
 310         HUD_Panel_GetName(highlightedPanel);
 311         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 312 }
 313
 314 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 315 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 316         float i;
 317
 318         vector targEndPos;
 319
 320         float dist_x, dist_y;
 321         float ratio;
 322         ratio = mySize_x/mySize_y;
 323
 324         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 325                 if(i == highlightedPanel || !panel_enabled)
 326                         continue;
 327
 328                 HUD_Panel_UpdatePosSizeForId(i);
 329
 330                 panel_pos -= '1 1 0' * panel_bg_border;
 331                 panel_size += '2 2 0' * panel_bg_border;
 332
 333                 targEndPos = panel_pos + panel_size;
 334
 335                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 336                 if(resizeorigin_x > panel_pos_x && resizeorigin_x < targEndPos_x && resizeorigin_y > panel_pos_y && resizeorigin_y < targEndPos_y)
 337                         continue;
 338
 339                 if (resizeCorner == 1)
 340                 {
 341                         // check if this panel is on our way
 342                         if (resizeorigin_x <= panel_pos_x)
 343                                 continue;
 344                         if (resizeorigin_y <= panel_pos_y)
 345                                 continue;
 346                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 347                                 continue;
 348                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 349                                 continue;
 350
 351                         // there is a collision:
 352                         // detect which side of the panel we are facing is actually limiting the resizing
 353                         // (which side the resize direction finds for first) and reduce the size up to there
 354                         //
 355                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 356                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 357                         dist_x = resizeorigin_x - targEndPos_x;
 358                         dist_y = resizeorigin_y - targEndPos_y;
 359                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 360                                 mySize_x = min(mySize_x, dist_x);
 361                         else
 362                                 mySize_y = min(mySize_y, dist_y);
 363                 }
 364                 else if (resizeCorner == 2)
 365                 {
 366                         if (resizeorigin_x >= targEndPos_x)
 367                                 continue;
 368                         if (resizeorigin_y <= panel_pos_y)
 369                                 continue;
 370                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 371                                 continue;
 372                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 373                                 continue;
 374
 375                         dist_x = panel_pos_x - resizeorigin_x;
 376                         dist_y = resizeorigin_y - targEndPos_y;
 377                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 378                                 mySize_x = min(mySize_x, dist_x);
 379                         else
 380                                 mySize_y = min(mySize_y, dist_y);
 381                 }
 382                 else if (resizeCorner == 3)
 383                 {
 384                         if (resizeorigin_x <= panel_pos_x)
 385                                 continue;
 386                         if (resizeorigin_y >= targEndPos_y)
 387                                 continue;
 388                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 389                                 continue;
 390                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 391                                 continue;
 392
 393                         dist_x = resizeorigin_x - targEndPos_x;
 394                         dist_y = panel_pos_y - resizeorigin_y;
 395                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 396                                 mySize_x = min(mySize_x, dist_x);
 397                         else
 398                                 mySize_y = min(mySize_y, dist_y);
 399                 }
 400                 else if (resizeCorner == 4)
 401                 {
 402                         if (resizeorigin_x >= targEndPos_x)
 403                                 continue;
 404                         if (resizeorigin_y >= targEndPos_y)
 405                                 continue;
 406                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 407                                 continue;
 408                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 409                                 continue;
 410
 411                         dist_x = panel_pos_x - resizeorigin_x;
 412                         dist_y = panel_pos_y - resizeorigin_y;
 413                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 414                                 mySize_x = min(mySize_x, dist_x);
 415                         else
 416                                 mySize_y = min(mySize_y, dist_y);
 417                 }
 418                 //if(cvar("hud_configure_checkcollisions_debug"))
 419                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 420         }
 421
 422         return mySize;
 423 }
 424
 425 void HUD_Panel_SetPosSize(vector mySize)
 426 {
 427         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 428         vector resizeorigin;
 429         resizeorigin = panel_click_resizeorigin;
 430         local noref vector myPos; // fteqcc sucks
 431
 432         // minimum panel size cap
 433         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 434         mySize_y = max(0.025 * vid_conheight, mySize_y);
 435
 436         if(highlightedPanel == HUD_PANEL_CHAT) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 437         {
 438                 mySize_x = max(17 * autocvar_con_chatsize, mySize_x);
 439                 mySize_y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize_y);
 440         }
 441
 442         // collision testing|
 443         // -----------------+
 444
 445         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 446         if(resizeCorner == 1) {
 447                 myPos_x = resizeorigin_x - mySize_x;
 448                 myPos_y = resizeorigin_y - mySize_y;
 449         } else if(resizeCorner == 2) {
 450                 myPos_x = resizeorigin_x;
 451                 myPos_y = resizeorigin_y - mySize_y;
 452         } else if(resizeCorner == 3) {
 453                 myPos_x = resizeorigin_x - mySize_x;
 454                 myPos_y = resizeorigin_y;
 455         } else { // resizeCorner == 4
 456                 myPos_x = resizeorigin_x;
 457                 myPos_y = resizeorigin_y;
 458         }
 459
 460         // left/top screen edges
 461         if(myPos_x < 0)
 462                 mySize_x = mySize_x + myPos_x;
 463         if(myPos_y < 0)
 464                 mySize_y = mySize_y + myPos_y;
 465
 466         // bottom/right screen edges
 467         if(myPos_x + mySize_x > vid_conwidth)
 468                 mySize_x = vid_conwidth - myPos_x;
 469         if(myPos_y + mySize_y > vid_conheight)
 470                 mySize_y = vid_conheight - myPos_y;
 471
 472         //if(cvar("hud_configure_checkcollisions_debug"))
 473                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 474
 475         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 476         if(autocvar_hud_configure_grid)
 477         {
 478                 mySize_x = floor((mySize_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 479                 mySize_y = floor((mySize_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 480         }
 481
 482         if(hud_configure_checkcollisions)
 483                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 484
 485         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 486         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 487         mySize_y = max(0.025 * vid_conheight, mySize_y);
 488
 489         // do another pos check, as size might have changed by now
 490         if(resizeCorner == 1) {
 491                 myPos_x = resizeorigin_x - mySize_x;
 492                 myPos_y = resizeorigin_y - mySize_y;
 493         } else if(resizeCorner == 2) {
 494                 myPos_x = resizeorigin_x;
 495                 myPos_y = resizeorigin_y - mySize_y;
 496         } else if(resizeCorner == 3) {
 497                 myPos_x = resizeorigin_x - mySize_x;
 498                 myPos_y = resizeorigin_y;
 499         } else { // resizeCorner == 4
 500                 myPos_x = resizeorigin_x;
 501                 myPos_y = resizeorigin_y;
 502         }
 503
 504         //if(cvar("hud_configure_checkcollisions_debug"))
 505                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 506
 507         HUD_Panel_GetName(highlightedPanel);
 508         string s;
 509         s = strcat(ftos(mySize_x/vid_conwidth), " ", ftos(mySize_y/vid_conheight));
 510         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 511
 512         s = strcat(ftos(myPos_x/vid_conwidth), " ", ftos(myPos_y/vid_conheight));
 513         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 514 }
 515
 516 float pressed_key_time;
 517 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 518 void HUD_Panel_Arrow_Action(float nPrimary)
 519 {
 520         if (highlightedPanel == -1)
 521                 return;
 522
 523         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 524
 525         float step;
 526         if(autocvar_hud_configure_grid)
 527         {
 528                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 529                 {
 530                         if (hudShiftState & S_SHIFT)
 531                                 step = hud_configure_realGridSize_y;
 532                         else
 533                                 step = 2 * hud_configure_realGridSize_y;
 534                 }
 535                 else
 536                 {
 537                         if (hudShiftState & S_SHIFT)
 538                                 step = hud_configure_realGridSize_x;
 539                         else
 540                                 step = 2 * hud_configure_realGridSize_x;
 541                 }
 542         }
 543         else
 544         {
 545                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 546                         step = vid_conheight;
 547                 else
 548                         step = vid_conwidth;
 549                 if (hudShiftState & S_SHIFT)
 550                         step = (step / 256); // more precision
 551                 else
 552                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 553         }
 554
 555         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 556
 557         highlightedPanel_initial_pos = panel_pos;
 558         highlightedPanel_initial_size = panel_size;
 559
 560         if (hudShiftState & S_ALT) // resize
 561         {
 562                 highlightedAction = 1;
 563                 if(nPrimary == K_UPARROW)
 564                         resizeCorner = 1;
 565                 else if(nPrimary == K_RIGHTARROW)
 566                         resizeCorner = 2;
 567                 else if(nPrimary == K_LEFTARROW)
 568                         resizeCorner = 3;
 569                 else // if(nPrimary == K_DOWNARROW)
 570                         resizeCorner = 4;
 571
 572                 // ctrl+arrow reduces the size, instead of increasing it
 573                 // Note that ctrl disables collisions check too, but it's fine
 574                 // since we don't collide with anything reducing the size
 575                 if (hudShiftState & S_CTRL) {
 576                         step = -step;
 577                         resizeCorner = 5 - resizeCorner;
 578                 }
 579
 580                 vector mySize;
 581                 mySize = panel_size;
 582                 panel_click_resizeorigin = panel_pos;
 583                 if(resizeCorner == 1) {
 584                         panel_click_resizeorigin += mySize;
 585                         mySize_y += step;
 586                 } else if(resizeCorner == 2) {
 587                         panel_click_resizeorigin_y += mySize_y;
 588                         mySize_x += step;
 589                 } else if(resizeCorner == 3) {
 590                         panel_click_resizeorigin_x += mySize_x;
 591                         mySize_x += step;
 592                 } else { // resizeCorner == 4
 593                         mySize_y += step;
 594                 }
 595                 HUD_Panel_SetPosSize(mySize);
 596         }
 597         else // move
 598         {
 599                 highlightedAction = 2;
 600                 vector pos;
 601                 pos = panel_pos;
 602                 if(nPrimary == K_UPARROW)
 603                         pos_y -= step;
 604                 else if(nPrimary == K_DOWNARROW)
 605                         pos_y += step;
 606                 else if(nPrimary == K_LEFTARROW)
 607                         pos_x -= step;
 608                 else // if(nPrimary == K_RIGHTARROW)
 609                         pos_x += step;
 610
 611                 HUD_Panel_SetPos(pos);
 612         }
 613
 614         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 615
 616         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 617         {
 618                 // backup!
 619                 panel_pos_backup = highlightedPanel_initial_pos;
 620                 panel_size_backup = highlightedPanel_initial_size;
 621                 highlightedPanel_backup = highlightedPanel;
 622         }
 623 }
 624
 625 const float S_MOUSE1 = 1;
 626 const float S_MOUSE2 = 2;
 627 const float S_MOUSE3 = 4;
 628 float mouseClicked;
 629 float prevMouseClicked; // previous state
 630 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
 631 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
 632
 633 void HUD_Panel_EnableMenu();
 634 float tab_panels[HUD_PANEL_NUM];
 635 float tab_panel, tab_backward;
 636 vector tab_panel_pos;
 637 void HUD_Panel_FirstInDrawQ(float id);
 638 void reset_tab_panels()
 639 {
 640         int i;
 641         for(i = 0; i < HUD_PANEL_NUM; ++i)
 642                 tab_panels[i] = -1;
 643 }
 644 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 645 {
 646         string s;
 647
 648         // we only care for keyboard events
 649         if(bInputType != 0 && bInputType != 1)
 650                 return false;
 651
 652         if(!autocvar__hud_configure)
 653                 return false;
 654
 655         // block any input while a menu dialog is fading
 656         if(autocvar__menu_alpha)
 657                 return true;
 658
 659         // allow console bind to work
 660         string con_keys;
 661         float keys;
 662         con_keys = findkeysforcommand("toggleconsole", 0);
 663         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 664
 665         float hit_con_bind, i;
 666         for (i = 0; i < keys; ++i)
 667         {
 668                 if(nPrimary == stof(argv(i)))
 669                         hit_con_bind = 1;
 670         }
 671
 672         if(bInputType == 0) {
 673                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 674                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 675                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 676         }
 677         else if(bInputType == 1) {
 678                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 679                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 680                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 681         }
 682
 683         if(nPrimary == K_CTRL)
 684         {
 685                 if (bInputType == 1) //ctrl has been released
 686                 {
 687                         if (tab_panel != -1)
 688                         {
 689                                 //switch to selected panel
 690                                 highlightedPanel = tab_panel;
 691                                 highlightedAction = 0;
 692                                 HUD_Panel_FirstInDrawQ(highlightedPanel);
 693                         }
 694                         tab_panel = -1;
 695                         reset_tab_panels();
 696                 }
 697         }
 698
 699         if(nPrimary == K_MOUSE1)
 700         {
 701                 if(bInputType == 0) // key pressed
 702                         mouseClicked |= S_MOUSE1;
 703                 else if(bInputType == 1) // key released
 704                         mouseClicked -= (mouseClicked & S_MOUSE1);
 705         }
 706         else if(nPrimary == K_MOUSE2)
 707         {
 708                 if(bInputType == 0) // key pressed
 709                         mouseClicked |= S_MOUSE2;
 710                 else if(bInputType == 1) // key released
 711                         mouseClicked -= (mouseClicked & S_MOUSE2);
 712         }
 713         else if(nPrimary == K_ESCAPE)
 714         {
 715                 if (bInputType == 1)
 716                         return true;
 717                 menu_enabled = 1;
 718                 menu_enabled_time = time;
 719                 localcmd("menu_showhudexit\n");
 720         }
 721         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 722         {
 723                 if (bInputType == 1)
 724                         return true;
 725                 if (!menu_enabled)
 726                         cvar_set("_hud_configure", "0");
 727         }
 728         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
 729         {
 730                 if (bInputType == 1 || mouseClicked)
 731                         return true;
 732
 733                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
 734                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
 735                 //(it should only after every other panel of the hud)
 736                 //It's a minor bug anyway, we can live with it
 737
 738                 float starting_panel;
 739                 float old_tab_panel = tab_panel;
 740                 if (tab_panel == -1) //first press of TAB
 741                 {
 742                         if (highlightedPanel != -1)
 743                                 HUD_Panel_UpdatePosSizeForId(highlightedPanel)
 744                         else
 745                                 panel_pos = '0 0 0';
 746                         starting_panel = highlightedPanel; //can be -1, it means no starting panel
 747                         tab_panel_pos = panel_pos; //to compute level
 748                 }
 749                 else
 750                 {
 751                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 752                                 reset_tab_panels();
 753                         starting_panel = tab_panel;
 754                 }
 755                 tab_backward = (hudShiftState & S_SHIFT);
 756
 757                 float k, level, start_pos_x;
 758                 vector candidate_pos;
 759                 const float LEVELS_NUM = 4;
 760                 float level_height = vid_conheight / LEVELS_NUM;
 761 :find_tab_panel
 762                 level = floor(tab_panel_pos_y / level_height) * level_height; //starting level
 763                 candidate_pos_x = (!tab_backward) ? vid_conwidth : 0;
 764                 start_pos_x = tab_panel_pos_x;
 765                 tab_panel = -1;
 766                 k=0;
 767                 while(++k)
 768                 {
 769                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 770                         {
 771                                 if (i == tab_panels[i] || i == starting_panel)
 772                                         continue;
 773                                 HUD_Panel_UpdatePosSizeForId(i)
 774                                 if (panel_pos_y >= level && (panel_pos_y - level) < level_height)
 775                                 if (  ( !tab_backward && panel_pos_x >= start_pos_x && (panel_pos_x < candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y <= candidate_pos_y)) )
 776                                         || ( tab_backward && panel_pos_x <= start_pos_x && (panel_pos_x > candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y >= candidate_pos_y)) )  )
 777                                 {
 778                                         tab_panel = i;
 779                                         tab_panel_pos = candidate_pos = panel_pos;
 780                                 }
 781                         }
 782                         if (tab_panel != -1)
 783                                 break;
 784                         if (k == LEVELS_NUM) //tab_panel not found
 785                         {
 786                                 reset_tab_panels();
 787                                 if (old_tab_panel == -2) //this prevents an infinite loop (should not happen normally)
 788                                 {
 789                                         tab_panel = -1;
 790                                         return true;
 791                                 }
 792                                 starting_panel = old_tab_panel;
 793                                 old_tab_panel = -2;
 794                                 goto find_tab_panel; //u must find tab_panel!
 795                         }
 796                         if (!tab_backward)
 797                         {
 798                                 level = mod(level + level_height, vid_conheight);
 799                                 start_pos_x = 0;
 800                                 candidate_pos_x = vid_conwidth;
 801                         }
 802                         else
 803                         {
 804                                 level = mod(level - level_height, vid_conheight);
 805                                 start_pos_x = vid_conwidth;
 806                                 candidate_pos_x = 0;
 807                         }
 808                 }
 809
 810                 tab_panels[tab_panel] = tab_panel;
 811         }
 812         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 813         {
 814                 if (bInputType == 1 || mouseClicked)
 815                         return true;
 816
 817                 if (highlightedPanel != -1)
 818                 {
 819                         HUD_Panel_GetName(highlightedPanel);
 820                         cvar_set(strcat("hud_panel_", panel_name), ftos(!(panel_enabled)));
 821                 }
 822                 else
 823                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 824         }
 825         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 826         {
 827                 if (bInputType == 1 || mouseClicked)
 828                         return true;
 829
 830                 if (highlightedPanel != -1)
 831                 {
 832                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 833                         panel_size_copied = panel_size;
 834                         highlightedPanel_copied = highlightedPanel;
 835                 }
 836         }
 837         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 838         {
 839                 if (bInputType == 1 || mouseClicked)
 840                         return true;
 841
 842                 if (highlightedPanel_copied == -1 || highlightedPanel == -1)
 843                         return true;
 844
 845                 HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 846
 847                 // reduce size if it'd go beyond screen boundaries
 848                 vector tmp_size = panel_size_copied;
 849                 if (panel_pos_x + panel_size_copied_x > vid_conwidth)
 850                         tmp_size_x = vid_conwidth - panel_pos_x;
 851                 if (panel_pos_y + panel_size_copied_y > vid_conheight)
 852                         tmp_size_y = vid_conheight - panel_pos_y;
 853
 854                 if (panel_size == tmp_size)
 855                         return true;
 856
 857                 // backup first!
 858                 panel_pos_backup = panel_pos;
 859                 panel_size_backup = panel_size;
 860                 highlightedPanel_backup = highlightedPanel;
 861
 862                 s = strcat(ftos(tmp_size_x/vid_conwidth), " ", ftos(tmp_size_y/vid_conheight));
 863                 HUD_Panel_GetName(highlightedPanel);
 864                 cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 865         }
 866         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 867         {
 868                 if (bInputType == 1 || mouseClicked)
 869                         return true;
 870                 //restore previous values
 871                 if (highlightedPanel_backup != -1)
 872                 {
 873                         HUD_Panel_GetName(highlightedPanel_backup);
 874                         s = strcat(ftos(panel_pos_backup_x/vid_conwidth), " ", ftos(panel_pos_backup_y/vid_conheight));
 875                         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 876                         s = strcat(ftos(panel_size_backup_x/vid_conwidth), " ", ftos(panel_size_backup_y/vid_conheight));
 877                         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 878                         highlightedPanel_backup = -1;
 879                 }
 880         }
 881         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 882         {
 883                 if (bInputType == 1)
 884                 {
 885                         pressed_key_time = 0;
 886                         return true;
 887                 }
 888                 else if (pressed_key_time == 0)
 889                         pressed_key_time = time;
 890
 891                 if (!mouseClicked)
 892                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 893         }
 894         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 895         {
 896                 if (bInputType == 1)
 897                         return true;
 898                 if (highlightedPanel != -1)
 899                         HUD_Panel_EnableMenu();
 900         }
 901         else if(hit_con_bind)
 902                 return false;
 903
 904         return true;
 905 }
 906
 907 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 908 {
 909         float i, j, border;
 910
 911         while(j < HUD_PANEL_NUM)
 912         {
 913                 i = panel_order[j];
 914                 j += 1;
 915
 916                 HUD_Panel_UpdatePosSizeForId(i);
 917
 918                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 919
 920                 // move
 921                 if(allow_move && mousepos_x >= panel_pos_x && mousepos_y >= panel_pos_y && mousepos_x <= panel_pos_x + panel_size_x && mousepos_y <= panel_pos_y + panel_size_y)
 922                 {
 923                         return 1;
 924                 }
 925                 // resize from topleft border
 926                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 927                 {
 928                         return 2;
 929                 }
 930                 // resize from topright border
 931                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 932                 {
 933                         return 3;
 934                 }
 935                 // resize from bottomleft border
 936                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
 937                 {
 938                         return 3;
 939                 }
 940                 // resize from bottomright border
 941                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
 942                 {
 943                         return 2;
 944                 }
 945         }
 946         return 0;
 947 }
 948
 949 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 950 void HUD_Panel_FirstInDrawQ(float id)
 951 {
 952         float i;
 953         var float place = -1;
 954         // find out where in the array our current id is, save into place
 955         for(i = 0; i < HUD_PANEL_NUM; ++i)
 956         {
 957                 if(panel_order[i] == id)
 958                 {
 959                         place = i;
 960                         break;
 961                 }
 962         }
 963         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 964         if(place == -1)
 965                 place = HUD_PANEL_NUM - 1;
 966
 967         // move all ids up by one step in the array until "place"
 968         for(i = place; i > 0; --i)
 969         {
 970                 panel_order[i] = panel_order[i-1];
 971         }
 972         // now save the new top id
 973         panel_order[0] = id;
 974
 975         // let's save them into the cvar by some strcat trickery
 976         string s;
 977         for(i = 0; i < HUD_PANEL_NUM; ++i)
 978         {
 979                 s = strcat(s, ftos(panel_order[i]), " ");
 980         }
 981         cvar_set("_hud_panelorder", s);
 982         if(hud_panelorder_prev)
 983                 strunzone(hud_panelorder_prev);
 984         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
 985 }
 986
 987 void HUD_Panel_Highlight(float allow_move)
 988 {
 989         float i, j, border;
 990
 991         while(j < HUD_PANEL_NUM)
 992         {
 993                 i = panel_order[j];
 994                 j += 1;
 995
 996                 HUD_Panel_UpdatePosSizeForId(i);
 997
 998                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 999
1000                 // move
1001                 if(allow_move && mousepos_x >= panel_pos_x && mousepos_y >= panel_pos_y && mousepos_x <= panel_pos_x + panel_size_x && mousepos_y <= panel_pos_y + panel_size_y)
1002                 {
1003                         highlightedPanel = i;
1004                         HUD_Panel_FirstInDrawQ(i);
1005                         highlightedAction = 1;
1006                         panel_click_distance = mousepos - panel_pos;
1007                         return;
1008                 }
1009                 // resize from topleft border
1010                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1011                 {
1012                         highlightedPanel = i;
1013                         HUD_Panel_FirstInDrawQ(i);
1014                         highlightedAction = 2;
1015                         resizeCorner = 1;
1016                         panel_click_distance = mousepos - panel_pos;
1017                         panel_click_resizeorigin = panel_pos + panel_size;
1018                         return;
1019                 }
1020                 // resize from topright border
1021                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1022                 {
1023                         highlightedPanel = i;
1024                         HUD_Panel_FirstInDrawQ(i);
1025                         highlightedAction = 2;
1026                         resizeCorner = 2;
1027                         panel_click_distance_x = panel_size_x - mousepos_x + panel_pos_x;
1028                         panel_click_distance_y = mousepos_y - panel_pos_y;
1029                         panel_click_resizeorigin = panel_pos + eY * panel_size_y;
1030                         return;
1031                 }
1032                 // resize from bottomleft border
1033                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
1034                 {
1035                         highlightedPanel = i;
1036                         HUD_Panel_FirstInDrawQ(i);
1037                         highlightedAction = 2;
1038                         resizeCorner = 3;
1039                         panel_click_distance_x = mousepos_x - panel_pos_x;
1040                         panel_click_distance_y = panel_size_y - mousepos_y + panel_pos_y;
1041                         panel_click_resizeorigin = panel_pos + eX * panel_size_x;
1042                         return;
1043                 }
1044                 // resize from bottomright border
1045                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
1046                 {
1047                         highlightedPanel = i;
1048                         HUD_Panel_FirstInDrawQ(i);
1049                         highlightedAction = 2;
1050                         resizeCorner = 4;
1051                         panel_click_distance = panel_size - mousepos + panel_pos;
1052                         panel_click_resizeorigin = panel_pos;
1053                         return;
1054                 }
1055         }
1056         highlightedPanel = -1;
1057         highlightedAction = 0;
1058 }
1059
1060 void HUD_Panel_EnableMenu()
1061 {
1062         menu_enabled = 2;
1063         menu_enabled_time = time;
1064         HUD_Panel_GetName(highlightedPanel);
1065         localcmd("menu_showhudoptions ", panel_name, "\n");
1066 }
1067 float mouse_over_panel;
1068 void HUD_Panel_Mouse()
1069 {
1070         // TODO: needs better check... is there any float that contains the current state of the menu? _menu_alpha isn't apparently updated the frame the menu gets enabled
1071         if (autocvar__menu_alpha == 0 && time - menu_enabled_time > 0.5)
1072                 menu_enabled = 0;
1073
1074         /*
1075         print("menu_enabled: ", ftos(menu_enabled), "\n");
1076         print("Highlighted: ", ftos(highlightedPanel), "\n");
1077         print("Menu theAlpha: ", ftos(autocvar__menu_alpha), "\n");
1078         */
1079
1080         if(autocvar__menu_alpha == 1)
1081                 return;
1082
1083         mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1084
1085         mousepos_x = bound(0, mousepos_x, vid_conwidth);
1086         mousepos_y = bound(0, mousepos_y, vid_conheight);
1087
1088         if(mouseClicked)
1089         {
1090                 if(prevMouseClicked == 0)
1091                 {
1092                         if (tab_panel != -1)
1093                         {
1094                                 //stop ctrl-tab selection
1095                                 tab_panel = -1;
1096                                 reset_tab_panels();
1097                         }
1098                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1099                                                                         // and calls HUD_Panel_UpdatePosSizeForId() for the highlighted panel
1100                         if (highlightedPanel != -1)
1101                         {
1102                                 highlightedPanel_initial_pos = panel_pos;
1103                                 highlightedPanel_initial_size = panel_size;
1104                         }
1105                         // doubleclick check
1106                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel != -1 && prevMouseClickedPos == mousepos)
1107                         {
1108                                 mouseClicked = 0; // to prevent spam, I guess.
1109                                 HUD_Panel_EnableMenu();
1110                         }
1111                         else
1112                         {
1113                                 if (mouseClicked & S_MOUSE1)
1114                                 {
1115                                         prevMouseClickedTime = time;
1116                                         prevMouseClickedPos = mousepos;
1117                                 }
1118                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1119                         }
1120                 }
1121                 else
1122                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
1123
1124                 if (highlightedPanel != -1)
1125                 {
1126                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1127                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1128                         {
1129                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1130                                 // backup!
1131                                 panel_pos_backup = highlightedPanel_initial_pos;
1132                                 panel_size_backup = highlightedPanel_initial_size;
1133                                 highlightedPanel_backup = highlightedPanel;
1134                         }
1135                         else
1136                                 // in case the clicked panel is inside another panel and we aren't
1137                                 // moving it, avoid the immediate "fix" of its position/size
1138                                 // (often unwanted and hateful) by disabling collisions check
1139                                 hud_configure_checkcollisions = false;
1140                 }
1141
1142                 if(highlightedAction == 1)
1143                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1144                 else if(highlightedAction == 2)
1145                 {
1146                         vector mySize;
1147                         if(resizeCorner == 1) {
1148                                 mySize_x = panel_click_resizeorigin_x - (mousepos_x - panel_click_distance_x);
1149                                 mySize_y = panel_click_resizeorigin_y - (mousepos_y - panel_click_distance_y);
1150                         } else if(resizeCorner == 2) {
1151                                 mySize_x = mousepos_x + panel_click_distance_x - panel_click_resizeorigin_x;
1152                                 mySize_y = panel_click_distance_y + panel_click_resizeorigin_y - mousepos_y;
1153                         } else if(resizeCorner == 3) {
1154                                 mySize_x = panel_click_resizeorigin_x + panel_click_distance_x - mousepos_x;
1155                                 mySize_y = mousepos_y + panel_click_distance_y - panel_click_resizeorigin_y;
1156                         } else { // resizeCorner == 4
1157                                 mySize_x = mousepos_x - (panel_click_resizeorigin_x - panel_click_distance_x);
1158                                 mySize_y = mousepos_y - (panel_click_resizeorigin_y - panel_click_distance_y);
1159                         }
1160                         HUD_Panel_SetPosSize(mySize);
1161                 }
1162         }
1163         else
1164         {
1165                 if(menu_enabled == 2)
1166                         mouse_over_panel = 0;
1167                 else
1168                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(TRUE);
1169                 if (mouse_over_panel && tab_panel == -1)
1170                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1171         }
1172         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1173         const vector cursorsize = '32 32 0';
1174         float cursor_alpha = 1 - autocvar__menu_alpha;
1175
1176         if(!mouse_over_panel)
1177                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1178         else if(mouse_over_panel == 1)
1179                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1180         else if(mouse_over_panel == 2)
1181                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1182         else
1183                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1184
1185         prevMouseClicked = mouseClicked;
1186 }
1187
1188 const float hlBorderSize = 4;
1189 const string hlBorder = "gfx/hud/default/border_highlighted";
1190 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1191 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1192 {
1193         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1194         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1195         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size_y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1196         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1197         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size_x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1198 }