CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
   2 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
   3 project(NetRadiant C CXX)
   4
   5 option(BUILD_RADIANT "Build the GUI" ON)
   6
   7 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
   8     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
   9 endif ()
  10
  11 #-----------------------------------------------------------------------
  12 # Version
  13 #-----------------------------------------------------------------------
  14
  15 # CMake 3.0+ would allow this in project()
  16 set(NetRadiant_VERSION_MAJOR 1)
  17 set(NetRadiant_VERSION_MINOR 5)
  18 set(NetRadiant_VERSION_PATCH 0)
  19 set(NetRadiant_VERSION "${NetRadiant_VERSION_MAJOR}.${NetRadiant_VERSION_MINOR}.${NetRadiant_VERSION_PATCH}")
  20
  21 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_MAJOR" ${NetRadiant_VERSION_MAJOR})
  22 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_MINOR" ${NetRadiant_VERSION_MINOR})
  23 file(WRITE "${PROJECT_BINARY_DIR}/RADIANT_PATCH" ${NetRadiant_VERSION_PATCH})
  24
  25 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
  26
  27 find_package(Git REQUIRED)
  28 execute_process(
  29         COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
  30         WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
  31         OUTPUT_VARIABLE GIT_VERSION
  32         OUTPUT_STRIP_TRAILING_WHITESPACE
  33 )
  34 set(RADIANT_VERSION_STRING "${NetRadiant_VERSION}n")
  35 if (GIT_VERSION)
  36     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
  37 endif ()
  38
  39 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
  40
  41 #-----------------------------------------------------------------------
  42 # Language standard
  43 #-----------------------------------------------------------------------
  44
  45 set(CMAKE_CXX_STANDARD 11)
  46 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  47 if (CMAKE_VERSION VERSION_LESS "3.1")
  48     if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
  49         include(CheckCXXCompilerFlag)
  50         check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
  51         if (STD_CXX)
  52             set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
  53         else ()
  54             message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
  55         endif ()
  56     else ()
  57         message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
  58     endif ()
  59 endif ()
  60
  61 #-----------------------------------------------------------------------
  62 # Flags
  63 #-----------------------------------------------------------------------
  64
  65 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
  66 macro(addflags_c args)
  67     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
  68 endmacro()
  69 macro(addflags_cxx args)
  70     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
  71 endmacro()
  72 macro(addflags args)
  73     addflags_c("${args}")
  74     addflags_cxx("${args}")
  75 endmacro()
  76 addflags("-fno-strict-aliasing")
  77 if (NOT WIN32)
  78     addflags("-fvisibility=hidden")
  79 endif ()
  80
  81 if ("${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
  82     addflags("-Werror")
  83     addflags("-pedantic-errors")
  84 endif ()
  85
  86 addflags("-Wall")
  87 addflags("-Wextra")
  88 addflags("-pedantic")
  89
  90 addflags_c("-Wno-deprecated-declarations") # vfs.c: g_strdown
  91
  92 addflags("-Wno-sign-compare")
  93 addflags("-Wno-unused-function")
  94 addflags("-Wno-unused-variable")
  95 addflags("-Wno-unused-parameter")
  96 addflags("-Wno-missing-field-initializers")
  97
  98 addflags_c("-Wno-int-conversion")
  99 addflags_c("-Wno-pointer-to-int-cast")
 100 addflags_c("-Wno-incompatible-pointer-types")
 101
 102 set(CMAKE_POSITION_INDEPENDENT_CODE 1)
 103 set(GTK_TARGET 2 CACHE STRING "GTK target")
 104 add_definitions(-DGTK_TARGET=${GTK_TARGET})
 105
 106 #-----------------------------------------------------------------------
 107 # Defs
 108 #-----------------------------------------------------------------------
 109
 110 add_definitions(-DRADIANT_VERSION="${NetRadiant_VERSION}")
 111 add_definitions(-DRADIANT_MAJOR_VERSION="${NetRadiant_VERSION_MAJOR}")
 112 add_definitions(-DRADIANT_MINOR_VERSION="${NetRadiant_VERSION_MINOR}")
 113 add_definitions(-DRADIANT_PATCH_VERSION="${NetRadiant_VERSION_PATCH}")
 114
 115 add_definitions(-DRADIANT_ABOUTMSG="${NetRadiant_ABOUT}")
 116
 117 if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 118     add_definitions(-D_DEBUG=1)
 119 endif ()
 120
 121 macro(disable_deprecated name gtk2only)
 122     add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 123     if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 124         add_definitions(-D${name}_DISABLE_DEPRECATED)
 125     endif ()
 126 endmacro()
 127
 128 disable_deprecated(ATK 0)
 129 disable_deprecated(G 0)
 130 disable_deprecated(GDK 0)
 131 disable_deprecated(GDK_PIXBUF 0)
 132 disable_deprecated(GTK 1)
 133 disable_deprecated(PANGO 0)
 134
 135 if (APPLE)
 136     option(XWINDOWS "Build against X11" ON)
 137     add_definitions(
 138             -DPOSIX=1
 139     )
 140 elseif (WIN32)
 141     add_definitions(
 142             -DWIN32=1
 143             -D_WIN32=1
 144     )
 145 else ()
 146     set(XWINDOWS ON)
 147     add_definitions(
 148             -DPOSIX=1
 149     )
 150 endif ()
 151
 152 if (XWINDOWS)
 153     find_package(X11 REQUIRED)
 154     include_directories(${X11_INCLUDE_DIR})
 155     add_definitions(-DXWINDOWS=1)
 156 endif ()
 157
 158 include_directories("${PROJECT_SOURCE_DIR}/include")
 159 include_directories("${PROJECT_SOURCE_DIR}/libs")
 160
 161 if (WIN32 AND NOT CMAKE_CROSSCOMPILING)
 162     set(BUNDLE_LIBRARIES_DEFAULT ON)
 163 else ()
 164     set(BUNDLE_LIBRARIES_DEFAULT OFF)
 165 endif ()
 166 option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
 167
 168 macro(copy_dlls target)
 169     if (BUNDLE_LIBRARIES)
 170         add_custom_command(TARGET ${target} POST_BUILD
 171                 COMMAND bash
 172                 ARGS -c "ldd '$<TARGET_FILE:${target}>' | grep -v /c/Windows | awk '{ print $1 }' | while read dll; do cp \"$(which $dll)\" '${PROJECT_BINARY_DIR}'; done"
 173                 VERBATIM
 174                 )
 175     endif ()
 176 endmacro()
 177
 178 #-----------------------------------------------------------------------
 179 # Libraries
 180 #-----------------------------------------------------------------------
 181
 182 add_subdirectory(libs)
 183 add_subdirectory(include)
 184
 185 #-----------------------------------------------------------------------
 186 # Plugins
 187 #-----------------------------------------------------------------------
 188
 189 if (BUILD_RADIANT)
 190     add_subdirectory(contrib)
 191 endif ()
 192
 193 #-----------------------------------------------------------------------
 194 # Modules
 195 #-----------------------------------------------------------------------
 196
 197 if (BUILD_RADIANT)
 198     add_subdirectory(plugins)
 199 endif ()
 200
 201 #-----------------------------------------------------------------------
 202 # Radiant
 203 #-----------------------------------------------------------------------
 204
 205 if (CMAKE_EXECUTABLE_SUFFIX)
 206     string(REGEX REPLACE "^[.]" "" RADIANT_EXECUTABLE ${CMAKE_EXECUTABLE_SUFFIX})
 207 else ()
 208     execute_process(
 209             COMMAND uname -m
 210             OUTPUT_VARIABLE RADIANT_EXECUTABLE
 211             OUTPUT_STRIP_TRAILING_WHITESPACE
 212     )
 213 endif ()
 214
 215 macro(radiant_tool name)
 216     add_executable(${name} ${ARGN})
 217     install(
 218             TARGETS ${name}
 219             RUNTIME DESTINATION .
 220     )
 221     if (NOT (CMAKE_EXECUTABLE_SUFFIX STREQUAL ".${RADIANT_EXECUTABLE}"))
 222         add_custom_command(TARGET ${name} POST_BUILD
 223                 COMMAND ln -f -s "$<TARGET_FILE_NAME:${name}>" "${PROJECT_BINARY_DIR}/${name}.${RADIANT_EXECUTABLE}"
 224                 VERBATIM
 225                 )
 226         install(CODE "execute_process(COMMAND ${CMAKE_COMMAND} -E create_symlink
 227                 ${name}${CMAKE_EXECUTABLE_SUFFIX} ${CMAKE_INSTALL_PREFIX}/${name}.${RADIANT_EXECUTABLE})
 228                 ")
 229     endif ()
 230 endmacro()
 231
 232 if (BUILD_RADIANT)
 233     add_subdirectory(radiant _radiant)
 234     set_target_properties(radiant PROPERTIES
 235             COMPILE_DEFINITIONS RADIANT_EXECUTABLE="${RADIANT_EXECUTABLE}"
 236             )
 237 endif ()
 238
 239 #-----------------------------------------------------------------------
 240 # Tools
 241 #-----------------------------------------------------------------------
 242
 243 add_subdirectory(tools)
 244
 245 file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 246
 247 if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 248     # Copy data files from sources to the build directory
 249     message(STATUS "Copying data files")
 250     file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 251 endif ()
 252
 253 #-----------------------------------------------------------------------
 254 # Game packs
 255 #-----------------------------------------------------------------------
 256
 257 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
 258 add_custom_target(game_packs
 259         COMMAND ${CMAKE_COMMAND} -E make_directory games
 260         COMMAND DOWNLOAD_GAMEPACKS=yes SOURCE_DIR="${PROJECT_SOURCE_DIR}" "${PROJECT_SOURCE_DIR}/install-gamepacks.sh" "${PROJECT_BINARY_DIR}"
 261         COMMENT "Downloading game packs"
 262         )
 263 if (DOWNLOAD_GAMEPACKS)
 264     add_custom_target(game_packs_all ALL DEPENDS game_packs)
 265 endif ()
 266
 267 #-----------------------------------------------------------------------
 268 # Install
 269 #-----------------------------------------------------------------------
 270
 271 install(
 272         FILES
 273         "${PROJECT_BINARY_DIR}/RADIANT_MAJOR"
 274         "${PROJECT_BINARY_DIR}/RADIANT_MINOR"
 275         "${PROJECT_BINARY_DIR}/RADIANT_PATCH"
 276         DESTINATION .
 277 )
 278
 279 install(
 280         DIRECTORY
 281         setup/data/tools/
 282         docs
 283         DESTINATION .
 284 )
 285
 286 set(GAME_FILES
 287         DarkPlaces
 288         Nexuiz
 289         OpenArena
 290         Osirion
 291         Q3
 292         Quake2
 293         Quake
 294         Quetoo
 295         Tremulous
 296         UFOAI
 297         Unvanquished
 298         Warsow
 299         Xonotic
 300         )
 301 unset(_tmp)
 302 foreach (it ${GAME_FILES})
 303     set(dir "${PROJECT_BINARY_DIR}/games/${it}Pack")
 304     string(TOLOWER "${it}" it)
 305     list(APPEND _tmp "${dir}/games")
 306     list(APPEND _tmp "${dir}/${it}.game")
 307 endforeach ()
 308 set(GAME_FILES ${_tmp})
 309
 310 install(
 311         DIRECTORY
 312         ${GAME_FILES}
 313         DESTINATION .
 314         OPTIONAL
 315 )
 316
 317 include(cmake/scripts/package.cmake)