CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
   2 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
   3 project(NetRadiant C CXX)
   4
   5 option(BUILD_RADIANT "Build the GUI" ON)
   6
   7 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
   8     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
   9 endif ()
  10
  11 #-----------------------------------------------------------------------
  12 # Version
  13 #-----------------------------------------------------------------------
  14
  15 # CMake 3.0+ would allow this in project()
  16 set(NetRadiant_VERSION_MAJOR 1)
  17 set(NetRadiant_VERSION_MINOR 5)
  18 set(NetRadiant_VERSION_PATCH 0)
  19 set(NetRadiant_VERSION "${NetRadiant_VERSION_MAJOR}.${NetRadiant_VERSION_MINOR}.${NetRadiant_VERSION_PATCH}")
  20
  21 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_MAJOR" ${NetRadiant_VERSION_MAJOR})
  22 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_MINOR" ${NetRadiant_VERSION_MINOR})
  23 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_PATCH" ${NetRadiant_VERSION_PATCH})
  24
  25 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
  26
  27 find_package(Git REQUIRED)
  28 execute_process(
  29         COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
  30         WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
  31         OUTPUT_VARIABLE GIT_VERSION
  32         OUTPUT_STRIP_TRAILING_WHITESPACE
  33 )
  34 set(RADIANT_VERSION_STRING "${NetRadiant_VERSION}n")
  35 if (GIT_VERSION)
  36     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
  37 endif ()
  38
  39 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
  40
  41 #-----------------------------------------------------------------------
  42 # Language standard
  43 #-----------------------------------------------------------------------
  44
  45 set(CMAKE_CXX_STANDARD 11)
  46 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  47 if (CMAKE_VERSION VERSION_LESS "3.1")
  48     if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
  49         include(CheckCXXCompilerFlag)
  50         check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
  51         if (STD_CXX)
  52             set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
  53         else ()
  54             message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
  55         endif ()
  56     else ()
  57         message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
  58     endif ()
  59 endif ()
  60
  61 #-----------------------------------------------------------------------
  62 # Flags
  63 #-----------------------------------------------------------------------
  64
  65 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
  66 macro(addflags_c args)
  67     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
  68 endmacro()
  69 macro(addflags_cxx args)
  70     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
  71 endmacro()
  72 macro(addflags args)
  73     addflags_c("${args}")
  74     addflags_cxx("${args}")
  75 endmacro()
  76 addflags("-fno-strict-aliasing")
  77 if (NOT WIN32)
  78     addflags("-fvisibility=hidden")
  79 endif ()
  80
  81 if ("${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
  82     addflags("-Werror")
  83     addflags("-pedantic-errors")
  84 endif ()
  85
  86 addflags("-Wall")
  87 addflags("-Wextra")
  88 addflags("-pedantic")
  89
  90 addflags("-Wno-sign-compare")
  91 addflags("-Wno-unused-function")
  92 addflags("-Wno-unused-variable")
  93 addflags("-Wno-unused-parameter")
  94 addflags("-Wno-deprecated-declarations")
  95 addflags("-Wno-unused-but-set-variable")
  96 addflags("-Wno-missing-field-initializers")
  97
  98 addflags_c("-Wno-int-conversion")
  99 addflags_c("-Wno-pointer-to-int-cast")
 100 addflags_c("-Wno-incompatible-pointer-types")
 101
 102 addflags_cxx("-Wno-reorder")
 103 addflags_cxx("-Wno-delete-non-virtual-dtor")
 104
 105 set(CMAKE_POSITION_INDEPENDENT_CODE 1)
 106 set(GTK_TARGET 2 CACHE STRING "GTK target")
 107 add_definitions(-DGTK_TARGET=${GTK_TARGET})
 108
 109 #-----------------------------------------------------------------------
 110 # Defs
 111 #-----------------------------------------------------------------------
 112
 113 add_definitions(-DRADIANT_VERSION="${NetRadiant_VERSION}")
 114 add_definitions(-DRADIANT_MAJOR_VERSION="${NetRadiant_VERSION_MAJOR}")
 115 add_definitions(-DRADIANT_MINOR_VERSION="${NetRadiant_VERSION_MINOR}")
 116 add_definitions(-DRADIANT_PATCH_VERSION="${NetRadiant_VERSION_PATCH}")
 117
 118 add_definitions(-DRADIANT_ABOUTMSG="${NetRadiant_ABOUT}")
 119
 120 if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 121     add_definitions(-D_DEBUG=1)
 122 endif ()
 123
 124 macro(disable_deprecated name gtk2only)
 125     add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 126     if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 127         add_definitions(-D${name}_DISABLE_DEPRECATED)
 128     endif ()
 129 endmacro()
 130
 131 disable_deprecated(ATK 0)
 132 disable_deprecated(G 0)
 133 disable_deprecated(GDK 0)
 134 disable_deprecated(GDK_PIXBUF 0)
 135 disable_deprecated(GTK 1)
 136 disable_deprecated(PANGO 0)
 137
 138 if (APPLE)
 139     option(XWINDOWS "Build against X11" ON)
 140     add_definitions(
 141             -DPOSIX=1
 142     )
 143 elseif (WIN32)
 144     add_definitions(
 145             -DWIN32=1
 146             -D_WIN32=1
 147     )
 148 else ()
 149     set(XWINDOWS ON)
 150     add_definitions(
 151             -DPOSIX=1
 152     )
 153 endif ()
 154
 155 if (XWINDOWS)
 156     find_package(X11 REQUIRED)
 157     include_directories(${X11_INCLUDE_DIR})
 158     add_definitions(-DXWINDOWS=1)
 159 endif ()
 160
 161 include_directories("${PROJECT_SOURCE_DIR}/include")
 162 include_directories("${PROJECT_SOURCE_DIR}/libs")
 163
 164 if (WIN32 AND NOT CMAKE_CROSSCOMPILING)
 165     set(BUNDLE_LIBRARIES_DEFAULT ON)
 166 else ()
 167     set(BUNDLE_LIBRARIES_DEFAULT OFF)
 168 endif ()
 169 option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
 170
 171 macro(copy_dlls target)
 172     if (BUNDLE_LIBRARIES)
 173         add_custom_command(TARGET ${target} POST_BUILD
 174                 COMMAND bash
 175                 ARGS -c "ldd '$<TARGET_FILE:${target}>' | grep -v /c/Windows | awk '{ print $1 }' | while read dll; do cp \"$(which $dll)\" '${PROJECT_BINARY_DIR}'; done"
 176                 VERBATIM
 177                 )
 178     endif ()
 179 endmacro()
 180
 181 #-----------------------------------------------------------------------
 182 # Libraries
 183 #-----------------------------------------------------------------------
 184
 185 add_subdirectory(libs)
 186 add_subdirectory(include)
 187
 188 #-----------------------------------------------------------------------
 189 # Plugins
 190 #-----------------------------------------------------------------------
 191
 192 if (BUILD_RADIANT)
 193     add_subdirectory(contrib)
 194 endif ()
 195
 196 #-----------------------------------------------------------------------
 197 # Modules
 198 #-----------------------------------------------------------------------
 199
 200 if (BUILD_RADIANT)
 201     add_subdirectory(plugins)
 202 endif ()
 203
 204 #-----------------------------------------------------------------------
 205 # Radiant
 206 #-----------------------------------------------------------------------
 207
 208 if (CMAKE_EXECUTABLE_SUFFIX)
 209     string(REGEX REPLACE "^[.]" "" RADIANT_EXECUTABLE ${CMAKE_EXECUTABLE_SUFFIX})
 210 else ()
 211     execute_process(
 212             COMMAND uname -m
 213             OUTPUT_VARIABLE RADIANT_EXECUTABLE
 214             OUTPUT_STRIP_TRAILING_WHITESPACE
 215     )
 216 endif ()
 217
 218 macro(radiant_tool name)
 219     add_executable(${name} ${ARGN})
 220     install(
 221             TARGETS ${name}
 222             RUNTIME DESTINATION .
 223     )
 224     if (NOT (CMAKE_EXECUTABLE_SUFFIX STREQUAL ".${RADIANT_EXECUTABLE}"))
 225         add_custom_command(TARGET ${name} POST_BUILD
 226                 COMMAND ln -f -s "$<TARGET_FILE_NAME:${name}>" "${PROJECT_BINARY_DIR}/${name}.${RADIANT_EXECUTABLE}"
 227                 VERBATIM
 228                 )
 229         install(CODE "execute_process(COMMAND ${CMAKE_COMMAND} -E create_symlink
 230                 ${name}${CMAKE_EXECUTABLE_SUFFIX} ${CMAKE_INSTALL_PREFIX}/${name}.${RADIANT_EXECUTABLE})
 231                 ")
 232     endif ()
 233 endmacro()
 234
 235 if (BUILD_RADIANT)
 236     add_subdirectory(radiant _radiant)
 237     set_target_properties(radiant PROPERTIES
 238             COMPILE_DEFINITIONS RADIANT_EXECUTABLE="${RADIANT_EXECUTABLE}"
 239             )
 240 endif ()
 241
 242 #-----------------------------------------------------------------------
 243 # Tools
 244 #-----------------------------------------------------------------------
 245
 246 add_subdirectory(tools)
 247
 248 file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 249
 250 if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 251     # Copy data files from sources to the build directory
 252     message(STATUS "Copying data files")
 253     file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 254 endif ()
 255
 256 #-----------------------------------------------------------------------
 257 # Game packs
 258 #-----------------------------------------------------------------------
 259
 260 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
 261 add_custom_target(game_packs
 262         COMMAND ${CMAKE_COMMAND} -E make_directory games
 263         COMMAND DOWNLOAD_GAMEPACKS=yes SOURCE_DIR="${PROJECT_SOURCE_DIR}" "${PROJECT_SOURCE_DIR}/install-gamepacks.sh" "${PROJECT_BINARY_DIR}"
 264         COMMENT "Downloading game packs"
 265         )
 266 if (DOWNLOAD_GAMEPACKS)
 267     add_custom_target(game_packs_all ALL DEPENDS game_packs)
 268 endif ()
 269
 270 #-----------------------------------------------------------------------
 271 # Install
 272 #-----------------------------------------------------------------------
 273
 274 install(
 275         FILES
 276         "${PROJECT_BINARY_DIR}/RADIANT_MAJOR"
 277         "${PROJECT_BINARY_DIR}/RADIANT_MINOR"
 278         "${PROJECT_BINARY_DIR}/RADIANT_PATCH"
 279         DESTINATION .
 280 )
 281
 282 install(
 283         DIRECTORY
 284         setup/data/tools/
 285         docs
 286         DESTINATION .
 287 )
 288
 289 set(GAME_FILES
 290         DarkPlaces
 291         Nexuiz
 292         OpenArena
 293         Osirion
 294         Q3
 295         Quake2
 296         Quake
 297         Quetoo
 298         Tremulous
 299         UFOAI
 300         Unvanquished
 301         Warsow
 302         Xonotic
 303         )
 304 unset(_tmp)
 305 foreach (it ${GAME_FILES})
 306     set(dir "${PROJECT_BINARY_DIR}/games/${it}Pack")
 307     string(TOLOWER "${it}" it)
 308     list(APPEND _tmp "${dir}/games")
 309     list(APPEND _tmp "${dir}/${it}.game")
 310 endforeach ()
 311 set(GAME_FILES ${_tmp})
 312
 313 install(
 314         DIRECTORY
 315         ${GAME_FILES}
 316         DESTINATION .
 317         OPTIONAL
 318 )
 319
 320 include(cmake/scripts/package.cmake)