CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
   2 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
   3 project(NetRadiant C CXX)
   4
   5 option(BUILD_RADIANT "Build the GUI" ON)
   6 option(BUILD_TOOLS "Build the tools" ON)
   7 option(BUILD_CRUNCH "Build Crunch image support" OFF)
   8 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
   9 option(USE_WERROR "Build with -Werror -pedantic-errors" OFF)
  10 option(FHS_INSTALL "Install according to Filesystem Hierarchy Standard" OFF)
  11
  12 set(BUILD_BINARIES OFF CACHE INTERNAL "...")
  13 if (BUILD_RADIANT OR BUILD_TOOLS)
  14     set(BUILD_BINARIES ON)
  15 endif ()
  16
  17 #-----------------------------------------------------------------------
  18 # Paths
  19 #-----------------------------------------------------------------------
  20
  21 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  22     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
  23 endif ()
  24
  25 set(RADIANT_NAME "NetRadiant" CACHE INTERNAL "...")
  26 add_definitions(-DRADIANT_NAME="${RADIANT_NAME}")
  27 set(RADIANT_BASENAME netradiant CACHE INTERNAL "...")
  28 add_definitions(-DRADIANT_BASENAME="${RADIANT_BASENAME}")
  29
  30 set(RADIANT_LIB_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  31 set(RADIANT_BIN_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  32 set(RADIANT_DATA_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  33
  34 if (FHS_INSTALL)
  35     set(RADIANT_LIB_DIR ${CMAKE_INSTALL_PREFIX}/lib/${RADIANT_BASENAME})
  36     set(RADIANT_BIN_DIR ${CMAKE_INSTALL_PREFIX}/bin)
  37     set(RADIANT_DATA_DIR ${CMAKE_INSTALL_PREFIX}/share/${RADIANT_BASENAME})
  38 endif ()
  39
  40 #-----------------------------------------------------------------------
  41 # Version
  42 #-----------------------------------------------------------------------
  43
  44 # CMake 3.0+ would allow this in project()
  45 set(RADIANT_VERSION_MAJOR 1)
  46 set(RADIANT_VERSION_MINOR 5)
  47 set(RADIANT_VERSION_PATCH 0)
  48 set(RADIANT_VERSION "${RADIANT_VERSION_MAJOR}.${RADIANT_VERSION_MINOR}.${RADIANT_VERSION_PATCH}")
  49
  50 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
  51
  52 find_package(Git REQUIRED)
  53
  54 execute_process(
  55      COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
  56      WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
  57      OUTPUT_VARIABLE GIT_VERSION
  58      OUTPUT_STRIP_TRAILING_WHITESPACE
  59 )
  60
  61 set(RADIANT_VERSION_STRING "${RADIANT_VERSION}n")
  62
  63 if (GIT_VERSION)
  64     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
  65 endif ()
  66
  67 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
  68
  69 #-----------------------------------------------------------------------
  70 # Language standard
  71 #-----------------------------------------------------------------------
  72
  73 if (BUILD_BINARIES)
  74     set(CMAKE_CXX_STANDARD 11)
  75     set(CMAKE_CXX_STANDARD_REQUIRED ON)
  76     set(CMAKE_CXX_EXTENSIONS OFF)
  77
  78     if (CMAKE_VERSION VERSION_LESS "3.1")
  79         if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
  80             include(CheckCXXCompilerFlag)
  81             check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
  82             if (STD_CXX)
  83                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
  84             else ()
  85                 message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
  86             endif ()
  87         else ()
  88             message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
  89         endif ()
  90     endif ()
  91 endif ()
  92
  93 #-----------------------------------------------------------------------
  94 # Flags
  95 #-----------------------------------------------------------------------
  96
  97 if (BUILD_BINARIES)
  98     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
  99
 100     macro (addflags_c args)
 101         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
 102     endmacro ()
 103
 104     macro (addflags_cxx args)
 105         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
 106     endmacro ()
 107
 108     macro (addflags args)
 109         addflags_c("${args}")
 110         addflags_cxx("${args}")
 111     endmacro ()
 112
 113     addflags("-fno-strict-aliasing")
 114     if (NOT WIN32)
 115         addflags("-fvisibility=hidden")
 116     endif ()
 117
 118     if (USE_WERROR)
 119         addflags("-Werror")
 120         addflags("-pedantic-errors")
 121     endif ()
 122
 123     addflags("-Wall")
 124     addflags("-Wextra")
 125     addflags("-pedantic")
 126
 127     addflags_c("-Wno-deprecated-declarations") # vfs.c: g_strdown
 128
 129     addflags("-Wno-unused-function")
 130     addflags("-Wno-unused-variable")
 131     addflags("-Wno-unused-parameter")
 132
 133     set(CMAKE_POSITION_INDEPENDENT_CODE 1)
 134 endif ()
 135
 136 if (BUILD_RADIANT)
 137     set(GTK_TARGET 2 CACHE STRING "GTK target")
 138     add_definitions(-DGTK_TARGET=${GTK_TARGET})
 139 endif ()
 140
 141 #-----------------------------------------------------------------------
 142 # Defs
 143 #-----------------------------------------------------------------------
 144
 145 if (BUILD_BINARIES)
 146     add_definitions(-DRADIANT_VERSION="${RADIANT_VERSION}")
 147
 148     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 149         add_definitions(-D_DEBUG=1)
 150     endif ()
 151 endif ()
 152
 153 if (BUILD_RADIANT)
 154     add_definitions(-DRADIANT_ABOUTMSG="${RADIANT_ABOUTMSG}")
 155
 156     macro (disable_deprecated name gtk2only)
 157         add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 158         if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 159             add_definitions(-D${name}_DISABLE_DEPRECATED)
 160         endif ()
 161     endmacro ()
 162
 163     disable_deprecated(ATK 0)
 164     disable_deprecated(G 0)
 165     disable_deprecated(GDK 0)
 166     disable_deprecated(GDK_PIXBUF 0)
 167     disable_deprecated(GTK 1)
 168     disable_deprecated(PANGO 0)
 169 endif ()
 170
 171 if (BUILD_BINARIES)
 172     if(APPLE OR ${CMAKE_SYSTEM_NAME} STREQUAL "FreeBSD")
 173         link_directories(
 174             /usr/local/lib
 175         )
 176     endif ()
 177
 178     if (WIN32)
 179         add_definitions(
 180             -DWIN32=1
 181             -D_WIN32=1
 182         )
 183     else ()
 184         add_definitions(
 185             -DPOSIX=1
 186         )
 187     endif ()
 188 endif ()
 189
 190 if (BUILD_RADIANT AND NOT APPLE AND NOT WIN32)
 191     set(XWINDOWS ON)
 192     find_package(X11 REQUIRED)
 193     include_directories(${X11_INCLUDE_DIR})
 194     add_definitions(-DXWINDOWS=1)
 195 endif ()
 196
 197 if (BUILD_BINARIES)
 198     include_directories("${PROJECT_SOURCE_DIR}/include")
 199     include_directories("${PROJECT_SOURCE_DIR}/libs")
 200
 201     if (WIN32 AND NOT CMAKE_CROSSCOMPILING)
 202         set(BUNDLE_LIBRARIES_DEFAULT ON)
 203     else ()
 204         set(BUNDLE_LIBRARIES_DEFAULT OFF)
 205     endif ()
 206
 207     option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
 208
 209     macro (copy_dlls target)
 210         if (BUNDLE_LIBRARIES AND WIN32)
 211             add_custom_command(TARGET ${target} POST_BUILD
 212                 COMMAND bash
 213                 ARGS -c "ldd '$<TARGET_FILE:${target}>' | egrep -i '\\.dll ' | grep -iv '/c/Windows' | awk '{ print $1 }' | while read dll; do dllbasename=\"$(which \"$dll\")\"; [ -f \"${PROJECT_BINARY_DIR}/$dllbasename\" ] || cp --preserve=timestamps \"$dllbasename\" '${PROJECT_BINARY_DIR}'; done"
 214                 VERBATIM
 215         )
 216         endif ()
 217     endmacro ()
 218
 219     macro (bundle_stuff target)
 220         if (BUNDLE_LIBRARIES AND WIN32)
 221             add_custom_command(TARGET ${target} POST_BUILD
 222                 COMMAND bash
 223                 ARGS -c "mkdir -p '${PROJECT_BINARY_DIR}/share/themes'; mkdir -p '${PROJECT_BINARY_DIR}/lib'; mingw=\"$(echo '${CMAKE_C_COMPILER}' | sed -e 's|/bin/.*||')\"; [ -d '${PROJECT_BINARY_DIR}/share/themes/MS-Windows' ] || cp -r --preserve=timestamps \"$mingw/share/themes/MS-Windows\" '${PROJECT_BINARY_DIR}/share/themes/'; [ -d '${PROJECT_BINARY_DIR}/lib/gdk-pixbuf-2.0' ] || cp -r --preserve=timestamps \"$mingw/lib/gdk-pixbuf-2.0\" '${PROJECT_BINARY_DIR}/lib/'; [ -d '${PROJECT_BINARY_DIR}/lib/gtk-2.0' ] || cp -r --preserve=timestamps \"$mingw/lib/gtk-2.0\" '${PROJECT_BINARY_DIR}/lib/'"
 224                 VERBATIM
 225         )
 226
 227         file(GLOB DLL_FILES ${PROJECT_BINARY_DIR}/*.dll)
 228
 229         install(FILES
 230             ${DLL_FILES}
 231             DESTINATION ${CMAKE_INSTALL_PREFIX}
 232         )
 233
 234         install(DIRECTORY
 235             ${PROJECT_BINARY_DIR}/lib
 236             ${PROJECT_BINARY_DIR}/share
 237             DESTINATION ${CMAKE_INSTALL_PREFIX}
 238         )
 239         endif ()
 240     endmacro ()
 241 endif ()
 242
 243 #-----------------------------------------------------------------------
 244 # Libraries
 245 #-----------------------------------------------------------------------
 246
 247 if (BUILD_BINARIES)
 248     add_subdirectory(libs)
 249 endif ()
 250
 251 if (BUILD_RADIANT)
 252     add_subdirectory(include)
 253 endif ()
 254
 255 #-----------------------------------------------------------------------
 256 # Plugins
 257 #-----------------------------------------------------------------------
 258
 259 if (BUILD_RADIANT)
 260     add_subdirectory(contrib)
 261 endif ()
 262
 263 #-----------------------------------------------------------------------
 264 # Modules
 265 #-----------------------------------------------------------------------
 266
 267 if (BUILD_RADIANT)
 268     add_subdirectory(plugins)
 269 endif ()
 270
 271 #-----------------------------------------------------------------------
 272 # Radiant
 273 #-----------------------------------------------------------------------
 274
 275 if (BUILD_BINARIES)
 276     if (CMAKE_EXECUTABLE_SUFFIX)
 277         string(REGEX REPLACE "^[.]" "" RADIANT_EXECUTABLE ${CMAKE_EXECUTABLE_SUFFIX})
 278     endif ()
 279
 280     macro (radiant_tool name)
 281         add_executable(${name} ${ARGN})
 282
 283         copy_dlls(${name})
 284
 285         install(
 286             TARGETS ${name}
 287             RUNTIME DESTINATION ${RADIANT_BIN_DIR}
 288         )
 289     endmacro ()
 290
 291     if (BUILD_RADIANT)
 292         add_subdirectory(radiant)
 293         set_target_properties(${RADIANT_BASENAME} PROPERTIES
 294         COMPILE_DEFINITIONS RADIANT_EXECUTABLE="${RADIANT_EXECUTABLE}"
 295     )
 296     endif ()
 297 endif ()
 298
 299 #-----------------------------------------------------------------------
 300 # Tools
 301 #-----------------------------------------------------------------------
 302
 303 if (BUILD_TOOLS)
 304     add_subdirectory(tools)
 305
 306     file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 307
 308     if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 309         # Copy data files from sources to the build directory
 310         message(STATUS "Copying data files")
 311         file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 312     endif ()
 313 endif ()
 314
 315 #-----------------------------------------------------------------------
 316 # Game packs
 317 #-----------------------------------------------------------------------
 318
 319 set(GAMEPACKS_LICENSE_LIST free CACHE STRING "Download game packs by license")
 320 set(GAMEPACKS_NAME_LIST none CACHE STRING "Download game packs by name")
 321
 322 if (DOWNLOAD_GAMEPACKS)
 323     add_custom_target(game_packs ALL
 324        COMMAND "${PROJECT_SOURCE_DIR}/gamepack-manager" --license ${GAMEPACKS_LICENSE_LIST} --name ${GAMEPACKS_NAME_LIST} --download-dir "${PROJECT_BINARY_DIR}/download" --install-dir "${PROJECT_BINARY_DIR}" --download --install
 325        COMMENT "Downloading game packs"
 326     )
 327 endif ()
 328
 329 #-----------------------------------------------------------------------
 330 # Install
 331 #-----------------------------------------------------------------------
 332
 333 if (BUILD_BINARIES)
 334     install(DIRECTORY
 335         setup/data/tools/base
 336         setup/data/tools/bitmaps
 337         setup/data/tools/gl
 338         setup/data/tools/plugins
 339         docs
 340         DESTINATION ${RADIANT_DATA_DIR}
 341     )
 342 endif ()
 343
 344 if (DOWNLOAD_GAMEPACKS)
 345     if (FHS_INSTALL)
 346        set(GAME_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/share/netradiant")
 347     else ()
 348        set(GAME_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}")
 349     endif ()
 350
 351     file(GLOB GAME_DIRS ${PROJECT_BINARY_DIR}/*.game)
 352
 353     install(DIRECTORY
 354         ${PROJECT_BINARY_DIR}/games
 355         ${GAME_DIRS}
 356         DESTINATION ${RADIANT_DATA_DIR}
 357     )
 358 endif ()
 359
 360 if(BUILD_BINARIES AND FHS_INSTALL AND NOT WIN32 AND NOT APPLE)
 361     install(FILES
 362         ${PROJECT_SOURCE_DIR}/icons/netradiant.png
 363         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/pixmaps
 364     )
 365     install(FILES
 366         ${PROJECT_SOURCE_DIR}/icons/netradiant.desktop
 367         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/applications
 368     )
 369     install(FILES
 370         ${PROJECT_SOURCE_DIR}/icons/mime/map.xml
 371         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/mime/model
 372     )
 373 endif ()
 374
 375 include(cmake/scripts/package.cmake)