qcsrc/client/hud/crosshair.qc

   1 #include "crosshair.qh"
   2
   3 #include <client/draw.qh>
   4 #include <client/hud/panel/scoreboard.qh>
   5 #include <client/view.qh>
   6 #include <common/deathtypes/all.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/mapobjects/trigger/viewloc.qh>
   9 #include <common/minigames/cl_minigames.qh>
  10 #include <common/minigames/cl_minigames_hud.qh>
  11 #include <common/mutators/mutator/overkill/oknex.qh>
  12 #include <common/vehicles/all.qh>
  13 #include <common/viewloc.qh>
  14 #include <common/wepent.qh>
  15 #include <lib/csqcmodel/cl_player.qh>
  16
  17 float pickup_crosshair_time, pickup_crosshair_size;
  18 float hitindication_crosshair_size;
  19 float use_vortex_chargepool;
  20
  21 float reticle_type;
  22
  23 vector wcross_origin;
  24 float wcross_scale_prev, wcross_alpha_prev;
  25 vector wcross_color_prev;
  26 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
  27 vector wcross_color_goal_prev;
  28 float wcross_changedonetime;
  29
  30 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
  31 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
  32 float wcross_name_changestarttime, wcross_name_changedonetime;
  33 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
  34
  35 float wcross_ring_prev;
  36
  37 entity trueaim;
  38 entity trueaim_rifle;
  39
  40 const float SHOTTYPE_HITTEAM = 1;
  41 const float SHOTTYPE_HITOBSTRUCTION = 2;
  42 const float SHOTTYPE_HITWORLD = 3;
  43 const float SHOTTYPE_HITENEMY = 4;
  44
  45 void TrueAim_Init()
  46 {
  47         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  48         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  49 }
  50
  51 float EnemyHitCheck()
  52 {
  53         float t, n;
  54         wcross_origin = project_3d_to_2d(trace_endpos);
  55         wcross_origin.z = 0;
  56         if(trace_ent)
  57                 n = trace_ent.entnum;
  58         else
  59                 n = trace_networkentity;
  60         if(n < 1)
  61                 return SHOTTYPE_HITWORLD;
  62         if(n > maxclients)
  63                 return SHOTTYPE_HITWORLD;
  64         t = entcs_GetTeam(n - 1);
  65         if(teamplay)
  66                 if(t == myteam)
  67                         return SHOTTYPE_HITTEAM;
  68         if(t == NUM_SPECTATOR)
  69                 return SHOTTYPE_HITWORLD;
  70         return SHOTTYPE_HITENEMY;
  71 }
  72
  73 float TrueAimCheck(entity wepent)
  74 {
  75         if(wepent.activeweapon.spawnflags & WEP_FLAG_NOTRUEAIM)
  76                 return SHOTTYPE_HITWORLD;
  77
  78         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
  79         vector vecs, trueaimpoint, w_shotorg;
  80         vector mi, ma, dv;
  81         float shottype;
  82         entity ta;
  83         float mv;
  84
  85         mi = ma = '0 0 0';
  86         ta = trueaim;
  87         mv = MOVE_NOMONSTERS;
  88
  89         switch(wepent.activeweapon) // WEAPONTODO
  90         {
  91                 case WEP_VORTEX:
  92                 case WEP_OVERKILL_NEX:
  93                 case WEP_VAPORIZER:
  94                         mv = MOVE_NORMAL;
  95                         break;
  96                 case WEP_RIFLE:
  97                         ta = trueaim_rifle;
  98                         mv = MOVE_NORMAL;
  99                         if(zoomscript_caught)
 100                         {
 101                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 102                                 return EnemyHitCheck();
 103                         }
 104                         break;
 105                 case WEP_DEVASTATOR: // projectile has a size!
 106                         mi = '-3 -3 -3';
 107                         ma = '3 3 3';
 108                         break;
 109                 case WEP_FIREBALL: // projectile has a size!
 110                         mi = '-16 -16 -16';
 111                         ma = '16 16 16';
 112                         break;
 113                 case WEP_SEEKER: // projectile has a size!
 114                         mi = '-2 -2 -2';
 115                         ma = '2 2 2';
 116                         break;
 117                 case WEP_ELECTRO: // projectile has a size!
 118                         mi = '0 0 -3';
 119                         ma = '0 0 -3';
 120                         break;
 121         }
 122
 123         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 124
 125         vecs = decompressShotOrigin(STAT(SHOTORG));
 126
 127         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 128         trueaimpoint = trace_endpos;
 129         // move trueaimpoint a little bit forward to make the final tracebox reliable
 130         // since it sometimes doesn't reach a teammate by a hair
 131         trueaimpoint += view_forward;
 132
 133         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 134                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 135
 136         if(vecs.x > 0)
 137                 vecs.y = -vecs.y;
 138         else
 139                 vecs = '0 0 0';
 140
 141         dv = view_right * vecs.y + view_up * vecs.z;
 142         w_shotorg = traceorigin + dv;
 143
 144         // now move the vecs forward as much as requested if possible
 145         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 146         w_shotorg = trace_endpos - view_forward * nudge;
 147
 148         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 149         shottype = EnemyHitCheck();
 150         if(shottype != SHOTTYPE_HITWORLD)
 151                 return shottype;
 152
 153 #if 0
 154         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 155         // or rather, I know why, but see no fix
 156         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 157                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 158                 return SHOTTYPE_HITOBSTRUCTION;
 159 #endif
 160
 161         return SHOTTYPE_HITWORLD;
 162 }
 163
 164 void HUD_Crosshair_Vehicle(entity this)
 165 {
 166         if(hud != HUD_BUMBLEBEE_GUN)
 167         {
 168                 Vehicle info = REGISTRY_GET(Vehicles, hud);
 169                 info.vr_crosshair(info, this);
 170         }
 171 }
 172
 173 vector crosshair_getcolor(entity this, float health_stat)
 174 {
 175         static float rainbow_last_flicker;
 176         static vector rainbow_prev_color;
 177         vector wcross_color = '0 0 0';
 178         switch(autocvar_crosshair_color_special)
 179         {
 180                 case 1: // weapon color
 181                 {
 182                         if(this != WEP_Null && hud == HUD_NORMAL)
 183                         {
 184                                 wcross_color = this.wpcolor;
 185                                 break;
 186                         }
 187                         else { goto normalcolor; }
 188                 }
 189
 190                 case 2: // color based on health and armor
 191                 {
 192                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 193                         float health_and_armor = floor(v.x + 1);
 194                         wcross_color = HUD_Get_Num_Color(health_and_armor, 200, false);
 195                         break;
 196                 }
 197
 198                 case 3: // rainbow/random color
 199                 {
 200                         if(time >= rainbow_last_flicker)
 201                         {
 202                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 203                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 204                         }
 205                         wcross_color = rainbow_prev_color;
 206                         break;
 207                 }
 208 LABEL(normalcolor)
 209                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 210         }
 211
 212         return wcross_color;
 213 }
 214
 215 void HUD_Crosshair(entity this)
 216 {
 217         // reset player's alpha here upon death since forced scoreboard prevents running the crosshair_chase code
 218         if(autocvar_chase_active > 0 && autocvar_crosshair_chase && STAT(HEALTH) <= 0 && csqcplayer)
 219                 csqcplayer.alpha = csqcplayer.m_alpha;
 220
 221         if (autocvar_chase_active > 0 && autocvar_chase_front)
 222         {
 223                 csqcplayer.alpha = csqcplayer.m_alpha;
 224                 return;
 225         }
 226
 227         float f, i, j;
 228         vector v;
 229         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) && !autocvar_cl_lockview
 230                 && spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair)
 231                 && !HUD_MinigameMenu_IsOpened())
 232         {
 233                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 234                         return;
 235
 236                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 237                         return;
 238
 239                 if (hud != HUD_NORMAL)
 240                 {
 241                         HUD_Crosshair_Vehicle(this);
 242                         return;
 243                 }
 244
 245                 string wcross_style;
 246                 float wcross_alpha, wcross_resolution;
 247                 wcross_style = autocvar_crosshair;
 248                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
 249                         wcross_style = autocvar_crosshair_2d;
 250                 if (wcross_style == "0")
 251                         return;
 252                 wcross_resolution = autocvar_crosshair_size;
 253                 if (wcross_resolution == 0)
 254                         return;
 255                 wcross_alpha = autocvar_crosshair_alpha;
 256                 if (wcross_alpha == 0)
 257                         return;
 258
 259                 // TrueAim check
 260                 float shottype;
 261
 262                 static int crosshair_chase_state = 0;
 263
 264                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 265                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
 266                         wcross_origin = viewloc_mousepos;
 267                 else if(autocvar_chase_active > 0 && autocvar_crosshair_chase)
 268                 {
 269                         vector player_org = ((csqcplayer) ? csqcplayer.origin + csqcplayer.view_ofs : view_origin);
 270                         float my_alpha = (!csqcplayer.m_alpha) ? 1 : csqcplayer.m_alpha;
 271                         float chase_playeralpha = bound(0.001, autocvar_crosshair_chase_playeralpha, 1);
 272                         if(csqcplayer && chase_playeralpha < 1 && my_alpha > chase_playeralpha)
 273                         {
 274                                 crosshair_chase_state = 2;
 275                                 bool hit = false;
 276                                 if (pointinsidebox(view_origin, csqcplayer.absmin, csqcplayer.absmax))
 277                                         hit = true;
 278                                 else
 279                                 {
 280                                         WarpZone_TraceLine(view_origin, view_origin + max_shot_distance * view_forward, MOVE_NORMAL, NULL);
 281                                         if(trace_ent == csqcplayer)
 282                                                 hit = true;
 283                                 }
 284                                 float prev_alpha = csqcplayer.alpha;
 285                                 if(hit)
 286                                         csqcplayer.alpha = max(csqcplayer.alpha - frametime * 5, chase_playeralpha);
 287                                 else
 288                                         csqcplayer.alpha = min(csqcplayer.alpha + frametime * 5, my_alpha);
 289
 290                                 if (csqcplayer.alpha != prev_alpha)
 291                                 {
 292                                         FOREACH_ENTITY_CLASS("ENT_CLIENT_MODEL", it.tag_entity == csqcplayer,
 293                                         {
 294                                                 it.alpha = csqcplayer.alpha;
 295                                         });
 296                                 }
 297                         }
 298                         traceline(player_org, player_org + max_shot_distance * view_forward, MOVE_WORLDONLY, NULL);
 299                         wcross_origin = project_3d_to_2d(trace_endpos);
 300                 }
 301                 else
 302                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
 303                 wcross_origin.z = 0;
 304                 if (crosshair_chase_state == 2) // enabled (this frame)
 305                         crosshair_chase_state = 1;
 306                 else if (crosshair_chase_state == 1) // turned off in the previous frame
 307                 {
 308                         // reset player alpha only in this frame
 309                         if (csqcplayer)
 310                                 csqcplayer.alpha = csqcplayer.m_alpha;
 311                         crosshair_chase_state = 0; // turned off and alpha reset
 312                 }
 313
 314                 if(autocvar_crosshair_hittest)
 315                 {
 316                         vector wcross_oldorigin;
 317                         entity thiswep = viewmodels[0]; // TODO: unhardcode
 318                         wcross_oldorigin = wcross_origin;
 319                         shottype = TrueAimCheck(thiswep);
 320                         if(shottype == SHOTTYPE_HITWORLD)
 321                         {
 322                                 v = wcross_origin - wcross_oldorigin;
 323                                 v.x /= vid_conwidth;
 324                                 v.y /= vid_conheight;
 325                                 if(vdist(v, >, 0.01))
 326                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 327                         }
 328                         if(!autocvar_crosshair_hittest_showimpact)
 329                                 wcross_origin = wcross_oldorigin;
 330                 }
 331                 else
 332                         shottype = SHOTTYPE_HITWORLD;
 333
 334                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 335                 string wcross_name = "";
 336                 float wcross_scale, wcross_blur;
 337
 338                 entity e = WEP_Null;
 339                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 340                 {
 341                         entity wepent = viewmodels[0]; // TODO: unhardcode
 342                         e = wepent.switchingweapon;
 343                         if(e)
 344                         {
 345                                 if(autocvar_crosshair_per_weapon)
 346                                 {
 347                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 348                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 349                                         //if (wcross_resolution == 0)
 350                                                 //return;
 351
 352                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 353                                         wcross_resolution *= e.w_crosshair_size;
 354                                         wcross_name = e.w_crosshair;
 355                                 }
 356                         }
 357                 }
 358
 359                 if(wcross_name == "")
 360                         wcross_name = strcat("gfx/crosshair", wcross_style);
 361
 362                 // MAIN CROSSHAIR COLOR DECISION
 363                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
 364
 365                 if(autocvar_crosshair_effect_scalefade)
 366                 {
 367                         wcross_scale = wcross_resolution;
 368                         wcross_resolution = 1;
 369                 }
 370                 else
 371                 {
 372                         wcross_scale = 1;
 373                 }
 374
 375                 if(autocvar_crosshair_pickup)
 376                 {
 377                         float stat_pickup_time = STAT(LAST_PICKUP);
 378
 379                         if(pickup_crosshair_time < stat_pickup_time)
 380                         {
 381                                 if(time - stat_pickup_time < 5) // don't trigger the animation if it's too old
 382                                         pickup_crosshair_size = 1;
 383
 384                                 pickup_crosshair_time = stat_pickup_time;
 385                         }
 386
 387                         if(pickup_crosshair_size > 0)
 388                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 389                         else
 390                                 pickup_crosshair_size = 0;
 391
 392                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 393                 }
 394
 395                 // todo: make crosshair hit indication dependent on damage dealt
 396                 if(autocvar_crosshair_hitindication)
 397                 {
 398                         vector col = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 399
 400                         if(unaccounted_damage)
 401                         {
 402                                 hitindication_crosshair_size = 1;
 403                         }
 404
 405                         if(hitindication_crosshair_size > 0)
 406                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 407                         else
 408                                 hitindication_crosshair_size = 0;
 409
 410                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 411                         wcross_color.x += sin(hitindication_crosshair_size) * col.x;
 412                         wcross_color.y += sin(hitindication_crosshair_size) * col.y;
 413                         wcross_color.z += sin(hitindication_crosshair_size) * col.z;
 414                 }
 415
 416                 // no effects needed for targeting enemies, this can't possibly span all valid targets!
 417                 // just show for teammates to give a sign that they're an invalid target
 418                 //if(shottype == SHOTTYPE_HITENEMY)
 419                         //wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 420                 if(shottype == SHOTTYPE_HITTEAM)
 421                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 422
 423                 f = fabs(autocvar_crosshair_effect_time);
 424                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 425                 {
 426                         wcross_changedonetime = time + f;
 427                 }
 428                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 429                 {
 430                         wcross_name_changestarttime = time;
 431                         wcross_name_changedonetime = time + f;
 432                         if(wcross_name_goal_prev_prev)
 433                                 strunzone(wcross_name_goal_prev_prev);
 434                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 435                         wcross_name_goal_prev = strzone(wcross_name);
 436                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 437                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 438                         wcross_resolution_goal_prev = wcross_resolution;
 439                 }
 440
 441                 wcross_scale_goal_prev = wcross_scale;
 442                 wcross_alpha_goal_prev = wcross_alpha;
 443                 wcross_color_goal_prev = wcross_color;
 444
 445                 if((shottype == SHOTTYPE_HITTEAM && autocvar_crosshair_hittest_blur_teammate)
 446                         || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur_wall && !autocvar_chase_active))
 447                 {
 448                         wcross_blur = 1;
 449                         wcross_alpha *= 0.75;
 450                 }
 451                 else
 452                         wcross_blur = 0;
 453                 // *_prev is at time-frametime
 454                 // * is at wcross_changedonetime+f
 455                 // what do we have at time?
 456                 if(time < wcross_changedonetime)
 457                 {
 458                         f = frametime / (wcross_changedonetime - time + frametime);
 459                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 460                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 461                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 462                 }
 463
 464                 wcross_scale_prev = wcross_scale;
 465                 wcross_alpha_prev = wcross_alpha;
 466                 wcross_color_prev = wcross_color;
 467
 468                 MUTATOR_CALLHOOK(UpdateCrosshair);
 469
 470                 wcross_scale *= 1 - autocvar__menu_alpha;
 471                 wcross_alpha *= 1 - autocvar__menu_alpha;
 472                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 473
 474                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 475                 {
 476                         // crosshair rings for weapon stats
 477                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 478                         {
 479                                 // declarations and stats
 480                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 481                                 string ring_image = string_null, ring_inner_image = string_null;
 482                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 483
 484                                 ring_scale = autocvar_crosshair_ring_size;
 485
 486                                 entity wepent = viewmodels[0]; // TODO: unhardcode
 487
 488                                 int weapon_clipload = wepent.clip_load;
 489                                 int weapon_clipsize = wepent.clip_size;
 490
 491                                 float arc_heat = wepent.arc_heat_percent;
 492
 493                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 494                                         vortex_charge_movingavg = wepent.vortex_charge;
 495
 496                                 float charge = 0;
 497                                 float chargepool = 0;
 498                                 bool ring_vortex_enabled = false;
 499                                 if (autocvar_crosshair_ring && autocvar_crosshair_ring_vortex)
 500                                 {
 501                                         if (wepent.activeweapon == WEP_VORTEX)
 502                                         {
 503                                                 charge = wepent.vortex_charge;
 504                                                 chargepool = wepent.vortex_chargepool_ammo;
 505                                         }
 506                                         else if (wepent.activeweapon == WEP_OVERKILL_NEX)
 507                                         {
 508                                                 charge = wepent.oknex_charge;
 509                                                 chargepool = wepent.oknex_chargepool_ammo;
 510                                         }
 511                                         if (charge)
 512                                                 ring_vortex_enabled = true;
 513                                 }
 514
 515                                 if (ring_vortex_enabled)
 516                                 {
 517                                         if (chargepool || use_vortex_chargepool) {
 518                                                 use_vortex_chargepool = 1;
 519                                                 ring_inner_value = chargepool;
 520                                         } else {
 521                                                 float rate = autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate;
 522                                                 vortex_charge_movingavg = (1 - rate) * vortex_charge_movingavg + rate * charge;
 523                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (charge - vortex_charge_movingavg), 1);
 524                                         }
 525
 526                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 527                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
 528                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 529
 530                                         // draw the outer ring to show the current charge of the weapon
 531                                         ring_value = charge;
 532                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 533                                         ring_rgb = wcross_color;
 534                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 535                                 }
 536                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
 537                                 {
 538                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1);
 539                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 540                                         ring_rgb = wcross_color;
 541                                         ring_image = "gfx/crosshair_ring.tga";
 542                                 }
 543                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
 544                                 {
 545                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
 546                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 547                                         ring_rgb = wcross_color;
 548                                         ring_image = "gfx/crosshair_ring.tga";
 549                                 }
 550                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 551                                 {
 552                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 553                                         ring_scale = autocvar_crosshair_ring_reload_size;
 554                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 555                                         ring_rgb = wcross_color;
 556
 557                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 558                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 559                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
 560                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 561                                         else
 562                                                 ring_image = "gfx/crosshair_ring.tga";
 563                                 }
 564                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
 565                                 {
 566                                         ring_value = arc_heat;
 567                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 568                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 569                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 570                                         ring_image = "gfx/crosshair_ring.tga";
 571                                 }
 572
 573                                 // if in weapon switch animation, fade ring out/in
 574                                 if(autocvar_crosshair_effect_time > 0)
 575                                 {
 576                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 577                                         if (f >= 1)
 578                                         {
 579                                                 wcross_ring_prev = ((ring_image) ? true : false);
 580                                         }
 581
 582                                         if(wcross_ring_prev)
 583                                         {
 584                                                 if(f < 1)
 585                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 586                                         }
 587                                         else
 588                                         {
 589                                                 if(f < 1)
 590                                                         ring_alpha *= bound(0, f, 1);
 591                                         }
 592                                 }
 593
 594                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 595                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * wcross_resolution * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 596
 597                                 if (ring_value)
 598                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * wcross_resolution * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 599                         }
 600
 601 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 602                         MACRO_BEGIN \
 603                                 vector scaled_sz = sz * wcross_size; \
 604                                 if(wcross_blur > 0) \
 605                                 { \
 606                                         for(i = -2; i <= 2; ++i) \
 607                                         for(j = -2; j <= 2; ++j) \
 608                                         M(i,j,sz,scaled_sz,wcross_name,wcross_alpha*0.04); \
 609                                 } \
 610                                 else \
 611                                 { \
 612                                         M(0,0,sz,scaled_sz,wcross_name,wcross_alpha); \
 613                                 } \
 614                         MACRO_END
 615
 616 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,scaled_sz,wcross_name,wcross_alpha) \
 617                         drawpic(wcross_origin - ('0.5 0 0' * (scaled_sz.x + i * wcross_blur) + '0 0.5 0' * (scaled_sz.y + j * wcross_blur)), wcross_name, scaled_sz, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 618
 619 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 620                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 621
 622                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 623                         {
 624                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 625                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 626                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 627                                 f = 1 - f;
 628                         }
 629                         else
 630                         {
 631                                 f = 1;
 632                         }
 633                         wcross_name_alpha_goal_prev = f;
 634
 635                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 636                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 637
 638                         if(autocvar_crosshair_dot)
 639                         {
 640                                 vector wcross_color_old;
 641                                 wcross_color_old = wcross_color;
 642
 643                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
 644                                         wcross_color = stov(autocvar_crosshair_dot_color);
 645
 646                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
 647                                 // FIXME why don't we use wcross_alpha here?
 648                                 wcross_color = wcross_color_old;
 649                         }
 650                 }
 651         }
 652         else
 653         {
 654                 wcross_scale_prev = 0;
 655                 wcross_alpha_prev = 0;
 656                 wcross_scale_goal_prev = 0;
 657                 wcross_alpha_goal_prev = 0;
 658                 wcross_changedonetime = 0;
 659                 strfree(wcross_name_goal_prev);
 660                 strfree(wcross_name_goal_prev_prev);
 661                 wcross_name_changestarttime = 0;
 662                 wcross_name_changedonetime = 0;
 663                 wcross_name_alpha_goal_prev = 0;
 664                 wcross_name_alpha_goal_prev_prev = 0;
 665                 wcross_resolution_goal_prev = 0;
 666                 wcross_resolution_goal_prev_prev = 0;
 667         }
 668 }
 669
 670 void DrawReticle(entity this)
 671 {
 672         if(!autocvar_cl_reticle || MUTATOR_CALLHOOK(DrawReticle))
 673         {
 674                 reticle_type = 0;
 675                 return;
 676         }
 677
 678         float is_dead = (STAT(HEALTH) <= 0);
 679         string reticle_image = string_null;
 680         bool wep_zoomed = false;
 681         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 682         {
 683                 entity wepe = viewmodels[slot];
 684                 Weapon wep = wepe.activeweapon;
 685                 if(wep != WEP_Null && wep.wr_zoom)
 686                 {
 687                         bool do_zoom = wep.wr_zoom(wep, NULL);
 688                         if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
 689                                 reticle_image = wep.w_reticle;
 690                         wep_zoomed += do_zoom;
 691                 }
 692         }
 693         // Draw the aiming reticle for weapons that use it
 694         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 695         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 696         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 697         if(spectatee_status || is_dead || hud != HUD_NORMAL || this.viewloc)
 698         {
 699                 // no zoom reticle while dead
 700                 reticle_type = 0;
 701         }
 702         else if(wep_zoomed && autocvar_cl_reticle_weapon)
 703         {
 704                 if(reticle_image) { reticle_type = 2; }
 705                 else { reticle_type = 0; }
 706         }
 707         else if(button_zoom || zoomscript_caught)
 708         {
 709                 // normal zoom
 710                 reticle_type = 1;
 711         }
 712
 713         if(reticle_type)
 714         {
 715                 vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 716                 if(autocvar_cl_reticle_stretch)
 717                 {
 718                         reticle_size.x = vid_conwidth;
 719                         reticle_size.y = vid_conheight;
 720                         reticle_pos.x = 0;
 721                         reticle_pos.y = 0;
 722                 }
 723                 else
 724                 {
 725                         reticle_size.x = max(vid_conwidth, vid_conheight);
 726                         reticle_size.y = max(vid_conwidth, vid_conheight);
 727                         reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
 728                         reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
 729                 }
 730
 731                 float f = (zoomscript_caught) ? 1 : current_zoomfraction;
 732
 733                 if(f)
 734                 {
 735                         switch(reticle_type)
 736                         {
 737                                 case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
 738                                 case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
 739                         }
 740                 }
 741         }
 742 }